gcc/ada/s-valwch.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                     S Y S T E M . V A L _ W C H A R                      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Interfaces;      use Interfaces;
  35 with System.Val_Util; use System.Val_Util;
  36 with System.WCh_Con;  use System.WCh_Con;
  37 with System.WCh_StW;  use System.WCh_StW;
  38
  39 package body System.Val_WChar is
  40
  41    --------------------------
  42    -- Value_Wide_Character --
  43    --------------------------
  44
  45    function Value_Wide_Character
  46       (Str : String;
  47        EM  : WC_Encoding_Method) return Wide_Character
  48    is
  49       WWC : constant Wide_Wide_Character :=
  50               Value_Wide_Wide_Character (Str, EM);
  51       WWV : constant Unsigned_32 := Wide_Wide_Character'Pos (WWC);
  52    begin
  53       if WWV > 16#FFFF# then
  54          raise Constraint_Error;
  55       else
  56          return Wide_Character'Val (WWV);
  57       end if;
  58    end Value_Wide_Character;
  59
  60    -------------------------------
  61    -- Value_Wide_Wide_Character --
  62    -------------------------------
  63
  64    function Value_Wide_Wide_Character
  65       (Str : String;
  66        EM  : System.WCh_Con.WC_Encoding_Method) return Wide_Wide_Character
  67    is
  68       F : Natural;
  69       L : Natural;
  70       S : String (Str'Range) := Str;
  71
  72    begin
  73       Normalize_String (S, F, L);
  74
  75       --  Character literal case
  76
  77       if S (F) = ''' and then S (L) = ''' then
  78
  79          --  If just three characters, simple character case
  80
  81          if L - F = 2 then
  82             return Wide_Wide_Character'Val (Character'Pos (S (F + 1)));
  83
  84          --  Otherwise must be a wide character in quotes. The easiest
  85          --  thing is to convert the string to a wide wide string and then
  86          --  pick up the single character that it should contain.
  87
  88          else
  89             declare
  90                WS : constant Wide_Wide_String :=
  91                       String_To_Wide_Wide_String (S (F + 1 .. L - 1), EM);
  92
  93             begin
  94                if WS'Length /= 1 then
  95                   raise Constraint_Error;
  96                else
  97                   return WS (WS'First);
  98                end if;
  99             end;
 100          end if;
 101
 102       --  the last two values of the type have language-defined names:
 103
 104       elsif S = "FFFE" then
 105          return Wide_Wide_Character'Val (16#FFFE#);
 106
 107       elsif S = "FFFF" then
 108          return Wide_Wide_Character'Val (16#FFFF#);
 109
 110       --  Otherwise must be a control character
 111
 112       else
 113          for C in Character'Val (16#00#) .. Character'Val (16#1F#) loop
 114             if S (F .. L) = Character'Image (C) then
 115                return Wide_Wide_Character'Val (Character'Pos (C));
 116             end if;
 117          end loop;
 118
 119          for C in Character'Val (16#7F#) .. Character'Val (16#9F#) loop
 120             if S (F .. L) = Character'Image (C) then
 121                return Wide_Wide_Character'Val (Character'Pos (C));
 122             end if;
 123          end loop;
 124
 125          raise Constraint_Error;
 126       end if;
 127    end Value_Wide_Wide_Character;
 128
 129 end System.Val_WChar;