gcc/ada/sem_ch3.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 3                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision$
  10 --                                                                          --
  11 --          Copyright (C) 1992-2001, Free Software Foundation, Inc.         --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- GNAT was originally developed  by the GNAT team at  New York University. --
  25 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  26 --                                                                          --
  27 ------------------------------------------------------------------------------
  28
  29 with Atree;    use Atree;
  30 with Checks;   use Checks;
  31 with Elists;   use Elists;
  32 with Einfo;    use Einfo;
  33 with Errout;   use Errout;
  34 with Eval_Fat; use Eval_Fat;
  35 with Exp_Ch3;  use Exp_Ch3;
  36 with Exp_Dist; use Exp_Dist;
  37 with Exp_Util; use Exp_Util;
  38 with Freeze;   use Freeze;
  39 with Itypes;   use Itypes;
  40 with Layout;   use Layout;
  41 with Lib;      use Lib;
  42 with Lib.Xref; use Lib.Xref;
  43 with Namet;    use Namet;
  44 with Nmake;    use Nmake;
  45 with Opt;      use Opt;
  46 with Restrict; use Restrict;
  47 with Rtsfind;  use Rtsfind;
  48 with Sem;      use Sem;
  49 with Sem_Case; use Sem_Case;
  50 with Sem_Cat;  use Sem_Cat;
  51 with Sem_Ch6;  use Sem_Ch6;
  52 with Sem_Ch7;  use Sem_Ch7;
  53 with Sem_Ch8;  use Sem_Ch8;
  54 with Sem_Ch13; use Sem_Ch13;
  55 with Sem_Disp; use Sem_Disp;
  56 with Sem_Dist; use Sem_Dist;
  57 with Sem_Elim; use Sem_Elim;
  58 with Sem_Eval; use Sem_Eval;
  59 with Sem_Mech; use Sem_Mech;
  60 with Sem_Res;  use Sem_Res;
  61 with Sem_Smem; use Sem_Smem;
  62 with Sem_Type; use Sem_Type;
  63 with Sem_Util; use Sem_Util;
  64 with Stand;    use Stand;
  65 with Sinfo;    use Sinfo;
  66 with Snames;   use Snames;
  67 with Tbuild;   use Tbuild;
  68 with Ttypes;   use Ttypes;
  69 with Uintp;    use Uintp;
  70 with Urealp;   use Urealp;
  71
  72 package body Sem_Ch3 is
  73
  74    -----------------------
  75    -- Local Subprograms --
  76    -----------------------
  77
  78    procedure Build_Derived_Type
  79      (N             : Node_Id;
  80       Parent_Type   : Entity_Id;
  81       Derived_Type  : Entity_Id;
  82       Is_Completion : Boolean;
  83       Derive_Subps  : Boolean := True);
  84    --  Create and decorate a Derived_Type given the Parent_Type entity.
  85    --  N is the N_Full_Type_Declaration node containing the derived type
  86    --  definition. Parent_Type is the entity for the parent type in the derived
  87    --  type definition and Derived_Type the actual derived type. Is_Completion
  88    --  must be set to False if Derived_Type is the N_Defining_Identifier node
  89    --  in N (ie Derived_Type = Defining_Identifier (N)). In this case N is not
  90    --  the completion of a private type declaration. If Is_Completion is
  91    --  set to True, N is the completion of a private type declaration and
  92    --  Derived_Type is different from the defining identifier inside N (i.e.
  93    --  Derived_Type /= Defining_Identifier (N)). Derive_Subps indicates whether
  94    --  the parent subprograms should be derived. The only case where this
  95    --  parameter is False is when Build_Derived_Type is recursively called to
  96    --  process an implicit derived full type for a type derived from a private
  97    --  type (in that case the subprograms must only be derived for the private
  98    --  view of the type).
  99    --  ??? These flags need a bit of re-examination and re-documentation:
 100    --  ???  are they both necessary (both seem related to the recursion)?
 101
 102    procedure Build_Derived_Access_Type
 103      (N            : Node_Id;
 104       Parent_Type  : Entity_Id;
 105       Derived_Type : Entity_Id);
 106    --  Subsidiary procedure to Build_Derived_Type. For a derived access type,
 107    --  create an implicit base if the parent type is constrained or if the
 108    --  subtype indication has a constraint.
 109
 110    procedure Build_Derived_Array_Type
 111      (N            : Node_Id;
 112       Parent_Type  : Entity_Id;
 113       Derived_Type : Entity_Id);
 114    --  Subsidiary procedure to Build_Derived_Type. For a derived array type,
 115    --  create an implicit base if the parent type is constrained or if the
 116    --  subtype indication has a constraint.
 117
 118    procedure Build_Derived_Concurrent_Type
 119      (N            : Node_Id;
 120       Parent_Type  : Entity_Id;
 121       Derived_Type : Entity_Id);
 122    --  Subsidiary procedure to Build_Derived_Type. For a derived task or pro-
 123    --  tected type, inherit entries and protected subprograms, check legality
 124    --  of discriminant constraints if any.
 125
 126    procedure Build_Derived_Enumeration_Type
 127      (N            : Node_Id;
 128       Parent_Type  : Entity_Id;
 129       Derived_Type : Entity_Id);
 130    --  Subsidiary procedure to Build_Derived_Type. For a derived enumeration
 131    --  type, we must create a new list of literals. Types derived from
 132    --  Character and Wide_Character are special-cased.
 133
 134    procedure Build_Derived_Numeric_Type
 135      (N            : Node_Id;
 136       Parent_Type  : Entity_Id;
 137       Derived_Type : Entity_Id);
 138    --  Subsidiary procedure to Build_Derived_Type. For numeric types, create
 139    --  an anonymous base type, and propagate constraint to subtype if needed.
 140
 141    procedure Build_Derived_Private_Type
 142      (N            : Node_Id;
 143       Parent_Type  : Entity_Id;
 144       Derived_Type : Entity_Id;
 145       Is_Completion : Boolean;
 146       Derive_Subps  : Boolean := True);
 147    --  Substidiary procedure to Build_Derived_Type. This procedure is complex
 148    --  because the parent may or may not have a completion, and the derivation
 149    --  may itself be a completion.
 150
 151    procedure Build_Derived_Record_Type
 152      (N            : Node_Id;
 153       Parent_Type  : Entity_Id;
 154       Derived_Type : Entity_Id;
 155       Derive_Subps : Boolean := True);
 156    --  Subsidiary procedure to Build_Derived_Type and
 157    --  Analyze_Private_Extension_Declaration used for tagged and untagged
 158    --  record types. All parameters are as in Build_Derived_Type except that
 159    --  N, in addition to being an N_Full_Type_Declaration node, can also be an
 160    --  N_Private_Extension_Declaration node. See the definition of this routine
 161    --  for much more info. Derive_Subps indicates whether subprograms should
 162    --  be derived from the parent type. The only case where Derive_Subps is
 163    --  False is for an implicit derived full type for a type derived from a
 164    --  private type (see Build_Derived_Type).
 165
 166    function Inherit_Components
 167      (N             : Node_Id;
 168       Parent_Base   : Entity_Id;
 169       Derived_Base  : Entity_Id;
 170       Is_Tagged     : Boolean;
 171       Inherit_Discr : Boolean;
 172       Discs         : Elist_Id)
 173       return          Elist_Id;
 174    --  Called from Build_Derived_Record_Type to inherit the components of
 175    --  Parent_Base (a base type) into the Derived_Base (the derived base type).
 176    --  For more information on derived types and component inheritance please
 177    --  consult the comment above the body of Build_Derived_Record_Type.
 178    --
 179    --  N is the original derived type declaration.
 180    --  Is_Tagged is set if we are dealing with tagged types.
 181    --  If Inherit_Discr is set, Derived_Base inherits its discriminants from
 182    --  Parent_Base, otherwise no discriminants are inherited.
 183    --  Discs gives the list of constraints that apply to Parent_Base in the
 184    --  derived type declaration. If Discs is set to No_Elist, then we have the
 185    --  following situation:
 186    --
 187    --     type Parent (D1..Dn : ..) is [tagged] record ...;
 188    --     type Derived is new Parent [with ...];
 189    --
 190    --  which gets treated as
 191    --
 192    --     type Derived (D1..Dn : ..) is new Parent (D1,..,Dn) [with ...];
 193    --
 194    --  For untagged types the returned value is an association list:
 195    --  (Old_Component => New_Component), where Old_Component is the Entity_Id
 196    --  of a component in Parent_Base and New_Component is the Entity_Id of the
 197    --  corresponding component in Derived_Base. For untagged records, this
 198    --  association list is needed when copying the record declaration for the
 199    --  derived base. In the tagged case the value returned is irrelevant.
 200
 201    procedure Build_Discriminal (Discrim : Entity_Id);
 202    --  Create the discriminal corresponding to discriminant Discrim, that is
 203    --  the parameter corresponding to Discrim to be used in initialization
 204    --  procedures for the type where Discrim is a discriminant. Discriminals
 205    --  are not used during semantic analysis, and are not fully defined
 206    --  entities until expansion. Thus they are not given a scope until
 207    --  initialization procedures are built.
 208
 209    function Build_Discriminant_Constraints
 210      (T           : Entity_Id;
 211       Def         : Node_Id;
 212       Derived_Def : Boolean := False)
 213       return        Elist_Id;
 214    --  Validate discriminant constraints, and return the list of the
 215    --  constraints in order of discriminant declarations. T is the
 216    --  discriminated unconstrained type. Def is the N_Subtype_Indication
 217    --  node where the discriminants constraints for T are specified.
 218    --  Derived_Def is True if we are building the discriminant constraints
 219    --  in a derived type definition of the form "type D (...) is new T (xxx)".
 220    --  In this case T is the parent type and Def is the constraint "(xxx)" on
 221    --  T and this routine sets the Corresponding_Discriminant field of the
 222    --  discriminants in the derived type D to point to the corresponding
 223    --  discriminants in the parent type T.
 224
 225    procedure Build_Discriminated_Subtype
 226      (T           : Entity_Id;
 227       Def_Id      : Entity_Id;
 228       Elist       : Elist_Id;
 229       Related_Nod : Node_Id;
 230       For_Access  : Boolean := False);
 231    --  Subsidiary procedure to Constrain_Discriminated_Type and to
 232    --  Process_Incomplete_Dependents. Given
 233    --
 234    --     T (a possibly discriminated base type)
 235    --     Def_Id (a very partially built subtype for T),
 236    --
 237    --  the call completes Def_Id to be the appropriate E_*_Subtype.
 238    --
 239    --  The Elist is the list of discriminant constraints if any (it is set to
 240    --  No_Elist if T is not a discriminated type, and to an empty list if
 241    --  T has discriminants but there are no discriminant constraints). The
 242    --  Related_Nod is the same as Decl_Node in Create_Constrained_Components.
 243    --  The For_Access says whether or not this subtype is really constraining
 244    --  an access type. That is its sole purpose is the designated type of an
 245    --  access type -- in which case a Private_Subtype Is_For_Access_Subtype
 246    --  is built to avoid freezing T when the access subtype is frozen.
 247
 248    function Build_Scalar_Bound
 249      (Bound : Node_Id;
 250       Par_T : Entity_Id;
 251       Der_T : Entity_Id;
 252       Loc   : Source_Ptr)
 253       return  Node_Id;
 254    --  The bounds of a derived scalar type are conversions of the bounds of
 255    --  the parent type. Optimize the representation if the bounds are literals.
 256    --  Needs a more complete spec--what are the parameters exactly, and what
 257    --  exactly is the returned value, and how is Bound affected???
 258
 259    procedure Build_Underlying_Full_View
 260      (N   : Node_Id;
 261       Typ : Entity_Id;
 262       Par : Entity_Id);
 263    --  If the completion of a private type is itself derived from a private
 264    --  type, or if the full view of a private subtype is itself private, the
 265    --  back-end has no way to compute the actual size of this type. We build
 266    --  an internal subtype declaration of the proper parent type to convey
 267    --  this information. This extra mechanism is needed because a full
 268    --  view cannot itself have a full view (it would get clobbered during
 269    --  view exchanges).
 270
 271    procedure Check_Access_Discriminant_Requires_Limited
 272      (D   : Node_Id;
 273       Loc : Node_Id);
 274    --  Check the restriction that the type to which an access discriminant
 275    --  belongs must be a concurrent type or a descendant of a type with
 276    --  the reserved word 'limited' in its declaration.
 277
 278    procedure Check_Delta_Expression (E : Node_Id);
 279    --  Check that the expression represented by E is suitable for use as
 280    --  a delta expression, i.e. it is of real type and is static.
 281
 282    procedure Check_Digits_Expression (E : Node_Id);
 283    --  Check that the expression represented by E is suitable for use as
 284    --  a digits expression, i.e. it is of integer type, positive and static.
 285
 286    procedure Check_Incomplete (T : Entity_Id);
 287    --  Called to verify that an incomplete type is not used prematurely
 288
 289    procedure Check_Initialization (T : Entity_Id; Exp : Node_Id);
 290    --  Validate the initialization of an object declaration. T is the
 291    --  required type, and Exp is the initialization expression.
 292
 293    procedure Check_Or_Process_Discriminants (N : Node_Id; T : Entity_Id);
 294    --  If T is the full declaration of an incomplete or private type, check
 295    --  the conformance of the discriminants, otherwise process them.
 296
 297    procedure Check_Real_Bound (Bound : Node_Id);
 298    --  Check given bound for being of real type and static. If not, post an
 299    --  appropriate message, and rewrite the bound with the real literal zero.
 300
 301    procedure Constant_Redeclaration
 302      (Id : Entity_Id;
 303       N  : Node_Id;
 304       T  : out Entity_Id);
 305    --  Various checks on legality of full declaration of deferred constant.
 306    --  Id is the entity for the redeclaration, N is the N_Object_Declaration,
 307    --  node. The caller has not yet set any attributes of this entity.
 308
 309    procedure Convert_Scalar_Bounds
 310      (N            : Node_Id;
 311       Parent_Type  : Entity_Id;
 312       Derived_Type : Entity_Id;
 313       Loc          : Source_Ptr);
 314    --  For derived scalar types, convert the bounds in the type definition
 315    --  to the derived type, and complete their analysis.
 316
 317    procedure Copy_Array_Base_Type_Attributes (T1, T2 : Entity_Id);
 318    --  Copies attributes from array base type T2 to array base type T1.
 319    --  Copies only attributes that apply to base types, but not subtypes.
 320
 321    procedure Copy_Array_Subtype_Attributes (T1, T2 : Entity_Id);
 322    --  Copies attributes from array subtype T2 to array subtype T1. Copies
 323    --  attributes that apply to both subtypes and base types.
 324
 325    procedure Create_Constrained_Components
 326      (Subt        : Entity_Id;
 327       Decl_Node   : Node_Id;
 328       Typ         : Entity_Id;
 329       Constraints : Elist_Id);
 330    --  Build the list of entities for a constrained discriminated record
 331    --  subtype. If a component depends on a discriminant, replace its subtype
 332    --  using the discriminant values in the discriminant constraint.
 333    --  Subt is the defining identifier for the subtype whose list of
 334    --  constrained entities we will create. Decl_Node is the type declaration
 335    --  node where we will attach all the itypes created. Typ is the base
 336    --  discriminated type for the subtype Subt. Constraints is the list of
 337    --  discriminant constraints for Typ.
 338
 339    function Constrain_Component_Type
 340      (Compon_Type     : Entity_Id;
 341       Constrained_Typ : Entity_Id;
 342       Related_Node    : Node_Id;
 343       Typ             : Entity_Id;
 344       Constraints     : Elist_Id)
 345       return            Entity_Id;
 346    --  Given a discriminated base type Typ, a list of discriminant constraint
 347    --  Constraints for Typ and the type of a component of Typ, Compon_Type,
 348    --  create and return the type corresponding to Compon_type where all
 349    --  discriminant references are replaced with the corresponding
 350    --  constraint. If no discriminant references occurr in Compon_Typ then
 351    --  return it as is. Constrained_Typ is the final constrained subtype to
 352    --  which the constrained Compon_Type belongs. Related_Node is the node
 353    --  where we will attach all the itypes created.
 354
 355    procedure Constrain_Access
 356      (Def_Id      : in out Entity_Id;
 357       S           : Node_Id;
 358       Related_Nod : Node_Id);
 359    --  Apply a list of constraints to an access type. If Def_Id is empty,
 360    --  it is an anonymous type created for a subtype indication. In that
 361    --  case it is created in the procedure and attached to Related_Nod.
 362
 363    procedure Constrain_Array
 364      (Def_Id      : in out Entity_Id;
 365       SI          : Node_Id;
 366       Related_Nod : Node_Id;
 367       Related_Id  : Entity_Id;
 368       Suffix      : Character);
 369    --  Apply a list of index constraints to an unconstrained array type. The
 370    --  first parameter is the entity for the resulting subtype. A value of
 371    --  Empty for Def_Id indicates that an implicit type must be created, but
 372    --  creation is delayed (and must be done by this procedure) because other
 373    --  subsidiary implicit types must be created first (which is why Def_Id
 374    --  is an in/out parameter). Related_Nod gives the place where this type has
 375    --  to be inserted in the tree. The Related_Id and Suffix parameters are
 376    --  used to build the associated Implicit type name.
 377
 378    procedure Constrain_Concurrent
 379      (Def_Id      : in out Entity_Id;
 380       SI          : Node_Id;
 381       Related_Nod : Node_Id;
 382       Related_Id  : Entity_Id;
 383       Suffix      : Character);
 384    --  Apply list of discriminant constraints to an unconstrained concurrent
 385    --  type.
 386    --
 387    --    SI is the N_Subtype_Indication node containing the constraint and
 388    --    the unconstrained type to constrain.
 389    --
 390    --    Def_Id is the entity for the resulting constrained subtype. A
 391    --    value of Empty for Def_Id indicates that an implicit type must be
 392    --    created, but creation is delayed (and must be done by this procedure)
 393    --    because other subsidiary implicit types must be created first (which
 394    --    is why Def_Id is an in/out parameter).
 395    --
 396    --    Related_Nod gives the place where this type has to be inserted
 397    --    in the tree
 398    --
 399    --  The last two arguments are used to create its external name if needed.
 400
 401    function Constrain_Corresponding_Record
 402      (Prot_Subt   : Entity_Id;
 403       Corr_Rec    : Entity_Id;
 404       Related_Nod : Node_Id;
 405       Related_Id  : Entity_Id)
 406       return Entity_Id;
 407    --  When constraining a protected type or task type with discriminants,
 408    --  constrain the corresponding record with the same discriminant values.
 409
 410    procedure Constrain_Decimal
 411      (Def_Id      : Node_Id;
 412       S           : Node_Id;
 413       Related_Nod : Node_Id);
 414    --  Constrain a decimal fixed point type with a digits constraint and/or a
 415    --  range constraint, and build E_Decimal_Fixed_Point_Subtype entity.
 416
 417    procedure Constrain_Discriminated_Type
 418      (Def_Id      : Entity_Id;
 419       S           : Node_Id;
 420       Related_Nod : Node_Id;
 421       For_Access  : Boolean := False);
 422    --  Process discriminant constraints of composite type. Verify that values
 423    --  have been provided for all discriminants, that the original type is
 424    --  unconstrained, and that the types of the supplied expressions match
 425    --  the discriminant types. The first three parameters are like in routine
 426    --  Constrain_Concurrent. See Build_Discrimated_Subtype for an explanation
 427    --  of For_Access.
 428
 429    procedure Constrain_Enumeration
 430      (Def_Id      : Node_Id;
 431       S           : Node_Id;
 432       Related_Nod : Node_Id);
 433    --  Constrain an enumeration type with a range constraint. This is
 434    --  identical to Constrain_Integer, but for the Ekind of the
 435    --  resulting subtype.
 436
 437    procedure Constrain_Float
 438      (Def_Id      : Node_Id;
 439       S           : Node_Id;
 440       Related_Nod : Node_Id);
 441    --  Constrain a floating point type with either a digits constraint
 442    --  and/or a range constraint, building a E_Floating_Point_Subtype.
 443
 444    procedure Constrain_Index
 445      (Index        : Node_Id;
 446       S            : Node_Id;
 447       Related_Nod  : Node_Id;
 448       Related_Id   : Entity_Id;
 449       Suffix       : Character;
 450       Suffix_Index : Nat);
 451    --  Process an index constraint in a constrained array declaration.
 452    --  The constraint can be a subtype name, or a range with or without
 453    --  an explicit subtype mark. The index is the corresponding index of the
 454    --  unconstrained array. The Related_Id and Suffix parameters are used to
 455    --  build the associated Implicit type name.
 456
 457    procedure Constrain_Integer
 458      (Def_Id      : Node_Id;
 459       S           : Node_Id;
 460       Related_Nod : Node_Id);
 461    --  Build subtype of a signed or modular integer type.
 462
 463    procedure Constrain_Ordinary_Fixed
 464      (Def_Id      : Node_Id;
 465       S           : Node_Id;
 466       Related_Nod : Node_Id);
 467    --  Constrain an ordinary fixed point type with a range constraint, and
 468    --  build an E_Ordinary_Fixed_Point_Subtype entity.
 469
 470    procedure Copy_And_Swap (Privat, Full : Entity_Id);
 471    --  Copy the Privat entity into the entity of its full declaration
 472    --  then swap the two entities in such a manner that the former private
 473    --  type is now seen as a full type.
 474
 475    procedure Copy_Private_To_Full (Priv, Full : Entity_Id);
 476    --  Initialize the full view declaration with the relevant fields
 477    --  from the private view.
 478
 479    procedure Decimal_Fixed_Point_Type_Declaration
 480      (T   : Entity_Id;
 481       Def : Node_Id);
 482    --  Create a new decimal fixed point type, and apply the constraint to
 483    --  obtain a subtype of this new type.
 484
 485    procedure Complete_Private_Subtype
 486      (Priv        : Entity_Id;
 487       Full        : Entity_Id;
 488       Full_Base   : Entity_Id;
 489       Related_Nod : Node_Id);
 490    --  Complete the implicit full view of a private subtype by setting
 491    --  the appropriate semantic fields. If the full view of the parent is
 492    --  a record type, build constrained components of subtype.
 493
 494    procedure Derived_Standard_Character
 495      (N             : Node_Id;
 496       Parent_Type   : Entity_Id;
 497       Derived_Type  : Entity_Id);
 498    --  Subsidiary procedure to Build_Derived_Enumeration_Type which handles
 499    --  derivations from types Standard.Character and Standard.Wide_Character.
 500
 501    procedure Derived_Type_Declaration
 502      (T             : Entity_Id;
 503       N             : Node_Id;
 504       Is_Completion : Boolean);
 505    --  Process a derived type declaration. This routine will invoke
 506    --  Build_Derived_Type to process the actual derived type definition.
 507    --  Parameters N and Is_Completion have the same meaning as in
 508    --  Build_Derived_Type. T is the N_Defining_Identifier for the entity
 509    --  defined in the N_Full_Type_Declaration node N, that is T is the
 510    --  derived type.
 511
 512    function Find_Type_Of_Subtype_Indic (S : Node_Id) return Entity_Id;
 513    --  Given a subtype indication S (which is really an N_Subtype_Indication
 514    --  node or a plain N_Identifier), find the type of the subtype mark.
 515
 516    procedure Enumeration_Type_Declaration (T : Entity_Id; Def : Node_Id);
 517    --  Insert each literal in symbol table, as an overloadable identifier
 518    --  Each enumeration type is mapped into a sequence of integers, and
 519    --  each literal is defined as a constant with integer value. If any
 520    --  of the literals are character literals, the type is a character
 521    --  type, which means that strings are legal aggregates for arrays of
 522    --  components of the type.
 523
 524    procedure Expand_Others_Choice
 525      (Case_Table     : Choice_Table_Type;
 526       Others_Choice  : Node_Id;
 527       Choice_Type    : Entity_Id);
 528    --  In the case of a variant part of a record type that has an OTHERS
 529    --  choice, this procedure expands the OTHERS into the actual choices
 530    --  that it represents. This new list of choice nodes is attached to
 531    --  the OTHERS node via the Others_Discrete_Choices field. The Case_Table
 532    --  contains all choices that have been given explicitly in the variant.
 533
 534    function Find_Type_Of_Object
 535      (Obj_Def     : Node_Id;
 536       Related_Nod : Node_Id)
 537       return        Entity_Id;
 538    --  Get type entity for object referenced by Obj_Def, attaching the
 539    --  implicit types generated to Related_Nod
 540
 541    procedure Floating_Point_Type_Declaration (T : Entity_Id; Def : Node_Id);
 542    --  Create a new float, and apply the constraint to obtain subtype of it
 543
 544    function Has_Range_Constraint (N : Node_Id) return Boolean;
 545    --  Given an N_Subtype_Indication node N, return True if a range constraint
 546    --  is present, either directly, or as part of a digits or delta constraint.
 547    --  In addition, a digits constraint in the decimal case returns True, since
 548    --  it establishes a default range if no explicit range is present.
 549
 550    function Is_Valid_Constraint_Kind
 551      (T_Kind          : Type_Kind;
 552       Constraint_Kind : Node_Kind)
 553       return Boolean;
 554    --  Returns True if it is legal to apply the given kind of constraint
 555    --  to the given kind of type (index constraint to an array type,
 556    --  for example).
 557
 558    procedure Modular_Type_Declaration (T : Entity_Id; Def : Node_Id);
 559    --  Create new modular type. Verify that modulus is in  bounds and is
 560    --  a power of two (implementation restriction).
 561
 562    procedure New_Binary_Operator (Op_Name : Name_Id; Typ : Entity_Id);
 563    --  Create an abbreviated declaration for an operator in order to
 564    --  materialize minimally operators on derived types.
 565
 566    procedure Ordinary_Fixed_Point_Type_Declaration
 567      (T   : Entity_Id;
 568       Def : Node_Id);
 569    --  Create a new ordinary fixed point type, and apply the constraint
 570    --  to obtain subtype of it.
 571
 572    procedure Prepare_Private_Subtype_Completion
 573      (Id          : Entity_Id;
 574       Related_Nod : Node_Id);
 575    --  Id is a subtype of some private type. Creates the full declaration
 576    --  associated with Id whenever possible, i.e. when the full declaration
 577    --  of the base type is already known. Records each subtype into
 578    --  Private_Dependents of the base type.
 579
 580    procedure Process_Incomplete_Dependents
 581      (N      : Node_Id;
 582       Full_T : Entity_Id;
 583       Inc_T  : Entity_Id);
 584    --  Process all entities that depend on an incomplete type. There include
 585    --  subtypes, subprogram types that mention the incomplete type in their
 586    --  profiles, and subprogram with access parameters that designate the
 587    --  incomplete type.
 588
 589    --  Inc_T is the defining identifier of an incomplete type declaration, its
 590    --  Ekind is E_Incomplete_Type.
 591    --
 592    --    N is the corresponding N_Full_Type_Declaration for Inc_T.
 593    --
 594    --    Full_T is N's defining identifier.
 595    --
 596    --  Subtypes of incomplete types with discriminants are completed when the
 597    --  parent type is. This is simpler than private subtypes, because they can
 598    --  only appear in the same scope, and there is no need to exchange views.
 599    --  Similarly, access_to_subprogram types may have a parameter or a return
 600    --  type that is an incomplete type, and that must be replaced with the
 601    --  full type.
 602
 603    --  If the full type is tagged, subprogram with access parameters that
 604    --  designated the incomplete may be primitive operations of the full type,
 605    --  and have to be processed accordingly.
 606
 607    procedure Process_Real_Range_Specification (Def : Node_Id);
 608    --  Given the type definition for a real type, this procedure processes
 609    --  and checks the real range specification of this type definition if
 610    --  one is present. If errors are found, error messages are posted, and
 611    --  the Real_Range_Specification of Def is reset to Empty.
 612
 613    procedure Record_Type_Declaration (T : Entity_Id; N : Node_Id);
 614    --  Process a record type declaration (for both untagged and tagged
 615    --  records). Parameters T and N are exactly like in procedure
 616    --  Derived_Type_Declaration, except that no flag Is_Completion is
 617    --  needed for this routine.
 618
 619    procedure Record_Type_Definition (Def : Node_Id; T : Entity_Id);
 620    --  This routine is used to process the actual record type definition
 621    --  (both for untagged and tagged records). Def is a record type
 622    --  definition node. This procedure analyzes the components in this
 623    --  record type definition. T is the entity for the enclosing record
 624    --  type. It is provided so that its Has_Task flag can be set if any of
 625    --  the component have Has_Task set.
 626
 627    procedure Set_Fixed_Range
 628      (E   : Entity_Id;
 629       Loc : Source_Ptr;
 630       Lo  : Ureal;
 631       Hi  : Ureal);
 632    --  Build a range node with the given bounds and set it as the Scalar_Range
 633    --  of the given fixed-point type entity. Loc is the source location used
 634    --  for the constructed range. See body for further details.
 635
 636    procedure Set_Scalar_Range_For_Subtype
 637      (Def_Id      : Entity_Id;
 638       R           : Node_Id;
 639       Subt        : Entity_Id;
 640       Related_Nod : Node_Id);
 641    --  This routine is used to set the scalar range field for a subtype
 642    --  given Def_Id, the entity for the subtype, and R, the range expression
 643    --  for the scalar range. Subt provides the parent subtype to be used
 644    --  to analyze, resolve, and check the given range.
 645
 646    procedure Signed_Integer_Type_Declaration (T : Entity_Id; Def : Node_Id);
 647    --  Create a new signed integer entity, and apply the constraint to obtain
 648    --  the required first named subtype of this type.
 649
 650    -----------------------
 651    -- Access_Definition --
 652    -----------------------
 653
 654    function Access_Definition
 655      (Related_Nod : Node_Id;
 656       N           : Node_Id)
 657       return        Entity_Id
 658    is
 659       Anon_Type : constant Entity_Id :=
 660                     Create_Itype (E_Anonymous_Access_Type, Related_Nod,
 661                                   Scope_Id => Scope (Current_Scope));
 662       Desig_Type : Entity_Id;
 663
 664    begin
 665       if Is_Entry (Current_Scope)
 666         and then Is_Task_Type (Etype (Scope (Current_Scope)))
 667       then
 668          Error_Msg_N ("task entries cannot have access parameters", N);
 669       end if;
 670
 671       Find_Type (Subtype_Mark (N));
 672       Desig_Type := Entity (Subtype_Mark (N));
 673
 674       Set_Directly_Designated_Type
 675                              (Anon_Type, Desig_Type);
 676       Set_Etype              (Anon_Type, Anon_Type);
 677       Init_Size_Align        (Anon_Type);
 678       Set_Depends_On_Private (Anon_Type, Has_Private_Component (Anon_Type));
 679
 680       --  The anonymous access type is as public as the discriminated type or
 681       --  subprogram that defines it. It is imported (for back-end purposes)
 682       --  if the designated type is.
 683
 684       Set_Is_Public          (Anon_Type, Is_Public (Scope (Anon_Type)));
 685       Set_From_With_Type     (Anon_Type, From_With_Type (Desig_Type));
 686
 687       --  The context is either a subprogram declaration or an access
 688       --  discriminant, in a private or a full type declaration. In
 689       --  the case of a subprogram, If the designated type is incomplete,
 690       --  the operation will be a primitive operation of the full type, to
 691       --  be updated subsequently.
 692
 693       if Ekind (Desig_Type) = E_Incomplete_Type
 694         and then Is_Overloadable (Current_Scope)
 695       then
 696          Append_Elmt (Current_Scope, Private_Dependents (Desig_Type));
 697          Set_Has_Delayed_Freeze (Current_Scope);
 698       end if;
 699
 700       return Anon_Type;
 701    end Access_Definition;
 702
 703    -----------------------------------
 704    -- Access_Subprogram_Declaration --
 705    -----------------------------------
 706
 707    procedure Access_Subprogram_Declaration
 708      (T_Name : Entity_Id;
 709       T_Def  : Node_Id)
 710    is
 711       Formals : constant List_Id   := Parameter_Specifications (T_Def);
 712       Formal  : Entity_Id;
 713       Desig_Type : constant Entity_Id :=
 714                    Create_Itype (E_Subprogram_Type, Parent (T_Def));
 715
 716    begin
 717       if Nkind (T_Def) = N_Access_Function_Definition then
 718          Analyze (Subtype_Mark (T_Def));
 719          Set_Etype (Desig_Type, Entity (Subtype_Mark (T_Def)));
 720       else
 721          Set_Etype (Desig_Type, Standard_Void_Type);
 722       end if;
 723
 724       if Present (Formals) then
 725          New_Scope (Desig_Type);
 726          Process_Formals (Desig_Type, Formals, Parent (T_Def));
 727
 728          --  A bit of a kludge here, End_Scope requires that the parent
 729          --  pointer be set to something reasonable, but Itypes don't
 730          --  have parent pointers. So we set it and then unset it ???
 731          --  If and when Itypes have proper parent pointers to their
 732          --  declarations, this kludge can be removed.
 733
 734          Set_Parent (Desig_Type, T_Name);
 735          End_Scope;
 736          Set_Parent (Desig_Type, Empty);
 737       end if;
 738
 739       --  The return type and/or any parameter type may be incomplete. Mark
 740       --  the subprogram_type as depending on the incomplete type, so that
 741       --  it can be updated when the full type declaration is seen.
 742
 743       if Present (Formals) then
 744          Formal := First_Formal (Desig_Type);
 745
 746          while Present (Formal) loop
 747
 748             if Ekind (Formal) /= E_In_Parameter
 749               and then Nkind (T_Def) = N_Access_Function_Definition
 750             then
 751                Error_Msg_N ("functions can only have IN parameters", Formal);
 752             end if;
 753
 754             if Ekind (Etype (Formal)) = E_Incomplete_Type then
 755                Append_Elmt (Desig_Type, Private_Dependents (Etype (Formal)));
 756                Set_Has_Delayed_Freeze (Desig_Type);
 757             end if;
 758
 759             Next_Formal (Formal);
 760          end loop;
 761       end if;
 762
 763       if Ekind (Etype (Desig_Type)) = E_Incomplete_Type
 764         and then not Has_Delayed_Freeze (Desig_Type)
 765       then
 766          Append_Elmt (Desig_Type, Private_Dependents (Etype (Desig_Type)));
 767          Set_Has_Delayed_Freeze (Desig_Type);
 768       end if;
 769
 770       Check_Delayed_Subprogram (Desig_Type);
 771
 772       if Protected_Present (T_Def) then
 773          Set_Ekind (T_Name, E_Access_Protected_Subprogram_Type);
 774          Set_Convention (Desig_Type, Convention_Protected);
 775       else
 776          Set_Ekind (T_Name, E_Access_Subprogram_Type);
 777       end if;
 778
 779       Set_Etype                    (T_Name, T_Name);
 780       Init_Size_Align              (T_Name);
 781       Set_Directly_Designated_Type (T_Name, Desig_Type);
 782
 783       Check_Restriction (No_Access_Subprograms, T_Def);
 784    end Access_Subprogram_Declaration;
 785
 786    ----------------------------
 787    -- Access_Type_Declaration --
 788    ----------------------------
 789
 790    procedure Access_Type_Declaration (T : Entity_Id; Def : Node_Id) is
 791       S : constant Node_Id := Subtype_Indication (Def);
 792       P : constant Node_Id := Parent (Def);
 793
 794    begin
 795       --  Check for permissible use of incomplete type
 796
 797       if Nkind (S) /= N_Subtype_Indication then
 798          Analyze (S);
 799
 800          if Ekind (Root_Type (Entity (S))) = E_Incomplete_Type then
 801             Set_Directly_Designated_Type (T, Entity (S));
 802          else
 803             Set_Directly_Designated_Type (T,
 804               Process_Subtype (S, P, T, 'P'));
 805          end if;
 806
 807       else
 808          Set_Directly_Designated_Type (T,
 809            Process_Subtype (S, P, T, 'P'));
 810       end if;
 811
 812       if All_Present (Def) or Constant_Present (Def) then
 813          Set_Ekind (T, E_General_Access_Type);
 814       else
 815          Set_Ekind (T, E_Access_Type);
 816       end if;
 817
 818       if Base_Type (Designated_Type (T)) = T then
 819          Error_Msg_N ("access type cannot designate itself", S);
 820       end if;
 821
 822       Set_Etype              (T, T);
 823
 824       --  If the type has appeared already in a with_type clause, it is
 825       --  frozen and the pointer size is already set. Else, initialize.
 826
 827       if not From_With_Type (T) then
 828          Init_Size_Align (T);
 829       end if;
 830
 831       Set_Is_Access_Constant (T, Constant_Present (Def));
 832
 833       --  If designated type is an imported tagged type, indicate that the
 834       --  access type is also imported, and therefore restricted in its use.
 835       --  The access type may already be imported, so keep setting otherwise.
 836
 837       if From_With_Type (Designated_Type (T)) then
 838          Set_From_With_Type (T);
 839       end if;
 840
 841       --  Note that Has_Task is always false, since the access type itself
 842       --  is not a task type. See Einfo for more description on this point.
 843       --  Exactly the same consideration applies to Has_Controlled_Component.
 844
 845       Set_Has_Task (T, False);
 846       Set_Has_Controlled_Component (T, False);
 847    end Access_Type_Declaration;
 848
 849    -----------------------------------
 850    -- Analyze_Component_Declaration --
 851    -----------------------------------
 852
 853    procedure Analyze_Component_Declaration (N : Node_Id) is
 854       Id : constant Entity_Id := Defining_Identifier (N);
 855       T  : Entity_Id;
 856       P  : Entity_Id;
 857
 858    begin
 859       Generate_Definition (Id);
 860       Enter_Name (Id);
 861       T := Find_Type_Of_Object (Subtype_Indication (N), N);
 862
 863       --  If the component declaration includes a default expression, then we
 864       --  check that the component is not of a limited type (RM 3.7(5)),
 865       --  and do the special preanalysis of the expression (see section on
 866       --  "Handling of Default Expressions" in the spec of package Sem).
 867
 868       if Present (Expression (N)) then
 869          Analyze_Default_Expression (Expression (N), T);
 870          Check_Initialization (T, Expression (N));
 871       end if;
 872
 873       --  The parent type may be a private view with unknown discriminants,
 874       --  and thus unconstrained. Regular components must be constrained.
 875
 876       if Is_Indefinite_Subtype (T) and then Chars (Id) /= Name_uParent then
 877          Error_Msg_N
 878            ("unconstrained subtype in component declaration",
 879             Subtype_Indication (N));
 880
 881       --  Components cannot be abstract, except for the special case of
 882       --  the _Parent field (case of extending an abstract tagged type)
 883
 884       elsif Is_Abstract (T) and then Chars (Id) /= Name_uParent then
 885          Error_Msg_N ("type of a component cannot be abstract", N);
 886       end if;
 887
 888       Set_Etype (Id, T);
 889       Set_Is_Aliased (Id, Aliased_Present (N));
 890
 891       --  If the this component is private (or depends on a private type),
 892       --  flag the record type to indicate that some operations are not
 893       --  available.
 894
 895       P := Private_Component (T);
 896
 897       if Present (P) then
 898          --  Check for circular definitions.
 899
 900          if P = Any_Type then
 901             Set_Etype (Id, Any_Type);
 902
 903          --  There is a gap in the visibility of operations only if the
 904          --  component type is not defined in the scope of the record type.
 905
 906          elsif Scope (P) = Scope (Current_Scope) then
 907             null;
 908
 909          elsif Is_Limited_Type (P) then
 910             Set_Is_Limited_Composite (Current_Scope);
 911
 912          else
 913             Set_Is_Private_Composite (Current_Scope);
 914          end if;
 915       end if;
 916
 917       if P /= Any_Type
 918         and then Is_Limited_Type (T)
 919         and then Chars (Id) /= Name_uParent
 920         and then Is_Tagged_Type (Current_Scope)
 921       then
 922          if Is_Derived_Type (Current_Scope)
 923            and then not Is_Limited_Record (Root_Type (Current_Scope))
 924          then
 925             Error_Msg_N
 926               ("extension of nonlimited type cannot have limited components",
 927                N);
 928             Set_Etype (Id, Any_Type);
 929             Set_Is_Limited_Composite (Current_Scope, False);
 930
 931          elsif not Is_Derived_Type (Current_Scope)
 932            and then not Is_Limited_Record (Current_Scope)
 933          then
 934             Error_Msg_N ("nonlimited type cannot have limited components", N);
 935             Set_Etype (Id, Any_Type);
 936             Set_Is_Limited_Composite (Current_Scope, False);
 937          end if;
 938       end if;
 939
 940       Set_Original_Record_Component (Id, Id);
 941    end Analyze_Component_Declaration;
 942
 943    --------------------------
 944    -- Analyze_Declarations --
 945    --------------------------
 946
 947    procedure Analyze_Declarations (L : List_Id) is
 948       D           : Node_Id;
 949       Next_Node   : Node_Id;
 950       Freeze_From : Entity_Id := Empty;
 951
 952       procedure Adjust_D;
 953       --  Adjust D not to include implicit label declarations, since these
 954       --  have strange Sloc values that result in elaboration check problems.
 955
 956       procedure Adjust_D is
 957       begin
 958          while Present (Prev (D))
 959            and then Nkind (D) = N_Implicit_Label_Declaration
 960          loop
 961             Prev (D);
 962          end loop;
 963       end Adjust_D;
 964
 965    --  Start of processing for Analyze_Declarations
 966
 967    begin
 968       D := First (L);
 969       while Present (D) loop
 970
 971          --  Complete analysis of declaration
 972
 973          Analyze (D);
 974          Next_Node := Next (D);
 975
 976          if No (Freeze_From) then
 977             Freeze_From := First_Entity (Current_Scope);
 978          end if;
 979
 980          --  At the end of a declarative part, freeze remaining entities
 981          --  declared in it. The end of the visible declarations of a
 982          --  package specification is not the end of a declarative part
 983          --  if private declarations are present. The end of a package
 984          --  declaration is a freezing point only if it a library package.
 985          --  A task definition or protected type definition is not a freeze
 986          --  point either. Finally, we do not freeze entities in generic
 987          --  scopes, because there is no code generated for them and freeze
 988          --  nodes will be generated for the instance.
 989
 990          --  The end of a package instantiation is not a freeze point, but
 991          --  for now we make it one, because the generic body is inserted
 992          --  (currently) immediately after. Generic instantiations will not
 993          --  be a freeze point once delayed freezing of bodies is implemented.
 994          --  (This is needed in any case for early instantiations ???).
 995
 996          if No (Next_Node) then
 997             if Nkind (Parent (L)) = N_Component_List
 998               or else Nkind (Parent (L)) = N_Task_Definition
 999               or else Nkind (Parent (L)) = N_Protected_Definition
1000             then
1001                null;
1002
1003             elsif Nkind (Parent (L)) /= N_Package_Specification then
1004
1005                if Nkind (Parent (L)) = N_Package_Body then
1006                   Freeze_From := First_Entity (Current_Scope);
1007                end if;
1008
1009                Adjust_D;
1010                Freeze_All (Freeze_From, D);
1011                Freeze_From := Last_Entity (Current_Scope);
1012
1013             elsif Scope (Current_Scope) /= Standard_Standard
1014               and then not Is_Child_Unit (Current_Scope)
1015               and then No (Generic_Parent (Parent (L)))
1016             then
1017                null;
1018
1019             elsif L /= Visible_Declarations (Parent (L))
1020                or else No (Private_Declarations (Parent (L)))
1021                or else Is_Empty_List (Private_Declarations (Parent (L)))
1022             then
1023                Adjust_D;
1024                Freeze_All (Freeze_From, D);
1025                Freeze_From := Last_Entity (Current_Scope);
1026             end if;
1027
1028          --  If next node is a body then freeze all types before the body.
1029          --  An exception occurs for expander generated bodies, which can
1030          --  be recognized by their already being analyzed. The expander
1031          --  ensures that all types needed by these bodies have been frozen
1032          --  but it is not necessary to freeze all types (and would be wrong
1033          --  since it would not correspond to an RM defined freeze point).
1034
1035          elsif not Analyzed (Next_Node)
1036            and then (Nkind (Next_Node) = N_Subprogram_Body
1037              or else Nkind (Next_Node) = N_Entry_Body
1038              or else Nkind (Next_Node) = N_Package_Body
1039              or else Nkind (Next_Node) = N_Protected_Body
1040              or else Nkind (Next_Node) = N_Task_Body
1041              or else Nkind (Next_Node) in N_Body_Stub)
1042          then
1043             Adjust_D;
1044             Freeze_All (Freeze_From, D);
1045             Freeze_From := Last_Entity (Current_Scope);
1046          end if;
1047
1048          D := Next_Node;
1049       end loop;
1050
1051    end Analyze_Declarations;
1052
1053    --------------------------------
1054    -- Analyze_Default_Expression --
1055    --------------------------------
1056
1057    procedure Analyze_Default_Expression (N : Node_Id; T : Entity_Id) is
1058       Save_In_Default_Expression : constant Boolean := In_Default_Expression;
1059
1060    begin
1061       In_Default_Expression := True;
1062       Pre_Analyze_And_Resolve (N, T);
1063       In_Default_Expression := Save_In_Default_Expression;
1064    end Analyze_Default_Expression;
1065
1066    ----------------------------------
1067    -- Analyze_Incomplete_Type_Decl --
1068    ----------------------------------
1069
1070    procedure Analyze_Incomplete_Type_Decl (N : Node_Id) is
1071       F : constant Boolean := Is_Pure (Current_Scope);
1072       T : Entity_Id;
1073
1074    begin
1075       Generate_Definition (Defining_Identifier (N));
1076
1077       --  Process an incomplete declaration. The identifier must not have been
1078       --  declared already in the scope. However, an incomplete declaration may
1079       --  appear in the private part of a package, for a private type that has
1080       --  already been declared.
1081
1082       --  In this case, the discriminants (if any) must match.
1083
1084       T := Find_Type_Name (N);
1085
1086       Set_Ekind (T, E_Incomplete_Type);
1087       Init_Size_Align (T);
1088       Set_Is_First_Subtype (T, True);
1089       Set_Etype (T, T);
1090       New_Scope (T);
1091
1092       Set_Girder_Constraint (T, No_Elist);
1093
1094       if Present (Discriminant_Specifications (N)) then
1095          Process_Discriminants (N);
1096       end if;
1097
1098       End_Scope;
1099
1100       --  If the type has discriminants, non-trivial subtypes may be
1101       --  be declared before the full view of the type. The full views
1102       --  of those subtypes will be built after the full view of the type.
1103
1104       Set_Private_Dependents (T, New_Elmt_List);
1105       Set_Is_Pure (T, F);
1106    end Analyze_Incomplete_Type_Decl;
1107
1108    -----------------------------
1109    -- Analyze_Itype_Reference --
1110    -----------------------------
1111
1112    --  Nothing to do. This node is placed in the tree only for the benefit
1113    --  of Gigi processing, and has no effect on the semantic processing.
1114
1115    procedure Analyze_Itype_Reference (N : Node_Id) is
1116    begin
1117       pragma Assert (Is_Itype (Itype (N)));
1118       null;
1119    end Analyze_Itype_Reference;
1120
1121    --------------------------------
1122    -- Analyze_Number_Declaration --
1123    --------------------------------
1124
1125    procedure Analyze_Number_Declaration (N : Node_Id) is
1126       Id    : constant Entity_Id := Defining_Identifier (N);
1127       E     : constant Node_Id   := Expression (N);
1128       T     : Entity_Id;
1129       Index : Interp_Index;
1130       It    : Interp;
1131
1132    begin
1133       Generate_Definition (Id);
1134       Enter_Name (Id);
1135
1136       --  This is an optimization of a common case of an integer literal
1137
1138       if Nkind (E) = N_Integer_Literal then
1139          Set_Is_Static_Expression (E, True);
1140          Set_Etype                (E, Universal_Integer);
1141
1142          Set_Etype     (Id, Universal_Integer);
1143          Set_Ekind     (Id, E_Named_Integer);
1144          Set_Is_Frozen (Id, True);
1145          return;
1146       end if;
1147
1148       Set_Is_Pure (Id, Is_Pure (Current_Scope));
1149
1150       --  Process expression, replacing error by integer zero, to avoid
1151       --  cascaded errors or aborts further along in the processing
1152
1153       --  Replace Error by integer zero, which seems least likely to
1154       --  cause cascaded errors.
1155
1156       if E = Error then
1157          Rewrite (E, Make_Integer_Literal (Sloc (E), Uint_0));
1158          Set_Error_Posted (E);
1159       end if;
1160
1161       Analyze (E);
1162
1163       --  Verify that the expression is static and numeric. If
1164       --  the expression is overloaded, we apply the preference
1165       --  rule that favors root numeric types.
1166
1167       if not Is_Overloaded (E) then
1168          T := Etype (E);
1169
1170       else
1171          T := Any_Type;
1172          Get_First_Interp (E, Index, It);
1173
1174          while Present (It.Typ) loop
1175             if (Is_Integer_Type (It.Typ)
1176                  or else Is_Real_Type (It.Typ))
1177               and then (Scope (Base_Type (It.Typ))) = Standard_Standard
1178             then
1179                if T = Any_Type then
1180                   T := It.Typ;
1181
1182                elsif It.Typ = Universal_Real
1183                  or else It.Typ = Universal_Integer
1184                then
1185                   --  Choose universal interpretation over any other.
1186
1187                   T := It.Typ;
1188                   exit;
1189                end if;
1190             end if;
1191
1192             Get_Next_Interp (Index, It);
1193          end loop;
1194       end if;
1195
1196       if Is_Integer_Type (T)  then
1197          Resolve (E, T);
1198          Set_Etype (Id, Universal_Integer);
1199          Set_Ekind (Id, E_Named_Integer);
1200
1201       elsif Is_Real_Type (T) then
1202
1203          --  Because the real value is converted to universal_real, this
1204          --  is a legal context for a universal fixed expression.
1205
1206          if T = Universal_Fixed then
1207             declare
1208                Loc  : constant Source_Ptr := Sloc (N);
1209                Conv : constant Node_Id := Make_Type_Conversion (Loc,
1210                         Subtype_Mark =>
1211                           New_Occurrence_Of (Universal_Real, Loc),
1212                         Expression => Relocate_Node (E));
1213
1214             begin
1215                Rewrite (E, Conv);
1216                Analyze (E);
1217             end;
1218
1219          elsif T = Any_Fixed then
1220             Error_Msg_N ("illegal context for mixed mode operation", E);
1221
1222             --  Expression is of the form : universal_fixed * integer.
1223             --  Try to resolve as universal_real.
1224
1225             T := Universal_Real;
1226             Set_Etype (E, T);
1227          end if;
1228
1229          Resolve (E, T);
1230          Set_Etype (Id, Universal_Real);
1231          Set_Ekind (Id, E_Named_Real);
1232
1233       else
1234          Wrong_Type (E, Any_Numeric);
1235          Resolve (E, T);
1236          Set_Etype               (Id, T);
1237          Set_Ekind               (Id, E_Constant);
1238          Set_Not_Source_Assigned (Id, True);
1239          Set_Is_True_Constant    (Id, True);
1240          return;
1241       end if;
1242
1243       if Nkind (E) = N_Integer_Literal
1244         or else Nkind (E) = N_Real_Literal
1245       then
1246          Set_Etype (E, Etype (Id));
1247       end if;
1248
1249       if not Is_OK_Static_Expression (E) then
1250          Error_Msg_N ("non-static expression used in number declaration", E);
1251          Rewrite (E, Make_Integer_Literal (Sloc (N), 1));
1252          Set_Etype (E, Any_Type);
1253       end if;
1254
1255    end Analyze_Number_Declaration;
1256
1257    --------------------------------
1258    -- Analyze_Object_Declaration --
1259    --------------------------------
1260
1261    procedure Analyze_Object_Declaration (N : Node_Id) is
1262       Loc   : constant Source_Ptr := Sloc (N);
1263       Id    : constant Entity_Id  := Defining_Identifier (N);
1264       T     : Entity_Id;
1265       Act_T : Entity_Id;
1266
1267       E : Node_Id := Expression (N);
1268       --  E is set to Expression (N) throughout this routine. When
1269       --  Expression (N) is modified, E is changed accordingly.
1270
1271       Prev_Entity : Entity_Id := Empty;
1272
1273       function Build_Default_Subtype return Entity_Id;
1274       --  If the object is limited or aliased, and if the type is unconstrained
1275       --  and there is no expression, the discriminants cannot be modified and
1276       --  the subtype of the object is constrained by the defaults, so it is
1277       --  worthile building the corresponding subtype.
1278
1279       ---------------------------
1280       -- Build_Default_Subtype --
1281       ---------------------------
1282
1283       function Build_Default_Subtype return Entity_Id is
1284          Act         : Entity_Id;
1285          Constraints : List_Id := New_List;
1286          Decl        : Node_Id;
1287          Disc        : Entity_Id;
1288
1289       begin
1290          Disc  := First_Discriminant (T);
1291
1292          if No (Discriminant_Default_Value (Disc)) then
1293             return T;   --   previous error.
1294          end if;
1295
1296          Act := Make_Defining_Identifier (Loc, New_Internal_Name ('S'));
1297          while Present (Disc) loop
1298             Append (
1299               New_Copy_Tree (
1300                 Discriminant_Default_Value (Disc)), Constraints);
1301             Next_Discriminant (Disc);
1302          end loop;
1303
1304          Decl :=
1305            Make_Subtype_Declaration (Loc,
1306              Defining_Identifier => Act,
1307              Subtype_Indication =>
1308                Make_Subtype_Indication (Loc,
1309                  Subtype_Mark => New_Occurrence_Of (T, Loc),
1310                  Constraint =>
1311                    Make_Index_Or_Discriminant_Constraint
1312                      (Loc, Constraints)));
1313
1314          Insert_Before (N, Decl);
1315          Analyze (Decl);
1316          return Act;
1317       end Build_Default_Subtype;
1318
1319    --  Start of processing for Analyze_Object_Declaration
1320
1321    begin
1322       --  There are three kinds of implicit types generated by an
1323       --  object declaration:
1324
1325       --   1. Those for generated by the original Object Definition
1326
1327       --   2. Those generated by the Expression
1328
1329       --   3. Those used to constrained the Object Definition with the
1330       --       expression constraints when it is unconstrained
1331
1332       --  They must be generated in this order to avoid order of elaboration
1333       --  issues. Thus the first step (after entering the name) is to analyze
1334       --  the object definition.
1335
1336       if Constant_Present (N) then
1337          Prev_Entity := Current_Entity_In_Scope (Id);
1338
1339          --  If homograph is an implicit subprogram, it is overridden by the
1340          --  current declaration.
1341
1342          if Present (Prev_Entity)
1343            and then Is_Overloadable (Prev_Entity)
1344            and then Is_Inherited_Operation (Prev_Entity)
1345          then
1346             Prev_Entity := Empty;
1347          end if;
1348       end if;
1349
1350       if Present (Prev_Entity) then
1351          Constant_Redeclaration (Id, N, T);
1352
1353          Generate_Reference (Prev_Entity, Id, 'c');
1354
1355          --  If in main unit, set as referenced, so we do not complain about
1356          --  the full declaration being an unreferenced entity.
1357
1358          if In_Extended_Main_Source_Unit (Id) then
1359             Set_Referenced (Id);
1360          end if;
1361
1362          if Error_Posted (N) then
1363             --  Type mismatch or illegal redeclaration, Do not analyze
1364             --  expression to avoid cascaded errors.
1365
1366             T := Find_Type_Of_Object (Object_Definition (N), N);
1367             Set_Etype (Id, T);
1368             Set_Ekind (Id, E_Variable);
1369             return;
1370          end if;
1371
1372       --  In the normal case, enter identifier at the start to catch
1373       --  premature usage in the initialization expression.
1374
1375       else
1376          Generate_Definition (Id);
1377          Enter_Name (Id);
1378
1379          T := Find_Type_Of_Object (Object_Definition (N), N);
1380
1381          if Error_Posted (Id) then
1382             Set_Etype (Id, T);
1383             Set_Ekind (Id, E_Variable);
1384             return;
1385          end if;
1386       end if;
1387
1388       Set_Is_Pure (Id, Is_Pure (Current_Scope));
1389
1390       --  If deferred constant, make sure context is appropriate. We detect
1391       --  a deferred constant as a constant declaration with no expression.
1392
1393       if Constant_Present (N)
1394         and then No (E)
1395       then
1396          if not Is_Package (Current_Scope)
1397            or else In_Private_Part (Current_Scope)
1398          then
1399             Error_Msg_N
1400               ("invalid context for deferred constant declaration", N);
1401             Set_Constant_Present (N, False);
1402
1403          --  In Ada 83, deferred constant must be of private type
1404
1405          elsif not Is_Private_Type (T) then
1406             if Ada_83 and then Comes_From_Source (N) then
1407                Error_Msg_N
1408                  ("(Ada 83) deferred constant must be private type", N);
1409             end if;
1410          end if;
1411
1412       --  If not a deferred constant, then object declaration freezes its type
1413
1414       else
1415          Check_Fully_Declared (T, N);
1416          Freeze_Before (N, T);
1417       end if;
1418
1419       --  If the object was created by a constrained array definition, then
1420       --  set the link in both the anonymous base type and anonymous subtype
1421       --  that are built to represent the array type to point to the object.
1422
1423       if Nkind (Object_Definition (Declaration_Node (Id))) =
1424                         N_Constrained_Array_Definition
1425       then
1426          Set_Related_Array_Object (T, Id);
1427          Set_Related_Array_Object (Base_Type (T), Id);
1428       end if;
1429
1430       --  Special checks for protected objects not at library level
1431
1432       if Is_Protected_Type (T)
1433         and then not Is_Library_Level_Entity (Id)
1434       then
1435          Check_Restriction (No_Local_Protected_Objects, Id);
1436
1437          --  Protected objects with interrupt handlers must be at library level
1438
1439          if Has_Interrupt_Handler (T) then
1440             Error_Msg_N
1441               ("interrupt object can only be declared at library level", Id);
1442          end if;
1443       end if;
1444
1445       --  The actual subtype of the object is the nominal subtype, unless
1446       --  the nominal one is unconstrained and obtained from the expression.
1447
1448       Act_T := T;
1449
1450       --  Process initialization expression if present and not in error
1451
1452       if Present (E) and then E /= Error then
1453          Analyze (E);
1454
1455          if not Assignment_OK (N) then
1456             Check_Initialization (T, E);
1457          end if;
1458
1459          Resolve (E, T);
1460
1461          --  Check for library level object that will require implicit
1462          --  heap allocation.
1463
1464          if Is_Array_Type (T)
1465            and then not Size_Known_At_Compile_Time (T)
1466            and then Is_Library_Level_Entity (Id)
1467          then
1468             --  String literals are always allowed
1469
1470             if T = Standard_String
1471               and then Nkind (E) = N_String_Literal
1472             then
1473                null;
1474
1475             --  Otherwise we do not allow this since it may cause an
1476             --  implicit heap allocation.
1477
1478             else
1479                Check_Restriction
1480                  (No_Implicit_Heap_Allocations, Object_Definition (N));
1481             end if;
1482          end if;
1483
1484          --  Check incorrect use of dynamically tagged expressions. Note
1485          --  the use of Is_Tagged_Type (T) which seems redundant but is in
1486          --  fact important to avoid spurious errors due to expanded code
1487          --  for dispatching functions over an anonymous access type
1488
1489          if (Is_Class_Wide_Type (Etype (E)) or else Is_Dynamically_Tagged (E))
1490            and then Is_Tagged_Type (T)
1491            and then not Is_Class_Wide_Type (T)
1492          then
1493             Error_Msg_N ("dynamically tagged expression not allowed!", E);
1494          end if;
1495
1496          Apply_Scalar_Range_Check (E, T);
1497          Apply_Static_Length_Check (E, T);
1498       end if;
1499
1500       --  Abstract type is never permitted for a variable or constant.
1501       --  Note: we inhibit this check for objects that do not come from
1502       --  source because there is at least one case (the expansion of
1503       --  x'class'input where x is abstract) where we legitimately
1504       --  generate an abstract object.
1505
1506       if Is_Abstract (T) and then Comes_From_Source (N) then
1507          Error_Msg_N ("type of object cannot be abstract",
1508            Object_Definition (N));
1509          if Is_CPP_Class (T) then
1510             Error_Msg_NE ("\} may need a cpp_constructor",
1511               Object_Definition (N), T);
1512          end if;
1513
1514       --  Case of unconstrained type
1515
1516       elsif Is_Indefinite_Subtype (T) then
1517
1518          --  Nothing to do in deferred constant case
1519
1520          if Constant_Present (N) and then No (E) then
1521             null;
1522
1523          --  Case of no initialization present
1524
1525          elsif No (E) then
1526             if No_Initialization (N) then
1527                null;
1528
1529             elsif Is_Class_Wide_Type (T) then
1530                Error_Msg_N
1531                  ("initialization required in class-wide declaration ", N);
1532
1533             else
1534                Error_Msg_N
1535                  ("unconstrained subtype not allowed (need initialization)",
1536                   Object_Definition (N));
1537             end if;
1538
1539          --  Case of initialization present but in error. Set initial
1540          --  expression as absent (but do not make above complaints)
1541
1542          elsif E = Error then
1543             Set_Expression (N, Empty);
1544             E := Empty;
1545
1546          --  Case of initialization present
1547
1548          else
1549             --  Not allowed in Ada 83
1550
1551             if not Constant_Present (N) then
1552                if Ada_83
1553                  and then Comes_From_Source (Object_Definition (N))
1554                then
1555                   Error_Msg_N
1556                     ("(Ada 83) unconstrained variable not allowed",
1557                      Object_Definition (N));
1558                end if;
1559             end if;
1560
1561             --  Now we constrain the variable from the initializing expression
1562
1563             --  If the expression is an aggregate, it has been expanded into
1564             --  individual assignments. Retrieve the actual type from the
1565             --  expanded construct.
1566
1567             if Is_Array_Type (T)
1568               and then No_Initialization (N)
1569               and then Nkind (Original_Node (E)) = N_Aggregate
1570             then
1571                Act_T := Etype (E);
1572
1573             else
1574                Expand_Subtype_From_Expr (N, T, Object_Definition (N), E);
1575                Act_T := Find_Type_Of_Object (Object_Definition (N), N);
1576             end if;
1577
1578             Set_Is_Constr_Subt_For_U_Nominal (Act_T);
1579
1580             if Aliased_Present (N) then
1581                Set_Is_Constr_Subt_For_UN_Aliased (Act_T);
1582             end if;
1583
1584             Freeze_Before (N, Act_T);
1585             Freeze_Before (N, T);
1586          end if;
1587
1588       elsif Is_Array_Type (T)
1589         and then No_Initialization (N)
1590         and then Nkind (Original_Node (E)) = N_Aggregate
1591       then
1592          if not Is_Entity_Name (Object_Definition (N)) then
1593             Act_T := Etype (E);
1594
1595             if Aliased_Present (N) then
1596                Set_Is_Constr_Subt_For_UN_Aliased (Act_T);
1597             end if;
1598          end if;
1599
1600          --  When the given object definition and the aggregate are specified
1601          --  independently, and their lengths might differ do a length check.
1602          --  This cannot happen if the aggregate is of the form (others =>...)
1603
1604          if not Is_Constrained (T) then
1605             null;
1606
1607          elsif Nkind (E) = N_Raise_Constraint_Error then
1608
1609             --  Aggregate is statically illegal. Place back in declaration
1610
1611             Set_Expression (N, E);
1612             Set_No_Initialization (N, False);
1613
1614          elsif T = Etype (E) then
1615             null;
1616
1617          elsif Nkind (E) = N_Aggregate
1618            and then Present (Component_Associations (E))
1619            and then Present (Choices (First (Component_Associations (E))))
1620            and then Nkind (First
1621             (Choices (First (Component_Associations (E))))) = N_Others_Choice
1622          then
1623             null;
1624
1625          else
1626             Apply_Length_Check (E, T);
1627          end if;
1628
1629       elsif (Is_Limited_Record (T)
1630                or else Is_Concurrent_Type (T))
1631         and then not Is_Constrained (T)
1632         and then Has_Discriminants (T)
1633       then
1634          Act_T := Build_Default_Subtype;
1635          Rewrite (Object_Definition (N), New_Occurrence_Of (Act_T, Loc));
1636
1637       elsif not Is_Constrained (T)
1638         and then Has_Discriminants (T)
1639         and then Constant_Present (N)
1640         and then Nkind (E) = N_Function_Call
1641       then
1642          --  The back-end has problems with constants of a discriminated type
1643          --  with defaults, if the initial value is a function call. We
1644          --  generate an intermediate temporary for the result of the call.
1645          --  It is unclear why this should make it acceptable to gcc. ???
1646
1647          Remove_Side_Effects (E);
1648       end if;
1649
1650       if T = Standard_Wide_Character
1651         or else Root_Type (T) = Standard_Wide_String
1652       then
1653          Check_Restriction (No_Wide_Characters, Object_Definition (N));
1654       end if;
1655
1656       --  Now establish the proper kind and type of the object
1657
1658       if Constant_Present (N) then
1659          Set_Ekind               (Id, E_Constant);
1660          Set_Not_Source_Assigned (Id, True);
1661          Set_Is_True_Constant    (Id, True);
1662
1663       else
1664          Set_Ekind (Id, E_Variable);
1665
1666          --  A variable is set as shared passive if it appears in a shared
1667          --  passive package, and is at the outer level. This is not done
1668          --  for entities generated during expansion, because those are
1669          --  always manipulated locally.
1670
1671          if Is_Shared_Passive (Current_Scope)
1672            and then Is_Library_Level_Entity (Id)
1673            and then Comes_From_Source (Id)
1674          then
1675             Set_Is_Shared_Passive (Id);
1676             Check_Shared_Var (Id, T, N);
1677          end if;
1678
1679          --  If an initializing expression is present, then the variable
1680          --  is potentially a true constant if no further assignments are
1681          --  present. The code generator can use this for optimization.
1682          --  The flag will be reset if there are any assignments. We only
1683          --  set this flag for non library level entities, since for any
1684          --  library level entities, assignments could exist in other units.
1685
1686          if Present (E) then
1687             if not Is_Library_Level_Entity (Id) then
1688
1689                --  For now we omit this, because it seems to cause some
1690                --  problems. In particular, if you uncomment this out, then
1691                --  test case 4427-002 will fail for unclear reasons ???
1692
1693                if False then
1694                   Set_Is_True_Constant (Id);
1695                end if;
1696             end if;
1697
1698          --  Case of no initializing expression present. If the type is not
1699          --  fully initialized, then we set Not_Source_Assigned, since this
1700          --  is a case of a potentially uninitialized object. Note that we
1701          --  do not consider access variables to be fully initialized for
1702          --  this purpose, since it still seems dubious if someone declares
1703          --  an access variable and never assigns to it.
1704
1705          else
1706             if Is_Access_Type (T)
1707               or else not Is_Fully_Initialized_Type (T)
1708             then
1709                Set_Not_Source_Assigned (Id);
1710             end if;
1711          end if;
1712       end if;
1713
1714       Init_Alignment (Id);
1715       Init_Esize     (Id);
1716
1717       if Aliased_Present (N) then
1718          Set_Is_Aliased (Id);
1719
1720          if No (E)
1721            and then Is_Record_Type (T)
1722            and then not Is_Constrained (T)
1723            and then Has_Discriminants (T)
1724          then
1725             Set_Actual_Subtype (Id, Build_Default_Subtype);
1726          end if;
1727       end if;
1728
1729       Set_Etype (Id, Act_T);
1730
1731       if Has_Controlled_Component (Etype (Id))
1732         or else Is_Controlled (Etype (Id))
1733       then
1734          if not Is_Library_Level_Entity (Id) then
1735             Check_Restriction (No_Nested_Finalization, N);
1736
1737          else
1738             Validate_Controlled_Object (Id);
1739          end if;
1740
1741          --  Generate a warning when an initialization causes an obvious
1742          --  ABE violation. If the init expression is a simple aggregate
1743          --  there shouldn't be any initialize/adjust call generated. This
1744          --  will be true as soon as aggregates are built in place when
1745          --  possible. ??? at the moment we do not generate warnings for
1746          --  temporaries created for those aggregates although a
1747          --  Program_Error might be generated if compiled with -gnato
1748
1749          if Is_Controlled (Etype (Id))
1750             and then Comes_From_Source (Id)
1751          then
1752             declare
1753                BT            : constant Entity_Id := Base_Type (Etype (Id));
1754                Implicit_Call : Entity_Id;
1755
1756                function Is_Aggr (N : Node_Id) return Boolean;
1757                --  Check that N is an aggregate
1758
1759                function Is_Aggr (N : Node_Id) return Boolean is
1760                begin
1761                   case Nkind (Original_Node (N)) is
1762                      when N_Aggregate | N_Extension_Aggregate =>
1763                         return True;
1764
1765                      when N_Qualified_Expression |
1766                           N_Type_Conversion      |
1767                           N_Unchecked_Type_Conversion =>
1768                         return Is_Aggr (Expression (Original_Node (N)));
1769
1770                      when others =>
1771                         return False;
1772                   end case;
1773                end Is_Aggr;
1774
1775             begin
1776                --  If no underlying type, we already are in an error situation
1777                --  don't try to add a warning since we do not have access
1778                --  prim-op list.
1779
1780                if No (Underlying_Type (BT)) then
1781                   Implicit_Call := Empty;
1782
1783                --  A generic type does not have usable primitive operators.
1784                --  Initialization calls are built for instances.
1785
1786                elsif Is_Generic_Type (BT) then
1787                   Implicit_Call := Empty;
1788
1789                --  if the init expression is not an aggregate, an adjust
1790                --  call will be generated
1791
1792                elsif Present (E) and then not Is_Aggr (E) then
1793                   Implicit_Call := Find_Prim_Op (BT, Name_Adjust);
1794
1795                --  if no init expression and we are not in the deferred
1796                --  constant case, an Initialize call will be generated
1797
1798                elsif No (E) and then not Constant_Present (N) then
1799                   Implicit_Call := Find_Prim_Op (BT, Name_Initialize);
1800
1801                else
1802                   Implicit_Call := Empty;
1803                end if;
1804             end;
1805          end if;
1806       end if;
1807
1808       if Has_Task (Etype (Id)) then
1809          if not Is_Library_Level_Entity (Id) then
1810             Check_Restriction (No_Task_Hierarchy, N);
1811             Check_Potentially_Blocking_Operation (N);
1812          end if;
1813       end if;
1814
1815       --  Some simple constant-propagation: if the expression is a constant
1816       --  string initialized with a literal, share the literal. This avoids
1817       --  a run-time copy.
1818
1819       if Present (E)
1820         and then Is_Entity_Name (E)
1821         and then Ekind (Entity (E)) = E_Constant
1822         and then Base_Type (Etype (E)) = Standard_String
1823       then
1824          declare
1825             Val : constant Node_Id := Constant_Value (Entity (E));
1826
1827          begin
1828             if Present (Val)
1829               and then Nkind (Val) = N_String_Literal
1830             then
1831                Rewrite (E, New_Copy (Val));
1832             end if;
1833          end;
1834       end if;
1835
1836       --  Another optimization: if the nominal subtype is unconstrained and
1837       --  the expression is a function call that returns and unconstrained
1838       --  type, rewrite the declararation as a renaming of the result of the
1839       --  call. The exceptions below are cases where the copy is expected,
1840       --  either by the back end (Aliased case) or by the semantics, as for
1841       --  initializing controlled types or copying tags for classwide types.
1842
1843       if Present (E)
1844         and then Nkind (E) = N_Explicit_Dereference
1845         and then Nkind (Original_Node (E)) = N_Function_Call
1846         and then not Is_Library_Level_Entity (Id)
1847         and then not Is_Constrained (T)
1848         and then not Is_Aliased (Id)
1849         and then not Is_Class_Wide_Type (T)
1850         and then not Is_Controlled (T)
1851         and then not Has_Controlled_Component (Base_Type (T))
1852         and then Expander_Active
1853       then
1854          Rewrite (N,
1855            Make_Object_Renaming_Declaration (Loc,
1856              Defining_Identifier => Id,
1857              Subtype_Mark        => New_Occurrence_Of
1858                                       (Base_Type (Etype (Id)), Loc),
1859              Name                => E));
1860
1861          Set_Renamed_Object (Id, E);
1862       end if;
1863
1864       if Present (Prev_Entity)
1865         and then Is_Frozen (Prev_Entity)
1866         and then not Error_Posted (Id)
1867       then
1868          Error_Msg_N ("full constant declaration appears too late", N);
1869       end if;
1870
1871       Check_Eliminated (Id);
1872    end Analyze_Object_Declaration;
1873
1874    ---------------------------
1875    -- Analyze_Others_Choice --
1876    ---------------------------
1877
1878    --  Nothing to do for the others choice node itself, the semantic analysis
1879    --  of the others choice will occur as part of the processing of the parent
1880
1881    procedure Analyze_Others_Choice (N : Node_Id) is
1882    begin
1883       null;
1884    end Analyze_Others_Choice;
1885
1886    -------------------------------------------
1887    -- Analyze_Private_Extension_Declaration --
1888    -------------------------------------------
1889
1890    procedure Analyze_Private_Extension_Declaration (N : Node_Id) is
1891       T           : Entity_Id        := Defining_Identifier (N);
1892       Indic       : constant Node_Id := Subtype_Indication (N);
1893       Parent_Type : Entity_Id;
1894       Parent_Base : Entity_Id;
1895
1896    begin
1897       Generate_Definition (T);
1898       Enter_Name (T);
1899
1900       Parent_Type := Find_Type_Of_Subtype_Indic (Indic);
1901       Parent_Base := Base_Type (Parent_Type);
1902
1903       if Parent_Type = Any_Type
1904         or else Etype (Parent_Type) = Any_Type
1905       then
1906          Set_Ekind (T, Ekind (Parent_Type));
1907          Set_Etype (T, Any_Type);
1908          return;
1909
1910       elsif not Is_Tagged_Type (Parent_Type) then
1911          Error_Msg_N
1912            ("parent of type extension must be a tagged type ", Indic);
1913          return;
1914
1915       elsif Ekind (Parent_Type) = E_Void
1916         or else Ekind (Parent_Type) = E_Incomplete_Type
1917       then
1918          Error_Msg_N ("premature derivation of incomplete type", Indic);
1919          return;
1920       end if;
1921
1922       --  Perhaps the parent type should be changed to the class-wide type's
1923       --  specific type in this case to prevent cascading errors ???
1924
1925       if Is_Class_Wide_Type (Parent_Type) then
1926          Error_Msg_N
1927            ("parent of type extension must not be a class-wide type", Indic);
1928          return;
1929       end if;
1930
1931       if (not Is_Package (Current_Scope)
1932            and then Nkind (Parent (N)) /= N_Generic_Subprogram_Declaration)
1933         or else In_Private_Part (Current_Scope)
1934
1935       then
1936          Error_Msg_N ("invalid context for private extension", N);
1937       end if;
1938
1939       --  Set common attributes
1940
1941       Set_Is_Pure          (T, Is_Pure (Current_Scope));
1942       Set_Scope            (T, Current_Scope);
1943       Set_Ekind            (T, E_Record_Type_With_Private);
1944       Init_Size_Align      (T);
1945
1946       Set_Etype            (T,            Parent_Base);
1947       Set_Has_Task         (T, Has_Task  (Parent_Base));
1948
1949       Set_Convention       (T, Convention     (Parent_Type));
1950       Set_First_Rep_Item   (T, First_Rep_Item (Parent_Type));
1951       Set_Is_First_Subtype (T);
1952       Make_Class_Wide_Type (T);
1953
1954       Build_Derived_Record_Type (N, Parent_Type, T);
1955    end Analyze_Private_Extension_Declaration;
1956
1957    ---------------------------------
1958    -- Analyze_Subtype_Declaration --
1959    ---------------------------------
1960
1961    procedure Analyze_Subtype_Declaration (N : Node_Id) is
1962       Id       : constant Entity_Id := Defining_Identifier (N);
1963       T        : Entity_Id;
1964       R_Checks : Check_Result;
1965
1966    begin
1967       Generate_Definition (Id);
1968       Set_Is_Pure (Id, Is_Pure (Current_Scope));
1969       Init_Size_Align (Id);
1970
1971       --  The following guard condition on Enter_Name is to handle cases
1972       --  where the defining identifier has already been entered into the
1973       --  scope but the declaration as a whole needs to be analyzed.
1974
1975       --  This case in particular happens for derived enumeration types.
1976       --  The derived enumeration type is processed as an inserted enumeration
1977       --  type declaration followed by a rewritten subtype declaration. The
1978       --  defining identifier, however, is entered into the name scope very
1979       --  early in the processing of the original type declaration and
1980       --  therefore needs to be avoided here, when the created subtype
1981       --  declaration is analyzed. (See Build_Derived_Types)
1982
1983       --  This also happens when the full view of a private type is a
1984       --  derived type with constraints. In this case the entity has been
1985       --  introduced in the private declaration.
1986
1987       if Present (Etype (Id))
1988         and then (Is_Private_Type (Etype (Id))
1989                    or else Is_Task_Type (Etype (Id))
1990                    or else Is_Rewrite_Substitution (N))
1991       then
1992          null;
1993
1994       else
1995          Enter_Name (Id);
1996       end if;
1997
1998       T := Process_Subtype (Subtype_Indication (N), N, Id, 'P');
1999
2000       --  Inherit common attributes
2001
2002       Set_Is_Generic_Type (Id, Is_Generic_Type (Base_Type (T)));
2003       Set_Is_Volatile (Id, Is_Volatile (T));
2004       Set_Is_Atomic   (Id, Is_Atomic   (T));
2005
2006       --  In the case where there is no constraint given in the subtype
2007       --  indication, Process_Subtype just returns the Subtype_Mark,
2008       --  so its semantic attributes must be established here.
2009
2010       if Nkind (Subtype_Indication (N)) /= N_Subtype_Indication then
2011          Set_Etype (Id, Base_Type (T));
2012
2013          case Ekind (T) is
2014             when Array_Kind =>
2015                Set_Ekind                (Id, E_Array_Subtype);
2016
2017                --  Shouldn't we call Copy_Array_Subtype_Attributes here???
2018
2019                Set_First_Index          (Id, First_Index        (T));
2020                Set_Is_Aliased           (Id, Is_Aliased         (T));
2021                Set_Is_Constrained       (Id, Is_Constrained     (T));
2022
2023             when Decimal_Fixed_Point_Kind =>
2024                Set_Ekind                (Id, E_Decimal_Fixed_Point_Subtype);
2025                Set_Digits_Value         (Id, Digits_Value       (T));
2026                Set_Delta_Value          (Id, Delta_Value        (T));
2027                Set_Scale_Value          (Id, Scale_Value        (T));
2028                Set_Small_Value          (Id, Small_Value        (T));
2029                Set_Scalar_Range         (Id, Scalar_Range       (T));
2030                Set_Machine_Radix_10     (Id, Machine_Radix_10   (T));
2031                Set_Is_Constrained       (Id, Is_Constrained     (T));
2032                Set_RM_Size              (Id, RM_Size            (T));
2033
2034             when Enumeration_Kind =>
2035                Set_Ekind                (Id, E_Enumeration_Subtype);
2036                Set_First_Literal        (Id, First_Literal (Base_Type (T)));
2037                Set_Scalar_Range         (Id, Scalar_Range       (T));
2038                Set_Is_Character_Type    (Id, Is_Character_Type  (T));
2039                Set_Is_Constrained       (Id, Is_Constrained     (T));
2040                Set_RM_Size              (Id, RM_Size            (T));
2041
2042             when Ordinary_Fixed_Point_Kind =>
2043                Set_Ekind                (Id, E_Ordinary_Fixed_Point_Subtype);
2044                Set_Scalar_Range         (Id, Scalar_Range       (T));
2045                Set_Small_Value          (Id, Small_Value        (T));
2046                Set_Delta_Value          (Id, Delta_Value        (T));
2047                Set_Is_Constrained       (Id, Is_Constrained     (T));
2048                Set_RM_Size              (Id, RM_Size            (T));
2049
2050             when Float_Kind =>
2051                Set_Ekind                (Id, E_Floating_Point_Subtype);
2052                Set_Scalar_Range         (Id, Scalar_Range       (T));
2053                Set_Digits_Value         (Id, Digits_Value       (T));
2054                Set_Is_Constrained       (Id, Is_Constrained     (T));
2055
2056             when Signed_Integer_Kind =>
2057                Set_Ekind                (Id, E_Signed_Integer_Subtype);
2058                Set_Scalar_Range         (Id, Scalar_Range       (T));
2059                Set_Is_Constrained       (Id, Is_Constrained     (T));
2060                Set_RM_Size              (Id, RM_Size            (T));
2061
2062             when Modular_Integer_Kind =>
2063                Set_Ekind                (Id, E_Modular_Integer_Subtype);
2064                Set_Scalar_Range         (Id, Scalar_Range       (T));
2065                Set_Is_Constrained       (Id, Is_Constrained     (T));
2066                Set_RM_Size              (Id, RM_Size            (T));
2067
2068             when Class_Wide_Kind =>
2069                Set_Ekind                (Id, E_Class_Wide_Subtype);
2070                Set_First_Entity         (Id, First_Entity       (T));
2071                Set_Last_Entity          (Id, Last_Entity        (T));
2072                Set_Class_Wide_Type      (Id, Class_Wide_Type    (T));
2073                Set_Cloned_Subtype       (Id, T);
2074                Set_Is_Tagged_Type       (Id, True);
2075                Set_Has_Unknown_Discriminants
2076                                         (Id, True);
2077
2078                if Ekind (T) = E_Class_Wide_Subtype then
2079                   Set_Equivalent_Type   (Id, Equivalent_Type    (T));
2080                end if;
2081
2082             when E_Record_Type | E_Record_Subtype =>
2083                Set_Ekind                (Id, E_Record_Subtype);
2084
2085                if Ekind (T) = E_Record_Subtype
2086                  and then Present (Cloned_Subtype (T))
2087                then
2088                   Set_Cloned_Subtype    (Id, Cloned_Subtype (T));
2089                else
2090                   Set_Cloned_Subtype    (Id, T);
2091                end if;
2092
2093                Set_First_Entity         (Id, First_Entity       (T));
2094                Set_Last_Entity          (Id, Last_Entity        (T));
2095                Set_Has_Discriminants    (Id, Has_Discriminants  (T));
2096                Set_Is_Constrained       (Id, Is_Constrained     (T));
2097                Set_Is_Limited_Record    (Id, Is_Limited_Record  (T));
2098                Set_Has_Unknown_Discriminants
2099                                         (Id, Has_Unknown_Discriminants (T));
2100
2101                if Has_Discriminants (T) then
2102                   Set_Discriminant_Constraint
2103                                         (Id, Discriminant_Constraint (T));
2104                   Set_Girder_Constraint_From_Discriminant_Constraint (Id);
2105
2106                elsif Has_Unknown_Discriminants (Id) then
2107                   Set_Discriminant_Constraint (Id, No_Elist);
2108                end if;
2109
2110                if Is_Tagged_Type (T) then
2111                   Set_Is_Tagged_Type    (Id);
2112                   Set_Is_Abstract       (Id, Is_Abstract (T));
2113                   Set_Primitive_Operations
2114                                         (Id, Primitive_Operations (T));
2115                   Set_Class_Wide_Type   (Id, Class_Wide_Type (T));
2116                end if;
2117
2118             when Private_Kind =>
2119                Set_Ekind              (Id, Subtype_Kind (Ekind   (T)));
2120                Set_Has_Discriminants  (Id, Has_Discriminants     (T));
2121                Set_Is_Constrained     (Id, Is_Constrained        (T));
2122                Set_First_Entity       (Id, First_Entity          (T));
2123                Set_Last_Entity        (Id, Last_Entity           (T));
2124                Set_Private_Dependents (Id, New_Elmt_List);
2125                Set_Is_Limited_Record  (Id, Is_Limited_Record     (T));
2126                Set_Has_Unknown_Discriminants
2127                                       (Id, Has_Unknown_Discriminants (T));
2128
2129                if Is_Tagged_Type (T) then
2130                   Set_Is_Tagged_Type  (Id);
2131                   Set_Is_Abstract     (Id, Is_Abstract (T));
2132                   Set_Class_Wide_Type (Id, Class_Wide_Type (T));
2133                end if;
2134
2135                --  In general the attributes of the subtype of a private
2136                --  type are the attributes of the partial view of parent.
2137                --  However, the full view may be a discriminated type,
2138                --  and the subtype must share the discriminant constraint
2139                --  to generate correct calls to initialization procedures.
2140
2141                if Has_Discriminants (T) then
2142                   Set_Discriminant_Constraint
2143                                      (Id, Discriminant_Constraint (T));
2144                   Set_Girder_Constraint_From_Discriminant_Constraint (Id);
2145
2146                elsif Present (Full_View (T))
2147                  and then Has_Discriminants (Full_View (T))
2148                then
2149                   Set_Discriminant_Constraint
2150                                (Id, Discriminant_Constraint (Full_View (T)));
2151                   Set_Girder_Constraint_From_Discriminant_Constraint (Id);
2152
2153                   --  This would seem semantically correct, but apparently
2154                   --  confuses the back-end (4412-009). To be explained ???
2155
2156                   --  Set_Has_Discriminants (Id);
2157                end if;
2158
2159                Prepare_Private_Subtype_Completion (Id, N);
2160
2161             when Access_Kind =>
2162                Set_Ekind             (Id, E_Access_Subtype);
2163                Set_Is_Constrained    (Id, Is_Constrained        (T));
2164                Set_Is_Access_Constant
2165                                      (Id, Is_Access_Constant    (T));
2166                Set_Directly_Designated_Type
2167                                      (Id, Designated_Type       (T));
2168
2169                --  A Pure library_item must not contain the declaration of a
2170                --  named access type, except within a subprogram, generic
2171                --  subprogram, task unit, or protected unit (RM 10.2.1(16)).
2172
2173                if Comes_From_Source (Id)
2174                  and then In_Pure_Unit
2175                  and then not In_Subprogram_Task_Protected_Unit
2176                then
2177                   Error_Msg_N
2178                     ("named access types not allowed in pure unit", N);
2179                end if;
2180
2181             when Concurrent_Kind =>
2182
2183                Set_Ekind                (Id, Subtype_Kind (Ekind   (T)));
2184                Set_Corresponding_Record_Type (Id,
2185                                          Corresponding_Record_Type (T));
2186                Set_First_Entity         (Id, First_Entity          (T));
2187                Set_First_Private_Entity (Id, First_Private_Entity  (T));
2188                Set_Has_Discriminants    (Id, Has_Discriminants     (T));
2189                Set_Is_Constrained       (Id, Is_Constrained        (T));
2190                Set_Last_Entity          (Id, Last_Entity           (T));
2191
2192                if Has_Discriminants (T) then
2193                   Set_Discriminant_Constraint (Id,
2194                                            Discriminant_Constraint (T));
2195                   Set_Girder_Constraint_From_Discriminant_Constraint (Id);
2196                end if;
2197
2198             --  If the subtype name denotes an incomplete type
2199             --  an error was already reported by Process_Subtype.
2200
2201             when E_Incomplete_Type =>
2202                Set_Etype (Id, Any_Type);
2203
2204             when others =>
2205                raise Program_Error;
2206          end case;
2207       end if;
2208
2209       if Etype (Id) = Any_Type then
2210          return;
2211       end if;
2212
2213       --  Some common processing on all types
2214
2215       Set_Size_Info      (Id,                 T);
2216       Set_First_Rep_Item (Id, First_Rep_Item (T));
2217
2218       T := Etype (Id);
2219
2220       Set_Is_Immediately_Visible (Id, True);
2221       Set_Depends_On_Private     (Id, Has_Private_Component (T));
2222
2223       if Present (Generic_Parent_Type (N))
2224         and then
2225           (Nkind
2226              (Parent (Generic_Parent_Type (N))) /= N_Formal_Type_Declaration
2227             or else Nkind
2228               (Formal_Type_Definition (Parent (Generic_Parent_Type (N))))
2229                 /=  N_Formal_Private_Type_Definition)
2230       then
2231          if Is_Tagged_Type (Id) then
2232             if Is_Class_Wide_Type (Id) then
2233                Derive_Subprograms (Generic_Parent_Type (N), Id, Etype (T));
2234             else
2235                Derive_Subprograms (Generic_Parent_Type (N), Id, T);
2236             end if;
2237
2238          elsif Scope (Etype (Id)) /= Standard_Standard then
2239             Derive_Subprograms (Generic_Parent_Type (N), Id);
2240          end if;
2241       end if;
2242
2243       if Is_Private_Type (T)
2244         and then Present (Full_View (T))
2245       then
2246          Conditional_Delay (Id, Full_View (T));
2247
2248       --  The subtypes of components or subcomponents of protected types
2249       --  do not need freeze nodes, which would otherwise appear in the
2250       --  wrong scope (before the freeze node for the protected type). The
2251       --  proper subtypes are those of the subcomponents of the corresponding
2252       --  record.
2253
2254       elsif Ekind (Scope (Id)) /= E_Protected_Type
2255         and then Present (Scope (Scope (Id))) -- error defense!
2256         and then Ekind (Scope (Scope (Id))) /= E_Protected_Type
2257       then
2258          Conditional_Delay (Id, T);
2259       end if;
2260
2261       --  Check that constraint_error is raised for a scalar subtype
2262       --  indication when the lower or upper bound of a non-null range
2263       --  lies outside the range of the type mark.
2264
2265       if Nkind (Subtype_Indication (N)) = N_Subtype_Indication then
2266          if Is_Scalar_Type (Etype (Id))
2267             and then Scalar_Range (Id) /=
2268                      Scalar_Range (Etype (Subtype_Mark
2269                                            (Subtype_Indication (N))))
2270          then
2271             Apply_Range_Check
2272               (Scalar_Range (Id),
2273                Etype (Subtype_Mark (Subtype_Indication (N))));
2274
2275          elsif Is_Array_Type (Etype (Id))
2276            and then Present (First_Index (Id))
2277          then
2278             --  This really should be a subprogram that finds the indications
2279             --  to check???
2280
2281             if ((Nkind (First_Index (Id)) = N_Identifier
2282                    and then Ekind (Entity (First_Index (Id))) in Scalar_Kind)
2283                  or else Nkind (First_Index (Id)) = N_Subtype_Indication)
2284               and then
2285                 Nkind (Scalar_Range (Etype (First_Index (Id)))) = N_Range
2286             then
2287                declare
2288                   Target_Typ : Entity_Id :=
2289                     Etype
2290                       (First_Index
2291                         (Etype (Subtype_Mark (Subtype_Indication (N)))));
2292                begin
2293                   R_Checks :=
2294                     Range_Check
2295                       (Scalar_Range (Etype (First_Index (Id))),
2296                        Target_Typ,
2297                        Etype (First_Index (Id)),
2298                        Defining_Identifier (N));
2299
2300                   Insert_Range_Checks
2301                     (R_Checks,
2302                      N,
2303                      Target_Typ,
2304                      Sloc (Defining_Identifier (N)));
2305                end;
2306             end if;
2307          end if;
2308       end if;
2309
2310       Check_Eliminated (Id);
2311    end Analyze_Subtype_Declaration;
2312
2313    --------------------------------
2314    -- Analyze_Subtype_Indication --
2315    --------------------------------
2316
2317    procedure Analyze_Subtype_Indication (N : Node_Id) is
2318       T : constant Entity_Id := Subtype_Mark (N);
2319       R : constant Node_Id   := Range_Expression (Constraint (N));
2320
2321    begin
2322       Analyze (T);
2323
2324       if R /= Error then
2325          Analyze (R);
2326          Set_Etype (N, Etype (R));
2327       else
2328          Set_Error_Posted (R);
2329          Set_Error_Posted (T);
2330       end if;
2331    end Analyze_Subtype_Indication;
2332
2333    ------------------------------
2334    -- Analyze_Type_Declaration --
2335    ------------------------------
2336
2337    procedure Analyze_Type_Declaration (N : Node_Id) is
2338       Def    : constant Node_Id   := Type_Definition (N);
2339       Def_Id : constant Entity_Id := Defining_Identifier (N);
2340       T      : Entity_Id;
2341       Prev   : Entity_Id;
2342
2343    begin
2344       Prev := Find_Type_Name (N);
2345
2346       if Ekind (Prev) = E_Incomplete_Type then
2347          T := Full_View (Prev);
2348       else
2349          T := Prev;
2350       end if;
2351
2352       Set_Is_Pure (T, Is_Pure (Current_Scope));
2353
2354       --  We set the flag Is_First_Subtype here. It is needed to set the
2355       --  corresponding flag for the Implicit class-wide-type created
2356       --  during tagged types processing.
2357
2358       Set_Is_First_Subtype (T, True);
2359
2360       --  Only composite types other than array types are allowed to have
2361       --  discriminants.
2362
2363       case Nkind (Def) is
2364
2365          --  For derived types, the rule will be checked once we've figured
2366          --  out the parent type.
2367
2368          when N_Derived_Type_Definition =>
2369             null;
2370
2371          --  For record types, discriminants are allowed.
2372
2373          when N_Record_Definition =>
2374             null;
2375
2376          when others =>
2377             if Present (Discriminant_Specifications (N)) then
2378                Error_Msg_N
2379                  ("elementary or array type cannot have discriminants",
2380                   Defining_Identifier
2381                   (First (Discriminant_Specifications (N))));
2382             end if;
2383       end case;
2384
2385       --  Elaborate the type definition according to kind, and generate
2386       --  susbsidiary (implicit) subtypes where needed. We skip this if
2387       --  it was already done (this happens during the reanalysis that
2388       --  follows a call to the high level optimizer).
2389
2390       if not Analyzed (T) then
2391          Set_Analyzed (T);
2392
2393          case Nkind (Def) is
2394
2395             when N_Access_To_Subprogram_Definition =>
2396                Access_Subprogram_Declaration (T, Def);
2397
2398                --  If this is a remote access to subprogram, we must create
2399                --  the equivalent fat pointer type, and related subprograms.
2400
2401                if Is_Remote_Types (Current_Scope)
2402                  or else Is_Remote_Call_Interface (Current_Scope)
2403                then
2404                   Validate_Remote_Access_To_Subprogram_Type (N);
2405                   Process_Remote_AST_Declaration (N);
2406                end if;
2407
2408                --  Validate categorization rule against access type declaration
2409                --  usually a violation in Pure unit, Shared_Passive unit.
2410
2411                Validate_Access_Type_Declaration (T, N);
2412
2413             when N_Access_To_Object_Definition =>
2414                Access_Type_Declaration (T, Def);
2415
2416                --  Validate categorization rule against access type declaration
2417                --  usually a violation in Pure unit, Shared_Passive unit.
2418
2419                Validate_Access_Type_Declaration (T, N);
2420
2421                --  If we are in a Remote_Call_Interface package and define
2422                --  a RACW, Read and Write attribute must be added.
2423
2424                if (Is_Remote_Call_Interface (Current_Scope)
2425                      or else Is_Remote_Types (Current_Scope))
2426                  and then Is_Remote_Access_To_Class_Wide_Type (Def_Id)
2427                then
2428                   Add_RACW_Features (Def_Id);
2429                end if;
2430
2431             when N_Array_Type_Definition =>
2432                Array_Type_Declaration (T, Def);
2433
2434             when N_Derived_Type_Definition =>
2435                Derived_Type_Declaration (T, N, T /= Def_Id);
2436
2437             when N_Enumeration_Type_Definition =>
2438                Enumeration_Type_Declaration (T, Def);
2439
2440             when N_Floating_Point_Definition =>
2441                Floating_Point_Type_Declaration (T, Def);
2442
2443             when N_Decimal_Fixed_Point_Definition =>
2444                Decimal_Fixed_Point_Type_Declaration (T, Def);
2445
2446             when N_Ordinary_Fixed_Point_Definition =>
2447                Ordinary_Fixed_Point_Type_Declaration (T, Def);
2448
2449             when N_Signed_Integer_Type_Definition =>
2450                Signed_Integer_Type_Declaration (T, Def);
2451
2452             when N_Modular_Type_Definition =>
2453                Modular_Type_Declaration (T, Def);
2454
2455             when N_Record_Definition =>
2456                Record_Type_Declaration (T, N);
2457
2458             when others =>
2459                raise Program_Error;
2460
2461          end case;
2462       end if;
2463
2464       if Etype (T) = Any_Type then
2465          return;
2466       end if;
2467
2468       --  Some common processing for all types
2469
2470       Set_Depends_On_Private (T, Has_Private_Component (T));
2471
2472       --  Both the declared entity, and its anonymous base type if one
2473       --  was created, need freeze nodes allocated.
2474
2475       declare
2476          B : constant Entity_Id := Base_Type (T);
2477
2478       begin
2479          --  In the case where the base type is different from the first
2480          --  subtype, we pre-allocate a freeze node, and set the proper
2481          --  link to the first subtype. Freeze_Entity will use this
2482          --  preallocated freeze node when it freezes the entity.
2483
2484          if B /= T then
2485             Ensure_Freeze_Node (B);
2486             Set_First_Subtype_Link (Freeze_Node (B), T);
2487          end if;
2488
2489          if not From_With_Type (T) then
2490             Set_Has_Delayed_Freeze (T);
2491          end if;
2492       end;
2493
2494       --  Case of T is the full declaration of some private type which has
2495       --  been swapped in Defining_Identifier (N).
2496
2497       if T /= Def_Id and then Is_Private_Type (Def_Id) then
2498          Process_Full_View (N, T, Def_Id);
2499
2500          --  Record the reference. The form of this is a little strange,
2501          --  since the full declaration has been swapped in. So the first
2502          --  parameter here represents the entity to which a reference is
2503          --  made which is the "real" entity, i.e. the one swapped in,
2504          --  and the second parameter provides the reference location.
2505
2506          Generate_Reference (T, T, 'c');
2507
2508          --  If in main unit, set as referenced, so we do not complain about
2509          --  the full declaration being an unreferenced entity.
2510
2511          if In_Extended_Main_Source_Unit (Def_Id) then
2512             Set_Referenced (Def_Id);
2513          end if;
2514
2515       --  For completion of incomplete type, process incomplete dependents
2516       --  and always mark the full type as referenced (it is the incomplete
2517       --  type that we get for any real reference).
2518
2519       elsif Ekind (Prev) = E_Incomplete_Type then
2520          Process_Incomplete_Dependents (N, T, Prev);
2521          Generate_Reference (Prev, Def_Id, 'c');
2522
2523          --  If in main unit, set as referenced, so we do not complain about
2524          --  the full declaration being an unreferenced entity.
2525
2526          if In_Extended_Main_Source_Unit (Def_Id) then
2527             Set_Referenced (Def_Id);
2528          end if;
2529
2530       --  If not private type or incomplete type completion, this is a real
2531       --  definition of a new entity, so record it.
2532
2533       else
2534          Generate_Definition (Def_Id);
2535       end if;
2536
2537       Check_Eliminated (Def_Id);
2538    end Analyze_Type_Declaration;
2539
2540    --------------------------
2541    -- Analyze_Variant_Part --
2542    --------------------------
2543
2544    procedure Analyze_Variant_Part (N : Node_Id) is
2545
2546       procedure Non_Static_Choice_Error (Choice : Node_Id);
2547       --  Error routine invoked by the generic instantiation below when
2548       --  the variant part has a non static choice.
2549
2550       procedure Process_Declarations (Variant : Node_Id);
2551       --  Analyzes all the declarations associated with a Variant.
2552       --  Needed by the generic instantiation below.
2553
2554       package Variant_Choices_Processing is new
2555         Generic_Choices_Processing
2556           (Get_Alternatives          => Variants,
2557            Get_Choices               => Discrete_Choices,
2558            Process_Empty_Choice      => No_OP,
2559            Process_Non_Static_Choice => Non_Static_Choice_Error,
2560            Process_Associated_Node   => Process_Declarations);
2561       use Variant_Choices_Processing;
2562       --  Instantiation of the generic choice processing package.
2563
2564       -----------------------------
2565       -- Non_Static_Choice_Error --
2566       -----------------------------
2567
2568       procedure Non_Static_Choice_Error (Choice : Node_Id) is
2569       begin
2570          Error_Msg_N ("choice given in variant part is not static", Choice);
2571       end Non_Static_Choice_Error;
2572
2573       --------------------------
2574       -- Process_Declarations --
2575       --------------------------
2576
2577       procedure Process_Declarations (Variant : Node_Id) is
2578       begin
2579          if not Null_Present (Component_List (Variant)) then
2580             Analyze_Declarations (Component_Items (Component_List (Variant)));
2581
2582             if Present (Variant_Part (Component_List (Variant))) then
2583                Analyze (Variant_Part (Component_List (Variant)));
2584             end if;
2585          end if;
2586       end Process_Declarations;
2587
2588       --  Variables local to Analyze_Case_Statement.
2589
2590       Others_Choice : Node_Id;
2591
2592       Discr_Name : Node_Id;
2593       Discr_Type : Entity_Id;
2594
2595       Case_Table     : Choice_Table_Type (1 .. Number_Of_Choices (N));
2596       Last_Choice    : Nat;
2597       Dont_Care      : Boolean;
2598       Others_Present : Boolean := False;
2599
2600    --  Start of processing for Analyze_Variant_Part
2601
2602    begin
2603       Discr_Name := Name (N);
2604       Analyze (Discr_Name);
2605
2606       if Ekind (Entity (Discr_Name)) /= E_Discriminant then
2607          Error_Msg_N ("invalid discriminant name in variant part", Discr_Name);
2608       end if;
2609
2610       Discr_Type := Etype (Entity (Discr_Name));
2611
2612       if not Is_Discrete_Type (Discr_Type) then
2613          Error_Msg_N
2614            ("discriminant in a variant part must be of a discrete type",
2615              Name (N));
2616          return;
2617       end if;
2618
2619       --  Call the instantiated Analyze_Choices which does the rest of the work
2620
2621       Analyze_Choices
2622         (N, Discr_Type, Case_Table, Last_Choice, Dont_Care, Others_Present);
2623
2624       if Others_Present then
2625          --  Fill in Others_Discrete_Choices field of the OTHERS choice
2626
2627          Others_Choice := First (Discrete_Choices (Last (Variants (N))));
2628          Expand_Others_Choice
2629            (Case_Table (1 .. Last_Choice), Others_Choice, Discr_Type);
2630       end if;
2631
2632    end Analyze_Variant_Part;
2633
2634    ----------------------------
2635    -- Array_Type_Declaration --
2636    ----------------------------
2637
2638    procedure Array_Type_Declaration (T : in out Entity_Id; Def : Node_Id) is
2639       Component_Def : constant Node_Id := Subtype_Indication (Def);
2640       Element_Type  : Entity_Id;
2641       Implicit_Base : Entity_Id;
2642       Index         : Node_Id;
2643       Related_Id    : Entity_Id := Empty;
2644       Nb_Index      : Nat;
2645       P             : constant Node_Id := Parent (Def);
2646       Priv          : Entity_Id;
2647
2648    begin
2649       if Nkind (Def) = N_Constrained_Array_Definition then
2650
2651          Index := First (Discrete_Subtype_Definitions (Def));
2652
2653          --  Find proper names for the implicit types which may be public.
2654          --  in case of anonymous arrays we use the name of the first object
2655          --  of that type as prefix.
2656
2657          if No (T) then
2658             Related_Id :=  Defining_Identifier (P);
2659          else
2660             Related_Id := T;
2661          end if;
2662
2663       else
2664          Index := First (Subtype_Marks (Def));
2665       end if;
2666
2667       Nb_Index := 1;
2668
2669       while Present (Index) loop
2670          Analyze (Index);
2671          Make_Index (Index, P, Related_Id, Nb_Index);
2672          Next_Index (Index);
2673          Nb_Index := Nb_Index + 1;
2674       end loop;
2675
2676       Element_Type := Process_Subtype (Component_Def, P, Related_Id, 'C');
2677
2678       --  Constrained array case
2679
2680       if No (T) then
2681          T := Create_Itype (E_Void, P, Related_Id, 'T');
2682       end if;
2683
2684       if Nkind (Def) = N_Constrained_Array_Definition then
2685
2686          --  Establish Implicit_Base as unconstrained base type
2687
2688          Implicit_Base := Create_Itype (E_Array_Type, P, Related_Id, 'B');
2689
2690          Init_Size_Align        (Implicit_Base);
2691          Set_Etype              (Implicit_Base, Implicit_Base);
2692          Set_Scope              (Implicit_Base, Current_Scope);
2693          Set_Has_Delayed_Freeze (Implicit_Base);
2694
2695          --  The constrained array type is a subtype of the unconstrained one
2696
2697          Set_Ekind          (T, E_Array_Subtype);
2698          Init_Size_Align    (T);
2699          Set_Etype          (T, Implicit_Base);
2700          Set_Scope          (T, Current_Scope);
2701          Set_Is_Constrained (T, True);
2702          Set_First_Index    (T, First (Discrete_Subtype_Definitions (Def)));
2703          Set_Has_Delayed_Freeze (T);
2704
2705          --  Complete setup of implicit base type
2706
2707          Set_First_Index    (Implicit_Base, First_Index (T));
2708          Set_Component_Type (Implicit_Base, Element_Type);
2709          Set_Has_Task       (Implicit_Base, Has_Task (Element_Type));
2710          Set_Component_Size (Implicit_Base, Uint_0);
2711          Set_Has_Controlled_Component (Implicit_Base,
2712            Has_Controlled_Component (Element_Type)
2713              or else Is_Controlled (Element_Type));
2714          Set_Finalize_Storage_Only (Implicit_Base,
2715            Finalize_Storage_Only (Element_Type));
2716
2717       --  Unconstrained array case
2718
2719       else
2720          Set_Ekind                    (T, E_Array_Type);
2721          Init_Size_Align              (T);
2722          Set_Etype                    (T, T);
2723          Set_Scope                    (T, Current_Scope);
2724          Set_Component_Size           (T, Uint_0);
2725          Set_Is_Constrained           (T, False);
2726          Set_First_Index              (T, First (Subtype_Marks (Def)));
2727          Set_Has_Delayed_Freeze       (T, True);
2728          Set_Has_Task                 (T, Has_Task (Element_Type));
2729          Set_Has_Controlled_Component (T,
2730            Has_Controlled_Component (Element_Type)
2731              or else Is_Controlled (Element_Type));
2732          Set_Finalize_Storage_Only (T,
2733            Finalize_Storage_Only (Element_Type));
2734       end if;
2735
2736       Set_Component_Type (T, Element_Type);
2737
2738       if Aliased_Present (Def) then
2739          Set_Has_Aliased_Components (Etype (T));
2740       end if;
2741
2742       Priv := Private_Component (Element_Type);
2743
2744       if Present (Priv) then
2745          --  Check for circular definitions.
2746
2747          if Priv = Any_Type then
2748             Set_Component_Type (T, Any_Type);
2749             Set_Component_Type (Etype (T), Any_Type);
2750
2751          --  There is a gap in the visiblity of operations on the composite
2752          --  type only if the component type is defined in a different scope.
2753
2754          elsif Scope (Priv) = Current_Scope then
2755             null;
2756
2757          elsif Is_Limited_Type (Priv) then
2758             Set_Is_Limited_Composite (Etype (T));
2759             Set_Is_Limited_Composite (T);
2760          else
2761             Set_Is_Private_Composite (Etype (T));
2762             Set_Is_Private_Composite (T);
2763          end if;
2764       end if;
2765
2766       --  Create a concatenation operator for the new type. Internal
2767       --  array types created for packed entities do not need such, they
2768       --  are compatible with the user-defined type.
2769
2770       if Number_Dimensions (T) = 1
2771          and then not Is_Packed_Array_Type (T)
2772       then
2773          New_Binary_Operator (Name_Op_Concat, T);
2774       end if;
2775
2776       --  In the case of an unconstrained array the parser has already
2777       --  verified that all the indices are unconstrained but we still
2778       --  need to make sure that the element type is constrained.
2779
2780       if Is_Indefinite_Subtype (Element_Type) then
2781          Error_Msg_N
2782            ("unconstrained element type in array declaration ",
2783             Component_Def);
2784
2785       elsif Is_Abstract (Element_Type) then
2786          Error_Msg_N ("The type of a component cannot be abstract ",
2787               Component_Def);
2788       end if;
2789
2790    end Array_Type_Declaration;
2791
2792    -------------------------------
2793    -- Build_Derived_Access_Type --
2794    -------------------------------
2795
2796    procedure Build_Derived_Access_Type
2797      (N            : Node_Id;
2798       Parent_Type  : Entity_Id;
2799       Derived_Type : Entity_Id)
2800    is
2801       S : constant Node_Id := Subtype_Indication (Type_Definition (N));
2802
2803       Desig_Type      : Entity_Id;
2804       Discr           : Entity_Id;
2805       Discr_Con_Elist : Elist_Id;
2806       Discr_Con_El    : Elmt_Id;
2807
2808       Subt            : Entity_Id;
2809
2810    begin
2811       --  Set the designated type so it is available in case this is
2812       --  an access to a self-referential type, e.g. a standard list
2813       --  type with a next pointer. Will be reset after subtype is built.
2814
2815       Set_Directly_Designated_Type (Derived_Type,
2816         Designated_Type (Parent_Type));
2817
2818       Subt := Process_Subtype (S, N);
2819
2820       if Nkind (S) /= N_Subtype_Indication
2821         and then Subt /= Base_Type (Subt)
2822       then
2823          Set_Ekind (Derived_Type, E_Access_Subtype);
2824       end if;
2825
2826       if Ekind (Derived_Type) = E_Access_Subtype then
2827          declare
2828             Pbase      : constant Entity_Id := Base_Type (Parent_Type);
2829             Ibase      : constant Entity_Id :=
2830                            Create_Itype (Ekind (Pbase), N, Derived_Type, 'B');
2831             Svg_Chars  : constant Name_Id   := Chars (Ibase);
2832             Svg_Next_E : constant Entity_Id := Next_Entity (Ibase);
2833
2834          begin
2835             Copy_Node (Pbase, Ibase);
2836
2837             Set_Chars       (Ibase, Svg_Chars);
2838             Set_Next_Entity (Ibase, Svg_Next_E);
2839             Set_Sloc        (Ibase, Sloc (Derived_Type));
2840             Set_Scope       (Ibase, Scope (Derived_Type));
2841             Set_Freeze_Node (Ibase, Empty);
2842             Set_Is_Frozen   (Ibase, False);
2843
2844             Set_Etype (Ibase, Pbase);
2845             Set_Etype (Derived_Type, Ibase);
2846          end;
2847       end if;
2848
2849       Set_Directly_Designated_Type
2850         (Derived_Type, Designated_Type (Subt));
2851
2852       Set_Is_Constrained     (Derived_Type, Is_Constrained (Subt));
2853       Set_Is_Access_Constant (Derived_Type, Is_Access_Constant (Parent_Type));
2854       Set_Size_Info          (Derived_Type,                     Parent_Type);
2855       Set_RM_Size            (Derived_Type, RM_Size            (Parent_Type));
2856       Set_Depends_On_Private (Derived_Type,
2857                               Has_Private_Component (Derived_Type));
2858       Conditional_Delay      (Derived_Type, Subt);
2859
2860       --  Note: we do not copy the Storage_Size_Variable, since
2861       --  we always go to the root type for this information.
2862
2863       --  Apply range checks to discriminants for derived record case
2864       --  ??? THIS CODE SHOULD NOT BE HERE REALLY.
2865
2866       Desig_Type := Designated_Type (Derived_Type);
2867       if Is_Composite_Type (Desig_Type)
2868         and then (not Is_Array_Type (Desig_Type))
2869         and then Has_Discriminants (Desig_Type)
2870         and then Base_Type (Desig_Type) /= Desig_Type
2871       then
2872          Discr_Con_Elist := Discriminant_Constraint (Desig_Type);
2873          Discr_Con_El := First_Elmt (Discr_Con_Elist);
2874
2875          Discr := First_Discriminant (Base_Type (Desig_Type));
2876          while Present (Discr_Con_El) loop
2877             Apply_Range_Check (Node (Discr_Con_El), Etype (Discr));
2878             Next_Elmt (Discr_Con_El);
2879             Next_Discriminant (Discr);
2880          end loop;
2881       end if;
2882    end Build_Derived_Access_Type;
2883
2884    ------------------------------
2885    -- Build_Derived_Array_Type --
2886    ------------------------------
2887
2888    procedure Build_Derived_Array_Type
2889      (N            : Node_Id;
2890       Parent_Type  : Entity_Id;
2891       Derived_Type : Entity_Id)
2892    is
2893       Loc           : constant Source_Ptr := Sloc (N);
2894       Tdef          : constant Node_Id    := Type_Definition (N);
2895       Indic         : constant Node_Id    := Subtype_Indication (Tdef);
2896       Parent_Base   : constant Entity_Id  := Base_Type (Parent_Type);
2897       Implicit_Base : Entity_Id;
2898       New_Indic     : Node_Id;
2899
2900       procedure Make_Implicit_Base;
2901       --  If the parent subtype is constrained, the derived type is a
2902       --  subtype of an implicit base type derived from the parent base.
2903
2904       ------------------------
2905       -- Make_Implicit_Base --
2906       ------------------------
2907
2908       procedure Make_Implicit_Base is
2909       begin
2910          Implicit_Base :=
2911            Create_Itype (Ekind (Parent_Base), N, Derived_Type, 'B');
2912
2913          Set_Ekind (Implicit_Base, Ekind (Parent_Base));
2914          Set_Etype (Implicit_Base, Parent_Base);
2915
2916          Copy_Array_Subtype_Attributes   (Implicit_Base, Parent_Base);
2917          Copy_Array_Base_Type_Attributes (Implicit_Base, Parent_Base);
2918
2919          Set_Has_Delayed_Freeze (Implicit_Base, True);
2920       end Make_Implicit_Base;
2921
2922    --  Start of processing for Build_Derived_Array_Type
2923
2924    begin
2925       if not Is_Constrained (Parent_Type) then
2926          if Nkind (Indic) /= N_Subtype_Indication then
2927             Set_Ekind (Derived_Type, E_Array_Type);
2928
2929             Copy_Array_Subtype_Attributes   (Derived_Type, Parent_Type);
2930             Copy_Array_Base_Type_Attributes (Derived_Type, Parent_Type);
2931
2932             Set_Has_Delayed_Freeze (Derived_Type, True);
2933
2934          else
2935             Make_Implicit_Base;
2936             Set_Etype (Derived_Type, Implicit_Base);
2937
2938             New_Indic :=
2939               Make_Subtype_Declaration (Loc,
2940                 Defining_Identifier => Derived_Type,
2941                 Subtype_Indication  =>
2942                   Make_Subtype_Indication (Loc,
2943                     Subtype_Mark => New_Reference_To (Implicit_Base, Loc),
2944                     Constraint => Constraint (Indic)));
2945
2946             Rewrite (N, New_Indic);
2947             Analyze (N);
2948          end if;
2949
2950       else
2951          if Nkind (Indic) /= N_Subtype_Indication then
2952             Make_Implicit_Base;
2953
2954             Set_Ekind             (Derived_Type, Ekind (Parent_Type));
2955             Set_Etype             (Derived_Type, Implicit_Base);
2956             Copy_Array_Subtype_Attributes (Derived_Type, Parent_Type);
2957
2958          else
2959             Error_Msg_N ("illegal constraint on constrained type", Indic);
2960          end if;
2961       end if;
2962
2963       --  If the parent type is not a derived type itself, and is
2964       --  declared in a closed scope (e.g., a subprogram), then we
2965       --  need to explicitly introduce the new type's concatenation
2966       --  operator since Derive_Subprograms will not inherit the
2967       --  parent's operator.
2968
2969       if Number_Dimensions (Parent_Type) = 1
2970         and then not Is_Limited_Type (Parent_Type)
2971         and then not Is_Derived_Type (Parent_Type)
2972         and then not Is_Package (Scope (Base_Type (Parent_Type)))
2973       then
2974          New_Binary_Operator (Name_Op_Concat, Derived_Type);
2975       end if;
2976    end Build_Derived_Array_Type;
2977
2978    -----------------------------------
2979    -- Build_Derived_Concurrent_Type --
2980    -----------------------------------
2981
2982    procedure Build_Derived_Concurrent_Type
2983      (N            : Node_Id;
2984       Parent_Type  : Entity_Id;
2985       Derived_Type : Entity_Id)
2986    is
2987       D_Constraint : Node_Id;
2988       Disc_Spec    : Node_Id;
2989       Old_Disc     : Entity_Id;
2990       New_Disc     : Entity_Id;
2991
2992       Constraint_Present : constant Boolean :=
2993                              Nkind (Subtype_Indication (Type_Definition (N)))
2994                                                      = N_Subtype_Indication;
2995
2996    begin
2997       Set_Girder_Constraint (Derived_Type, No_Elist);
2998
2999       if Is_Task_Type (Parent_Type) then
3000          Set_Storage_Size_Variable (Derived_Type,
3001            Storage_Size_Variable (Parent_Type));
3002       end if;
3003
3004       if Present (Discriminant_Specifications (N)) then
3005          New_Scope (Derived_Type);
3006          Check_Or_Process_Discriminants (N, Derived_Type);
3007          End_Scope;
3008
3009       elsif Constraint_Present then
3010
3011          --  Build constrained subtype and derive from it
3012
3013          declare
3014             Loc  : constant Source_Ptr := Sloc (N);
3015             Anon : Entity_Id :=
3016                      Make_Defining_Identifier (Loc,
3017                        New_External_Name (Chars (Derived_Type), 'T'));
3018             Decl : Node_Id;
3019
3020          begin
3021             Decl :=
3022               Make_Subtype_Declaration (Loc,
3023                 Defining_Identifier => Anon,
3024                 Subtype_Indication =>
3025                   New_Copy_Tree (Subtype_Indication (Type_Definition (N))));
3026             Insert_Before (N, Decl);
3027             Rewrite (Subtype_Indication (Type_Definition (N)),
3028               New_Occurrence_Of (Anon, Loc));
3029             Analyze (Decl);
3030             Set_Analyzed (Derived_Type, False);
3031             Analyze (N);
3032             return;
3033          end;
3034       end if;
3035
3036       --  All attributes are inherited from parent. In particular,
3037       --  entries and the corresponding record type are the same.
3038       --  Discriminants may be renamed, and must be treated separately.
3039
3040       Set_Has_Discriminants
3041         (Derived_Type, Has_Discriminants         (Parent_Type));
3042       Set_Corresponding_Record_Type
3043         (Derived_Type, Corresponding_Record_Type (Parent_Type));
3044
3045       if Constraint_Present then
3046
3047          if not Has_Discriminants (Parent_Type) then
3048             Error_Msg_N ("untagged parent must have discriminants", N);
3049
3050          elsif Present (Discriminant_Specifications (N)) then
3051
3052             --  Verify that new discriminants are used to constrain
3053             --  the old ones.
3054
3055             Old_Disc   := First_Discriminant (Parent_Type);
3056             New_Disc   := First_Discriminant (Derived_Type);
3057             Disc_Spec  := First (Discriminant_Specifications (N));
3058             D_Constraint :=
3059               First
3060                 (Constraints
3061                   (Constraint (Subtype_Indication (Type_Definition (N)))));
3062
3063             while Present (Old_Disc) and then Present (Disc_Spec) loop
3064
3065                if Nkind (Discriminant_Type (Disc_Spec)) /=
3066                                               N_Access_Definition
3067                then
3068                   Analyze (Discriminant_Type (Disc_Spec));
3069
3070                   if not Subtypes_Statically_Compatible (
3071                              Etype (Discriminant_Type (Disc_Spec)),
3072                                Etype (Old_Disc))
3073                   then
3074                      Error_Msg_N
3075                        ("not statically compatible with parent discriminant",
3076                         Discriminant_Type (Disc_Spec));
3077                   end if;
3078                end if;
3079
3080                if Nkind (D_Constraint) = N_Identifier
3081                  and then Chars (D_Constraint) /=
3082                    Chars (Defining_Identifier (Disc_Spec))
3083                then
3084                   Error_Msg_N ("new discriminants must constrain old ones",
3085                     D_Constraint);
3086                else
3087                   Set_Corresponding_Discriminant (New_Disc, Old_Disc);
3088                end if;
3089
3090                Next_Discriminant (Old_Disc);
3091                Next_Discriminant (New_Disc);
3092                Next (Disc_Spec);
3093             end loop;
3094
3095             if Present (Old_Disc) or else Present (Disc_Spec) then
3096                Error_Msg_N ("discriminant mismatch in derivation", N);
3097             end if;
3098
3099          end if;
3100
3101       elsif Present (Discriminant_Specifications (N)) then
3102          Error_Msg_N
3103            ("missing discriminant constraint in untagged derivation",
3104             N);
3105       end if;
3106
3107       if Present (Discriminant_Specifications (N)) then
3108
3109          Old_Disc := First_Discriminant (Parent_Type);
3110
3111          while Present (Old_Disc) loop
3112
3113             if No (Next_Entity (Old_Disc))
3114               or else Ekind (Next_Entity (Old_Disc)) /= E_Discriminant
3115             then
3116                Set_Next_Entity (Last_Entity (Derived_Type),
3117                                          Next_Entity (Old_Disc));
3118                exit;
3119             end if;
3120
3121             Next_Discriminant (Old_Disc);
3122          end loop;
3123
3124       else
3125          Set_First_Entity (Derived_Type, First_Entity (Parent_Type));
3126          if Has_Discriminants (Parent_Type) then
3127             Set_Discriminant_Constraint (
3128               Derived_Type, Discriminant_Constraint (Parent_Type));
3129          end if;
3130       end if;
3131
3132       Set_Last_Entity  (Derived_Type, Last_Entity  (Parent_Type));
3133
3134       Set_Has_Completion (Derived_Type);
3135    end Build_Derived_Concurrent_Type;
3136
3137    ------------------------------------
3138    -- Build_Derived_Enumeration_Type --
3139    ------------------------------------
3140
3141    procedure Build_Derived_Enumeration_Type
3142      (N            : Node_Id;
3143       Parent_Type  : Entity_Id;
3144       Derived_Type : Entity_Id)
3145    is
3146       Loc           : constant Source_Ptr := Sloc (N);
3147       Def           : constant Node_Id    := Type_Definition (N);
3148       Indic         : constant Node_Id    := Subtype_Indication (Def);
3149       Implicit_Base : Entity_Id;
3150       Literal       : Entity_Id;
3151       New_Lit       : Entity_Id;
3152       Literals_List : List_Id;
3153       Type_Decl     : Node_Id;
3154       Hi, Lo        : Node_Id;
3155       Rang_Expr     : Node_Id;
3156
3157    begin
3158       --  Since types Standard.Character and Standard.Wide_Character do
3159       --  not have explicit literals lists we need to process types derived
3160       --  from them specially. This is handled by Derived_Standard_Character.
3161       --  If the parent type is a generic type, there are no literals either,
3162       --  and we construct the same skeletal representation as for the generic
3163       --  parent type.
3164
3165       if Root_Type (Parent_Type) = Standard_Character
3166         or else Root_Type (Parent_Type) = Standard_Wide_Character
3167       then
3168          Derived_Standard_Character (N, Parent_Type, Derived_Type);
3169
3170       elsif Is_Generic_Type (Root_Type (Parent_Type)) then
3171          declare
3172             Lo : Node_Id;
3173             Hi : Node_Id;
3174
3175          begin
3176             Lo :=
3177                Make_Attribute_Reference (Loc,
3178                  Attribute_Name => Name_First,
3179                  Prefix => New_Reference_To (Derived_Type, Loc));
3180             Set_Etype (Lo, Derived_Type);
3181
3182             Hi :=
3183                Make_Attribute_Reference (Loc,
3184                  Attribute_Name => Name_Last,
3185                  Prefix => New_Reference_To (Derived_Type, Loc));
3186             Set_Etype (Hi, Derived_Type);
3187
3188             Set_Scalar_Range (Derived_Type,
3189                Make_Range (Loc,
3190                  Low_Bound => Lo,
3191                  High_Bound => Hi));
3192          end;
3193
3194       else
3195          --  If a constraint is present, analyze the bounds to catch
3196          --  premature usage of the derived literals.
3197
3198          if Nkind (Indic) = N_Subtype_Indication
3199            and then Nkind (Range_Expression (Constraint (Indic))) = N_Range
3200          then
3201             Analyze (Low_Bound  (Range_Expression (Constraint (Indic))));
3202             Analyze (High_Bound (Range_Expression (Constraint (Indic))));
3203          end if;
3204
3205          --  Introduce an implicit base type for the derived type even
3206          --  if there is no constraint attached to it, since this seems
3207          --  closer to the Ada semantics. Build a full type declaration
3208          --  tree for the derived type using the implicit base type as
3209          --  the defining identifier. The build a subtype declaration
3210          --  tree which applies the constraint (if any) have it replace
3211          --  the derived type declaration.
3212
3213          Literal := First_Literal (Parent_Type);
3214          Literals_List := New_List;
3215
3216          while Present (Literal)
3217            and then Ekind (Literal) = E_Enumeration_Literal
3218          loop
3219             --  Literals of the derived type have the same representation as
3220             --  those of the parent type, but this representation can be
3221             --  overridden by an explicit representation clause. Indicate
3222             --  that there is no explicit representation given yet. These
3223             --  derived literals are implicit operations of the new type,
3224             --  and can be overriden by explicit ones.
3225
3226             if Nkind (Literal) = N_Defining_Character_Literal then
3227                New_Lit :=
3228                  Make_Defining_Character_Literal (Loc, Chars (Literal));
3229             else
3230                New_Lit := Make_Defining_Identifier (Loc, Chars (Literal));
3231             end if;
3232
3233             Set_Ekind                (New_Lit, E_Enumeration_Literal);
3234             Set_Enumeration_Pos      (New_Lit, Enumeration_Pos (Literal));
3235             Set_Enumeration_Rep      (New_Lit, Enumeration_Rep (Literal));
3236             Set_Enumeration_Rep_Expr (New_Lit, Empty);
3237             Set_Alias                (New_Lit, Literal);
3238             Set_Is_Known_Valid       (New_Lit, True);
3239
3240             Append (New_Lit, Literals_List);
3241             Next_Literal (Literal);
3242          end loop;
3243
3244          Implicit_Base :=
3245            Make_Defining_Identifier (Sloc (Derived_Type),
3246              New_External_Name (Chars (Derived_Type), 'B'));
3247
3248          --  Indicate the proper nature of the derived type. This must
3249          --  be done before analysis of the literals, to recognize cases
3250          --  when a literal may be hidden by a previous explicit function
3251          --  definition (cf. c83031a).
3252
3253          Set_Ekind (Derived_Type, E_Enumeration_Subtype);
3254          Set_Etype (Derived_Type, Implicit_Base);
3255
3256          Type_Decl :=
3257            Make_Full_Type_Declaration (Loc,
3258              Defining_Identifier => Implicit_Base,
3259              Discriminant_Specifications => No_List,
3260              Type_Definition =>
3261                Make_Enumeration_Type_Definition (Loc, Literals_List));
3262
3263          Mark_Rewrite_Insertion (Type_Decl);
3264          Insert_Before (N, Type_Decl);
3265          Analyze (Type_Decl);
3266
3267          --  After the implicit base is analyzed its Etype needs to be
3268          --  changed to reflect the fact that it is derived from the
3269          --  parent type which was ignored during analysis. We also set
3270          --  the size at this point.
3271
3272          Set_Etype (Implicit_Base, Parent_Type);
3273
3274          Set_Size_Info      (Implicit_Base,                 Parent_Type);
3275          Set_RM_Size        (Implicit_Base, RM_Size        (Parent_Type));
3276          Set_First_Rep_Item (Implicit_Base, First_Rep_Item (Parent_Type));
3277
3278          Set_Has_Non_Standard_Rep
3279                             (Implicit_Base, Has_Non_Standard_Rep
3280                                                            (Parent_Type));
3281          Set_Has_Delayed_Freeze (Implicit_Base);
3282
3283          --  Process the subtype indication including a validation check
3284          --  on the constraint, if any. If a constraint is given, its bounds
3285          --  must be implicitly converted to the new type.
3286
3287          if Nkind (Indic) = N_Subtype_Indication then
3288
3289             declare
3290                R   : constant Node_Id :=
3291                        Range_Expression (Constraint (Indic));
3292
3293             begin
3294                if Nkind (R) = N_Range then
3295                   Hi := Build_Scalar_Bound
3296                           (High_Bound (R), Parent_Type, Implicit_Base, Loc);
3297                   Lo := Build_Scalar_Bound
3298                           (Low_Bound  (R), Parent_Type, Implicit_Base, Loc);
3299
3300                else
3301                   --  Constraint is a Range attribute. Replace with the
3302                   --  explicit mention of the bounds of the prefix, which
3303                   --  must be a subtype.
3304
3305                   Analyze (Prefix (R));
3306                   Hi :=
3307                     Convert_To (Implicit_Base,
3308                       Make_Attribute_Reference (Loc,
3309                         Attribute_Name => Name_Last,
3310                         Prefix =>
3311                           New_Occurrence_Of (Entity (Prefix (R)), Loc)));
3312
3313                   Lo :=
3314                     Convert_To (Implicit_Base,
3315                       Make_Attribute_Reference (Loc,
3316                         Attribute_Name => Name_First,
3317                         Prefix =>
3318                           New_Occurrence_Of (Entity (Prefix (R)), Loc)));
3319                end if;
3320
3321             end;
3322
3323          else
3324             Hi :=
3325               Build_Scalar_Bound
3326                 (Type_High_Bound (Parent_Type),
3327                  Parent_Type, Implicit_Base, Loc);
3328             Lo :=
3329                Build_Scalar_Bound
3330                  (Type_Low_Bound (Parent_Type),
3331                   Parent_Type, Implicit_Base, Loc);
3332          end if;
3333
3334          Rang_Expr :=
3335            Make_Range (Loc,
3336              Low_Bound  => Lo,
3337              High_Bound => Hi);
3338
3339          --  If we constructed a default range for the case where no range
3340          --  was given, then the expressions in the range must not freeze
3341          --  since they do not correspond to expressions in the source.
3342
3343          if Nkind (Indic) /= N_Subtype_Indication then
3344             Set_Must_Not_Freeze (Lo);
3345             Set_Must_Not_Freeze (Hi);
3346             Set_Must_Not_Freeze (Rang_Expr);
3347          end if;
3348
3349          Rewrite (N,
3350            Make_Subtype_Declaration (Loc,
3351              Defining_Identifier => Derived_Type,
3352              Subtype_Indication =>
3353                Make_Subtype_Indication (Loc,
3354                  Subtype_Mark => New_Occurrence_Of (Implicit_Base, Loc),
3355                  Constraint =>
3356                    Make_Range_Constraint (Loc,
3357                      Range_Expression => Rang_Expr))));
3358
3359          Analyze (N);
3360
3361          --  If pragma Discard_Names applies on the first subtype
3362          --  of the parent type, then it must be applied on this
3363          --  subtype as well.
3364
3365          if Einfo.Discard_Names (First_Subtype (Parent_Type)) then
3366             Set_Discard_Names (Derived_Type);
3367          end if;
3368
3369          --  Apply a range check. Since this range expression doesn't
3370          --  have an Etype, we have to specifically pass the Source_Typ
3371          --  parameter. Is this right???
3372
3373          if Nkind (Indic) = N_Subtype_Indication then
3374             Apply_Range_Check (Range_Expression (Constraint (Indic)),
3375                                Parent_Type,
3376                                Source_Typ => Entity (Subtype_Mark (Indic)));
3377          end if;
3378       end if;
3379
3380    end Build_Derived_Enumeration_Type;
3381
3382    --------------------------------
3383    -- Build_Derived_Numeric_Type --
3384    --------------------------------
3385
3386    procedure Build_Derived_Numeric_Type
3387      (N            : Node_Id;
3388       Parent_Type  : Entity_Id;
3389       Derived_Type : Entity_Id)
3390    is
3391       Loc           : constant Source_Ptr := Sloc (N);
3392       Tdef          : constant Node_Id    := Type_Definition (N);
3393       Indic         : constant Node_Id    := Subtype_Indication (Tdef);
3394       Parent_Base   : constant Entity_Id  := Base_Type (Parent_Type);
3395       No_Constraint : constant Boolean    := Nkind (Indic) /=
3396                                                   N_Subtype_Indication;
3397       Implicit_Base    : Entity_Id;
3398
3399       Lo : Node_Id;
3400       Hi : Node_Id;
3401       T  : Entity_Id;
3402
3403    begin
3404       --  Process the subtype indication including a validation check on
3405       --  the constraint if any.
3406
3407       T := Process_Subtype (Indic, N);
3408
3409       --  Introduce an implicit base type for the derived type even if
3410       --  there is no constraint attached to it, since this seems closer
3411       --  to the Ada semantics.
3412
3413       Implicit_Base :=
3414         Create_Itype (Ekind (Parent_Base), N, Derived_Type, 'B');
3415
3416       Set_Etype          (Implicit_Base, Parent_Base);
3417       Set_Ekind          (Implicit_Base, Ekind          (Parent_Base));
3418       Set_Size_Info      (Implicit_Base,                 Parent_Base);
3419       Set_RM_Size        (Implicit_Base, RM_Size        (Parent_Base));
3420       Set_First_Rep_Item (Implicit_Base, First_Rep_Item (Parent_Base));
3421       Set_Parent         (Implicit_Base, Parent (Derived_Type));
3422
3423       if Is_Discrete_Or_Fixed_Point_Type (Parent_Base) then
3424          Set_RM_Size (Implicit_Base, RM_Size (Parent_Base));
3425       end if;
3426
3427       Set_Has_Delayed_Freeze (Implicit_Base);
3428
3429       Lo := New_Copy_Tree (Type_Low_Bound  (Parent_Base));
3430       Hi := New_Copy_Tree (Type_High_Bound (Parent_Base));
3431
3432       Set_Scalar_Range (Implicit_Base,
3433         Make_Range (Loc,
3434           Low_Bound  => Lo,
3435           High_Bound => Hi));
3436
3437       if Has_Infinities (Parent_Base) then
3438          Set_Includes_Infinities (Scalar_Range (Implicit_Base));
3439       end if;
3440
3441       --  The Derived_Type, which is the entity of the declaration, is
3442       --  a subtype of the implicit base. Its Ekind is a subtype, even
3443       --  in the absence of an explicit constraint.
3444
3445       Set_Etype (Derived_Type, Implicit_Base);
3446
3447       --  If we did not have a constraint, then the Ekind is set from the
3448       --  parent type (otherwise Process_Subtype has set the bounds)
3449
3450       if No_Constraint then
3451          Set_Ekind (Derived_Type, Subtype_Kind (Ekind (Parent_Type)));
3452       end if;
3453
3454       --  If we did not have a range constraint, then set the range
3455       --  from the parent type. Otherwise, the call to Process_Subtype
3456       --  has set the bounds.
3457
3458       if No_Constraint
3459         or else not Has_Range_Constraint (Indic)
3460       then
3461          Set_Scalar_Range (Derived_Type,
3462            Make_Range (Loc,
3463              Low_Bound  => New_Copy_Tree (Type_Low_Bound  (Parent_Type)),
3464              High_Bound => New_Copy_Tree (Type_High_Bound (Parent_Type))));
3465          Set_Is_Constrained (Derived_Type, Is_Constrained (Parent_Type));
3466
3467          if Has_Infinities (Parent_Type) then
3468             Set_Includes_Infinities (Scalar_Range (Derived_Type));
3469          end if;
3470       end if;
3471
3472       --  Set remaining type-specific fields, depending on numeric type
3473
3474       if Is_Modular_Integer_Type (Parent_Type) then
3475          Set_Modulus (Implicit_Base, Modulus (Parent_Base));
3476
3477          Set_Non_Binary_Modulus
3478            (Implicit_Base, Non_Binary_Modulus (Parent_Base));
3479
3480       elsif Is_Floating_Point_Type (Parent_Type) then
3481
3482          --  Digits of base type is always copied from the digits value of
3483          --  the parent base type, but the digits of the derived type will
3484          --  already have been set if there was a constraint present.
3485
3486          Set_Digits_Value (Implicit_Base, Digits_Value (Parent_Base));
3487          Set_Vax_Float    (Implicit_Base, Vax_Float    (Parent_Base));
3488
3489          if No_Constraint then
3490             Set_Digits_Value (Derived_Type, Digits_Value (Parent_Type));
3491          end if;
3492
3493       elsif Is_Fixed_Point_Type (Parent_Type) then
3494
3495          --  Small of base type and derived type are always copied from
3496          --  the parent base type, since smalls never change. The delta
3497          --  of the base type is also copied from the parent base type.
3498          --  However the delta of the derived type will have been set
3499          --  already if a constraint was present.
3500
3501          Set_Small_Value (Derived_Type,  Small_Value (Parent_Base));
3502          Set_Small_Value (Implicit_Base, Small_Value (Parent_Base));
3503          Set_Delta_Value (Implicit_Base, Delta_Value (Parent_Base));
3504
3505          if No_Constraint then
3506             Set_Delta_Value (Derived_Type,  Delta_Value (Parent_Type));
3507          end if;
3508
3509          --  The scale and machine radix in the decimal case are always
3510          --  copied from the parent base type.
3511
3512          if Is_Decimal_Fixed_Point_Type (Parent_Type) then
3513             Set_Scale_Value (Derived_Type,  Scale_Value (Parent_Base));
3514             Set_Scale_Value (Implicit_Base, Scale_Value (Parent_Base));
3515
3516             Set_Machine_Radix_10
3517               (Derived_Type,  Machine_Radix_10 (Parent_Base));
3518             Set_Machine_Radix_10
3519               (Implicit_Base, Machine_Radix_10 (Parent_Base));
3520
3521             Set_Digits_Value (Implicit_Base, Digits_Value (Parent_Base));
3522
3523             if No_Constraint then
3524                Set_Digits_Value (Derived_Type, Digits_Value (Parent_Base));
3525
3526             else
3527                --  the analysis of the subtype_indication sets the
3528                --  digits value of the derived type.
3529
3530                null;
3531             end if;
3532          end if;
3533       end if;
3534
3535       --  The type of the bounds is that of the parent type, and they
3536       --  must be converted to the derived type.
3537
3538       Convert_Scalar_Bounds (N, Parent_Type, Derived_Type, Loc);
3539
3540       --  The implicit_base should be frozen when the derived type is frozen,
3541       --  but note that it is used in the conversions of the bounds. For
3542       --  fixed types we delay the determination of the bounds until the proper
3543       --  freezing point. For other numeric types this is rejected by GCC, for
3544       --  reasons that are currently unclear (???), so we choose to freeze the
3545       --  implicit base now. In the case of integers and floating point types
3546       --  this is harmless because subsequent representation clauses cannot
3547       --  affect anything, but it is still baffling that we cannot use the
3548       --  same mechanism for all derived numeric types.
3549
3550       if Is_Fixed_Point_Type (Parent_Type) then
3551          Conditional_Delay (Implicit_Base, Parent_Type);
3552       else
3553          Freeze_Before (N, Implicit_Base);
3554       end if;
3555
3556    end Build_Derived_Numeric_Type;
3557
3558    --------------------------------
3559    -- Build_Derived_Private_Type --
3560    --------------------------------
3561
3562    procedure Build_Derived_Private_Type
3563      (N            : Node_Id;
3564       Parent_Type  : Entity_Id;
3565       Derived_Type : Entity_Id;
3566       Is_Completion : Boolean;
3567       Derive_Subps  : Boolean := True)
3568    is
3569       Der_Base    : Entity_Id;
3570       Discr       : Entity_Id;
3571       Full_Decl   : Node_Id := Empty;
3572       Full_Der    : Entity_Id;
3573       Full_P      : Entity_Id;
3574       Last_Discr  : Entity_Id;
3575       Par_Scope   : constant Entity_Id := Scope (Base_Type (Parent_Type));
3576       Swapped     : Boolean := False;
3577
3578       procedure Copy_And_Build;
3579       --  Copy derived type declaration, replace parent with its full view,
3580       --  and analyze new declaration.
3581
3582       procedure Copy_And_Build is
3583          Full_N  : Node_Id;
3584
3585       begin
3586          if Ekind (Parent_Type) in Record_Kind
3587            or else (Ekind (Parent_Type) in Enumeration_Kind
3588              and then Root_Type (Parent_Type) /= Standard_Character
3589              and then Root_Type (Parent_Type) /= Standard_Wide_Character
3590              and then not Is_Generic_Type (Root_Type (Parent_Type)))
3591          then
3592             Full_N := New_Copy_Tree (N);
3593             Insert_After (N, Full_N);
3594             Build_Derived_Type (
3595               Full_N, Parent_Type, Full_Der, True, Derive_Subps => False);
3596
3597          else
3598             Build_Derived_Type (
3599               N, Parent_Type, Full_Der, True, Derive_Subps => False);
3600          end if;
3601       end Copy_And_Build;
3602
3603    --  Start of processing for Build_Derived_Private_Type
3604
3605    begin
3606       if Is_Tagged_Type (Parent_Type) then
3607          Build_Derived_Record_Type
3608            (N, Parent_Type, Derived_Type, Derive_Subps);
3609          return;
3610
3611       elsif Has_Discriminants (Parent_Type) then
3612
3613          if Present (Full_View (Parent_Type)) then
3614             if not Is_Completion then
3615
3616                --  Copy declaration for subsequent analysis.
3617
3618                Full_Decl := New_Copy_Tree (N);
3619                Full_Der  := New_Copy (Derived_Type);
3620                Insert_After (N, Full_Decl);
3621
3622             else
3623                --  If this is a completion, the full view being built is
3624                --  itself private. We build a subtype of the parent with
3625                --  the same constraints as this full view, to convey to the
3626                --  back end the constrained components and the size of this
3627                --  subtype. If the parent is constrained, its full view can
3628                --  serve as the underlying full view of the derived type.
3629
3630                if No (Discriminant_Specifications (N)) then
3631
3632                   if Nkind (Subtype_Indication (Type_Definition (N)))
3633                     = N_Subtype_Indication
3634                   then
3635                      Build_Underlying_Full_View (N, Derived_Type, Parent_Type);
3636
3637                   elsif Is_Constrained (Full_View (Parent_Type)) then
3638                      Set_Underlying_Full_View (Derived_Type,
3639                        Full_View (Parent_Type));
3640                   end if;
3641
3642                else
3643                   --  If there are new discriminants, the parent subtype is
3644                   --  constrained by them, but it is not clear how to build
3645                   --  the underlying_full_view in this case ???
3646
3647                   null;
3648                end if;
3649             end if;
3650          end if;
3651
3652          Build_Derived_Record_Type
3653            (N, Parent_Type, Derived_Type, Derive_Subps);
3654
3655          if Present (Full_View (Parent_Type))
3656            and then not Is_Completion
3657          then
3658             if not In_Open_Scopes (Par_Scope)
3659               or else not In_Same_Source_Unit (N, Parent_Type)
3660             then
3661                --  Swap partial and full views temporarily
3662
3663                Install_Private_Declarations (Par_Scope);
3664                Install_Visible_Declarations (Par_Scope);
3665                Swapped := True;
3666             end if;
3667
3668             --  Subprograms have been derived on the private view,
3669             --  the completion does not derive them anew.
3670
3671             Build_Derived_Record_Type
3672               (Full_Decl, Parent_Type, Full_Der, False);
3673
3674             if Swapped then
3675                Uninstall_Declarations (Par_Scope);
3676
3677                if In_Open_Scopes (Par_Scope) then
3678                   Install_Visible_Declarations (Par_Scope);
3679                end if;
3680             end if;
3681
3682             Der_Base := Base_Type (Derived_Type);
3683             Set_Full_View (Derived_Type, Full_Der);
3684             Set_Full_View (Der_Base, Base_Type (Full_Der));
3685
3686             --  Copy the discriminant list from full view to
3687             --  the partial views (base type and its subtype).
3688             --  Gigi requires that the partial and full views
3689             --  have the same discriminants.
3690             --  ??? Note that since the partial view is pointing
3691             --  to discriminants in the full view, their scope
3692             --  will be that of the full view. This might
3693             --  cause some front end problems and need
3694             --  adustment?
3695
3696             Discr := First_Discriminant (Base_Type (Full_Der));
3697             Set_First_Entity (Der_Base, Discr);
3698
3699             loop
3700                Last_Discr := Discr;
3701                Next_Discriminant (Discr);
3702                exit when No (Discr);
3703             end loop;
3704
3705             Set_Last_Entity (Der_Base, Last_Discr);
3706
3707             Set_First_Entity (Derived_Type, First_Entity (Der_Base));
3708             Set_Last_Entity  (Derived_Type, Last_Entity  (Der_Base));
3709
3710          else
3711             --  If this is a completion, the derived type stays private
3712             --  and there is no need to create a further full view, except
3713             --  in the unusual case when the derivation is nested within a
3714             --  child unit, see below.
3715
3716             null;
3717          end if;
3718
3719       elsif Present (Full_View (Parent_Type))
3720         and then  Has_Discriminants (Full_View (Parent_Type))
3721       then
3722          if Has_Unknown_Discriminants (Parent_Type)
3723            and then Nkind (Subtype_Indication (Type_Definition (N)))
3724              = N_Subtype_Indication
3725          then
3726             Error_Msg_N
3727               ("cannot constrain type with unknown discriminants",
3728                Subtype_Indication (Type_Definition (N)));
3729             return;
3730          end if;
3731
3732          --  Inherit the discriminants of the full view, but
3733          --  keep the proper parent type.
3734
3735          --  ??? this looks wrong, we are replacing (and thus,
3736          --  erasing) the partial view!
3737
3738          --  In any case, the primitive operations are inherited from
3739          --  the parent type, not from the internal full view.
3740
3741          Build_Derived_Record_Type
3742            (N, Full_View (Parent_Type), Derived_Type,
3743              Derive_Subps => False);
3744          Set_Etype (Base_Type (Derived_Type), Base_Type (Parent_Type));
3745
3746          if Derive_Subps then
3747             Derive_Subprograms (Parent_Type, Derived_Type);
3748          end if;
3749
3750       else
3751
3752          --  Untagged type, No discriminants on either view.
3753
3754          if Nkind (Subtype_Indication (Type_Definition (N)))
3755            = N_Subtype_Indication
3756          then
3757             Error_Msg_N
3758               ("illegal constraint on type without discriminants", N);
3759          end if;
3760
3761          if Present (Discriminant_Specifications (N))
3762            and then Present (Full_View (Parent_Type))
3763            and then not Is_Tagged_Type (Full_View (Parent_Type))
3764          then
3765             Error_Msg_N
3766               ("cannot add discriminants to untagged type", N);
3767          end if;
3768
3769          Set_Girder_Constraint (Derived_Type, No_Elist);
3770          Set_Is_Constrained (Derived_Type, Is_Constrained (Parent_Type));
3771          Set_Is_Controlled  (Derived_Type, Is_Controlled  (Parent_Type));
3772          Set_Has_Controlled_Component (Derived_Type,
3773            Has_Controlled_Component (Parent_Type));
3774
3775          --  Direct controlled types do not inherit the Finalize_Storage_Only
3776          --  flag.
3777
3778          if not Is_Controlled  (Parent_Type) then
3779             Set_Finalize_Storage_Only (Derived_Type,
3780               Finalize_Storage_Only (Parent_Type));
3781          end if;
3782
3783          --  Construct the implicit full view by deriving from full
3784          --  view of the parent type. In order to get proper visiblity,
3785          --  we install the parent scope and its declarations.
3786
3787          --  ??? if the parent is untagged private and its
3788          --  completion is tagged, this mechanism will not
3789          --  work because we cannot derive from the tagged
3790          --  full view unless we have an extension
3791
3792          if Present (Full_View (Parent_Type))
3793            and then not Is_Tagged_Type (Full_View (Parent_Type))
3794            and then not Is_Completion
3795          then
3796             Full_Der := Make_Defining_Identifier (Sloc (Derived_Type),
3797                                               Chars (Derived_Type));
3798             Set_Is_Itype (Full_Der);
3799             Set_Has_Private_Declaration (Full_Der);
3800             Set_Has_Private_Declaration (Derived_Type);
3801             Set_Associated_Node_For_Itype (Full_Der, N);
3802             Set_Parent (Full_Der, Parent (Derived_Type));
3803             Set_Full_View (Derived_Type, Full_Der);
3804
3805             if not In_Open_Scopes (Par_Scope) then
3806                Install_Private_Declarations (Par_Scope);
3807                Install_Visible_Declarations (Par_Scope);
3808                Copy_And_Build;
3809                Uninstall_Declarations (Par_Scope);
3810
3811             --  If parent scope is open and in another unit, and
3812             --  parent has a completion, then the derivation is taking
3813             --  place in the visible part of a child unit. In that
3814             --  case retrieve the full view of the parent momentarily.
3815
3816             elsif not In_Same_Source_Unit (N, Parent_Type) then
3817                Full_P := Full_View (Parent_Type);
3818                Exchange_Declarations (Parent_Type);
3819                Copy_And_Build;
3820                Exchange_Declarations (Full_P);
3821
3822             --  Otherwise it is a local derivation.
3823
3824             else
3825                Copy_And_Build;
3826             end if;
3827
3828             Set_Scope                (Full_Der, Current_Scope);
3829             Set_Is_First_Subtype     (Full_Der,
3830                                        Is_First_Subtype (Derived_Type));
3831             Set_Has_Size_Clause      (Full_Der, False);
3832             Set_Has_Alignment_Clause (Full_Der, False);
3833             Set_Next_Entity          (Full_Der, Empty);
3834             Set_Has_Delayed_Freeze   (Full_Der);
3835             Set_Is_Frozen            (Full_Der, False);
3836             Set_Freeze_Node          (Full_Der, Empty);
3837             Set_Depends_On_Private   (Full_Der,
3838                                         Has_Private_Component    (Full_Der));
3839             Set_Public_Status        (Full_Der);
3840          end if;
3841       end if;
3842
3843       Set_Has_Unknown_Discriminants (Derived_Type,
3844         Has_Unknown_Discriminants (Parent_Type));
3845
3846       if Is_Private_Type (Derived_Type) then
3847          Set_Private_Dependents (Derived_Type, New_Elmt_List);
3848       end if;
3849
3850       if Is_Private_Type (Parent_Type)
3851         and then Base_Type (Parent_Type) = Parent_Type
3852         and then In_Open_Scopes (Scope (Parent_Type))
3853       then
3854          Append_Elmt (Derived_Type, Private_Dependents (Parent_Type));
3855
3856          if Is_Child_Unit (Scope (Current_Scope))
3857            and then Is_Completion
3858            and then In_Private_Part (Current_Scope)
3859            and then Scope (Parent_Type) /= Current_Scope
3860          then
3861             --  This is the unusual case where a type completed by a private
3862             --  derivation occurs within a package nested in a child unit,
3863             --  and the parent is declared in an ancestor. In this case, the
3864             --  full view of the parent type will become visible in the body
3865             --  of the enclosing child, and only then will the current type
3866             --  be possibly non-private. We build a underlying full view that
3867             --  will be installed when the enclosing child body is compiled.
3868
3869             declare
3870                IR : constant Node_Id := Make_Itype_Reference (Sloc (N));
3871
3872             begin
3873                Full_Der :=
3874                  Make_Defining_Identifier (Sloc (Derived_Type),
3875                    Chars (Derived_Type));
3876                Set_Is_Itype (Full_Der);
3877                Set_Itype (IR, Full_Der);
3878                Insert_After (N, IR);
3879
3880                --  The full view will be used to swap entities on entry/exit
3881                --  to the body, and must appear in the entity list for the
3882                --  package.
3883
3884                Append_Entity (Full_Der, Scope (Derived_Type));
3885                Set_Has_Private_Declaration (Full_Der);
3886                Set_Has_Private_Declaration (Derived_Type);
3887                Set_Associated_Node_For_Itype (Full_Der, N);
3888                Set_Parent (Full_Der, Parent (Derived_Type));
3889                Full_P := Full_View (Parent_Type);
3890                Exchange_Declarations (Parent_Type);
3891                Copy_And_Build;
3892                Exchange_Declarations (Full_P);
3893                Set_Underlying_Full_View (Derived_Type, Full_Der);
3894             end;
3895          end if;
3896       end if;
3897    end Build_Derived_Private_Type;
3898
3899    -------------------------------
3900    -- Build_Derived_Record_Type --
3901    -------------------------------
3902
3903    --  1. INTRODUCTION.
3904
3905    --  Ideally we would like to use the same model of type derivation for
3906    --  tagged and untagged record types. Unfortunately this is not quite
3907    --  possible because the semantics of representation clauses is different
3908    --  for tagged and untagged records under inheritance. Consider the
3909    --  following:
3910
3911    --     type R (...) is [tagged] record ... end record;
3912    --     type T (...) is new R (...) [with ...];
3913
3914    --  The representation clauses of T can specify a completely different
3915    --  record layout from R's. Hence a same component can be placed in two very
3916    --  different positions in objects of type T and R. If R and T are tagged
3917    --  types, representation clauses for T can only specify the layout of non
3918    --  inherited components, thus components that are common in R and T have
3919    --  the same position in objects of type R or T.
3920
3921    --  This has two implications. The first is that the entire tree for R's
3922    --  declaration needs to be copied for T in the untagged case, so that
3923    --  T can be viewd as a record type of its own with its own derivation
3924    --  clauses. The second implication is the way we handle discriminants.
3925    --  Specifically, in the untagged case we need a way to communicate to Gigi
3926    --  what are the real discriminants in the record, while for the semantics
3927    --  we need to consider those introduced by the user to rename the
3928    --  discriminants in the parent type. This is handled by introducing the
3929    --  notion of girder discriminants. See below for more.
3930
3931    --  Fortunately the way regular components are inherited can be handled in
3932    --  the same way in tagged and untagged types.
3933
3934    --  To complicate things a bit more the private view of a private extension
3935    --  cannot be handled in the same way as the full view (for one thing the
3936    --  semantic rules are somewhat different). We will explain what differs
3937    --  below.
3938
3939    --  2. DISCRIMINANTS UNDER INHERITANCE.
3940
3941    --  The semantic rules governing the discriminants of derived types are
3942    --  quite subtle.
3943
3944    --   type Derived_Type_Name [KNOWN_DISCRIMINANT_PART] is new
3945    --      [abstract]  Parent_Type_Name [CONSTRAINT] [RECORD_EXTENSION_PART]
3946
3947    --  If parent type has discriminants, then the discriminants that are
3948    --  declared in the derived type are [3.4 (11)]:
3949
3950    --  o The discriminants specified by a new KNOWN_DISCRIMINANT_PART, if
3951    --    there is one;
3952
3953    --  o Otherwise, each discriminant of the parent type (implicitly
3954    --    declared in the same order with the same specifications). In this
3955    --    case, the discriminants are said to be "inherited", or if unknown in
3956    --    the parent are also unknown in the derived type.
3957
3958    --  Furthermore if a KNOWN_DISCRIMINANT_PART is provided, then [3.7(13-18)]:
3959
3960    --  o The parent subtype shall be constrained;
3961
3962    --  o If the parent type is not a tagged type, then each discriminant of
3963    --    the derived type shall be used in the constraint defining a parent
3964    --    subtype [Implementation note: this ensures that the new discriminant
3965    --    can share storage with an existing discriminant.].
3966
3967    --  For the derived type each discriminant of the parent type is either
3968    --  inherited, constrained to equal some new discriminant of the derived
3969    --  type, or constrained to the value of an expression.
3970
3971    --  When inherited or constrained to equal some new discriminant, the
3972    --  parent discriminant and the discriminant of the derived type are said
3973    --  to "correspond".
3974
3975    --  If a discriminant of the parent type is constrained to a specific value
3976    --  in the derived type definition, then the discriminant is said to be
3977    --  "specified" by that derived type definition.
3978
3979    --  3. DISCRIMINANTS IN DERIVED UNTAGGED RECORD TYPES.
3980
3981    --  We have spoken about girder discriminants in the point 1 (introduction)
3982    --  above. There are two sort of girder discriminants: implicit and
3983    --  explicit. As long as the derived type inherits the same discriminants as
3984    --  the root record type, girder discriminants are the same as regular
3985    --  discriminants, and are said to be implicit. However, if any discriminant
3986    --  in the root type was renamed in the derived type, then the derived
3987    --  type will contain explicit girder discriminants. Explicit girder
3988    --  discriminants are discriminants in addition to the semantically visible
3989    --  discriminants defined for the derived type. Girder discriminants are
3990    --  used by Gigi to figure out what are the physical discriminants in
3991    --  objects of the derived type (see precise definition in einfo.ads).
3992    --  As an example, consider the following:
3993
3994    --           type R  (D1, D2, D3 : Int) is record ... end record;
3995    --           type T1 is new R;
3996    --           type T2 (X1, X2: Int) is new T1 (X2, 88, X1);
3997    --           type T3 is new T2;
3998    --           type T4 (Y : Int) is new T3 (Y, 99);
3999
4000    --  The following table summarizes the discriminants and girder
4001    --  discriminants in R and T1 through T4.
4002
4003    --   Type      Discrim     Girder Discrim  Comment
4004    --    R      (D1, D2, D3)   (D1, D2, D3)   Gider discrims are implicit in R
4005    --    T1     (D1, D2, D3)   (D1, D2, D3)   Gider discrims are implicit in T1
4006    --    T2     (X1, X2)       (D1, D2, D3)   Gider discrims are EXPLICIT in T2
4007    --    T3     (X1, X2)       (D1, D2, D3)   Gider discrims are EXPLICIT in T3
4008    --    T4     (Y)            (D1, D2, D3)   Gider discrims are EXPLICIT in T4
4009
4010    --  Field Corresponding_Discriminant (abbreviated CD below) allows to find
4011    --  the corresponding discriminant in the parent type, while
4012    --  Original_Record_Component (abbreviated ORC below), the actual physical
4013    --  component that is renamed. Finally the field Is_Completely_Hidden
4014    --  (abbreaviated ICH below) is set for all explicit girder discriminants
4015    --  (see einfo.ads for more info). For the above example this gives:
4016
4017    --                 Discrim     CD        ORC     ICH
4018    --                 ^^^^^^^     ^^        ^^^     ^^^
4019    --                 D1 in R    empty     itself    no
4020    --                 D2 in R    empty     itself    no
4021    --                 D3 in R    empty     itself    no
4022
4023    --                 D1 in T1  D1 in R    itself    no
4024    --                 D2 in T1  D2 in R    itself    no
4025    --                 D3 in T1  D3 in R    itself    no
4026
4027    --                 X1 in T2  D3 in T1  D3 in T2   no
4028    --                 X2 in T2  D1 in T1  D1 in T2   no
4029    --                 D1 in T2   empty    itself    yes
4030    --                 D2 in T2   empty    itself    yes
4031    --                 D3 in T2   empty    itself    yes
4032
4033    --                 X1 in T3  X1 in T2  D3 in T3   no
4034    --                 X2 in T3  X2 in T2  D1 in T3   no
4035    --                 D1 in T3   empty    itself    yes
4036    --                 D2 in T3   empty    itself    yes
4037    --                 D3 in T3   empty    itself    yes
4038
4039    --                 Y  in T4  X1 in T3  D3 in T3   no
4040    --                 D1 in T3   empty    itself    yes
4041    --                 D2 in T3   empty    itself    yes
4042    --                 D3 in T3   empty    itself    yes
4043
4044    --  4. DISCRIMINANTS IN DERIVED TAGGED RECORD TYPES.
4045
4046    --  Type derivation for tagged types is fairly straightforward. if no
4047    --  discriminants are specified by the derived type, these are inherited
4048    --  from the parent. No explicit girder discriminants are ever necessary.
4049    --  The only manipulation that is done to the tree is that of adding a
4050    --  _parent field with parent type and constrained to the same constraint
4051    --  specified for the parent in the derived type definition. For instance:
4052
4053    --           type R  (D1, D2, D3 : Int) is tagged record ... end record;
4054    --           type T1 is new R with null record;
4055    --           type T2 (X1, X2: Int) is new T1 (X2, 88, X1) with null record;
4056
4057    --  are changed into :
4058
4059    --           type T1 (D1, D2, D3 : Int) is new R (D1, D2, D3) with record
4060    --              _parent : R (D1, D2, D3);
4061    --           end record;
4062
4063    --           type T2 (X1, X2: Int) is new T1 (X2, 88, X1) with record
4064    --              _parent : T1 (X2, 88, X1);
4065    --           end record;
4066
4067    --  The discriminants actually present in R, T1 and T2 as well as their CD,
4068    --  ORC and ICH fields are:
4069
4070    --                 Discrim     CD        ORC     ICH
4071    --                 ^^^^^^^     ^^        ^^^     ^^^
4072    --                 D1 in R    empty     itself    no
4073    --                 D2 in R    empty     itself    no
4074    --                 D3 in R    empty     itself    no
4075
4076    --                 D1 in T1  D1 in R    D1 in R   no
4077    --                 D2 in T1  D2 in R    D2 in R   no
4078    --                 D3 in T1  D3 in R    D3 in R   no
4079
4080    --                 X1 in T2  D3 in T1   D3 in R   no
4081    --                 X2 in T2  D1 in T1   D1 in R   no
4082
4083    --  5. FIRST TRANSFORMATION FOR DERIVED RECORDS.
4084    --
4085    --  Regardless of whether we dealing with a tagged or untagged type
4086    --  we will transform all derived type declarations of the form
4087    --
4088    --               type T is new R (...) [with ...];
4089    --  or
4090    --               subtype S is R (...);
4091    --               type T is new S [with ...];
4092    --  into
4093    --               type BT is new R [with ...];
4094    --               subtype T is BT (...);
4095    --
4096    --  That is, the base derived type is constrained only if it has no
4097    --  discriminants. The reason for doing this is that GNAT's semantic model
4098    --  assumes that a base type with discriminants is unconstrained.
4099    --
4100    --  Note that, strictly speaking, the above transformation is not always
4101    --  correct. Consider for instance the following exercpt from ACVC b34011a:
4102    --
4103    --       procedure B34011A is
4104    --          type REC (D : integer := 0) is record
4105    --             I : Integer;
4106    --          end record;
4107
4108    --          package P is
4109    --             type T6 is new Rec;
4110    --             function F return T6;
4111    --          end P;
4112
4113    --          use P;
4114    --          package Q6 is
4115    --             type U is new T6 (Q6.F.I);                   -- ERROR: Q6.F.
4116    --          end Q6;
4117    --
4118    --  The definition of Q6.U is illegal. However transforming Q6.U into
4119
4120    --             type BaseU is new T6;
4121    --             subtype U is BaseU (Q6.F.I)
4122
4123    --  turns U into a legal subtype, which is incorrect. To avoid this problem
4124    --  we always analyze the constraint (in this case (Q6.F.I)) before applying
4125    --  the transformation described above.
4126
4127    --  There is another instance where the above transformation is incorrect.
4128    --  Consider:
4129
4130    --          package Pack is
4131    --             type Base (D : Integer) is tagged null record;
4132    --             procedure P (X : Base);
4133
4134    --             type Der is new Base (2) with null record;
4135    --             procedure P (X : Der);
4136    --          end Pack;
4137
4138    --  Then the above transformation turns this into
4139
4140    --             type Der_Base is new Base with null record;
4141    --             --  procedure P (X : Base) is implicitly inherited here
4142    --             --  as procedure P (X : Der_Base).
4143
4144    --             subtype Der is Der_Base (2);
4145    --             procedure P (X : Der);
4146    --             --  The overriding of P (X : Der_Base) is illegal since we
4147    --             --  have a parameter conformance problem.
4148
4149    --  To get around this problem, after having semantically processed Der_Base
4150    --  and the rewritten subtype declaration for Der, we copy Der_Base field
4151    --  Discriminant_Constraint from Der so that when parameter conformance is
4152    --  checked when P is overridden, no sematic errors are flagged.
4153
4154    --  6. SECOND TRANSFORMATION FOR DERIVED RECORDS.
4155
4156    --  Regardless of the fact that we dealing with a tagged or untagged type
4157    --  we will transform all derived type declarations of the form
4158
4159    --               type R (D1, .., Dn : ...) is [tagged] record ...;
4160    --               type T is new R [with ...];
4161    --  into
4162    --               type T (D1, .., Dn : ...) is new R (D1, .., Dn) [with ...];
4163
4164    --  The reason for such transformation is that it allows us to implement a
4165    --  very clean form of component inheritance as explained below.
4166
4167    --  Note that this transformation is not achieved by direct tree rewriting
4168    --  and manipulation, but rather by redoing the semantic actions that the
4169    --  above transformation will entail. This is done directly in routine
4170    --  Inherit_Components.
4171
4172    --  7. TYPE DERIVATION AND COMPONENT INHERITANCE.
4173
4174    --  In both tagged and untagged derived types, regular non discriminant
4175    --  components are inherited in the derived type from the parent type. In
4176    --  the absence of discriminants component, inheritance is straightforward
4177    --  as components can simply be copied from the parent.
4178    --  If the parent has discriminants, inheriting components constrained with
4179    --  these discriminants requires caution. Consider the following example:
4180
4181    --      type R  (D1, D2 : Positive) is [tagged] record
4182    --         S : String (D1 .. D2);
4183    --      end record;
4184
4185    --      type T1                is new R        [with null record];
4186    --      type T2 (X : positive) is new R (1, X) [with null record];
4187
4188    --  As explained in 6. above, T1 is rewritten as
4189
4190    --      type T1 (D1, D2 : Positive) is new R (D1, D2) [with null record];
4191
4192    --  which makes the treatment for T1 and T2 identical.
4193
4194    --  What we want when inheriting S, is that references to D1 and D2 in R are
4195    --  replaced with references to their correct constraints, ie D1 and D2 in
4196    --  T1 and 1 and X in T2. So all R's discriminant references are replaced
4197    --  with either discriminant references in the derived type or expressions.
4198    --  This replacement is acheived as follows: before inheriting R's
4199    --  components, a subtype R (D1, D2) for T1 (resp. R (1, X) for T2) is
4200    --  created in the scope of T1 (resp. scope of T2) so that discriminants D1
4201    --  and D2 of T1 are visible (resp. discriminant X of T2 is visible).
4202    --  For T2, for instance, this has the effect of replacing String (D1 .. D2)
4203    --  by String (1 .. X).
4204
4205    --  8. TYPE DERIVATION IN PRIVATE TYPE EXTENSIONS.
4206
4207    --  We explain here the rules governing private type extensions relevant to
4208    --  type derivation. These rules are explained on the following example:
4209
4210    --      type D [(...)] is new A [(...)] with private;      <-- partial view
4211    --      type D [(...)] is new P [(...)] with null record;  <-- full view
4212
4213    --  Type A is called the ancestor subtype of the private extension.
4214    --  Type P is the parent type of the full view of the private extension. It
4215    --  must be A or a type derived from A.
4216
4217    --  The rules concerning the discriminants of private type extensions are
4218    --  [7.3(10-13)]:
4219
4220    --  o If a private extension inherits known discriminants from the ancestor
4221    --    subtype, then the full view shall also inherit its discriminants from
4222    --    the ancestor subtype and the parent subtype of the full view shall be
4223    --    constrained if and only if the ancestor subtype is constrained.
4224
4225    --  o If a partial view has unknown discriminants, then the full view may
4226    --    define a definite or an indefinite subtype, with or without
4227    --    discriminants.
4228
4229    --  o If a partial view has neither known nor unknown discriminants, then
4230    --    the full view shall define a definite subtype.
4231
4232    --  o If the ancestor subtype of a private extension has constrained
4233    --    discrimiants, then the parent subtype of the full view shall impose a
4234    --    statically matching constraint on those discriminants.
4235
4236    --  This means that only the following forms of private extensions are
4237    --  allowed:
4238
4239    --      type D is new A with private;      <-- partial view
4240    --      type D is new P with null record;  <-- full view
4241
4242    --  If A has no discriminants than P has no discriminants, otherwise P must
4243    --  inherit A's discriminants.
4244
4245    --      type D is new A (...) with private;      <-- partial view
4246    --      type D is new P (:::) with null record;  <-- full view
4247
4248    --  P must inherit A's discriminants and (...) and (:::) must statically
4249    --  match.
4250
4251    --      subtype A is R (...);
4252    --      type D is new A with private;      <-- partial view
4253    --      type D is new P with null record;  <-- full view
4254
4255    --  P must have inherited R's discriminants and must be derived from A or
4256    --  any of its subtypes.
4257
4258    --      type D (..) is new A with private;              <-- partial view
4259    --      type D (..) is new P [(:::)] with null record;  <-- full view
4260
4261    --  No specific constraints on P's discriminants or constraint (:::).
4262    --  Note that A can be unconstrained, but the parent subtype P must either
4263    --  be constrained or (:::) must be present.
4264
4265    --      type D (..) is new A [(...)] with private;      <-- partial view
4266    --      type D (..) is new P [(:::)] with null record;  <-- full view
4267
4268    --  P's constraints on A's discriminants must statically match those
4269    --  imposed by (...).
4270
4271    --  9. IMPLEMENTATION OF TYPE DERIVATION FOR PRIVATE EXTENSIONS.
4272
4273    --  The full view of a private extension is handled exactly as described
4274    --  above. The model chose for the private view of a private extension
4275    --  is the same for what concerns discriminants (ie they receive the same
4276    --  treatment as in the tagged case). However, the private view of the
4277    --  private extension always inherits the components of the parent base,
4278    --  without replacing any discriminant reference. Strictly speacking this
4279    --  is incorrect. However, Gigi never uses this view to generate code so
4280    --  this is a purely semantic issue. In theory, a set of transformations
4281    --  similar to those given in 5. and 6. above could be applied to private
4282    --  views of private extensions to have the same model of component
4283    --  inheritance as for non private extensions. However, this is not done
4284    --  because it would further complicate private type processing.
4285    --  Semantically speaking, this leaves us in an uncomfortable
4286    --  situation. As an example consider:
4287
4288    --          package Pack is
4289    --             type R (D : integer) is tagged record
4290    --                S : String (1 .. D);
4291    --             end record;
4292    --             procedure P (X : R);
4293    --             type T is new R (1) with private;
4294    --          private
4295    --             type T is new R (1) with null record;
4296    --          end;
4297
4298    --  This is transformed into:
4299
4300    --          package Pack is
4301    --             type R (D : integer) is tagged record
4302    --                S : String (1 .. D);
4303    --             end record;
4304    --             procedure P (X : R);
4305    --             type T is new R (1) with private;
4306    --          private
4307    --             type BaseT is new R with null record;
4308    --             subtype  T is BaseT (1);
4309    --          end;
4310
4311    --  (strictly speaking the above is incorrect Ada).
4312
4313    --  From the semantic standpoint the private view of private extension T
4314    --  should be flagged as constrained since one can clearly have
4315    --
4316    --             Obj : T;
4317    --
4318    --  in a unit withing Pack. However, when deriving subprograms for the
4319    --  private view of private extension T, T must be seen as unconstrained
4320    --  since T has discriminants (this is a constraint of the current
4321    --  subprogram derivation model). Thus, when processing the private view of
4322    --  a private extension such as T, we first mark T as unconstrained, we
4323    --  process it, we perform program derivation and just before returning from
4324    --  Build_Derived_Record_Type we mark T as constrained.
4325    --  ??? Are there are other unconfortable cases that we will have to
4326    --      deal with.
4327
4328    --  10. RECORD_TYPE_WITH_PRIVATE complications.
4329
4330    --  Types that are derived from a visible record type and have a private
4331    --  extension present other peculiarities. They behave mostly like private
4332    --  types, but if they have primitive operations defined, these will not
4333    --  have the proper signatures for further inheritance, because other
4334    --  primitive operations will use the implicit base that we define for
4335    --  private derivations below. This affect subprogram inheritance (see
4336    --  Derive_Subprograms for details). We also derive the implicit base from
4337    --  the base type of the full view, so that the implicit base is a record
4338    --  type and not another private type, This avoids infinite loops.
4339
4340    procedure Build_Derived_Record_Type
4341      (N            : Node_Id;
4342       Parent_Type  : Entity_Id;
4343       Derived_Type : Entity_Id;
4344       Derive_Subps : Boolean := True)
4345    is
4346       Loc          : constant Source_Ptr := Sloc (N);
4347       Parent_Base  : Entity_Id;
4348
4349       Type_Def     : Node_Id;
4350       Indic        : Node_Id;
4351
4352       Discrim      : Entity_Id;
4353       Last_Discrim : Entity_Id;
4354       Constrs      : Elist_Id;
4355       Discs        : Elist_Id := New_Elmt_List;
4356       --  An empty Discs list means that there were no constraints in the
4357       --  subtype indication or that there was an error processing it.
4358
4359       Assoc_List   : Elist_Id;
4360       New_Discrs   : Elist_Id;
4361
4362       New_Base     : Entity_Id;
4363       New_Decl     : Node_Id;
4364       New_Indic    : Node_Id;
4365
4366       Is_Tagged          : constant Boolean := Is_Tagged_Type (Parent_Type);
4367       Discriminant_Specs : constant Boolean
4368         := Present (Discriminant_Specifications (N));
4369       Private_Extension  : constant Boolean
4370         := (Nkind (N) = N_Private_Extension_Declaration);
4371
4372       Constraint_Present : Boolean;
4373       Inherit_Discrims   : Boolean := False;
4374
4375       Save_Etype         : Entity_Id;
4376       Save_Discr_Constr  : Elist_Id;
4377       Save_Next_Entity   : Entity_Id;
4378
4379    begin
4380       if Ekind (Parent_Type) = E_Record_Type_With_Private
4381         and then Present (Full_View (Parent_Type))
4382         and then Has_Discriminants (Parent_Type)
4383       then
4384          Parent_Base := Base_Type (Full_View (Parent_Type));
4385       else
4386          Parent_Base := Base_Type (Parent_Type);
4387       end if;
4388
4389       --  Before we start the previously documented transformations, here is
4390       --  a little fix for size and alignment of tagged types. Normally when
4391       --  we derive type D from type P, we copy the size and alignment of P
4392       --  as the default for D, and in the absence of explicit representation
4393       --  clauses for D, the size and alignment are indeed the same as the
4394       --  parent.
4395
4396       --  But this is wrong for tagged types, since fields may be added,
4397       --  and the default size may need to be larger, and the default
4398       --  alignment may need to be larger.
4399
4400       --  We therefore reset the size and alignment fields in the tagged
4401       --  case. Note that the size and alignment will in any case be at
4402       --  least as large as the parent type (since the derived type has
4403       --  a copy of the parent type in the _parent field)
4404
4405       if Is_Tagged then
4406          Init_Size_Align (Derived_Type);
4407       end if;
4408
4409       --  STEP 0a: figure out what kind of derived type declaration we have.
4410
4411       if Private_Extension then
4412          Type_Def := N;
4413          Set_Ekind (Derived_Type, E_Record_Type_With_Private);
4414
4415       else
4416          Type_Def := Type_Definition (N);
4417
4418          --  Ekind (Parent_Base) in not necessarily E_Record_Type since
4419          --  Parent_Base can be a private type or private extension. However,
4420          --  for tagged types with an extension the newly added fields are
4421          --  visible and hence the Derived_Type is always an E_Record_Type.
4422          --  (except that the parent may have its own private fields).
4423          --  For untagged types we preserve the Ekind of the Parent_Base.
4424
4425          if Present (Record_Extension_Part (Type_Def)) then
4426             Set_Ekind (Derived_Type, E_Record_Type);
4427          else
4428             Set_Ekind (Derived_Type, Ekind (Parent_Base));
4429          end if;
4430       end if;
4431
4432       --  Indic can either be an N_Identifier if the subtype indication
4433       --  contains no constraint or an N_Subtype_Indication if the subtype
4434       --  indication has a constraint.
4435
4436       Indic := Subtype_Indication (Type_Def);
4437       Constraint_Present := (Nkind (Indic) = N_Subtype_Indication);
4438
4439       if Constraint_Present then
4440          if not Has_Discriminants (Parent_Base) then
4441             Error_Msg_N
4442               ("invalid constraint: type has no discriminant",
4443                  Constraint (Indic));
4444
4445             Constraint_Present := False;
4446             Rewrite (Indic, New_Copy_Tree (Subtype_Mark (Indic)));
4447
4448          elsif Is_Constrained (Parent_Type) then
4449             Error_Msg_N
4450                ("invalid constraint: parent type is already constrained",
4451                   Constraint (Indic));
4452
4453             Constraint_Present := False;
4454             Rewrite (Indic, New_Copy_Tree (Subtype_Mark (Indic)));
4455          end if;
4456       end if;
4457
4458       --  STEP 0b: If needed, apply transformation given in point 5. above.
4459
4460       if not Private_Extension
4461         and then Has_Discriminants (Parent_Type)
4462         and then not Discriminant_Specs
4463         and then (Is_Constrained (Parent_Type) or else Constraint_Present)
4464       then
4465          --  First, we must analyze the constraint (see comment in point 5.).
4466
4467          if Constraint_Present then
4468             New_Discrs := Build_Discriminant_Constraints (Parent_Type, Indic);
4469
4470             if Has_Discriminants (Derived_Type)
4471               and then Has_Private_Declaration (Derived_Type)
4472               and then Present (Discriminant_Constraint (Derived_Type))
4473             then
4474                --  Verify that constraints of the full view conform to those
4475                --  given in partial view.
4476
4477                declare
4478                   C1, C2 : Elmt_Id;
4479
4480                begin
4481                   C1 := First_Elmt (New_Discrs);
4482                   C2 := First_Elmt (Discriminant_Constraint (Derived_Type));
4483
4484                   while Present (C1) and then Present (C2) loop
4485                      if not
4486                        Fully_Conformant_Expressions (Node (C1), Node (C2))
4487                      then
4488                         Error_Msg_N (
4489                           "constraint not conformant to previous declaration",
4490                              Node (C1));
4491                      end if;
4492                      Next_Elmt (C1);
4493                      Next_Elmt (C2);
4494                   end loop;
4495                end;
4496             end if;
4497          end if;
4498
4499          --  Insert and analyze the declaration for the unconstrained base type
4500
4501          New_Base := Create_Itype (Ekind (Derived_Type), N, Derived_Type, 'B');
4502
4503          New_Decl :=
4504            Make_Full_Type_Declaration (Loc,
4505               Defining_Identifier => New_Base,
4506               Type_Definition     =>
4507                 Make_Derived_Type_Definition (Loc,
4508                   Abstract_Present      => Abstract_Present (Type_Def),
4509                   Subtype_Indication    =>
4510                     New_Occurrence_Of (Parent_Base, Loc),
4511                   Record_Extension_Part =>
4512                     Relocate_Node (Record_Extension_Part (Type_Def))));
4513
4514          Set_Parent (New_Decl, Parent (N));
4515          Mark_Rewrite_Insertion (New_Decl);
4516          Insert_Before (N, New_Decl);
4517
4518          --  Note that this call passes False for the Derive_Subps
4519          --  parameter because subprogram derivation is deferred until
4520          --  after creating the subtype (see below).
4521
4522          Build_Derived_Type
4523            (New_Decl, Parent_Base, New_Base,
4524             Is_Completion => True, Derive_Subps => False);
4525
4526          --  ??? This needs re-examination to determine whether the
4527          --  above call can simply be replaced by a call to Analyze.
4528
4529          Set_Analyzed (New_Decl);
4530
4531          --  Insert and analyze the declaration for the constrained subtype
4532
4533          if Constraint_Present then
4534             New_Indic :=
4535               Make_Subtype_Indication (Loc,
4536                 Subtype_Mark => New_Occurrence_Of (New_Base, Loc),
4537                 Constraint   => Relocate_Node (Constraint (Indic)));
4538
4539          else
4540             declare
4541                Expr        : Node_Id;
4542                Constr_List : List_Id := New_List;
4543                C           : Elmt_Id;
4544
4545             begin
4546                C := First_Elmt (Discriminant_Constraint (Parent_Type));
4547                while Present (C) loop
4548                   Expr := Node (C);
4549
4550                   --  It is safe here to call New_Copy_Tree since
4551                   --  Force_Evaluation was called on each constraint in
4552                   --  Build_Discriminant_Constraints.
4553
4554                   Append (New_Copy_Tree (Expr), To => Constr_List);
4555
4556                   Next_Elmt (C);
4557                end loop;
4558
4559                New_Indic :=
4560                  Make_Subtype_Indication (Loc,
4561                    Subtype_Mark => New_Occurrence_Of (New_Base, Loc),
4562                    Constraint   =>
4563                      Make_Index_Or_Discriminant_Constraint (Loc, Constr_List));
4564             end;
4565          end if;
4566
4567          Rewrite (N,
4568            Make_Subtype_Declaration (Loc,
4569              Defining_Identifier => Derived_Type,
4570              Subtype_Indication  => New_Indic));
4571
4572          Analyze (N);
4573
4574          --  Derivation of subprograms must be delayed until the
4575          --  full subtype has been established to ensure proper
4576          --  overriding of subprograms inherited by full types.
4577          --  If the derivations occurred as part of the call to
4578          --  Build_Derived_Type above, then the check for type
4579          --  conformance would fail because earlier primitive
4580          --  subprograms could still refer to the full type prior
4581          --  the change to the new subtype and hence wouldn't
4582          --  match the new base type created here.
4583
4584          Derive_Subprograms (Parent_Type, Derived_Type);
4585
4586          --  For tagged types the Discriminant_Constraint of the new base itype
4587          --  is inherited from the first subtype so that no subtype conformance
4588          --  problem arise when the first subtype overrides primitive
4589          --  operations inherited by the implicit base type.
4590
4591          if Is_Tagged then
4592             Set_Discriminant_Constraint
4593               (New_Base, Discriminant_Constraint (Derived_Type));
4594          end if;
4595
4596          return;
4597       end if;
4598
4599       --  If we get here Derived_Type will have no discriminants or it will be
4600       --  a discriminated unconstrained base type.
4601
4602       --  STEP 1a: perform preliminary actions/checks for derived tagged types
4603
4604       if Is_Tagged then
4605          --  The parent type is frozen for non-private extensions (RM 13.14(7))
4606
4607          if not Private_Extension then
4608             Freeze_Before (N, Parent_Type);
4609          end if;
4610
4611          if Type_Access_Level (Derived_Type) /= Type_Access_Level (Parent_Type)
4612            and then not Is_Generic_Type (Derived_Type)
4613          then
4614             if Is_Controlled (Parent_Type) then
4615                Error_Msg_N
4616                  ("controlled type must be declared at the library level",
4617                   Indic);
4618             else
4619                Error_Msg_N
4620                  ("type extension at deeper accessibility level than parent",
4621                   Indic);
4622             end if;
4623
4624          else
4625             declare
4626                GB : constant Node_Id := Enclosing_Generic_Body (Derived_Type);
4627
4628             begin
4629                if Present (GB)
4630                  and then GB /= Enclosing_Generic_Body (Parent_Base)
4631                then
4632                   Error_Msg_N
4633                     ("parent type must not be outside generic body",
4634                      Indic);
4635                end if;
4636             end;
4637          end if;
4638       end if;
4639
4640       --  STEP 1b : preliminary cleanup of the full view of private types
4641
4642       --  If the type is already marked as having discriminants, then it's the
4643       --  completion of a private type or private extension and we need to
4644       --  retain the discriminants from the partial view if the current
4645       --  declaration has Discriminant_Specifications so that we can verify
4646       --  conformance. However, we must remove any existing components that
4647       --  were inherited from the parent (and attached in Copy_Private_To_Full)
4648       --  because the full type inherits all appropriate components anyway, and
4649       --  we don't want the partial view's components interfering.
4650
4651       if Has_Discriminants (Derived_Type) and then Discriminant_Specs then
4652          Discrim := First_Discriminant (Derived_Type);
4653          loop
4654             Last_Discrim := Discrim;
4655             Next_Discriminant (Discrim);
4656             exit when No (Discrim);
4657          end loop;
4658
4659          Set_Last_Entity (Derived_Type, Last_Discrim);
4660
4661       --  In all other cases wipe out the list of inherited components (even
4662       --  inherited discriminants), it will be properly rebuilt here.
4663
4664       else
4665          Set_First_Entity (Derived_Type, Empty);
4666          Set_Last_Entity  (Derived_Type, Empty);
4667       end if;
4668
4669       --  STEP 1c: Initialize some flags for the Derived_Type
4670
4671       --  The following flags must be initialized here so that
4672       --  Process_Discriminants can check that discriminants of tagged types
4673       --  do not have a default initial value and that access discriminants
4674       --  are only specified for limited records. For completeness, these
4675       --  flags are also initialized along with all the other flags below.
4676
4677       Set_Is_Tagged_Type    (Derived_Type, Is_Tagged);
4678       Set_Is_Limited_Record (Derived_Type, Is_Limited_Record (Parent_Type));
4679
4680       --  STEP 2a: process discriminants of derived type if any.
4681
4682       New_Scope (Derived_Type);
4683
4684       if Discriminant_Specs then
4685          Set_Has_Unknown_Discriminants (Derived_Type, False);
4686
4687          --  The following call initializes fields Has_Discriminants and
4688          --  Discriminant_Constraint, unless we are processing the completion
4689          --  of a private type declaration.
4690
4691          Check_Or_Process_Discriminants (N, Derived_Type);
4692
4693          --  For non-tagged types the constraint on the Parent_Type must be
4694          --  present and is used to rename the discriminants.
4695
4696          if not Is_Tagged and then not Has_Discriminants (Parent_Type) then
4697             Error_Msg_N ("untagged parent must have discriminants", Indic);
4698
4699          elsif not Is_Tagged and then not Constraint_Present then
4700             Error_Msg_N
4701               ("discriminant constraint needed for derived untagged records",
4702                Indic);
4703
4704          --  Otherwise the parent subtype must be constrained unless we have a
4705          --  private extension.
4706
4707          elsif not Constraint_Present
4708            and then not Private_Extension
4709            and then not Is_Constrained (Parent_Type)
4710          then
4711             Error_Msg_N
4712               ("unconstrained type not allowed in this context", Indic);
4713
4714          elsif Constraint_Present then
4715             --  The following call sets the field Corresponding_Discriminant
4716             --  for the discriminants in the Derived_Type.
4717
4718             Discs := Build_Discriminant_Constraints (Parent_Type, Indic, True);
4719
4720             --  For untagged types all new discriminants must rename
4721             --  discriminants in the parent. For private extensions new
4722             --  discriminants cannot rename old ones (implied by [7.3(13)]).
4723
4724             Discrim := First_Discriminant (Derived_Type);
4725
4726             while Present (Discrim) loop
4727                if not Is_Tagged
4728                  and then not Present (Corresponding_Discriminant (Discrim))
4729                then
4730                   Error_Msg_N
4731                     ("new discriminants must constrain old ones", Discrim);
4732
4733                elsif Private_Extension
4734                  and then Present (Corresponding_Discriminant (Discrim))
4735                then
4736                   Error_Msg_N
4737                     ("Only static constraints allowed for parent"
4738                      & " discriminants in the partial view", Indic);
4739
4740                   exit;
4741                end if;
4742
4743                --  If a new discriminant is used in the constraint,
4744                --  then its subtype must be statically compatible
4745                --  with the parent discriminant's subtype (3.7(15)).
4746
4747                if Present (Corresponding_Discriminant (Discrim))
4748                  and then
4749                    not Subtypes_Statically_Compatible
4750                          (Etype (Discrim),
4751                           Etype (Corresponding_Discriminant (Discrim)))
4752                then
4753                   Error_Msg_N
4754                     ("subtype must be compatible with parent discriminant",
4755                      Discrim);
4756                end if;
4757
4758                Next_Discriminant (Discrim);
4759             end loop;
4760          end if;
4761
4762       --  STEP 2b: No new discriminants, inherit discriminants if any
4763
4764       else
4765          if Private_Extension then
4766             Set_Has_Unknown_Discriminants
4767               (Derived_Type, Has_Unknown_Discriminants (Parent_Type)
4768                              or else Unknown_Discriminants_Present (N));
4769          else
4770             Set_Has_Unknown_Discriminants
4771               (Derived_Type, Has_Unknown_Discriminants (Parent_Type));
4772          end if;
4773
4774          if not Has_Unknown_Discriminants (Derived_Type)
4775            and then Has_Discriminants (Parent_Type)
4776          then
4777             Inherit_Discrims := True;
4778             Set_Has_Discriminants
4779               (Derived_Type, True);
4780             Set_Discriminant_Constraint
4781               (Derived_Type, Discriminant_Constraint (Parent_Base));
4782          end if;
4783
4784          --  The following test is true for private types (remember
4785          --  transformation 5. is not applied to those) and in an error
4786          --  situation.
4787
4788          if Constraint_Present then
4789             Discs := Build_Discriminant_Constraints (Parent_Type, Indic);
4790          end if;
4791
4792          --  For now mark a new derived type as cosntrained only if it has no
4793          --  discriminants. At the end of Build_Derived_Record_Type we properly
4794          --  set this flag in the case of private extensions. See comments in
4795          --  point 9. just before body of Build_Derived_Record_Type.
4796
4797          Set_Is_Constrained
4798            (Derived_Type,
4799             not (Inherit_Discrims
4800                  or else Has_Unknown_Discriminants (Derived_Type)));
4801       end if;
4802
4803       --  STEP 3: initialize fields of derived type.
4804
4805       Set_Is_Tagged_Type    (Derived_Type, Is_Tagged);
4806       Set_Girder_Constraint (Derived_Type, No_Elist);
4807
4808       --  Fields inherited from the Parent_Type
4809
4810       Set_Discard_Names
4811         (Derived_Type, Einfo.Discard_Names      (Parent_Type));
4812       Set_Has_Specified_Layout
4813         (Derived_Type, Has_Specified_Layout     (Parent_Type));
4814       Set_Is_Limited_Composite
4815         (Derived_Type, Is_Limited_Composite     (Parent_Type));
4816       Set_Is_Limited_Record
4817         (Derived_Type, Is_Limited_Record        (Parent_Type));
4818       Set_Is_Private_Composite
4819         (Derived_Type, Is_Private_Composite     (Parent_Type));
4820
4821       --  Fields inherited from the Parent_Base
4822
4823       Set_Has_Controlled_Component
4824         (Derived_Type, Has_Controlled_Component (Parent_Base));
4825       Set_Has_Non_Standard_Rep
4826         (Derived_Type, Has_Non_Standard_Rep     (Parent_Base));
4827       Set_Has_Primitive_Operations
4828         (Derived_Type, Has_Primitive_Operations (Parent_Base));
4829
4830       --  Direct controlled types do not inherit the Finalize_Storage_Only
4831       --  flag.
4832
4833       if not Is_Controlled  (Parent_Type) then
4834          Set_Finalize_Storage_Only (Derived_Type,
4835            Finalize_Storage_Only (Parent_Type));
4836       end if;
4837
4838       --  Set fields for private derived types.
4839
4840       if Is_Private_Type (Derived_Type) then
4841          Set_Depends_On_Private (Derived_Type, True);
4842          Set_Private_Dependents (Derived_Type, New_Elmt_List);
4843
4844       --  Inherit fields from non private record types. If this is the
4845       --  completion of a derivation from a private type, the parent itself
4846       --  is private, and the attributes come from its full view, which must
4847       --  be present.
4848
4849       else
4850          if Is_Private_Type (Parent_Base)
4851            and then not Is_Record_Type (Parent_Base)
4852          then
4853             Set_Component_Alignment
4854               (Derived_Type, Component_Alignment (Full_View (Parent_Base)));
4855             Set_C_Pass_By_Copy
4856               (Derived_Type, C_Pass_By_Copy      (Full_View (Parent_Base)));
4857          else
4858             Set_Component_Alignment
4859               (Derived_Type, Component_Alignment (Parent_Base));
4860
4861             Set_C_Pass_By_Copy
4862               (Derived_Type, C_Pass_By_Copy      (Parent_Base));
4863          end if;
4864       end if;
4865
4866       --  Set fields for tagged types.
4867
4868       if Is_Tagged then
4869          Set_Primitive_Operations (Derived_Type, New_Elmt_List);
4870
4871          --  All tagged types defined in Ada.Finalization are controlled
4872
4873          if Chars (Scope (Derived_Type)) = Name_Finalization
4874            and then Chars (Scope (Scope (Derived_Type))) = Name_Ada
4875            and then Scope (Scope (Scope (Derived_Type))) = Standard_Standard
4876          then
4877             Set_Is_Controlled (Derived_Type);
4878          else
4879             Set_Is_Controlled (Derived_Type, Is_Controlled (Parent_Base));
4880          end if;
4881
4882          Make_Class_Wide_Type (Derived_Type);
4883          Set_Is_Abstract      (Derived_Type, Abstract_Present (Type_Def));
4884
4885          if Has_Discriminants (Derived_Type)
4886            and then Constraint_Present
4887          then
4888             Set_Girder_Constraint
4889               (Derived_Type, Expand_To_Girder_Constraint (Parent_Base, Discs));
4890          end if;
4891
4892       else
4893          Set_Is_Packed (Derived_Type, Is_Packed (Parent_Base));
4894          Set_Has_Non_Standard_Rep
4895                        (Derived_Type, Has_Non_Standard_Rep (Parent_Base));
4896       end if;
4897
4898       --  STEP 4: Inherit components from the parent base and constrain them.
4899       --          Apply the second transformation described in point 6. above.
4900
4901       if (not Is_Empty_Elmt_List (Discs) or else Inherit_Discrims)
4902         or else not Has_Discriminants (Parent_Type)
4903         or else not Is_Constrained (Parent_Type)
4904       then
4905          Constrs := Discs;
4906       else
4907          Constrs := Discriminant_Constraint (Parent_Type);
4908       end if;
4909
4910       Assoc_List := Inherit_Components (N,
4911         Parent_Base, Derived_Type, Is_Tagged, Inherit_Discrims, Constrs);
4912
4913       --  STEP 5a: Copy the parent record declaration for untagged types
4914
4915       if not Is_Tagged then
4916
4917          --  Discriminant_Constraint (Derived_Type) has been properly
4918          --  constructed. Save it and temporarily set it to Empty because we do
4919          --  not want the call to New_Copy_Tree below to mess this list.
4920
4921          if Has_Discriminants (Derived_Type) then
4922             Save_Discr_Constr := Discriminant_Constraint (Derived_Type);
4923             Set_Discriminant_Constraint (Derived_Type, No_Elist);
4924          else
4925             Save_Discr_Constr := No_Elist;
4926          end if;
4927
4928          --  Save the Etype field of Derived_Type. It is correctly set now, but
4929          --  the call to New_Copy tree may remap it to point to itself, which
4930          --  is not what we want. Ditto for the Next_Entity field.
4931
4932          Save_Etype       := Etype (Derived_Type);
4933          Save_Next_Entity := Next_Entity (Derived_Type);
4934
4935          --  Assoc_List maps all girder discriminants in the Parent_Base to
4936          --  girder discriminants in the Derived_Type. It is fundamental that
4937          --  no types or itypes with discriminants other than the girder
4938          --  discriminants appear in the entities declared inside
4939          --  Derived_Type. Gigi won't like it.
4940
4941          New_Decl :=
4942            New_Copy_Tree
4943              (Parent (Parent_Base), Map => Assoc_List, New_Sloc => Loc);
4944
4945          --  Restore the fields saved prior to the New_Copy_Tree call
4946          --  and compute the girder constraint.
4947
4948          Set_Etype       (Derived_Type, Save_Etype);
4949          Set_Next_Entity (Derived_Type, Save_Next_Entity);
4950
4951          if Has_Discriminants (Derived_Type) then
4952             Set_Discriminant_Constraint
4953               (Derived_Type, Save_Discr_Constr);
4954             Set_Girder_Constraint
4955               (Derived_Type, Expand_To_Girder_Constraint (Parent_Base, Discs));
4956          end if;
4957
4958          --  Insert the new derived type declaration
4959
4960          Rewrite (N, New_Decl);
4961
4962       --  STEP 5b: Complete the processing for record extensions in generics
4963
4964       --  There is no completion for record extensions declared in the
4965       --  parameter part of a generic, so we need to complete processing for
4966       --  these generic record extensions here. The call to
4967       --  Record_Type_Definition will change the Ekind of the components
4968       --  from E_Void to E_Component.
4969
4970       elsif Private_Extension and then Is_Generic_Type (Derived_Type) then
4971          Record_Type_Definition (Empty, Derived_Type);
4972
4973       --  STEP 5c: Process the record extension for non private tagged types.
4974
4975       elsif not Private_Extension then
4976          --  Add the _parent field in the derived type.
4977
4978          Expand_Derived_Record (Derived_Type, Type_Def);
4979
4980          --  Analyze the record extension
4981
4982          Record_Type_Definition
4983            (Record_Extension_Part (Type_Def), Derived_Type);
4984       end if;
4985
4986       End_Scope;
4987
4988       if Etype (Derived_Type) = Any_Type then
4989          return;
4990       end if;
4991
4992       --  Set delayed freeze and then derive subprograms, we need to do
4993       --  this in this order so that derived subprograms inherit the
4994       --  derived freeze if necessary.
4995
4996       Set_Has_Delayed_Freeze (Derived_Type);
4997       if Derive_Subps then
4998          Derive_Subprograms (Parent_Type, Derived_Type);
4999       end if;
5000
5001       --  If we have a private extension which defines a constrained derived
5002       --  type mark as constrained here after we have derived subprograms. See
5003       --  comment on point 9. just above the body of Build_Derived_Record_Type.
5004
5005       if Private_Extension and then Inherit_Discrims then
5006          if Constraint_Present and then not Is_Empty_Elmt_List (Discs) then
5007             Set_Is_Constrained          (Derived_Type, True);
5008             Set_Discriminant_Constraint (Derived_Type, Discs);
5009
5010          elsif Is_Constrained (Parent_Type) then
5011             Set_Is_Constrained
5012               (Derived_Type, True);
5013             Set_Discriminant_Constraint
5014               (Derived_Type, Discriminant_Constraint (Parent_Type));
5015          end if;
5016       end if;
5017
5018    end Build_Derived_Record_Type;
5019
5020    ------------------------
5021    -- Build_Derived_Type --
5022    ------------------------
5023
5024    procedure Build_Derived_Type
5025      (N             : Node_Id;
5026       Parent_Type   : Entity_Id;
5027       Derived_Type  : Entity_Id;
5028       Is_Completion : Boolean;
5029       Derive_Subps  : Boolean := True)
5030    is
5031       Parent_Base : constant Entity_Id := Base_Type (Parent_Type);
5032
5033    begin
5034       --  Set common attributes
5035
5036       Set_Scope          (Derived_Type, Current_Scope);
5037
5038       Set_Ekind          (Derived_Type, Ekind     (Parent_Base));
5039       Set_Etype          (Derived_Type,            Parent_Base);
5040       Set_Has_Task       (Derived_Type, Has_Task  (Parent_Base));
5041
5042       Set_Size_Info      (Derived_Type,                 Parent_Type);
5043       Set_RM_Size        (Derived_Type, RM_Size        (Parent_Type));
5044       Set_Convention     (Derived_Type, Convention     (Parent_Type));
5045       Set_Is_Controlled  (Derived_Type, Is_Controlled  (Parent_Type));
5046       Set_First_Rep_Item (Derived_Type, First_Rep_Item (Parent_Type));
5047
5048       case Ekind (Parent_Type) is
5049          when Numeric_Kind =>
5050             Build_Derived_Numeric_Type (N, Parent_Type, Derived_Type);
5051
5052          when Array_Kind =>
5053             Build_Derived_Array_Type (N, Parent_Type,  Derived_Type);
5054
5055          when E_Record_Type
5056             | E_Record_Subtype
5057             | Class_Wide_Kind  =>
5058             Build_Derived_Record_Type
5059               (N, Parent_Type, Derived_Type, Derive_Subps);
5060             return;
5061
5062          when Enumeration_Kind =>
5063             Build_Derived_Enumeration_Type (N, Parent_Type, Derived_Type);
5064
5065          when Access_Kind =>
5066             Build_Derived_Access_Type (N, Parent_Type, Derived_Type);
5067
5068          when Incomplete_Or_Private_Kind =>
5069             Build_Derived_Private_Type
5070               (N, Parent_Type, Derived_Type, Is_Completion, Derive_Subps);
5071
5072             --  For discriminated types, the derivation includes deriving
5073             --  primitive operations. For others it is done below.
5074
5075             if Is_Tagged_Type (Parent_Type)
5076               or else Has_Discriminants (Parent_Type)
5077               or else (Present (Full_View (Parent_Type))
5078                         and then Has_Discriminants (Full_View (Parent_Type)))
5079             then
5080                return;
5081             end if;
5082
5083          when Concurrent_Kind =>
5084             Build_Derived_Concurrent_Type (N, Parent_Type, Derived_Type);
5085
5086          when others =>
5087             raise Program_Error;
5088       end case;
5089
5090       if Etype (Derived_Type) = Any_Type then
5091          return;
5092       end if;
5093
5094       --  Set delayed freeze and then derive subprograms, we need to do
5095       --  this in this order so that derived subprograms inherit the
5096       --  derived freeze if necessary.
5097
5098       Set_Has_Delayed_Freeze (Derived_Type);
5099       if Derive_Subps then
5100          Derive_Subprograms (Parent_Type, Derived_Type);
5101       end if;
5102
5103       Set_Has_Primitive_Operations
5104         (Base_Type (Derived_Type), Has_Primitive_Operations (Parent_Type));
5105    end Build_Derived_Type;
5106
5107    -----------------------
5108    -- Build_Discriminal --
5109    -----------------------
5110
5111    procedure Build_Discriminal (Discrim : Entity_Id) is
5112       D_Minal : Entity_Id;
5113       CR_Disc : Entity_Id;
5114
5115    begin
5116       --  A discriminal has the same names as the discriminant.
5117
5118       D_Minal := Make_Defining_Identifier (Sloc (Discrim), Chars (Discrim));
5119
5120       Set_Ekind     (D_Minal, E_In_Parameter);
5121       Set_Mechanism (D_Minal, Default_Mechanism);
5122       Set_Etype     (D_Minal, Etype (Discrim));
5123
5124       Set_Discriminal (Discrim, D_Minal);
5125       Set_Discriminal_Link (D_Minal, Discrim);
5126
5127       --  For task types, build at once the discriminants of the corresponding
5128       --  record, which are needed if discriminants are used in entry defaults
5129       --  and in family bounds.
5130
5131       if Is_Concurrent_Type (Current_Scope)
5132         or else Is_Limited_Type (Current_Scope)
5133       then
5134          CR_Disc := Make_Defining_Identifier (Sloc (Discrim), Chars (Discrim));
5135
5136          Set_Ekind     (CR_Disc, E_In_Parameter);
5137          Set_Mechanism (CR_Disc, Default_Mechanism);
5138          Set_Etype     (CR_Disc, Etype (Discrim));
5139          Set_CR_Discriminant (Discrim, CR_Disc);
5140       end if;
5141    end Build_Discriminal;
5142
5143    ------------------------------------
5144    -- Build_Discriminant_Constraints --
5145    ------------------------------------
5146
5147    function Build_Discriminant_Constraints
5148      (T           : Entity_Id;
5149       Def         : Node_Id;
5150       Derived_Def : Boolean := False)
5151       return        Elist_Id
5152    is
5153       C          : constant Node_Id := Constraint (Def);
5154       Nb_Discr   : constant Nat     := Number_Discriminants (T);
5155       Discr_Expr : array (1 .. Nb_Discr) of Node_Id := (others => Empty);
5156       --  Saves the expression corresponding to a given discriminant in T.
5157
5158       function Pos_Of_Discr (T : Entity_Id; D : Entity_Id) return Nat;
5159       --  Return the Position number within array Discr_Expr of a discriminant
5160       --  D within the discriminant list of the discriminated type T.
5161
5162       ------------------
5163       -- Pos_Of_Discr --
5164       ------------------
5165
5166       function Pos_Of_Discr (T : Entity_Id; D : Entity_Id) return Nat is
5167          Disc : Entity_Id;
5168
5169       begin
5170          Disc := First_Discriminant (T);
5171          for J in Discr_Expr'Range loop
5172             if Disc = D then
5173                return J;
5174             end if;
5175
5176             Next_Discriminant (Disc);
5177          end loop;
5178
5179          --  Note: Since this function is called on discriminants that are
5180          --  known to belong to the discriminated type, falling through the
5181          --  loop with no match signals an internal compiler error.
5182
5183          raise Program_Error;
5184       end Pos_Of_Discr;
5185
5186       --  Variables local to Build_Discriminant_Constraints
5187
5188       Discr : Entity_Id;
5189       E     : Entity_Id;
5190       Elist : Elist_Id := New_Elmt_List;
5191
5192       Constr    : Node_Id;
5193       Expr      : Node_Id;
5194       Id        : Node_Id;
5195       Position  : Nat;
5196       Found     : Boolean;
5197
5198       Discrim_Present : Boolean := False;
5199
5200    --  Start of processing for Build_Discriminant_Constraints
5201
5202    begin
5203       --  The following loop will process positional associations only.
5204       --  For a positional association, the (single) discriminant is
5205       --  implicitly specified by position, in textual order (RM 3.7.2).
5206
5207       Discr  := First_Discriminant (T);
5208       Constr := First (Constraints (C));
5209
5210       for D in Discr_Expr'Range loop
5211          exit when Nkind (Constr) = N_Discriminant_Association;
5212
5213          if No (Constr) then
5214             Error_Msg_N ("too few discriminants given in constraint", C);
5215             return New_Elmt_List;
5216
5217          elsif Nkind (Constr) = N_Range
5218            or else (Nkind (Constr) = N_Attribute_Reference
5219                      and then
5220                     Attribute_Name (Constr) = Name_Range)
5221          then
5222             Error_Msg_N
5223               ("a range is not a valid discriminant constraint", Constr);
5224             Discr_Expr (D) := Error;
5225
5226          else
5227             Analyze_And_Resolve (Constr, Base_Type (Etype (Discr)));
5228             Discr_Expr (D) := Constr;
5229          end if;
5230
5231          Next_Discriminant (Discr);
5232          Next (Constr);
5233       end loop;
5234
5235       if No (Discr) and then Present (Constr) then
5236          Error_Msg_N ("too many discriminants given in constraint", Constr);
5237          return New_Elmt_List;
5238       end if;
5239
5240       --  Named associations can be given in any order, but if both positional
5241       --  and named associations are used in the same discriminant constraint,
5242       --  then positional associations must occur first, at their normal
5243       --  position. Hence once a named association is used, the rest of the
5244       --  discriminant constraint must use only named associations.
5245
5246       while Present (Constr) loop
5247
5248          --  Positional association forbidden after a named association.
5249
5250          if Nkind (Constr) /= N_Discriminant_Association then
5251             Error_Msg_N ("positional association follows named one", Constr);
5252             return New_Elmt_List;
5253
5254          --  Otherwise it is a named association
5255
5256          else
5257             --  E records the type of the discriminants in the named
5258             --  association. All the discriminants specified in the same name
5259             --  association must have the same type.
5260
5261             E := Empty;
5262
5263             --  Search the list of discriminants in T to see if the simple name
5264             --  given in the constraint matches any of them.
5265
5266             Id := First (Selector_Names (Constr));
5267             while Present (Id) loop
5268                Found := False;
5269
5270                --  If Original_Discriminant is present, we are processing a
5271                --  generic instantiation and this is an instance node. We need
5272                --  to find the name of the corresponding discriminant in the
5273                --  actual record type T and not the name of the discriminant in
5274                --  the generic formal. Example:
5275                --
5276                --    generic
5277                --       type G (D : int) is private;
5278                --    package P is
5279                --       subtype W is G (D => 1);
5280                --    end package;
5281                --    type Rec (X : int) is record ... end record;
5282                --    package Q is new P (G => Rec);
5283                --
5284                --  At the point of the instantiation, formal type G is Rec
5285                --  and therefore when reanalyzing "subtype W is G (D => 1);"
5286                --  which really looks like "subtype W is Rec (D => 1);" at
5287                --  the point of instantiation, we want to find the discriminant
5288                --  that corresponds to D in Rec, ie X.
5289
5290                if Present (Original_Discriminant (Id)) then
5291                   Discr := Find_Corresponding_Discriminant (Id, T);
5292                   Found := True;
5293
5294                else
5295                   Discr := First_Discriminant (T);
5296                   while Present (Discr) loop
5297                      if Chars (Discr) = Chars (Id) then
5298                         Found := True;
5299                         exit;
5300                      end if;
5301
5302                      Next_Discriminant (Discr);
5303                   end loop;
5304
5305                   if not Found then
5306                      Error_Msg_N ("& does not match any discriminant", Id);
5307                      return New_Elmt_List;
5308
5309                   --  The following is only useful for the benefit of generic
5310                   --  instances but it does not interfere with other
5311                   --  processing for the non-generic case so we do it in all
5312                   --  cases (for generics this statement is executed when
5313                   --  processing the generic definition, see comment at the
5314                   --  begining of this if statement).
5315
5316                   else
5317                      Set_Original_Discriminant (Id, Discr);
5318                   end if;
5319                end if;
5320
5321                Position := Pos_Of_Discr (T, Discr);
5322
5323                if Present (Discr_Expr (Position)) then
5324                   Error_Msg_N ("duplicate constraint for discriminant&", Id);
5325
5326                else
5327                   --  Each discriminant specified in the same named association
5328                   --  must be associated with a separate copy of the
5329                   --  corresponding expression.
5330
5331                   if Present (Next (Id)) then
5332                      Expr := New_Copy_Tree (Expression (Constr));
5333                      Set_Parent (Expr, Parent (Expression (Constr)));
5334                   else
5335                      Expr := Expression (Constr);
5336                   end if;
5337
5338                   Discr_Expr (Position) := Expr;
5339                   Analyze_And_Resolve (Expr, Base_Type (Etype (Discr)));
5340                end if;
5341
5342                --  A discriminant association with more than one discriminant
5343                --  name is only allowed if the named discriminants are all of
5344                --  the same type (RM 3.7.1(8)).
5345
5346                if E = Empty then
5347                   E := Base_Type (Etype (Discr));
5348
5349                elsif Base_Type (Etype (Discr)) /= E then
5350                   Error_Msg_N
5351                     ("all discriminants in an association " &
5352                      "must have the same type", Id);
5353                end if;
5354
5355                Next (Id);
5356             end loop;
5357          end if;
5358
5359          Next (Constr);
5360       end loop;
5361
5362       --  A discriminant constraint must provide exactly one value for each
5363       --  discriminant of the type (RM 3.7.1(8)).
5364
5365       for J in Discr_Expr'Range loop
5366          if No (Discr_Expr (J)) then
5367             Error_Msg_N ("too few discriminants given in constraint", C);
5368             return New_Elmt_List;
5369          end if;
5370       end loop;
5371
5372       --  Determine if there are discriminant expressions in the constraint.
5373
5374       for J in Discr_Expr'Range loop
5375          if Denotes_Discriminant (Discr_Expr (J)) then
5376             Discrim_Present := True;
5377          end if;
5378       end loop;
5379
5380       --  Build an element list consisting of the expressions given in the
5381       --  discriminant constraint and apply the appropriate range
5382       --  checks. The list is constructed after resolving any named
5383       --  discriminant associations and therefore the expressions appear in
5384       --  the textual order of the discriminants.
5385
5386       Discr := First_Discriminant (T);
5387       for J in Discr_Expr'Range loop
5388          if Discr_Expr (J) /= Error then
5389
5390             Append_Elmt (Discr_Expr (J), Elist);
5391
5392             --  If any of the discriminant constraints is given by a
5393             --  discriminant and we are in a derived type declaration we
5394             --  have a discriminant renaming. Establish link between new
5395             --  and old discriminant.
5396
5397             if Denotes_Discriminant (Discr_Expr (J)) then
5398                if Derived_Def then
5399                   Set_Corresponding_Discriminant
5400                     (Entity (Discr_Expr (J)), Discr);
5401                end if;
5402
5403             --  Force the evaluation of non-discriminant expressions.
5404             --  If we have found a discriminant in the constraint 3.4(26)
5405             --  and 3.8(18) demand that no range checks are performed are
5406             --  after evaluation. In all other cases perform a range check.
5407
5408             else
5409                if not Discrim_Present then
5410                   Apply_Range_Check (Discr_Expr (J), Etype (Discr));
5411                end if;
5412
5413                Force_Evaluation (Discr_Expr (J));
5414             end if;
5415
5416          --  Check that the designated type of an access discriminant's
5417          --  expression is not a class-wide type unless the discriminant's
5418          --  designated type is also class-wide.
5419
5420             if Ekind (Etype (Discr)) = E_Anonymous_Access_Type
5421               and then not Is_Class_Wide_Type
5422                          (Designated_Type (Etype (Discr)))
5423               and then Etype (Discr_Expr (J)) /= Any_Type
5424               and then Is_Class_Wide_Type
5425                          (Designated_Type (Etype (Discr_Expr (J))))
5426             then
5427                Wrong_Type (Discr_Expr (J), Etype (Discr));
5428             end if;
5429          end if;
5430
5431          Next_Discriminant (Discr);
5432       end loop;
5433
5434       return Elist;
5435    end Build_Discriminant_Constraints;
5436
5437    ---------------------------------
5438    -- Build_Discriminated_Subtype --
5439    ---------------------------------
5440
5441    procedure Build_Discriminated_Subtype
5442      (T           : Entity_Id;
5443       Def_Id      : Entity_Id;
5444       Elist       : Elist_Id;
5445       Related_Nod : Node_Id;
5446       For_Access  : Boolean := False)
5447    is
5448       Has_Discrs  : constant Boolean := Has_Discriminants (T);
5449       Constrained : constant Boolean
5450                       := (Has_Discrs and then not Is_Empty_Elmt_List (Elist))
5451                            or else Is_Constrained (T);
5452
5453    begin
5454       if Ekind (T) = E_Record_Type then
5455          if For_Access then
5456             Set_Ekind (Def_Id, E_Private_Subtype);
5457             Set_Is_For_Access_Subtype (Def_Id, True);
5458          else
5459             Set_Ekind (Def_Id, E_Record_Subtype);
5460          end if;
5461
5462       elsif Ekind (T) = E_Task_Type then
5463          Set_Ekind (Def_Id, E_Task_Subtype);
5464
5465       elsif Ekind (T) = E_Protected_Type then
5466          Set_Ekind (Def_Id, E_Protected_Subtype);
5467
5468       elsif Is_Private_Type (T) then
5469          Set_Ekind (Def_Id, Subtype_Kind (Ekind (T)));
5470
5471       elsif Is_Class_Wide_Type (T) then
5472          Set_Ekind (Def_Id, E_Class_Wide_Subtype);
5473
5474       else
5475          --  Incomplete type. Attach subtype to list of dependents, to be
5476          --  completed with full view of parent type.
5477
5478          Set_Ekind (Def_Id, Ekind (T));
5479          Append_Elmt (Def_Id, Private_Dependents (T));
5480       end if;
5481
5482       Set_Etype             (Def_Id, T);
5483       Init_Size_Align       (Def_Id);
5484       Set_Has_Discriminants (Def_Id, Has_Discrs);
5485       Set_Is_Constrained    (Def_Id, Constrained);
5486
5487       Set_First_Entity      (Def_Id, First_Entity   (T));
5488       Set_Last_Entity       (Def_Id, Last_Entity    (T));
5489       Set_First_Rep_Item    (Def_Id, First_Rep_Item (T));
5490
5491       if Is_Tagged_Type (T) then
5492          Set_Is_Tagged_Type  (Def_Id);
5493          Make_Class_Wide_Type (Def_Id);
5494       end if;
5495
5496       Set_Girder_Constraint (Def_Id, No_Elist);
5497
5498       if Has_Discrs then
5499          Set_Discriminant_Constraint (Def_Id, Elist);
5500          Set_Girder_Constraint_From_Discriminant_Constraint (Def_Id);
5501       end if;
5502
5503       if Is_Tagged_Type (T) then
5504          Set_Primitive_Operations (Def_Id, Primitive_Operations (T));
5505          Set_Is_Abstract (Def_Id, Is_Abstract (T));
5506       end if;
5507
5508       --  Subtypes introduced by component declarations do not need to be
5509       --  marked as delayed, and do not get freeze nodes, because the semantics
5510       --  verifies that the parents of the subtypes are frozen before the
5511       --  enclosing record is frozen.
5512
5513       if not Is_Type (Scope (Def_Id)) then
5514          Set_Depends_On_Private (Def_Id, Depends_On_Private (T));
5515
5516          if Is_Private_Type (T)
5517            and then Present (Full_View (T))
5518          then
5519             Conditional_Delay (Def_Id, Full_View (T));
5520          else
5521             Conditional_Delay (Def_Id, T);
5522          end if;
5523       end if;
5524
5525       if Is_Record_Type (T) then
5526          Set_Is_Limited_Record (Def_Id, Is_Limited_Record (T));
5527
5528          if Has_Discrs
5529             and then not Is_Empty_Elmt_List (Elist)
5530             and then not For_Access
5531          then
5532             Create_Constrained_Components (Def_Id, Related_Nod, T, Elist);
5533          elsif not For_Access then
5534             Set_Cloned_Subtype (Def_Id, T);
5535          end if;
5536       end if;
5537
5538    end Build_Discriminated_Subtype;
5539
5540    ------------------------
5541    -- Build_Scalar_Bound --
5542    ------------------------
5543
5544    function Build_Scalar_Bound
5545      (Bound : Node_Id;
5546       Par_T : Entity_Id;
5547       Der_T : Entity_Id;
5548       Loc   : Source_Ptr)
5549       return Node_Id
5550    is
5551       New_Bound : Entity_Id;
5552
5553    begin
5554       --  Note: not clear why this is needed, how can the original bound
5555       --  be unanalyzed at this point? and if it is, what business do we
5556       --  have messing around with it? and why is the base type of the
5557       --  parent type the right type for the resolution. It probably is
5558       --  not! It is OK for the new bound we are creating, but not for
5559       --  the old one??? Still if it never happens, no problem!
5560
5561       Analyze_And_Resolve (Bound, Base_Type (Par_T));
5562
5563       if Nkind (Bound) = N_Integer_Literal
5564         or else Nkind (Bound) = N_Real_Literal
5565       then
5566          New_Bound := New_Copy (Bound);
5567          Set_Etype (New_Bound, Der_T);
5568          Set_Analyzed (New_Bound);
5569
5570       elsif Is_Entity_Name (Bound) then
5571          New_Bound := OK_Convert_To (Der_T, New_Copy (Bound));
5572
5573       --  The following is almost certainly wrong. What business do we have
5574       --  relocating a node (Bound) that is presumably still attached to
5575       --  the tree elsewhere???
5576
5577       else
5578          New_Bound := OK_Convert_To (Der_T, Relocate_Node (Bound));
5579       end if;
5580
5581       Set_Etype (New_Bound, Der_T);
5582       return New_Bound;
5583    end Build_Scalar_Bound;
5584
5585    --------------------------------
5586    -- Build_Underlying_Full_View --
5587    --------------------------------
5588
5589    procedure Build_Underlying_Full_View
5590      (N   : Node_Id;
5591       Typ : Entity_Id;
5592       Par : Entity_Id)
5593    is
5594       Loc  : constant Source_Ptr := Sloc (N);
5595       Subt : constant Entity_Id :=
5596                Make_Defining_Identifier
5597                  (Loc, New_External_Name (Chars (Typ), 'S'));
5598
5599       Constr : Node_Id;
5600       Indic  : Node_Id;
5601       C      : Node_Id;
5602       Id     : Node_Id;
5603
5604    begin
5605       if Nkind (N) = N_Full_Type_Declaration then
5606          Constr := Constraint (Subtype_Indication (Type_Definition (N)));
5607
5608       --  ??? ??? is this assert right, I assume so otherwise Constr
5609       --  would not be defined below (this used to be an elsif)
5610
5611       else pragma Assert (Nkind (N) = N_Subtype_Declaration);
5612          Constr := New_Copy_Tree (Constraint (Subtype_Indication (N)));
5613       end if;
5614
5615       --  If the constraint has discriminant associations, the discriminant
5616       --  entity is already set, but it denotes a discriminant of the new
5617       --  type, not the original parent, so it must be found anew.
5618
5619       C := First (Constraints (Constr));
5620
5621       while Present (C) loop
5622
5623          if Nkind (C) = N_Discriminant_Association then
5624             Id := First (Selector_Names (C));
5625
5626             while Present (Id) loop
5627                Set_Original_Discriminant (Id, Empty);
5628                Next (Id);
5629             end loop;
5630          end if;
5631
5632          Next (C);
5633       end loop;
5634
5635       Indic := Make_Subtype_Declaration (Loc,
5636          Defining_Identifier => Subt,
5637          Subtype_Indication  =>
5638            Make_Subtype_Indication (Loc,
5639              Subtype_Mark => New_Reference_To (Par, Loc),
5640              Constraint   => New_Copy_Tree (Constr)));
5641
5642       Insert_Before (N, Indic);
5643       Analyze (Indic);
5644       Set_Underlying_Full_View (Typ, Full_View (Subt));
5645    end Build_Underlying_Full_View;
5646
5647    -------------------------------
5648    -- Check_Abstract_Overriding --
5649    -------------------------------
5650
5651    procedure Check_Abstract_Overriding (T : Entity_Id) is
5652       Op_List  : Elist_Id;
5653       Elmt     : Elmt_Id;
5654       Subp     : Entity_Id;
5655       Type_Def : Node_Id;
5656
5657    begin
5658       Op_List := Primitive_Operations (T);
5659
5660       --  Loop to check primitive operations
5661
5662       Elmt := First_Elmt (Op_List);
5663       while Present (Elmt) loop
5664          Subp := Node (Elmt);
5665
5666          --  Special exception, do not complain about failure to
5667          --  override _Input and _Output, since we always provide
5668          --  automatic overridings for these subprograms.
5669
5670          if Is_Abstract (Subp)
5671            and then Chars (Subp) /= Name_uInput
5672            and then Chars (Subp) /= Name_uOutput
5673            and then not Is_Abstract (T)
5674          then
5675             if Present (Alias (Subp)) then
5676                --  Only perform the check for a derived subprogram when
5677                --  the type has an explicit record extension. This avoids
5678                --  incorrectly flagging abstract subprograms for the case
5679                --  of a type without an extension derived from a formal type
5680                --  with a tagged actual (can occur within a private part).
5681
5682                Type_Def := Type_Definition (Parent (T));
5683                if Nkind (Type_Def) = N_Derived_Type_Definition
5684                  and then Present (Record_Extension_Part (Type_Def))
5685                then
5686                   Error_Msg_NE
5687                     ("type must be declared abstract or & overridden",
5688                      T, Subp);
5689                end if;
5690             else
5691                Error_Msg_NE
5692                  ("abstract subprogram not allowed for type&",
5693                   Subp, T);
5694                Error_Msg_NE
5695                  ("nonabstract type has abstract subprogram&",
5696                   T, Subp);
5697             end if;
5698          end if;
5699
5700          Next_Elmt (Elmt);
5701       end loop;
5702    end Check_Abstract_Overriding;
5703
5704    ------------------------------------------------
5705    -- Check_Access_Discriminant_Requires_Limited --
5706    ------------------------------------------------
5707
5708    procedure Check_Access_Discriminant_Requires_Limited
5709      (D   : Node_Id;
5710       Loc : Node_Id)
5711    is
5712    begin
5713       --  A discriminant_specification for an access discriminant
5714       --  shall appear only in the declaration for a task or protected
5715       --  type, or for a type with the reserved word 'limited' in
5716       --  its definition or in one of its ancestors. (RM 3.7(10))
5717
5718       if Nkind (Discriminant_Type (D)) = N_Access_Definition
5719         and then not Is_Concurrent_Type (Current_Scope)
5720         and then not Is_Concurrent_Record_Type (Current_Scope)
5721         and then not Is_Limited_Record (Current_Scope)
5722         and then Ekind (Current_Scope) /= E_Limited_Private_Type
5723       then
5724          Error_Msg_N
5725            ("access discriminants allowed only for limited types", Loc);
5726       end if;
5727    end Check_Access_Discriminant_Requires_Limited;
5728
5729    -----------------------------------
5730    -- Check_Aliased_Component_Types --
5731    -----------------------------------
5732
5733    procedure Check_Aliased_Component_Types (T : Entity_Id) is
5734       C : Entity_Id;
5735
5736    begin
5737       --  ??? Also need to check components of record extensions,
5738       --  but not components of protected types (which are always
5739       --  limited).
5740
5741       if not Is_Limited_Type (T) then
5742          if Ekind (T) = E_Record_Type then
5743             C := First_Component (T);
5744             while Present (C) loop
5745                if Is_Aliased (C)
5746                  and then Has_Discriminants (Etype (C))
5747                  and then not Is_Constrained (Etype (C))
5748                  and then not In_Instance
5749                then
5750                   Error_Msg_N
5751                     ("aliased component must be constrained ('R'M 3.6(11))",
5752                       C);
5753                end if;
5754
5755                Next_Component (C);
5756             end loop;
5757
5758          elsif Ekind (T) = E_Array_Type then
5759             if Has_Aliased_Components (T)
5760               and then Has_Discriminants (Component_Type (T))
5761               and then not Is_Constrained (Component_Type (T))
5762               and then not In_Instance
5763             then
5764                Error_Msg_N
5765                  ("aliased component type must be constrained ('R'M 3.6(11))",
5766                     T);
5767             end if;
5768          end if;
5769       end if;
5770    end Check_Aliased_Component_Types;
5771
5772    ----------------------
5773    -- Check_Completion --
5774    ----------------------
5775
5776    procedure Check_Completion (Body_Id : Node_Id := Empty) is
5777       E : Entity_Id;
5778
5779       procedure Post_Error;
5780       --  Post error message for lack of completion for entity E
5781
5782       procedure Post_Error is
5783       begin
5784          if not Comes_From_Source (E) then
5785
5786             if (Ekind (E) = E_Task_Type
5787               or else Ekind (E) = E_Protected_Type)
5788             then
5789                --  It may be an anonymous protected type created for a
5790                --  single variable. Post error on variable, if present.
5791
5792                declare
5793                   Var : Entity_Id;
5794
5795                begin
5796                   Var := First_Entity (Current_Scope);
5797
5798                   while Present (Var) loop
5799                      exit when Etype (Var) = E
5800                        and then Comes_From_Source (Var);
5801
5802                      Next_Entity (Var);
5803                   end loop;
5804
5805                   if Present (Var) then
5806                      E := Var;
5807                   end if;
5808                end;
5809             end if;
5810          end if;
5811
5812          --  If a generated entity has no completion, then either previous
5813          --  semantic errors have disabled the expansion phase, or else
5814          --  we had missing subunits, or else we are compiling without expan-
5815          --  sion, or else something is very wrong.
5816
5817          if not Comes_From_Source (E) then
5818             pragma Assert
5819               (Errors_Detected > 0
5820                 or else Subunits_Missing
5821                 or else not Expander_Active);
5822             return;
5823
5824          --  Here for source entity
5825
5826          else
5827             --  Here if no body to post the error message, so we post the error
5828             --  on the declaration that has no completion. This is not really
5829             --  the right place to post it, think about this later ???
5830
5831             if No (Body_Id) then
5832                if Is_Type (E) then
5833                   Error_Msg_NE
5834                     ("missing full declaration for }", Parent (E), E);
5835                else
5836                   Error_Msg_NE
5837                     ("missing body for &", Parent (E), E);
5838                end if;
5839
5840             --  Package body has no completion for a declaration that appears
5841             --  in the corresponding spec. Post error on the body, with a
5842             --  reference to the non-completed declaration.
5843
5844             else
5845                Error_Msg_Sloc := Sloc (E);
5846
5847                if Is_Type (E) then
5848                   Error_Msg_NE
5849                     ("missing full declaration for }!", Body_Id, E);
5850
5851                elsif Is_Overloadable (E)
5852                  and then Current_Entity_In_Scope (E) /= E
5853                then
5854                   --  It may be that the completion is mistyped and appears
5855                   --  as a  distinct overloading of the entity.
5856
5857                   declare
5858                      Candidate : Entity_Id := Current_Entity_In_Scope (E);
5859                      Decl      : Node_Id := Unit_Declaration_Node (Candidate);
5860
5861                   begin
5862                      if Is_Overloadable (Candidate)
5863                        and then Ekind (Candidate) = Ekind (E)
5864                        and then Nkind (Decl) = N_Subprogram_Body
5865                        and then Acts_As_Spec (Decl)
5866                      then
5867                         Check_Type_Conformant (Candidate, E);
5868
5869                      else
5870                         Error_Msg_NE ("missing body for & declared#!",
5871                            Body_Id, E);
5872                      end if;
5873                   end;
5874                else
5875                   Error_Msg_NE ("missing body for & declared#!",
5876                      Body_Id, E);
5877                end if;
5878             end if;
5879          end if;
5880       end Post_Error;
5881
5882    --  Start processing for Check_Completion
5883
5884    begin
5885       E := First_Entity (Current_Scope);
5886       while Present (E) loop
5887          if Is_Intrinsic_Subprogram (E) then
5888             null;
5889
5890          --  The following situation requires special handling: a child
5891          --  unit that appears in the context clause of the body of its
5892          --  parent:
5893
5894          --    procedure Parent.Child (...);
5895          --
5896          --    with Parent.Child;
5897          --    package body Parent is
5898
5899          --  Here Parent.Child appears as a local entity, but should not
5900          --  be flagged as requiring completion, because it is a
5901          --  compilation unit.
5902
5903          elsif     Ekind (E) = E_Function
5904            or else Ekind (E) = E_Procedure
5905            or else Ekind (E) = E_Generic_Function
5906            or else Ekind (E) = E_Generic_Procedure
5907          then
5908             if not Has_Completion (E)
5909               and then not Is_Abstract (E)
5910               and then Nkind (Parent (Unit_Declaration_Node (E))) /=
5911                                                        N_Compilation_Unit
5912               and then Chars (E) /= Name_uSize
5913             then
5914                Post_Error;
5915             end if;
5916
5917          elsif Is_Entry (E) then
5918             if not Has_Completion (E) and then
5919               (Ekind (Scope (E)) = E_Protected_Object
5920                 or else Ekind (Scope (E)) = E_Protected_Type)
5921             then
5922                Post_Error;
5923             end if;
5924
5925          elsif Is_Package (E) then
5926             if Unit_Requires_Body (E) then
5927                if not Has_Completion (E)
5928                  and then Nkind (Parent (Unit_Declaration_Node (E))) /=
5929                                                        N_Compilation_Unit
5930                then
5931                   Post_Error;
5932                end if;
5933
5934             elsif not Is_Child_Unit (E) then
5935                May_Need_Implicit_Body (E);
5936             end if;
5937
5938          elsif Ekind (E) = E_Incomplete_Type
5939            and then No (Underlying_Type (E))
5940          then
5941             Post_Error;
5942
5943          elsif (Ekind (E) = E_Task_Type or else
5944                 Ekind (E) = E_Protected_Type)
5945            and then not Has_Completion (E)
5946          then
5947             Post_Error;
5948
5949          elsif Ekind (E) = E_Constant
5950            and then Ekind (Etype (E)) = E_Task_Type
5951            and then not Has_Completion (Etype (E))
5952          then
5953             Post_Error;
5954
5955          elsif Ekind (E) = E_Protected_Object
5956            and then not Has_Completion (Etype (E))
5957          then
5958             Post_Error;
5959
5960          elsif Ekind (E) = E_Record_Type then
5961             if Is_Tagged_Type (E) then
5962                Check_Abstract_Overriding (E);
5963             end if;
5964
5965             Check_Aliased_Component_Types (E);
5966
5967          elsif Ekind (E) = E_Array_Type then
5968             Check_Aliased_Component_Types (E);
5969
5970          end if;
5971
5972          Next_Entity (E);
5973       end loop;
5974    end Check_Completion;
5975
5976    ----------------------------
5977    -- Check_Delta_Expression --
5978    ----------------------------
5979
5980    procedure Check_Delta_Expression (E : Node_Id) is
5981    begin
5982       if not (Is_Real_Type (Etype (E))) then
5983          Wrong_Type (E, Any_Real);
5984
5985       elsif not Is_OK_Static_Expression (E) then
5986          Error_Msg_N ("non-static expression used for delta value", E);
5987
5988       elsif not UR_Is_Positive (Expr_Value_R (E)) then
5989          Error_Msg_N ("delta expression must be positive", E);
5990
5991       else
5992          return;
5993       end if;
5994
5995       --  If any of above errors occurred, then replace the incorrect
5996       --  expression by the real 0.1, which should prevent further errors.
5997
5998       Rewrite (E,
5999         Make_Real_Literal (Sloc (E), Ureal_Tenth));
6000       Analyze_And_Resolve (E, Standard_Float);
6001
6002    end Check_Delta_Expression;
6003
6004    -----------------------------
6005    -- Check_Digits_Expression --
6006    -----------------------------
6007
6008    procedure Check_Digits_Expression (E : Node_Id) is
6009    begin
6010       if not (Is_Integer_Type (Etype (E))) then
6011          Wrong_Type (E, Any_Integer);
6012
6013       elsif not Is_OK_Static_Expression (E) then
6014          Error_Msg_N ("non-static expression used for digits value", E);
6015
6016       elsif Expr_Value (E) <= 0 then
6017          Error_Msg_N ("digits value must be greater than zero", E);
6018
6019       else
6020          return;
6021       end if;
6022
6023       --  If any of above errors occurred, then replace the incorrect
6024       --  expression by the integer 1, which should prevent further errors.
6025
6026       Rewrite (E, Make_Integer_Literal (Sloc (E), 1));
6027       Analyze_And_Resolve (E, Standard_Integer);
6028
6029    end Check_Digits_Expression;
6030
6031    ----------------------
6032    -- Check_Incomplete --
6033    ----------------------
6034
6035    procedure Check_Incomplete (T : Entity_Id) is
6036    begin
6037       if Ekind (Root_Type (Entity (T))) = E_Incomplete_Type then
6038          Error_Msg_N ("invalid use of type before its full declaration", T);
6039       end if;
6040    end Check_Incomplete;
6041
6042    --------------------------
6043    -- Check_Initialization --
6044    --------------------------
6045
6046    procedure Check_Initialization (T : Entity_Id; Exp : Node_Id) is
6047    begin
6048       if (Is_Limited_Type (T)
6049            or else Is_Limited_Composite (T))
6050         and then not In_Instance
6051       then
6052          Error_Msg_N
6053            ("cannot initialize entities of limited type", Exp);
6054       end if;
6055    end Check_Initialization;
6056
6057    ------------------------------------
6058    -- Check_Or_Process_Discriminants --
6059    ------------------------------------
6060
6061    --  If an incomplete or private type declaration was already given for
6062    --  the type, the discriminants may have already been processed if they
6063    --  were present on the incomplete declaration. In this case a full
6064    --  conformance check is performed otherwise just process them.
6065
6066    procedure Check_Or_Process_Discriminants (N : Node_Id; T : Entity_Id) is
6067    begin
6068       if Has_Discriminants (T) then
6069
6070          --  Make the discriminants visible to component declarations.
6071
6072          declare
6073             D    : Entity_Id := First_Discriminant (T);
6074             Prev : Entity_Id;
6075
6076          begin
6077             while Present (D) loop
6078                Prev := Current_Entity (D);
6079                Set_Current_Entity (D);
6080                Set_Is_Immediately_Visible (D);
6081                Set_Homonym (D, Prev);
6082
6083                --  This restriction gets applied to the full type here; it
6084                --  has already been applied earlier to the partial view
6085
6086                Check_Access_Discriminant_Requires_Limited (Parent (D), N);
6087
6088                Next_Discriminant (D);
6089             end loop;
6090          end;
6091
6092       elsif Present (Discriminant_Specifications (N)) then
6093          Process_Discriminants (N);
6094       end if;
6095    end Check_Or_Process_Discriminants;
6096
6097    ----------------------
6098    -- Check_Real_Bound --
6099    ----------------------
6100
6101    procedure Check_Real_Bound (Bound : Node_Id) is
6102    begin
6103       if not Is_Real_Type (Etype (Bound)) then
6104          Error_Msg_N
6105            ("bound in real type definition must be of real type", Bound);
6106
6107       elsif not Is_OK_Static_Expression (Bound) then
6108          Error_Msg_N
6109            ("non-static expression used for real type bound", Bound);
6110
6111       else
6112          return;
6113       end if;
6114
6115       Rewrite
6116         (Bound, Make_Real_Literal (Sloc (Bound), Ureal_0));
6117       Analyze (Bound);
6118       Resolve (Bound, Standard_Float);
6119    end Check_Real_Bound;
6120
6121    ------------------------------
6122    -- Complete_Private_Subtype --
6123    ------------------------------
6124
6125    procedure Complete_Private_Subtype
6126      (Priv        : Entity_Id;
6127       Full        : Entity_Id;
6128       Full_Base   : Entity_Id;
6129       Related_Nod : Node_Id)
6130    is
6131       Save_Next_Entity : Entity_Id;
6132       Save_Homonym     : Entity_Id;
6133
6134    begin
6135       --  Set semantic attributes for (implicit) private subtype completion.
6136       --  If the full type has no discriminants, then it is a copy of the full
6137       --  view of the base. Otherwise, it is a subtype of the base with a
6138       --  possible discriminant constraint. Save and restore the original
6139       --  Next_Entity field of full to ensure that the calls to Copy_Node
6140       --  do not corrupt the entity chain.
6141
6142       --  Note that the type of the full view is the same entity as the
6143       --  type of the partial view. In this fashion, the subtype has
6144       --  access to the correct view of the parent.
6145
6146       Save_Next_Entity := Next_Entity (Full);
6147       Save_Homonym     := Homonym (Priv);
6148
6149       case Ekind (Full_Base) is
6150
6151          when E_Record_Type    |
6152               E_Record_Subtype |
6153               Class_Wide_Kind  |
6154               Private_Kind     |
6155               Task_Kind        |
6156               Protected_Kind   =>
6157             Copy_Node (Priv, Full);
6158
6159             Set_Has_Discriminants  (Full, Has_Discriminants (Full_Base));
6160             Set_First_Entity       (Full, First_Entity (Full_Base));
6161             Set_Last_Entity        (Full, Last_Entity (Full_Base));
6162
6163          when others =>
6164             Copy_Node (Full_Base, Full);
6165             Set_Chars          (Full, Chars (Priv));
6166             Conditional_Delay  (Full, Priv);
6167             Set_Sloc           (Full, Sloc (Priv));
6168
6169       end case;
6170
6171       Set_Next_Entity (Full, Save_Next_Entity);
6172       Set_Homonym     (Full, Save_Homonym);
6173       Set_Associated_Node_For_Itype (Full, Related_Nod);
6174
6175       --  Set common attributes for all subtypes.
6176
6177       Set_Ekind (Full, Subtype_Kind (Ekind (Full_Base)));
6178
6179       --  The Etype of the full view is inconsistent. Gigi needs to see the
6180       --  structural full view,  which is what the current scheme gives:
6181       --  the Etype of the full view is the etype of the full base. However,
6182       --  if the full base is a derived type, the full view then looks like
6183       --  a subtype of the parent, not a subtype of the full base. If instead
6184       --  we write:
6185
6186       --       Set_Etype (Full, Full_Base);
6187
6188       --  then we get inconsistencies in the front-end (confusion between
6189       --  views). Several outstanding bugs are related to this.
6190
6191       Set_Is_First_Subtype (Full, False);
6192       Set_Scope            (Full, Scope (Priv));
6193       Set_Size_Info        (Full, Full_Base);
6194       Set_RM_Size          (Full, RM_Size (Full_Base));
6195       Set_Is_Itype         (Full);
6196
6197       --  A subtype of a private-type-without-discriminants, whose full-view
6198       --  has discriminants with default expressions, is not constrained!
6199
6200       if not Has_Discriminants (Priv) then
6201          Set_Is_Constrained (Full, Is_Constrained (Full_Base));
6202       end if;
6203
6204       Set_First_Rep_Item     (Full, First_Rep_Item (Full_Base));
6205       Set_Depends_On_Private (Full, Has_Private_Component (Full));
6206
6207       --  Freeze the private subtype entity if its parent is delayed,
6208       --  and not already frozen. We skip this processing if the type
6209       --  is an anonymous subtype of a record component, or is the
6210       --  corresponding record of a protected type, since ???
6211
6212       if not Is_Type (Scope (Full)) then
6213          Set_Has_Delayed_Freeze (Full,
6214            Has_Delayed_Freeze (Full_Base)
6215                and then (not Is_Frozen (Full_Base)));
6216       end if;
6217
6218       Set_Freeze_Node (Full, Empty);
6219       Set_Is_Frozen (Full, False);
6220       Set_Full_View (Priv, Full);
6221
6222       if Has_Discriminants (Full) then
6223          Set_Girder_Constraint_From_Discriminant_Constraint (Full);
6224          Set_Girder_Constraint (Priv, Girder_Constraint (Full));
6225          if Has_Unknown_Discriminants (Full) then
6226             Set_Discriminant_Constraint (Full, No_Elist);
6227          end if;
6228       end if;
6229
6230       if Ekind (Full_Base) = E_Record_Type
6231         and then Has_Discriminants (Full_Base)
6232         and then Has_Discriminants (Priv) -- might not, if errors
6233         and then not Is_Empty_Elmt_List (Discriminant_Constraint (Priv))
6234       then
6235          Create_Constrained_Components
6236            (Full, Related_Nod, Full_Base, Discriminant_Constraint (Priv));
6237
6238       --  If the full base is itself derived from private, build a congruent
6239       --  subtype of its underlying type, for use by the back end.
6240
6241       elsif Ekind (Full_Base) in Private_Kind
6242         and then Is_Derived_Type (Full_Base)
6243         and then Has_Discriminants (Full_Base)
6244         and then
6245           Nkind (Subtype_Indication (Parent (Priv))) = N_Subtype_Indication
6246       then
6247          Build_Underlying_Full_View (Parent (Priv), Full, Etype (Full_Base));
6248
6249       elsif Is_Record_Type (Full_Base) then
6250
6251          --  Show Full is simply a renaming of Full_Base.
6252
6253          Set_Cloned_Subtype (Full, Full_Base);
6254       end if;
6255
6256       --  It is usafe to share to bounds of a scalar type, because the
6257       --  Itype is elaborated on demand, and if a bound is non-static
6258       --  then different orders of elaboration in different units will
6259       --  lead to different external symbols.
6260
6261       if Is_Scalar_Type (Full_Base) then
6262          Set_Scalar_Range (Full,
6263            Make_Range (Sloc (Related_Nod),
6264              Low_Bound  => Duplicate_Subexpr (Type_Low_Bound  (Full_Base)),
6265              High_Bound => Duplicate_Subexpr (Type_High_Bound (Full_Base))));
6266       end if;
6267
6268       --  ??? It seems that a lot of fields are missing that should be
6269       --  copied from  Full_Base to Full. Here are some that are introduced
6270       --  in a non-disruptive way but a cleanup is necessary.
6271
6272       if Is_Tagged_Type (Full_Base) then
6273          Set_Is_Tagged_Type (Full);
6274          Set_Primitive_Operations (Full, Primitive_Operations (Full_Base));
6275
6276       elsif Is_Concurrent_Type (Full_Base) then
6277
6278          if Has_Discriminants (Full)
6279            and then Present (Corresponding_Record_Type (Full_Base))
6280          then
6281             Set_Corresponding_Record_Type (Full,
6282               Constrain_Corresponding_Record
6283                 (Full, Corresponding_Record_Type (Full_Base),
6284                   Related_Nod, Full_Base));
6285
6286          else
6287             Set_Corresponding_Record_Type (Full,
6288               Corresponding_Record_Type (Full_Base));
6289          end if;
6290       end if;
6291
6292    end Complete_Private_Subtype;
6293
6294    ----------------------------
6295    -- Constant_Redeclaration --
6296    ----------------------------
6297
6298    procedure Constant_Redeclaration
6299      (Id : Entity_Id;
6300       N  : Node_Id;
6301       T  : out Entity_Id)
6302    is
6303       Prev    : constant Entity_Id := Current_Entity_In_Scope (Id);
6304       Obj_Def : constant Node_Id := Object_Definition (N);
6305       New_T   : Entity_Id;
6306
6307    begin
6308       if Nkind (Parent (Prev)) = N_Object_Declaration then
6309          if Nkind (Object_Definition
6310                      (Parent (Prev))) = N_Subtype_Indication
6311          then
6312             --  Find type of new declaration. The constraints of the two
6313             --  views must match statically, but there is no point in
6314             --  creating an itype for the full view.
6315
6316             if Nkind (Obj_Def) = N_Subtype_Indication then
6317                Find_Type (Subtype_Mark (Obj_Def));
6318                New_T := Entity (Subtype_Mark (Obj_Def));
6319
6320             else
6321                Find_Type (Obj_Def);
6322                New_T := Entity (Obj_Def);
6323             end if;
6324
6325             T := Etype (Prev);
6326
6327          else
6328             --  The full view may impose a constraint, even if the partial
6329             --  view does not, so construct the subtype.
6330
6331             New_T := Find_Type_Of_Object (Obj_Def, N);
6332             T     := New_T;
6333          end if;
6334
6335       else
6336          --  Current declaration is illegal, diagnosed below in Enter_Name.
6337
6338          T := Empty;
6339          New_T := Any_Type;
6340       end if;
6341
6342       --  If previous full declaration exists, or if a homograph is present,
6343       --  let Enter_Name handle it, either with an error, or with the removal
6344       --  of an overridden implicit subprogram.
6345
6346       if Ekind (Prev) /= E_Constant
6347         or else Present (Expression (Parent (Prev)))
6348       then
6349          Enter_Name (Id);
6350
6351       --  Verify that types of both declarations match.
6352
6353       elsif Base_Type (Etype (Prev)) /= Base_Type (New_T) then
6354          Error_Msg_Sloc := Sloc (Prev);
6355          Error_Msg_N ("type does not match declaration#", N);
6356          Set_Full_View (Prev, Id);
6357          Set_Etype (Id, Any_Type);
6358
6359       --  If so, process the full constant declaration
6360
6361       else
6362          Set_Full_View (Prev, Id);
6363          Set_Is_Public (Id, Is_Public (Prev));
6364          Set_Is_Internal (Id);
6365          Append_Entity (Id, Current_Scope);
6366
6367          --  Check ALIASED present if present before (RM 7.4(7))
6368
6369          if Is_Aliased (Prev)
6370            and then not Aliased_Present (N)
6371          then
6372             Error_Msg_Sloc := Sloc (Prev);
6373             Error_Msg_N ("ALIASED required (see declaration#)", N);
6374          end if;
6375
6376          --  Check that placement is in private part
6377
6378          if Ekind (Current_Scope) = E_Package
6379            and then not In_Private_Part (Current_Scope)
6380          then
6381             Error_Msg_Sloc := Sloc (Prev);
6382             Error_Msg_N ("full constant for declaration#"
6383                          & " must be in private part", N);
6384          end if;
6385       end if;
6386    end Constant_Redeclaration;
6387
6388    ----------------------
6389    -- Constrain_Access --
6390    ----------------------
6391
6392    procedure Constrain_Access
6393      (Def_Id      : in out Entity_Id;
6394       S           : Node_Id;
6395       Related_Nod : Node_Id)
6396    is
6397       T             : constant Entity_Id := Entity (Subtype_Mark (S));
6398       Desig_Type    : constant Entity_Id := Designated_Type (T);
6399       Desig_Subtype : Entity_Id := Create_Itype (E_Void, Related_Nod);
6400       Constraint_OK : Boolean := True;
6401
6402    begin
6403       if Is_Array_Type (Desig_Type) then
6404          Constrain_Array (Desig_Subtype, S, Related_Nod, Def_Id, 'P');
6405
6406       elsif (Is_Record_Type (Desig_Type)
6407               or else Is_Incomplete_Or_Private_Type (Desig_Type))
6408         and then not Is_Constrained (Desig_Type)
6409       then
6410          --  ??? The following code is a temporary kludge to ignore
6411          --  discriminant constraint on access type if
6412          --  it is constraining the current record. Avoid creating the
6413          --  implicit subtype of the record we are currently compiling
6414          --  since right now, we cannot handle these.
6415          --  For now, just return the access type itself.
6416
6417          if Desig_Type = Current_Scope
6418            and then No (Def_Id)
6419          then
6420             Set_Ekind (Desig_Subtype, E_Record_Subtype);
6421             Def_Id := Entity (Subtype_Mark (S));
6422
6423             --  This call added to ensure that the constraint is
6424             --  analyzed (needed for a B test). Note that we
6425             --  still return early from this procedure to avoid
6426             --  recursive processing. ???
6427
6428             Constrain_Discriminated_Type
6429               (Desig_Subtype, S, Related_Nod, For_Access => True);
6430
6431             return;
6432          end if;
6433
6434          Constrain_Discriminated_Type (Desig_Subtype, S, Related_Nod,
6435            For_Access => True);
6436
6437       elsif (Is_Task_Type (Desig_Type)
6438               or else Is_Protected_Type (Desig_Type))
6439         and then not Is_Constrained (Desig_Type)
6440       then
6441          Constrain_Concurrent
6442            (Desig_Subtype, S, Related_Nod, Desig_Type, ' ');
6443
6444       else
6445          Error_Msg_N ("invalid constraint on access type", S);
6446          Desig_Subtype := Desig_Type; -- Ignore invalid constraint.
6447          Constraint_OK := False;
6448       end if;
6449
6450       if No (Def_Id) then
6451          Def_Id := Create_Itype (E_Access_Subtype, Related_Nod);
6452       else
6453          Set_Ekind (Def_Id, E_Access_Subtype);
6454       end if;
6455
6456       if Constraint_OK then
6457          Set_Etype (Def_Id, Base_Type (T));
6458
6459          if Is_Private_Type (Desig_Type) then
6460             Prepare_Private_Subtype_Completion (Desig_Subtype, Related_Nod);
6461          end if;
6462       else
6463          Set_Etype (Def_Id, Any_Type);
6464       end if;
6465
6466       Set_Size_Info                (Def_Id, T);
6467       Set_Is_Constrained           (Def_Id, Constraint_OK);
6468       Set_Directly_Designated_Type (Def_Id, Desig_Subtype);
6469       Set_Depends_On_Private       (Def_Id, Has_Private_Component (Def_Id));
6470       Set_Is_Access_Constant       (Def_Id, Is_Access_Constant (T));
6471
6472       --  Itypes created for constrained record components do not receive
6473       --  a freeze node, they are elaborated when first seen.
6474
6475       if not Is_Record_Type (Current_Scope) then
6476          Conditional_Delay (Def_Id, T);
6477       end if;
6478    end Constrain_Access;
6479
6480    ---------------------
6481    -- Constrain_Array --
6482    ---------------------
6483
6484    procedure Constrain_Array
6485      (Def_Id      : in out Entity_Id;
6486       SI          : Node_Id;
6487       Related_Nod : Node_Id;
6488       Related_Id  : Entity_Id;
6489       Suffix      : Character)
6490    is
6491       C                     : constant Node_Id := Constraint (SI);
6492       Number_Of_Constraints : Nat := 0;
6493       Index                 : Node_Id;
6494       S, T                  : Entity_Id;
6495       Constraint_OK         : Boolean := True;
6496
6497    begin
6498       T := Entity (Subtype_Mark (SI));
6499
6500       if Ekind (T) in Access_Kind then
6501          T := Designated_Type (T);
6502       end if;
6503
6504       --  If an index constraint follows a subtype mark in a subtype indication
6505       --  then the type or subtype denoted by the subtype mark must not already
6506       --  impose an index constraint. The subtype mark must denote either an
6507       --  unconstrained array type or an access type whose designated type
6508       --  is such an array type... (RM 3.6.1)
6509
6510       if Is_Constrained (T) then
6511          Error_Msg_N
6512            ("array type is already constrained", Subtype_Mark (SI));
6513          Constraint_OK := False;
6514
6515       else
6516          S := First (Constraints (C));
6517
6518          while Present (S) loop
6519             Number_Of_Constraints := Number_Of_Constraints + 1;
6520             Next (S);
6521          end loop;
6522
6523          --  In either case, the index constraint must provide a discrete
6524          --  range for each index of the array type and the type of each
6525          --  discrete range must be the same as that of the corresponding
6526          --  index. (RM 3.6.1)
6527
6528          if Number_Of_Constraints /= Number_Dimensions (T) then
6529             Error_Msg_NE ("incorrect number of index constraints for }", C, T);
6530             Constraint_OK := False;
6531
6532          else
6533             S := First (Constraints (C));
6534             Index := First_Index (T);
6535             Analyze (Index);
6536
6537             --  Apply constraints to each index type
6538
6539             for J in 1 .. Number_Of_Constraints loop
6540                Constrain_Index (Index, S, Related_Nod, Related_Id, Suffix, J);
6541                Next (Index);
6542                Next (S);
6543             end loop;
6544
6545          end if;
6546       end if;
6547
6548       if No (Def_Id) then
6549          Def_Id :=
6550            Create_Itype (E_Array_Subtype, Related_Nod, Related_Id, Suffix);
6551       else
6552          Set_Ekind (Def_Id, E_Array_Subtype);
6553       end if;
6554
6555       Set_Size_Info      (Def_Id,                (T));
6556       Set_First_Rep_Item (Def_Id, First_Rep_Item (T));
6557       Set_Etype          (Def_Id, Base_Type      (T));
6558
6559       if Constraint_OK then
6560          Set_First_Index (Def_Id, First (Constraints (C)));
6561       end if;
6562
6563       Set_Component_Type     (Def_Id, Component_Type (T));
6564       Set_Is_Constrained     (Def_Id, True);
6565       Set_Is_Aliased         (Def_Id, Is_Aliased (T));
6566       Set_Depends_On_Private (Def_Id, Has_Private_Component (Def_Id));
6567
6568       Set_Is_Private_Composite (Def_Id, Is_Private_Composite (T));
6569       Set_Is_Limited_Composite (Def_Id, Is_Limited_Composite (T));
6570
6571       --  If the subtype is not that of a record component, build a freeze
6572       --  node if parent still needs one.
6573
6574       --  If the subtype is not that of a record component, make sure
6575       --  that the Depends_On_Private status is set (explanation ???)
6576       --  and also that a conditional delay is set.
6577
6578       if not Is_Type (Scope (Def_Id)) then
6579          Set_Depends_On_Private (Def_Id, Depends_On_Private (T));
6580          Conditional_Delay (Def_Id, T);
6581       end if;
6582
6583    end Constrain_Array;
6584
6585    ------------------------------
6586    -- Constrain_Component_Type --
6587    ------------------------------
6588
6589    function Constrain_Component_Type
6590      (Compon_Type     : Entity_Id;
6591       Constrained_Typ : Entity_Id;
6592       Related_Node    : Node_Id;
6593       Typ             : Entity_Id;
6594       Constraints     : Elist_Id)
6595       return            Entity_Id
6596    is
6597       Loc : constant Source_Ptr := Sloc (Constrained_Typ);
6598
6599       function Build_Constrained_Array_Type
6600         (Old_Type : Entity_Id)
6601          return     Entity_Id;
6602       --  If Old_Type is an array type, one of whose indices is
6603       --  constrained by a discriminant, build an Itype whose constraint
6604       --  replaces the discriminant with its value in the constraint.
6605
6606       function Build_Constrained_Discriminated_Type
6607         (Old_Type : Entity_Id)
6608          return     Entity_Id;
6609       --  Ditto for record components.
6610
6611       function Build_Constrained_Access_Type
6612         (Old_Type : Entity_Id)
6613          return     Entity_Id;
6614       --  Ditto for access types. Makes use of previous two functions, to
6615       --  constrain designated type.
6616
6617       function Build_Subtype (T : Entity_Id; C : List_Id) return Entity_Id;
6618       --  T is an array or discriminated type, C is a list of constraints
6619       --  that apply to T. This routine builds the constrained subtype.
6620
6621       function Is_Discriminant (Expr : Node_Id) return Boolean;
6622       --  Returns True if Expr is a discriminant.
6623
6624       function Get_Value (Discrim : Entity_Id) return Node_Id;
6625       --  Find the value of discriminant Discrim in Constraint.
6626
6627       -----------------------------------
6628       -- Build_Constrained_Access_Type --
6629       -----------------------------------
6630
6631       function Build_Constrained_Access_Type
6632         (Old_Type : Entity_Id)
6633         return      Entity_Id
6634       is
6635          Desig_Type    : constant Entity_Id := Designated_Type (Old_Type);
6636          Itype         : Entity_Id;
6637          Desig_Subtype : Entity_Id;
6638          Scop          : Entity_Id;
6639
6640       begin
6641          --  if the original access type was not embedded in the enclosing
6642          --  type definition, there is no need to produce a new access
6643          --  subtype. In fact every access type with an explicit constraint
6644          --  generates an itype whose scope is the enclosing record.
6645
6646          if not Is_Type (Scope (Old_Type)) then
6647             return Old_Type;
6648
6649          elsif Is_Array_Type (Desig_Type) then
6650             Desig_Subtype := Build_Constrained_Array_Type (Desig_Type);
6651
6652          elsif Has_Discriminants (Desig_Type) then
6653
6654             --  This may be an access type to an enclosing record type for
6655             --  which we are constructing the constrained components. Return
6656             --  the enclosing record subtype. This is not always correct,
6657             --  but avoids infinite recursion. ???
6658
6659             Desig_Subtype := Any_Type;
6660
6661             for J in reverse 0 .. Scope_Stack.Last loop
6662                Scop := Scope_Stack.Table (J).Entity;
6663
6664                if Is_Type (Scop)
6665                  and then Base_Type (Scop) = Base_Type (Desig_Type)
6666                then
6667                   Desig_Subtype := Scop;
6668                end if;
6669
6670                exit when not Is_Type (Scop);
6671             end loop;
6672
6673             if Desig_Subtype = Any_Type then
6674                Desig_Subtype :=
6675                  Build_Constrained_Discriminated_Type (Desig_Type);
6676             end if;
6677
6678          else
6679             return Old_Type;
6680          end if;
6681
6682          if Desig_Subtype /= Desig_Type then
6683             --  The Related_Node better be here or else we won't be able
6684             --  to attach new itypes to a node in the tree.
6685
6686             pragma Assert (Present (Related_Node));
6687
6688             Itype := Create_Itype (E_Access_Subtype, Related_Node);
6689
6690             Set_Etype                    (Itype, Base_Type      (Old_Type));
6691             Set_Size_Info                (Itype,                (Old_Type));
6692             Set_Directly_Designated_Type (Itype, Desig_Subtype);
6693             Set_Depends_On_Private       (Itype, Has_Private_Component
6694                                                                 (Old_Type));
6695             Set_Is_Access_Constant       (Itype, Is_Access_Constant
6696                                                                 (Old_Type));
6697
6698             --  The new itype needs freezing when it depends on a not frozen
6699             --  type and the enclosing subtype needs freezing.
6700
6701             if Has_Delayed_Freeze (Constrained_Typ)
6702               and then not Is_Frozen (Constrained_Typ)
6703             then
6704                Conditional_Delay (Itype, Base_Type (Old_Type));
6705             end if;
6706
6707             return Itype;
6708
6709          else
6710             return Old_Type;
6711          end if;
6712       end Build_Constrained_Access_Type;
6713
6714       ----------------------------------
6715       -- Build_Constrained_Array_Type --
6716       ----------------------------------
6717
6718       function Build_Constrained_Array_Type
6719         (Old_Type : Entity_Id)
6720          return     Entity_Id
6721       is
6722          Lo_Expr     : Node_Id;
6723          Hi_Expr     : Node_Id;
6724          Old_Index   : Node_Id;
6725          Range_Node  : Node_Id;
6726          Constr_List : List_Id;
6727
6728          Need_To_Create_Itype : Boolean := False;
6729
6730       begin
6731          Old_Index := First_Index (Old_Type);
6732          while Present (Old_Index) loop
6733             Get_Index_Bounds (Old_Index, Lo_Expr, Hi_Expr);
6734
6735             if Is_Discriminant (Lo_Expr)
6736               or else Is_Discriminant (Hi_Expr)
6737             then
6738                Need_To_Create_Itype := True;
6739             end if;
6740
6741             Next_Index (Old_Index);
6742          end loop;
6743
6744          if Need_To_Create_Itype then
6745             Constr_List := New_List;
6746
6747             Old_Index := First_Index (Old_Type);
6748             while Present (Old_Index) loop
6749                Get_Index_Bounds (Old_Index, Lo_Expr, Hi_Expr);
6750
6751                if Is_Discriminant (Lo_Expr) then
6752                   Lo_Expr := Get_Value (Lo_Expr);
6753                end if;
6754
6755                if Is_Discriminant (Hi_Expr) then
6756                   Hi_Expr := Get_Value (Hi_Expr);
6757                end if;
6758
6759                Range_Node :=
6760                  Make_Range
6761                    (Loc, New_Copy_Tree (Lo_Expr), New_Copy_Tree (Hi_Expr));
6762
6763                Append (Range_Node, To => Constr_List);
6764
6765                Next_Index (Old_Index);
6766             end loop;
6767
6768             return Build_Subtype (Old_Type, Constr_List);
6769
6770          else
6771             return Old_Type;
6772          end if;
6773       end Build_Constrained_Array_Type;
6774
6775       ------------------------------------------
6776       -- Build_Constrained_Discriminated_Type --
6777       ------------------------------------------
6778
6779       function Build_Constrained_Discriminated_Type
6780         (Old_Type : Entity_Id)
6781          return     Entity_Id
6782       is
6783          Expr           : Node_Id;
6784          Constr_List    : List_Id;
6785          Old_Constraint : Elmt_Id;
6786
6787          Need_To_Create_Itype : Boolean := False;
6788
6789       begin
6790          Old_Constraint := First_Elmt (Discriminant_Constraint (Old_Type));
6791          while Present (Old_Constraint) loop
6792             Expr := Node (Old_Constraint);
6793
6794             if Is_Discriminant (Expr) then
6795                Need_To_Create_Itype := True;
6796             end if;
6797
6798             Next_Elmt (Old_Constraint);
6799          end loop;
6800
6801          if Need_To_Create_Itype then
6802             Constr_List := New_List;
6803
6804             Old_Constraint := First_Elmt (Discriminant_Constraint (Old_Type));
6805             while Present (Old_Constraint) loop
6806                Expr := Node (Old_Constraint);
6807
6808                if Is_Discriminant (Expr) then
6809                   Expr := Get_Value (Expr);
6810                end if;
6811
6812                Append (New_Copy_Tree (Expr), To => Constr_List);
6813
6814                Next_Elmt (Old_Constraint);
6815             end loop;
6816
6817             return Build_Subtype (Old_Type, Constr_List);
6818
6819          else
6820             return Old_Type;
6821          end if;
6822       end Build_Constrained_Discriminated_Type;
6823
6824       -------------------
6825       -- Build_Subtype --
6826       -------------------
6827
6828       function Build_Subtype (T : Entity_Id; C : List_Id) return Entity_Id is
6829          Indic       : Node_Id;
6830          Subtyp_Decl : Node_Id;
6831          Def_Id      : Entity_Id;
6832          Btyp        : Entity_Id := Base_Type (T);
6833
6834       begin
6835          --  The Related_Node better be here or else we won't be able
6836          --  to attach new itypes to a node in the tree.
6837
6838          pragma Assert (Present (Related_Node));
6839
6840          --  If the view of the component's type is incomplete or private
6841          --  with unknown discriminants, then the constraint must be applied
6842          --  to the full type.
6843
6844          if Has_Unknown_Discriminants (Btyp)
6845            and then Present (Underlying_Type (Btyp))
6846          then
6847             Btyp := Underlying_Type (Btyp);
6848          end if;
6849
6850          Indic :=
6851            Make_Subtype_Indication (Loc,
6852              Subtype_Mark => New_Occurrence_Of (Btyp, Loc),
6853              Constraint   => Make_Index_Or_Discriminant_Constraint (Loc, C));
6854
6855          Def_Id := Create_Itype (Ekind (T), Related_Node);
6856
6857          Subtyp_Decl :=
6858            Make_Subtype_Declaration (Loc,
6859              Defining_Identifier => Def_Id,
6860              Subtype_Indication  => Indic);
6861          Set_Parent (Subtyp_Decl, Parent (Related_Node));
6862
6863          --  Itypes must be analyzed with checks off (see itypes.ads).
6864
6865          Analyze (Subtyp_Decl, Suppress => All_Checks);
6866
6867          return Def_Id;
6868       end Build_Subtype;
6869
6870       ---------------
6871       -- Get_Value --
6872       ---------------
6873
6874       function Get_Value (Discrim : Entity_Id) return Node_Id is
6875          D : Entity_Id := First_Discriminant (Typ);
6876          E : Elmt_Id   := First_Elmt (Constraints);
6877
6878       begin
6879          while Present (D) loop
6880
6881             --  If we are constraining the subtype of a derived tagged type,
6882             --  recover the discriminant of the parent, which appears in
6883             --  the constraint of an inherited component.
6884
6885             if D = Entity (Discrim)
6886               or else Corresponding_Discriminant (D) = Entity (Discrim)
6887             then
6888                return Node (E);
6889             end if;
6890
6891             Next_Discriminant (D);
6892             Next_Elmt (E);
6893          end loop;
6894
6895          --  Something is wrong if we did not find the value
6896
6897          raise Program_Error;
6898       end Get_Value;
6899
6900       ---------------------
6901       -- Is_Discriminant --
6902       ---------------------
6903
6904       function Is_Discriminant (Expr : Node_Id) return Boolean is
6905          Discrim_Scope : Entity_Id;
6906
6907       begin
6908          if Denotes_Discriminant (Expr) then
6909             Discrim_Scope := Scope (Entity (Expr));
6910
6911             --  Either we have a reference to one of Typ's discriminants,
6912
6913             pragma Assert (Discrim_Scope = Typ
6914
6915                --  or to the discriminants of the parent type, in the case
6916                --  of a derivation of a tagged type with variants.
6917
6918                or else Discrim_Scope = Etype (Typ)
6919                or else Full_View (Discrim_Scope) = Etype (Typ)
6920
6921                --  or same as above for the case where the discriminants
6922                --  were declared in Typ's private view.
6923
6924                or else (Is_Private_Type (Discrim_Scope)
6925                         and then Chars (Discrim_Scope) = Chars (Typ))
6926
6927                --  or else we are deriving from the full view and the
6928                --  discriminant is declared in the private entity.
6929
6930                or else (Is_Private_Type (Typ)
6931                         and then Chars (Discrim_Scope) = Chars (Typ))
6932
6933                --  or we have a class-wide type, in which case make sure the
6934                --  discriminant found belongs to the root type.
6935
6936                or else (Is_Class_Wide_Type (Typ)
6937                         and then Etype (Typ) = Discrim_Scope));
6938
6939             return True;
6940          end if;
6941
6942          --  In all other cases we have something wrong.
6943
6944          return False;
6945       end Is_Discriminant;
6946
6947    --  Start of processing for Constrain_Component_Type
6948
6949    begin
6950       if Is_Array_Type (Compon_Type) then
6951          return Build_Constrained_Array_Type (Compon_Type);
6952
6953       elsif Has_Discriminants (Compon_Type) then
6954          return Build_Constrained_Discriminated_Type (Compon_Type);
6955
6956       elsif Is_Access_Type (Compon_Type) then
6957          return Build_Constrained_Access_Type (Compon_Type);
6958       end if;
6959
6960       return Compon_Type;
6961    end Constrain_Component_Type;
6962
6963    --------------------------
6964    -- Constrain_Concurrent --
6965    --------------------------
6966
6967    --  For concurrent types, the associated record value type carries the same
6968    --  discriminants, so when we constrain a concurrent type, we must constrain
6969    --  the value type as well.
6970
6971    procedure Constrain_Concurrent
6972      (Def_Id      : in out Entity_Id;
6973       SI          : Node_Id;
6974       Related_Nod : Node_Id;
6975       Related_Id  : Entity_Id;
6976       Suffix      : Character)
6977    is
6978       T_Ent : Entity_Id := Entity (Subtype_Mark (SI));
6979       T_Val : Entity_Id;
6980
6981    begin
6982       if Ekind (T_Ent) in Access_Kind then
6983          T_Ent := Designated_Type (T_Ent);
6984       end if;
6985
6986       T_Val := Corresponding_Record_Type (T_Ent);
6987
6988       if Present (T_Val) then
6989
6990          if No (Def_Id) then
6991             Def_Id := Create_Itype (E_Void, Related_Nod, Related_Id, Suffix);
6992          end if;
6993
6994          Constrain_Discriminated_Type (Def_Id, SI, Related_Nod);
6995
6996          Set_Depends_On_Private (Def_Id, Has_Private_Component (Def_Id));
6997          Set_Corresponding_Record_Type (Def_Id,
6998            Constrain_Corresponding_Record
6999              (Def_Id, T_Val, Related_Nod, Related_Id));
7000
7001       else
7002          --  If there is no associated record, expansion is disabled and this
7003          --  is a generic context. Create a subtype in any case, so that
7004          --  semantic analysis can proceed.
7005
7006          if No (Def_Id) then
7007             Def_Id := Create_Itype (E_Void, Related_Nod, Related_Id, Suffix);
7008          end if;
7009
7010          Constrain_Discriminated_Type (Def_Id, SI, Related_Nod);
7011       end if;
7012    end Constrain_Concurrent;
7013
7014    ------------------------------------
7015    -- Constrain_Corresponding_Record --
7016    ------------------------------------
7017
7018    function Constrain_Corresponding_Record
7019      (Prot_Subt   : Entity_Id;
7020       Corr_Rec    : Entity_Id;
7021       Related_Nod : Node_Id;
7022       Related_Id  : Entity_Id)
7023       return Entity_Id
7024    is
7025       T_Sub : constant Entity_Id
7026         := Create_Itype (E_Record_Subtype, Related_Nod, Related_Id, 'V');
7027
7028    begin
7029       Set_Etype                   (T_Sub, Corr_Rec);
7030       Init_Size_Align             (T_Sub);
7031       Set_Has_Discriminants       (T_Sub, Has_Discriminants (Prot_Subt));
7032       Set_Is_Constrained          (T_Sub, True);
7033       Set_First_Entity            (T_Sub, First_Entity (Corr_Rec));
7034       Set_Last_Entity             (T_Sub, Last_Entity  (Corr_Rec));
7035
7036       Conditional_Delay (T_Sub, Corr_Rec);
7037
7038       if Has_Discriminants (Prot_Subt) then -- False only if errors.
7039          Set_Discriminant_Constraint (T_Sub,
7040                                       Discriminant_Constraint (Prot_Subt));
7041          Set_Girder_Constraint_From_Discriminant_Constraint (T_Sub);
7042          Create_Constrained_Components (T_Sub, Related_Nod, Corr_Rec,
7043                                         Discriminant_Constraint (T_Sub));
7044       end if;
7045
7046       Set_Depends_On_Private      (T_Sub, Has_Private_Component (T_Sub));
7047
7048       return T_Sub;
7049    end Constrain_Corresponding_Record;
7050
7051    -----------------------
7052    -- Constrain_Decimal --
7053    -----------------------
7054
7055    procedure Constrain_Decimal
7056      (Def_Id      : Node_Id;
7057       S           : Node_Id;
7058       Related_Nod : Node_Id)
7059    is
7060       T           : constant Entity_Id  := Entity (Subtype_Mark (S));
7061       C           : constant Node_Id    := Constraint (S);
7062       Loc         : constant Source_Ptr := Sloc (C);
7063       Range_Expr  : Node_Id;
7064       Digits_Expr : Node_Id;
7065       Digits_Val  : Uint;
7066       Bound_Val   : Ureal;
7067
7068    begin
7069       Set_Ekind (Def_Id, E_Decimal_Fixed_Point_Subtype);
7070
7071       if Nkind (C) = N_Range_Constraint then
7072          Range_Expr := Range_Expression (C);
7073          Digits_Val := Digits_Value (T);
7074
7075       else
7076          pragma Assert (Nkind (C) = N_Digits_Constraint);
7077          Digits_Expr := Digits_Expression (C);
7078          Analyze_And_Resolve (Digits_Expr, Any_Integer);
7079
7080          Check_Digits_Expression (Digits_Expr);
7081          Digits_Val := Expr_Value (Digits_Expr);
7082
7083          if Digits_Val > Digits_Value (T) then
7084             Error_Msg_N
7085                ("digits expression is incompatible with subtype", C);
7086             Digits_Val := Digits_Value (T);
7087          end if;
7088
7089          if Present (Range_Constraint (C)) then
7090             Range_Expr := Range_Expression (Range_Constraint (C));
7091          else
7092             Range_Expr := Empty;
7093          end if;
7094       end if;
7095
7096       Set_Etype            (Def_Id, Base_Type        (T));
7097       Set_Size_Info        (Def_Id,                  (T));
7098       Set_First_Rep_Item   (Def_Id, First_Rep_Item   (T));
7099       Set_Delta_Value      (Def_Id, Delta_Value      (T));
7100       Set_Scale_Value      (Def_Id, Scale_Value      (T));
7101       Set_Small_Value      (Def_Id, Small_Value      (T));
7102       Set_Machine_Radix_10 (Def_Id, Machine_Radix_10 (T));
7103       Set_Digits_Value     (Def_Id, Digits_Val);
7104
7105       --  Manufacture range from given digits value if no range present
7106
7107       if No (Range_Expr) then
7108          Bound_Val := (Ureal_10 ** Digits_Val - Ureal_1) * Small_Value (T);
7109          Range_Expr :=
7110             Make_Range (Loc,
7111                Low_Bound =>
7112                  Convert_To (T, Make_Real_Literal (Loc, (-Bound_Val))),
7113                High_Bound =>
7114                  Convert_To (T, Make_Real_Literal (Loc, Bound_Val)));
7115
7116       end if;
7117
7118       Set_Scalar_Range_For_Subtype (Def_Id, Range_Expr, T, Related_Nod);
7119       Set_Discrete_RM_Size (Def_Id);
7120
7121       --  Unconditionally delay the freeze, since we cannot set size
7122       --  information in all cases correctly until the freeze point.
7123
7124       Set_Has_Delayed_Freeze (Def_Id);
7125    end Constrain_Decimal;
7126
7127    ----------------------------------
7128    -- Constrain_Discriminated_Type --
7129    ----------------------------------
7130
7131    procedure Constrain_Discriminated_Type
7132      (Def_Id      : Entity_Id;
7133       S           : Node_Id;
7134       Related_Nod : Node_Id;
7135       For_Access  : Boolean := False)
7136    is
7137       T     : Entity_Id;
7138       C     : Node_Id;
7139       Elist : Elist_Id := New_Elmt_List;
7140
7141       procedure Fixup_Bad_Constraint;
7142       --  This is called after finding a bad constraint, and after having
7143       --  posted an appropriate error message. The mission is to leave the
7144       --  entity T in as reasonable state as possible!
7145
7146       procedure Fixup_Bad_Constraint is
7147       begin
7148          --  Set a reasonable Ekind for the entity. For an incomplete type,
7149          --  we can't do much, but for other types, we can set the proper
7150          --  corresponding subtype kind.
7151
7152          if Ekind (T) = E_Incomplete_Type then
7153             Set_Ekind (Def_Id, Ekind (T));
7154          else
7155             Set_Ekind (Def_Id, Subtype_Kind (Ekind (T)));
7156          end if;
7157
7158          Set_Etype (Def_Id, Any_Type);
7159          Set_Error_Posted (Def_Id);
7160       end Fixup_Bad_Constraint;
7161
7162    --  Start of processing for Constrain_Discriminated_Type
7163
7164    begin
7165       C := Constraint (S);
7166
7167       --  A discriminant constraint is only allowed in a subtype indication,
7168       --  after a subtype mark. This subtype mark must denote either a type
7169       --  with discriminants, or an access type whose designated type is a
7170       --  type with discriminants. A discriminant constraint specifies the
7171       --  values of these discriminants (RM 3.7.2(5)).
7172
7173       T := Base_Type (Entity (Subtype_Mark (S)));
7174
7175       if Ekind (T) in Access_Kind then
7176          T := Designated_Type (T);
7177       end if;
7178
7179       if not Has_Discriminants (T) then
7180          Error_Msg_N ("invalid constraint: type has no discriminant", C);
7181          Fixup_Bad_Constraint;
7182          return;
7183
7184       elsif Is_Constrained (Entity (Subtype_Mark (S))) then
7185          Error_Msg_N ("type is already constrained", Subtype_Mark (S));
7186          Fixup_Bad_Constraint;
7187          return;
7188       end if;
7189
7190       --  T may be an unconstrained subtype (e.g. a generic actual).
7191       --  Constraint applies to the base type.
7192
7193       T := Base_Type (T);
7194
7195       Elist := Build_Discriminant_Constraints (T, S);
7196
7197       --  If the list returned was empty we had an error in building the
7198       --  discriminant constraint. We have also already signalled an error
7199       --  in the incomplete type case
7200
7201       if Is_Empty_Elmt_List (Elist) then
7202          Fixup_Bad_Constraint;
7203          return;
7204       end if;
7205
7206       Build_Discriminated_Subtype (T, Def_Id, Elist, Related_Nod, For_Access);
7207    end Constrain_Discriminated_Type;
7208
7209    ---------------------------
7210    -- Constrain_Enumeration --
7211    ---------------------------
7212
7213    procedure Constrain_Enumeration
7214      (Def_Id      : Node_Id;
7215       S           : Node_Id;
7216       Related_Nod : Node_Id)
7217    is
7218       T : constant Entity_Id := Entity (Subtype_Mark (S));
7219       C : constant Node_Id   := Constraint (S);
7220
7221    begin
7222       Set_Ekind (Def_Id, E_Enumeration_Subtype);
7223
7224       Set_First_Literal     (Def_Id, First_Literal (Base_Type (T)));
7225
7226       Set_Etype             (Def_Id, Base_Type         (T));
7227       Set_Size_Info         (Def_Id,                   (T));
7228       Set_First_Rep_Item    (Def_Id, First_Rep_Item    (T));
7229       Set_Is_Character_Type (Def_Id, Is_Character_Type (T));
7230
7231       Set_Scalar_Range_For_Subtype
7232         (Def_Id, Range_Expression (C), T, Related_Nod);
7233
7234       Set_Discrete_RM_Size (Def_Id);
7235
7236    end Constrain_Enumeration;
7237
7238    ----------------------
7239    -- Constrain_Float --
7240    ----------------------
7241
7242    procedure Constrain_Float
7243      (Def_Id      : Node_Id;
7244       S           : Node_Id;
7245       Related_Nod : Node_Id)
7246    is
7247       T    : constant Entity_Id := Entity (Subtype_Mark (S));
7248       C    : Node_Id;
7249       D    : Node_Id;
7250       Rais : Node_Id;
7251
7252    begin
7253       Set_Ekind (Def_Id, E_Floating_Point_Subtype);
7254
7255       Set_Etype          (Def_Id, Base_Type      (T));
7256       Set_Size_Info      (Def_Id,                (T));
7257       Set_First_Rep_Item (Def_Id, First_Rep_Item (T));
7258
7259       --  Process the constraint
7260
7261       C := Constraint (S);
7262
7263       --  Digits constraint present
7264
7265       if Nkind (C) = N_Digits_Constraint then
7266          D := Digits_Expression (C);
7267          Analyze_And_Resolve (D, Any_Integer);
7268          Check_Digits_Expression (D);
7269          Set_Digits_Value (Def_Id, Expr_Value (D));
7270
7271          --  Check that digits value is in range. Obviously we can do this
7272          --  at compile time, but it is strictly a runtime check, and of
7273          --  course there is an ACVC test that checks this!
7274
7275          if Digits_Value (Def_Id) > Digits_Value (T) then
7276             Error_Msg_Uint_1 := Digits_Value (T);
7277             Error_Msg_N ("?digits value is too large, maximum is ^", D);
7278             Rais := Make_Raise_Constraint_Error (Sloc (D));
7279             Insert_Action (Declaration_Node (Def_Id), Rais);
7280          end if;
7281
7282          C := Range_Constraint (C);
7283
7284       --  No digits constraint present
7285
7286       else
7287          Set_Digits_Value (Def_Id, Digits_Value (T));
7288       end if;
7289
7290       --  Range constraint present
7291
7292       if Nkind (C) = N_Range_Constraint then
7293          Set_Scalar_Range_For_Subtype
7294            (Def_Id, Range_Expression (C), T, Related_Nod);
7295
7296       --  No range constraint present
7297
7298       else
7299          pragma Assert (No (C));
7300          Set_Scalar_Range (Def_Id, Scalar_Range (T));
7301       end if;
7302
7303       Set_Is_Constrained (Def_Id);
7304    end Constrain_Float;
7305
7306    ---------------------
7307    -- Constrain_Index --
7308    ---------------------
7309
7310    procedure Constrain_Index
7311      (Index        : Node_Id;
7312       S            : Node_Id;
7313       Related_Nod  : Node_Id;
7314       Related_Id   : Entity_Id;
7315       Suffix       : Character;
7316       Suffix_Index : Nat)
7317    is
7318       Def_Id     : Entity_Id;
7319       R          : Node_Id := Empty;
7320       Checks_Off : Boolean := False;
7321       T          : constant Entity_Id := Etype (Index);
7322
7323    begin
7324       if Nkind (S) = N_Range
7325         or else Nkind (S) = N_Attribute_Reference
7326       then
7327          --  A Range attribute will transformed into N_Range by Resolve.
7328
7329          Analyze (S);
7330          Set_Etype (S, T);
7331          R := S;
7332
7333          --  ??? Why on earth do we turn checks of in this very specific case ?
7334
7335          --  From the revision history: (Constrain_Index): Call
7336          --  Process_Range_Expr_In_Decl with range checking off for range
7337          --  bounds that are attributes. This avoids some horrible
7338          --  constraint error checks.
7339
7340          if Nkind (R) = N_Range
7341            and then Nkind (Low_Bound (R)) = N_Attribute_Reference
7342            and then Nkind (High_Bound (R)) = N_Attribute_Reference
7343          then
7344             Checks_Off := True;
7345          end if;
7346
7347          Process_Range_Expr_In_Decl
7348            (R, T, Related_Nod, Empty_List, Checks_Off);
7349
7350          if not Error_Posted (S)
7351            and then
7352              (Nkind (S) /= N_Range
7353                or else Base_Type (T) /= Base_Type (Etype (Low_Bound (S)))
7354                or else Base_Type (T) /= Base_Type (Etype (High_Bound (S))))
7355          then
7356             if Base_Type (T) /= Any_Type
7357               and then Etype (Low_Bound (S)) /= Any_Type
7358               and then Etype (High_Bound (S)) /= Any_Type
7359             then
7360                Error_Msg_N ("range expected", S);
7361             end if;
7362          end if;
7363
7364       elsif Nkind (S) = N_Subtype_Indication then
7365          --  the parser has verified that this is a discrete indication.
7366
7367          Resolve_Discrete_Subtype_Indication (S, T);
7368          R := Range_Expression (Constraint (S));
7369
7370       elsif Nkind (S) = N_Discriminant_Association then
7371
7372          --  syntactically valid in subtype indication.
7373
7374          Error_Msg_N ("invalid index constraint", S);
7375          Rewrite (S, New_Occurrence_Of (T, Sloc (S)));
7376          return;
7377
7378       --  Subtype_Mark case, no anonymous subtypes to construct
7379
7380       else
7381          Analyze (S);
7382
7383          if Is_Entity_Name (S) then
7384
7385             if not Is_Type (Entity (S)) then
7386                Error_Msg_N ("expect subtype mark for index constraint", S);
7387
7388             elsif Base_Type (Entity (S)) /= Base_Type (T) then
7389                Wrong_Type (S, Base_Type (T));
7390             end if;
7391
7392             return;
7393
7394          else
7395             Error_Msg_N ("invalid index constraint", S);
7396             Rewrite (S, New_Occurrence_Of (T, Sloc (S)));
7397             return;
7398          end if;
7399       end if;
7400
7401       Def_Id :=
7402         Create_Itype (E_Void, Related_Nod, Related_Id, Suffix, Suffix_Index);
7403
7404       Set_Etype (Def_Id, Base_Type (T));
7405
7406       if Is_Modular_Integer_Type (T) then
7407          Set_Ekind (Def_Id, E_Modular_Integer_Subtype);
7408
7409       elsif Is_Integer_Type (T) then
7410          Set_Ekind (Def_Id, E_Signed_Integer_Subtype);
7411
7412       else
7413          Set_Ekind (Def_Id, E_Enumeration_Subtype);
7414          Set_Is_Character_Type (Def_Id, Is_Character_Type (T));
7415       end if;
7416
7417       Set_Size_Info      (Def_Id,                (T));
7418       Set_RM_Size        (Def_Id, RM_Size        (T));
7419       Set_First_Rep_Item (Def_Id, First_Rep_Item (T));
7420
7421       Set_Scalar_Range   (Def_Id, R);
7422
7423       Set_Etype (S, Def_Id);
7424       Set_Discrete_RM_Size (Def_Id);
7425    end Constrain_Index;
7426
7427    -----------------------
7428    -- Constrain_Integer --
7429    -----------------------
7430
7431    procedure Constrain_Integer
7432      (Def_Id      : Node_Id;
7433       S           : Node_Id;
7434       Related_Nod : Node_Id)
7435    is
7436       T : constant Entity_Id := Entity (Subtype_Mark (S));
7437       C : constant Node_Id   := Constraint (S);
7438
7439    begin
7440       Set_Scalar_Range_For_Subtype
7441         (Def_Id, Range_Expression (C), T, Related_Nod);
7442
7443       if Is_Modular_Integer_Type (T) then
7444          Set_Ekind (Def_Id, E_Modular_Integer_Subtype);
7445       else
7446          Set_Ekind (Def_Id, E_Signed_Integer_Subtype);
7447       end if;
7448
7449       Set_Etype            (Def_Id, Base_Type        (T));
7450       Set_Size_Info        (Def_Id,                  (T));
7451       Set_First_Rep_Item   (Def_Id, First_Rep_Item   (T));
7452       Set_Discrete_RM_Size (Def_Id);
7453
7454    end Constrain_Integer;
7455
7456    ------------------------------
7457    -- Constrain_Ordinary_Fixed --
7458    ------------------------------
7459
7460    procedure Constrain_Ordinary_Fixed
7461      (Def_Id      : Node_Id;
7462       S           : Node_Id;
7463       Related_Nod : Node_Id)
7464    is
7465       T    : constant Entity_Id := Entity (Subtype_Mark (S));
7466       C    : Node_Id;
7467       D    : Node_Id;
7468       Rais : Node_Id;
7469
7470    begin
7471       Set_Ekind          (Def_Id, E_Ordinary_Fixed_Point_Subtype);
7472       Set_Etype          (Def_Id, Base_Type        (T));
7473       Set_Size_Info      (Def_Id,                  (T));
7474       Set_First_Rep_Item (Def_Id, First_Rep_Item   (T));
7475       Set_Small_Value    (Def_Id, Small_Value      (T));
7476
7477       --  Process the constraint
7478
7479       C := Constraint (S);
7480
7481       --  Delta constraint present
7482
7483       if Nkind (C) = N_Delta_Constraint then
7484          D := Delta_Expression (C);
7485          Analyze_And_Resolve (D, Any_Real);
7486          Check_Delta_Expression (D);
7487          Set_Delta_Value (Def_Id, Expr_Value_R (D));
7488
7489          --  Check that delta value is in range. Obviously we can do this
7490          --  at compile time, but it is strictly a runtime check, and of
7491          --  course there is an ACVC test that checks this!
7492
7493          if Delta_Value (Def_Id) < Delta_Value (T) then
7494             Error_Msg_N ("?delta value is too small", D);
7495             Rais := Make_Raise_Constraint_Error (Sloc (D));
7496             Insert_Action (Declaration_Node (Def_Id), Rais);
7497          end if;
7498
7499          C := Range_Constraint (C);
7500
7501       --  No delta constraint present
7502
7503       else
7504          Set_Delta_Value (Def_Id, Delta_Value (T));
7505       end if;
7506
7507       --  Range constraint present
7508
7509       if Nkind (C) = N_Range_Constraint then
7510          Set_Scalar_Range_For_Subtype
7511            (Def_Id, Range_Expression (C), T, Related_Nod);
7512
7513       --  No range constraint present
7514
7515       else
7516          pragma Assert (No (C));
7517          Set_Scalar_Range (Def_Id, Scalar_Range (T));
7518
7519       end if;
7520
7521       Set_Discrete_RM_Size (Def_Id);
7522
7523       --  Unconditionally delay the freeze, since we cannot set size
7524       --  information in all cases correctly until the freeze point.
7525
7526       Set_Has_Delayed_Freeze (Def_Id);
7527    end Constrain_Ordinary_Fixed;
7528
7529    ---------------------------
7530    -- Convert_Scalar_Bounds --
7531    ---------------------------
7532
7533    procedure Convert_Scalar_Bounds
7534      (N            : Node_Id;
7535       Parent_Type  : Entity_Id;
7536       Derived_Type : Entity_Id;
7537       Loc          : Source_Ptr)
7538    is
7539       Implicit_Base : constant Entity_Id := Base_Type (Derived_Type);
7540
7541       Lo  : Node_Id;
7542       Hi  : Node_Id;
7543       Rng : Node_Id;
7544
7545    begin
7546       Lo := Build_Scalar_Bound
7547               (Type_Low_Bound (Derived_Type),
7548                Parent_Type, Implicit_Base, Loc);
7549
7550       Hi := Build_Scalar_Bound
7551               (Type_High_Bound (Derived_Type),
7552                Parent_Type, Implicit_Base, Loc);
7553
7554       Rng :=
7555         Make_Range (Loc,
7556           Low_Bound  => Lo,
7557           High_Bound => Hi);
7558
7559       Set_Includes_Infinities (Rng, Has_Infinities (Derived_Type));
7560
7561       Set_Parent (Rng, N);
7562       Set_Scalar_Range (Derived_Type, Rng);
7563
7564       --  Analyze the bounds
7565
7566       Analyze_And_Resolve (Lo, Implicit_Base);
7567       Analyze_And_Resolve (Hi, Implicit_Base);
7568
7569       --  Analyze the range itself, except that we do not analyze it if
7570       --  the bounds are real literals, and we have a fixed-point type.
7571       --  The reason for this is that we delay setting the bounds in this
7572       --  case till we know the final Small and Size values (see circuit
7573       --  in Freeze.Freeze_Fixed_Point_Type for further details).
7574
7575       if Is_Fixed_Point_Type (Parent_Type)
7576         and then Nkind (Lo) = N_Real_Literal
7577         and then Nkind (Hi) = N_Real_Literal
7578       then
7579          return;
7580
7581       --  Here we do the analysis of the range.
7582
7583       --  Note: we do this manually, since if we do a normal Analyze and
7584       --  Resolve call, there are problems with the conversions used for
7585       --  the derived type range.
7586
7587       else
7588          Set_Etype    (Rng, Implicit_Base);
7589          Set_Analyzed (Rng, True);
7590       end if;
7591    end Convert_Scalar_Bounds;
7592
7593    -------------------
7594    -- Copy_And_Swap --
7595    -------------------
7596
7597    procedure Copy_And_Swap (Privat, Full : Entity_Id) is
7598    begin
7599       --  Initialize new full declaration entity by copying the pertinent
7600       --  fields of the corresponding private declaration entity.
7601
7602       Copy_Private_To_Full (Privat, Full);
7603
7604       --  Swap the two entities. Now Privat is the full type entity and
7605       --  Full is the private one. They will be swapped back at the end
7606       --  of the private part. This swapping ensures that the entity that
7607       --  is visible in the private part is the full declaration.
7608
7609       Exchange_Entities (Privat, Full);
7610       Append_Entity (Full, Scope (Full));
7611    end Copy_And_Swap;
7612
7613    -------------------------------------
7614    -- Copy_Array_Base_Type_Attributes --
7615    -------------------------------------
7616
7617    procedure Copy_Array_Base_Type_Attributes (T1, T2 : Entity_Id) is
7618    begin
7619       Set_Component_Alignment      (T1, Component_Alignment      (T2));
7620       Set_Component_Type           (T1, Component_Type           (T2));
7621       Set_Component_Size           (T1, Component_Size           (T2));
7622       Set_Has_Controlled_Component (T1, Has_Controlled_Component (T2));
7623       Set_Finalize_Storage_Only    (T1, Finalize_Storage_Only    (T2));
7624       Set_Has_Non_Standard_Rep     (T1, Has_Non_Standard_Rep     (T2));
7625       Set_Has_Task                 (T1, Has_Task                 (T2));
7626       Set_Is_Packed                (T1, Is_Packed                (T2));
7627       Set_Has_Aliased_Components   (T1, Has_Aliased_Components   (T2));
7628       Set_Has_Atomic_Components    (T1, Has_Atomic_Components    (T2));
7629       Set_Has_Volatile_Components  (T1, Has_Volatile_Components  (T2));
7630    end Copy_Array_Base_Type_Attributes;
7631
7632    -----------------------------------
7633    -- Copy_Array_Subtype_Attributes --
7634    -----------------------------------
7635
7636    procedure Copy_Array_Subtype_Attributes (T1, T2 : Entity_Id) is
7637    begin
7638       Set_Size_Info (T1, T2);
7639
7640       Set_First_Index          (T1, First_Index           (T2));
7641       Set_Is_Aliased           (T1, Is_Aliased            (T2));
7642       Set_Is_Atomic            (T1, Is_Atomic             (T2));
7643       Set_Is_Volatile          (T1, Is_Volatile           (T2));
7644       Set_Is_Constrained       (T1, Is_Constrained        (T2));
7645       Set_Depends_On_Private   (T1, Has_Private_Component (T2));
7646       Set_First_Rep_Item       (T1, First_Rep_Item        (T2));
7647       Set_Convention           (T1, Convention            (T2));
7648       Set_Is_Limited_Composite (T1, Is_Limited_Composite  (T2));
7649       Set_Is_Private_Composite (T1, Is_Private_Composite  (T2));
7650    end Copy_Array_Subtype_Attributes;
7651
7652    --------------------------
7653    -- Copy_Private_To_Full --
7654    --------------------------
7655
7656    procedure Copy_Private_To_Full (Priv, Full : Entity_Id) is
7657    begin
7658       --  We temporarily set Ekind to a value appropriate for a type to
7659       --  avoid assert failures in Einfo from checking for setting type
7660       --  attributes on something that is not a type. Ekind (Priv) is an
7661       --  appropriate choice, since it allowed the attributes to be set
7662       --  in the first place. This Ekind value will be modified later.
7663
7664       Set_Ekind (Full, Ekind (Priv));
7665
7666       --  Also set Etype temporarily to Any_Type, again, in the absence
7667       --  of errors, it will be properly reset, and if there are errors,
7668       --  then we want a value of Any_Type to remain.
7669
7670       Set_Etype (Full, Any_Type);
7671
7672       --  Now start copying attributes
7673
7674       Set_Has_Discriminants          (Full, Has_Discriminants       (Priv));
7675
7676       if Has_Discriminants (Full) then
7677          Set_Discriminant_Constraint (Full, Discriminant_Constraint (Priv));
7678          Set_Girder_Constraint       (Full, Girder_Constraint       (Priv));
7679       end if;
7680
7681       Set_Homonym                    (Full, Homonym                 (Priv));
7682       Set_Is_Immediately_Visible     (Full, Is_Immediately_Visible  (Priv));
7683       Set_Is_Public                  (Full, Is_Public               (Priv));
7684       Set_Is_Pure                    (Full, Is_Pure                 (Priv));
7685       Set_Is_Tagged_Type             (Full, Is_Tagged_Type          (Priv));
7686
7687       Conditional_Delay              (Full,                          Priv);
7688
7689       if Is_Tagged_Type (Full) then
7690          Set_Primitive_Operations    (Full, Primitive_Operations    (Priv));
7691
7692          if Priv = Base_Type (Priv) then
7693             Set_Class_Wide_Type      (Full, Class_Wide_Type         (Priv));
7694          end if;
7695       end if;
7696
7697       Set_Is_Volatile                (Full, Is_Volatile             (Priv));
7698       Set_Scope                      (Full, Scope                   (Priv));
7699       Set_Next_Entity                (Full, Next_Entity             (Priv));
7700       Set_First_Entity               (Full, First_Entity            (Priv));
7701       Set_Last_Entity                (Full, Last_Entity             (Priv));
7702
7703       --  If access types have been recorded for later handling, keep them
7704       --  in the full view so that they get handled when the full view freeze
7705       --  node is expanded.
7706
7707       if Present (Freeze_Node (Priv))
7708         and then Present (Access_Types_To_Process (Freeze_Node (Priv)))
7709       then
7710          Ensure_Freeze_Node (Full);
7711          Set_Access_Types_To_Process (Freeze_Node (Full),
7712            Access_Types_To_Process (Freeze_Node (Priv)));
7713       end if;
7714    end Copy_Private_To_Full;
7715
7716    -----------------------------------
7717    -- Create_Constrained_Components --
7718    -----------------------------------
7719
7720    procedure Create_Constrained_Components
7721      (Subt        : Entity_Id;
7722       Decl_Node   : Node_Id;
7723       Typ         : Entity_Id;
7724       Constraints : Elist_Id)
7725    is
7726       Loc         : constant Source_Ptr := Sloc (Subt);
7727       Assoc_List  : List_Id  := New_List;
7728       Comp_List   : Elist_Id := New_Elmt_List;
7729       Discr_Val   : Elmt_Id;
7730       Errors      : Boolean;
7731       New_C       : Entity_Id;
7732       Old_C       : Entity_Id;
7733       Is_Static   : Boolean := True;
7734       Parent_Type : constant Entity_Id := Etype (Typ);
7735
7736       procedure Collect_Fixed_Components (Typ : Entity_Id);
7737       --  Collect components of parent type that do not appear in a variant
7738       --  part.
7739
7740       procedure Create_All_Components;
7741       --  Iterate over Comp_List to create the components of the subtype.
7742
7743       function Create_Component (Old_Compon : Entity_Id) return Entity_Id;
7744       --  Creates a new component from Old_Compon, coppying all the fields from
7745       --  it, including its Etype, inserts the new component in the Subt entity
7746       --  chain and returns the new component.
7747
7748       function Is_Variant_Record (T : Entity_Id) return Boolean;
7749       --  If true, and discriminants are static, collect only components from
7750       --  variants selected by discriminant values.
7751
7752       ------------------------------
7753       -- Collect_Fixed_Components --
7754       ------------------------------
7755
7756       procedure Collect_Fixed_Components (Typ : Entity_Id) is
7757       begin
7758       --   Build association list for discriminants, and find components of
7759       --  the variant part selected by the values of the discriminants.
7760
7761          Old_C := First_Discriminant (Typ);
7762          Discr_Val := First_Elmt (Constraints);
7763
7764          while Present (Old_C) loop
7765             Append_To (Assoc_List,
7766               Make_Component_Association (Loc,
7767                  Choices    => New_List (New_Occurrence_Of (Old_C, Loc)),
7768                  Expression => New_Copy (Node (Discr_Val))));
7769
7770             Next_Elmt (Discr_Val);
7771             Next_Discriminant (Old_C);
7772          end loop;
7773
7774          --  The tag, and the possible parent and controller components
7775          --  are unconditionally in the subtype.
7776
7777          if Is_Tagged_Type (Typ)
7778            or else Has_Controlled_Component (Typ)
7779          then
7780             Old_C := First_Component (Typ);
7781
7782             while Present (Old_C) loop
7783                if Chars ((Old_C)) = Name_uTag
7784                  or else Chars ((Old_C)) = Name_uParent
7785                  or else Chars ((Old_C)) = Name_uController
7786                then
7787                   Append_Elmt (Old_C, Comp_List);
7788                end if;
7789
7790                Next_Component (Old_C);
7791             end loop;
7792          end if;
7793       end Collect_Fixed_Components;
7794
7795       ---------------------------
7796       -- Create_All_Components --
7797       ---------------------------
7798
7799       procedure Create_All_Components is
7800          Comp : Elmt_Id;
7801
7802       begin
7803          Comp := First_Elmt (Comp_List);
7804
7805          while Present (Comp) loop
7806             Old_C := Node (Comp);
7807             New_C := Create_Component (Old_C);
7808
7809             Set_Etype
7810               (New_C,
7811                Constrain_Component_Type
7812                  (Etype (Old_C), Subt, Decl_Node, Typ, Constraints));
7813             Set_Is_Public (New_C, Is_Public (Subt));
7814
7815             Next_Elmt (Comp);
7816          end loop;
7817       end Create_All_Components;
7818
7819       ----------------------
7820       -- Create_Component --
7821       ----------------------
7822
7823       function Create_Component (Old_Compon : Entity_Id) return Entity_Id is
7824          New_Compon : Entity_Id := New_Copy (Old_Compon);
7825
7826       begin
7827          --  Set the parent so we have a proper link for freezing etc. This
7828          --  is not a real parent pointer, since of course our parent does
7829          --  not own up to us and reference us, we are an illegitimate
7830          --  child of the original parent!
7831
7832          Set_Parent (New_Compon, Parent (Old_Compon));
7833
7834          --  We do not want this node marked as Comes_From_Source, since
7835          --  otherwise it would get first class status and a separate
7836          --  cross-reference line would be generated. Illegitimate
7837          --  children do not rate such recognition.
7838
7839          Set_Comes_From_Source (New_Compon, False);
7840
7841          --  But it is a real entity, and a birth certificate must be
7842          --  properly registered by entering it into the entity list.
7843
7844          Enter_Name (New_Compon);
7845          return New_Compon;
7846       end Create_Component;
7847
7848       -----------------------
7849       -- Is_Variant_Record --
7850       -----------------------
7851
7852       function Is_Variant_Record (T : Entity_Id) return Boolean is
7853       begin
7854          return Nkind (Parent (T)) = N_Full_Type_Declaration
7855            and then Nkind (Type_Definition (Parent (T))) = N_Record_Definition
7856            and then Present (Component_List (Type_Definition (Parent (T))))
7857            and then Present (
7858              Variant_Part (Component_List (Type_Definition (Parent (T)))));
7859       end Is_Variant_Record;
7860
7861    --  Start of processing for Create_Constrained_Components
7862
7863    begin
7864       pragma Assert (Subt /= Base_Type (Subt));
7865       pragma Assert (Typ = Base_Type (Typ));
7866
7867       Set_First_Entity (Subt, Empty);
7868       Set_Last_Entity  (Subt, Empty);
7869
7870       --  Check whether constraint is fully static, in which case we can
7871       --  optimize the list of components.
7872
7873       Discr_Val := First_Elmt (Constraints);
7874
7875       while Present (Discr_Val) loop
7876
7877          if not Is_OK_Static_Expression (Node (Discr_Val)) then
7878             Is_Static := False;
7879             exit;
7880          end if;
7881
7882          Next_Elmt (Discr_Val);
7883       end loop;
7884
7885       New_Scope (Subt);
7886
7887       --  Inherit the discriminants of the parent type.
7888
7889       Old_C := First_Discriminant (Typ);
7890
7891       while Present (Old_C) loop
7892          New_C := Create_Component (Old_C);
7893          Set_Is_Public (New_C, Is_Public (Subt));
7894          Next_Discriminant (Old_C);
7895       end loop;
7896
7897       if Is_Static
7898         and then Is_Variant_Record (Typ)
7899       then
7900          Collect_Fixed_Components (Typ);
7901
7902          Gather_Components (
7903            Typ,
7904            Component_List (Type_Definition (Parent (Typ))),
7905            Governed_By   => Assoc_List,
7906            Into          => Comp_List,
7907            Report_Errors => Errors);
7908          pragma Assert (not Errors);
7909
7910          Create_All_Components;
7911
7912       --  If the subtype declaration is created for a tagged type derivation
7913       --  with constraints, we retrieve the record definition of the parent
7914       --  type to select the components of the proper variant.
7915
7916       elsif Is_Static
7917         and then Is_Tagged_Type (Typ)
7918         and then Nkind (Parent (Typ)) = N_Full_Type_Declaration
7919         and then
7920           Nkind (Type_Definition (Parent (Typ))) = N_Derived_Type_Definition
7921         and then Is_Variant_Record (Parent_Type)
7922       then
7923          Collect_Fixed_Components (Typ);
7924
7925          Gather_Components (
7926            Typ,
7927            Component_List (Type_Definition (Parent (Parent_Type))),
7928            Governed_By   => Assoc_List,
7929            Into          => Comp_List,
7930            Report_Errors => Errors);
7931          pragma Assert (not Errors);
7932
7933          --  If the tagged derivation has a type extension, collect all the
7934          --  new components therein.
7935
7936          if Present (
7937            Record_Extension_Part (Type_Definition (Parent (Typ))))
7938          then
7939             Old_C := First_Component (Typ);
7940
7941             while Present (Old_C) loop
7942                if Original_Record_Component (Old_C) = Old_C
7943                 and then Chars (Old_C) /= Name_uTag
7944                 and then Chars (Old_C) /= Name_uParent
7945                 and then Chars (Old_C) /= Name_uController
7946                then
7947                   Append_Elmt (Old_C, Comp_List);
7948                end if;
7949
7950                Next_Component (Old_C);
7951             end loop;
7952          end if;
7953
7954          Create_All_Components;
7955
7956       else
7957          --  If the discriminants are not static, or if this is a multi-level
7958          --  type extension, we have to include all the components of the
7959          --  parent type.
7960
7961          Old_C := First_Component (Typ);
7962
7963          while Present (Old_C) loop
7964             New_C := Create_Component (Old_C);
7965
7966             Set_Etype
7967               (New_C,
7968                Constrain_Component_Type
7969                  (Etype (Old_C), Subt, Decl_Node, Typ, Constraints));
7970             Set_Is_Public (New_C, Is_Public (Subt));
7971
7972             Next_Component (Old_C);
7973          end loop;
7974       end if;
7975
7976       End_Scope;
7977    end Create_Constrained_Components;
7978
7979    ------------------------------------------
7980    -- Decimal_Fixed_Point_Type_Declaration --
7981    ------------------------------------------
7982
7983    procedure Decimal_Fixed_Point_Type_Declaration
7984      (T   : Entity_Id;
7985       Def : Node_Id)
7986    is
7987       Loc           : constant Source_Ptr := Sloc (Def);
7988       Digs_Expr     : constant Node_Id    := Digits_Expression (Def);
7989       Delta_Expr    : constant Node_Id    := Delta_Expression (Def);
7990       Implicit_Base : Entity_Id;
7991       Digs_Val      : Uint;
7992       Delta_Val     : Ureal;
7993       Scale_Val     : Uint;
7994       Bound_Val     : Ureal;
7995
7996    --  Start of processing for Decimal_Fixed_Point_Type_Declaration
7997
7998    begin
7999       Check_Restriction (No_Fixed_Point, Def);
8000
8001       --  Create implicit base type
8002
8003       Implicit_Base :=
8004         Create_Itype (E_Decimal_Fixed_Point_Type, Parent (Def), T, 'B');
8005       Set_Etype (Implicit_Base, Implicit_Base);
8006
8007       --  Analyze and process delta expression
8008
8009       Analyze_And_Resolve (Delta_Expr, Universal_Real);
8010
8011       Check_Delta_Expression (Delta_Expr);
8012       Delta_Val := Expr_Value_R (Delta_Expr);
8013
8014       --  Check delta is power of 10, and determine scale value from it
8015
8016       declare
8017          Val : Ureal := Delta_Val;
8018
8019       begin
8020          Scale_Val := Uint_0;
8021
8022          if Val < Ureal_1 then
8023             while Val < Ureal_1 loop
8024                Val := Val * Ureal_10;
8025                Scale_Val := Scale_Val + 1;
8026             end loop;
8027
8028             if Scale_Val > 18 then
8029                Error_Msg_N ("scale exceeds maximum value of 18", Def);
8030                Scale_Val := UI_From_Int (+18);
8031             end if;
8032
8033          else
8034             while Val > Ureal_1 loop
8035                Val := Val / Ureal_10;
8036                Scale_Val := Scale_Val - 1;
8037             end loop;
8038
8039             if Scale_Val < -18 then
8040                Error_Msg_N ("scale is less than minimum value of -18", Def);
8041                Scale_Val := UI_From_Int (-18);
8042             end if;
8043          end if;
8044
8045          if Val /= Ureal_1 then
8046             Error_Msg_N ("delta expression must be a power of 10", Def);
8047             Delta_Val := Ureal_10 ** (-Scale_Val);
8048          end if;
8049       end;
8050
8051       --  Set delta, scale and small (small = delta for decimal type)
8052
8053       Set_Delta_Value (Implicit_Base, Delta_Val);
8054       Set_Scale_Value (Implicit_Base, Scale_Val);
8055       Set_Small_Value (Implicit_Base, Delta_Val);
8056
8057       --  Analyze and process digits expression
8058
8059       Analyze_And_Resolve (Digs_Expr, Any_Integer);
8060       Check_Digits_Expression (Digs_Expr);
8061       Digs_Val := Expr_Value (Digs_Expr);
8062
8063       if Digs_Val > 18 then
8064          Digs_Val := UI_From_Int (+18);
8065          Error_Msg_N ("digits value out of range, maximum is 18", Digs_Expr);
8066       end if;
8067
8068       Set_Digits_Value (Implicit_Base, Digs_Val);
8069       Bound_Val := UR_From_Uint (10 ** Digs_Val - 1) * Delta_Val;
8070
8071       --  Set range of base type from digits value for now. This will be
8072       --  expanded to represent the true underlying base range by Freeze.
8073
8074       Set_Fixed_Range (Implicit_Base, Loc, -Bound_Val, Bound_Val);
8075
8076       --  Set size to zero for now, size will be set at freeze time. We have
8077       --  to do this for ordinary fixed-point, because the size depends on
8078       --  the specified small, and we might as well do the same for decimal
8079       --  fixed-point.
8080
8081       Init_Size_Align (Implicit_Base);
8082
8083       --  Complete entity for first subtype
8084
8085       Set_Ekind          (T, E_Decimal_Fixed_Point_Subtype);
8086       Set_Etype          (T, Implicit_Base);
8087       Set_Size_Info      (T, Implicit_Base);
8088       Set_First_Rep_Item (T, First_Rep_Item (Implicit_Base));
8089       Set_Digits_Value   (T, Digs_Val);
8090       Set_Delta_Value    (T, Delta_Val);
8091       Set_Small_Value    (T, Delta_Val);
8092       Set_Scale_Value    (T, Scale_Val);
8093       Set_Is_Constrained (T);
8094
8095       --  If there are bounds given in the declaration use them as the
8096       --  bounds of the first named subtype.
8097
8098       if Present (Real_Range_Specification (Def)) then
8099          declare
8100             RRS      : constant Node_Id := Real_Range_Specification (Def);
8101             Low      : constant Node_Id := Low_Bound (RRS);
8102             High     : constant Node_Id := High_Bound (RRS);
8103             Low_Val  : Ureal;
8104             High_Val : Ureal;
8105
8106          begin
8107             Analyze_And_Resolve (Low, Any_Real);
8108             Analyze_And_Resolve (High, Any_Real);
8109             Check_Real_Bound (Low);
8110             Check_Real_Bound (High);
8111             Low_Val := Expr_Value_R (Low);
8112             High_Val := Expr_Value_R (High);
8113
8114             if Low_Val < (-Bound_Val) then
8115                Error_Msg_N
8116                  ("range low bound too small for digits value", Low);
8117                Low_Val := -Bound_Val;
8118             end if;
8119
8120             if High_Val > Bound_Val then
8121                Error_Msg_N
8122                  ("range high bound too large for digits value", High);
8123                High_Val := Bound_Val;
8124             end if;
8125
8126             Set_Fixed_Range (T, Loc, Low_Val, High_Val);
8127          end;
8128
8129       --  If no explicit range, use range that corresponds to given
8130       --  digits value. This will end up as the final range for the
8131       --  first subtype.
8132
8133       else
8134          Set_Fixed_Range (T, Loc, -Bound_Val, Bound_Val);
8135       end if;
8136
8137    end Decimal_Fixed_Point_Type_Declaration;
8138
8139    -----------------------
8140    -- Derive_Subprogram --
8141    -----------------------
8142
8143    procedure Derive_Subprogram
8144      (New_Subp     : in out Entity_Id;
8145       Parent_Subp  : Entity_Id;
8146       Derived_Type : Entity_Id;
8147       Parent_Type  : Entity_Id;
8148       Actual_Subp  : Entity_Id := Empty)
8149    is
8150       Formal     : Entity_Id;
8151       New_Formal : Entity_Id;
8152       Same_Subt  : constant Boolean :=
8153         Is_Scalar_Type (Parent_Type)
8154           and then Subtypes_Statically_Compatible (Parent_Type, Derived_Type);
8155
8156       function Is_Private_Overriding return Boolean;
8157       --  If Subp is a private overriding of a visible operation, the in-
8158       --  herited operation derives from the overridden op (even though
8159       --  its body is the overriding one) and the inherited operation is
8160       --  visible now. See sem_disp to see the details of the handling of
8161       --  the overridden subprogram, which is removed from the list of
8162       --  primitive operations of the type.
8163
8164       procedure Replace_Type (Id, New_Id : Entity_Id);
8165       --  When the type is an anonymous access type, create a new access type
8166       --  designating the derived type.
8167
8168       ---------------------------
8169       -- Is_Private_Overriding --
8170       ---------------------------
8171
8172       function Is_Private_Overriding return Boolean is
8173          Prev : Entity_Id;
8174
8175       begin
8176          Prev := Homonym (Parent_Subp);
8177
8178          --  The visible operation that is overriden is a homonym of
8179          --  the parent subprogram. We scan the homonym chain to find
8180          --  the one whose alias is the subprogram we are deriving.
8181
8182          while Present (Prev) loop
8183             if Is_Dispatching_Operation (Parent_Subp)
8184               and then Present (Prev)
8185               and then Ekind (Prev) = Ekind (Parent_Subp)
8186               and then Alias (Prev) = Parent_Subp
8187               and then Scope (Parent_Subp) = Scope (Prev)
8188               and then not Is_Hidden (Prev)
8189             then
8190                return True;
8191             end if;
8192
8193             Prev := Homonym (Prev);
8194          end loop;
8195
8196          return False;
8197       end Is_Private_Overriding;
8198
8199       ------------------
8200       -- Replace_Type --
8201       ------------------
8202
8203       procedure Replace_Type (Id, New_Id : Entity_Id) is
8204          Acc_Type : Entity_Id;
8205          IR       : Node_Id;
8206
8207       begin
8208          --  When the type is an anonymous access type, create a new access
8209          --  type designating the derived type. This itype must be elaborated
8210          --  at the point of the derivation, not on subsequent calls that may
8211          --  be out of the proper scope for Gigi, so we insert a reference to
8212          --  it after the derivation.
8213
8214          if Ekind (Etype (Id)) = E_Anonymous_Access_Type then
8215             declare
8216                Desig_Typ : Entity_Id := Designated_Type (Etype (Id));
8217
8218             begin
8219                if Ekind (Desig_Typ) = E_Record_Type_With_Private
8220                  and then Present (Full_View (Desig_Typ))
8221                  and then not Is_Private_Type (Parent_Type)
8222                then
8223                   Desig_Typ := Full_View (Desig_Typ);
8224                end if;
8225
8226                if Base_Type (Desig_Typ) = Base_Type (Parent_Type) then
8227                   Acc_Type := New_Copy (Etype (Id));
8228                   Set_Etype (Acc_Type, Acc_Type);
8229                   Set_Scope (Acc_Type, New_Subp);
8230
8231                   --  Compute size of anonymous access type.
8232
8233                   if Is_Array_Type (Desig_Typ)
8234                     and then not Is_Constrained (Desig_Typ)
8235                   then
8236                      Init_Size (Acc_Type, 2 * System_Address_Size);
8237                   else
8238                      Init_Size (Acc_Type, System_Address_Size);
8239                   end if;
8240
8241                   Init_Alignment (Acc_Type);
8242
8243                   Set_Directly_Designated_Type (Acc_Type, Derived_Type);
8244
8245                   Set_Etype (New_Id, Acc_Type);
8246                   Set_Scope (New_Id, New_Subp);
8247
8248                   --  Create a reference to it.
8249
8250                   IR := Make_Itype_Reference (Sloc (Parent (Derived_Type)));
8251                   Set_Itype (IR, Acc_Type);
8252                   Insert_After (Parent (Derived_Type), IR);
8253
8254                else
8255                   Set_Etype (New_Id, Etype (Id));
8256                end if;
8257             end;
8258          elsif Base_Type (Etype (Id)) = Base_Type (Parent_Type)
8259            or else
8260              (Ekind (Etype (Id)) = E_Record_Type_With_Private
8261                and then Present (Full_View (Etype (Id)))
8262                and then Base_Type (Full_View (Etype (Id))) =
8263                  Base_Type (Parent_Type))
8264          then
8265
8266             --  Constraint checks on formals are generated during expansion,
8267             --  based on the signature of the original subprogram. The bounds
8268             --  of the derived type are not relevant, and thus we can use
8269             --  the base type for the formals. However, the return type may be
8270             --  used in a context that requires that the proper static bounds
8271             --  be used (a case statement, for example)  and for those cases
8272             --  we must use the derived type (first subtype), not its base.
8273
8274             if Etype (Id) = Parent_Type
8275               and then Same_Subt
8276             then
8277                Set_Etype (New_Id, Derived_Type);
8278             else
8279                Set_Etype (New_Id, Base_Type (Derived_Type));
8280             end if;
8281
8282          else
8283             Set_Etype (New_Id, Etype (Id));
8284          end if;
8285       end Replace_Type;
8286
8287    --  Start of processing for Derive_Subprogram
8288
8289    begin
8290       New_Subp :=
8291          New_Entity (Nkind (Parent_Subp), Sloc (Derived_Type));
8292       Set_Ekind (New_Subp, Ekind (Parent_Subp));
8293
8294       --  Check whether the inherited subprogram is a private operation that
8295       --  should be inherited but not yet made visible. Such subprograms can
8296       --  become visible at a later point (e.g., the private part of a public
8297       --  child unit) via Declare_Inherited_Private_Subprograms. If the
8298       --  following predicate is true, then this is not such a private
8299       --  operation and the subprogram simply inherits the name of the parent
8300       --  subprogram. Note the special check for the names of controlled
8301       --  operations, which are currently exempted from being inherited with
8302       --  a hidden name because they must be findable for generation of
8303       --  implicit run-time calls.
8304
8305       if not Is_Hidden (Parent_Subp)
8306         or else Is_Internal (Parent_Subp)
8307         or else Is_Private_Overriding
8308         or else Is_Internal_Name (Chars (Parent_Subp))
8309         or else Chars (Parent_Subp) = Name_Initialize
8310         or else Chars (Parent_Subp) = Name_Adjust
8311         or else Chars (Parent_Subp) = Name_Finalize
8312       then
8313          Set_Chars (New_Subp, Chars (Parent_Subp));
8314
8315       --  If parent is hidden, this can be a regular derivation if the
8316       --  parent is immediately visible in a non-instantiating context,
8317       --  or if we are in the private part of an instance. This test
8318       --  should still be refined ???
8319
8320       --  The test for In_Instance_Not_Visible avoids inheriting the
8321       --  derived operation as a non-visible operation in cases where
8322       --  the parent subprogram might not be visible now, but was
8323       --  visible within the original generic, so it would be wrong
8324       --  to make the inherited subprogram non-visible now. (Not
8325       --  clear if this test is fully correct; are there any cases
8326       --  where we should declare the inherited operation as not
8327       --  visible to avoid it being overridden, e.g., when the
8328       --  parent type is a generic actual with private primitives ???)
8329
8330       --  (they should be treated the same as other private inherited
8331       --  subprograms, but it's not clear how to do this cleanly). ???
8332
8333       elsif (In_Open_Scopes (Scope (Base_Type (Parent_Type)))
8334               and then Is_Immediately_Visible (Parent_Subp)
8335               and then not In_Instance)
8336         or else In_Instance_Not_Visible
8337       then
8338          Set_Chars (New_Subp, Chars (Parent_Subp));
8339
8340       --  The type is inheriting a private operation, so enter
8341       --  it with a special name so it can't be overridden.
8342
8343       else
8344          Set_Chars (New_Subp, New_External_Name (Chars (Parent_Subp), 'P'));
8345       end if;
8346
8347       Set_Parent (New_Subp, Parent (Derived_Type));
8348       Replace_Type (Parent_Subp, New_Subp);
8349       Conditional_Delay (New_Subp, Parent_Subp);
8350
8351       Formal := First_Formal (Parent_Subp);
8352       while Present (Formal) loop
8353          New_Formal := New_Copy (Formal);
8354
8355          --  Normally we do not go copying parents, but in the case of
8356          --  formals, we need to link up to the declaration (which is
8357          --  the parameter specification), and it is fine to link up to
8358          --  the original formal's parameter specification in this case.
8359
8360          Set_Parent (New_Formal, Parent (Formal));
8361
8362          Append_Entity (New_Formal, New_Subp);
8363
8364          Replace_Type (Formal, New_Formal);
8365          Next_Formal (Formal);
8366       end loop;
8367
8368       --  If this derivation corresponds to a tagged generic actual, then
8369       --  primitive operations rename those of the actual. Otherwise the
8370       --  primitive operations rename those of the parent type.
8371
8372       if No (Actual_Subp) then
8373          Set_Alias (New_Subp, Parent_Subp);
8374          Set_Is_Intrinsic_Subprogram (New_Subp,
8375            Is_Intrinsic_Subprogram (Parent_Subp));
8376
8377       else
8378          Set_Alias (New_Subp, Actual_Subp);
8379       end if;
8380
8381       --  Derived subprograms of a tagged type must inherit the convention
8382       --  of the parent subprogram (a requirement of AI-117). Derived
8383       --  subprograms of untagged types simply get convention Ada by default.
8384
8385       if Is_Tagged_Type (Derived_Type) then
8386          Set_Convention  (New_Subp, Convention  (Parent_Subp));
8387       end if;
8388
8389       Set_Is_Imported (New_Subp, Is_Imported (Parent_Subp));
8390       Set_Is_Exported (New_Subp, Is_Exported (Parent_Subp));
8391
8392       if Ekind (Parent_Subp) = E_Procedure then
8393          Set_Is_Valued_Procedure
8394            (New_Subp, Is_Valued_Procedure (Parent_Subp));
8395       end if;
8396
8397       New_Overloaded_Entity (New_Subp, Derived_Type);
8398
8399       --  Check for case of a derived subprogram for the instantiation
8400       --  of a formal derived tagged type, so mark the subprogram as
8401       --  dispatching and inherit the dispatching attributes of the
8402       --  parent subprogram. The derived subprogram is effectively a
8403       --  renaming of the actual subprogram, so it needs to have the
8404       --  same attributes as the actual.
8405
8406       if Present (Actual_Subp)
8407         and then Is_Dispatching_Operation (Parent_Subp)
8408       then
8409          Set_Is_Dispatching_Operation (New_Subp);
8410          if Present (DTC_Entity (Parent_Subp)) then
8411             Set_DTC_Entity (New_Subp, DTC_Entity (Parent_Subp));
8412             Set_DT_Position (New_Subp, DT_Position (Parent_Subp));
8413          end if;
8414       end if;
8415
8416       --  Indicate that a derived subprogram does not require a body
8417       --  and that it does not require processing of default expressions.
8418
8419       Set_Has_Completion (New_Subp);
8420       Set_Default_Expressions_Processed (New_Subp);
8421
8422       --  A derived function with a controlling result is abstract.
8423       --  If the Derived_Type is a nonabstract formal generic derived
8424       --  type, then inherited operations are not abstract: check is
8425       --  done at instantiation time. If the derivation is for a generic
8426       --  actual, the function is not abstract unless the actual is.
8427
8428       if Is_Generic_Type (Derived_Type)
8429         and then not Is_Abstract (Derived_Type)
8430       then
8431          null;
8432
8433       elsif Is_Abstract (Alias (New_Subp))
8434         or else (Is_Tagged_Type (Derived_Type)
8435                    and then Etype (New_Subp) = Derived_Type
8436                    and then No (Actual_Subp))
8437       then
8438          Set_Is_Abstract (New_Subp);
8439       end if;
8440
8441       if Ekind (New_Subp) = E_Function then
8442          Set_Mechanism (New_Subp, Mechanism (Parent_Subp));
8443       end if;
8444    end Derive_Subprogram;
8445
8446    ------------------------
8447    -- Derive_Subprograms --
8448    ------------------------
8449
8450    procedure Derive_Subprograms
8451      (Parent_Type    : Entity_Id;
8452       Derived_Type   : Entity_Id;
8453       Generic_Actual : Entity_Id := Empty)
8454    is
8455       Op_List     : Elist_Id := Collect_Primitive_Operations (Parent_Type);
8456       Act_List    : Elist_Id;
8457       Act_Elmt    : Elmt_Id;
8458       Elmt        : Elmt_Id;
8459       Subp        : Entity_Id;
8460       New_Subp    : Entity_Id := Empty;
8461       Parent_Base : Entity_Id;
8462
8463    begin
8464       if Ekind (Parent_Type) = E_Record_Type_With_Private
8465         and then Has_Discriminants (Parent_Type)
8466         and then Present (Full_View (Parent_Type))
8467       then
8468          Parent_Base := Full_View (Parent_Type);
8469       else
8470          Parent_Base := Parent_Type;
8471       end if;
8472
8473       Elmt := First_Elmt (Op_List);
8474
8475       if Present (Generic_Actual) then
8476          Act_List := Collect_Primitive_Operations (Generic_Actual);
8477          Act_Elmt := First_Elmt (Act_List);
8478       else
8479          Act_Elmt := No_Elmt;
8480       end if;
8481
8482       --  Literals are derived earlier in the process of building the
8483       --  derived type, and are skipped here.
8484
8485       while Present (Elmt) loop
8486          Subp := Node (Elmt);
8487
8488          if Ekind (Subp) /= E_Enumeration_Literal then
8489             if No (Generic_Actual) then
8490                Derive_Subprogram
8491                  (New_Subp, Subp, Derived_Type, Parent_Base);
8492
8493             else
8494                Derive_Subprogram (New_Subp, Subp,
8495                  Derived_Type, Parent_Base, Node (Act_Elmt));
8496                Next_Elmt (Act_Elmt);
8497             end if;
8498          end if;
8499
8500          Next_Elmt (Elmt);
8501       end loop;
8502    end Derive_Subprograms;
8503
8504    --------------------------------
8505    -- Derived_Standard_Character --
8506    --------------------------------
8507
8508    procedure Derived_Standard_Character
8509      (N             : Node_Id;
8510       Parent_Type   : Entity_Id;
8511       Derived_Type  : Entity_Id)
8512    is
8513       Loc           : constant Source_Ptr := Sloc (N);
8514       Def           : constant Node_Id    := Type_Definition (N);
8515       Indic         : constant Node_Id    := Subtype_Indication (Def);
8516       Parent_Base   : constant Entity_Id  := Base_Type (Parent_Type);
8517       Implicit_Base : constant Entity_Id  :=
8518                         Create_Itype
8519                           (E_Enumeration_Type, N, Derived_Type, 'B');
8520
8521       Lo : Node_Id;
8522       Hi : Node_Id;
8523       T  : Entity_Id;
8524
8525    begin
8526       T := Process_Subtype (Indic, N);
8527
8528       Set_Etype     (Implicit_Base, Parent_Base);
8529       Set_Size_Info (Implicit_Base, Root_Type (Parent_Type));
8530       Set_RM_Size   (Implicit_Base, RM_Size (Root_Type (Parent_Type)));
8531
8532       Set_Is_Character_Type  (Implicit_Base, True);
8533       Set_Has_Delayed_Freeze (Implicit_Base);
8534
8535       Lo := New_Copy_Tree (Type_Low_Bound  (Parent_Type));
8536       Hi := New_Copy_Tree (Type_High_Bound (Parent_Type));
8537
8538       Set_Scalar_Range (Implicit_Base,
8539         Make_Range (Loc,
8540           Low_Bound  => Lo,
8541           High_Bound => Hi));
8542
8543       Conditional_Delay (Derived_Type, Parent_Type);
8544
8545       Set_Ekind (Derived_Type, E_Enumeration_Subtype);
8546       Set_Etype (Derived_Type, Implicit_Base);
8547       Set_Size_Info         (Derived_Type, Parent_Type);
8548
8549       if Unknown_RM_Size (Derived_Type) then
8550          Set_RM_Size (Derived_Type, RM_Size (Parent_Type));
8551       end if;
8552
8553       Set_Is_Character_Type (Derived_Type, True);
8554
8555       if Nkind (Indic) /= N_Subtype_Indication then
8556          Set_Scalar_Range (Derived_Type, Scalar_Range (Implicit_Base));
8557       end if;
8558
8559       Convert_Scalar_Bounds (N, Parent_Type, Derived_Type, Loc);
8560
8561       --  Because the implicit base is used in the conversion of the bounds,
8562       --  we have to freeze it now. This is similar to what is done for
8563       --  numeric types, and it equally suspicious, but otherwise a non-
8564       --  static bound will have a reference to an unfrozen type, which is
8565       --  rejected by Gigi (???).
8566
8567       Freeze_Before (N, Implicit_Base);
8568
8569    end Derived_Standard_Character;
8570
8571    ------------------------------
8572    -- Derived_Type_Declaration --
8573    ------------------------------
8574
8575    procedure Derived_Type_Declaration
8576      (T             : Entity_Id;
8577       N             : Node_Id;
8578       Is_Completion : Boolean)
8579    is
8580       Def          : constant Node_Id := Type_Definition (N);
8581       Indic        : constant Node_Id := Subtype_Indication (Def);
8582       Extension    : constant Node_Id := Record_Extension_Part (Def);
8583       Parent_Type  : Entity_Id;
8584       Parent_Scope : Entity_Id;
8585       Taggd        : Boolean;
8586
8587    begin
8588       Parent_Type := Find_Type_Of_Subtype_Indic (Indic);
8589
8590       if Parent_Type = Any_Type
8591         or else Etype (Parent_Type) = Any_Type
8592         or else (Is_Class_Wide_Type (Parent_Type)
8593                   and then Etype (Parent_Type) = T)
8594       then
8595          --  If Parent_Type is undefined or illegal, make new type into
8596          --  a subtype of Any_Type, and set a few attributes to prevent
8597          --  cascaded errors. If this is a self-definition, emit error now.
8598
8599          if T = Parent_Type
8600            or else T = Etype (Parent_Type)
8601          then
8602             Error_Msg_N ("type cannot be used in its own definition", Indic);
8603          end if;
8604
8605          Set_Ekind        (T, Ekind (Parent_Type));
8606          Set_Etype        (T, Any_Type);
8607          Set_Scalar_Range (T, Scalar_Range (Any_Type));
8608
8609          if Is_Tagged_Type (T) then
8610             Set_Primitive_Operations (T, New_Elmt_List);
8611          end if;
8612          return;
8613
8614       elsif Is_Unchecked_Union (Parent_Type) then
8615          Error_Msg_N ("cannot derive from Unchecked_Union type", N);
8616       end if;
8617
8618       --  Only composite types other than array types are allowed to have
8619       --  discriminants.
8620
8621       if Present (Discriminant_Specifications (N))
8622         and then (Is_Elementary_Type (Parent_Type)
8623                   or else Is_Array_Type (Parent_Type))
8624         and then not Error_Posted (N)
8625       then
8626          Error_Msg_N
8627            ("elementary or array type cannot have discriminants",
8628             Defining_Identifier (First (Discriminant_Specifications (N))));
8629          Set_Has_Discriminants (T, False);
8630       end if;
8631
8632       --  In Ada 83, a derived type defined in a package specification cannot
8633       --  be used for further derivation until the end of its visible part.
8634       --  Note that derivation in the private part of the package is allowed.
8635
8636       if Ada_83
8637         and then Is_Derived_Type (Parent_Type)
8638         and then In_Visible_Part (Scope (Parent_Type))
8639       then
8640          if Ada_83 and then Comes_From_Source (Indic) then
8641             Error_Msg_N
8642               ("(Ada 83): premature use of type for derivation", Indic);
8643          end if;
8644       end if;
8645
8646       --  Check for early use of incomplete or private type
8647
8648       if Ekind (Parent_Type) = E_Void
8649         or else Ekind (Parent_Type) = E_Incomplete_Type
8650       then
8651          Error_Msg_N ("premature derivation of incomplete type", Indic);
8652          return;
8653
8654       elsif (Is_Incomplete_Or_Private_Type (Parent_Type)
8655               and then not Is_Generic_Type (Parent_Type)
8656               and then not Is_Generic_Type (Root_Type (Parent_Type))
8657               and then not Is_Generic_Actual_Type (Parent_Type))
8658         or else Has_Private_Component (Parent_Type)
8659       then
8660          --  The ancestor type of a formal type can be incomplete, in which
8661          --  case only the operations of the partial view are available in
8662          --  the generic. Subsequent checks may be required when the full
8663          --  view is analyzed, to verify that derivation from a tagged type
8664          --  has an extension.
8665
8666          if Nkind (Original_Node (N)) = N_Formal_Type_Declaration then
8667             null;
8668
8669          elsif No (Underlying_Type (Parent_Type))
8670            or else Has_Private_Component (Parent_Type)
8671          then
8672             Error_Msg_N
8673               ("premature derivation of derived or private type", Indic);
8674
8675             --  Flag the type itself as being in error, this prevents some
8676             --  nasty problems with people looking at the malformed type.
8677
8678             Set_Error_Posted (T);
8679
8680          --  Check that within the immediate scope of an untagged partial
8681          --  view it's illegal to derive from the partial view if the
8682          --  full view is tagged. (7.3(7))
8683
8684          --  We verify that the Parent_Type is a partial view by checking
8685          --  that it is not a Full_Type_Declaration (i.e. a private type or
8686          --  private extension declaration), to distinguish a partial view
8687          --  from  a derivation from a private type which also appears as
8688          --  E_Private_Type.
8689
8690          elsif Present (Full_View (Parent_Type))
8691            and then Nkind (Parent (Parent_Type)) /= N_Full_Type_Declaration
8692            and then not Is_Tagged_Type (Parent_Type)
8693            and then Is_Tagged_Type (Full_View (Parent_Type))
8694          then
8695             Parent_Scope := Scope (T);
8696             while Present (Parent_Scope)
8697               and then Parent_Scope /= Standard_Standard
8698             loop
8699                if Parent_Scope = Scope (Parent_Type) then
8700                   Error_Msg_N
8701                     ("premature derivation from type with tagged full view",
8702                      Indic);
8703                end if;
8704
8705                Parent_Scope := Scope (Parent_Scope);
8706             end loop;
8707          end if;
8708       end if;
8709
8710       --  Check that form of derivation is appropriate
8711
8712       Taggd := Is_Tagged_Type (Parent_Type);
8713
8714       --  Perhaps the parent type should be changed to the class-wide type's
8715       --  specific type in this case to prevent cascading errors ???
8716
8717       if Present (Extension) and then Is_Class_Wide_Type (Parent_Type) then
8718          Error_Msg_N ("parent type must not be a class-wide type", Indic);
8719          return;
8720       end if;
8721
8722       if Present (Extension) and then not Taggd then
8723          Error_Msg_N
8724            ("type derived from untagged type cannot have extension", Indic);
8725
8726       elsif No (Extension) and then Taggd then
8727          --  If this is within a private part (or body) of a generic
8728          --  instantiation then the derivation is allowed (the parent
8729          --  type can only appear tagged in this case if it's a generic
8730          --  actual type, since it would otherwise have been rejected
8731          --  in the analysis of the generic template).
8732
8733          if not Is_Generic_Actual_Type (Parent_Type)
8734            or else In_Visible_Part (Scope (Parent_Type))
8735          then
8736             Error_Msg_N
8737               ("type derived from tagged type must have extension", Indic);
8738          end if;
8739       end if;
8740
8741       Build_Derived_Type (N, Parent_Type, T, Is_Completion);
8742    end Derived_Type_Declaration;
8743
8744    ----------------------------------
8745    -- Enumeration_Type_Declaration --
8746    ----------------------------------
8747
8748    procedure Enumeration_Type_Declaration (T : Entity_Id; Def : Node_Id) is
8749       Ev     : Uint;
8750       L      : Node_Id;
8751       R_Node : Node_Id;
8752       B_Node : Node_Id;
8753
8754    begin
8755       --  Create identifier node representing lower bound
8756
8757       B_Node := New_Node (N_Identifier, Sloc (Def));
8758       L := First (Literals (Def));
8759       Set_Chars (B_Node, Chars (L));
8760       Set_Entity (B_Node,  L);
8761       Set_Etype (B_Node, T);
8762       Set_Is_Static_Expression (B_Node, True);
8763
8764       R_Node := New_Node (N_Range, Sloc (Def));
8765       Set_Low_Bound  (R_Node, B_Node);
8766
8767       Set_Ekind (T, E_Enumeration_Type);
8768       Set_First_Literal (T, L);
8769       Set_Etype (T, T);
8770       Set_Is_Constrained (T);
8771
8772       Ev := Uint_0;
8773
8774       --  Loop through literals of enumeration type setting pos and rep values
8775       --  except that if the Ekind is already set, then it means that the
8776       --  literal was already constructed (case of a derived type declaration
8777       --  and we should not disturb the Pos and Rep values.
8778
8779       while Present (L) loop
8780          if Ekind (L) /= E_Enumeration_Literal then
8781             Set_Ekind (L, E_Enumeration_Literal);
8782             Set_Enumeration_Pos (L, Ev);
8783             Set_Enumeration_Rep (L, Ev);
8784             Set_Is_Known_Valid  (L, True);
8785          end if;
8786
8787          Set_Etype (L, T);
8788          New_Overloaded_Entity (L);
8789          Generate_Definition (L);
8790          Set_Convention (L, Convention_Intrinsic);
8791
8792          if Nkind (L) = N_Defining_Character_Literal then
8793             Set_Is_Character_Type (T, True);
8794          end if;
8795
8796          Ev := Ev + 1;
8797          Next (L);
8798       end loop;
8799
8800       --  Now create a node representing upper bound
8801
8802       B_Node := New_Node (N_Identifier, Sloc (Def));
8803       Set_Chars (B_Node, Chars (Last (Literals (Def))));
8804       Set_Entity (B_Node,  Last (Literals (Def)));
8805       Set_Etype (B_Node, T);
8806       Set_Is_Static_Expression (B_Node, True);
8807
8808       Set_High_Bound (R_Node, B_Node);
8809       Set_Scalar_Range (T, R_Node);
8810       Set_RM_Size (T, UI_From_Int (Minimum_Size (T)));
8811       Set_Enum_Esize (T);
8812
8813       --  Set Discard_Names if configuration pragma setg, or if there is
8814       --  a parameterless pragma in the current declarative region
8815
8816       if Global_Discard_Names
8817         or else Discard_Names (Scope (T))
8818       then
8819          Set_Discard_Names (T);
8820       end if;
8821    end Enumeration_Type_Declaration;
8822
8823    --------------------------
8824    -- Expand_Others_Choice --
8825    --------------------------
8826
8827    procedure Expand_Others_Choice
8828      (Case_Table    : Choice_Table_Type;
8829       Others_Choice : Node_Id;
8830       Choice_Type   : Entity_Id)
8831    is
8832       Choice      : Node_Id;
8833       Choice_List : List_Id := New_List;
8834       Exp_Lo      : Node_Id;
8835       Exp_Hi      : Node_Id;
8836       Hi          : Uint;
8837       Lo          : Uint;
8838       Loc         : Source_Ptr := Sloc (Others_Choice);
8839       Previous_Hi : Uint;
8840
8841       function Build_Choice (Value1, Value2 : Uint) return Node_Id;
8842       --  Builds a node representing the missing choices given by the
8843       --  Value1 and Value2. A N_Range node is built if there is more than
8844       --  one literal value missing. Otherwise a single N_Integer_Literal,
8845       --  N_Identifier or N_Character_Literal is built depending on what
8846       --  Choice_Type is.
8847
8848       function Lit_Of (Value : Uint) return Node_Id;
8849       --  Returns the Node_Id for the enumeration literal corresponding to the
8850       --  position given by Value within the enumeration type Choice_Type.
8851
8852       ------------------
8853       -- Build_Choice --
8854       ------------------
8855
8856       function Build_Choice (Value1, Value2 : Uint) return Node_Id is
8857          Lit_Node : Node_Id;
8858          Lo, Hi   : Node_Id;
8859
8860       begin
8861          --  If there is only one choice value missing between Value1 and
8862          --  Value2, build an integer or enumeration literal to represent it.
8863
8864          if (Value2 - Value1) = 0 then
8865             if Is_Integer_Type (Choice_Type) then
8866                Lit_Node := Make_Integer_Literal (Loc, Value1);
8867                Set_Etype (Lit_Node, Choice_Type);
8868             else
8869                Lit_Node := Lit_Of (Value1);
8870             end if;
8871
8872          --  Otherwise is more that one choice value that is missing between
8873          --  Value1 and Value2, therefore build a N_Range node of either
8874          --  integer or enumeration literals.
8875
8876          else
8877             if Is_Integer_Type (Choice_Type) then
8878                Lo := Make_Integer_Literal (Loc, Value1);
8879                Set_Etype (Lo, Choice_Type);
8880                Hi := Make_Integer_Literal (Loc, Value2);
8881                Set_Etype (Hi, Choice_Type);
8882                Lit_Node :=
8883                  Make_Range (Loc,
8884                    Low_Bound  => Lo,
8885                    High_Bound => Hi);
8886
8887             else
8888                Lit_Node :=
8889                  Make_Range (Loc,
8890                    Low_Bound  => Lit_Of (Value1),
8891                    High_Bound => Lit_Of (Value2));
8892             end if;
8893          end if;
8894
8895          return Lit_Node;
8896       end Build_Choice;
8897
8898       ------------
8899       -- Lit_Of --
8900       ------------
8901
8902       function Lit_Of (Value : Uint) return Node_Id is
8903          Lit : Entity_Id;
8904
8905       begin
8906          --  In the case where the literal is of type Character, there needs
8907          --  to be some special handling since there is no explicit chain
8908          --  of literals to search. Instead, a N_Character_Literal node
8909          --  is created with the appropriate Char_Code and Chars fields.
8910
8911          if Root_Type (Choice_Type) = Standard_Character then
8912             Set_Character_Literal_Name (Char_Code (UI_To_Int (Value)));
8913             Lit := New_Node (N_Character_Literal, Loc);
8914             Set_Chars (Lit, Name_Find);
8915             Set_Char_Literal_Value (Lit, Char_Code (UI_To_Int (Value)));
8916             Set_Etype (Lit, Choice_Type);
8917             Set_Is_Static_Expression (Lit, True);
8918             return Lit;
8919
8920          --  Otherwise, iterate through the literals list of Choice_Type
8921          --  "Value" number of times until the desired literal is reached
8922          --  and then return an occurrence of it.
8923
8924          else
8925             Lit := First_Literal (Choice_Type);
8926             for J in 1 .. UI_To_Int (Value) loop
8927                Next_Literal (Lit);
8928             end loop;
8929
8930             return New_Occurrence_Of (Lit, Loc);
8931          end if;
8932       end Lit_Of;
8933
8934    --  Start of processing for Expand_Others_Choice
8935
8936    begin
8937       if Case_Table'Length = 0 then
8938
8939          --  Pathological case: only an others case is present.
8940          --  The others case covers the full range of the type.
8941
8942          if Is_Static_Subtype (Choice_Type) then
8943             Choice := New_Occurrence_Of (Choice_Type, Loc);
8944          else
8945             Choice := New_Occurrence_Of (Base_Type (Choice_Type), Loc);
8946          end if;
8947
8948          Set_Others_Discrete_Choices (Others_Choice, New_List (Choice));
8949          return;
8950       end if;
8951
8952       --  Establish the bound values for the variant depending upon whether
8953       --  the type of the discriminant name is static or not.
8954
8955       if Is_OK_Static_Subtype (Choice_Type) then
8956          Exp_Lo := Type_Low_Bound (Choice_Type);
8957          Exp_Hi := Type_High_Bound (Choice_Type);
8958       else
8959          Exp_Lo := Type_Low_Bound (Base_Type (Choice_Type));
8960          Exp_Hi := Type_High_Bound (Base_Type (Choice_Type));
8961       end if;
8962
8963       Lo := Expr_Value (Case_Table (Case_Table'First).Lo);
8964       Hi := Expr_Value (Case_Table (Case_Table'First).Hi);
8965       Previous_Hi := Expr_Value (Case_Table (Case_Table'First).Hi);
8966
8967       --  Build the node for any missing choices that are smaller than any
8968       --  explicit choices given in the variant.
8969
8970       if Expr_Value (Exp_Lo) < Lo then
8971          Append (Build_Choice (Expr_Value (Exp_Lo), Lo - 1), Choice_List);
8972       end if;
8973
8974       --  Build the nodes representing any missing choices that lie between
8975       --  the explicit ones given in the variant.
8976
8977       for J in Case_Table'First + 1 .. Case_Table'Last loop
8978          Lo := Expr_Value (Case_Table (J).Lo);
8979          Hi := Expr_Value (Case_Table (J).Hi);
8980
8981          if Lo /= (Previous_Hi + 1) then
8982             Append_To (Choice_List, Build_Choice (Previous_Hi + 1, Lo - 1));
8983          end if;
8984
8985          Previous_Hi := Hi;
8986       end loop;
8987
8988       --  Build the node for any missing choices that are greater than any
8989       --  explicit choices given in the variant.
8990
8991       if Expr_Value (Exp_Hi) > Hi then
8992          Append (Build_Choice (Hi + 1, Expr_Value (Exp_Hi)), Choice_List);
8993       end if;
8994
8995       Set_Others_Discrete_Choices (Others_Choice, Choice_List);
8996    end Expand_Others_Choice;
8997
8998    ---------------------------------
8999    -- Expand_To_Girder_Constraint --
9000    ---------------------------------
9001
9002    function Expand_To_Girder_Constraint
9003      (Typ        : Entity_Id;
9004       Constraint : Elist_Id)
9005       return       Elist_Id
9006    is
9007       Explicitly_Discriminated_Type : Entity_Id;
9008       Expansion    : Elist_Id;
9009       Discriminant : Entity_Id;
9010
9011       function Type_With_Explicit_Discrims (Id : Entity_Id) return Entity_Id;
9012       --  Find the nearest type that actually specifies discriminants.
9013
9014       ---------------------------------
9015       -- Type_With_Explicit_Discrims --
9016       ---------------------------------
9017
9018       function Type_With_Explicit_Discrims (Id : Entity_Id) return Entity_Id is
9019          Typ : constant E := Base_Type (Id);
9020
9021       begin
9022          if Ekind (Typ) in Incomplete_Or_Private_Kind then
9023             if Present (Full_View (Typ)) then
9024                return Type_With_Explicit_Discrims (Full_View (Typ));
9025             end if;
9026
9027          else
9028             if Has_Discriminants (Typ) then
9029                return Typ;
9030             end if;
9031          end if;
9032
9033          if Etype (Typ) = Typ then
9034             return Empty;
9035          elsif Has_Discriminants (Typ) then
9036             return Typ;
9037          else
9038             return Type_With_Explicit_Discrims (Etype (Typ));
9039          end if;
9040
9041       end Type_With_Explicit_Discrims;
9042
9043    --  Start of processing for Expand_To_Girder_Constraint
9044
9045    begin
9046       if No (Constraint)
9047         or else Is_Empty_Elmt_List (Constraint)
9048       then
9049          return No_Elist;
9050       end if;
9051
9052       Explicitly_Discriminated_Type := Type_With_Explicit_Discrims (Typ);
9053
9054       if No (Explicitly_Discriminated_Type) then
9055          return No_Elist;
9056       end if;
9057
9058       Expansion := New_Elmt_List;
9059
9060       Discriminant :=
9061          First_Girder_Discriminant (Explicitly_Discriminated_Type);
9062
9063       while Present (Discriminant) loop
9064
9065          Append_Elmt (
9066            Get_Discriminant_Value (
9067              Discriminant, Explicitly_Discriminated_Type, Constraint),
9068            Expansion);
9069
9070          Next_Girder_Discriminant (Discriminant);
9071       end loop;
9072
9073       return Expansion;
9074    end Expand_To_Girder_Constraint;
9075
9076    --------------------
9077    -- Find_Type_Name --
9078    --------------------
9079
9080    function Find_Type_Name (N : Node_Id) return Entity_Id is
9081       Id       : constant Entity_Id := Defining_Identifier (N);
9082       Prev     : Entity_Id;
9083       New_Id   : Entity_Id;
9084       Prev_Par : Node_Id;
9085
9086    begin
9087       --  Find incomplete declaration, if some was given.
9088
9089       Prev := Current_Entity_In_Scope (Id);
9090
9091       if Present (Prev) then
9092
9093          --  Previous declaration exists. Error if not incomplete/private case
9094          --  except if previous declaration is implicit, etc. Enter_Name will
9095          --  emit error if appropriate.
9096
9097          Prev_Par := Parent (Prev);
9098
9099          if not Is_Incomplete_Or_Private_Type (Prev) then
9100             Enter_Name (Id);
9101             New_Id := Id;
9102
9103          elsif Nkind (N) /= N_Full_Type_Declaration
9104            and then Nkind (N) /= N_Task_Type_Declaration
9105            and then Nkind (N) /= N_Protected_Type_Declaration
9106          then
9107             --  Completion must be a full type declarations (RM 7.3(4))
9108
9109             Error_Msg_Sloc := Sloc (Prev);
9110             Error_Msg_NE ("invalid completion of }", Id, Prev);
9111
9112             --  Set scope of Id to avoid cascaded errors. Entity is never
9113             --  examined again, except when saving globals in generics.
9114
9115             Set_Scope (Id, Current_Scope);
9116             New_Id := Id;
9117
9118          --  Case of full declaration of incomplete type
9119
9120          elsif Ekind (Prev) = E_Incomplete_Type then
9121
9122             --  Indicate that the incomplete declaration has a matching
9123             --  full declaration. The defining occurrence of the incomplete
9124             --  declaration remains the visible one, and the procedure
9125             --  Get_Full_View dereferences it whenever the type is used.
9126
9127             if Present (Full_View (Prev)) then
9128                Error_Msg_NE ("invalid redeclaration of }", Id, Prev);
9129             end if;
9130
9131             Set_Full_View (Prev,  Id);
9132             Append_Entity (Id, Current_Scope);
9133             Set_Is_Public (Id, Is_Public (Prev));
9134             Set_Is_Internal (Id);
9135             New_Id := Prev;
9136
9137          --  Case of full declaration of private type
9138
9139          else
9140             if Nkind (Parent (Prev)) /= N_Private_Extension_Declaration then
9141                if Etype (Prev) /= Prev then
9142
9143                   --  Prev is a private subtype or a derived type, and needs
9144                   --  no completion.
9145
9146                   Error_Msg_NE ("invalid redeclaration of }", Id, Prev);
9147                   New_Id := Id;
9148
9149                elsif Ekind (Prev) = E_Private_Type
9150                  and then
9151                    (Nkind (N) = N_Task_Type_Declaration
9152                      or else Nkind (N) = N_Protected_Type_Declaration)
9153                then
9154                   Error_Msg_N
9155                    ("completion of nonlimited type cannot be limited", N);
9156                end if;
9157
9158             elsif Nkind (N) /= N_Full_Type_Declaration
9159               or else Nkind (Type_Definition (N)) /= N_Derived_Type_Definition
9160             then
9161                Error_Msg_N ("full view of private extension must be"
9162                  & " an extension", N);
9163
9164             elsif not (Abstract_Present (Parent (Prev)))
9165               and then Abstract_Present (Type_Definition (N))
9166             then
9167                Error_Msg_N ("full view of non-abstract extension cannot"
9168                  & " be abstract", N);
9169             end if;
9170
9171             if not In_Private_Part (Current_Scope) then
9172                Error_Msg_N
9173                  ("declaration of full view must appear in private part",  N);
9174             end if;
9175
9176             Copy_And_Swap (Prev, Id);
9177             Set_Full_View (Id, Prev);
9178             Set_Has_Private_Declaration (Prev);
9179             Set_Has_Private_Declaration (Id);
9180             New_Id := Prev;
9181          end if;
9182
9183          --  Verify that full declaration conforms to incomplete one
9184
9185          if Is_Incomplete_Or_Private_Type (Prev)
9186            and then Present (Discriminant_Specifications (Prev_Par))
9187          then
9188             if Present (Discriminant_Specifications (N)) then
9189                if Ekind (Prev) = E_Incomplete_Type then
9190                   Check_Discriminant_Conformance (N, Prev, Prev);
9191                else
9192                   Check_Discriminant_Conformance (N, Prev, Id);
9193                end if;
9194
9195             else
9196                Error_Msg_N
9197                  ("missing discriminants in full type declaration", N);
9198
9199                --  To avoid cascaded errors on subsequent use, share the
9200                --  discriminants of the partial view.
9201
9202                Set_Discriminant_Specifications (N,
9203                  Discriminant_Specifications (Prev_Par));
9204             end if;
9205          end if;
9206
9207          --  A prior untagged private type can have an associated
9208          --  class-wide type due to use of the class attribute,
9209          --  and in this case also the full type is required to
9210          --  be tagged.
9211
9212          if Is_Type (Prev)
9213            and then (Is_Tagged_Type (Prev)
9214                       or else Present (Class_Wide_Type (Prev)))
9215          then
9216             --  The full declaration is either a tagged record or an
9217             --  extension otherwise this is an error
9218
9219             if Nkind (Type_Definition (N)) = N_Record_Definition then
9220                if not Tagged_Present (Type_Definition (N)) then
9221                   Error_Msg_NE
9222                     ("full declaration of } must be tagged", Prev, Id);
9223                   Set_Is_Tagged_Type (Id);
9224                   Set_Primitive_Operations (Id, New_Elmt_List);
9225                end if;
9226
9227             elsif Nkind (Type_Definition (N)) = N_Derived_Type_Definition then
9228                if No (Record_Extension_Part (Type_Definition (N))) then
9229                   Error_Msg_NE (
9230                     "full declaration of } must be a record extension",
9231                     Prev, Id);
9232                   Set_Is_Tagged_Type (Id);
9233                   Set_Primitive_Operations (Id, New_Elmt_List);
9234                end if;
9235
9236             else
9237                Error_Msg_NE
9238                  ("full declaration of } must be a tagged type", Prev, Id);
9239
9240             end if;
9241          end if;
9242
9243          return New_Id;
9244
9245       else
9246          --  New type declaration
9247
9248          Enter_Name (Id);
9249          return Id;
9250       end if;
9251    end Find_Type_Name;
9252
9253    -------------------------
9254    -- Find_Type_Of_Object --
9255    -------------------------
9256
9257    function Find_Type_Of_Object
9258      (Obj_Def     : Node_Id;
9259       Related_Nod : Node_Id)
9260       return        Entity_Id
9261    is
9262       Def_Kind : constant Node_Kind := Nkind (Obj_Def);
9263       P        : constant Node_Id   := Parent (Obj_Def);
9264       T        : Entity_Id;
9265       Nam      : Name_Id;
9266
9267    begin
9268       --  Case of an anonymous array subtype
9269
9270       if Def_Kind = N_Constrained_Array_Definition
9271         or else Def_Kind = N_Unconstrained_Array_Definition
9272       then
9273          T := Empty;
9274          Array_Type_Declaration (T, Obj_Def);
9275
9276       --  Create an explicit subtype whenever possible.
9277
9278       elsif Nkind (P) /= N_Component_Declaration
9279         and then Def_Kind = N_Subtype_Indication
9280       then
9281          --  Base name of subtype on object name, which will be unique in
9282          --  the current scope.
9283
9284          --  If this is a duplicate declaration, return base type, to avoid
9285          --  generating duplicate anonymous types.
9286
9287          if Error_Posted (P) then
9288             Analyze (Subtype_Mark (Obj_Def));
9289             return Entity (Subtype_Mark (Obj_Def));
9290          end if;
9291
9292          Nam :=
9293             New_External_Name
9294              (Chars (Defining_Identifier (Related_Nod)), 'S', 0, 'T');
9295
9296          T := Make_Defining_Identifier (Sloc (P), Nam);
9297
9298          Insert_Action (Obj_Def,
9299            Make_Subtype_Declaration (Sloc (P),
9300              Defining_Identifier => T,
9301              Subtype_Indication  => Relocate_Node (Obj_Def)));
9302
9303          --  This subtype may need freezing and it will not be done
9304          --  automatically if the object declaration is not in a
9305          --  declarative part. Since this is an object declaration, the
9306          --  type cannot always be frozen here. Deferred constants do not
9307          --  freeze their type (which often enough will be private).
9308
9309          if Nkind (P) = N_Object_Declaration
9310            and then Constant_Present (P)
9311            and then No (Expression (P))
9312          then
9313             null;
9314
9315          else
9316             Insert_Actions (Obj_Def, Freeze_Entity (T, Sloc (P)));
9317          end if;
9318
9319       else
9320          T := Process_Subtype (Obj_Def, Related_Nod);
9321       end if;
9322
9323       return T;
9324    end Find_Type_Of_Object;
9325
9326    --------------------------------
9327    -- Find_Type_Of_Subtype_Indic --
9328    --------------------------------
9329
9330    function Find_Type_Of_Subtype_Indic (S : Node_Id) return Entity_Id is
9331       Typ : Entity_Id;
9332
9333    begin
9334       --  Case of subtype mark with a constraint
9335
9336       if Nkind (S) = N_Subtype_Indication then
9337          Find_Type (Subtype_Mark (S));
9338          Typ := Entity (Subtype_Mark (S));
9339
9340          if not
9341            Is_Valid_Constraint_Kind (Ekind (Typ), Nkind (Constraint (S)))
9342          then
9343             Error_Msg_N
9344               ("incorrect constraint for this kind of type", Constraint (S));
9345             Rewrite (S, New_Copy_Tree (Subtype_Mark (S)));
9346          end if;
9347
9348       --  Otherwise we have a subtype mark without a constraint
9349
9350       elsif Error_Posted (S) then
9351          Rewrite (S, New_Occurrence_Of (Any_Id, Sloc (S)));
9352          return Any_Type;
9353
9354       else
9355          Find_Type (S);
9356          Typ := Entity (S);
9357       end if;
9358
9359       if Typ = Standard_Wide_Character
9360         or else Typ = Standard_Wide_String
9361       then
9362          Check_Restriction (No_Wide_Characters, S);
9363       end if;
9364
9365       return Typ;
9366    end Find_Type_Of_Subtype_Indic;
9367
9368    -------------------------------------
9369    -- Floating_Point_Type_Declaration --
9370    -------------------------------------
9371
9372    procedure Floating_Point_Type_Declaration (T : Entity_Id; Def : Node_Id) is
9373       Digs          : constant Node_Id := Digits_Expression (Def);
9374       Digs_Val      : Uint;
9375       Base_Typ      : Entity_Id;
9376       Implicit_Base : Entity_Id;
9377       Bound         : Node_Id;
9378
9379       function Can_Derive_From (E : Entity_Id) return Boolean;
9380       --  Find if given digits value allows derivation from specified type
9381
9382       function Can_Derive_From (E : Entity_Id) return Boolean is
9383          Spec : constant Entity_Id := Real_Range_Specification (Def);
9384
9385       begin
9386          if Digs_Val > Digits_Value (E) then
9387             return False;
9388          end if;
9389
9390          if Present (Spec) then
9391             if Expr_Value_R (Type_Low_Bound (E)) >
9392                Expr_Value_R (Low_Bound (Spec))
9393             then
9394                return False;
9395             end if;
9396
9397             if Expr_Value_R (Type_High_Bound (E)) <
9398                Expr_Value_R (High_Bound (Spec))
9399             then
9400                return False;
9401             end if;
9402          end if;
9403
9404          return True;
9405       end Can_Derive_From;
9406
9407    --  Start of processing for Floating_Point_Type_Declaration
9408
9409    begin
9410       Check_Restriction (No_Floating_Point, Def);
9411
9412       --  Create an implicit base type
9413
9414       Implicit_Base :=
9415         Create_Itype (E_Floating_Point_Type, Parent (Def), T, 'B');
9416
9417       --  Analyze and verify digits value
9418
9419       Analyze_And_Resolve (Digs, Any_Integer);
9420       Check_Digits_Expression (Digs);
9421       Digs_Val := Expr_Value (Digs);
9422
9423       --  Process possible range spec and find correct type to derive from
9424
9425       Process_Real_Range_Specification (Def);
9426
9427       if Can_Derive_From (Standard_Short_Float) then
9428          Base_Typ := Standard_Short_Float;
9429       elsif Can_Derive_From (Standard_Float) then
9430          Base_Typ := Standard_Float;
9431       elsif Can_Derive_From (Standard_Long_Float) then
9432          Base_Typ := Standard_Long_Float;
9433       elsif Can_Derive_From (Standard_Long_Long_Float) then
9434          Base_Typ := Standard_Long_Long_Float;
9435
9436       --  If we can't derive from any existing type, use long long float
9437       --  and give appropriate message explaining the problem.
9438
9439       else
9440          Base_Typ := Standard_Long_Long_Float;
9441
9442          if Digs_Val >= Digits_Value (Standard_Long_Long_Float) then
9443             Error_Msg_Uint_1 := Digits_Value (Standard_Long_Long_Float);
9444             Error_Msg_N ("digits value out of range, maximum is ^", Digs);
9445
9446          else
9447             Error_Msg_N
9448               ("range too large for any predefined type",
9449                Real_Range_Specification (Def));
9450          end if;
9451       end if;
9452
9453       --  If there are bounds given in the declaration use them as the bounds
9454       --  of the type, otherwise use the bounds of the predefined base type
9455       --  that was chosen based on the Digits value.
9456
9457       if Present (Real_Range_Specification (Def)) then
9458          Set_Scalar_Range (T, Real_Range_Specification (Def));
9459          Set_Is_Constrained (T);
9460
9461          --  The bounds of this range must be converted to machine numbers
9462          --  in accordance with RM 4.9(38).
9463
9464          Bound := Type_Low_Bound (T);
9465
9466          if Nkind (Bound) = N_Real_Literal then
9467             Set_Realval (Bound, Machine (Base_Typ, Realval (Bound), Round));
9468             Set_Is_Machine_Number (Bound);
9469          end if;
9470
9471          Bound := Type_High_Bound (T);
9472
9473          if Nkind (Bound) = N_Real_Literal then
9474             Set_Realval (Bound, Machine (Base_Typ, Realval (Bound), Round));
9475             Set_Is_Machine_Number (Bound);
9476          end if;
9477
9478       else
9479          Set_Scalar_Range (T, Scalar_Range (Base_Typ));
9480       end if;
9481
9482       --  Complete definition of implicit base and declared first subtype
9483
9484       Set_Etype          (Implicit_Base, Base_Typ);
9485
9486       Set_Scalar_Range   (Implicit_Base, Scalar_Range   (Base_Typ));
9487       Set_Size_Info      (Implicit_Base,                (Base_Typ));
9488       Set_RM_Size        (Implicit_Base, RM_Size        (Base_Typ));
9489       Set_First_Rep_Item (Implicit_Base, First_Rep_Item (Base_Typ));
9490       Set_Digits_Value   (Implicit_Base, Digits_Value   (Base_Typ));
9491       Set_Vax_Float      (Implicit_Base, Vax_Float      (Base_Typ));
9492
9493       Set_Ekind          (T, E_Floating_Point_Subtype);
9494       Set_Etype          (T, Implicit_Base);
9495
9496       Set_Size_Info      (T,                (Implicit_Base));
9497       Set_RM_Size        (T, RM_Size        (Implicit_Base));
9498       Set_First_Rep_Item (T, First_Rep_Item (Implicit_Base));
9499       Set_Digits_Value   (T, Digs_Val);
9500
9501    end Floating_Point_Type_Declaration;
9502
9503    ----------------------------
9504    -- Get_Discriminant_Value --
9505    ----------------------------
9506
9507    --  This is the situation...
9508
9509    --  There is a non-derived type
9510
9511    --       type T0 (Dx, Dy, Dz...)
9512
9513    --  There are zero or more levels of derivation, with each
9514    --  derivation either purely inheriting the discriminants, or
9515    --  defining its own.
9516
9517    --       type Ti      is new Ti-1
9518    --  or
9519    --       type Ti (Dw) is new Ti-1(Dw, 1, X+Y)
9520    --  or
9521    --       subtype Ti is ...
9522
9523    --  The subtype issue is avoided by the use of
9524    --    Original_Record_Component, and the fact that derived subtypes
9525    --    also derive the constraits.
9526
9527    --  This chain leads back from
9528
9529    --       Typ_For_Constraint
9530
9531    --  Typ_For_Constraint has discriminants, and the value for each
9532    --  discriminant is given by its corresponding Elmt of Constraints.
9533
9534    --  Discriminant is some discriminant in this hierarchy.
9535
9536    --  We need to return its value.
9537
9538    --  We do this by recursively searching each level, and looking for
9539    --  Discriminant. Once we get to the bottom, we start backing up
9540    --  returning the value for it which may in turn be a discriminant
9541    --  further up, so on the backup we continue the substitution.
9542
9543    function Get_Discriminant_Value
9544      (Discriminant       : Entity_Id;
9545       Typ_For_Constraint : Entity_Id;
9546       Constraint         : Elist_Id)
9547       return               Node_Id
9548    is
9549       function Recurse
9550         (Ti                    : Entity_Id;
9551          Discrim_Values        : Elist_Id;
9552          Girder_Discrim_Values : Boolean)
9553          return                Node_Or_Entity_Id;
9554       --  This is the routine that performs the recursive search of levels
9555       --  as described above.
9556
9557       function Recurse
9558         (Ti                    : Entity_Id;
9559          Discrim_Values        : Elist_Id;
9560          Girder_Discrim_Values : Boolean)
9561          return                  Node_Or_Entity_Id
9562       is
9563          Assoc          : Elmt_Id;
9564          Disc           : Entity_Id;
9565          Result         : Node_Or_Entity_Id;
9566          Result_Entity  : Node_Id;
9567
9568       begin
9569          --  If inappropriate type, return Error, this happens only in
9570          --  cascaded error situations, and we want to avoid a blow up.
9571
9572          if not Is_Composite_Type (Ti) or else Is_Array_Type (Ti) then
9573             return Error;
9574          end if;
9575
9576          --  Look deeper if possible. Use Girder_Constraints only for
9577          --  untagged types. For tagged types use the given constraint.
9578          --  This asymmetry needs explanation???
9579
9580          if not Girder_Discrim_Values
9581            and then Present (Girder_Constraint (Ti))
9582            and then not Is_Tagged_Type (Ti)
9583          then
9584             Result := Recurse (Ti, Girder_Constraint (Ti), True);
9585          else
9586             declare
9587                Td : Entity_Id := Etype (Ti);
9588             begin
9589
9590                if Td = Ti then
9591                   Result := Discriminant;
9592
9593                else
9594                   if Present (Girder_Constraint (Ti)) then
9595                      Result :=
9596                         Recurse (Td, Girder_Constraint (Ti), True);
9597                   else
9598                      Result :=
9599                         Recurse (Td, Discrim_Values, Girder_Discrim_Values);
9600                   end if;
9601                end if;
9602             end;
9603          end if;
9604
9605          --  Extra underlying places to search, if not found above. For
9606          --  concurrent types, the relevant discriminant appears in the
9607          --  corresponding record. For a type derived from a private type
9608          --  without discriminant, the full view inherits the discriminants
9609          --  of the full view of the parent.
9610
9611          if Result = Discriminant then
9612             if Is_Concurrent_Type (Ti)
9613               and then Present (Corresponding_Record_Type (Ti))
9614             then
9615                Result :=
9616                  Recurse (
9617                    Corresponding_Record_Type (Ti),
9618                    Discrim_Values,
9619                    Girder_Discrim_Values);
9620
9621             elsif Is_Private_Type (Ti)
9622               and then not Has_Discriminants (Ti)
9623               and then Present (Full_View (Ti))
9624               and then Etype (Full_View (Ti)) /= Ti
9625             then
9626                Result :=
9627                  Recurse (
9628                    Full_View (Ti),
9629                    Discrim_Values,
9630                    Girder_Discrim_Values);
9631             end if;
9632          end if;
9633
9634          --  If Result is not a (reference to a) discriminant,
9635          --  return it, otherwise set Result_Entity to the discriminant.
9636
9637          if Nkind (Result) = N_Defining_Identifier then
9638
9639             pragma Assert (Result = Discriminant);
9640
9641             Result_Entity := Result;
9642
9643          else
9644             if not Denotes_Discriminant (Result) then
9645                return Result;
9646             end if;
9647
9648             Result_Entity := Entity (Result);
9649          end if;
9650
9651          --  See if this level of derivation actually has discriminants
9652          --  because tagged derivations can add them, hence the lower
9653          --  levels need not have any.
9654
9655          if not Has_Discriminants (Ti) then
9656             return Result;
9657          end if;
9658
9659          --  Scan Ti's discriminants for Result_Entity,
9660          --  and return its corresponding value, if any.
9661
9662          Result_Entity := Original_Record_Component (Result_Entity);
9663
9664          Assoc := First_Elmt (Discrim_Values);
9665
9666          if Girder_Discrim_Values then
9667             Disc := First_Girder_Discriminant (Ti);
9668          else
9669             Disc := First_Discriminant (Ti);
9670          end if;
9671
9672          while Present (Disc) loop
9673
9674             pragma Assert (Present (Assoc));
9675
9676             if Original_Record_Component (Disc) = Result_Entity then
9677                return Node (Assoc);
9678             end if;
9679
9680             Next_Elmt (Assoc);
9681
9682             if Girder_Discrim_Values then
9683                Next_Girder_Discriminant (Disc);
9684             else
9685                Next_Discriminant (Disc);
9686             end if;
9687          end loop;
9688
9689          --  Could not find it
9690          --
9691          return Result;
9692       end Recurse;
9693
9694       Result : Node_Or_Entity_Id;
9695
9696    --  Start of processing for Get_Discriminant_Value
9697
9698    begin
9699       --  ??? this routine is a gigantic mess and will be deleted.
9700       --  for the time being just test for the trivial case before calling
9701       --  recurse.
9702
9703       if Base_Type (Scope (Discriminant)) = Base_Type (Typ_For_Constraint) then
9704          declare
9705             D : Entity_Id := First_Discriminant (Typ_For_Constraint);
9706             E : Elmt_Id   := First_Elmt (Constraint);
9707          begin
9708             while Present (D) loop
9709                if Chars (D) = Chars (Discriminant) then
9710                   return Node (E);
9711                end if;
9712
9713                Next_Discriminant (D);
9714                Next_Elmt (E);
9715             end loop;
9716          end;
9717       end if;
9718
9719       Result := Recurse (Typ_For_Constraint, Constraint, False);
9720
9721       --  ??? hack to disappear when this routine is gone
9722
9723       if  Nkind (Result) = N_Defining_Identifier then
9724          declare
9725             D : Entity_Id := First_Discriminant (Typ_For_Constraint);
9726             E : Elmt_Id   := First_Elmt (Constraint);
9727          begin
9728             while Present (D) loop
9729                if Corresponding_Discriminant (D) = Discriminant then
9730                   return Node (E);
9731                end if;
9732
9733                Next_Discriminant (D);
9734                Next_Elmt (E);
9735             end loop;
9736          end;
9737       end if;
9738
9739       pragma Assert (Nkind (Result) /= N_Defining_Identifier);
9740       return Result;
9741    end Get_Discriminant_Value;
9742
9743    --------------------------
9744    -- Has_Range_Constraint --
9745    --------------------------
9746
9747    function Has_Range_Constraint (N : Node_Id) return Boolean is
9748       C : constant Node_Id := Constraint (N);
9749
9750    begin
9751       if Nkind (C) = N_Range_Constraint then
9752          return True;
9753
9754       elsif Nkind (C) = N_Digits_Constraint then
9755          return
9756             Is_Decimal_Fixed_Point_Type (Entity (Subtype_Mark (N)))
9757               or else
9758             Present (Range_Constraint (C));
9759
9760       elsif Nkind (C) = N_Delta_Constraint then
9761          return Present (Range_Constraint (C));
9762
9763       else
9764          return False;
9765       end if;
9766    end Has_Range_Constraint;
9767
9768    ------------------------
9769    -- Inherit_Components --
9770    ------------------------
9771
9772    function Inherit_Components
9773      (N             : Node_Id;
9774       Parent_Base   : Entity_Id;
9775       Derived_Base  : Entity_Id;
9776       Is_Tagged     : Boolean;
9777       Inherit_Discr : Boolean;
9778       Discs         : Elist_Id)
9779       return          Elist_Id
9780    is
9781       Assoc_List : Elist_Id := New_Elmt_List;
9782
9783       procedure Inherit_Component
9784         (Old_C          : Entity_Id;
9785          Plain_Discrim  : Boolean := False;
9786          Girder_Discrim : Boolean := False);
9787       --  Inherits component Old_C from Parent_Base to the Derived_Base.
9788       --  If Plain_Discrim is True, Old_C is a discriminant.
9789       --  If Girder_Discrim is True, Old_C is a girder discriminant.
9790       --  If they are both false then Old_C is a regular component.
9791
9792       -----------------------
9793       -- Inherit_Component --
9794       -----------------------
9795
9796       procedure Inherit_Component
9797         (Old_C          : Entity_Id;
9798          Plain_Discrim  : Boolean := False;
9799          Girder_Discrim : Boolean := False)
9800       is
9801          New_C : Entity_Id := New_Copy (Old_C);
9802
9803          Discrim      : Entity_Id;
9804          Corr_Discrim : Entity_Id;
9805
9806       begin
9807          pragma Assert (not Is_Tagged or else not Girder_Discrim);
9808
9809          Set_Parent (New_C, Parent (Old_C));
9810
9811          --  Regular discriminants and components must be inserted
9812          --  in the scope of the Derived_Base. Do it here.
9813
9814          if not Girder_Discrim then
9815             Enter_Name (New_C);
9816          end if;
9817
9818          --  For tagged types the Original_Record_Component must point to
9819          --  whatever this field was pointing to in the parent type. This has
9820          --  already been achieved by the call to New_Copy above.
9821
9822          if not Is_Tagged then
9823             Set_Original_Record_Component (New_C, New_C);
9824          end if;
9825
9826          --  If we have inherited a component then see if its Etype contains
9827          --  references to Parent_Base discriminants. In this case, replace
9828          --  these references with the constraints given in Discs. We do not
9829          --  do this for the partial view of private types because this is
9830          --  not needed (only the components of the full view will be used
9831          --  for code generation) and cause problem. We also avoid this
9832          --  transformation in some error situations.
9833
9834          if Ekind (New_C) = E_Component then
9835             if (Is_Private_Type (Derived_Base)
9836                   and then not Is_Generic_Type (Derived_Base))
9837               or else (Is_Empty_Elmt_List (Discs)
9838                        and then  not Expander_Active)
9839             then
9840                Set_Etype (New_C, Etype (Old_C));
9841             else
9842                Set_Etype (New_C, Constrain_Component_Type (Etype (Old_C),
9843                  Derived_Base, N, Parent_Base, Discs));
9844             end if;
9845          end if;
9846
9847          --  In derived tagged types it is illegal to reference a non
9848          --  discriminant component in the parent type. To catch this, mark
9849          --  these components with an Ekind of E_Void. This will be reset in
9850          --  Record_Type_Definition after processing the record extension of
9851          --  the derived type.
9852
9853          if Is_Tagged and then Ekind (New_C) = E_Component then
9854             Set_Ekind (New_C, E_Void);
9855          end if;
9856
9857          if Plain_Discrim then
9858             Set_Corresponding_Discriminant (New_C, Old_C);
9859             Build_Discriminal (New_C);
9860
9861          --  If we are explicitly inheriting a girder discriminant it will be
9862          --  completely hidden.
9863
9864          elsif Girder_Discrim then
9865             Set_Corresponding_Discriminant (New_C, Empty);
9866             Set_Discriminal (New_C, Empty);
9867             Set_Is_Completely_Hidden (New_C);
9868
9869             --  Set the Original_Record_Component of each discriminant in the
9870             --  derived base to point to the corresponding girder that we just
9871             --  created.
9872
9873             Discrim := First_Discriminant (Derived_Base);
9874             while Present (Discrim) loop
9875                Corr_Discrim := Corresponding_Discriminant (Discrim);
9876
9877                --  Corr_Discrimm could be missing in an error situation.
9878
9879                if Present (Corr_Discrim)
9880                  and then Original_Record_Component (Corr_Discrim) = Old_C
9881                then
9882                   Set_Original_Record_Component (Discrim, New_C);
9883                end if;
9884
9885                Next_Discriminant (Discrim);
9886             end loop;
9887
9888             Append_Entity (New_C, Derived_Base);
9889          end if;
9890
9891          if not Is_Tagged then
9892             Append_Elmt (Old_C, Assoc_List);
9893             Append_Elmt (New_C, Assoc_List);
9894          end if;
9895       end Inherit_Component;
9896
9897       --  Variables local to Inherit_Components.
9898
9899       Loc : constant Source_Ptr := Sloc (N);
9900
9901       Parent_Discrim : Entity_Id;
9902       Girder_Discrim : Entity_Id;
9903       D              : Entity_Id;
9904
9905       Component        : Entity_Id;
9906
9907    --  Start of processing for Inherit_Components
9908
9909    begin
9910       if not Is_Tagged then
9911          Append_Elmt (Parent_Base,  Assoc_List);
9912          Append_Elmt (Derived_Base, Assoc_List);
9913       end if;
9914
9915       --  Inherit parent discriminants if needed.
9916
9917       if Inherit_Discr then
9918          Parent_Discrim := First_Discriminant (Parent_Base);
9919          while Present (Parent_Discrim) loop
9920             Inherit_Component (Parent_Discrim, Plain_Discrim => True);
9921             Next_Discriminant (Parent_Discrim);
9922          end loop;
9923       end if;
9924
9925       --  Create explicit girder discrims for untagged types when necessary.
9926
9927       if not Has_Unknown_Discriminants (Derived_Base)
9928         and then Has_Discriminants (Parent_Base)
9929         and then not Is_Tagged
9930         and then
9931           (not Inherit_Discr
9932            or else First_Discriminant (Parent_Base) /=
9933                    First_Girder_Discriminant (Parent_Base))
9934       then
9935          Girder_Discrim := First_Girder_Discriminant (Parent_Base);
9936          while Present (Girder_Discrim) loop
9937             Inherit_Component (Girder_Discrim, Girder_Discrim => True);
9938             Next_Girder_Discriminant (Girder_Discrim);
9939          end loop;
9940       end if;
9941
9942       --  See if we can apply the second transformation for derived types, as
9943       --  explained in point 6. in the comments above Build_Derived_Record_Type
9944       --  This is achieved by appending Derived_Base discriminants into
9945       --  Discs, which has the side effect of returning a non empty Discs
9946       --  list to the caller of Inherit_Components, which is what we want.
9947
9948       if Inherit_Discr
9949         and then Is_Empty_Elmt_List (Discs)
9950         and then (not Is_Private_Type (Derived_Base)
9951                    or Is_Generic_Type (Derived_Base))
9952       then
9953          D := First_Discriminant (Derived_Base);
9954          while Present (D) loop
9955             Append_Elmt (New_Reference_To (D, Loc), Discs);
9956             Next_Discriminant (D);
9957          end loop;
9958       end if;
9959
9960       --  Finally, inherit non-discriminant components unless they are not
9961       --  visible because defined or inherited from the full view of the
9962       --  parent. Don't inherit the _parent field of the parent type.
9963
9964       Component := First_Entity (Parent_Base);
9965       while Present (Component) loop
9966          if Ekind (Component) /= E_Component
9967            or else Chars (Component) = Name_uParent
9968          then
9969             null;
9970
9971          --  If the derived type is within the parent type's declarative
9972          --  region, then the components can still be inherited even though
9973          --  they aren't visible at this point. This can occur for cases
9974          --  such as within public child units where the components must
9975          --  become visible upon entering the child unit's private part.
9976
9977          elsif not Is_Visible_Component (Component)
9978            and then not In_Open_Scopes (Scope (Parent_Base))
9979          then
9980             null;
9981
9982          elsif Ekind (Derived_Base) = E_Private_Type
9983            or else Ekind (Derived_Base) = E_Limited_Private_Type
9984          then
9985             null;
9986
9987          else
9988             Inherit_Component (Component);
9989          end if;
9990
9991          Next_Entity (Component);
9992       end loop;
9993
9994       --  For tagged derived types, inherited discriminants cannot be used in
9995       --  component declarations of the record extension part. To achieve this
9996       --  we mark the inherited discriminants as not visible.
9997
9998       if Is_Tagged and then Inherit_Discr then
9999          D := First_Discriminant (Derived_Base);
10000          while Present (D) loop
10001             Set_Is_Immediately_Visible (D, False);
10002             Next_Discriminant (D);
10003          end loop;
10004       end if;
10005
10006       return Assoc_List;
10007    end Inherit_Components;
10008
10009    ------------------------------
10010    -- Is_Valid_Constraint_Kind --
10011    ------------------------------
10012
10013    function Is_Valid_Constraint_Kind
10014      (T_Kind          : Type_Kind;
10015       Constraint_Kind : Node_Kind)
10016       return            Boolean
10017    is
10018    begin
10019       case T_Kind is
10020
10021          when Enumeration_Kind |
10022               Integer_Kind =>
10023             return Constraint_Kind = N_Range_Constraint;
10024
10025          when Decimal_Fixed_Point_Kind =>
10026             return
10027               Constraint_Kind = N_Digits_Constraint
10028                 or else
10029               Constraint_Kind = N_Range_Constraint;
10030
10031          when Ordinary_Fixed_Point_Kind =>
10032             return
10033               Constraint_Kind = N_Delta_Constraint
10034                 or else
10035               Constraint_Kind = N_Range_Constraint;
10036
10037          when Float_Kind =>
10038             return
10039               Constraint_Kind = N_Digits_Constraint
10040                 or else
10041               Constraint_Kind = N_Range_Constraint;
10042
10043          when Access_Kind       |
10044               Array_Kind        |
10045               E_Record_Type     |
10046               E_Record_Subtype  |
10047               Class_Wide_Kind   |
10048               E_Incomplete_Type |
10049               Private_Kind      |
10050               Concurrent_Kind  =>
10051             return Constraint_Kind = N_Index_Or_Discriminant_Constraint;
10052
10053          when others =>
10054             return True; -- Error will be detected later.
10055       end case;
10056
10057    end Is_Valid_Constraint_Kind;
10058
10059    --------------------------
10060    -- Is_Visible_Component --
10061    --------------------------
10062
10063    function Is_Visible_Component (C : Entity_Id) return Boolean is
10064       Original_Comp  : constant Entity_Id := Original_Record_Component (C);
10065       Original_Scope : Entity_Id;
10066
10067    begin
10068       if No (Original_Comp) then
10069
10070          --  Premature usage, or previous error
10071
10072          return False;
10073
10074       else
10075          Original_Scope := Scope (Original_Comp);
10076       end if;
10077
10078       --  This test only concern tagged types
10079
10080       if not Is_Tagged_Type (Original_Scope) then
10081          return True;
10082
10083       --  If it is _Parent or _Tag, there is no visiblity issue
10084
10085       elsif not Comes_From_Source (Original_Comp) then
10086          return True;
10087
10088       --  If we are in the body of an instantiation, the component is
10089       --  visible even when the parent type (possibly defined in an
10090       --  enclosing unit or in a parent unit) might not.
10091
10092       elsif In_Instance_Body then
10093          return True;
10094
10095       --  Discriminants are always visible.
10096
10097       elsif Ekind (Original_Comp) = E_Discriminant
10098         and then not Has_Unknown_Discriminants (Original_Scope)
10099       then
10100          return True;
10101
10102       --  If the component has been declared in an ancestor which is
10103       --  currently a private type, then it is not visible. The same
10104       --  applies if the component's containing type is not in an
10105       --  open scope and the original component's enclosing type
10106       --  is a visible full type of a private type (which can occur
10107       --  in cases where an attempt is being made to reference a
10108       --  component in a sibling package that is inherited from
10109       --  a visible component of a type in an ancestor package;
10110       --  the component in the sibling package should not be
10111       --  visible even though the component it inherited from
10112       --  is visible). This does not apply however in the case
10113       --  where the scope of the type is a private child unit.
10114       --  The latter suppression of visibility is needed for cases
10115       --  that are tested in B730006.
10116
10117       elsif (Ekind (Original_Comp) /= E_Discriminant
10118               or else Has_Unknown_Discriminants (Original_Scope))
10119         and then
10120           (Is_Private_Type (Original_Scope)
10121             or else
10122               (not Is_Private_Descendant (Scope (Base_Type (Scope (C))))
10123                 and then not In_Open_Scopes (Scope (Base_Type (Scope (C))))
10124                 and then Has_Private_Declaration (Original_Scope)))
10125       then
10126          return False;
10127
10128       --  There is another weird way in which a component may be invisible
10129       --  when the private and the full view are not derived from the same
10130       --  ancestor. Here is an example :
10131
10132       --       type A1 is tagged      record F1 : integer; end record;
10133       --       type A2 is new A1 with record F2 : integer; end record;
10134       --       type T is new A1 with private;
10135       --     private
10136       --       type T is new A2 with private;
10137
10138       --  In this case, the full view of T inherits F1 and F2 but the
10139       --  private view inherits only F1
10140
10141       else
10142          declare
10143             Ancestor : Entity_Id := Scope (C);
10144
10145          begin
10146             loop
10147                if Ancestor = Original_Scope then
10148                   return True;
10149                elsif Ancestor = Etype (Ancestor) then
10150                   return False;
10151                end if;
10152
10153                Ancestor := Etype (Ancestor);
10154             end loop;
10155
10156             return True;
10157          end;
10158       end if;
10159    end Is_Visible_Component;
10160
10161    --------------------------
10162    -- Make_Class_Wide_Type --
10163    --------------------------
10164
10165    procedure Make_Class_Wide_Type (T : Entity_Id) is
10166       CW_Type : Entity_Id;
10167       CW_Name : Name_Id;
10168       Next_E  : Entity_Id;
10169
10170    begin
10171       --  The class wide type can have been defined by the partial view in
10172       --  which case everything is already done
10173
10174       if Present (Class_Wide_Type (T)) then
10175          return;
10176       end if;
10177
10178       CW_Type :=
10179         New_External_Entity (E_Void, Scope (T), Sloc (T), T, 'C', 0, 'T');
10180
10181       --  Inherit root type characteristics
10182
10183       CW_Name := Chars (CW_Type);
10184       Next_E  := Next_Entity (CW_Type);
10185       Copy_Node (T, CW_Type);
10186       Set_Comes_From_Source (CW_Type, False);
10187       Set_Chars (CW_Type, CW_Name);
10188       Set_Parent (CW_Type, Parent (T));
10189       Set_Next_Entity (CW_Type, Next_E);
10190       Set_Has_Delayed_Freeze (CW_Type);
10191
10192       --  Customize the class-wide type: It has no prim. op., it cannot be
10193       --  abstract and its Etype points back to the root type
10194
10195       Set_Ekind                (CW_Type, E_Class_Wide_Type);
10196       Set_Is_Tagged_Type       (CW_Type, True);
10197       Set_Primitive_Operations (CW_Type, New_Elmt_List);
10198       Set_Is_Abstract          (CW_Type, False);
10199       Set_Etype                (CW_Type, T);
10200       Set_Is_Constrained       (CW_Type, False);
10201       Set_Is_First_Subtype     (CW_Type, Is_First_Subtype (T));
10202       Init_Size_Align          (CW_Type);
10203
10204       --  If this is the class_wide type of a constrained subtype, it does
10205       --  not have discriminants.
10206
10207       Set_Has_Discriminants (CW_Type,
10208         Has_Discriminants (T) and then not Is_Constrained (T));
10209
10210       Set_Has_Unknown_Discriminants (CW_Type, True);
10211       Set_Class_Wide_Type (T, CW_Type);
10212       Set_Equivalent_Type (CW_Type, Empty);
10213
10214       --  The class-wide type of a class-wide type is itself (RM 3.9(14))
10215
10216       Set_Class_Wide_Type (CW_Type, CW_Type);
10217
10218    end Make_Class_Wide_Type;
10219
10220    ----------------
10221    -- Make_Index --
10222    ----------------
10223
10224    procedure Make_Index
10225      (I            : Node_Id;
10226       Related_Nod  : Node_Id;
10227       Related_Id   : Entity_Id := Empty;
10228       Suffix_Index : Nat := 1)
10229    is
10230       R      : Node_Id;
10231       T      : Entity_Id;
10232       Def_Id : Entity_Id := Empty;
10233       Found  : Boolean := False;
10234
10235    begin
10236       --  For a discrete range used in a constrained array definition and
10237       --  defined by a range, an implicit conversion to the predefined type
10238       --  INTEGER is assumed if each bound is either a numeric literal, a named
10239       --  number, or an attribute, and the type of both bounds (prior to the
10240       --  implicit conversion) is the type universal_integer. Otherwise, both
10241       --  bounds must be of the same discrete type, other than universal
10242       --  integer; this type must be determinable independently of the
10243       --  context, but using the fact that the type must be discrete and that
10244       --  both bounds must have the same type.
10245
10246       --  Character literals also have a universal type in the absence of
10247       --  of additional context,  and are resolved to Standard_Character.
10248
10249       if Nkind (I) = N_Range then
10250
10251          --  The index is given by a range constraint. The bounds are known
10252          --  to be of a consistent type.
10253
10254          if not Is_Overloaded (I) then
10255             T := Etype (I);
10256
10257             --  If the bounds are universal, choose the specific predefined
10258             --  type.
10259
10260             if T = Universal_Integer then
10261                T := Standard_Integer;
10262
10263             elsif T = Any_Character then
10264
10265                if not Ada_83 then
10266                   Error_Msg_N
10267                     ("ambiguous character literals (could be Wide_Character)",
10268                       I);
10269                end if;
10270
10271                T := Standard_Character;
10272             end if;
10273
10274          else
10275             T := Any_Type;
10276
10277             declare
10278                Ind : Interp_Index;
10279                It  : Interp;
10280
10281             begin
10282                Get_First_Interp (I, Ind, It);
10283
10284                while Present (It.Typ) loop
10285                   if Is_Discrete_Type (It.Typ) then
10286
10287                      if Found
10288                        and then not Covers (It.Typ, T)
10289                        and then not Covers (T, It.Typ)
10290                      then
10291                         Error_Msg_N ("ambiguous bounds in discrete range", I);
10292                         exit;
10293                      else
10294                         T := It.Typ;
10295                         Found := True;
10296                      end if;
10297                   end if;
10298
10299                   Get_Next_Interp (Ind, It);
10300                end loop;
10301
10302                if T = Any_Type then
10303                   Error_Msg_N ("discrete type required for range", I);
10304                   Set_Etype (I, Any_Type);
10305                   return;
10306
10307                elsif T = Universal_Integer then
10308                   T := Standard_Integer;
10309                end if;
10310             end;
10311          end if;
10312
10313          if not Is_Discrete_Type (T) then
10314             Error_Msg_N ("discrete type required for range", I);
10315             Set_Etype (I, Any_Type);
10316             return;
10317          end if;
10318
10319          R := I;
10320          Process_Range_Expr_In_Decl (R, T, Related_Nod);
10321
10322       elsif Nkind (I) = N_Subtype_Indication then
10323
10324          --  The index is given by a subtype with a range constraint.
10325
10326          T :=  Base_Type (Entity (Subtype_Mark (I)));
10327
10328          if not Is_Discrete_Type (T) then
10329             Error_Msg_N ("discrete type required for range", I);
10330             Set_Etype (I, Any_Type);
10331             return;
10332          end if;
10333
10334          R := Range_Expression (Constraint (I));
10335
10336          Resolve (R, T);
10337          Process_Range_Expr_In_Decl (R,
10338            Entity (Subtype_Mark (I)), Related_Nod);
10339
10340       elsif Nkind (I) = N_Attribute_Reference then
10341
10342          --  The parser guarantees that the attribute is a RANGE attribute
10343
10344          Analyze_And_Resolve (I);
10345          T := Etype (I);
10346          R := I;
10347
10348       --  If none of the above, must be a subtype. We convert this to a
10349       --  range attribute reference because in the case of declared first
10350       --  named subtypes, the types in the range reference can be different
10351       --  from the type of the entity. A range attribute normalizes the
10352       --  reference and obtains the correct types for the bounds.
10353
10354       --  This transformation is in the nature of an expansion, is only
10355       --  done if expansion is active. In particular, it is not done on
10356       --  formal generic types,  because we need to retain the name of the
10357       --  original index for instantiation purposes.
10358
10359       else
10360          if not Is_Entity_Name (I) or else not Is_Type (Entity (I)) then
10361             Error_Msg_N ("invalid subtype mark in discrete range ", I);
10362             Set_Etype (I, Any_Integer);
10363             return;
10364          else
10365             --  The type mark may be that of an incomplete type. It is only
10366             --  now that we can get the full view, previous analysis does
10367             --  not look specifically for a type mark.
10368
10369             Set_Entity (I, Get_Full_View (Entity (I)));
10370             Set_Etype  (I, Entity (I));
10371             Def_Id := Entity (I);
10372
10373             if not Is_Discrete_Type (Def_Id) then
10374                Error_Msg_N ("discrete type required for index", I);
10375                Set_Etype (I, Any_Type);
10376                return;
10377             end if;
10378          end if;
10379
10380          if Expander_Active then
10381             Rewrite (I,
10382               Make_Attribute_Reference (Sloc (I),
10383                 Attribute_Name => Name_Range,
10384                 Prefix         => Relocate_Node (I)));
10385
10386             --  The original was a subtype mark that does not freeze. This
10387             --  means that the rewritten version must not freeze either.
10388
10389             Set_Must_Not_Freeze (I);
10390             Set_Must_Not_Freeze (Prefix (I));
10391
10392             --  Is order critical??? if so, document why, if not
10393             --  use Analyze_And_Resolve
10394
10395             Analyze (I);
10396             T := Etype (I);
10397             Resolve (I, T);
10398             R := I;
10399
10400          else
10401             --  Type is legal, nothing else to construct.
10402             return;
10403          end if;
10404       end if;
10405
10406       if not Is_Discrete_Type (T) then
10407          Error_Msg_N ("discrete type required for range", I);
10408          Set_Etype (I, Any_Type);
10409          return;
10410
10411       elsif T = Any_Type then
10412          Set_Etype (I, Any_Type);
10413          return;
10414       end if;
10415
10416       --  We will now create the appropriate Itype to describe the
10417       --  range, but first a check. If we originally had a subtype,
10418       --  then we just label the range with this subtype. Not only
10419       --  is there no need to construct a new subtype, but it is wrong
10420       --  to do so for two reasons:
10421
10422       --    1. A legality concern, if we have a subtype, it must not
10423       --       freeze, and the Itype would cause freezing incorrectly
10424
10425       --    2. An efficiency concern, if we created an Itype, it would
10426       --       not be recognized as the same type for the purposes of
10427       --       eliminating checks in some circumstances.
10428
10429       --  We signal this case by setting the subtype entity in Def_Id.
10430
10431       --  It would be nice to also do this optimization for the cases
10432       --  of X'Range and also the explicit range X'First .. X'Last,
10433       --  but that is not done yet (it is just an efficiency concern) ???
10434
10435       if No (Def_Id) then
10436
10437          Def_Id :=
10438            Create_Itype (E_Void, Related_Nod, Related_Id, 'D', Suffix_Index);
10439          Set_Etype (Def_Id, Base_Type (T));
10440
10441          if Is_Signed_Integer_Type (T) then
10442             Set_Ekind (Def_Id, E_Signed_Integer_Subtype);
10443
10444          elsif Is_Modular_Integer_Type (T) then
10445             Set_Ekind (Def_Id, E_Modular_Integer_Subtype);
10446
10447          else
10448             Set_Ekind             (Def_Id, E_Enumeration_Subtype);
10449             Set_Is_Character_Type (Def_Id, Is_Character_Type (T));
10450          end if;
10451
10452          Set_Size_Info      (Def_Id,                  (T));
10453          Set_RM_Size        (Def_Id, RM_Size          (T));
10454          Set_First_Rep_Item (Def_Id, First_Rep_Item   (T));
10455
10456          Set_Scalar_Range   (Def_Id, R);
10457          Conditional_Delay  (Def_Id, T);
10458
10459          --  In the subtype indication case, if the immediate parent of the
10460          --  new subtype is non-static, then the subtype we create is non-
10461          --  static, even if its bounds are static.
10462
10463          if Nkind (I) = N_Subtype_Indication
10464            and then not Is_Static_Subtype (Entity (Subtype_Mark (I)))
10465          then
10466             Set_Is_Non_Static_Subtype (Def_Id);
10467          end if;
10468       end if;
10469
10470       --  Final step is to label the index with this constructed type
10471
10472       Set_Etype (I, Def_Id);
10473    end Make_Index;
10474
10475    ------------------------------
10476    -- Modular_Type_Declaration --
10477    ------------------------------
10478
10479    procedure Modular_Type_Declaration (T : Entity_Id; Def : Node_Id) is
10480       Mod_Expr : constant Node_Id := Expression (Def);
10481       M_Val    : Uint;
10482
10483       procedure Set_Modular_Size (Bits : Int);
10484       --  Sets RM_Size to Bits, and Esize to normal word size above this
10485
10486       procedure Set_Modular_Size (Bits : Int) is
10487       begin
10488          Set_RM_Size (T, UI_From_Int (Bits));
10489
10490          if Bits <= 8 then
10491             Init_Esize (T, 8);
10492
10493          elsif Bits <= 16 then
10494             Init_Esize (T, 16);
10495
10496          elsif Bits <= 32 then
10497             Init_Esize (T, 32);
10498
10499          else
10500             Init_Esize (T, System_Max_Binary_Modulus_Power);
10501          end if;
10502       end Set_Modular_Size;
10503
10504    --  Start of processing for Modular_Type_Declaration
10505
10506    begin
10507       Analyze_And_Resolve (Mod_Expr, Any_Integer);
10508       Set_Etype (T, T);
10509       Set_Ekind (T, E_Modular_Integer_Type);
10510       Init_Alignment (T);
10511       Set_Is_Constrained (T);
10512
10513       if not Is_OK_Static_Expression (Mod_Expr) then
10514          Error_Msg_N
10515            ("non-static expression used for modular type bound", Mod_Expr);
10516          M_Val := 2 ** System_Max_Binary_Modulus_Power;
10517       else
10518          M_Val := Expr_Value (Mod_Expr);
10519       end if;
10520
10521       if M_Val < 1 then
10522          Error_Msg_N ("modulus value must be positive", Mod_Expr);
10523          M_Val := 2 ** System_Max_Binary_Modulus_Power;
10524       end if;
10525
10526       Set_Modulus (T, M_Val);
10527
10528       --   Create bounds for the modular type based on the modulus given in
10529       --   the type declaration and then analyze and resolve those bounds.
10530
10531       Set_Scalar_Range (T,
10532         Make_Range (Sloc (Mod_Expr),
10533           Low_Bound  =>
10534             Make_Integer_Literal (Sloc (Mod_Expr), 0),
10535           High_Bound =>
10536             Make_Integer_Literal (Sloc (Mod_Expr), M_Val - 1)));
10537
10538       --  Properly analyze the literals for the range. We do this manually
10539       --  because we can't go calling Resolve, since we are resolving these
10540       --  bounds with the type, and this type is certainly not complete yet!
10541
10542       Set_Etype (Low_Bound  (Scalar_Range (T)), T);
10543       Set_Etype (High_Bound (Scalar_Range (T)), T);
10544       Set_Is_Static_Expression (Low_Bound  (Scalar_Range (T)));
10545       Set_Is_Static_Expression (High_Bound (Scalar_Range (T)));
10546
10547       --  Loop through powers of two to find number of bits required
10548
10549       for Bits in Int range 0 .. System_Max_Binary_Modulus_Power loop
10550
10551          --  Binary case
10552
10553          if M_Val = 2 ** Bits then
10554             Set_Modular_Size (Bits);
10555             return;
10556
10557          --  Non-binary case
10558
10559          elsif M_Val < 2 ** Bits then
10560             Set_Non_Binary_Modulus (T);
10561
10562             if Bits > System_Max_Nonbinary_Modulus_Power then
10563                Error_Msg_Uint_1 :=
10564                  UI_From_Int (System_Max_Nonbinary_Modulus_Power);
10565                Error_Msg_N
10566                  ("nonbinary modulus exceeds limit (2 '*'*^ - 1)", Mod_Expr);
10567                Set_Modular_Size (System_Max_Binary_Modulus_Power);
10568                return;
10569
10570             else
10571                --  In the non-binary case, set size as per RM 13.3(55).
10572
10573                Set_Modular_Size (Bits);
10574                return;
10575             end if;
10576          end if;
10577
10578       end loop;
10579
10580       --  If we fall through, then the size exceed System.Max_Binary_Modulus
10581       --  so we just signal an error and set the maximum size.
10582
10583       Error_Msg_Uint_1 := UI_From_Int (System_Max_Binary_Modulus_Power);
10584       Error_Msg_N ("modulus exceeds limit (2 '*'*^)", Mod_Expr);
10585
10586       Set_Modular_Size (System_Max_Binary_Modulus_Power);
10587       Init_Alignment (T);
10588
10589    end Modular_Type_Declaration;
10590
10591    -------------------------
10592    -- New_Binary_Operator --
10593    -------------------------
10594
10595    procedure New_Binary_Operator (Op_Name : Name_Id; Typ : Entity_Id) is
10596       Loc : constant Source_Ptr := Sloc (Typ);
10597       Op  : Entity_Id;
10598
10599       function Make_Op_Formal (Typ, Op : Entity_Id) return Entity_Id;
10600       --  Create abbreviated declaration for the formal of a predefined
10601       --  Operator 'Op' of type 'Typ'
10602
10603       --------------------
10604       -- Make_Op_Formal --
10605       --------------------
10606
10607       function Make_Op_Formal (Typ, Op : Entity_Id) return Entity_Id is
10608          Formal : Entity_Id;
10609
10610       begin
10611          Formal := New_Internal_Entity (E_In_Parameter, Op, Loc, 'P');
10612          Set_Etype (Formal, Typ);
10613          Set_Mechanism (Formal, Default_Mechanism);
10614          return Formal;
10615       end Make_Op_Formal;
10616
10617    --  Start of processing for New_Binary_Operator
10618
10619    begin
10620       Op := Make_Defining_Operator_Symbol (Loc, Op_Name);
10621
10622       Set_Ekind                   (Op, E_Operator);
10623       Set_Scope                   (Op, Current_Scope);
10624       Set_Etype                   (Op, Typ);
10625       Set_Homonym                 (Op, Get_Name_Entity_Id (Op_Name));
10626       Set_Is_Immediately_Visible  (Op);
10627       Set_Is_Intrinsic_Subprogram (Op);
10628       Set_Has_Completion          (Op);
10629       Append_Entity               (Op, Current_Scope);
10630
10631       Set_Name_Entity_Id (Op_Name, Op);
10632
10633       Append_Entity (Make_Op_Formal (Typ, Op), Op);
10634       Append_Entity (Make_Op_Formal (Typ, Op), Op);
10635
10636    end New_Binary_Operator;
10637
10638    -------------------------------------------
10639    -- Ordinary_Fixed_Point_Type_Declaration --
10640    -------------------------------------------
10641
10642    procedure Ordinary_Fixed_Point_Type_Declaration
10643      (T   : Entity_Id;
10644       Def : Node_Id)
10645    is
10646       Loc           : constant Source_Ptr := Sloc (Def);
10647       Delta_Expr    : constant Node_Id    := Delta_Expression (Def);
10648       RRS           : constant Node_Id    := Real_Range_Specification (Def);
10649       Implicit_Base : Entity_Id;
10650       Delta_Val     : Ureal;
10651       Small_Val     : Ureal;
10652       Low_Val       : Ureal;
10653       High_Val      : Ureal;
10654
10655    begin
10656       Check_Restriction (No_Fixed_Point, Def);
10657
10658       --  Create implicit base type
10659
10660       Implicit_Base :=
10661         Create_Itype (E_Ordinary_Fixed_Point_Type, Parent (Def), T, 'B');
10662       Set_Etype (Implicit_Base, Implicit_Base);
10663
10664       --  Analyze and process delta expression
10665
10666       Analyze_And_Resolve (Delta_Expr, Any_Real);
10667
10668       Check_Delta_Expression (Delta_Expr);
10669       Delta_Val := Expr_Value_R (Delta_Expr);
10670
10671       Set_Delta_Value (Implicit_Base, Delta_Val);
10672
10673       --  Compute default small from given delta, which is the largest
10674       --  power of two that does not exceed the given delta value.
10675
10676       declare
10677          Tmp   : Ureal := Ureal_1;
10678          Scale : Int   := 0;
10679
10680       begin
10681          if Delta_Val < Ureal_1 then
10682             while Delta_Val < Tmp loop
10683                Tmp := Tmp / Ureal_2;
10684                Scale := Scale + 1;
10685             end loop;
10686
10687          else
10688             loop
10689                Tmp := Tmp * Ureal_2;
10690                exit when Tmp > Delta_Val;
10691                Scale := Scale - 1;
10692             end loop;
10693          end if;
10694
10695          Small_Val := UR_From_Components (Uint_1, UI_From_Int (Scale), 2);
10696       end;
10697
10698       Set_Small_Value (Implicit_Base, Small_Val);
10699
10700       --  If no range was given, set a dummy range
10701
10702       if RRS <= Empty_Or_Error then
10703          Low_Val  := -Small_Val;
10704          High_Val := Small_Val;
10705
10706       --  Otherwise analyze and process given range
10707
10708       else
10709          declare
10710             Low  : constant Node_Id := Low_Bound  (RRS);
10711             High : constant Node_Id := High_Bound (RRS);
10712
10713          begin
10714             Analyze_And_Resolve (Low, Any_Real);
10715             Analyze_And_Resolve (High, Any_Real);
10716             Check_Real_Bound (Low);
10717             Check_Real_Bound (High);
10718
10719             --  Obtain and set the range
10720
10721             Low_Val  := Expr_Value_R (Low);
10722             High_Val := Expr_Value_R (High);
10723
10724             if Low_Val > High_Val then
10725                Error_Msg_NE ("?fixed point type& has null range", Def, T);
10726             end if;
10727          end;
10728       end if;
10729
10730       --  The range for both the implicit base and the declared first
10731       --  subtype cannot be set yet, so we use the special routine
10732       --  Set_Fixed_Range to set a temporary range in place. Note that
10733       --  the bounds of the base type will be widened to be symmetrical
10734       --  and to fill the available bits when the type is frozen.
10735
10736       --  We could do this with all discrete types, and probably should, but
10737       --  we absolutely have to do it for fixed-point, since the end-points
10738       --  of the range and the size are determined by the small value, which
10739       --  could be reset before the freeze point.
10740
10741       Set_Fixed_Range (Implicit_Base, Loc, Low_Val, High_Val);
10742       Set_Fixed_Range (T, Loc, Low_Val, High_Val);
10743
10744       Init_Size_Align (Implicit_Base);
10745
10746       --  Complete definition of first subtype
10747
10748       Set_Ekind          (T, E_Ordinary_Fixed_Point_Subtype);
10749       Set_Etype          (T, Implicit_Base);
10750       Init_Size_Align    (T);
10751       Set_First_Rep_Item (T, First_Rep_Item (Implicit_Base));
10752       Set_Small_Value    (T, Small_Val);
10753       Set_Delta_Value    (T, Delta_Val);
10754       Set_Is_Constrained (T);
10755
10756    end Ordinary_Fixed_Point_Type_Declaration;
10757
10758    ----------------------------------------
10759    -- Prepare_Private_Subtype_Completion --
10760    ----------------------------------------
10761
10762    procedure Prepare_Private_Subtype_Completion
10763      (Id          : Entity_Id;
10764       Related_Nod : Node_Id)
10765    is
10766       Id_B   : constant Entity_Id := Base_Type (Id);
10767       Full_B : constant Entity_Id := Full_View (Id_B);
10768       Full   : Entity_Id;
10769
10770    begin
10771       if Present (Full_B) then
10772
10773          --  The Base_Type is already completed, we can complete the
10774          --  subtype now. We have to create a new entity with the same name,
10775          --  Thus we can't use Create_Itype.
10776          --  This is messy, should be fixed ???
10777
10778          Full := Make_Defining_Identifier (Sloc (Id), Chars (Id));
10779          Set_Is_Itype (Full);
10780          Set_Associated_Node_For_Itype (Full, Related_Nod);
10781          Complete_Private_Subtype (Id, Full, Full_B, Related_Nod);
10782       end if;
10783
10784       --  The parent subtype may be private, but the base might not, in some
10785       --  nested instances. In that case, the subtype does not need to be
10786       --  exchanged. It would still be nice to make private subtypes and their
10787       --  bases consistent at all times ???
10788
10789       if Is_Private_Type (Id_B) then
10790          Append_Elmt (Id, Private_Dependents (Id_B));
10791       end if;
10792
10793    end Prepare_Private_Subtype_Completion;
10794
10795    ---------------------------
10796    -- Process_Discriminants --
10797    ---------------------------
10798
10799    procedure Process_Discriminants (N : Node_Id) is
10800       Id                  : Node_Id;
10801       Discr               : Node_Id;
10802       Discr_Number        : Uint;
10803       Discr_Type          : Entity_Id;
10804       Default_Present     : Boolean := False;
10805       Default_Not_Present : Boolean := False;
10806       Elist               : Elist_Id := New_Elmt_List;
10807
10808    begin
10809       --  A composite type other than an array type can have discriminants.
10810       --  Discriminants of non-limited types must have a discrete type.
10811       --  On entry, the current scope is the composite type.
10812
10813       --  The discriminants are initially entered into the scope of the type
10814       --  via Enter_Name with the default Ekind of E_Void to prevent premature
10815       --  use, as explained at the end of this procedure.
10816
10817       Discr := First (Discriminant_Specifications (N));
10818       while Present (Discr) loop
10819          Enter_Name (Defining_Identifier (Discr));
10820
10821          if Nkind (Discriminant_Type (Discr)) = N_Access_Definition then
10822             Discr_Type := Access_Definition (N, Discriminant_Type (Discr));
10823
10824          else
10825             Find_Type (Discriminant_Type (Discr));
10826             Discr_Type := Etype (Discriminant_Type (Discr));
10827
10828             if Error_Posted (Discriminant_Type (Discr)) then
10829                Discr_Type := Any_Type;
10830             end if;
10831          end if;
10832
10833          if Is_Access_Type (Discr_Type) then
10834             Check_Access_Discriminant_Requires_Limited
10835               (Discr, Discriminant_Type (Discr));
10836
10837             if Ada_83 and then Comes_From_Source (Discr) then
10838                Error_Msg_N
10839                  ("(Ada 83) access discriminant not allowed", Discr);
10840             end if;
10841
10842          elsif not Is_Discrete_Type (Discr_Type) then
10843             Error_Msg_N ("discriminants must have a discrete or access type",
10844               Discriminant_Type (Discr));
10845          end if;
10846
10847          Set_Etype (Defining_Identifier (Discr), Discr_Type);
10848
10849          --  If a discriminant specification includes the assignment compound
10850          --  delimiter followed by an expression, the expression is the default
10851          --  expression of the discriminant; the default expression must be of
10852          --  the type of the discriminant. (RM 3.7.1) Since this expression is
10853          --  a default expression, we do the special preanalysis, since this
10854          --  expression does not freeze (see "Handling of Default Expressions"
10855          --  in spec of package Sem).
10856
10857          if Present (Expression (Discr)) then
10858             Analyze_Default_Expression (Expression (Discr), Discr_Type);
10859
10860             if Nkind (N) = N_Formal_Type_Declaration then
10861                Error_Msg_N
10862                  ("discriminant defaults not allowed for formal type",
10863                   Expression (Discr));
10864
10865             elsif Is_Tagged_Type (Current_Scope) then
10866                Error_Msg_N
10867                  ("discriminants of tagged type cannot have defaults",
10868                   Expression (Discr));
10869
10870             else
10871                Default_Present := True;
10872                Append_Elmt (Expression (Discr), Elist);
10873
10874                --  Tag the defining identifiers for the discriminants with
10875                --  their corresponding default expressions from the tree.
10876
10877                Set_Discriminant_Default_Value
10878                  (Defining_Identifier (Discr), Expression (Discr));
10879             end if;
10880
10881          else
10882             Default_Not_Present := True;
10883          end if;
10884
10885          Next (Discr);
10886       end loop;
10887
10888       --  An element list consisting of the default expressions of the
10889       --  discriminants is constructed in the above loop and used to set
10890       --  the Discriminant_Constraint attribute for the type. If an object
10891       --  is declared of this (record or task) type without any explicit
10892       --  discriminant constraint given, this element list will form the
10893       --  actual parameters for the corresponding initialization procedure
10894       --  for the type.
10895
10896       Set_Discriminant_Constraint (Current_Scope, Elist);
10897       Set_Girder_Constraint (Current_Scope, No_Elist);
10898
10899       --  Default expressions must be provided either for all or for none
10900       --  of the discriminants of a discriminant part. (RM 3.7.1)
10901
10902       if Default_Present and then Default_Not_Present then
10903          Error_Msg_N
10904            ("incomplete specification of defaults for discriminants", N);
10905       end if;
10906
10907       --  The use of the name of a discriminant is not allowed in default
10908       --  expressions of a discriminant part if the specification of the
10909       --  discriminant is itself given in the discriminant part. (RM 3.7.1)
10910
10911       --  To detect this, the discriminant names are entered initially with an
10912       --  Ekind of E_Void (which is the default Ekind given by Enter_Name). Any
10913       --  attempt to use a void entity (for example in an expression that is
10914       --  type-checked) produces the error message: premature usage. Now after
10915       --  completing the semantic analysis of the discriminant part, we can set
10916       --  the Ekind of all the discriminants appropriately.
10917
10918       Discr := First (Discriminant_Specifications (N));
10919       Discr_Number := Uint_1;
10920
10921       while Present (Discr) loop
10922          Id := Defining_Identifier (Discr);
10923          Set_Ekind (Id, E_Discriminant);
10924          Init_Component_Location (Id);
10925          Init_Esize (Id);
10926          Set_Discriminant_Number (Id, Discr_Number);
10927
10928          --  Make sure this is always set, even in illegal programs
10929
10930          Set_Corresponding_Discriminant (Id, Empty);
10931
10932          --  Initialize the Original_Record_Component to the entity itself.
10933          --  Inherit_Components will propagate the right value to
10934          --  discriminants in derived record types.
10935
10936          Set_Original_Record_Component (Id, Id);
10937
10938          --  Create the discriminal for the discriminant.
10939
10940          Build_Discriminal (Id);
10941
10942          Next (Discr);
10943          Discr_Number := Discr_Number + 1;
10944       end loop;
10945
10946       Set_Has_Discriminants (Current_Scope);
10947    end Process_Discriminants;
10948
10949    -----------------------
10950    -- Process_Full_View --
10951    -----------------------
10952
10953    procedure Process_Full_View (N : Node_Id; Full_T, Priv_T : Entity_Id) is
10954       Priv_Parent : Entity_Id;
10955       Full_Parent : Entity_Id;
10956       Full_Indic  : Node_Id;
10957
10958    begin
10959       --  First some sanity checks that must be done after semantic
10960       --  decoration of the full view and thus cannot be placed with other
10961       --  similar checks in Find_Type_Name
10962
10963       if not Is_Limited_Type (Priv_T)
10964         and then (Is_Limited_Type (Full_T)
10965                    or else Is_Limited_Composite (Full_T))
10966       then
10967          Error_Msg_N
10968            ("completion of nonlimited type cannot be limited", Full_T);
10969
10970       elsif Is_Abstract (Full_T) and then not Is_Abstract (Priv_T) then
10971          Error_Msg_N
10972            ("completion of nonabstract type cannot be abstract", Full_T);
10973
10974       elsif Is_Tagged_Type (Priv_T)
10975         and then Is_Limited_Type (Priv_T)
10976         and then not Is_Limited_Type (Full_T)
10977       then
10978          --  GNAT allow its own definition of Limited_Controlled to disobey
10979          --  this rule in order in ease the implementation. The next test is
10980          --  safe because Root_Controlled is defined in a private system child
10981
10982          if Etype (Full_T) = Full_View (RTE (RE_Root_Controlled)) then
10983             Set_Is_Limited_Composite (Full_T);
10984          else
10985             Error_Msg_N
10986               ("completion of limited tagged type must be limited", Full_T);
10987          end if;
10988
10989       elsif Is_Generic_Type (Priv_T) then
10990          Error_Msg_N ("generic type cannot have a completion", Full_T);
10991       end if;
10992
10993       if Is_Tagged_Type (Priv_T)
10994         and then Nkind (Parent (Priv_T)) = N_Private_Extension_Declaration
10995         and then Is_Derived_Type (Full_T)
10996       then
10997          Priv_Parent := Etype (Priv_T);
10998
10999          --  The full view of a private extension may have been transformed
11000          --  into an unconstrained derived type declaration and a subtype
11001          --  declaration (see build_derived_record_type for details).
11002
11003          if Nkind (N) = N_Subtype_Declaration then
11004             Full_Indic  := Subtype_Indication (N);
11005             Full_Parent := Etype (Base_Type (Full_T));
11006          else
11007             Full_Indic  := Subtype_Indication (Type_Definition (N));
11008             Full_Parent := Etype (Full_T);
11009          end if;
11010
11011          --  Check that the parent type of the full type is a descendant of
11012          --  the ancestor subtype given in the private extension. If either
11013          --  entity has an Etype equal to Any_Type then we had some previous
11014          --  error situation [7.3(8)].
11015
11016          if Priv_Parent = Any_Type or else Full_Parent = Any_Type then
11017             return;
11018
11019          elsif not Is_Ancestor (Base_Type (Priv_Parent), Full_Parent) then
11020             Error_Msg_N
11021               ("parent of full type must descend from parent"
11022                   & " of private extension", Full_Indic);
11023
11024          --  Check the rules of 7.3(10): if the private extension inherits
11025          --  known discriminants, then the full type must also inherit those
11026          --  discriminants from the same (ancestor) type, and the parent
11027          --  subtype of the full type must be constrained if and only if
11028          --  the ancestor subtype of the private extension is constrained.
11029
11030          elsif not Present (Discriminant_Specifications (Parent (Priv_T)))
11031            and then not Has_Unknown_Discriminants (Priv_T)
11032            and then Has_Discriminants (Base_Type (Priv_Parent))
11033          then
11034             declare
11035                Priv_Indic  : constant Node_Id :=
11036                                Subtype_Indication (Parent (Priv_T));
11037
11038                Priv_Constr : constant Boolean :=
11039                                Is_Constrained (Priv_Parent)
11040                                  or else
11041                                    Nkind (Priv_Indic) = N_Subtype_Indication
11042                                  or else Is_Constrained (Entity (Priv_Indic));
11043
11044                Full_Constr : constant Boolean :=
11045                                Is_Constrained (Full_Parent)
11046                                  or else
11047                                    Nkind (Full_Indic) = N_Subtype_Indication
11048                                  or else Is_Constrained (Entity (Full_Indic));
11049
11050                Priv_Discr : Entity_Id;
11051                Full_Discr : Entity_Id;
11052
11053             begin
11054                Priv_Discr := First_Discriminant (Priv_Parent);
11055                Full_Discr := First_Discriminant (Full_Parent);
11056
11057                while Present (Priv_Discr) and then Present (Full_Discr) loop
11058                   if Original_Record_Component (Priv_Discr) =
11059                      Original_Record_Component (Full_Discr)
11060                     or else
11061                      Corresponding_Discriminant (Priv_Discr) =
11062                      Corresponding_Discriminant (Full_Discr)
11063                   then
11064                      null;
11065                   else
11066                      exit;
11067                   end if;
11068
11069                   Next_Discriminant (Priv_Discr);
11070                   Next_Discriminant (Full_Discr);
11071                end loop;
11072
11073                if Present (Priv_Discr) or else Present (Full_Discr) then
11074                   Error_Msg_N
11075                     ("full view must inherit discriminants of the parent type"
11076                      & " used in the private extension", Full_Indic);
11077
11078                elsif Priv_Constr and then not Full_Constr then
11079                   Error_Msg_N
11080                     ("parent subtype of full type must be constrained",
11081                      Full_Indic);
11082
11083                elsif Full_Constr and then not Priv_Constr then
11084                   Error_Msg_N
11085                     ("parent subtype of full type must be unconstrained",
11086                      Full_Indic);
11087                end if;
11088             end;
11089
11090          --  Check the rules of 7.3(12): if a partial view has neither known
11091          --  or unknown discriminants, then the full type declaration shall
11092          --  define a definite subtype.
11093
11094          elsif      not Has_Unknown_Discriminants (Priv_T)
11095            and then not Has_Discriminants (Priv_T)
11096            and then not Is_Constrained (Full_T)
11097          then
11098             Error_Msg_N
11099               ("full view must define a constrained type if partial view"
11100                & " has no discriminants", Full_T);
11101          end if;
11102
11103          --  ??????? Do we implement the following properly ?????
11104          --  If the ancestor subtype of a private extension has constrained
11105          --  discriminants, then the parent subtype of the full view shall
11106          --  impose a statically matching constraint on those discriminants
11107          --  [7.3(13)].
11108
11109       else
11110          --  For untagged types, verify that a type without discriminants
11111          --  is not completed with an unconstrained type.
11112
11113          if not Is_Indefinite_Subtype (Priv_T)
11114            and then Is_Indefinite_Subtype (Full_T)
11115          then
11116             Error_Msg_N ("full view of type must be definite subtype", Full_T);
11117          end if;
11118       end if;
11119
11120       --  Create a full declaration for all its subtypes recorded in
11121       --  Private_Dependents and swap them similarly to the base type.
11122       --  These are subtypes that have been define before the full
11123       --  declaration of the private type. We also swap the entry in
11124       --  Private_Dependents list so we can properly restore the
11125       --  private view on exit from the scope.
11126
11127       declare
11128          Priv_Elmt : Elmt_Id;
11129          Priv      : Entity_Id;
11130          Full      : Entity_Id;
11131
11132       begin
11133          Priv_Elmt := First_Elmt (Private_Dependents (Priv_T));
11134          while Present (Priv_Elmt) loop
11135             Priv := Node (Priv_Elmt);
11136
11137             if Ekind (Priv) = E_Private_Subtype
11138               or else Ekind (Priv) = E_Limited_Private_Subtype
11139               or else Ekind (Priv) = E_Record_Subtype_With_Private
11140             then
11141                Full := Make_Defining_Identifier (Sloc (Priv), Chars (Priv));
11142                Set_Is_Itype (Full);
11143                Set_Parent (Full, Parent (Priv));
11144                Set_Associated_Node_For_Itype (Full, N);
11145
11146                --  Now we need to complete the private subtype, but since the
11147                --  base type has already been swapped, we must also swap the
11148                --  subtypes (and thus, reverse the arguments in the call to
11149                --  Complete_Private_Subtype).
11150
11151                Copy_And_Swap (Priv, Full);
11152                Complete_Private_Subtype (Full, Priv, Full_T, N);
11153                Replace_Elmt (Priv_Elmt, Full);
11154             end if;
11155
11156             Next_Elmt (Priv_Elmt);
11157          end loop;
11158       end;
11159
11160       --  If the private view was tagged, copy the new Primitive
11161       --  operations from the private view to the full view.
11162
11163       if Is_Tagged_Type (Full_T) then
11164          declare
11165             Priv_List : Elist_Id;
11166             Full_List : constant Elist_Id := Primitive_Operations (Full_T);
11167             P1, P2    : Elmt_Id;
11168             Prim      : Entity_Id;
11169             D_Type    : Entity_Id;
11170
11171          begin
11172             if Is_Tagged_Type (Priv_T) then
11173                Priv_List := Primitive_Operations (Priv_T);
11174
11175                P1 := First_Elmt (Priv_List);
11176                while Present (P1) loop
11177                   Prim := Node (P1);
11178
11179                   --  Transfer explicit primitives, not those inherited from
11180                   --  parent of partial view, which will be re-inherited on
11181                   --  the full view.
11182
11183                   if Comes_From_Source (Prim) then
11184                      P2 := First_Elmt (Full_List);
11185                      while Present (P2) and then Node (P2) /= Prim loop
11186                         Next_Elmt (P2);
11187                      end loop;
11188
11189                      --  If not found, that is a new one
11190
11191                      if No (P2) then
11192                         Append_Elmt (Prim, Full_List);
11193                      end if;
11194                   end if;
11195
11196                   Next_Elmt (P1);
11197                end loop;
11198
11199             else
11200                --  In this case the partial view is untagged, so here we
11201                --  locate all of the earlier primitives that need to be
11202                --  treated as dispatching (those that appear between the
11203                --  two views). Note that these additional operations must
11204                --  all be new operations (any earlier operations that
11205                --  override inherited operations of the full view will
11206                --  already have been inserted in the primitives list and
11207                --  marked as dispatching by Check_Operation_From_Private_View.
11208                --  Note that implicit "/=" operators are excluded from being
11209                --  added to the primitives list since they shouldn't be
11210                --  treated as dispatching (tagged "/=" is handled specially).
11211
11212                Prim := Next_Entity (Full_T);
11213                while Present (Prim) and then Prim /= Priv_T loop
11214                   if (Ekind (Prim) = E_Procedure
11215                        or else Ekind (Prim) = E_Function)
11216                   then
11217
11218                      D_Type := Find_Dispatching_Type (Prim);
11219
11220                      if D_Type = Full_T
11221                        and then (Chars (Prim) /= Name_Op_Ne
11222                                   or else Comes_From_Source (Prim))
11223                      then
11224                         Check_Controlling_Formals (Full_T, Prim);
11225
11226                         if not Is_Dispatching_Operation (Prim) then
11227                            Append_Elmt (Prim, Full_List);
11228                            Set_Is_Dispatching_Operation (Prim, True);
11229                            Set_DT_Position (Prim, No_Uint);
11230                         end if;
11231
11232                      elsif Is_Dispatching_Operation (Prim)
11233                        and then D_Type  /= Full_T
11234                      then
11235
11236                         --  Verify that it is not otherwise controlled by
11237                         --  a formal or a return value ot type T.
11238
11239                         Check_Controlling_Formals (D_Type, Prim);
11240                      end if;
11241                   end if;
11242
11243                   Next_Entity (Prim);
11244                end loop;
11245             end if;
11246
11247             --  For the tagged case, the two views can share the same
11248             --  Primitive Operation list and the same class wide type.
11249             --  Update attributes of the class-wide type which depend on
11250             --  the full declaration.
11251
11252             if Is_Tagged_Type (Priv_T) then
11253                Set_Primitive_Operations (Priv_T, Full_List);
11254                Set_Class_Wide_Type
11255                  (Base_Type (Full_T), Class_Wide_Type (Priv_T));
11256
11257                --  Any other attributes should be propagated to C_W ???
11258
11259                Set_Has_Task (Class_Wide_Type (Priv_T), Has_Task (Full_T));
11260
11261             end if;
11262          end;
11263       end if;
11264    end Process_Full_View;
11265
11266    -----------------------------------
11267    -- Process_Incomplete_Dependents --
11268    -----------------------------------
11269
11270    procedure Process_Incomplete_Dependents
11271      (N      : Node_Id;
11272       Full_T : Entity_Id;
11273       Inc_T  : Entity_Id)
11274    is
11275       Inc_Elmt : Elmt_Id;
11276       Priv_Dep : Entity_Id;
11277       New_Subt : Entity_Id;
11278
11279       Disc_Constraint : Elist_Id;
11280
11281    begin
11282       if No (Private_Dependents (Inc_T)) then
11283          return;
11284
11285       else
11286          Inc_Elmt := First_Elmt (Private_Dependents (Inc_T));
11287
11288          --  Itypes that may be generated by the completion of an incomplete
11289          --  subtype are not used by the back-end and not attached to the tree.
11290          --  They are created only for constraint-checking purposes.
11291       end if;
11292
11293       while Present (Inc_Elmt) loop
11294          Priv_Dep := Node (Inc_Elmt);
11295
11296          if Ekind (Priv_Dep) = E_Subprogram_Type then
11297
11298             --  An Access_To_Subprogram type may have a return type or a
11299             --  parameter type that is incomplete. Replace with the full view.
11300
11301             if Etype (Priv_Dep) = Inc_T then
11302                Set_Etype (Priv_Dep, Full_T);
11303             end if;
11304
11305             declare
11306                Formal : Entity_Id;
11307
11308             begin
11309                Formal := First_Formal (Priv_Dep);
11310
11311                while Present (Formal) loop
11312
11313                   if Etype (Formal) = Inc_T then
11314                      Set_Etype (Formal, Full_T);
11315                   end if;
11316
11317                   Next_Formal (Formal);
11318                end loop;
11319             end;
11320
11321          elsif  Is_Overloadable (Priv_Dep) then
11322
11323             if Is_Tagged_Type (Full_T) then
11324
11325                --  Subprogram has an access parameter whose designated type
11326                --  was incomplete. Reexamine declaration now, because it may
11327                --  be a primitive operation of the full type.
11328
11329                Check_Operation_From_Incomplete_Type (Priv_Dep, Inc_T);
11330                Set_Is_Dispatching_Operation (Priv_Dep);
11331                Check_Controlling_Formals (Full_T, Priv_Dep);
11332             end if;
11333
11334          elsif Ekind (Priv_Dep) = E_Subprogram_Body then
11335
11336             --  Can happen during processing of a body before the completion
11337             --  of a TA type. Ignore, because spec is also on dependent list.
11338
11339             return;
11340
11341          --  Dependent is a subtype
11342
11343          else
11344             --  We build a new subtype indication using the full view of the
11345             --  incomplete parent. The discriminant constraints have been
11346             --  elaborated already at the point of the subtype declaration.
11347
11348             New_Subt := Create_Itype (E_Void, N);
11349
11350             if Has_Discriminants (Full_T) then
11351                Disc_Constraint := Discriminant_Constraint (Priv_Dep);
11352             else
11353                Disc_Constraint := No_Elist;
11354             end if;
11355
11356             Build_Discriminated_Subtype (Full_T, New_Subt, Disc_Constraint, N);
11357             Set_Full_View (Priv_Dep, New_Subt);
11358          end if;
11359
11360          Next_Elmt (Inc_Elmt);
11361       end loop;
11362
11363    end Process_Incomplete_Dependents;
11364
11365    --------------------------------
11366    -- Process_Range_Expr_In_Decl --
11367    --------------------------------
11368
11369    procedure Process_Range_Expr_In_Decl
11370      (R           : Node_Id;
11371       T           : Entity_Id;
11372       Related_Nod : Node_Id;
11373       Check_List  : List_Id := Empty_List;
11374       R_Check_Off : Boolean := False)
11375    is
11376       Lo, Hi    : Node_Id;
11377       R_Checks  : Check_Result;
11378       Type_Decl : Node_Id;
11379       Def_Id    : Entity_Id;
11380
11381    begin
11382       Analyze_And_Resolve (R, Base_Type (T));
11383
11384       if Nkind (R) = N_Range then
11385          Lo := Low_Bound (R);
11386          Hi := High_Bound (R);
11387
11388          --  If there were errors in the declaration, try and patch up some
11389          --  common mistakes in the bounds. The cases handled are literals
11390          --  which are Integer where the expected type is Real and vice versa.
11391          --  These corrections allow the compilation process to proceed further
11392          --  along since some basic assumptions of the format of the bounds
11393          --  are guaranteed.
11394
11395          if Etype (R) = Any_Type then
11396
11397             if Nkind (Lo) = N_Integer_Literal and then Is_Real_Type (T) then
11398                Rewrite (Lo,
11399                  Make_Real_Literal (Sloc (Lo), UR_From_Uint (Intval (Lo))));
11400
11401             elsif Nkind (Hi) = N_Integer_Literal and then Is_Real_Type (T) then
11402                Rewrite (Hi,
11403                  Make_Real_Literal (Sloc (Hi), UR_From_Uint (Intval (Hi))));
11404
11405             elsif Nkind (Lo) = N_Real_Literal and then Is_Integer_Type (T) then
11406                Rewrite (Lo,
11407                  Make_Integer_Literal (Sloc (Lo), UR_To_Uint (Realval (Lo))));
11408
11409             elsif Nkind (Hi) = N_Real_Literal and then Is_Integer_Type (T) then
11410                Rewrite (Hi,
11411                  Make_Integer_Literal (Sloc (Hi), UR_To_Uint (Realval (Hi))));
11412             end if;
11413
11414             Set_Etype (Lo, T);
11415             Set_Etype (Hi, T);
11416          end if;
11417
11418          --  If the bounds of the range have been mistakenly given as
11419          --  string literals (perhaps in place of character literals),
11420          --  then an error has already been reported, but we rewrite
11421          --  the string literal as a bound of the range's type to
11422          --  avoid blowups in later processing that looks at static
11423          --  values.
11424
11425          if Nkind (Lo) = N_String_Literal then
11426             Rewrite (Lo,
11427               Make_Attribute_Reference (Sloc (Lo),
11428                 Attribute_Name => Name_First,
11429                 Prefix => New_Reference_To (T, Sloc (Lo))));
11430             Analyze_And_Resolve (Lo);
11431          end if;
11432
11433          if Nkind (Hi) = N_String_Literal then
11434             Rewrite (Hi,
11435               Make_Attribute_Reference (Sloc (Hi),
11436                 Attribute_Name => Name_First,
11437                 Prefix => New_Reference_To (T, Sloc (Hi))));
11438             Analyze_And_Resolve (Hi);
11439          end if;
11440
11441          --  If bounds aren't scalar at this point then exit, avoiding
11442          --  problems with further processing of the range in this procedure.
11443
11444          if not Is_Scalar_Type (Etype (Lo)) then
11445             return;
11446          end if;
11447
11448          --  Resolve (actually Sem_Eval) has checked that the bounds are in
11449          --  then range of the base type. Here we check whether the bounds
11450          --  are in the range of the subtype itself. Note that if the bounds
11451          --  represent the null range the Constraint_Error exception should
11452          --  not be raised.
11453
11454          --  ??? The following code should be cleaned up as follows
11455          --  1. The Is_Null_Range (Lo, Hi) test should disapper since it
11456          --     is done in the call to Range_Check (R, T); below
11457          --  2. The use of R_Check_Off should be investigated and possibly
11458          --     removed, this would clean up things a bit.
11459
11460          if Is_Null_Range (Lo, Hi) then
11461             null;
11462
11463          else
11464             --  We use a flag here instead of suppressing checks on the
11465             --  type because the type we check against isn't necessarily the
11466             --  place where we put the check.
11467
11468             if not R_Check_Off then
11469                R_Checks := Range_Check (R, T);
11470                Type_Decl := Parent (R);
11471
11472                --  Look up tree to find an appropriate insertion point.
11473                --  This seems really junk code, and very brittle, couldn't
11474                --  we just use an insert actions call of some kind ???
11475
11476                while Present (Type_Decl) and then not
11477                  (Nkind (Type_Decl) = N_Full_Type_Declaration
11478                     or else
11479                   Nkind (Type_Decl) = N_Subtype_Declaration
11480                     or else
11481                   Nkind (Type_Decl) = N_Loop_Statement
11482                     or else
11483                   Nkind (Type_Decl) = N_Task_Type_Declaration
11484                     or else
11485                   Nkind (Type_Decl) = N_Single_Task_Declaration
11486                     or else
11487                   Nkind (Type_Decl) = N_Protected_Type_Declaration
11488                     or else
11489                   Nkind (Type_Decl) = N_Single_Protected_Declaration)
11490                loop
11491                   Type_Decl := Parent (Type_Decl);
11492                end loop;
11493
11494                --  Why would Type_Decl not be present???  Without this test,
11495                --  short regression tests fail.
11496
11497                if Present (Type_Decl) then
11498                   if Nkind (Type_Decl) = N_Loop_Statement then
11499                      declare
11500                         Indic : Node_Id := Parent (R);
11501                      begin
11502                         while Present (Indic) and then not
11503                           (Nkind (Indic) = N_Subtype_Indication)
11504                         loop
11505                            Indic := Parent (Indic);
11506                         end loop;
11507
11508                         if Present (Indic) then
11509                            Def_Id := Etype (Subtype_Mark (Indic));
11510
11511                            Insert_Range_Checks
11512                              (R_Checks,
11513                               Type_Decl,
11514                               Def_Id,
11515                               Sloc (Type_Decl),
11516                               R,
11517                               Do_Before => True);
11518                         end if;
11519                      end;
11520                   else
11521                      Def_Id := Defining_Identifier (Type_Decl);
11522
11523                      if (Ekind (Def_Id) = E_Record_Type
11524                           and then Depends_On_Discriminant (R))
11525                        or else
11526                         (Ekind (Def_Id) = E_Protected_Type
11527                           and then Has_Discriminants (Def_Id))
11528                      then
11529                         Append_Range_Checks
11530                           (R_Checks, Check_List, Def_Id, Sloc (Type_Decl), R);
11531
11532                      else
11533                         Insert_Range_Checks
11534                           (R_Checks, Type_Decl, Def_Id, Sloc (Type_Decl), R);
11535
11536                      end if;
11537                   end if;
11538                end if;
11539             end if;
11540          end if;
11541       end if;
11542
11543       Get_Index_Bounds (R, Lo, Hi);
11544
11545       if Expander_Active then
11546          Force_Evaluation (Lo);
11547          Force_Evaluation (Hi);
11548       end if;
11549
11550    end Process_Range_Expr_In_Decl;
11551
11552    --------------------------------------
11553    -- Process_Real_Range_Specification --
11554    --------------------------------------
11555
11556    procedure Process_Real_Range_Specification (Def : Node_Id) is
11557       Spec : constant Node_Id := Real_Range_Specification (Def);
11558       Lo   : Node_Id;
11559       Hi   : Node_Id;
11560       Err  : Boolean := False;
11561
11562       procedure Analyze_Bound (N : Node_Id);
11563       --  Analyze and check one bound
11564
11565       procedure Analyze_Bound (N : Node_Id) is
11566       begin
11567          Analyze_And_Resolve (N, Any_Real);
11568
11569          if not Is_OK_Static_Expression (N) then
11570             Error_Msg_N
11571               ("bound in real type definition is not static", N);
11572             Err := True;
11573          end if;
11574       end Analyze_Bound;
11575
11576    begin
11577       if Present (Spec) then
11578          Lo := Low_Bound (Spec);
11579          Hi := High_Bound (Spec);
11580          Analyze_Bound (Lo);
11581          Analyze_Bound (Hi);
11582
11583          --  If error, clear away junk range specification
11584
11585          if Err then
11586             Set_Real_Range_Specification (Def, Empty);
11587          end if;
11588       end if;
11589    end Process_Real_Range_Specification;
11590
11591    ---------------------
11592    -- Process_Subtype --
11593    ---------------------
11594
11595    function Process_Subtype
11596      (S           : Node_Id;
11597       Related_Nod : Node_Id;
11598       Related_Id  : Entity_Id := Empty;
11599       Suffix      : Character := ' ')
11600       return        Entity_Id
11601    is
11602       P               : Node_Id;
11603       Def_Id          : Entity_Id;
11604       Full_View_Id    : Entity_Id;
11605       Subtype_Mark_Id : Entity_Id;
11606       N_Dynamic_Ityp  : Node_Id := Empty;
11607
11608    begin
11609       --  Case of constraint present, so that we have an N_Subtype_Indication
11610       --  node (this node is created only if constraints are present).
11611
11612       if Nkind (S) = N_Subtype_Indication then
11613          Find_Type (Subtype_Mark (S));
11614
11615          if Nkind (Parent (S)) /= N_Access_To_Object_Definition
11616            and then not
11617             (Nkind (Parent (S)) = N_Subtype_Declaration
11618               and then
11619              Is_Itype (Defining_Identifier (Parent (S))))
11620          then
11621             Check_Incomplete (Subtype_Mark (S));
11622          end if;
11623
11624          P := Parent (S);
11625          Subtype_Mark_Id := Entity (Subtype_Mark (S));
11626
11627          if Is_Unchecked_Union (Subtype_Mark_Id)
11628            and then Comes_From_Source (Related_Nod)
11629          then
11630             Error_Msg_N
11631               ("cannot create subtype of Unchecked_Union", Related_Nod);
11632          end if;
11633
11634          --  Explicit subtype declaration case
11635
11636          if Nkind (P) = N_Subtype_Declaration then
11637             Def_Id := Defining_Identifier (P);
11638
11639          --  Explicit derived type definition case
11640
11641          elsif Nkind (P) = N_Derived_Type_Definition then
11642             Def_Id := Defining_Identifier (Parent (P));
11643
11644          --  Implicit case, the Def_Id must be created as an implicit type.
11645          --  The one exception arises in the case of concurrent types,
11646          --  array and access types, where other subsidiary implicit types
11647          --  may be created and must appear before the main implicit type.
11648          --  In these cases we leave Def_Id set to Empty as a signal that
11649          --  Create_Itype has not yet been called to create Def_Id.
11650
11651          else
11652             if Is_Array_Type (Subtype_Mark_Id)
11653               or else Is_Concurrent_Type (Subtype_Mark_Id)
11654               or else Is_Access_Type (Subtype_Mark_Id)
11655             then
11656                Def_Id := Empty;
11657
11658             --  For the other cases, we create a new unattached Itype,
11659             --  and set the indication to ensure it gets attached later.
11660
11661             else
11662                Def_Id :=
11663                  Create_Itype (E_Void, Related_Nod, Related_Id, Suffix);
11664             end if;
11665
11666             N_Dynamic_Ityp := Related_Nod;
11667          end if;
11668
11669          --  If the kind of constraint is invalid for this kind of type,
11670          --  then give an error, and then pretend no constraint was given.
11671
11672          if not Is_Valid_Constraint_Kind
11673                    (Ekind (Subtype_Mark_Id), Nkind (Constraint (S)))
11674          then
11675             Error_Msg_N
11676               ("incorrect constraint for this kind of type", Constraint (S));
11677
11678             Rewrite (S, New_Copy_Tree (Subtype_Mark (S)));
11679
11680             --  Make recursive call, having got rid of the bogus constraint
11681
11682             return Process_Subtype (S, Related_Nod, Related_Id, Suffix);
11683          end if;
11684
11685          --  Remaining processing depends on type
11686
11687          case Ekind (Subtype_Mark_Id) is
11688
11689             when Access_Kind =>
11690                Constrain_Access (Def_Id, S, Related_Nod);
11691
11692             when Array_Kind =>
11693                Constrain_Array (Def_Id, S, Related_Nod, Related_Id, Suffix);
11694
11695             when Decimal_Fixed_Point_Kind =>
11696                Constrain_Decimal (Def_Id, S, N_Dynamic_Ityp);
11697
11698             when Enumeration_Kind =>
11699                Constrain_Enumeration (Def_Id, S, N_Dynamic_Ityp);
11700
11701             when Ordinary_Fixed_Point_Kind =>
11702                Constrain_Ordinary_Fixed (Def_Id, S, N_Dynamic_Ityp);
11703
11704             when Float_Kind =>
11705                Constrain_Float (Def_Id, S, N_Dynamic_Ityp);
11706
11707             when Integer_Kind =>
11708                Constrain_Integer (Def_Id, S, N_Dynamic_Ityp);
11709
11710             when E_Record_Type     |
11711                  E_Record_Subtype  |
11712                  Class_Wide_Kind   |
11713                  E_Incomplete_Type =>
11714                Constrain_Discriminated_Type (Def_Id, S, Related_Nod);
11715
11716             when Private_Kind =>
11717                Constrain_Discriminated_Type (Def_Id, S, Related_Nod);
11718                Set_Private_Dependents (Def_Id, New_Elmt_List);
11719
11720                --  In case of an invalid constraint prevent further processing
11721                --  since the type constructed is missing expected fields.
11722
11723                if Etype (Def_Id) = Any_Type then
11724                   return Def_Id;
11725                end if;
11726
11727                --  If the full view is that of a task with discriminants,
11728                --  we must constrain both the concurrent type and its
11729                --  corresponding record type. Otherwise we will just propagate
11730                --  the constraint to the full view, if available.
11731
11732                if Present (Full_View (Subtype_Mark_Id))
11733                  and then Has_Discriminants (Subtype_Mark_Id)
11734                  and then Is_Concurrent_Type (Full_View (Subtype_Mark_Id))
11735                then
11736                   Full_View_Id :=
11737                     Create_Itype (E_Void, Related_Nod, Related_Id, Suffix);
11738
11739                   Set_Entity (Subtype_Mark (S), Full_View (Subtype_Mark_Id));
11740                   Constrain_Concurrent (Full_View_Id, S,
11741                     Related_Nod, Related_Id, Suffix);
11742                   Set_Entity (Subtype_Mark (S), Subtype_Mark_Id);
11743                   Set_Full_View (Def_Id, Full_View_Id);
11744
11745                else
11746                   Prepare_Private_Subtype_Completion (Def_Id, Related_Nod);
11747                end if;
11748
11749             when Concurrent_Kind  =>
11750                Constrain_Concurrent (Def_Id, S,
11751                  Related_Nod, Related_Id, Suffix);
11752
11753             when others =>
11754                Error_Msg_N ("invalid subtype mark in subtype indication", S);
11755          end case;
11756
11757          --  Size and Convention are always inherited from the base type
11758
11759          Set_Size_Info  (Def_Id,            (Subtype_Mark_Id));
11760          Set_Convention (Def_Id, Convention (Subtype_Mark_Id));
11761
11762          return Def_Id;
11763
11764       --  Case of no constraints present
11765
11766       else
11767          Find_Type (S);
11768          Check_Incomplete (S);
11769          return Entity (S);
11770       end if;
11771    end Process_Subtype;
11772
11773    -----------------------------
11774    -- Record_Type_Declaration --
11775    -----------------------------
11776
11777    procedure Record_Type_Declaration (T : Entity_Id; N : Node_Id) is
11778       Def : constant Node_Id := Type_Definition (N);
11779       Range_Checks_Suppressed_Flag : Boolean := False;
11780
11781       Is_Tagged : Boolean;
11782       Tag_Comp  : Entity_Id;
11783
11784    begin
11785       --  The flag Is_Tagged_Type might have already been set by Find_Type_Name
11786       --  if it detected an error for declaration T. This arises in the case of
11787       --  private tagged types where the full view omits the word tagged.
11788
11789       Is_Tagged := Tagged_Present (Def)
11790         or else (Errors_Detected > 0 and then Is_Tagged_Type (T));
11791
11792       --  Records constitute a scope for the component declarations within.
11793       --  The scope is created prior to the processing of these declarations.
11794       --  Discriminants are processed first, so that they are visible when
11795       --  processing the other components. The Ekind of the record type itself
11796       --  is set to E_Record_Type (subtypes appear as E_Record_Subtype).
11797
11798       --  Enter record scope
11799
11800       New_Scope (T);
11801
11802       --  These flags must be initialized before calling Process_Discriminants
11803       --  because this routine makes use of them.
11804
11805       Set_Is_Tagged_Type     (T, Is_Tagged);
11806       Set_Is_Limited_Record  (T, Limited_Present (Def));
11807
11808       --  Type is abstract if full declaration carries keyword, or if
11809       --  previous partial view did.
11810
11811       Set_Is_Abstract (T, Is_Abstract (T) or else Abstract_Present (Def));
11812
11813       Set_Ekind       (T, E_Record_Type);
11814       Set_Etype       (T, T);
11815       Init_Size_Align (T);
11816
11817       Set_Girder_Constraint (T, No_Elist);
11818
11819       --  If an incomplete or private type declaration was already given for
11820       --  the type, then this scope already exists, and the discriminants have
11821       --  been declared within. We must verify that the full declaration
11822       --  matches the incomplete one.
11823
11824       Check_Or_Process_Discriminants (N, T);
11825
11826       Set_Is_Constrained     (T, not Has_Discriminants (T));
11827       Set_Has_Delayed_Freeze (T, True);
11828
11829       --  For tagged types add a manually analyzed component corresponding
11830       --  to the component _tag, the corresponding piece of tree will be
11831       --  expanded as part of the freezing actions if it is not a CPP_Class.
11832
11833       if Is_Tagged then
11834          --  Do not add the tag unless we are in expansion mode.
11835
11836          if Expander_Active then
11837             Tag_Comp := Make_Defining_Identifier (Sloc (Def), Name_uTag);
11838             Enter_Name (Tag_Comp);
11839
11840             Set_Is_Tag                    (Tag_Comp);
11841             Set_Ekind                     (Tag_Comp, E_Component);
11842             Set_Etype                     (Tag_Comp, RTE (RE_Tag));
11843             Set_DT_Entry_Count            (Tag_Comp, No_Uint);
11844             Set_Original_Record_Component (Tag_Comp, Tag_Comp);
11845             Init_Component_Location       (Tag_Comp);
11846          end if;
11847
11848          Make_Class_Wide_Type (T);
11849          Set_Primitive_Operations (T, New_Elmt_List);
11850       end if;
11851
11852       --  We must suppress range checks when processing the components
11853       --  of a record in the presence of discriminants, since we don't
11854       --  want spurious checks to be generated during their analysis, but
11855       --  must reset the Suppress_Range_Checks flags after having procesed
11856       --  the record definition.
11857
11858       if Has_Discriminants (T) and then not Suppress_Range_Checks (T) then
11859          Set_Suppress_Range_Checks (T, True);
11860          Range_Checks_Suppressed_Flag := True;
11861       end if;
11862
11863       Record_Type_Definition (Def, T);
11864
11865       if Range_Checks_Suppressed_Flag then
11866          Set_Suppress_Range_Checks (T, False);
11867          Range_Checks_Suppressed_Flag := False;
11868       end if;
11869
11870       --  Exit from record scope
11871
11872       End_Scope;
11873    end Record_Type_Declaration;
11874
11875    ----------------------------
11876    -- Record_Type_Definition --
11877    ----------------------------
11878
11879    procedure Record_Type_Definition (Def : Node_Id; T : Entity_Id) is
11880       Component          : Entity_Id;
11881       Ctrl_Components    : Boolean := False;
11882       Final_Storage_Only : Boolean := not Is_Controlled (T);
11883
11884    begin
11885       --  If the component list of a record type is defined by the reserved
11886       --  word null and there is no discriminant part, then the record type has
11887       --  no components and all records of the type are null records (RM 3.7)
11888       --  This procedure is also called to process the extension part of a
11889       --  record extension, in which case the current scope may have inherited
11890       --  components.
11891
11892       if No (Def)
11893         or else No (Component_List (Def))
11894         or else Null_Present (Component_List (Def))
11895       then
11896          null;
11897
11898       else
11899          Analyze_Declarations (Component_Items (Component_List (Def)));
11900
11901          if Present (Variant_Part (Component_List (Def))) then
11902             Analyze (Variant_Part (Component_List (Def)));
11903          end if;
11904       end if;
11905
11906       --  After completing the semantic analysis of the record definition,
11907       --  record components, both new and inherited, are accessible. Set
11908       --  their kind accordingly.
11909
11910       Component := First_Entity (Current_Scope);
11911       while Present (Component) loop
11912
11913          if Ekind (Component) = E_Void then
11914             Set_Ekind (Component, E_Component);
11915             Init_Component_Location (Component);
11916          end if;
11917
11918          if Has_Task (Etype (Component)) then
11919             Set_Has_Task (T);
11920          end if;
11921
11922          if Ekind (Component) /= E_Component then
11923             null;
11924
11925          elsif Has_Controlled_Component (Etype (Component))
11926            or else (Chars (Component) /= Name_uParent
11927                     and then Is_Controlled (Etype (Component)))
11928          then
11929             Set_Has_Controlled_Component (T, True);
11930             Final_Storage_Only := Final_Storage_Only
11931               and then Finalize_Storage_Only (Etype (Component));
11932             Ctrl_Components := True;
11933          end if;
11934
11935          Next_Entity (Component);
11936       end loop;
11937
11938       --  A type is Finalize_Storage_Only only if all its controlled
11939       --  components are so.
11940
11941       if Ctrl_Components then
11942          Set_Finalize_Storage_Only (T, Final_Storage_Only);
11943       end if;
11944
11945       if Present (Def) then
11946          Process_End_Label (Def, 'e');
11947       end if;
11948    end Record_Type_Definition;
11949
11950    ---------------------
11951    -- Set_Fixed_Range --
11952    ---------------------
11953
11954    --  The range for fixed-point types is complicated by the fact that we
11955    --  do not know the exact end points at the time of the declaration. This
11956    --  is true for three reasons:
11957
11958    --     A size clause may affect the fudging of the end-points
11959    --     A small clause may affect the values of the end-points
11960    --     We try to include the end-points if it does not affect the size
11961
11962    --  This means that the actual end-points must be established at the
11963    --  point when the type is frozen. Meanwhile, we first narrow the range
11964    --  as permitted (so that it will fit if necessary in a small specified
11965    --  size), and then build a range subtree with these narrowed bounds.
11966
11967    --  Set_Fixed_Range constructs the range from real literal values, and
11968    --  sets the range as the Scalar_Range of the given fixed-point type
11969    --  entity.
11970
11971    --  The parent of this range is set to point to the entity so that it
11972    --  is properly hooked into the tree (unlike normal Scalar_Range entries
11973    --  for other scalar types, which are just pointers to the range in the
11974    --  original tree, this would otherwise be an orphan).
11975
11976    --  The tree is left unanalyzed. When the type is frozen, the processing
11977    --  in Freeze.Freeze_Fixed_Point_Type notices that the range is not
11978    --  analyzed, and uses this as an indication that it should complete
11979    --  work on the range (it will know the final small and size values).
11980
11981    procedure Set_Fixed_Range
11982      (E   : Entity_Id;
11983       Loc : Source_Ptr;
11984       Lo  : Ureal;
11985       Hi  : Ureal)
11986    is
11987       S : constant Node_Id :=
11988             Make_Range (Loc,
11989               Low_Bound  => Make_Real_Literal (Loc, Lo),
11990               High_Bound => Make_Real_Literal (Loc, Hi));
11991
11992    begin
11993       Set_Scalar_Range (E, S);
11994       Set_Parent (S, E);
11995    end Set_Fixed_Range;
11996
11997    --------------------------------------------------------
11998    -- Set_Girder_Constraint_From_Discriminant_Constraint --
11999    --------------------------------------------------------
12000
12001    procedure Set_Girder_Constraint_From_Discriminant_Constraint
12002      (E : Entity_Id)
12003    is
12004    begin
12005       --  Make sure set if encountered during
12006       --  Expand_To_Girder_Constraint
12007
12008       Set_Girder_Constraint (E, No_Elist);
12009
12010       --  Give it the right value
12011
12012       if Is_Constrained (E) and then Has_Discriminants (E) then
12013          Set_Girder_Constraint (E,
12014            Expand_To_Girder_Constraint (E, Discriminant_Constraint (E)));
12015       end if;
12016
12017    end Set_Girder_Constraint_From_Discriminant_Constraint;
12018
12019    ----------------------------------
12020    -- Set_Scalar_Range_For_Subtype --
12021    ----------------------------------
12022
12023    procedure Set_Scalar_Range_For_Subtype
12024      (Def_Id      : Entity_Id;
12025       R           : Node_Id;
12026       Subt        : Entity_Id;
12027       Related_Nod : Node_Id)
12028    is
12029       Kind : constant Entity_Kind :=  Ekind (Def_Id);
12030    begin
12031       Set_Scalar_Range (Def_Id, R);
12032
12033       --  We need to link the range into the tree before resolving it so
12034       --  that types that are referenced, including importantly the subtype
12035       --  itself, are properly frozen (Freeze_Expression requires that the
12036       --  expression be properly linked into the tree). Of course if it is
12037       --  already linked in, then we do not disturb the current link.
12038
12039       if No (Parent (R)) then
12040          Set_Parent (R, Def_Id);
12041       end if;
12042
12043       --  Reset the kind of the subtype during analysis of the range, to
12044       --  catch possible premature use in the bounds themselves.
12045
12046       Set_Ekind (Def_Id, E_Void);
12047       Process_Range_Expr_In_Decl (R, Subt, Related_Nod);
12048       Set_Ekind (Def_Id, Kind);
12049
12050    end Set_Scalar_Range_For_Subtype;
12051
12052    -------------------------------------
12053    -- Signed_Integer_Type_Declaration --
12054    -------------------------------------
12055
12056    procedure Signed_Integer_Type_Declaration (T : Entity_Id; Def : Node_Id) is
12057       Implicit_Base : Entity_Id;
12058       Base_Typ      : Entity_Id;
12059       Lo_Val        : Uint;
12060       Hi_Val        : Uint;
12061       Errs          : Boolean := False;
12062       Lo            : Node_Id;
12063       Hi            : Node_Id;
12064
12065       function Can_Derive_From (E : Entity_Id) return Boolean;
12066       --  Determine whether given bounds allow derivation from specified type
12067
12068       procedure Check_Bound (Expr : Node_Id);
12069       --  Check bound to make sure it is integral and static. If not, post
12070       --  appropriate error message and set Errs flag
12071
12072       function Can_Derive_From (E : Entity_Id) return Boolean is
12073          Lo : constant Uint := Expr_Value (Type_Low_Bound (E));
12074          Hi : constant Uint := Expr_Value (Type_High_Bound (E));
12075
12076       begin
12077          --  Note we check both bounds against both end values, to deal with
12078          --  strange types like ones with a range of 0 .. -12341234.
12079
12080          return Lo <= Lo_Val and then Lo_Val <= Hi
12081                   and then
12082                 Lo <= Hi_Val and then Hi_Val <= Hi;
12083       end Can_Derive_From;
12084
12085       procedure Check_Bound (Expr : Node_Id) is
12086       begin
12087          --  If a range constraint is used as an integer type definition, each
12088          --  bound of the range must be defined by a static expression of some
12089          --  integer type, but the two bounds need not have the same integer
12090          --  type (Negative bounds are allowed.) (RM 3.5.4)
12091
12092          if not Is_Integer_Type (Etype (Expr)) then
12093             Error_Msg_N
12094               ("integer type definition bounds must be of integer type", Expr);
12095             Errs := True;
12096
12097          elsif not Is_OK_Static_Expression (Expr) then
12098             Error_Msg_N
12099               ("non-static expression used for integer type bound", Expr);
12100             Errs := True;
12101
12102          --  The bounds are folded into literals, and we set their type to be
12103          --  universal, to avoid typing difficulties: we cannot set the type
12104          --  of the literal to the new type, because this would be a forward
12105          --  reference for the back end,  and if the original type is user-
12106          --  defined this can lead to spurious semantic errors (e.g. 2928-003).
12107
12108          else
12109             if Is_Entity_Name (Expr) then
12110                Fold_Uint (Expr, Expr_Value (Expr));
12111             end if;
12112
12113             Set_Etype (Expr, Universal_Integer);
12114          end if;
12115       end Check_Bound;
12116
12117    --  Start of processing for Signed_Integer_Type_Declaration
12118
12119    begin
12120       --  Create an anonymous base type
12121
12122       Implicit_Base :=
12123         Create_Itype (E_Signed_Integer_Type, Parent (Def), T, 'B');
12124
12125       --  Analyze and check the bounds, they can be of any integer type
12126
12127       Lo := Low_Bound (Def);
12128       Hi := High_Bound (Def);
12129
12130       --  Arbitrarily use Integer as the type if either bound had an error
12131
12132       if Hi = Error or else Lo = Error then
12133          Base_Typ := Any_Integer;
12134          Set_Error_Posted (T, True);
12135
12136       --  Here both bounds are OK expressions
12137
12138       else
12139          Analyze_And_Resolve (Lo, Any_Integer);
12140          Analyze_And_Resolve (Hi, Any_Integer);
12141
12142          Check_Bound (Lo);
12143          Check_Bound (Hi);
12144
12145          if Errs then
12146             Hi := Type_High_Bound (Standard_Long_Long_Integer);
12147             Lo := Type_Low_Bound (Standard_Long_Long_Integer);
12148          end if;
12149
12150          --  Find type to derive from
12151
12152          Lo_Val := Expr_Value (Lo);
12153          Hi_Val := Expr_Value (Hi);
12154
12155          if Can_Derive_From (Standard_Short_Short_Integer) then
12156             Base_Typ := Base_Type (Standard_Short_Short_Integer);
12157
12158          elsif Can_Derive_From (Standard_Short_Integer) then
12159             Base_Typ := Base_Type (Standard_Short_Integer);
12160
12161          elsif Can_Derive_From (Standard_Integer) then
12162             Base_Typ := Base_Type (Standard_Integer);
12163
12164          elsif Can_Derive_From (Standard_Long_Integer) then
12165             Base_Typ := Base_Type (Standard_Long_Integer);
12166
12167          elsif Can_Derive_From (Standard_Long_Long_Integer) then
12168             Base_Typ := Base_Type (Standard_Long_Long_Integer);
12169
12170          else
12171             Base_Typ := Base_Type (Standard_Long_Long_Integer);
12172             Error_Msg_N ("integer type definition bounds out of range", Def);
12173             Hi := Type_High_Bound (Standard_Long_Long_Integer);
12174             Lo := Type_Low_Bound (Standard_Long_Long_Integer);
12175          end if;
12176       end if;
12177
12178       --  Complete both implicit base and declared first subtype entities
12179
12180       Set_Etype          (Implicit_Base, Base_Typ);
12181       Set_Scalar_Range   (Implicit_Base, Scalar_Range   (Base_Typ));
12182       Set_Size_Info      (Implicit_Base,                (Base_Typ));
12183       Set_RM_Size        (Implicit_Base, RM_Size        (Base_Typ));
12184       Set_First_Rep_Item (Implicit_Base, First_Rep_Item (Base_Typ));
12185
12186       Set_Ekind          (T, E_Signed_Integer_Subtype);
12187       Set_Etype          (T, Implicit_Base);
12188
12189       Set_Size_Info      (T,                (Implicit_Base));
12190       Set_First_Rep_Item (T, First_Rep_Item (Implicit_Base));
12191       Set_Scalar_Range   (T, Def);
12192       Set_RM_Size        (T, UI_From_Int (Minimum_Size (T)));
12193       Set_Is_Constrained (T);
12194
12195    end Signed_Integer_Type_Declaration;
12196
12197 end Sem_Ch3;