gcc/ada/sem_ch5.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 5                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Expander; use Expander;
  31 with Exp_Util; use Exp_Util;
  32 with Freeze;   use Freeze;
  33 with Lib;      use Lib;
  34 with Lib.Xref; use Lib.Xref;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Rtsfind;  use Rtsfind;
  40 with Sem;      use Sem;
  41 with Sem_Aux;  use Sem_Aux;
  42 with Sem_Case; use Sem_Case;
  43 with Sem_Ch3;  use Sem_Ch3;
  44 with Sem_Ch8;  use Sem_Ch8;
  45 with Sem_Disp; use Sem_Disp;
  46 with Sem_Elab; use Sem_Elab;
  47 with Sem_Eval; use Sem_Eval;
  48 with Sem_Res;  use Sem_Res;
  49 with Sem_Type; use Sem_Type;
  50 with Sem_Util; use Sem_Util;
  51 with Sem_Warn; use Sem_Warn;
  52 with Snames;   use Snames;
  53 with Stand;    use Stand;
  54 with Sinfo;    use Sinfo;
  55 with Targparm; use Targparm;
  56 with Tbuild;   use Tbuild;
  57 with Uintp;    use Uintp;
  58
  59 package body Sem_Ch5 is
  60
  61    Unblocked_Exit_Count : Nat := 0;
  62    --  This variable is used when processing if statements, case statements,
  63    --  and block statements. It counts the number of exit points that are not
  64    --  blocked by unconditional transfer instructions: for IF and CASE, these
  65    --  are the branches of the conditional; for a block, they are the statement
  66    --  sequence of the block, and the statement sequences of any exception
  67    --  handlers that are part of the block. When processing is complete, if
  68    --  this count is zero, it means that control cannot fall through the IF,
  69    --  CASE or block statement. This is used for the generation of warning
  70    --  messages. This variable is recursively saved on entry to processing the
  71    --  construct, and restored on exit.
  72
  73    -----------------------
  74    -- Local Subprograms --
  75    -----------------------
  76
  77    procedure Analyze_Iteration_Scheme (N : Node_Id);
  78
  79    ------------------------
  80    -- Analyze_Assignment --
  81    ------------------------
  82
  83    procedure Analyze_Assignment (N : Node_Id) is
  84       Lhs  : constant Node_Id := Name (N);
  85       Rhs  : constant Node_Id := Expression (N);
  86       T1   : Entity_Id;
  87       T2   : Entity_Id;
  88       Decl : Node_Id;
  89
  90       procedure Diagnose_Non_Variable_Lhs (N : Node_Id);
  91       --  N is the node for the left hand side of an assignment, and it is not
  92       --  a variable. This routine issues an appropriate diagnostic.
  93
  94       procedure Kill_Lhs;
  95       --  This is called to kill current value settings of a simple variable
  96       --  on the left hand side. We call it if we find any error in analyzing
  97       --  the assignment, and at the end of processing before setting any new
  98       --  current values in place.
  99
 100       procedure Set_Assignment_Type
 101         (Opnd      : Node_Id;
 102          Opnd_Type : in out Entity_Id);
 103       --  Opnd is either the Lhs or Rhs of the assignment, and Opnd_Type
 104       --  is the nominal subtype. This procedure is used to deal with cases
 105       --  where the nominal subtype must be replaced by the actual subtype.
 106
 107       -------------------------------
 108       -- Diagnose_Non_Variable_Lhs --
 109       -------------------------------
 110
 111       procedure Diagnose_Non_Variable_Lhs (N : Node_Id) is
 112       begin
 113          --  Not worth posting another error if left hand side already
 114          --  flagged as being illegal in some respect.
 115
 116          if Error_Posted (N) then
 117             return;
 118
 119          --  Some special bad cases of entity names
 120
 121          elsif Is_Entity_Name (N) then
 122             declare
 123                Ent : constant Entity_Id := Entity (N);
 124
 125             begin
 126                if Ekind (Ent) = E_In_Parameter then
 127                   Error_Msg_N
 128                     ("assignment to IN mode parameter not allowed", N);
 129
 130                --  Renamings of protected private components are turned into
 131                --  constants when compiling a protected function. In the case
 132                --  of single protected types, the private component appears
 133                --  directly.
 134
 135                elsif (Is_Prival (Ent)
 136                         and then
 137                           (Ekind (Current_Scope) = E_Function
 138                              or else Ekind (Enclosing_Dynamic_Scope (
 139                                        Current_Scope)) = E_Function))
 140                    or else
 141                      (Ekind (Ent) = E_Component
 142                         and then Is_Protected_Type (Scope (Ent)))
 143                then
 144                   Error_Msg_N
 145                     ("protected function cannot modify protected object", N);
 146
 147                elsif Ekind (Ent) = E_Loop_Parameter then
 148                   Error_Msg_N
 149                     ("assignment to loop parameter not allowed", N);
 150
 151                else
 152                   Error_Msg_N
 153                     ("left hand side of assignment must be a variable", N);
 154                end if;
 155             end;
 156
 157          --  For indexed components or selected components, test prefix
 158
 159          elsif Nkind (N) = N_Indexed_Component then
 160             Diagnose_Non_Variable_Lhs (Prefix (N));
 161
 162          --  Another special case for assignment to discriminant
 163
 164          elsif Nkind (N) = N_Selected_Component then
 165             if Present (Entity (Selector_Name (N)))
 166               and then Ekind (Entity (Selector_Name (N))) = E_Discriminant
 167             then
 168                Error_Msg_N
 169                  ("assignment to discriminant not allowed", N);
 170             else
 171                Diagnose_Non_Variable_Lhs (Prefix (N));
 172             end if;
 173
 174          else
 175             --  If we fall through, we have no special message to issue!
 176
 177             Error_Msg_N ("left hand side of assignment must be a variable", N);
 178          end if;
 179       end Diagnose_Non_Variable_Lhs;
 180
 181       --------------
 182       -- Kill_LHS --
 183       --------------
 184
 185       procedure Kill_Lhs is
 186       begin
 187          if Is_Entity_Name (Lhs) then
 188             declare
 189                Ent : constant Entity_Id := Entity (Lhs);
 190             begin
 191                if Present (Ent) then
 192                   Kill_Current_Values (Ent);
 193                end if;
 194             end;
 195          end if;
 196       end Kill_Lhs;
 197
 198       -------------------------
 199       -- Set_Assignment_Type --
 200       -------------------------
 201
 202       procedure Set_Assignment_Type
 203         (Opnd      : Node_Id;
 204          Opnd_Type : in out Entity_Id)
 205       is
 206       begin
 207          Require_Entity (Opnd);
 208
 209          --  If the assignment operand is an in-out or out parameter, then we
 210          --  get the actual subtype (needed for the unconstrained case).
 211          --  If the operand is the actual in an entry declaration, then within
 212          --  the accept statement it is replaced with a local renaming, which
 213          --  may also have an actual subtype.
 214
 215          if Is_Entity_Name (Opnd)
 216            and then (Ekind (Entity (Opnd)) = E_Out_Parameter
 217                       or else Ekind (Entity (Opnd)) =
 218                            E_In_Out_Parameter
 219                       or else Ekind (Entity (Opnd)) =
 220                            E_Generic_In_Out_Parameter
 221                       or else
 222                         (Ekind (Entity (Opnd)) = E_Variable
 223                           and then Nkind (Parent (Entity (Opnd))) =
 224                              N_Object_Renaming_Declaration
 225                           and then Nkind (Parent (Parent (Entity (Opnd)))) =
 226                              N_Accept_Statement))
 227          then
 228             Opnd_Type := Get_Actual_Subtype (Opnd);
 229
 230          --  If assignment operand is a component reference, then we get the
 231          --  actual subtype of the component for the unconstrained case.
 232
 233          elsif Nkind_In (Opnd, N_Selected_Component, N_Explicit_Dereference)
 234            and then not Is_Unchecked_Union (Opnd_Type)
 235          then
 236             Decl := Build_Actual_Subtype_Of_Component (Opnd_Type, Opnd);
 237
 238             if Present (Decl) then
 239                Insert_Action (N, Decl);
 240                Mark_Rewrite_Insertion (Decl);
 241                Analyze (Decl);
 242                Opnd_Type := Defining_Identifier (Decl);
 243                Set_Etype (Opnd, Opnd_Type);
 244                Freeze_Itype (Opnd_Type, N);
 245
 246             elsif Is_Constrained (Etype (Opnd)) then
 247                Opnd_Type := Etype (Opnd);
 248             end if;
 249
 250          --  For slice, use the constrained subtype created for the slice
 251
 252          elsif Nkind (Opnd) = N_Slice then
 253             Opnd_Type := Etype (Opnd);
 254          end if;
 255       end Set_Assignment_Type;
 256
 257    --  Start of processing for Analyze_Assignment
 258
 259    begin
 260       Mark_Coextensions (N, Rhs);
 261
 262       Analyze (Rhs);
 263       Analyze (Lhs);
 264
 265       --  Start type analysis for assignment
 266
 267       T1 := Etype (Lhs);
 268
 269       --  In the most general case, both Lhs and Rhs can be overloaded, and we
 270       --  must compute the intersection of the possible types on each side.
 271
 272       if Is_Overloaded (Lhs) then
 273          declare
 274             I  : Interp_Index;
 275             It : Interp;
 276
 277          begin
 278             T1 := Any_Type;
 279             Get_First_Interp (Lhs, I, It);
 280
 281             while Present (It.Typ) loop
 282                if Has_Compatible_Type (Rhs, It.Typ) then
 283                   if T1 /= Any_Type then
 284
 285                      --  An explicit dereference is overloaded if the prefix
 286                      --  is. Try to remove the ambiguity on the prefix, the
 287                      --  error will be posted there if the ambiguity is real.
 288
 289                      if Nkind (Lhs) = N_Explicit_Dereference then
 290                         declare
 291                            PI    : Interp_Index;
 292                            PI1   : Interp_Index := 0;
 293                            PIt   : Interp;
 294                            Found : Boolean;
 295
 296                         begin
 297                            Found := False;
 298                            Get_First_Interp (Prefix (Lhs), PI, PIt);
 299
 300                            while Present (PIt.Typ) loop
 301                               if Is_Access_Type (PIt.Typ)
 302                                 and then Has_Compatible_Type
 303                                            (Rhs, Designated_Type (PIt.Typ))
 304                               then
 305                                  if Found then
 306                                     PIt :=
 307                                       Disambiguate (Prefix (Lhs),
 308                                         PI1, PI, Any_Type);
 309
 310                                     if PIt = No_Interp then
 311                                        Error_Msg_N
 312                                          ("ambiguous left-hand side"
 313                                             & " in assignment", Lhs);
 314                                        exit;
 315                                     else
 316                                        Resolve (Prefix (Lhs), PIt.Typ);
 317                                     end if;
 318
 319                                     exit;
 320                                  else
 321                                     Found := True;
 322                                     PI1 := PI;
 323                                  end if;
 324                               end if;
 325
 326                               Get_Next_Interp (PI, PIt);
 327                            end loop;
 328                         end;
 329
 330                      else
 331                         Error_Msg_N
 332                           ("ambiguous left-hand side in assignment", Lhs);
 333                         exit;
 334                      end if;
 335                   else
 336                      T1 := It.Typ;
 337                   end if;
 338                end if;
 339
 340                Get_Next_Interp (I, It);
 341             end loop;
 342          end;
 343
 344          if T1 = Any_Type then
 345             Error_Msg_N
 346               ("no valid types for left-hand side for assignment", Lhs);
 347             Kill_Lhs;
 348             return;
 349          end if;
 350       end if;
 351
 352       --  The resulting assignment type is T1, so now we will resolve the
 353       --  left hand side of the assignment using this determined type.
 354
 355       Resolve (Lhs, T1);
 356
 357       --  Cases where Lhs is not a variable
 358
 359       if not Is_Variable (Lhs) then
 360
 361          --  Ada 2005 (AI-327): Check assignment to the attribute Priority of
 362          --  a protected object.
 363
 364          declare
 365             Ent : Entity_Id;
 366             S   : Entity_Id;
 367
 368          begin
 369             if Ada_Version >= Ada_05 then
 370
 371                --  Handle chains of renamings
 372
 373                Ent := Lhs;
 374                while Nkind (Ent) in N_Has_Entity
 375                  and then Present (Entity (Ent))
 376                  and then Present (Renamed_Object (Entity (Ent)))
 377                loop
 378                   Ent := Renamed_Object (Entity (Ent));
 379                end loop;
 380
 381                if (Nkind (Ent) = N_Attribute_Reference
 382                      and then Attribute_Name (Ent) = Name_Priority)
 383
 384                   --  Renamings of the attribute Priority applied to protected
 385                   --  objects have been previously expanded into calls to the
 386                   --  Get_Ceiling run-time subprogram.
 387
 388                  or else
 389                   (Nkind (Ent) = N_Function_Call
 390                      and then (Entity (Name (Ent)) = RTE (RE_Get_Ceiling)
 391                                 or else
 392                                Entity (Name (Ent)) = RTE (RO_PE_Get_Ceiling)))
 393                then
 394                   --  The enclosing subprogram cannot be a protected function
 395
 396                   S := Current_Scope;
 397                   while not (Is_Subprogram (S)
 398                                and then Convention (S) = Convention_Protected)
 399                      and then S /= Standard_Standard
 400                   loop
 401                      S := Scope (S);
 402                   end loop;
 403
 404                   if Ekind (S) = E_Function
 405                     and then Convention (S) = Convention_Protected
 406                   then
 407                      Error_Msg_N
 408                        ("protected function cannot modify protected object",
 409                         Lhs);
 410                   end if;
 411
 412                   --  Changes of the ceiling priority of the protected object
 413                   --  are only effective if the Ceiling_Locking policy is in
 414                   --  effect (AARM D.5.2 (5/2)).
 415
 416                   if Locking_Policy /= 'C' then
 417                      Error_Msg_N ("assignment to the attribute PRIORITY has " &
 418                                   "no effect?", Lhs);
 419                      Error_Msg_N ("\since no Locking_Policy has been " &
 420                                   "specified", Lhs);
 421                   end if;
 422
 423                   return;
 424                end if;
 425             end if;
 426          end;
 427
 428          Diagnose_Non_Variable_Lhs (Lhs);
 429          return;
 430
 431       --  Error of assigning to limited type. We do however allow this in
 432       --  certain cases where the front end generates the assignments.
 433
 434       elsif Is_Limited_Type (T1)
 435         and then not Assignment_OK (Lhs)
 436         and then not Assignment_OK (Original_Node (Lhs))
 437         and then not Is_Value_Type (T1)
 438       then
 439          --  CPP constructors can only be called in declarations
 440
 441          if Is_CPP_Constructor_Call (Rhs) then
 442             Error_Msg_N ("invalid use of 'C'P'P constructor", Rhs);
 443          else
 444             Error_Msg_N
 445               ("left hand of assignment must not be limited type", Lhs);
 446             Explain_Limited_Type (T1, Lhs);
 447          end if;
 448          return;
 449
 450       --  Enforce RM 3.9.3 (8): left-hand side cannot be abstract
 451
 452       elsif Is_Interface (T1)
 453         and then not Is_Class_Wide_Type (T1)
 454       then
 455          Error_Msg_N
 456            ("target of assignment operation may not be abstract", Lhs);
 457          return;
 458       end if;
 459
 460       --  Resolution may have updated the subtype, in case the left-hand
 461       --  side is a private protected component. Use the correct subtype
 462       --  to avoid scoping issues in the back-end.
 463
 464       T1 := Etype (Lhs);
 465
 466       --  Ada 2005 (AI-50217, AI-326): Check wrong dereference of incomplete
 467       --  type. For example:
 468
 469       --    limited with P;
 470       --    package Pkg is
 471       --      type Acc is access P.T;
 472       --    end Pkg;
 473
 474       --    with Pkg; use Acc;
 475       --    procedure Example is
 476       --       A, B : Acc;
 477       --    begin
 478       --       A.all := B.all;  -- ERROR
 479       --    end Example;
 480
 481       if Nkind (Lhs) = N_Explicit_Dereference
 482         and then Ekind (T1) = E_Incomplete_Type
 483       then
 484          Error_Msg_N ("invalid use of incomplete type", Lhs);
 485          Kill_Lhs;
 486          return;
 487       end if;
 488
 489       --  Now we can complete the resolution of the right hand side
 490
 491       Set_Assignment_Type (Lhs, T1);
 492       Resolve (Rhs, T1);
 493
 494       --  This is the point at which we check for an unset reference
 495
 496       Check_Unset_Reference (Rhs);
 497       Check_Unprotected_Access (Lhs, Rhs);
 498
 499       --  Remaining steps are skipped if Rhs was syntactically in error
 500
 501       if Rhs = Error then
 502          Kill_Lhs;
 503          return;
 504       end if;
 505
 506       T2 := Etype (Rhs);
 507
 508       if not Covers (T1, T2) then
 509          Wrong_Type (Rhs, Etype (Lhs));
 510          Kill_Lhs;
 511          return;
 512       end if;
 513
 514       --  Ada 2005 (AI-326): In case of explicit dereference of incomplete
 515       --  types, use the non-limited view if available
 516
 517       if Nkind (Rhs) = N_Explicit_Dereference
 518         and then Ekind (T2) = E_Incomplete_Type
 519         and then Is_Tagged_Type (T2)
 520         and then Present (Non_Limited_View (T2))
 521       then
 522          T2 := Non_Limited_View (T2);
 523       end if;
 524
 525       Set_Assignment_Type (Rhs, T2);
 526
 527       if Total_Errors_Detected /= 0 then
 528          if No (T1) then
 529             T1 := Any_Type;
 530          end if;
 531
 532          if No (T2) then
 533             T2 := Any_Type;
 534          end if;
 535       end if;
 536
 537       if T1 = Any_Type or else T2 = Any_Type then
 538          Kill_Lhs;
 539          return;
 540       end if;
 541
 542       --  If the rhs is class-wide or dynamically tagged, then require the lhs
 543       --  to be class-wide. The case where the rhs is a dynamically tagged call
 544       --  to a dispatching operation with a controlling access result is
 545       --  excluded from this check, since the target has an access type (and
 546       --  no tag propagation occurs in that case).
 547
 548       if (Is_Class_Wide_Type (T2)
 549            or else (Is_Dynamically_Tagged (Rhs)
 550                      and then not Is_Access_Type (T1)))
 551         and then not Is_Class_Wide_Type (T1)
 552       then
 553          Error_Msg_N ("dynamically tagged expression not allowed!", Rhs);
 554
 555       elsif Is_Class_Wide_Type (T1)
 556         and then not Is_Class_Wide_Type (T2)
 557         and then not Is_Tag_Indeterminate (Rhs)
 558         and then not Is_Dynamically_Tagged (Rhs)
 559       then
 560          Error_Msg_N ("dynamically tagged expression required!", Rhs);
 561       end if;
 562
 563       --  Propagate the tag from a class-wide target to the rhs when the rhs
 564       --  is a tag-indeterminate call.
 565
 566       if Is_Tag_Indeterminate (Rhs) then
 567          if Is_Class_Wide_Type (T1) then
 568             Propagate_Tag (Lhs, Rhs);
 569
 570          elsif Nkind (Rhs) = N_Function_Call
 571               and then Is_Entity_Name (Name (Rhs))
 572               and then Is_Abstract_Subprogram (Entity (Name (Rhs)))
 573          then
 574             Error_Msg_N
 575               ("call to abstract function must be dispatching", Name (Rhs));
 576
 577          elsif Nkind (Rhs) = N_Qualified_Expression
 578            and then Nkind (Expression (Rhs)) = N_Function_Call
 579               and then Is_Entity_Name (Name (Expression (Rhs)))
 580               and then
 581                 Is_Abstract_Subprogram (Entity (Name (Expression (Rhs))))
 582          then
 583             Error_Msg_N
 584               ("call to abstract function must be dispatching",
 585                 Name (Expression (Rhs)));
 586          end if;
 587       end if;
 588
 589       --  Ada 2005 (AI-385): When the lhs type is an anonymous access type,
 590       --  apply an implicit conversion of the rhs to that type to force
 591       --  appropriate static and run-time accessibility checks. This applies
 592       --  as well to anonymous access-to-subprogram types that are component
 593       --  subtypes or formal parameters.
 594
 595       if Ada_Version >= Ada_05
 596         and then Is_Access_Type (T1)
 597       then
 598          if Is_Local_Anonymous_Access (T1)
 599            or else Ekind (T2) = E_Anonymous_Access_Subprogram_Type
 600          then
 601             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 602             Analyze_And_Resolve (Rhs, T1);
 603          end if;
 604       end if;
 605
 606       --  Ada 2005 (AI-231): Assignment to not null variable
 607
 608       if Ada_Version >= Ada_05
 609         and then Can_Never_Be_Null (T1)
 610         and then not Assignment_OK (Lhs)
 611       then
 612          --  Case where we know the right hand side is null
 613
 614          if Known_Null (Rhs) then
 615             Apply_Compile_Time_Constraint_Error
 616               (N   => Rhs,
 617                Msg => "(Ada 2005) null not allowed in null-excluding objects?",
 618                Reason => CE_Null_Not_Allowed);
 619
 620             --  We still mark this as a possible modification, that's necessary
 621             --  to reset Is_True_Constant, and desirable for xref purposes.
 622
 623             Note_Possible_Modification (Lhs, Sure => True);
 624             return;
 625
 626          --  If we know the right hand side is non-null, then we convert to the
 627          --  target type, since we don't need a run time check in that case.
 628
 629          elsif not Can_Never_Be_Null (T2) then
 630             Rewrite (Rhs, Convert_To (T1, Relocate_Node (Rhs)));
 631             Analyze_And_Resolve (Rhs, T1);
 632          end if;
 633       end if;
 634
 635       if Is_Scalar_Type (T1) then
 636          Apply_Scalar_Range_Check (Rhs, Etype (Lhs));
 637
 638       --  For array types, verify that lengths match. If the right hand side
 639       --  if a function call that has been inlined, the assignment has been
 640       --  rewritten as a block, and the constraint check will be applied to the
 641       --  assignment within the block.
 642
 643       elsif Is_Array_Type (T1)
 644         and then
 645           (Nkind (Rhs) /= N_Type_Conversion
 646             or else Is_Constrained (Etype (Rhs)))
 647         and then
 648           (Nkind (Rhs) /= N_Function_Call
 649             or else Nkind (N) /= N_Block_Statement)
 650       then
 651          --  Assignment verifies that the length of the Lsh and Rhs are equal,
 652          --  but of course the indices do not have to match. If the right-hand
 653          --  side is a type conversion to an unconstrained type, a length check
 654          --  is performed on the expression itself during expansion. In rare
 655          --  cases, the redundant length check is computed on an index type
 656          --  with a different representation, triggering incorrect code in
 657          --  the back end.
 658
 659          Apply_Length_Check (Rhs, Etype (Lhs));
 660
 661       else
 662          --  Discriminant checks are applied in the course of expansion
 663
 664          null;
 665       end if;
 666
 667       --  Note: modifications of the Lhs may only be recorded after
 668       --  checks have been applied.
 669
 670       Note_Possible_Modification (Lhs, Sure => True);
 671
 672       --  ??? a real accessibility check is needed when ???
 673
 674       --  Post warning for redundant assignment or variable to itself
 675
 676       if Warn_On_Redundant_Constructs
 677
 678          --  We only warn for source constructs
 679
 680          and then Comes_From_Source (N)
 681
 682          --  Where the object is the same on both sides
 683
 684          and then Same_Object (Lhs, Original_Node (Rhs))
 685
 686          --  But exclude the case where the right side was an operation
 687          --  that got rewritten (e.g. JUNK + K, where K was known to be
 688          --  zero). We don't want to warn in such a case, since it is
 689          --  reasonable to write such expressions especially when K is
 690          --  defined symbolically in some other package.
 691
 692         and then Nkind (Original_Node (Rhs)) not in N_Op
 693       then
 694          if Nkind (Lhs) in N_Has_Entity then
 695             Error_Msg_NE
 696               ("?useless assignment of & to itself!", N, Entity (Lhs));
 697          else
 698             Error_Msg_N
 699               ("?useless assignment of object to itself!", N);
 700          end if;
 701       end if;
 702
 703       --  Check for non-allowed composite assignment
 704
 705       if not Support_Composite_Assign_On_Target
 706         and then (Is_Array_Type (T1) or else Is_Record_Type (T1))
 707         and then (not Has_Size_Clause (T1) or else Esize (T1) > 64)
 708       then
 709          Error_Msg_CRT ("composite assignment", N);
 710       end if;
 711
 712       --  Check elaboration warning for left side if not in elab code
 713
 714       if not In_Subprogram_Or_Concurrent_Unit then
 715          Check_Elab_Assign (Lhs);
 716       end if;
 717
 718       --  Set Referenced_As_LHS if appropriate. We only set this flag if the
 719       --  assignment is a source assignment in the extended main source unit.
 720       --  We are not interested in any reference information outside this
 721       --  context, or in compiler generated assignment statements.
 722
 723       if Comes_From_Source (N)
 724         and then In_Extended_Main_Source_Unit (Lhs)
 725       then
 726          Set_Referenced_Modified (Lhs, Out_Param => False);
 727       end if;
 728
 729       --  Final step. If left side is an entity, then we may be able to
 730       --  reset the current tracked values to new safe values. We only have
 731       --  something to do if the left side is an entity name, and expansion
 732       --  has not modified the node into something other than an assignment,
 733       --  and of course we only capture values if it is safe to do so.
 734
 735       if Is_Entity_Name (Lhs)
 736         and then Nkind (N) = N_Assignment_Statement
 737       then
 738          declare
 739             Ent : constant Entity_Id := Entity (Lhs);
 740
 741          begin
 742             if Safe_To_Capture_Value (N, Ent) then
 743
 744                --  If simple variable on left side, warn if this assignment
 745                --  blots out another one (rendering it useless) and note
 746                --  location of assignment in case no one references value.
 747                --  We only do this for source assignments, otherwise we can
 748                --  generate bogus warnings when an assignment is rewritten as
 749                --  another assignment, and gets tied up with itself.
 750
 751                --  Note: we don't use Record_Last_Assignment here, because we
 752                --  have lots of other stuff to do under control of this test.
 753
 754                if Warn_On_Modified_Unread
 755                  and then Is_Assignable (Ent)
 756                  and then Comes_From_Source (N)
 757                  and then In_Extended_Main_Source_Unit (Ent)
 758                then
 759                   Warn_On_Useless_Assignment (Ent, N);
 760                   Set_Last_Assignment (Ent, Lhs);
 761                end if;
 762
 763                --  If we are assigning an access type and the left side is an
 764                --  entity, then make sure that the Is_Known_[Non_]Null flags
 765                --  properly reflect the state of the entity after assignment.
 766
 767                if Is_Access_Type (T1) then
 768                   if Known_Non_Null (Rhs) then
 769                      Set_Is_Known_Non_Null (Ent, True);
 770
 771                   elsif Known_Null (Rhs)
 772                     and then not Can_Never_Be_Null (Ent)
 773                   then
 774                      Set_Is_Known_Null (Ent, True);
 775
 776                   else
 777                      Set_Is_Known_Null (Ent, False);
 778
 779                      if not Can_Never_Be_Null (Ent) then
 780                         Set_Is_Known_Non_Null (Ent, False);
 781                      end if;
 782                   end if;
 783
 784                --  For discrete types, we may be able to set the current value
 785                --  if the value is known at compile time.
 786
 787                elsif Is_Discrete_Type (T1)
 788                  and then Compile_Time_Known_Value (Rhs)
 789                then
 790                   Set_Current_Value (Ent, Rhs);
 791                else
 792                   Set_Current_Value (Ent, Empty);
 793                end if;
 794
 795             --  If not safe to capture values, kill them
 796
 797             else
 798                Kill_Lhs;
 799             end if;
 800          end;
 801       end if;
 802    end Analyze_Assignment;
 803
 804    -----------------------------
 805    -- Analyze_Block_Statement --
 806    -----------------------------
 807
 808    procedure Analyze_Block_Statement (N : Node_Id) is
 809       Decls : constant List_Id := Declarations (N);
 810       Id    : constant Node_Id := Identifier (N);
 811       HSS   : constant Node_Id := Handled_Statement_Sequence (N);
 812
 813    begin
 814       --  If no handled statement sequence is present, things are really
 815       --  messed up, and we just return immediately (this is a defence
 816       --  against previous errors).
 817
 818       if No (HSS) then
 819          return;
 820       end if;
 821
 822       --  Normal processing with HSS present
 823
 824       declare
 825          EH  : constant List_Id := Exception_Handlers (HSS);
 826          Ent : Entity_Id        := Empty;
 827          S   : Entity_Id;
 828
 829          Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 830          --  Recursively save value of this global, will be restored on exit
 831
 832       begin
 833          --  Initialize unblocked exit count for statements of begin block
 834          --  plus one for each exception handler that is present.
 835
 836          Unblocked_Exit_Count := 1;
 837
 838          if Present (EH) then
 839             Unblocked_Exit_Count := Unblocked_Exit_Count + List_Length (EH);
 840          end if;
 841
 842          --  If a label is present analyze it and mark it as referenced
 843
 844          if Present (Id) then
 845             Analyze (Id);
 846             Ent := Entity (Id);
 847
 848             --  An error defense. If we have an identifier, but no entity,
 849             --  then something is wrong. If we have previous errors, then
 850             --  just remove the identifier and continue, otherwise raise
 851             --  an exception.
 852
 853             if No (Ent) then
 854                if Total_Errors_Detected /= 0 then
 855                   Set_Identifier (N, Empty);
 856                else
 857                   raise Program_Error;
 858                end if;
 859
 860             else
 861                Set_Ekind (Ent, E_Block);
 862                Generate_Reference (Ent, N, ' ');
 863                Generate_Definition (Ent);
 864
 865                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
 866                   Set_Label_Construct (Parent (Ent), N);
 867                end if;
 868             end if;
 869          end if;
 870
 871          --  If no entity set, create a label entity
 872
 873          if No (Ent) then
 874             Ent := New_Internal_Entity (E_Block, Current_Scope, Sloc (N), 'B');
 875             Set_Identifier (N, New_Occurrence_Of (Ent, Sloc (N)));
 876             Set_Parent (Ent, N);
 877          end if;
 878
 879          Set_Etype (Ent, Standard_Void_Type);
 880          Set_Block_Node (Ent, Identifier (N));
 881          Push_Scope (Ent);
 882
 883          if Present (Decls) then
 884             Analyze_Declarations (Decls);
 885             Check_Completion;
 886             Inspect_Deferred_Constant_Completion (Decls);
 887          end if;
 888
 889          Analyze (HSS);
 890          Process_End_Label (HSS, 'e', Ent);
 891
 892          --  If exception handlers are present, then we indicate that
 893          --  enclosing scopes contain a block with handlers. We only
 894          --  need to mark non-generic scopes.
 895
 896          if Present (EH) then
 897             S := Scope (Ent);
 898             loop
 899                Set_Has_Nested_Block_With_Handler (S);
 900                exit when Is_Overloadable (S)
 901                  or else Ekind (S) = E_Package
 902                  or else Is_Generic_Unit (S);
 903                S := Scope (S);
 904             end loop;
 905          end if;
 906
 907          Check_References (Ent);
 908          Warn_On_Useless_Assignments (Ent);
 909          End_Scope;
 910
 911          if Unblocked_Exit_Count = 0 then
 912             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 913             Check_Unreachable_Code (N);
 914          else
 915             Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
 916          end if;
 917       end;
 918    end Analyze_Block_Statement;
 919
 920    ----------------------------
 921    -- Analyze_Case_Statement --
 922    ----------------------------
 923
 924    procedure Analyze_Case_Statement (N : Node_Id) is
 925       Exp            : Node_Id;
 926       Exp_Type       : Entity_Id;
 927       Exp_Btype      : Entity_Id;
 928       Last_Choice    : Nat;
 929       Dont_Care      : Boolean;
 930       Others_Present : Boolean;
 931
 932       pragma Warnings (Off, Last_Choice);
 933       pragma Warnings (Off, Dont_Care);
 934       --  Don't care about assigned values
 935
 936       Statements_Analyzed : Boolean := False;
 937       --  Set True if at least some statement sequences get analyzed.
 938       --  If False on exit, means we had a serious error that prevented
 939       --  full analysis of the case statement, and as a result it is not
 940       --  a good idea to output warning messages about unreachable code.
 941
 942       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
 943       --  Recursively save value of this global, will be restored on exit
 944
 945       procedure Non_Static_Choice_Error (Choice : Node_Id);
 946       --  Error routine invoked by the generic instantiation below when
 947       --  the case statement has a non static choice.
 948
 949       procedure Process_Statements (Alternative : Node_Id);
 950       --  Analyzes all the statements associated to a case alternative.
 951       --  Needed by the generic instantiation below.
 952
 953       package Case_Choices_Processing is new
 954         Generic_Choices_Processing
 955           (Get_Alternatives          => Alternatives,
 956            Get_Choices               => Discrete_Choices,
 957            Process_Empty_Choice      => No_OP,
 958            Process_Non_Static_Choice => Non_Static_Choice_Error,
 959            Process_Associated_Node   => Process_Statements);
 960       use Case_Choices_Processing;
 961       --  Instantiation of the generic choice processing package
 962
 963       -----------------------------
 964       -- Non_Static_Choice_Error --
 965       -----------------------------
 966
 967       procedure Non_Static_Choice_Error (Choice : Node_Id) is
 968       begin
 969          Flag_Non_Static_Expr
 970            ("choice given in case statement is not static!", Choice);
 971       end Non_Static_Choice_Error;
 972
 973       ------------------------
 974       -- Process_Statements --
 975       ------------------------
 976
 977       procedure Process_Statements (Alternative : Node_Id) is
 978          Choices : constant List_Id := Discrete_Choices (Alternative);
 979          Ent     : Entity_Id;
 980
 981       begin
 982          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
 983          Statements_Analyzed := True;
 984
 985          --  An interesting optimization. If the case statement expression
 986          --  is a simple entity, then we can set the current value within
 987          --  an alternative if the alternative has one possible value.
 988
 989          --    case N is
 990          --      when 1      => alpha
 991          --      when 2 | 3  => beta
 992          --      when others => gamma
 993
 994          --  Here we know that N is initially 1 within alpha, but for beta
 995          --  and gamma, we do not know anything more about the initial value.
 996
 997          if Is_Entity_Name (Exp) then
 998             Ent := Entity (Exp);
 999
