gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Atree;    use Atree;
  28 with Checks;   use Checks;
  29 with Einfo;    use Einfo;
  30 with Errout;   use Errout;
  31 with Expander; use Expander;
  32 with Exp_Util; use Exp_Util;
  33 with Freeze;   use Freeze;
  34 with Lib.Xref; use Lib.Xref;
  35 with Nlists;   use Nlists;
  36 with Nmake;    use Nmake;
  37 with Opt;      use Opt;
  38 with Sem;      use Sem;
  39 with Sem_Case; use Sem_Case;
  40 with Sem_Ch3;  use Sem_Ch3;
  41 with Sem_Ch8;  use Sem_Ch8;
  42 with Sem_Disp; use Sem_Disp;
  43 with Sem_Eval; use Sem_Eval;
  44 with Sem_Res;  use Sem_Res;
  45 with Sem_Type; use Sem_Type;
  46 with Sem_Util; use Sem_Util;
  47 with Sem_Warn; use Sem_Warn;
  48 with Stand;    use Stand;
  49 with Sinfo;    use Sinfo;
  50 with Targparm; use Targparm;
  51 with Tbuild;   use Tbuild;
  52 with Uintp;    use Uintp;
  53
  54 package body Sem_Ch5 is
  55
  56    Unblocked_Exit_Count : Nat := 0;
  57    --  This variable is used when processing if statements, case statements,
  58    --  and block statements. It counts the number of exit points that are
  59    --  not blocked by unconditional transfer instructions (for IF and CASE,
  60    --  these are the branches of the conditional, for a block, they are the
  61    --  statement sequence of the block, and the statement sequences of any
  62    --  exception handlers that are part of the block. When processing is
  63    --  complete, if this count is zero, it means that control cannot fall
  64    --  through the IF, CASE or block statement. This is used for the
  65    --  generation of warning messages. This variable is recursively saved
  66    --  on entry to processing the construct, and restored on exit.
  67
  68    -----------------------
  69    -- Local Subprograms --
  70    -----------------------
  71
  72    procedure Analyze_Iteration_Scheme (N : Node_Id);
  73
  74    procedure Check_Possible_Current_Value_Condition (Cnode : Node_Id);
  75    --  Cnode is N_If_Statement, N_Elsif_Part, or N_Iteration_Scheme
  76    --  (the latter when a WHILE condition is present). This call checks
  77    --  if Condition (Cnode) is of the form ([NOT] var op val), where var
  78    --  is a simple object, val is known at compile time, and op is one
  79    --  of the six relational operators. If this is the case, and the
  80    --  Current_Value field of "var" is not set, then it is set to Cnode.
  81    --  See Exp_Util.Set_Current_Value_Condition for further details.
  82
  83    ------------------------
  84    -- Analyze_Assignment --
  85    ------------------------
  86
  87    procedure Analyze_Assignment (N : Node_Id) is
  88       Lhs  : constant Node_Id := Name (N);
  89       Rhs  : constant Node_Id := Expression (N);
  90       T1   : Entity_Id;
  91       T2   : Entity_Id;
  92       Decl : Node_Id;
  93       Ent  : Entity_Id;
  94
  95       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  96       --  N is the node for the left hand side of an assignment, and it
  97       --  is not a variable. This routine issues an appropriate diagnostic.
  98
  99       procedure Set_Assignment_Type
 100         (Opnd      : Node_Id;
 101          Opnd_Type : in out Entity_Id);
 102       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 103       --  is the nominal subtype. This procedure is used to deal with cases
 104       --  where the nominal subtype must be replaced by the actual subtype.
 105
 106       -------------------------------
 107       -- Diagnose_Non_Variable_Lhs --
 108       -------------------------------
 109
 110       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 111       begin
 112          --  Not worth posting another error if left hand side already
 113          --  flagged as being illegal in some respect
 114
 115          if Error_Posted (N) then
 116             return;
 117
 118          --  Some special bad cases of entity names
 119
 120          elsif Is_Entity_Name (N) then
 121             if Ekind (Entity (N)) = E_In_Parameter then
 122                Error_Msg_N
 123                  ("assignment to IN mode parameter not allowed", N);
 124
 125             --  Private declarations in a protected object are turned into
 126             --  constants when compiling a protected function.
 127
 128             elsif Present (Scope (Entity (N)))
 129               and then Is_Protected_Type (Scope (Entity (N)))
 130               and then
 131                 (Ekind (Current_Scope) = E_Function
 132                   or else
 133                  Ekind (Enclosing_Dynamic_Scope (Current_Scope)) = E_Function)
 134             then
 135                Error_Msg_N
 136                  ("protected function cannot modify protected object", N);
 137
 138             elsif Ekind (Entity (N)) = E_Loop_Parameter then
 139                Error_Msg_N
 140                  ("assignment to loop parameter not allowed", N);
 141
 142             else
 143                Error_Msg_N
 144                  ("left hand side of assignment must be a variable", N);
 145             end if;
 146
 147          --  For indexed components or selected components, test prefix
 148
 149          elsif Nkind (N) = N_Indexed_Component then
 150             Diagnose_Non_Variable_Lhs (Prefix (N));
 151
 152          --  Another special case for assignment to discriminant.
 153
 154          elsif Nkind (N) = N_Selected_Component then
 155             if Present (Entity (Selector_Name (N)))
 156               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 157             then
 158                Error_Msg_N
 159                  ("assignment to discriminant not allowed", N);
 160             else
 161                Diagnose_Non_Variable_Lhs (Prefix (N));
 162             end if;
 163
 164          else
 165             --  If we fall through, we have no special message to issue!
 166
 167             Error_Msg_N ("left hand side of assignment must be a variable", N);
 168          end if;
 169       end Diagnose_Non_Variable_Lhs;
 170
 171       -------------------------
 172       -- Set_Assignment_Type --
 173       -------------------------
 174
 175       procedure Set_Assignment_Type
 176         (Opnd      : Node_Id;
 177          Opnd_Type : in out Entity_Id)
 178       is
 179       begin
 180          Require_Entity (Opnd);
 181
 182          --  If the assignment operand is an in-out or out parameter, then we
 183          --  get the actual subtype (needed for the unconstrained case).
 184          --  If the operand is the actual in an entry declaration, then within
 185          --  the accept statement it is replaced with a local renaming, which
 186          --  may also have an actual subtype.
 187
 188          if Is_Entity_Name (Opnd)
 189            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 190                       or else Ekind (Entity (Opnd)) =
 191                            E_In_Out_Parameter
 192                       or else Ekind (Entity (Opnd)) =
 193                            E_Generic_In_Out_Parameter
 194                       or else
 195                         (Ekind (Entity (Opnd)) = E_Variable
 196                           and then Nkind (Parent (Entity (Opnd))) =
 197                              N_Object_Renaming_Declaration
 198                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 199                              N_Accept_Statement))
 200          then
 201             Opnd_Type := Get_Actual_Subtype (Opnd);
 202
 203          --  If assignment operand is a component reference, then we get the
 204          --  actual subtype of the component for the unconstrained case.
 205
 206          elsif
 207            (Nkind (Opnd) = N_Selected_Component
 208              or else Nkind (Opnd) = N_Explicit_Dereference)
 209            and then not Is_Unchecked_Union (Opnd_Type)
 210          then
 211             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 212
 213             if Present (Decl) then
 214                Insert_Action (N, Decl);
 215                Mark_Rewrite_Insertion (Decl);
 216                Analyze (Decl);
 217                Opnd_Type := Defining_Identifier (Decl);
 218                Set_Etype (Opnd, Opnd_Type);
 219                Freeze_Itype (Opnd_Type, N);
 220
 221             elsif Is_Constrained (Etype (Opnd)) then
 222                Opnd_Type := Etype (Opnd);
 223             end if;
 224
 225          --  For slice, use the constrained subtype created for the slice
 226
 227          elsif Nkind (Opnd) = N_Slice then
 228             Opnd_Type := Etype (Opnd);
 229          end if;
 230       end Set_Assignment_Type;
 231
 232    --  Start of processing for Analyze_Assignment
 233
 234    begin
 235       Analyze (Rhs);
 236       Analyze (Lhs);
 237       T1 := Etype (Lhs);
 238
 239       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 240       --  must compute the intersection of the possible types on each side.
 241
 242       if Is_Overloaded (Lhs) then
 243          declare
 244             I  : Interp_Index;
 245             It : Interp;
 246
 247          begin
 248             T1 := Any_Type;
 249             Get_First_Interp (Lhs, I, It);
 250
 251             while Present (It.Typ) loop
 252                if Has_Compatible_Type (Rhs, It.Typ) then
 253                   if T1 /= Any_Type then
 254
 255                      --  An explicit dereference is overloaded if the prefix
 256                      --  is. Try to remove the ambiguity on the prefix, the
 257                      --  error will be posted there if the ambiguity is real.
 258
 259                      if Nkind (Lhs) = N_Explicit_Dereference then
 260                         declare
 261                            PI    : Interp_Index;
 262                            PI1   : Interp_Index := 0;
 263                            PIt   : Interp;
 264                            Found : Boolean;
 265
 266                         begin
 267                            Found := False;
 268                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 269
 270                            while Present (PIt.Typ) loop
 271                               if Is_Access_Type (PIt.Typ)
 272                                 and then Has_Compatible_Type
 273                                            (Rhs, Designated_Type (PIt.Typ))
 274                               then
 275                                  if Found then
 276                                     PIt :=
 277                                       Disambiguate (Prefix (Lhs),
 278                                         PI1, PI, Any_Type);
 279
 280                                     if PIt = No_Interp then
 281                                        Error_Msg_N
 282                                          ("ambiguous left-hand side"
 283                                             & " in assignment", Lhs);
 284                                        exit;
 285                                     else
 286                                        Resolve (Prefix (Lhs), PIt.Typ);
 287                                     end if;
 288
 289                                     exit;
 290                                  else
 291                                     Found := True;
 292                                     PI1 := PI;
 293                                  end if;
 294                               end if;
 295
 296                               Get_Next_Interp (PI, PIt);
 297                            end loop;
 298                         end;
 299
 300                      else
 301                         Error_Msg_N
 302                           ("ambiguous left-hand side in assignment", Lhs);
 303                         exit;
 304                      end if;
 305                   else
 306                      T1 := It.Typ;
 307                   end if;
 308                end if;
 309
 310                Get_Next_Interp (I, It);
 311             end loop;
 312          end;
 313
 314          if T1 = Any_Type then
 315             Error_Msg_N
 316               ("no valid types for left-hand side for assignment", Lhs);
 317             return;
 318          end if;
 319       end if;
 320
 321       Resolve (Lhs, T1);
 322
 323       if not Is_Variable (Lhs) then
 324          Diagnose_Non_Variable_Lhs (Lhs);
 325          return;
 326
 327       elsif Is_Limited_Type (T1)
 328         and then not Assignment_OK (Lhs)
 329         and then not Assignment_OK (Original_Node (Lhs))
 330       then
 331          Error_Msg_N
 332            ("left hand of assignment must not be limited type", Lhs);
 333          Explain_Limited_Type (T1, Lhs);
 334          return;
 335       end if;
 336
 337       --  Resolution may have updated the subtype, in case the left-hand
 338       --  side is a private protected component. Use the correct subtype
 339       --  to avoid scoping issues in the back-end.
 340
 341       T1 := Etype (Lhs);
 342       Set_Assignment_Type (Lhs, T1);
 343
 344       Resolve (Rhs, T1);
 345       Check_Unset_Reference (Rhs);
 346
 347       --  Remaining steps are skipped if Rhs was syntactically in error
 348
 349       if Rhs = Error then
 350          return;
 351       end if;
 352
 353       T2 := Etype (Rhs);
 354
 355       if Covers (T1, T2) then
 356          null;
 357       else
 358          Wrong_Type (Rhs, Etype (Lhs));
 359          return;
 360       end if;
 361
 362       Set_Assignment_Type (Rhs, T2);
 363
 364       if Total_Errors_Detected /= 0 then
 365          if No (T1) then
 366             T1 := Any_Type;
 367          end if;
 368
 369          if No (T2) then
 370             T2 := Any_Type;
 371          end if;
 372       end if;
 373
 374       if T1 = Any_Type or else T2 = Any_Type then
 375          return;
 376       end if;
 377
 378       if (Is_Class_Wide_Type (T2) or else Is_Dynamically_Tagged (Rhs))
 379         and then not Is_Class_Wide_Type (T1)
 380       then
 381          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 382
 383       elsif Is_Class_Wide_Type (T1)
 384         and then not Is_Class_Wide_Type (T2)
 385         and then not Is_Tag_Indeterminate (Rhs)
 386         and then not Is_Dynamically_Tagged (Rhs)
 387       then
 388          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 389       end if;
 390
 391       --  Tag propagation is done only in semantics mode only. If expansion
 392       --  is on, the rhs tag indeterminate function call has been expanded
 393       --  and tag propagation would have happened too late, so the
 394       --  propagation take place in expand_call instead.
 395
 396       if not Expander_Active
 397         and then Is_Class_Wide_Type (T1)
 398         and then Is_Tag_Indeterminate (Rhs)
 399       then
 400          Propagate_Tag (Lhs, Rhs);
 401       end if;
 402
 403       --  Ada 2005 (AI-231)
 404
 405       if Ada_Version >= Ada_05
 406         and then Nkind (Rhs) = N_Null
 407         and then Is_Access_Type (T1)
 408         and then not Assignment_OK (Lhs)
 409         and then ((Is_Entity_Name (Lhs)
 410                      and then Can_Never_Be_Null (Entity (Lhs)))
 411                    or else Can_Never_Be_Null (Etype (Lhs)))
 412       then
 413          Error_Msg_N
 414            ("(Ada 2005) NULL not allowed in null-excluding objects", Lhs);
 415       end if;
 416
 417       if Is_Scalar_Type (T1) then
 418          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 419
 420       elsif Is_Array_Type (T1)
 421         and then
 422           (Nkind (Rhs) /= N_Type_Conversion
 423              or else Is_Constrained (Etype (Rhs)))
 424       then
 425          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 426          --  but of course the indices do not have to match. If the right-hand
 427          --  side is a type conversion to an unconstrained type, a length check
 428          --  is performed on the expression itself during expansion. In rare
 429          --  cases, the redundant length check is computed on an index type
 430          --  with a different representation, triggering incorrect code in
 431          --  the back end.
 432
 433          Apply_Length_Check (Rhs, Etype (Lhs));
 434
 435       else
 436          --  Discriminant checks are applied in the course of expansion
 437
 438          null;
 439       end if;
 440
 441       --  Note: modifications of the Lhs may only be recorded after
 442       --  checks have been applied.
 443
 444       Note_Possible_Modification (Lhs);
 445
 446       --  ??? a real accessibility check is needed when ???
 447
 448       --  Post warning for useless assignment
 449
 450       if Warn_On_Redundant_Constructs
 451
 452          --  We only warn for source constructs
 453
 454          and then Comes_From_Source (N)
 455
 456          --  Where the entity is the same on both sides
 457
 458          and then Is_Entity_Name (Lhs)
 459          and then Is_Entity_Name (Original_Node (Rhs))
 460          and then Entity (Lhs) = Entity (Original_Node (Rhs))
 461
 462          --  But exclude the case where the right side was an operation
 463          --  that got rewritten (e.g. JUNK + K, where K was known to be
 464          --  zero). We don't want to warn in such a case, since it is
 465          --  reasonable to write such expressions especially when K is
 466          --  defined symbolically in some other package.
 467
 468         and then Nkind (Original_Node (Rhs)) not in N_Op
 469       then
 470          Error_Msg_NE
 471            ("?useless assignment of & to itself", N, Entity (Lhs));
 472       end if;
 473
 474       --  Check for non-allowed composite assignment
 475
 476       if not Support_Composite_Assign_On_Target
 477         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 478         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 479       then
 480          Error_Msg_CRT ("composite assignment", N);
 481       end if;
 482
 483       --  One more step. Let's see if we have a simple assignment of a
 484       --  known at compile time value to a simple variable. If so, we
 485       --  can record the value as the current value providing that:
 486
 487       --    We still have a simple assignment statement (no expansion
 488       --    activity has modified it in some peculiar manner)
 489
 490       --    The type is a discrete type
 491
 492       --    The assignment is to a named entity
 493
 494       --    The value is known at compile time
 495
 496       if Nkind (N) /= N_Assignment_Statement
 497         or else not Is_Discrete_Type (T1)
 498         or else not Is_Entity_Name (Lhs)
 499         or else not Compile_Time_Known_Value (Rhs)
 500       then
 501          return;
 502       end if;
 503
 504       Ent := Entity (Lhs);
 505
 506       --  Capture value if save to do so
 507
 508       if Safe_To_Capture_Value (N, Ent) then
 509          Set_Current_Value (Ent, Rhs);
 510       end if;
 511    end Analyze_Assignment;
 512
 513    -----------------------------
 514    -- Analyze_Block_Statement --
 515    -----------------------------
 516
 517    procedure Analyze_Block_Statement (N : Node_Id) is
 518       Decls : constant List_Id := Declarations (N);
 519       Id    : constant Node_Id := Identifier (N);
 520       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 521
 522    begin
 523       --  If no handled statement sequence is present, things are really
 524       --  messed up, and we just return immediately (this is a defence
 525       --  against previous errors).
 526
 527       if No (HSS) then
 528          return;
 529       end if;
 530
 531       --  Normal processing with HSS present
 532
 533       declare
 534          EH  : constant List_Id := Exception_Handlers (HSS);
 535          Ent : Entity_Id        := Empty;
 536          S   : Entity_Id;
 537
 538          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 539          --  Recursively save value of this global, will be restored on exit
 540
 541       begin
 542          --  Initialize unblocked exit count for statements of begin block
 543          --  plus one for each excption handler that is present.
 544
 545          Unblocked_Exit_Count := 1;
 546
 547          if Present (EH) then
 548             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 549          end if;
 550
 551          --  If a label is present analyze it and mark it as referenced
 552
 553          if Present (Id) then
 554             Analyze (Id);
 555             Ent := Entity (Id);
 556
 557             --  An error defense. If we have an identifier, but no entity,
 558             --  then something is wrong. If we have previous errors, then
 559             --  just remove the identifier and continue, otherwise raise
 560             --  an exception.
 561
 562             if No (Ent) then
 563                if Total_Errors_Detected /= 0 then
 564                   Set_Identifier (N, Empty);
 565                else
 566                   raise Program_Error;
 567                end if;
 568
 569             else
 570                Set_Ekind (Ent, E_Block);
 571                Generate_Reference (Ent, N, ' ');
 572                Generate_Definition (Ent);
 573
 574                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 575                   Set_Label_Construct (Parent (Ent), N);
 576                end if;
 577             end if;
 578          end if;
 579
 580          --  If no entity set, create a label entity
 581
 582          if No (Ent) then
 583             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 584             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 585             Set_Parent (Ent, N);
 586          end if;
 587
 588          Set_Etype (Ent, Standard_Void_Type);
 589          Set_Block_Node (Ent, Identifier (N));
 590          New_Scope (Ent);
 591
 592          if Present (Decls) then
 593             Analyze_Declarations (Decls);
 594             Check_Completion;
 595          end if;
 596
 597          Analyze (HSS);
 598          Process_End_Label (HSS, 'e', Ent);
 599
 600          --  If exception handlers are present, then we indicate that
 601          --  enclosing scopes contain a block with handlers. We only
 602          --  need to mark non-generic scopes.
 603
 604          if Present (EH) then
 605             S := Scope (Ent);
 606             loop
 607                Set_Has_Nested_Block_With_Handler (S);
 608                exit when Is_Overloadable (S)
 609                  or else Ekind (S) = E_Package
 610                  or else Is_Generic_Unit (S);
 611                S := Scope (S);
 612             end loop;
 613          end if;
 614
 615          Check_References (Ent);
 616          End_Scope;
 617
 618          if Unblocked_Exit_Count = 0 then
 619             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 620             Check_Unreachable_Code (N);
 621          else
 622             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 623          end if;
 624       end;
 625    end Analyze_Block_Statement;
 626
 627    ----------------------------
 628    -- Analyze_Case_Statement --
 629    ----------------------------
 630
 631    procedure Analyze_Case_Statement (N : Node_Id) is
 632       Exp            : Node_Id;
 633       Exp_Type       : Entity_Id;
 634       Exp_Btype      : Entity_Id;
 635       Last_Choice    : Nat;
 636       Dont_Care      : Boolean;
 637       Others_Present : Boolean;
 638
 639       Statements_Analyzed : Boolean := False;
 640       --  Set True if at least some statement sequences get analyzed.
 641       --  If False on exit, means we had a serious error that prevented
 642       --  full analysis of the case statement, and as a result it is not
 643       --  a good idea to output warning messages about unreachable code.
 644
 645       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 646       --  Recursively save value of this global, will be restored on exit
 647
 648       procedure Non_Static_Choice_Error (Choice : Node_Id);
 649       --  Error routine invoked by the generic instantiation below when
 650       --  the case statment has a non static choice.
 651
 652       procedure Process_Statements (Alternative : Node_Id);
 653       --  Analyzes all the statements associated to a case alternative.
 654       --  Needed by the generic instantiation below.
 655
 656       package Case_Choices_Processing is new
 657         Generic_Choices_Processing
 658           (Get_Alternatives          => Alternatives,
 659            Get_Choices               => Discrete_Choices,
 660            Process_Empty_Choice      => No_OP,
 661            Process_Non_Static_Choice => Non_Static_Choice_Error,
 662            Process_Associated_Node   => Process_Statements);
 663       use Case_Choices_Processing;
 664       --  Instantiation of the generic choice processing package
 665
 666       -----------------------------
 667       -- Non_Static_Choice_Error --
 668       -----------------------------
 669
 670       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 671       begin
 672          Flag_Non_Static_Expr
 673            ("choice given in case statement is not static!", Choice);
 674       end Non_Static_Choice_Error;
 675
 676       ------------------------
 677       -- Process_Statements --
 678       ------------------------
 679
 680       procedure Process_Statements (Alternative : Node_Id) is
 681          Choices : constant List_Id := Discrete_Choices (Alternative);
 682          Ent     : Entity_Id;
 683
 684       begin
 685          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 686          Statements_Analyzed := True;
 687
 688          --  An interesting optimization. If the case statement expression
 689          --  is a simple entity, then we can set the current value within
 690          --  an alternative if the alternative has one possible value.
 691
 692          --    case N is
 693          --      when 1      => alpha
 694          --      when 2 | 3  => beta
 695          --      when others => gamma
 696
 697          --  Here we know that N is initially 1 within alpha, but for beta
 698          --  and gamma, we do not know anything more about the initial value.
 699
 700          if Is_Entity_Name (Exp) then
 701             Ent := Entity (Exp);
 702
 703             if Ekind (Ent) = E_Variable
 704                  or else
 705                Ekind (Ent) = E_In_Out_Parameter
 706                  or else
 707                Ekind (Ent) = E_Out_Parameter
 708             then
 709                if List_Length (Choices) = 1
 710                  and then Nkind (First (Choices)) in N_Subexpr
 711                  and then Compile_Time_Known_Value (First (Choices))
 712                then
 713                   Set_Current_Value (Entity (Exp), First (Choices));
 714                end if;
 715
 716                Analyze_Statements (Statements (Alternative));
 717
 718                --  After analyzing the case, set the current value to empty
 719                --  since we won't know what it is for the next alternative
 720                --  (unless reset by this same circuit), or after the case.
 721
 722                Set_Current_Value (Entity (Exp), Empty);
 723                return;
 724             end if;
 725          end if;
 726
 727          --  Case where expression is not an entity name of a variable
 728
 729          Analyze_Statements (Statements (Alternative));
 730       end Process_Statements;
 731
 732       --  Table to record choices. Put after subprograms since we make
 733       --  a call to Number_Of_Choices to get the right number of entries.
 734
 735       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
 736
 737    --  Start of processing for Analyze_Case_Statement
 738
 739    begin
 740       Unblocked_Exit_Count := 0;
 741       Exp := Expression (N);
 742       Analyze_And_Resolve (Exp, Any_Discrete);
 743       Check_Unset_Reference (Exp);
 744       Exp_Type  := Etype (Exp);
 745       Exp_Btype := Base_Type (Exp_Type);
 746
 747       --  The expression must be of a discrete type which must be determinable
 748       --  independently of the context in which the expression occurs, but
 749       --  using the fact that the expression must be of a discrete type.
 750       --  Moreover, the type this expression must not be a character literal
 751       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
 752
 753       --  If error already reported by Resolve, nothing more to do
 754
 755       if Exp_Btype = Any_Discrete
 756         or else Exp_Btype = Any_Type
 757       then
 758          return;
 759
 760       elsif Exp_Btype = Any_Character then
 761          Error_Msg_N
 762            ("character literal as case expression is ambiguous", Exp);
 763          return;
 764
 765       elsif Ada_Version = Ada_83
 766         and then (Is_Generic_Type (Exp_Btype)
 767                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
 768       then
 769          Error_Msg_N
 770            ("(Ada 83) case expression cannot be of a generic type", Exp);
 771          return;
 772       end if;
 773
 774       --  If the case expression is a formal object of mode in out, then
 775       --  treat it as having a nonstatic subtype by forcing use of the base
 776       --  type (which has to get passed to Check_Case_Choices below).  Also
 777       --  use base type when the case expression is parenthesized.
 778
 779       if Paren_Count (Exp) > 0
 780         or else (Is_Entity_Name (Exp)
 781                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
 782       then
 783          Exp_Type := Exp_Btype;
 784       end if;
 785
 786       --  Call instantiated Analyze_Choices which does the rest of the work
 787
 788       Analyze_Choices
 789         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
 790
 791       if Exp_Type = Universal_Integer and then not Others_Present then
 792          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
 793       end if;
 794
 795       --  If all our exits were blocked by unconditional transfers of control,
 796       --  then the entire CASE statement acts as an unconditional transfer of
 797       --  control, so treat it like one, and check unreachable code. Skip this
 798       --  test if we had serious errors preventing any statement analysis.
 799
 800       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
 801          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 802          Check_Unreachable_Code (N);
 803       else
 804          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 805       end if;
 806
 807       if not Expander_Active
 808         and then Compile_Time_Known_Value (Expression (N))
 809         and then Serious_Errors_Detected = 0
 810       then
 811          declare
 812             Chosen : constant Node_Id := Find_Static_Alternative (N);
 813             Alt    : Node_Id;
 814
 815          begin
 816             Alt := First (Alternatives (N));
 817
 818             while Present (Alt) loop
 819                if Alt /= Chosen then
 820                   Remove_Warning_Messages (Statements (Alt));
 821                end if;
 822
 823                Next (Alt);
 824             end loop;
 825          end;
 826       end if;
 827    end Analyze_Case_Statement;
 828
 829    ----------------------------
 830    -- Analyze_Exit_Statement --
 831    ----------------------------
 832
 833    --  If the exit includes a name, it must be the name of a currently open
 834    --  loop. Otherwise there must be an innermost open loop on the stack,
 835    --  to which the statement implicitly refers.
 836
 837    procedure Analyze_Exit_Statement (N : Node_Id) is
 838       Target   : constant Node_Id := Name (N);
 839       Cond     : constant Node_Id := Condition (N);
 840       Scope_Id : Entity_Id;
 841       U_Name   : Entity_Id;
 842       Kind     : Entity_Kind;
 843
 844    begin
 845       if No (Cond) then
 846          Check_Unreachable_Code (N);
 847       end if;
 848
 849       if Present (Target) then
 850          Analyze (Target);
 851          U_Name := Entity (Target);
 852
 853          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
 854             Error_Msg_N ("invalid loop name in exit statement", N);
 855             return;
 856          else
 857             Set_Has_Exit (U_Name);
 858          end if;
 859
 860       else
 861          U_Name := Empty;
 862       end if;
 863
 864       for J in reverse 0 .. Scope_Stack.Last loop
 865          Scope_Id := Scope_Stack.Table (J).Entity;
 866          Kind := Ekind (Scope_Id);
 867
 868          if Kind = E_Loop
 869            and then (No (Target) or else Scope_Id = U_Name) then
 870             Set_Has_Exit (Scope_Id);
 871             exit;
 872
 873          elsif Kind = E_Block or else Kind = E_Loop then
 874             null;
 875
 876          else
 877             Error_Msg_N
 878               ("cannot exit from program unit or accept statement", N);
 879             exit;
 880          end if;
 881       end loop;
 882
 883       --  Verify that if present the condition is a Boolean expression
 884
 885       if Present (Cond) then
 886          Analyze_And_Resolve (Cond, Any_Boolean);
 887          Check_Unset_Reference (Cond);
 888       end if;
 889    end Analyze_Exit_Statement;
 890
 891    ----------------------------
 892    -- Analyze_Goto_Statement --
 893    ----------------------------
 894
 895    procedure Analyze_Goto_Statement (N : Node_Id) is
 896       Label       : constant Node_Id := Name (N);
 897       Scope_Id    : Entity_Id;
 898       Label_Scope : Entity_Id;
 899
 900    begin
 901       Check_Unreachable_Code (N);
 902
 903       Analyze (Label);
 904
 905       if Entity (Label) = Any_Id then
 906          return;
 907
 908       elsif Ekind (Entity (Label)) /= E_Label then
 909          Error_Msg_N ("target of goto statement must be a label", Label);
 910          return;
 911
 912       elsif not Reachable (Entity (Label)) then
 913          Error_Msg_N ("target of goto statement is not reachable", Label);
 914          return;
 915       end if;
 916
 917       Label_Scope := Enclosing_Scope (Entity (Label));
 918
 919       for J in reverse 0 .. Scope_Stack.Last loop
 920          Scope_Id := Scope_Stack.Table (J).Entity;
 921
 922          if Label_Scope = Scope_Id
 923            or else (Ekind (Scope_Id) /= E_Block
 924                      and then Ekind (Scope_Id) /= E_Loop)
 925          then
 926             if Scope_Id /= Label_Scope then
 927                Error_Msg_N
 928                  ("cannot exit from program unit or accept statement", N);
 929             end if;
 930
 931             return;
 932          end if;
 933       end loop;
 934
 935       raise Program_Error;
 936    end Analyze_Goto_Statement;
 937
 938    --------------------------
 939    -- Analyze_If_Statement --
 940    --------------------------
 941
 942    --  A special complication arises in the analysis of if statements.
 943
 944    --  The expander has circuitry to completely delete code that it
 945    --  can tell will not be executed (as a result of compile time known
 946    --  conditions). In the analyzer, we ensure that code that will be
 947    --  deleted in this manner is analyzed but not expanded. This is
 948    --  obviously more efficient, but more significantly, difficulties
 949    --  arise if code is expanded and then eliminated (e.g. exception
 950    --  table entries disappear). Similarly, itypes generated in deleted
 951    --  code must be frozen from start, because the nodes on which they
 952    --  depend will not be available at the freeze point.
 953
 954    procedure Analyze_If_Statement (N : Node_Id) is
 955       E : Node_Id;
 956
 957       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 958       --  Recursively save value of this global, will be restored on exit
 959
 960       Save_In_Deleted_Code : Boolean;
 961
 962       Del : Boolean := False;
 963       --  This flag gets set True if a True condition has been found,
 964       --  which means that remaining ELSE/ELSIF parts are deleted.
 965
 966       procedure Analyze_Cond_Then (Cnode : Node_Id);
 967       --  This is applied to either the N_If_Statement node itself or
 968       --  to an N_Elsif_Part node. It deals with analyzing the condition
 969       --  and the THEN statements associated with it.
 970
 971       -----------------------
 972       -- Analyze_Cond_Then --
 973       -----------------------
 974
 975       procedure Analyze_Cond_Then (Cnode : Node_Id) is
 976          Cond : constant Node_Id := Condition (Cnode);
 977          Tstm : constant List_Id := Then_Statements (Cnode);
 978
 979       begin
 980          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 981          Analyze_And_Resolve (Cond, Any_Boolean);
 982          Check_Unset_Reference (Cond);
 983          Check_Possible_Current_Value_Condition (Cnode);
 984
 985          --  If already deleting, then just analyze then statements
 986
 987          if Del then
 988             Analyze_Statements (Tstm);
 989
 990          --  Compile time known value, not deleting yet
 991
 992          elsif Compile_Time_Known_Value (Cond) then
 993             Save_In_Deleted_Code := In_Deleted_Code;
 994
 995             --  If condition is True, then analyze the THEN statements
 996             --  and set no expansion for ELSE and ELSIF parts.
 997
 998             if Is_True (Expr_Value (Cond)) then
 999                Analyze_Statements (Tstm);
1000                Del := True;
1001                Expander_Mode_Save_And_Set (False);
1002                In_Deleted_Code := True;
1003
1004             --  If condition is False, analyze THEN with expansion off
1005
1006             else -- Is_False (Expr_Value (Cond))
1007                Expander_Mode_Save_And_Set (False);
1008                In_Deleted_Code := True;
1009                Analyze_Statements (Tstm);
1010                Expander_Mode_Restore;
1011                In_Deleted_Code := Save_In_Deleted_Code;
1012             end if;
1013
1014          --  Not known at compile time, not deleting, normal analysis
1015
1016          else
1017             Analyze_Statements (Tstm);
1018          end if;
1019       end Analyze_Cond_Then;
1020
1021    --  Start of Analyze_If_Statement
1022
1023    begin
1024       --  Initialize exit count for else statements. If there is no else
1025       --  part, this count will stay non-zero reflecting the fact that the
1026       --  uncovered else case is an unblocked exit.
1027
1028       Unblocked_Exit_Count := 1;
1029       Analyze_Cond_Then (N);
1030
1031       --  Now to analyze the elsif parts if any are present
1032
1033       if Present (Elsif_Parts (N)) then
1034          E := First (Elsif_Parts (N));
1035          while Present (E) loop
1036             Analyze_Cond_Then (E);
1037             Next (E);
1038          end loop;
1039       end if;
1040
1041       if Present (Else_Statements (N)) then
1042          Analyze_Statements (Else_Statements (N));
1043       end if;
1044
1045       --  If all our exits were blocked by unconditional transfers of control,
1046       --  then the entire IF statement acts as an unconditional transfer of
1047       --  control, so treat it like one, and check unreachable code.
1048
1049       if Unblocked_Exit_Count = 0 then
1050          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1051          Check_Unreachable_Code (N);
1052       else
1053          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1054       end if;
1055
1056       if Del then
1057          Expander_Mode_Restore;
1058          In_Deleted_Code := Save_In_Deleted_Code;
1059       end if;
1060
1061       if not Expander_Active
1062         and then Compile_Time_Known_Value (Condition (N))
1063         and then Serious_Errors_Detected = 0
1064       then
1065          if Is_True (Expr_Value (Condition (N))) then
1066             Remove_Warning_Messages (Else_Statements (N));
1067
1068             if Present (Elsif_Parts (N)) then
1069                E := First (Elsif_Parts (N));
1070
1071                while Present (E) loop
1072                   Remove_Warning_Messages (Then_Statements (E));
1073                   Next (E);
1074                end loop;
1075             end if;
1076
1077          else
1078             Remove_Warning_Messages (Then_Statements (N));
1079          end if;
1080       end if;
1081    end Analyze_If_Statement;
1082
1083    ----------------------------------------
1084    -- Analyze_Implicit_Label_Declaration --
1085    ----------------------------------------
1086
1087    --  An implicit label declaration is generated in the innermost
1088    --  enclosing declarative part. This is done for labels as well as
1089    --  block and loop names.
1090
1091    --  Note: any changes in this routine may need to be reflected in
1092    --  Analyze_Label_Entity.
1093
1094    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1095       Id : constant Node_Id := Defining_Identifier (N);
1096    begin
1097       Enter_Name          (Id);
1098       Set_Ekind           (Id, E_Label);
1099       Set_Etype           (Id, Standard_Void_Type);
1100       Set_Enclosing_Scope (Id, Current_Scope);
1101    end Analyze_Implicit_Label_Declaration;
1102
1103    ------------------------------
1104    -- Analyze_Iteration_Scheme --
1105    ------------------------------
1106
1107    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1108       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1109       --  If the bounds are given by a 'Range reference on a function call
1110       --  that returns a controlled array, introduce an explicit declaration
1111       --  to capture the bounds, so that the function result can be finalized
1112       --  in timely fashion.
1113
1114       --------------------------------------
1115       -- Check_Controlled_Array_Attribute --
1116       --------------------------------------
1117
1118       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1119       begin
1120          if Nkind (DS) = N_Attribute_Reference
1121             and then Is_Entity_Name (Prefix (DS))
1122             and then Ekind (Entity (Prefix (DS))) = E_Function
1123             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1124             and then
1125               Is_Controlled (
1126                 Component_Type (Etype (Entity (Prefix (DS)))))
1127             and then Expander_Active
1128          then
1129             declare
1130                Loc  : constant Source_Ptr := Sloc (N);
1131                Arr  : constant Entity_Id :=
1132                         Etype (Entity (Prefix (DS)));
1133                Indx : constant Entity_Id :=
1134                         Base_Type (Etype (First_Index (Arr)));
1135                Subt : constant Entity_Id :=
1136                         Make_Defining_Identifier
1137                           (Loc, New_Internal_Name ('S'));
1138                Decl : Node_Id;
1139
1140             begin
1141                Decl :=
1142                  Make_Subtype_Declaration (Loc,
1143                    Defining_Identifier => Subt,
1144                    Subtype_Indication  =>
1145                       Make_Subtype_Indication (Loc,
1146                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1147                         Constraint =>
1148                           Make_Range_Constraint (Loc,
1149                             Relocate_Node (DS))));
1150                Insert_Before (Parent (N), Decl);
1151                Analyze (Decl);
1152
1153                Rewrite (DS,
1154                   Make_Attribute_Reference (Loc,
1155                     Prefix => New_Reference_To (Subt, Loc),
1156                     Attribute_Name => Attribute_Name (DS)));
1157                Analyze (DS);
1158             end;
1159          end if;
1160       end Check_Controlled_Array_Attribute;
1161
1162    --  Start of processing for Analyze_Iteration_Scheme
1163
1164    begin
1165       --  For an infinite loop, there is no iteration scheme
1166
1167       if No (N) then
1168          return;
1169
1170       else
1171          declare
1172             Cond : constant Node_Id := Condition (N);
1173
1174          begin
1175             --  For WHILE loop, verify that the condition is a Boolean
1176             --  expression and resolve and check it.
1177
1178             if Present (Cond) then
1179                Analyze_And_Resolve (Cond, Any_Boolean);
1180                Check_Unset_Reference (Cond);
1181
1182             --  Else we have a FOR loop
1183
1184             else
1185                declare
1186                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1187                   Id : constant Entity_Id := Defining_Identifier (LP);
1188                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1189
1190                begin
1191                   Enter_Name (Id);
1192
1193                   --  We always consider the loop variable to be referenced,
1194                   --  since the loop may be used just for counting purposes.
1195
1196                   Generate_Reference (Id, N, ' ');
1197
1198                   --  Check for case of loop variable hiding a local
1199                   --  variable (used later on to give a nice warning
1200                   --  if the hidden variable is never assigned).
1201
1202                   declare
1203                      H : constant Entity_Id := Homonym (Id);
1204                   begin
1205                      if Present (H)
1206                        and then Enclosing_Dynamic_Scope (H) =
1207                                 Enclosing_Dynamic_Scope (Id)
1208                        and then Ekind (H) = E_Variable
1209                        and then Is_Discrete_Type (Etype (H))
1210                      then
1211                         Set_Hiding_Loop_Variable (H, Id);
1212                      end if;
1213                   end;
1214
1215                   --  Now analyze the subtype definition
1216
1217                   Analyze (DS);
1218
1219                   if DS = Error then
1220                      return;
1221                   end if;
1222
1223                   --  The subtype indication may denote the completion
1224                   --  of an incomplete type declaration.
1225
1226                   if Is_Entity_Name (DS)
1227                     and then Present (Entity (DS))
1228                     and then Is_Type (Entity (DS))
1229                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1230                   then
1231                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1232                      Set_Etype  (DS, Entity (DS));
1233                   end if;
1234
1235                   if not Is_Discrete_Type (Etype (DS)) then
1236                      Wrong_Type (DS, Any_Discrete);
1237                      Set_Etype (DS, Any_Type);
1238                   end if;
1239
1240                   Check_Controlled_Array_Attribute (DS);
1241                   Make_Index (DS, LP);
1242
1243                   Set_Ekind          (Id, E_Loop_Parameter);
1244                   Set_Etype          (Id, Etype (DS));
1245                   Set_Is_Known_Valid (Id, True);
1246
1247                   --  The loop is not a declarative part, so the only entity
1248                   --  declared "within" must be frozen explicitly.
1249
1250                   declare
1251                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1252                   begin
1253                      if Is_Non_Empty_List (Flist) then
1254                         Insert_Actions (N, Flist);
1255                      end if;
1256                   end;
1257
1258                   --  Check for null or possibly null range and issue warning.
1259                   --  We suppress such messages in generic templates and
1260                   --  instances, because in practice they tend to be dubious
1261                   --  in these cases.
1262
1263                   if Nkind (DS) = N_Range
1264                     and then Comes_From_Source (N)
1265                   then
1266                      declare
1267                         L : constant Node_Id := Low_Bound  (DS);
1268                         H : constant Node_Id := High_Bound (DS);
1269
1270                         Llo : Uint;
1271                         Lhi : Uint;
1272                         LOK : Boolean;
1273                         Hlo : Uint;
1274                         Hhi : Uint;
1275                         HOK : Boolean;
1276
1277                      begin
1278                         Determine_Range (L, LOK, Llo, Lhi);
1279                         Determine_Range (H, HOK, Hlo, Hhi);
1280
1281                         --  If range of loop is null, issue warning
1282
1283                         if (LOK and HOK) and then Llo > Hhi then
1284
1285                            --  Suppress the warning if inside a generic
1286                            --  template or instance, since in practice
1287                            --  they tend to be dubious in these cases since
1288                            --  they can result from intended parametrization.
1289
1290                            if not Inside_A_Generic
1291                               and then not In_Instance
1292                            then
1293                               Error_Msg_N
1294                                 ("?loop range is null, loop will not execute",
1295                                  DS);
1296                            end if;
1297
1298                            --  Since we know the range of the loop is null,
1299                            --  set the appropriate flag to suppress any
1300                            --  warnings that would otherwise be issued in
1301                            --  the body of the loop that will not execute.
1302                            --  We do this even in the generic case, since
1303                            --  if it is dubious to warn on the null loop
1304                            --  itself, it is certainly dubious to warn for
1305                            --  conditions that occur inside it!
1306
1307                            Set_Is_Null_Loop (Parent (N));
1308
1309                         --  The other case for a warning is a reverse loop
1310                         --  where the upper bound is the integer literal
1311                         --  zero or one, and the lower bound can be positive.
1312
1313                         --  For example, we have
1314
1315                         --     for J in reverse N .. 1 loop
1316
1317                         --  In practice, this is very likely to be a case
1318                         --  of reversing the bounds incorrectly in the range.
1319
1320                         elsif Reverse_Present (LP)
1321                           and then Nkind (H) = N_Integer_Literal
1322                           and then (Intval (H) = Uint_0
1323                                       or else
1324                                     Intval (H) = Uint_1)
1325                           and then Lhi > Hhi
1326                         then
1327                            Error_Msg_N ("?loop range may be null", DS);
1328                         end if;
1329                      end;
1330                   end if;
1331                end;
1332             end if;
1333          end;
1334       end if;
1335    end Analyze_Iteration_Scheme;
1336
1337    -------------------
1338    -- Analyze_Label --
1339    -------------------
1340
1341    --  Note: the semantic work required for analyzing labels (setting them as
1342    --  reachable) was done in a prepass through the statements in the block,
1343    --  so that forward gotos would be properly handled. See Analyze_Statements
1344    --  for further details. The only processing required here is to deal with
1345    --  optimizations that depend on an assumption of sequential control flow,
1346    --  since of course the occurrence of a label breaks this assumption.
1347
1348    procedure Analyze_Label (N : Node_Id) is
1349       pragma Warnings (Off, N);
1350    begin
1351       Kill_Current_Values;
1352    end Analyze_Label;
1353
1354    --------------------------
1355    -- Analyze_Label_Entity --
1356    --------------------------
1357
1358    procedure Analyze_Label_Entity (E : Entity_Id) is
1359    begin
1360       Set_Ekind           (E, E_Label);
1361       Set_Etype           (E, Standard_Void_Type);
1362       Set_Enclosing_Scope (E, Current_Scope);
1363       Set_Reachable       (E, True);
1364    end Analyze_Label_Entity;
1365
1366    ----------------------------
1367    -- Analyze_Loop_Statement --
1368    ----------------------------
1369
1370    procedure Analyze_Loop_Statement (N : Node_Id) is
1371       Id  : constant Node_Id := Identifier (N);
1372       Ent : Entity_Id;
1373
1374    begin
1375       if Present (Id) then
1376
1377          --  Make name visible, e.g. for use in exit statements. Loop
1378          --  labels are always considered to be referenced.
1379
1380          Analyze (Id);
1381          Ent := Entity (Id);
1382          Generate_Reference  (Ent, N, ' ');
1383          Generate_Definition (Ent);
1384
1385          --  If we found a label, mark its type. If not, ignore it, since it
1386          --  means we have a conflicting declaration, which would already have
1387          --  been diagnosed at declaration time. Set Label_Construct of the
1388          --  implicit label declaration, which is not created by the parser
1389          --  for generic units.
1390
1391          if Ekind (Ent) = E_Label then
1392             Set_Ekind (Ent, E_Loop);
1393
1394             if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
1395                Set_Label_Construct (Parent (Ent), N);
1396             end if;
1397          end if;
1398
1399       --  Case of no identifier present
1400
1401       else
1402          Ent := New_Internal_Entity (E_Loop, Current_Scope, Sloc (N), 'L');
1403          Set_Etype (Ent,  Standard_Void_Type);
1404          Set_Parent (Ent, N);
1405       end if;
1406
1407       --  Kill current values on entry to loop, since statements in body
1408       --  of loop may have been executed before the loop is entered.
1409       --  Similarly we kill values after the loop, since we do not know
1410       --  that the body of the loop was executed.
1411
1412       Kill_Current_Values;
1413       New_Scope (Ent);
1414       Analyze_Iteration_Scheme (Iteration_Scheme (N));
1415       Analyze_Statements (Statements (N));
1416       Process_End_Label (N, 'e', Ent);
1417       End_Scope;
1418       Kill_Current_Values;
1419    end Analyze_Loop_Statement;
1420
1421    ----------------------------
1422    -- Analyze_Null_Statement --
1423    ----------------------------
1424
1425    --  Note: the semantics of the null statement is implemented by a single
1426    --  null statement, too bad everything isn't as simple as this!
1427
1428    procedure Analyze_Null_Statement (N : Node_Id) is
1429       pragma Warnings (Off, N);
1430    begin
1431       null;
1432    end Analyze_Null_Statement;
1433
1434    ------------------------
1435    -- Analyze_Statements --
1436    ------------------------
1437
1438    procedure Analyze_Statements (L : List_Id) is
1439       S   : Node_Id;
1440       Lab : Entity_Id;
1441
1442    begin
1443       --  The labels declared in the statement list are reachable from
1444       --  statements in the list. We do this as a prepass so that any
1445       --  goto statement will be properly flagged if its target is not
1446       --  reachable. This is not required, but is nice behavior!
1447
1448       S := First (L);
1449       while Present (S) loop
1450          if Nkind (S) = N_Label then
1451             Analyze (Identifier (S));
1452             Lab := Entity (Identifier (S));
1453
1454             --  If we found a label mark it as reachable.
1455
1456             if Ekind (Lab) = E_Label then
1457                Generate_Definition (Lab);
1458                Set_Reachable (Lab);
1459
1460                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
1461                   Set_Label_Construct (Parent (Lab), S);
1462                end if;
1463
1464             --  If we failed to find a label, it means the implicit declaration
1465             --  of the label was hidden.  A for-loop parameter can do this to
1466             --  a label with the same name inside the loop, since the implicit
1467             --  label declaration is in the innermost enclosing body or block
1468             --  statement.
1469
1470             else
1471                Error_Msg_Sloc := Sloc (Lab);
1472                Error_Msg_N
1473                  ("implicit label declaration for & is hidden#",
1474                   Identifier (S));
1475             end if;
1476          end if;
1477
1478          Next (S);
1479       end loop;
1480
1481       --  Perform semantic analysis on all statements
1482
1483       Conditional_Statements_Begin;
1484
1485       S := First (L);
1486       while Present (S) loop
1487          Analyze (S);
1488          Next (S);
1489       end loop;
1490
1491       Conditional_Statements_End;
1492
1493       --  Make labels unreachable. Visibility is not sufficient, because
1494       --  labels in one if-branch for example are not reachable from the
1495       --  other branch, even though their declarations are in the enclosing
1496       --  declarative part.
1497
1498       S := First (L);
1499       while Present (S) loop
1500          if Nkind (S) = N_Label then
1501             Set_Reachable (Entity (Identifier (S)), False);
1502          end if;
1503
1504          Next (S);
1505       end loop;
1506    end Analyze_Statements;
1507
1508    --------------------------------------------
1509    -- Check_Possible_Current_Value_Condition --
1510    --------------------------------------------
1511
1512    procedure Check_Possible_Current_Value_Condition (Cnode : Node_Id) is
1513       Cond : Node_Id;
1514
1515    begin
1516       --  Loop to deal with (ignore for now) any NOT operators present
1517
1518       Cond := Condition (Cnode);
1519       while Nkind (Cond) = N_Op_Not loop
1520          Cond := Right_Opnd (Cond);
1521       end loop;
1522
1523       --  Check possible relational operator
1524
1525       if Nkind (Cond) = N_Op_Eq
1526            or else
1527          Nkind (Cond) = N_Op_Ne
1528            or else
1529          Nkind (Cond) = N_Op_Ge
1530            or else
1531          Nkind (Cond) = N_Op_Le
1532            or else
1533          Nkind (Cond) = N_Op_Gt
1534            or else
1535          Nkind (Cond) = N_Op_Lt
1536       then
1537          if Compile_Time_Known_Value (Right_Opnd (Cond))
1538            and then Nkind (Left_Opnd (Cond)) = N_Identifier
1539          then
1540             declare
1541                Ent : constant Entity_Id := Entity (Left_Opnd (Cond));
1542
1543             begin
1544                if Ekind (Ent) = E_Variable
1545                     or else
1546                   Ekind (Ent) = E_Constant
1547                     or else
1548                   Is_Formal (Ent)
1549                     or else
1550                   Ekind (Ent) = E_Loop_Parameter
1551                then
1552                   --  Here we have a case where the Current_Value field
1553                   --  may need to be set. We set it if it is not already
1554                   --  set to a compile time expression value.
1555
1556                   --  Note that this represents a decision that one
1557                   --  condition blots out another previous one. That's
1558                   --  certainly right if they occur at the same level.
1559                   --  If the second one is nested, then the decision is
1560                   --  neither right nor wrong (it would be equally OK
1561                   --  to leave the outer one in place, or take the new
1562                   --  inner one. Really we should record both, but our
1563                   --  data structures are not that elaborate.
1564
1565                   if Nkind (Current_Value (Ent)) not in N_Subexpr then
1566                      Set_Current_Value (Ent, Cnode);
1567                   end if;
1568                end if;
1569             end;
1570          end if;
1571       end if;
1572    end Check_Possible_Current_Value_Condition;
1573
1574    ----------------------------
1575    -- Check_Unreachable_Code --
1576    ----------------------------
1577
1578    procedure Check_Unreachable_Code (N : Node_Id) is
1579       Error_Loc : Source_Ptr;
1580       P         : Node_Id;
1581
1582    begin
1583       if Is_List_Member (N)
1584         and then Comes_From_Source (N)
1585       then
1586          declare
1587             Nxt : Node_Id;
1588
1589          begin
1590             Nxt := Original_Node (Next (N));
1591
1592             --  If a label follows us, then we never have dead code, since
1593             --  someone could branch to the label, so we just ignore it.
1594
1595             if Nkind (Nxt) = N_Label then
1596                return;
1597
1598             --  Otherwise see if we have a real statement following us
1599
1600             elsif Present (Nxt)
1601               and then Comes_From_Source (Nxt)
1602               and then Is_Statement (Nxt)
1603             then
1604                --  Special very annoying exception. If we have a return that
1605                --  follows a raise, then we allow it without a warning, since
1606                --  the Ada RM annoyingly requires a useless return here!
1607
1608                if Nkind (Original_Node (N)) /= N_Raise_Statement
1609                  or else Nkind (Nxt) /= N_Return_Statement
1610                then
1611                   --  The rather strange shenanigans with the warning message
1612                   --  here reflects the fact that Kill_Dead_Code is very good
1613                   --  at removing warnings in deleted code, and this is one
1614                   --  warning we would prefer NOT to have removed :-)
1615
1616                   Error_Loc := Sloc (Nxt);
1617
1618                   --  If we have unreachable code, analyze and remove the
1619                   --  unreachable code, since it is useless and we don't
1620                   --  want to generate junk warnings.
1621
1622                   --  We skip this step if we are not in code generation mode.
1623                   --  This is the one case where we remove dead code in the
1624                   --  semantics as opposed to the expander, and we do not want
1625                   --  to remove code if we are not in code generation mode,
1626                   --  since this messes up the ASIS trees.
1627
1628                   --  Note that one might react by moving the whole circuit to
1629                   --  exp_ch5, but then we lose the warning in -gnatc mode.
1630
1631                   if Operating_Mode = Generate_Code then
1632                      loop
1633                         Nxt := Next (N);
1634
1635                         --  Quit deleting when we have nothing more to delete
1636                         --  or if we hit a label (since someone could transfer
1637                         --  control to a label, so we should not delete it).
1638
1639                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
1640
1641                         --  Statement/declaration is to be deleted
1642
1643                         Analyze (Nxt);
1644                         Remove (Nxt);
1645                         Kill_Dead_Code (Nxt);
1646                      end loop;
1647                   end if;
1648
1649                   --  Now issue the warning
1650
1651                   Error_Msg ("?unreachable code", Error_Loc);
1652                end if;
1653
1654             --  If the unconditional transfer of control instruction is
1655             --  the last statement of a sequence, then see if our parent
1656             --  is one of the constructs for which we count unblocked exits,
1657             --  and if so, adjust the count.
1658
1659             else
1660                P := Parent (N);
1661
1662                --  Statements in THEN part or ELSE part of IF statement
1663
1664                if Nkind (P) = N_If_Statement then
1665                   null;
1666
1667                --  Statements in ELSIF part of an IF statement
1668
1669                elsif Nkind (P) = N_Elsif_Part then
1670                   P := Parent (P);
1671                   pragma Assert (Nkind (P) = N_If_Statement);
1672
1673                --  Statements in CASE statement alternative
1674
1675                elsif Nkind (P) = N_Case_Statement_Alternative then
1676                   P := Parent (P);
1677                   pragma Assert (Nkind (P) = N_Case_Statement);
1678
1679                --  Statements in body of block
1680
1681                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
1682                  and then Nkind (Parent (P)) = N_Block_Statement
1683                then
1684                   null;
1685
1686                --  Statements in exception handler in a block
1687
1688                elsif Nkind (P) = N_Exception_Handler
1689                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
1690                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
1691                then
1692                   null;
1693
1694                --  None of these cases, so return
1695
1696                else
1697                   return;
1698                end if;
1699
1700                --  This was one of the cases we are looking for (i.e. the
1701                --  parent construct was IF, CASE or block) so decrement count.
1702
1703                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
1704             end if;
1705          end;
1706       end if;
1707    end Check_Unreachable_Code;
1708
1709 end Sem_Ch5;