gcc/ada/sem_ch3.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 3                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Nlists; use Nlists;
  27 with Types;  use Types;
  28
  29 package Sem_Ch3 is
  30    procedure Analyze_Component_Declaration         (N : Node_Id);
  31    procedure Analyze_Incomplete_Type_Decl          (N : Node_Id);
  32    procedure Analyze_Itype_Reference               (N : Node_Id);
  33    procedure Analyze_Number_Declaration            (N : Node_Id);
  34    procedure Analyze_Object_Declaration            (N : Node_Id);
  35    procedure Analyze_Others_Choice                 (N : Node_Id);
  36    procedure Analyze_Private_Extension_Declaration (N : Node_Id);
  37    procedure Analyze_Subtype_Indication            (N : Node_Id);
  38    procedure Analyze_Type_Declaration              (N : Node_Id);
  39    procedure Analyze_Variant_Part                  (N : Node_Id);
  40
  41    procedure Analyze_Subtype_Declaration
  42      (N    : Node_Id;
  43       Skip : Boolean := False);
  44    --  Called to analyze a subtype declaration. The parameter Skip is used for
  45    --  Ada 2005 (AI-412). We set to True in order to avoid reentering the
  46    --  defining identifier of N when analyzing a rewritten incomplete subtype
  47    --  declaration.
  48
  49    function Access_Definition
  50      (Related_Nod : Node_Id;
  51       N           : Node_Id) return Entity_Id;
  52    --  An access definition defines a general access type for a formal
  53    --  parameter. The procedure is called when processing formals, when
  54    --  the current scope is the subprogram. The Implicit type is attached
  55    --  to the Related_Nod put into the enclosing scope, so that the only
  56    --  entities defined in the spec are the formals themselves.
  57
  58    procedure Access_Subprogram_Declaration
  59      (T_Name : Entity_Id;
  60       T_Def  : Node_Id);
  61    --  The subprogram specification yields the signature of an implicit
  62    --  type, whose Ekind is Access_Subprogram_Type. This implicit type is
  63    --  the designated type of the declared access type. In subprogram calls,
  64    --  the signature of the implicit type works like the profile of a regular
  65    --  subprogram.
  66
  67    procedure Add_Internal_Interface_Entities (Tagged_Type : Entity_Id);
  68    --  Add to the list of primitives of Tagged_Type the internal entities
  69    --  associated with covered interface primitives. These entities link the
  70    --  interface primitives with the tagged type primitives that cover them.
  71
  72    procedure Analyze_Declarations (L : List_Id);
  73    --  Called to analyze a list of declarations (in what context ???). Also
  74    --  performs necessary freezing actions (more description needed ???)
  75
  76    procedure Analyze_Interface_Declaration (T : Entity_Id; Def : Node_Id);
  77    --  Analyze an interface declaration or a formal interface declaration
  78
  79    procedure Array_Type_Declaration (T : in out Entity_Id; Def : Node_Id);
  80    --  Process an array type declaration. If the array is constrained, we
  81    --  create an implicit parent array type, with the same index types and
  82    --  component type.
  83
  84    procedure Access_Type_Declaration (T : Entity_Id; Def : Node_Id);
  85    --  Process an access type declaration
  86
  87    procedure Build_Itype_Reference
  88      (Ityp : Entity_Id;
  89       Nod  : Node_Id);
  90    --  Create a reference to an internal type, for use by Gigi. The back-end
  91    --  elaborates itypes on demand, i.e. when their first use is seen. This
  92    --  can lead to scope anomalies if the first use is within a scope that is
  93    --  nested within the scope that contains  the point of definition of the
  94    --  itype. The Itype_Reference node forces the elaboration of the itype
  95    --  in the proper scope. The node is inserted after Nod, which is the
  96    --  enclosing declaration that generated Ityp.
  97    --
  98    --  A related mechanism is used during expansion, for itypes created in
  99    --  branches of conditionals. See Ensure_Defined in exp_util.
 100    --  Could both mechanisms be merged ???
 101
 102    procedure Check_Abstract_Overriding (T : Entity_Id);
 103    --  Check that all abstract subprograms inherited from T's parent type have
 104    --  been overridden as required, and that nonabstract subprograms have not
 105    --  been incorrectly overridden with an abstract subprogram.
 106
 107    procedure Check_Aliased_Component_Types (T : Entity_Id);
 108    --  Given an array type or record type T, check that if the type is
 109    --  nonlimited, then the nominal subtype of any components of T that
 110    --  have discriminants must be constrained.
 111
 112    procedure Check_Completion (Body_Id : Node_Id := Empty);
 113    --  At the end of a declarative part, verify that all entities that require
 114    --  completion have received one. If Body_Id is absent, the error indicating
 115    --  a missing completion is placed on the declaration that needs completion.
 116    --  If Body_Id is present, it is the defining identifier of a package body,
 117    --  and errors are posted on that node, rather than on the declarations that
 118    --  require completion in the package declaration.
 119
 120    procedure Derive_Subprogram
 121      (New_Subp     : in out Entity_Id;
 122       Parent_Subp  : Entity_Id;
 123       Derived_Type : Entity_Id;
 124       Parent_Type  : Entity_Id;
 125       Actual_Subp  : Entity_Id := Empty);
 126    --  Derive the subprogram Parent_Subp from Parent_Type, and replace the
 127    --  subsidiary subtypes with the derived type to build the specification
 128    --  of the inherited subprogram (returned in New_Subp). For tagged types,
 129    --  the derived subprogram is aliased to that of the actual (in the
 130    --  case where Actual_Subp is nonempty) rather than to the corresponding
 131    --  subprogram of the parent type.
 132
 133    procedure Derive_Subprograms
 134      (Parent_Type    : Entity_Id;
 135       Derived_Type   : Entity_Id;
 136       Generic_Actual : Entity_Id := Empty);
 137    --  To complete type derivation, collect/retrieve the primitive operations
 138    --  of the parent type, and replace the subsidiary subtypes with the derived
 139    --  type, to build the specs of the inherited ops. For generic actuals, the
 140    --  mapping of the primitive operations to those of the parent type is also
 141    --  done by rederiving the operations within the instance. For tagged types,
 142    --  the derived subprograms are aliased to those of the actual, not those of
 143    --  the ancestor.
 144    --
 145    --  Note: one might expect this to be private to the package body, but there
 146    --  is one rather unusual usage in package Exp_Dist.
 147
 148    function Find_Hidden_Interface
 149      (Src  : Elist_Id;
 150       Dest : Elist_Id) return Entity_Id;
 151    --  Ada 2005: Determine whether the interfaces in list Src are all present
 152    --  in the list Dest. Return the first differing interface, or Empty
 153    --  otherwise.
 154
 155    function Find_Type_Of_Subtype_Indic (S : Node_Id) return Entity_Id;
 156    --  Given a subtype indication S (which is really an N_Subtype_Indication
 157    --  node or a plain N_Identifier), find the type of the subtype mark.
 158
 159    function Find_Type_Name (N : Node_Id) return Entity_Id;
 160    --  Enter the identifier in a type definition, or find the entity already
 161    --  declared, in the case of the full declaration of an incomplete or
 162    --  private type.
 163
 164    function Get_Discriminant_Value
 165      (Discriminant       : Entity_Id;
 166       Typ_For_Constraint : Entity_Id;
 167       Constraint         : Elist_Id) return Node_Id;
 168    --  ??? MORE DOCUMENTATION
 169    --  Given a discriminant somewhere in the Typ_For_Constraint tree and a
 170    --  Constraint, return the value of that discriminant.
 171
 172    function Is_Null_Extension (T : Entity_Id) return Boolean;
 173    --  Returns True if the tagged type T has an N_Full_Type_Declaration that
 174    --  is a null extension, meaning that it has an extension part without any
 175    --  components and does not have a known discriminant part.
 176
 177    function Is_Visible_Component (C : Entity_Id) return Boolean;
 178    --  Determines if a record component C is visible in the present context.
 179    --  Note that even though component C could appear in the entity chain
 180    --  of a record type, C may not be visible in the current context. For
 181    --  instance, C may be a component inherited in the full view of a private
 182    --  extension which is not visible in the current context.
 183
 184    procedure Make_Index
 185      (I            : Node_Id;
 186       Related_Nod  : Node_Id;
 187       Related_Id   : Entity_Id := Empty;
 188       Suffix_Index : Nat := 1);
 189    --  Process an index that is given in an array declaration, an entry
 190    --  family declaration or a loop iteration. The index is given by an
 191    --  index declaration (a 'box'), or by a discrete range. The later can
 192    --  be the name of a discrete type, or a subtype indication.
 193    --
 194    --  Related_Nod is the node where the potential generated implicit types
 195    --  will be inserted. The 2 last parameters are used for creating the name.
 196
 197    procedure Make_Class_Wide_Type (T : Entity_Id);
 198    --  A Class_Wide_Type is created for each tagged type definition. The
 199    --  attributes of a class-wide type are inherited from those of the type T.
 200    --  If T is introduced by a private declaration, the corresponding class
 201    --  wide type is created at the same time, and therefore there is a private
 202    --  and a full declaration for the class-wide type as well.
 203
 204    function OK_For_Limited_Init_In_05
 205      (Typ : Entity_Id;
 206       Exp : Node_Id) return Boolean;
 207    --  Presuming Exp is an expression of an inherently limited type Typ,
 208    --  returns True if the expression is allowed in an initialization context
 209    --  by the rules of Ada 2005. We use the rule in RM-7.5(2.1/2), "...it is an
 210    --  aggregate, a function_call, or a parenthesized expression or qualified
 211    --  expression whose operand is permitted...". Note that in Ada 95 mode,
 212    --  we sometimes wish to give warnings based on whether the program _would_
 213    --  be legal in Ada 2005. Note that Exp must already have been resolved,
 214    --  so we can know whether it's a function call (as opposed to an indexed
 215    --  component, for example). In the case where Typ is a limited interface's
 216    --  class-wide type, then the expression is allowed to be of any kind if its
 217    --  type is a nonlimited descendant of the interface.
 218
 219    function OK_For_Limited_Init
 220      (Typ : Entity_Id;
 221       Exp : Node_Id) return Boolean;
 222    --  Always False in Ada 95 mode. Equivalent to OK_For_Limited_Init_In_05 in
 223    --  Ada 2005 mode.
 224
 225    procedure Preanalyze_Spec_Expression (N : Node_Id; T : Entity_Id);
 226    --  Default and per object expressions do not freeze their components, and
 227    --  must be analyzed and resolved accordingly. The analysis is done by
 228    --  calling the Preanalyze_And_Resolve routine and setting the global
 229    --  In_Default_Expression flag. See the documentation section entitled
 230    --  "Handling of Default and Per-Object Expressions" in sem.ads for full
 231    --  details. N is the expression to be analyzed, T is the expected type.
 232
 233    procedure Process_Full_View (N : Node_Id; Full_T, Priv_T : Entity_Id);
 234    --  Process some semantic actions when the full view of a private type is
 235    --  encountered and analyzed. The first action is to create the full views
 236    --  of the dependant private subtypes. The second action is to recopy the
 237    --  primitive operations of the private view (in the tagged case).
 238    --  N is the N_Full_Type_Declaration node.
 239    --
 240    --    Full_T is the full view of the type whose full declaration is in N.
 241    --
 242    --    Priv_T is the private view of the type whose full declaration is in N.
 243
 244    procedure Process_Range_Expr_In_Decl
 245      (R           : Node_Id;
 246       T           : Entity_Id;
 247       Check_List  : List_Id := Empty_List;
 248       R_Check_Off : Boolean := False);
 249    --  Process a range expression that appears in a declaration context. The
 250    --  range is analyzed and resolved with the base type of the given type, and
 251    --  an appropriate check for expressions in non-static contexts made on the
 252    --  bounds. R is analyzed and resolved using T, so the caller should if
 253    --  necessary link R into the tree before the call, and in particular in the
 254    --  case of a subtype declaration, it is appropriate to set the parent
 255    --  pointer of R so that the types get properly frozen. Check_List is used
 256    --  when the subprogram is called from Build_Record_Init_Proc and is used to
 257    --  return a set of constraint checking statements generated by the Checks
 258    --  package. R_Check_Off is set to True when the call to Range_Check is to
 259    --  be skipped.
 260
 261    function Process_Subtype
 262      (S           : Node_Id;
 263       Related_Nod : Node_Id;
 264       Related_Id  : Entity_Id := Empty;
 265       Suffix      : Character := ' ') return Entity_Id;
 266    --  Process a subtype indication S and return corresponding entity.
 267    --  Related_Nod is the node where the potential generated implicit types
 268    --  will be inserted. The Related_Id and Suffix parameters are used to
 269    --  build the associated Implicit type name.
 270
 271    procedure Process_Discriminants
 272      (N    : Node_Id;
 273       Prev : Entity_Id := Empty);
 274    --  Process the discriminants contained in an N_Full_Type_Declaration or
 275    --  N_Incomplete_Type_Decl node N. If the declaration is a completion,
 276    --  Prev is entity on the partial view, on which references are posted.
 277
 278    function Replace_Anonymous_Access_To_Protected_Subprogram
 279      (N : Node_Id) return Entity_Id;
 280    --  Ada 2005 (AI-254): Create and decorate an internal full type declaration
 281    --  for an anonymous access to protected subprogram. For a record component
 282    --  declaration, the type is created in the enclosing scope, for an array
 283    --  type declaration or an object declaration it is simply placed ahead of
 284    --  this declaration.
 285
 286    procedure Set_Completion_Referenced (E : Entity_Id);
 287    --  If E is the completion of a private or incomplete  type declaration,
 288    --  or the completion of a deferred constant declaration, mark the entity
 289    --  as referenced. Warnings on unused entities, if needed, go on the
 290    --  partial view.
 291
 292 end Sem_Ch3;