1000             if Ekind (Ent) = E_Variable
1001                  or else
1002                Ekind (Ent) = E_In_Out_Parameter
1003                  or else
1004                Ekind (Ent) = E_Out_Parameter
1005             then
1006                if List_Length (Choices) = 1
1007                  and then Nkind (First (Choices)) in N_Subexpr
1008                  and then Compile_Time_Known_Value (First (Choices))
1009                then
1010                   Set_Current_Value (Entity (Exp), First (Choices));
1011                end if;
1012
1013                Analyze_Statements (Statements (Alternative));
1014
1015                --  After analyzing the case, set the current value to empty
1016                --  since we won't know what it is for the next alternative
1017                --  (unless reset by this same circuit), or after the case.
1018
1019                Set_Current_Value (Entity (Exp), Empty);
1020                return;
1021             end if;
1022          end if;
1023
1024          --  Case where expression is not an entity name of a variable
1025
1026          Analyze_Statements (Statements (Alternative));
1027       end Process_Statements;
1028
1029       --  Table to record choices. Put after subprograms since we make
1030       --  a call to Number_Of_Choices to get the right number of entries.
1031
1032       Case_Table : Choice_Table_Type (1 .. Number_Of_Choices (N));
1033       pragma Warnings (Off, Case_Table);
1034
1035    --  Start of processing for Analyze_Case_Statement
1036
1037    begin
1038       Unblocked_Exit_Count := 0;
1039       Exp := Expression (N);
1040       Analyze (Exp);
1041
1042       --  The expression must be of any discrete type. In rare cases, the
1043       --  expander constructs a case statement whose expression has a private
1044       --  type whose full view is discrete. This can happen when generating
1045       --  a stream operation for a variant type after the type is frozen,
1046       --  when the partial of view of the type of the discriminant is private.
1047       --  In that case, use the full view to analyze case alternatives.
1048
1049       if not Is_Overloaded (Exp)
1050         and then not Comes_From_Source (N)
1051         and then Is_Private_Type (Etype (Exp))
1052         and then Present (Full_View (Etype (Exp)))
1053         and then Is_Discrete_Type (Full_View (Etype (Exp)))
1054       then
1055          Resolve (Exp, Etype (Exp));
1056          Exp_Type := Full_View (Etype (Exp));
1057
1058       else
1059          Analyze_And_Resolve (Exp, Any_Discrete);
1060          Exp_Type := Etype (Exp);
1061       end if;
1062
1063       Check_Unset_Reference (Exp);
1064       Exp_Btype := Base_Type (Exp_Type);
1065
1066       --  The expression must be of a discrete type which must be determinable
1067       --  independently of the context in which the expression occurs, but
1068       --  using the fact that the expression must be of a discrete type.
1069       --  Moreover, the type this expression must not be a character literal
1070       --  (which is always ambiguous) or, for Ada-83, a generic formal type.
1071
1072       --  If error already reported by Resolve, nothing more to do
1073
1074       if Exp_Btype = Any_Discrete
1075         or else Exp_Btype = Any_Type
1076       then
1077          return;
1078
1079       elsif Exp_Btype = Any_Character then
1080          Error_Msg_N
1081            ("character literal as case expression is ambiguous", Exp);
1082          return;
1083
1084       elsif Ada_Version = Ada_83
1085         and then (Is_Generic_Type (Exp_Btype)
1086                     or else Is_Generic_Type (Root_Type (Exp_Btype)))
1087       then
1088          Error_Msg_N
1089            ("(Ada 83) case expression cannot be of a generic type", Exp);
1090          return;
1091       end if;
1092
1093       --  If the case expression is a formal object of mode in out, then
1094       --  treat it as having a nonstatic subtype by forcing use of the base
1095       --  type (which has to get passed to Check_Case_Choices below).  Also
1096       --  use base type when the case expression is parenthesized.
1097
1098       if Paren_Count (Exp) > 0
1099         or else (Is_Entity_Name (Exp)
1100                   and then Ekind (Entity (Exp)) = E_Generic_In_Out_Parameter)
1101       then
1102          Exp_Type := Exp_Btype;
1103       end if;
1104
1105       --  Call instantiated Analyze_Choices which does the rest of the work
1106
1107       Analyze_Choices
1108         (N, Exp_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
1109
1110       if Exp_Type = Universal_Integer and then not Others_Present then
1111          Error_Msg_N ("case on universal integer requires OTHERS choice", Exp);
1112       end if;
1113
1114       --  If all our exits were blocked by unconditional transfers of control,
1115       --  then the entire CASE statement acts as an unconditional transfer of
1116       --  control, so treat it like one, and check unreachable code. Skip this
1117       --  test if we had serious errors preventing any statement analysis.
1118
1119       if Unblocked_Exit_Count = 0 and then Statements_Analyzed then
1120          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1121          Check_Unreachable_Code (N);
1122       else
1123          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1124       end if;
1125
1126       if not Expander_Active
1127         and then Compile_Time_Known_Value (Expression (N))
1128         and then Serious_Errors_Detected = 0
1129       then
1130          declare
1131             Chosen : constant Node_Id := Find_Static_Alternative (N);
1132             Alt    : Node_Id;
1133
1134          begin
1135             Alt := First (Alternatives (N));
1136             while Present (Alt) loop
1137                if Alt /= Chosen then
1138                   Remove_Warning_Messages (Statements (Alt));
1139                end if;
1140
1141                Next (Alt);
1142             end loop;
1143          end;
1144       end if;
1145    end Analyze_Case_Statement;
1146
1147    ----------------------------
1148    -- Analyze_Exit_Statement --
1149    ----------------------------
1150
1151    --  If the exit includes a name, it must be the name of a currently open
1152    --  loop. Otherwise there must be an innermost open loop on the stack,
1153    --  to which the statement implicitly refers.
1154
1155    procedure Analyze_Exit_Statement (N : Node_Id) is
1156       Target   : constant Node_Id := Name (N);
1157       Cond     : constant Node_Id := Condition (N);
1158       Scope_Id : Entity_Id;
1159       U_Name   : Entity_Id;
1160       Kind     : Entity_Kind;
1161
1162    begin
1163       if No (Cond) then
1164          Check_Unreachable_Code (N);
1165       end if;
1166
1167       if Present (Target) then
1168          Analyze (Target);
1169          U_Name := Entity (Target);
1170
1171          if not In_Open_Scopes (U_Name) or else Ekind (U_Name) /= E_Loop then
1172             Error_Msg_N ("invalid loop name in exit statement", N);
1173             return;
1174          else
1175             Set_Has_Exit (U_Name);
1176          end if;
1177
1178       else
1179          U_Name := Empty;
1180       end if;
1181
1182       for J in reverse 0 .. Scope_Stack.Last loop
1183          Scope_Id := Scope_Stack.Table (J).Entity;
1184          Kind := Ekind (Scope_Id);
1185
1186          if Kind = E_Loop
1187            and then (No (Target) or else Scope_Id = U_Name) then
1188             Set_Has_Exit (Scope_Id);
1189             exit;
1190
1191          elsif Kind = E_Block
1192            or else Kind = E_Loop
1193            or else Kind = E_Return_Statement
1194          then
1195             null;
1196
1197          else
1198             Error_Msg_N
1199               ("cannot exit from program unit or accept statement", N);
1200             exit;
1201          end if;
1202       end loop;
1203
1204       --  Verify that if present the condition is a Boolean expression
1205
1206       if Present (Cond) then
1207          Analyze_And_Resolve (Cond, Any_Boolean);
1208          Check_Unset_Reference (Cond);
1209       end if;
1210
1211       --  Since the exit may take us out of a loop, any previous assignment
1212       --  statement is not useless, so clear last assignment indications. It
1213       --  is OK to keep other current values, since if the exit statement
1214       --  does not exit, then the current values are still valid.
1215
1216       Kill_Current_Values (Last_Assignment_Only => True);
1217    end Analyze_Exit_Statement;
1218
1219    ----------------------------
1220    -- Analyze_Goto_Statement --
1221    ----------------------------
1222
1223    procedure Analyze_Goto_Statement (N : Node_Id) is
1224       Label       : constant Node_Id := Name (N);
1225       Scope_Id    : Entity_Id;
1226       Label_Scope : Entity_Id;
1227       Label_Ent   : Entity_Id;
1228
1229    begin
1230       Check_Unreachable_Code (N);
1231       Kill_Current_Values (Last_Assignment_Only => True);
1232
1233       Analyze (Label);
1234       Label_Ent := Entity (Label);
1235
1236       --  Ignore previous error
1237
1238       if Label_Ent = Any_Id then
1239          return;
1240
1241       --  We just have a label as the target of a goto
1242
1243       elsif Ekind (Label_Ent) /= E_Label then
1244          Error_Msg_N ("target of goto statement must be a label", Label);
1245          return;
1246
1247       --  Check that the target of the goto is reachable according to Ada
1248       --  scoping rules. Note: the special gotos we generate for optimizing
1249       --  local handling of exceptions would violate these rules, but we mark
1250       --  such gotos as analyzed when built, so this code is never entered.
1251
1252       elsif not Reachable (Label_Ent) then
1253          Error_Msg_N ("target of goto statement is not reachable", Label);
1254          return;
1255       end if;
1256
1257       --  Here if goto passes initial validity checks
1258
1259       Label_Scope := Enclosing_Scope (Label_Ent);
1260
1261       for J in reverse 0 .. Scope_Stack.Last loop
1262          Scope_Id := Scope_Stack.Table (J).Entity;
1263
1264          if Label_Scope = Scope_Id
1265            or else (Ekind (Scope_Id) /= E_Block
1266                      and then Ekind (Scope_Id) /= E_Loop
1267                      and then Ekind (Scope_Id) /= E_Return_Statement)
1268          then
1269             if Scope_Id /= Label_Scope then
1270                Error_Msg_N
1271                  ("cannot exit from program unit or accept statement", N);
1272             end if;
1273
1274             return;
1275          end if;
1276       end loop;
1277
1278       raise Program_Error;
1279    end Analyze_Goto_Statement;
1280
1281    --------------------------
1282    -- Analyze_If_Statement --
1283    --------------------------
1284
1285    --  A special complication arises in the analysis of if statements
1286
1287    --  The expander has circuitry to completely delete code that it
1288    --  can tell will not be executed (as a result of compile time known
1289    --  conditions). In the analyzer, we ensure that code that will be
1290    --  deleted in this manner is analyzed but not expanded. This is
1291    --  obviously more efficient, but more significantly, difficulties
1292    --  arise if code is expanded and then eliminated (e.g. exception
1293    --  table entries disappear). Similarly, itypes generated in deleted
1294    --  code must be frozen from start, because the nodes on which they
1295    --  depend will not be available at the freeze point.
1296
1297    procedure Analyze_If_Statement (N : Node_Id) is
1298       E : Node_Id;
1299
1300       Save_Unblocked_Exit_Count : constant Nat := Unblocked_Exit_Count;
1301       --  Recursively save value of this global, will be restored on exit
1302
1303       Save_In_Deleted_Code : Boolean;
1304
1305       Del : Boolean := False;
1306       --  This flag gets set True if a True condition has been found,
1307       --  which means that remaining ELSE/ELSIF parts are deleted.
1308
1309       procedure Analyze_Cond_Then (Cnode : Node_Id);
1310       --  This is applied to either the N_If_Statement node itself or
1311       --  to an N_Elsif_Part node. It deals with analyzing the condition
1312       --  and the THEN statements associated with it.
1313
1314       -----------------------
1315       -- Analyze_Cond_Then --
1316       -----------------------
1317
1318       procedure Analyze_Cond_Then (Cnode : Node_Id) is
1319          Cond : constant Node_Id := Condition (Cnode);
1320          Tstm : constant List_Id := Then_Statements (Cnode);
1321
1322       begin
1323          Unblocked_Exit_Count := Unblocked_Exit_Count + 1;
1324          Analyze_And_Resolve (Cond, Any_Boolean);
1325          Check_Unset_Reference (Cond);
1326          Set_Current_Value_Condition (Cnode);
1327
1328          --  If already deleting, then just analyze then statements
1329
1330          if Del then
1331             Analyze_Statements (Tstm);
1332
1333          --  Compile time known value, not deleting yet
1334
1335          elsif Compile_Time_Known_Value (Cond) then
1336             Save_In_Deleted_Code := In_Deleted_Code;
1337
1338             --  If condition is True, then analyze the THEN statements
1339             --  and set no expansion for ELSE and ELSIF parts.
1340
1341             if Is_True (Expr_Value (Cond)) then
1342                Analyze_Statements (Tstm);
1343                Del := True;
1344                Expander_Mode_Save_And_Set (False);
1345                In_Deleted_Code := True;
1346
1347             --  If condition is False, analyze THEN with expansion off
1348
1349             else -- Is_False (Expr_Value (Cond))
1350                Expander_Mode_Save_And_Set (False);
1351                In_Deleted_Code := True;
1352                Analyze_Statements (Tstm);
1353                Expander_Mode_Restore;
1354                In_Deleted_Code := Save_In_Deleted_Code;
1355             end if;
1356
1357          --  Not known at compile time, not deleting, normal analysis
1358
1359          else
1360             Analyze_Statements (Tstm);
1361          end if;
1362       end Analyze_Cond_Then;
1363
1364    --  Start of Analyze_If_Statement
1365
1366    begin
1367       --  Initialize exit count for else statements. If there is no else
1368       --  part, this count will stay non-zero reflecting the fact that the
1369       --  uncovered else case is an unblocked exit.
1370
1371       Unblocked_Exit_Count := 1;
1372       Analyze_Cond_Then (N);
1373
1374       --  Now to analyze the elsif parts if any are present
1375
1376       if Present (Elsif_Parts (N)) then
1377          E := First (Elsif_Parts (N));
1378          while Present (E) loop
1379             Analyze_Cond_Then (E);
1380             Next (E);
1381          end loop;
1382       end if;
1383
1384       if Present (Else_Statements (N)) then
1385          Analyze_Statements (Else_Statements (N));
1386       end if;
1387
1388       --  If all our exits were blocked by unconditional transfers of control,
1389       --  then the entire IF statement acts as an unconditional transfer of
1390       --  control, so treat it like one, and check unreachable code.
1391
1392       if Unblocked_Exit_Count = 0 then
1393          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1394          Check_Unreachable_Code (N);
1395       else
1396          Unblocked_Exit_Count := Save_Unblocked_Exit_Count;
1397       end if;
1398
1399       if Del then
1400          Expander_Mode_Restore;
1401          In_Deleted_Code := Save_In_Deleted_Code;
1402       end if;
1403
1404       if not Expander_Active
1405         and then Compile_Time_Known_Value (Condition (N))
1406         and then Serious_Errors_Detected = 0
1407       then
1408          if Is_True (Expr_Value (Condition (N))) then
1409             Remove_Warning_Messages (Else_Statements (N));
1410
1411             if Present (Elsif_Parts (N)) then
1412                E := First (Elsif_Parts (N));
1413                while Present (E) loop
1414                   Remove_Warning_Messages (Then_Statements (E));
1415                   Next (E);
1416                end loop;
1417             end if;
1418
1419          else
1420             Remove_Warning_Messages (Then_Statements (N));
1421          end if;
1422       end if;
1423    end Analyze_If_Statement;
1424
1425    ----------------------------------------
1426    -- Analyze_Implicit_Label_Declaration --
1427    ----------------------------------------
1428
1429    --  An implicit label declaration is generated in the innermost
1430    --  enclosing declarative part. This is done for labels as well as
1431    --  block and loop names.
1432
1433    --  Note: any changes in this routine may need to be reflected in
1434    --  Analyze_Label_Entity.
1435
1436    procedure Analyze_Implicit_Label_Declaration (N : Node_Id) is
1437       Id : constant Node_Id := Defining_Identifier (N);
1438    begin
1439       Enter_Name          (Id);
1440       Set_Ekind           (Id, E_Label);
1441       Set_Etype           (Id, Standard_Void_Type);
1442       Set_Enclosing_Scope (Id, Current_Scope);
1443    end Analyze_Implicit_Label_Declaration;
1444
1445    ------------------------------
1446    -- Analyze_Iteration_Scheme --
1447    ------------------------------
1448
1449    procedure Analyze_Iteration_Scheme (N : Node_Id) is
1450
1451       procedure Process_Bounds (R : Node_Id);
1452       --  If the iteration is given by a range, create temporaries and
1453       --  assignment statements block to capture the bounds and perform
1454       --  required finalization actions in case a bound includes a function
1455       --  call that uses the temporary stack. We first pre-analyze a copy of
1456       --  the range in order to determine the expected type, and analyze and
1457       --  resolve the original bounds.
1458
1459       procedure Check_Controlled_Array_Attribute (DS : Node_Id);
1460       --  If the bounds are given by a 'Range reference on a function call
1461       --  that returns a controlled array, introduce an explicit declaration
1462       --  to capture the bounds, so that the function result can be finalized
1463       --  in timely fashion.
1464
1465       --------------------
1466       -- Process_Bounds --
1467       --------------------
1468
1469       procedure Process_Bounds (R : Node_Id) is
1470          Loc          : constant Source_Ptr := Sloc (N);
1471          R_Copy       : constant Node_Id := New_Copy_Tree (R);
1472          Lo           : constant Node_Id := Low_Bound  (R);
1473          Hi           : constant Node_Id := High_Bound (R);
1474          New_Lo_Bound : Node_Id := Empty;
1475          New_Hi_Bound : Node_Id := Empty;
1476          Typ          : Entity_Id;
1477          Save_Analysis : Boolean;
1478
1479          function One_Bound
1480            (Original_Bound : Node_Id;
1481             Analyzed_Bound : Node_Id) return Node_Id;
1482          --  Capture value of bound and return captured value
1483
1484          ---------------
1485          -- One_Bound --
1486          ---------------
1487
1488          function One_Bound
1489            (Original_Bound : Node_Id;
1490             Analyzed_Bound : Node_Id) return Node_Id
1491          is
1492             Assign : Node_Id;
1493             Id     : Entity_Id;
1494             Decl   : Node_Id;
1495
1496          begin
1497             --  If the bound is a constant or an object, no need for a separate
1498             --  declaration. If the bound is the result of previous expansion
1499             --  it is already analyzed and should not be modified. Note that
1500             --  the Bound will be resolved later, if needed, as part of the
1501             --  call to Make_Index (literal bounds may need to be resolved to
1502             --  type Integer).
1503
1504             if Analyzed (Original_Bound) then
1505                return Original_Bound;
1506
1507             elsif Nkind_In (Analyzed_Bound, N_Integer_Literal,
1508                                             N_Character_Literal)
1509               or else Is_Entity_Name (Analyzed_Bound)
1510             then
1511                Analyze_And_Resolve (Original_Bound, Typ);
1512                return Original_Bound;
1513             end if;
1514
1515             --  Here we need to capture the value
1516
1517             Analyze_And_Resolve (Original_Bound, Typ);
1518
1519             Id :=
1520               Make_Defining_Identifier (Loc,
1521                 Chars => New_Internal_Name ('S'));
1522
1523             --  Normally, the best approach is simply to generate a constant
1524             --  declaration that captures the bound. However, there is a nasty
1525             --  case where this is wrong. If the bound is complex, and has a
1526             --  possible use of the secondary stack, we need to generate a
1527             --  separate assignment statement to ensure the creation of a block
1528             --  which will release the secondary stack.
1529
1530             --  We prefer the constant declaration, since it leaves us with a
1531             --  proper trace of the value, useful in optimizations that get rid
1532             --  of junk range checks.
1533
1534             --  Probably we want something like the Side_Effect_Free routine
1535             --  in Exp_Util, but for now, we just optimize the cases of 'Last
1536             --  and 'First applied to an entity, since these are the important
1537             --  cases for range check optimizations.
1538
1539             if Nkind (Original_Bound) = N_Attribute_Reference
1540               and then (Attribute_Name (Original_Bound) = Name_First
1541                           or else
1542                         Attribute_Name (Original_Bound) = Name_Last)
1543               and then Is_Entity_Name (Prefix (Original_Bound))
1544             then
1545                Decl :=
1546                  Make_Object_Declaration (Loc,
1547                    Defining_Identifier => Id,
1548                    Constant_Present    => True,
1549                    Object_Definition   => New_Occurrence_Of (Typ, Loc),
1550                    Expression          => Relocate_Node (Original_Bound));
1551
1552                Insert_Before (Parent (N), Decl);
1553                Analyze (Decl);
1554                Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1555                return Expression (Decl);
1556             end if;
1557
1558             --  Here we make a declaration with a separate assignment statement
1559
1560             Decl :=
1561               Make_Object_Declaration (Loc,
1562                 Defining_Identifier => Id,
1563                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
1564
1565             Insert_Before (Parent (N), Decl);
1566             Analyze (Decl);
1567
1568             Assign :=
1569               Make_Assignment_Statement (Loc,
1570                 Name        => New_Occurrence_Of (Id, Loc),
1571                 Expression  => Relocate_Node (Original_Bound));
1572
1573             Insert_Before (Parent (N), Assign);
1574             Analyze (Assign);
1575
1576             Rewrite (Original_Bound, New_Occurrence_Of (Id, Loc));
1577
1578             if Nkind (Assign) = N_Assignment_Statement then
1579                return Expression (Assign);
1580             else
1581                return Original_Bound;
1582             end if;
1583          end One_Bound;
1584
1585       --  Start of processing for Process_Bounds
1586
1587       begin
1588          --  Determine expected type of range by analyzing separate copy
1589          --  Do the analysis and resolution of the copy of the bounds with
1590          --  expansion disabled, to prevent the generation of finalization
1591          --  actions on each bound. This prevents memory leaks when the
1592          --  bounds contain calls to functions returning controlled arrays.
1593
1594          Set_Parent (R_Copy, Parent (R));
1595          Save_Analysis := Full_Analysis;
1596          Full_Analysis := False;
1597          Expander_Mode_Save_And_Set (False);
1598
1599          Analyze (R_Copy);
1600
1601          if Is_Overloaded (R_Copy) then
1602
1603             --  Apply preference rules for range of predefined integer types,
1604             --  or diagnose true ambiguity.
1605
1606             declare
1607                I     : Interp_Index;
1608                It    : Interp;
1609                Found : Entity_Id := Empty;
1610
1611             begin
1612                Get_First_Interp (R_Copy, I, It);
1613                while Present (It.Typ) loop
1614                   if Is_Discrete_Type (It.Typ) then
1615                      if No (Found) then
1616                         Found := It.Typ;
1617                      else
1618                         if Scope (Found) = Standard_Standard then
1619                            null;
1620
1621                         elsif Scope (It.Typ) = Standard_Standard then
1622                            Found := It.Typ;
1623
1624                         else
1625                            --  Both of them are user-defined
1626
1627                            Error_Msg_N
1628                              ("ambiguous bounds in range of iteration",
1629                                R_Copy);
1630                            Error_Msg_N ("\possible interpretations:", R_Copy);
1631                            Error_Msg_NE ("\\} ", R_Copy, Found);
1632                            Error_Msg_NE ("\\} ", R_Copy, It.Typ);
1633                            exit;
1634                         end if;
1635                      end if;
1636                   end if;
1637
1638                   Get_Next_Interp (I, It);
1639                end loop;
1640             end;
1641          end if;
1642
1643          Resolve (R_Copy);
1644          Expander_Mode_Restore;
1645          Full_Analysis := Save_Analysis;
1646
1647          Typ := Etype (R_Copy);
1648
1649          --  If the type of the discrete range is Universal_Integer, then
1650          --  the bound's type must be resolved to Integer, and any object
1651          --  used to hold the bound must also have type Integer, unless the
1652          --  literal bounds are constant-folded expressions that carry a user-
1653          --  defined type.
1654
1655          if Typ = Universal_Integer then
1656             if Nkind (Lo) = N_Integer_Literal
1657               and then Present (Etype (Lo))
1658               and then Scope (Etype (Lo)) /= Standard_Standard
1659             then
1660                Typ := Etype (Lo);
1661
1662             elsif Nkind (Hi) = N_Integer_Literal
1663               and then Present (Etype (Hi))
1664               and then Scope (Etype (Hi)) /= Standard_Standard
1665             then
1666                Typ := Etype (Hi);
1667
1668             else
1669                Typ := Standard_Integer;
1670             end if;
1671          end if;
1672
1673          Set_Etype (R, Typ);
1674
1675          New_Lo_Bound := One_Bound (Lo, Low_Bound  (R_Copy));
1676          New_Hi_Bound := One_Bound (Hi, High_Bound (R_Copy));
1677
1678          --  Propagate staticness to loop range itself, in case the
1679          --  corresponding subtype is static.
1680
1681          if New_Lo_Bound /= Lo
1682            and then Is_Static_Expression (New_Lo_Bound)
1683          then
1684             Rewrite  (Low_Bound (R), New_Copy (New_Lo_Bound));
1685          end if;
1686
1687          if New_Hi_Bound /= Hi
1688            and then Is_Static_Expression (New_Hi_Bound)
1689          then
1690             Rewrite (High_Bound (R), New_Copy (New_Hi_Bound));
1691          end if;
1692       end Process_Bounds;
1693
1694       --------------------------------------
1695       -- Check_Controlled_Array_Attribute --
1696       --------------------------------------
1697
1698       procedure Check_Controlled_Array_Attribute (DS : Node_Id) is
1699       begin
1700          if Nkind (DS) = N_Attribute_Reference
1701             and then Is_Entity_Name (Prefix (DS))
1702             and then Ekind (Entity (Prefix (DS))) = E_Function
1703             and then Is_Array_Type (Etype (Entity (Prefix (DS))))
1704             and then
1705               Is_Controlled (
1706                 Component_Type (Etype (Entity (Prefix (DS)))))
1707             and then Expander_Active
1708          then
1709             declare
1710                Loc  : constant Source_Ptr := Sloc (N);
1711                Arr  : constant Entity_Id :=
1712                         Etype (Entity (Prefix (DS)));
1713                Indx : constant Entity_Id :=
1714                         Base_Type (Etype (First_Index (Arr)));
1715                Subt : constant Entity_Id :=
1716                         Make_Defining_Identifier
1717                           (Loc, New_Internal_Name ('S'));
1718                Decl : Node_Id;
1719
1720             begin
1721                Decl :=
1722                  Make_Subtype_Declaration (Loc,
1723                    Defining_Identifier => Subt,
1724                    Subtype_Indication  =>
1725                       Make_Subtype_Indication (Loc,
1726                         Subtype_Mark  => New_Reference_To (Indx, Loc),
1727                         Constraint =>
1728                           Make_Range_Constraint (Loc,
1729                             Relocate_Node (DS))));
1730                Insert_Before (Parent (N), Decl);
1731                Analyze (Decl);
1732
1733                Rewrite (DS,
1734                   Make_Attribute_Reference (Loc,
1735                     Prefix => New_Reference_To (Subt, Loc),
1736                     Attribute_Name => Attribute_Name (DS)));
1737                Analyze (DS);
1738             end;
1739          end if;
1740       end Check_Controlled_Array_Attribute;
1741
1742    --  Start of processing for Analyze_Iteration_Scheme
1743
1744    begin
1745       --  For an infinite loop, there is no iteration scheme
1746
1747       if No (N) then
1748          return;
1749
1750       else
1751          declare
1752             Cond : constant Node_Id := Condition (N);
1753
1754          begin
1755             --  For WHILE loop, verify that the condition is a Boolean
1756             --  expression and resolve and check it.
1757
1758             if Present (Cond) then
1759                Analyze_And_Resolve (Cond, Any_Boolean);
1760                Check_Unset_Reference (Cond);
1761                Set_Current_Value_Condition (N);
1762                return;
1763
1764             --  Else we have a FOR loop
1765
1766             else
1767                declare
1768                   LP : constant Node_Id   := Loop_Parameter_Specification (N);
1769                   Id : constant Entity_Id := Defining_Identifier (LP);
1770                   DS : constant Node_Id   := Discrete_Subtype_Definition (LP);
1771
1772                begin
1773                   Enter_Name (Id);
1774
1775                   --  We always consider the loop variable to be referenced,
1776                   --  since the loop may be used just for counting purposes.
1777
1778                   Generate_Reference (Id, N, ' ');
1779
1780                   --  Check for case of loop variable hiding a local
1781                   --  variable (used later on to give a nice warning
1782                   --  if the hidden variable is never assigned).
1783
1784                   declare
1785                      H : constant Entity_Id := Homonym (Id);
1786                   begin
1787                      if Present (H)
1788                        and then Enclosing_Dynamic_Scope (H) =
1789                                 Enclosing_Dynamic_Scope (Id)
1790                        and then Ekind (H) = E_Variable
1791                        and then Is_Discrete_Type (Etype (H))
1792                      then
1793                         Set_Hiding_Loop_Variable (H, Id);
1794                      end if;
1795                   end;
1796
1797                   --  Now analyze the subtype definition. If it is
1798                   --  a range, create temporaries for bounds.
1799
1800                   if Nkind (DS) = N_Range
1801                     and then Expander_Active
1802                   then
1803                      Process_Bounds (DS);
1804                   else
1805                      Analyze (DS);
1806                   end if;
1807
1808                   if DS = Error then
1809                      return;
1810                   end if;
1811
1812                   --  The subtype indication may denote the completion
1813                   --  of an incomplete type declaration.
1814
1815                   if Is_Entity_Name (DS)
1816                     and then Present (Entity (DS))
1817                     and then Is_Type (Entity (DS))
1818                     and then Ekind (Entity (DS)) = E_Incomplete_Type
1819                   then
1820                      Set_Entity (DS, Get_Full_View (Entity (DS)));
1821                      Set_Etype  (DS, Entity (DS));
1822                   end if;
1823
1824                   if not Is_Discrete_Type (Etype (DS)) then
1825                      Wrong_Type (DS, Any_Discrete);
1826                      Set_Etype (DS, Any_Type);
1827                   end if;
1828
1829                   Check_Controlled_Array_Attribute (DS);
1830
1831                   Make_Index (DS, LP);
1832
1833                   Set_Ekind          (Id, E_Loop_Parameter);
1834                   Set_Etype          (Id, Etype (DS));
1835
1836                   --  Treat a range as an implicit reference to the type, to
1837                   --  inhibit spurious warnings.
1838
1839                   Generate_Reference (Base_Type (Etype (DS)), N, ' ');
1840                   Set_Is_Known_Valid (Id, True);
1841
1842                   --  The loop is not a declarative part, so the only entity
1843                   --  declared "within" must be frozen explicitly.
1844
1845                   declare
1846                      Flist : constant List_Id := Freeze_Entity (Id, Sloc (N));
1847                   begin
1848                      if Is_Non_Empty_List (Flist) then
1849                         Insert_Actions (N, Flist);
1850                      end if;
1851                   end;
1852
1853                   --  Check for null or possibly null range and issue warning.
1854                   --  We suppress such messages in generic templates and
1855                   --  instances, because in practice they tend to be dubious
1856                   --  in these cases.
1857
1858                   if Nkind (DS) = N_Range
1859                     and then Comes_From_Source (N)
1860                   then
1861                      declare
1862                         L : constant Node_Id := Low_Bound  (DS);
1863                         H : constant Node_Id := High_Bound (DS);
1864
1865                      begin
1866                         --  If range of loop is null, issue warning
1867
1868                         if Compile_Time_Compare
1869                             (L, H, Assume_Valid => True) = GT
1870                         then
1871                            --  Suppress the warning if inside a generic
1872                            --  template or instance, since in practice
1873                            --  they tend to be dubious in these cases since
1874                            --  they can result from intended parametrization.
1875
1876                            if not Inside_A_Generic
1877                               and then not In_Instance
1878                            then
1879                               --  Specialize msg if invalid values could make
1880                               --  the loop non-null after all.
1881
1882                               if Compile_Time_Compare
1883                                    (L, H, Assume_Valid => False) = GT
1884                               then
1885                                  Error_Msg_N
1886                                    ("?loop range is null, "
1887                                     & "loop will not execute",
1888                                     DS);
1889
1890                                  --  Since we know the range of the loop is
1891                                  --  null, set the appropriate flag to remove
1892                                  --  the loop entirely during expansion.
1893
1894                                  Set_Is_Null_Loop (Parent (N));
1895
1896                               --  Here is where the loop could execute because
1897                               --  of invalid values, so issue appropriate
1898                               --  message and in this case we do not set the
1899                               --  Is_Null_Loop flag since the loop may execute.
1900
1901                               else
1902                                  Error_Msg_N
1903                                    ("?loop range may be null, "
1904                                     & "loop may not execute",
1905                                     DS);
1906                                  Error_Msg_N
1907                                    ("?can only execute if invalid values "
1908                                     & "are present",
1909                                     DS);
1910                               end if;
1911                            end if;
1912
1913                            --  In either case, suppress warnings in the body of
1914                            --  the loop, since it is likely that these warnings
1915                            --  will be inappropriate if the loop never actually
1916                            --  executes, which is unlikely.
1917
1918                            Set_Suppress_Loop_Warnings (Parent (N));
1919
1920                         --  The other case for a warning is a reverse loop
1921                         --  where the upper bound is the integer literal
1922                         --  zero or one, and the lower bound can be positive.
1923
1924                         --  For example, we have
1925
1926                         --     for J in reverse N .. 1 loop
1927
1928                         --  In practice, this is very likely to be a case
1929                         --  of reversing the bounds incorrectly in the range.
1930
1931                         elsif Reverse_Present (LP)
1932                           and then Nkind (Original_Node (H)) =
1933                                                           N_Integer_Literal
1934                           and then (Intval (Original_Node (H)) = Uint_0
1935                                       or else
1936                                     Intval (Original_Node (H)) = Uint_1)
1937                         then
1938                            Error_Msg_N ("?loop range may be null", DS);
1939                            Error_Msg_N ("\?bounds may be wrong way round", DS);
1940                         end if;
1941                      end;
1942                   end if;
1943                end;
1944             end if;
1945          end;
1946       end if;
1947    end Analyze_Iteration_Scheme;
1948
1949    -------------------
1950    -- Analyze_Label --
1951    -------------------
1952
1953    --  Note: the semantic work required for analyzing labels (setting them as
1954    --  reachable) was done in a prepass through the statements in the block,
1955    --  so that forward gotos would be properly handled. See Analyze_Statements
1956    --  for further details. The only processing required here is to deal with
1957    --  optimizations that depend on an assumption of sequential control flow,
1958    --  since of course the occurrence of a label breaks this assumption.
1959
1960    procedure Analyze_Label (N : Node_Id) is
1961       pragma Warnings (Off, N);
1962    begin
1963       Kill_Current_Values;
1964    end Analyze_Label;
1965
1966    --------------------------
1967    -- Analyze_Label_Entity --
1968    --------------------------
1969
1970    procedure Analyze_Label_Entity (E : Entity_Id) is
1971    begin
1972       Set_Ekind           (E, E_Label);
1973       Set_Etype           (E, Standard_Void_Type);
1974       Set_Enclosing_Scope (E, Current_Scope);
1975       Set_Reachable       (E, True);
1976    end Analyze_Label_Entity;
1977
1978    ----------------------------
1979    -- Analyze_Loop_Statement --
1980    ----------------------------
1981
1982    procedure Analyze_Loop_Statement (N : Node_Id) is
1983       Loop_Statement : constant Node_Id := N;
1984
1985       Id   : constant Node_Id := Identifier (Loop_Statement);
1986       Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
1987       Ent  : Entity_Id;
1988
1989    begin
1990       if Present (Id) then
1991
1992          --  Make name visible, e.g. for use in exit statements. Loop
1993          --  labels are always considered to be referenced.
1994
1995          Analyze (Id);
1996          Ent := Entity (Id);
1997
1998          --  Guard against serious error (typically, a scope mismatch when
1999          --  semantic analysis is requested) by creating loop entity to
2000          --  continue analysis.
2001
2002          if No (Ent) then
2003             if Total_Errors_Detected /= 0 then
2004                Ent :=
2005                  New_Internal_Entity
2006                    (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2007             else
2008                raise Program_Error;
2009             end if;
2010
2011          else
2012             Generate_Reference  (Ent, Loop_Statement, ' ');
2013             Generate_Definition (Ent);
2014
2015             --  If we found a label, mark its type. If not, ignore it, since it
2016             --  means we have a conflicting declaration, which would already
2017             --  have been diagnosed at declaration time. Set Label_Construct
2018             --  of the implicit label declaration, which is not created by the
2019             --  parser for generic units.
2020
2021             if Ekind (Ent) = E_Label then
2022                Set_Ekind (Ent, E_Loop);
2023
2024                if Nkind (Parent (Ent)) = N_Implicit_Label_Declaration then
2025                   Set_Label_Construct (Parent (Ent), Loop_Statement);
2026                end if;
2027             end if;
2028          end if;
2029
2030       --  Case of no identifier present
2031
2032       else
2033          Ent :=
2034            New_Internal_Entity
2035              (E_Loop, Current_Scope, Sloc (Loop_Statement), 'L');
2036          Set_Etype (Ent,  Standard_Void_Type);
2037          Set_Parent (Ent, Loop_Statement);
2038       end if;
2039
2040       --  Kill current values on entry to loop, since statements in body of
2041       --  loop may have been executed before the loop is entered. Similarly we
2042       --  kill values after the loop, since we do not know that the body of the
2043       --  loop was executed.
2044
2045       Kill_Current_Values;
2046       Push_Scope (Ent);
2047       Analyze_Iteration_Scheme (Iter);
2048       Analyze_Statements (Statements (Loop_Statement));
2049       Process_End_Label (Loop_Statement, 'e', Ent);
2050       End_Scope;
2051       Kill_Current_Values;
2052
2053       --  Check for infinite loop. We skip this check for generated code, since
2054       --  it justs waste time and makes debugging the routine called harder.
2055
2056       if Comes_From_Source (N) then
2057          Check_Infinite_Loop_Warning (N);
2058       end if;
2059
2060       --  Code after loop is unreachable if the loop has no WHILE or FOR
2061       --  and contains no EXIT statements within the body of the loop.
2062
2063       if No (Iter) and then not Has_Exit (Ent) then
2064          Check_Unreachable_Code (N);
2065       end if;
2066    end Analyze_Loop_Statement;
2067
2068    ----------------------------
2069    -- Analyze_Null_Statement --
2070    ----------------------------
2071
2072    --  Note: the semantics of the null statement is implemented by a single
2073    --  null statement, too bad everything isn't as simple as this!
2074
2075    procedure Analyze_Null_Statement (N : Node_Id) is
2076       pragma Warnings (Off, N);
2077    begin
2078       null;
2079    end Analyze_Null_Statement;
2080
2081    ------------------------
2082    -- Analyze_Statements --
2083    ------------------------
2084
2085    procedure Analyze_Statements (L : List_Id) is
2086       S   : Node_Id;
2087       Lab : Entity_Id;
2088
2089    begin
2090       --  The labels declared in the statement list are reachable from
2091       --  statements in the list. We do this as a prepass so that any
2092       --  goto statement will be properly flagged if its target is not
2093       --  reachable. This is not required, but is nice behavior!
2094
2095       S := First (L);
2096       while Present (S) loop
2097          if Nkind (S) = N_Label then
2098             Analyze (Identifier (S));
2099             Lab := Entity (Identifier (S));
2100
2101             --  If we found a label mark it as reachable
2102
2103             if Ekind (Lab) = E_Label then
2104                Generate_Definition (Lab);
2105                Set_Reachable (Lab);
2106
2107                if Nkind (Parent (Lab)) = N_Implicit_Label_Declaration then
2108                   Set_Label_Construct (Parent (Lab), S);
2109                end if;
2110
2111             --  If we failed to find a label, it means the implicit declaration
2112             --  of the label was hidden.  A for-loop parameter can do this to
2113             --  a label with the same name inside the loop, since the implicit
2114             --  label declaration is in the innermost enclosing body or block
2115             --  statement.
2116
2117             else
2118                Error_Msg_Sloc := Sloc (Lab);
2119                Error_Msg_N
2120                  ("implicit label declaration for & is hidden#",
2121                   Identifier (S));
2122             end if;
2123          end if;
2124
2125          Next (S);
2126       end loop;
2127
2128       --  Perform semantic analysis on all statements
2129
2130       Conditional_Statements_Begin;
2131
2132       S := First (L);
2133       while Present (S) loop
2134          Analyze (S);
2135          Next (S);
2136       end loop;
2137
2138       Conditional_Statements_End;
2139
2140       --  Make labels unreachable. Visibility is not sufficient, because
2141       --  labels in one if-branch for example are not reachable from the
2142       --  other branch, even though their declarations are in the enclosing
2143       --  declarative part.
2144
2145       S := First (L);
2146       while Present (S) loop
2147          if Nkind (S) = N_Label then
2148             Set_Reachable (Entity (Identifier (S)), False);
2149          end if;
2150
2151          Next (S);
2152       end loop;
2153    end Analyze_Statements;
2154
2155    ----------------------------
2156    -- Check_Unreachable_Code --
2157    ----------------------------
2158
2159    procedure Check_Unreachable_Code (N : Node_Id) is
2160       Error_Loc : Source_Ptr;
2161       P         : Node_Id;
2162
2163    begin
2164       if Is_List_Member (N)
2165         and then Comes_From_Source (N)
2166       then
2167          declare
2168             Nxt : Node_Id;
2169
2170          begin
2171             Nxt := Original_Node (Next (N));
2172
2173             --  If a label follows us, then we never have dead code, since
2174             --  someone could branch to the label, so we just ignore it.
2175
2176             if Nkind (Nxt) = N_Label then
2177                return;
2178
2179             --  Otherwise see if we have a real statement following us
2180
2181             elsif Present (Nxt)
2182               and then Comes_From_Source (Nxt)
2183               and then Is_Statement (Nxt)
2184             then
2185                --  Special very annoying exception. If we have a return that
2186                --  follows a raise, then we allow it without a warning, since
2187                --  the Ada RM annoyingly requires a useless return here!
2188
2189                if Nkind (Original_Node (N)) /= N_Raise_Statement
2190                  or else Nkind (Nxt) /= N_Simple_Return_Statement
2191                then
2192                   --  The rather strange shenanigans with the warning message
2193                   --  here reflects the fact that Kill_Dead_Code is very good
2194                   --  at removing warnings in deleted code, and this is one
2195                   --  warning we would prefer NOT to have removed.
2196
2197                   Error_Loc := Sloc (Nxt);
2198
2199                   --  If we have unreachable code, analyze and remove the
2200                   --  unreachable code, since it is useless and we don't
2201                   --  want to generate junk warnings.
2202
2203                   --  We skip this step if we are not in code generation mode.
2204                   --  This is the one case where we remove dead code in the
2205                   --  semantics as opposed to the expander, and we do not want
2206                   --  to remove code if we are not in code generation mode,
2207                   --  since this messes up the ASIS trees.
2208
2209                   --  Note that one might react by moving the whole circuit to
2210                   --  exp_ch5, but then we lose the warning in -gnatc mode.
2211
2212                   if Operating_Mode = Generate_Code then
2213                      loop
2214                         Nxt := Next (N);
2215
2216                         --  Quit deleting when we have nothing more to delete
2217                         --  or if we hit a label (since someone could transfer
2218                         --  control to a label, so we should not delete it).
2219
2220                         exit when No (Nxt) or else Nkind (Nxt) = N_Label;
2221
2222                         --  Statement/declaration is to be deleted
2223
2224                         Analyze (Nxt);
2225                         Remove (Nxt);
2226                         Kill_Dead_Code (Nxt);
2227                      end loop;
2228                   end if;
2229
2230                   --  Now issue the warning
2231
2232                   Error_Msg ("?unreachable code!", Error_Loc);
2233                end if;
2234
2235             --  If the unconditional transfer of control instruction is
2236             --  the last statement of a sequence, then see if our parent
2237             --  is one of the constructs for which we count unblocked exits,
2238             --  and if so, adjust the count.
2239
2240             else
2241                P := Parent (N);
2242
2243                --  Statements in THEN part or ELSE part of IF statement
2244
2245                if Nkind (P) = N_If_Statement then
2246                   null;
2247
2248                --  Statements in ELSIF part of an IF statement
2249
2250                elsif Nkind (P) = N_Elsif_Part then
2251                   P := Parent (P);
2252                   pragma Assert (Nkind (P) = N_If_Statement);
2253
2254                --  Statements in CASE statement alternative
2255
2256                elsif Nkind (P) = N_Case_Statement_Alternative then
2257                   P := Parent (P);
2258                   pragma Assert (Nkind (P) = N_Case_Statement);
2259
2260                --  Statements in body of block
2261
2262                elsif Nkind (P) = N_Handled_Sequence_Of_Statements
2263                  and then Nkind (Parent (P)) = N_Block_Statement
2264                then
2265                   null;
2266
2267                --  Statements in exception handler in a block
2268
2269                elsif Nkind (P) = N_Exception_Handler
2270                  and then Nkind (Parent (P)) = N_Handled_Sequence_Of_Statements
2271                  and then Nkind (Parent (Parent (P))) = N_Block_Statement
2272                then
2273                   null;
2274
2275                --  None of these cases, so return
2276
2277                else
2278                   return;
2279                end if;
2280
2281                --  This was one of the cases we are looking for (i.e. the
2282                --  parent construct was IF, CASE or block) so decrement count.
2283
2284                Unblocked_Exit_Count := Unblocked_Exit_Count - 1;
2285             end if;
2286          end;
2287       end if;
2288    end Check_Unreachable_Code;
2289
2290 end Sem_Ch5;