gcc/ada/s-wchcnv.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       S Y S T E M . W C H _ C N V                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This unit may be used directly from an application program by providing
  35 --  an appropriate WITH, and the interface can be expected to remain stable.
  36
  37 with System.WCh_Con;
  38
  39 package System.WCh_Cnv is
  40    pragma Pure;
  41
  42    type UTF_32_Code is range 0 .. 16#7FFF_FFFF#;
  43    for UTF_32_Code'Size use 32;
  44    --  Range of allowed UTF-32 encoding values
  45
  46    generic
  47       with function In_Char return Character;
  48    function Char_Sequence_To_Wide_Char
  49      (C  : Character;
  50       EM : System.WCh_Con.WC_Encoding_Method) return Wide_Character;
  51    --  C is the first character of a sequence of one or more characters which
  52    --  represent a wide character sequence. Calling the function In_Char for
  53    --  additional characters as required, Char_To_Wide_Char returns the
  54    --  corresponding wide character value. Constraint_Error is raised if the
  55    --  sequence of characters encountered is not a valid wide character
  56    --  sequence for the given encoding method.
  57
  58    generic
  59       with function In_Char return Character;
  60    function Char_Sequence_To_UTF_32
  61      (C  : Character;
  62       EM : System.WCh_Con.WC_Encoding_Method) return UTF_32_Code;
  63    --  This is similar to the above, but the function returns a code from
  64    --  the full UTF_32 code set, which covers the full range of possible
  65    --  values in Wide_Wide_Character. The result can be converted to
  66    --  Wide_Wide_Character form using Wide_Wide_Character'Val.
  67
  68    generic
  69       with procedure Out_Char (C : Character);
  70    procedure Wide_Char_To_Char_Sequence
  71      (WC : Wide_Character;
  72       EM : System.WCh_Con.WC_Encoding_Method);
  73    --  Given a wide character, converts it into a sequence of one or
  74    --  more characters, calling the given Out_Char procedure for each.
  75    --  Constraint_Error is raised if the given wide character value is
  76    --  not a valid value for the given encoding method.
  77
  78    generic
  79       with procedure Out_Char (C : Character);
  80    procedure UTF_32_To_Char_Sequence
  81      (Val : UTF_32_Code;
  82       EM  : System.WCh_Con.WC_Encoding_Method);
  83    --  This is similar to the above, but the input value is a code from the
  84    --  full UTF_32 code set, which covers the full range of possible values
  85    --  in Wide_Wide_Character. To convert a Wide_Wide_Character value, the
  86    --  caller can use Wide_Wide_Character'Pos in the call.
  87
  88 end System.WCh_Cnv;