gcc/ada/s-taprop-vxworks.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS              --
   4 --                                                                          --
   5 --     S Y S T E M . T A S K _ P R I M I T I V E S . O P E R A T I O N S    --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --         Copyright (C) 1992-2004, Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the VxWorks version of this package
  35
  36 --  This package contains all the GNULL primitives that interface directly
  37 --  with the underlying OS.
  38
  39 pragma Polling (Off);
  40 --  Turn off polling, we do not want ATC polling to take place during
  41 --  tasking operations. It causes infinite loops and other problems.
  42
  43 with System.Tasking.Debug;
  44 --  used for Known_Tasks
  45
  46 with System.Interrupt_Management;
  47 --  used for Keep_Unmasked
  48 --           Abort_Task_Signal
  49 --           Signal_ID
  50 --           Initialize_Interrupts
  51
  52 with System.Soft_Links;
  53 --  used for Defer/Undefer_Abort
  54
  55 --  Note that we do not use System.Tasking.Initialization directly since
  56 --  this is a higher level package that we shouldn't depend on. For example
  57 --  when using the restricted run time, it is replaced by
  58 --  System.Tasking.Restricted.Stages.
  59
  60 with System.OS_Interface;
  61 --  used for various type, constant, and operations
  62
  63 with System.Parameters;
  64 --  used for Size_Type
  65
  66 with System.Tasking;
  67 --  used for Ada_Task_Control_Block
  68 --           Task_Id
  69 --           ATCB components and types
  70
  71 with Interfaces.C;
  72
  73 with Unchecked_Conversion;
  74 with Unchecked_Deallocation;
  75
  76 package body System.Task_Primitives.Operations is
  77
  78    use System.Tasking.Debug;
  79    use System.Tasking;
  80    use System.OS_Interface;
  81    use System.Parameters;
  82    use type Interfaces.C.int;
  83
  84    package SSL renames System.Soft_Links;
  85
  86    subtype int is System.OS_Interface.int;
  87
  88    Relative : constant := 0;
  89
  90    ----------------
  91    -- Local Data --
  92    ----------------
  93
  94    --  The followings are logically constants, but need to be initialized
  95    --  at run time.
  96
  97    Single_RTS_Lock : aliased RTS_Lock;
  98    --  This is a lock to allow only one thread of control in the RTS at
  99    --  a time; it is used to execute in mutual exclusion from all other tasks.
 100    --  Used mainly in Single_Lock mode, but also to protect All_Tasks_List
 101
 102    ATCB_Key : aliased System.Address := System.Null_Address;
 103    --  Key used to find the Ada Task_Id associated with a thread
 104
 105    ATCB_Key_Addr : System.Address := ATCB_Key'Address;
 106    pragma Export (Ada, ATCB_Key_Addr, "__gnat_ATCB_key_addr");
 107    --  Exported to support the temporary AE653 task registration
 108    --  implementation. This mechanism is used to minimize impact on other
 109    --  targets.
 110
 111    Environment_Task_Id : Task_Id;
 112    --  A variable to hold Task_Id for the environment task.
 113
 114    Unblocked_Signal_Mask : aliased sigset_t;
 115    --  The set of signals that should unblocked in all tasks
 116
 117    --  The followings are internal configuration constants needed.
 118
 119    Time_Slice_Val : Integer;
 120    pragma Import (C, Time_Slice_Val, "__gl_time_slice_val");
 121
 122    Locking_Policy : Character;
 123    pragma Import (C, Locking_Policy, "__gl_locking_policy");
 124
 125    Dispatching_Policy : Character;
 126    pragma Import (C, Dispatching_Policy, "__gl_task_dispatching_policy");
 127
 128    FIFO_Within_Priorities : constant Boolean := Dispatching_Policy = 'F';
 129    --  Indicates whether FIFO_Within_Priorities is set.
 130
 131    Mutex_Protocol : Priority_Type;
 132
 133    Foreign_Task_Elaborated : aliased Boolean := True;
 134    --  Used to identified fake tasks (i.e., non-Ada Threads).
 135
 136    --------------------
 137    -- Local Packages --
 138    --------------------
 139
 140    package Specific is
 141
 142       function Is_Valid_Task return Boolean;
 143       pragma Inline (Is_Valid_Task);
 144       --  Does executing thread have a TCB?
 145
 146       procedure Set (Self_Id : Task_Id);
 147       pragma Inline (Set);
 148       --  Set the self id for the current task.
 149
 150       function Self return Task_Id;
 151       pragma Inline (Self);
 152       --  Return a pointer to the Ada Task Control Block of the calling task.
 153
 154    end Specific;
 155
 156    package body Specific is separate;
 157    --  The body of this package is target specific.
 158
 159    ---------------------------------
 160    -- Support for foreign threads --
 161    ---------------------------------
 162
 163    function Register_Foreign_Thread (Thread : Thread_Id) return Task_Id;
 164    --  Allocate and Initialize a new ATCB for the current Thread.
 165
 166    function Register_Foreign_Thread
 167      (Thread : Thread_Id) return Task_Id is separate;
 168
 169    -----------------------
 170    -- Local Subprograms --
 171    -----------------------
 172
 173    procedure Abort_Handler (signo : Signal);
 174    --  Handler for the abort (SIGABRT) signal to handle asynchronous abortion.
 175
 176    procedure Install_Signal_Handlers;
 177    --  Install the default signal handlers for the current task
 178
 179    function To_Address is new Unchecked_Conversion (Task_Id, System.Address);
 180
 181    -------------------
 182    -- Abort_Handler --
 183    -------------------
 184
 185    procedure Abort_Handler (signo : Signal) is
 186       pragma Unreferenced (signo);
 187
 188       Self_ID : constant Task_Id := Self;
 189       Result  : int;
 190       Old_Set : aliased sigset_t;
 191
 192    begin
 193       --  It is not safe to raise an exception when using ZCX and the GCC
 194       --  exception handling mechanism.
 195
 196       if ZCX_By_Default and then GCC_ZCX_Support then
 197          return;
 198       end if;
 199
 200       if Self_ID.Deferral_Level = 0
 201         and then Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level
 202         and then not Self_ID.Aborting
 203       then
 204          Self_ID.Aborting := True;
 205
 206          --  Make sure signals used for RTS internal purpose are unmasked
 207
 208          Result := pthread_sigmask (SIG_UNBLOCK,
 209            Unblocked_Signal_Mask'Unchecked_Access, Old_Set'Unchecked_Access);
 210          pragma Assert (Result = 0);
 211
 212          raise Standard'Abort_Signal;
 213       end if;
 214    end Abort_Handler;
 215
 216    -----------------
 217    -- Stack_Guard --
 218    -----------------
 219
 220    procedure Stack_Guard (T : ST.Task_Id; On : Boolean) is
 221       pragma Unreferenced (T);
 222       pragma Unreferenced (On);
 223
 224    begin
 225       --  Nothing needed (why not???)
 226
 227       null;
 228    end Stack_Guard;
 229
 230    -------------------
 231    -- Get_Thread_Id --
 232    -------------------
 233
 234    function Get_Thread_Id (T : ST.Task_Id) return OSI.Thread_Id is
 235    begin
 236       return T.Common.LL.Thread;
 237    end Get_Thread_Id;
 238
 239    ----------
 240    -- Self --
 241    ----------
 242
 243    function Self return Task_Id renames Specific.Self;
 244
 245    -----------------------------
 246    -- Install_Signal_Handlers --
 247    -----------------------------
 248
 249    procedure Install_Signal_Handlers is
 250       act     : aliased struct_sigaction;
 251       old_act : aliased struct_sigaction;
 252       Tmp_Set : aliased sigset_t;
 253       Result  : int;
 254
 255    begin
 256       act.sa_flags := 0;
 257       act.sa_handler := Abort_Handler'Address;
 258
 259       Result := sigemptyset (Tmp_Set'Access);
 260       pragma Assert (Result = 0);
 261       act.sa_mask := Tmp_Set;
 262
 263       Result :=
 264         sigaction
 265           (Signal (Interrupt_Management.Abort_Task_Signal),
 266            act'Unchecked_Access,
 267            old_act'Unchecked_Access);
 268       pragma Assert (Result = 0);
 269
 270       Interrupt_Management.Initialize_Interrupts;
 271    end Install_Signal_Handlers;
 272
 273    ---------------------
 274    -- Initialize_Lock --
 275    ---------------------
 276
 277    procedure Initialize_Lock (Prio : System.Any_Priority; L : access Lock) is
 278    begin
 279       L.Mutex := semMCreate (SEM_Q_PRIORITY + SEM_INVERSION_SAFE);
 280       L.Prio_Ceiling := int (Prio);
 281       L.Protocol := Mutex_Protocol;
 282       pragma Assert (L.Mutex /= 0);
 283    end Initialize_Lock;
 284
 285    procedure Initialize_Lock (L : access RTS_Lock; Level : Lock_Level) is
 286       pragma Unreferenced (Level);
 287
 288    begin
 289       L.Mutex := semMCreate (SEM_Q_PRIORITY + SEM_INVERSION_SAFE);
 290       L.Prio_Ceiling := int (System.Any_Priority'Last);
 291       L.Protocol := Mutex_Protocol;
 292       pragma Assert (L.Mutex /= 0);
 293    end Initialize_Lock;
 294
 295    -------------------
 296    -- Finalize_Lock --
 297    -------------------
 298
 299    procedure Finalize_Lock (L : access Lock) is
 300       Result : int;
 301
 302    begin
 303       Result := semDelete (L.Mutex);
 304       pragma Assert (Result = 0);
 305    end Finalize_Lock;
 306
 307    procedure Finalize_Lock (L : access RTS_Lock) is
 308       Result : int;
 309
 310    begin
 311       Result := semDelete (L.Mutex);
 312       pragma Assert (Result = 0);
 313    end Finalize_Lock;
 314
 315    ----------------
 316    -- Write_Lock --
 317    ----------------
 318
 319    procedure Write_Lock (L : access Lock; Ceiling_Violation : out Boolean) is
 320       Result : int;
 321
 322    begin
 323       if L.Protocol = Prio_Protect
 324         and then int (Self.Common.Current_Priority) > L.Prio_Ceiling
 325       then
 326          Ceiling_Violation := True;
 327          return;
 328       else
 329          Ceiling_Violation := False;
 330       end if;
 331
 332       Result := semTake (L.Mutex, WAIT_FOREVER);
 333       pragma Assert (Result = 0);
 334    end Write_Lock;
 335
 336    procedure Write_Lock
 337      (L           : access RTS_Lock;
 338       Global_Lock : Boolean := False)
 339    is
 340       Result : int;
 341
 342    begin
 343       if not Single_Lock or else Global_Lock then
 344          Result := semTake (L.Mutex, WAIT_FOREVER);
 345          pragma Assert (Result = 0);
 346       end if;
 347    end Write_Lock;
 348
 349    procedure Write_Lock (T : Task_Id) is
 350       Result : int;
 351
 352    begin
 353       if not Single_Lock then
 354          Result := semTake (T.Common.LL.L.Mutex, WAIT_FOREVER);
 355          pragma Assert (Result = 0);
 356       end if;
 357    end Write_Lock;
 358
 359    ---------------
 360    -- Read_Lock --
 361    ---------------
 362
 363    procedure Read_Lock (L : access Lock; Ceiling_Violation : out Boolean) is
 364    begin
 365       Write_Lock (L, Ceiling_Violation);
 366    end Read_Lock;
 367
 368    ------------
 369    -- Unlock --
 370    ------------
 371
 372    procedure Unlock (L : access Lock) is
 373       Result  : int;
 374
 375    begin
 376       Result := semGive (L.Mutex);
 377       pragma Assert (Result = 0);
 378    end Unlock;
 379
 380    procedure Unlock (L : access RTS_Lock; Global_Lock : Boolean := False) is
 381       Result : int;
 382
 383    begin
 384       if not Single_Lock or else Global_Lock then
 385          Result := semGive (L.Mutex);
 386          pragma Assert (Result = 0);
 387       end if;
 388    end Unlock;
 389
 390    procedure Unlock (T : Task_Id) is
 391       Result : int;
 392
 393    begin
 394       if not Single_Lock then
 395          Result := semGive (T.Common.LL.L.Mutex);
 396          pragma Assert (Result = 0);
 397       end if;
 398    end Unlock;
 399
 400    -----------
 401    -- Sleep --
 402    -----------
 403
 404    procedure Sleep (Self_ID : Task_Id; Reason : System.Tasking.Task_States) is
 405       pragma Unreferenced (Reason);
 406
 407       Result : int;
 408
 409    begin
 410       pragma Assert (Self_ID = Self);
 411
 412       --  Release the mutex before sleeping.
 413       if Single_Lock then
 414          Result := semGive (Single_RTS_Lock.Mutex);
 415       else
 416          Result := semGive (Self_ID.Common.LL.L.Mutex);
 417       end if;
 418
 419       pragma Assert (Result = 0);
 420
 421       --  Perform a blocking operation to take the CV semaphore.
 422       --  Note that a blocking operation in VxWorks will reenable
 423       --  task scheduling. When we are no longer blocked and control
 424       --  is returned, task scheduling will again be disabled.
 425
 426       Result := semTake (Self_ID.Common.LL.CV, WAIT_FOREVER);
 427       pragma Assert (Result = 0);
 428
 429       --  Take the mutex back.
 430       if Single_Lock then
 431          Result := semTake (Single_RTS_Lock.Mutex, WAIT_FOREVER);
 432       else
 433          Result := semTake (Self_ID.Common.LL.L.Mutex, WAIT_FOREVER);
 434       end if;
 435
 436       pragma Assert (Result = 0);
 437    end Sleep;
 438
 439    -----------------
 440    -- Timed_Sleep --
 441    -----------------
 442
 443    --  This is for use within the run-time system, so abort is
 444    --  assumed to be already deferred, and the caller should be
 445    --  holding its own ATCB lock.
 446
 447    procedure Timed_Sleep
 448      (Self_ID  : Task_Id;
 449       Time     : Duration;
 450       Mode     : ST.Delay_Modes;
 451       Reason   : System.Tasking.Task_States;
 452       Timedout : out Boolean;
 453       Yielded  : out Boolean)
 454    is
 455       pragma Unreferenced (Reason);
 456
 457       Orig     : constant Duration := Monotonic_Clock;
 458       Absolute : Duration;
 459       Ticks    : int;
 460       Result   : int;
 461       Wakeup   : Boolean := False;
 462
 463    begin
 464       Timedout := False;
 465       Yielded  := True;
 466
 467       if Mode = Relative then
 468          Absolute := Orig + Time;
 469
 470          --  Systematically add one since the first tick will delay
 471          --  *at most* 1 / Rate_Duration seconds, so we need to add one to
 472          --  be on the safe side.
 473
 474          Ticks := To_Clock_Ticks (Time);
 475
 476          if Ticks > 0 and then Ticks < int'Last then
 477             Ticks := Ticks + 1;
 478          end if;
 479
 480       else
 481          Absolute := Time;
 482          Ticks    := To_Clock_Ticks (Time - Monotonic_Clock);
 483       end if;
 484
 485       if Ticks > 0 then
 486          loop
 487             --  Release the mutex before sleeping.
 488             if Single_Lock then
 489                Result := semGive (Single_RTS_Lock.Mutex);
 490             else
 491                Result := semGive (Self_ID.Common.LL.L.Mutex);
 492             end if;
 493
 494             pragma Assert (Result = 0);
 495
 496             --  Perform a blocking operation to take the CV semaphore.
 497             --  Note that a blocking operation in VxWorks will reenable
 498             --  task scheduling. When we are no longer blocked and control
 499             --  is returned, task scheduling will again be disabled.
 500
 501             Result := semTake (Self_ID.Common.LL.CV, Ticks);
 502
 503             if Result = 0 then
 504                --  Somebody may have called Wakeup for us
 505
 506                Wakeup := True;
 507
 508             else
 509                if errno /= S_objLib_OBJ_TIMEOUT then
 510                   Wakeup := True;
 511                else
 512                   --  If Ticks = int'last, it was most probably truncated
 513                   --  so let's make another round after recomputing Ticks
 514                   --  from the the absolute time.
 515
 516                   if Ticks /= int'Last then
 517                      Timedout := True;
 518                   else
 519                      Ticks := To_Clock_Ticks (Absolute - Monotonic_Clock);
 520
 521                      if Ticks < 0 then
 522                         Timedout := True;
 523                      end if;
 524                   end if;
 525                end if;
 526             end if;
 527
 528             --  Take the mutex back.
 529             if Single_Lock then
 530                Result := semTake (Single_RTS_Lock.Mutex, WAIT_FOREVER);
 531             else
 532                Result := semTake (Self_ID.Common.LL.L.Mutex, WAIT_FOREVER);
 533             end if;
 534
 535             pragma Assert (Result = 0);
 536
 537             exit when Timedout or Wakeup;
 538          end loop;
 539
 540       else
 541          Timedout := True;
 542
 543          --  Should never hold a lock while yielding.
 544          if Single_Lock then
 545             Result := semGive (Single_RTS_Lock.Mutex);
 546             taskDelay (0);
 547             Result := semTake (Single_RTS_Lock.Mutex, WAIT_FOREVER);
 548
 549          else
 550             Result := semGive (Self_ID.Common.LL.L.Mutex);
 551             taskDelay (0);
 552             Result := semTake (Self_ID.Common.LL.L.Mutex, WAIT_FOREVER);
 553          end if;
 554       end if;
 555    end Timed_Sleep;
 556
 557    -----------------
 558    -- Timed_Delay --
 559    -----------------
 560
 561    --  This is for use in implementing delay statements, so
 562    --  we assume the caller is holding no locks.
 563
 564    procedure Timed_Delay
 565      (Self_ID  : Task_Id;
 566       Time     : Duration;
 567       Mode     : ST.Delay_Modes)
 568    is
 569       Orig     : constant Duration := Monotonic_Clock;
 570       Absolute : Duration;
 571       Ticks    : int;
 572       Timedout : Boolean;
 573       Result   : int;
 574       Aborted  : Boolean := False;
 575
 576    begin
 577       SSL.Abort_Defer.all;
 578
 579       if Mode = Relative then
 580          Absolute := Orig + Time;
 581          Ticks    := To_Clock_Ticks (Time);
 582
 583          if Ticks > 0 and then Ticks < int'Last then
 584
 585             --  The first tick will delay anytime between 0 and
 586             --  1 / sysClkRateGet seconds, so we need to add one to
 587             --  be on the safe side.
 588
 589             Ticks := Ticks + 1;
 590          end if;
 591
 592       else
 593          Absolute := Time;
 594          Ticks    := To_Clock_Ticks (Time - Orig);
 595       end if;
 596
 597       if Ticks > 0 then
 598          --  Modifying State and Pending_Priority_Change, locking the TCB.
 599          if Single_Lock then
 600             Result := semTake (Single_RTS_Lock.Mutex, WAIT_FOREVER);
 601          else
 602             Result := semTake (Self_ID.Common.LL.L.Mutex, WAIT_FOREVER);
 603          end if;
 604
 605          pragma Assert (Result = 0);
 606
 607          Self_ID.Common.State := Delay_Sleep;
 608          Timedout := False;
 609
 610          loop
 611             if Self_ID.Pending_Priority_Change then
 612                Self_ID.Pending_Priority_Change := False;
 613                Self_ID.Common.Base_Priority    := Self_ID.New_Base_Priority;
 614                Set_Priority (Self_ID, Self_ID.Common.Base_Priority);
 615             end if;
 616
 617             Aborted := Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level;
 618
 619             --  Release the TCB before sleeping
 620
 621             if Single_Lock then
 622                Result := semGive (Single_RTS_Lock.Mutex);
 623             else
 624                Result := semGive (Self_ID.Common.LL.L.Mutex);
 625             end if;
 626             pragma Assert (Result = 0);
 627
 628             exit when Aborted;
 629
 630             Result := semTake (Self_ID.Common.LL.CV, Ticks);
 631
 632             if Result /= 0 then
 633                --  If Ticks = int'last, it was most probably truncated
 634                --  so let's make another round after recomputing Ticks
 635                --  from the the absolute time.
 636
 637                if errno = S_objLib_OBJ_TIMEOUT and then Ticks /= int'Last then
 638                   Timedout := True;
 639                else
 640                   Ticks := To_Clock_Ticks (Absolute - Monotonic_Clock);
 641
 642                   if Ticks < 0 then
 643                      Timedout := True;
 644                   end if;
 645                end if;
 646             end if;
 647
 648             --  Take back the lock after having slept, to protect further
 649             --  access to Self_ID
 650
 651             if Single_Lock then
 652                Result := semTake (Single_RTS_Lock.Mutex, WAIT_FOREVER);
 653             else
 654                Result := semTake (Self_ID.Common.LL.L.Mutex, WAIT_FOREVER);
 655             end if;
 656
 657             pragma Assert (Result = 0);
 658
 659             exit when Timedout;
 660          end loop;
 661
 662          Self_ID.Common.State := Runnable;
 663
 664          if Single_Lock then
 665             Result := semGive (Single_RTS_Lock.Mutex);
 666          else
 667             Result := semGive (Self_ID.Common.LL.L.Mutex);
 668          end if;
 669
 670       else
 671          taskDelay (0);
 672       end if;
 673
 674       SSL.Abort_Undefer.all;
 675    end Timed_Delay;
 676
 677    ---------------------
 678    -- Monotonic_Clock --
 679    ---------------------
 680
 681    function Monotonic_Clock return Duration is
 682       TS     : aliased timespec;
 683       Result : int;
 684    begin
 685       Result := clock_gettime (CLOCK_REALTIME, TS'Unchecked_Access);
 686       pragma Assert (Result = 0);
 687       return To_Duration (TS);
 688    end Monotonic_Clock;
 689
 690    -------------------
 691    -- RT_Resolution --
 692    -------------------
 693
 694    function RT_Resolution return Duration is
 695    begin
 696       return 1.0 / Duration (sysClkRateGet);
 697    end RT_Resolution;
 698
 699    ------------
 700    -- Wakeup --
 701    ------------
 702
 703    procedure Wakeup (T : Task_Id; Reason : System.Tasking.Task_States) is
 704       pragma Unreferenced (Reason);
 705       Result : int;
 706    begin
 707       Result := semGive (T.Common.LL.CV);
 708       pragma Assert (Result = 0);
 709    end Wakeup;
 710
 711    -----------
 712    -- Yield --
 713    -----------
 714
 715    procedure Yield (Do_Yield : Boolean := True) is
 716       pragma Unreferenced (Do_Yield);
 717       Result : int;
 718       pragma Unreferenced (Result);
 719    begin
 720       Result := taskDelay (0);
 721    end Yield;
 722
 723    ------------------
 724    -- Set_Priority --
 725    ------------------
 726
 727    type Prio_Array_Type is array (System.Any_Priority) of Integer;
 728    pragma Atomic_Components (Prio_Array_Type);
 729
 730    Prio_Array : Prio_Array_Type;
 731    --  Global array containing the id of the currently running task for
 732    --  each priority. Note that we assume that we are on a single processor
 733    --  with run-till-blocked scheduling.
 734
 735    procedure Set_Priority
 736      (T                   : Task_Id;
 737       Prio                : System.Any_Priority;
 738       Loss_Of_Inheritance : Boolean := False)
 739    is
 740       Array_Item : Integer;
 741       Result     : int;
 742
 743    begin
 744       Result :=
 745         taskPrioritySet
 746           (T.Common.LL.Thread, To_VxWorks_Priority (int (Prio)));
 747       pragma Assert (Result = 0);
 748
 749       if FIFO_Within_Priorities then
 750
 751          --  Annex D requirement [RM D.2.2 par. 9]:
 752          --    If the task drops its priority due to the loss of inherited
 753          --    priority, it is added at the head of the ready queue for its
 754          --    new active priority.
 755
 756          if Loss_Of_Inheritance
 757            and then Prio < T.Common.Current_Priority
 758          then
 759             Array_Item := Prio_Array (T.Common.Base_Priority) + 1;
 760             Prio_Array (T.Common.Base_Priority) := Array_Item;
 761
 762             loop
 763                --  Give some processes a chance to arrive
 764
 765                taskDelay (0);
 766
 767                --  Then wait for our turn to proceed
 768
 769                exit when Array_Item = Prio_Array (T.Common.Base_Priority)
 770                  or else Prio_Array (T.Common.Base_Priority) = 1;
 771             end loop;
 772
 773             Prio_Array (T.Common.Base_Priority) :=
 774               Prio_Array (T.Common.Base_Priority) - 1;
 775          end if;
 776       end if;
 777
 778       T.Common.Current_Priority := Prio;
 779    end Set_Priority;
 780
 781    ------------------
 782    -- Get_Priority --
 783    ------------------
 784
 785    function Get_Priority (T : Task_Id) return System.Any_Priority is
 786    begin
 787       return T.Common.Current_Priority;
 788    end Get_Priority;
 789
 790    ----------------
 791    -- Enter_Task --
 792    ----------------
 793
 794    procedure Enter_Task (Self_ID : Task_Id) is
 795       procedure Init_Float;
 796       pragma Import (C, Init_Float, "__gnat_init_float");
 797       --  Properly initializes the FPU for PPC/MIPS systems.
 798
 799    begin
 800       Self_ID.Common.LL.Thread := taskIdSelf;
 801       Specific.Set (Self_ID);
 802
 803       Init_Float;
 804
 805       --  Install the signal handlers.
 806       --  This is called for each task since there is no signal inheritance
 807       --  between VxWorks tasks.
 808
 809       Install_Signal_Handlers;
 810
 811       Lock_RTS;
 812
 813       for J in Known_Tasks'Range loop
 814          if Known_Tasks (J) = null then
 815             Known_Tasks (J) := Self_ID;
 816             Self_ID.Known_Tasks_Index := J;
 817             exit;
 818          end if;
 819       end loop;
 820
 821       Unlock_RTS;
 822    end Enter_Task;
 823
 824    --------------
 825    -- New_ATCB --
 826    --------------
 827
 828    function New_ATCB (Entry_Num : Task_Entry_Index) return Task_Id is
 829    begin
 830       return new Ada_Task_Control_Block (Entry_Num);
 831    end New_ATCB;
 832
 833    -------------------
 834    -- Is_Valid_Task --
 835    -------------------
 836
 837    function Is_Valid_Task return Boolean renames Specific.Is_Valid_Task;
 838
 839    -----------------------------
 840    -- Register_Foreign_Thread --
 841    -----------------------------
 842
 843    function Register_Foreign_Thread return Task_Id is
 844    begin
 845       if Is_Valid_Task then
 846          return Self;
 847       else
 848          return Register_Foreign_Thread (taskIdSelf);
 849       end if;
 850    end Register_Foreign_Thread;
 851
 852    --------------------
 853    -- Initialize_TCB --
 854    --------------------
 855
 856    procedure Initialize_TCB (Self_ID : Task_Id; Succeeded : out Boolean) is
 857    begin
 858       Self_ID.Common.LL.CV := semBCreate (SEM_Q_PRIORITY, SEM_EMPTY);
 859       Self_ID.Common.LL.Thread := 0;
 860
 861       if Self_ID.Common.LL.CV = 0 then
 862          Succeeded := False;
 863       else
 864          Succeeded := True;
 865
 866          if not Single_Lock then
 867             Initialize_Lock (Self_ID.Common.LL.L'Access, ATCB_Level);
 868          end if;
 869       end if;
 870    end Initialize_TCB;
 871
 872    -----------------
 873    -- Create_Task --
 874    -----------------
 875
 876    procedure Create_Task
 877      (T          : Task_Id;
 878       Wrapper    : System.Address;
 879       Stack_Size : System.Parameters.Size_Type;
 880       Priority   : System.Any_Priority;
 881       Succeeded  : out Boolean)
 882    is
 883       Adjusted_Stack_Size : size_t;
 884    begin
 885       if Stack_Size = Unspecified_Size then
 886          Adjusted_Stack_Size := size_t (Default_Stack_Size);
 887
 888       elsif Stack_Size < Minimum_Stack_Size then
 889          Adjusted_Stack_Size := size_t (Minimum_Stack_Size);
 890
 891       else
 892          Adjusted_Stack_Size := size_t (Stack_Size);
 893       end if;
 894
 895       --  Ask for 4 extra bytes of stack space so that the ATCB
 896       --  pointer can be stored below the stack limit, plus extra
 897       --  space for the frame of Task_Wrapper.  This is so the user
 898       --  gets the amount of stack requested exclusive of the needs
 899       --  of the runtime.
 900       --
 901       --  We also have to allocate n more bytes for the task name
 902       --  storage and enough space for the Wind Task Control Block
 903       --  which is around 0x778 bytes.  VxWorks also seems to carve out
 904       --  additional space, so use 2048 as a nice round number.
 905       --  We might want to increment to the nearest page size in
 906       --  case we ever support VxVMI.
 907       --
 908       --  XXX - we should come back and visit this so we can
 909       --        set the task name to something appropriate.
 910
 911       Adjusted_Stack_Size := Adjusted_Stack_Size + 2048;
 912
 913       --  Since the initial signal mask of a thread is inherited from the
 914       --  creator, and the Environment task has all its signals masked, we
 915       --  do not need to manipulate caller's signal mask at this point.
 916       --  All tasks in RTS will have All_Tasks_Mask initially.
 917
 918       if T.Common.Task_Image_Len = 0 then
 919          T.Common.LL.Thread := taskSpawn
 920            (System.Null_Address,
 921             To_VxWorks_Priority (int (Priority)),
 922             VX_FP_TASK,
 923             Adjusted_Stack_Size,
 924             Wrapper,
 925             To_Address (T));
 926       else
 927          declare
 928             Name : aliased String (1 .. T.Common.Task_Image_Len + 1);
 929          begin
 930             Name (1 .. Name'Last - 1) :=
 931               T.Common.Task_Image (1 .. T.Common.Task_Image_Len);
 932             Name (Name'Last) := ASCII.NUL;
 933
 934             T.Common.LL.Thread := taskSpawn
 935               (Name'Address,
 936                To_VxWorks_Priority (int (Priority)),
 937                VX_FP_TASK,
 938                Adjusted_Stack_Size,
 939                Wrapper,
 940                To_Address (T));
 941          end;
 942       end if;
 943
 944       if T.Common.LL.Thread = -1 then
 945          Succeeded := False;
 946       else
 947          Succeeded := True;
 948       end if;
 949
 950       Task_Creation_Hook (T.Common.LL.Thread);
 951       Set_Priority (T, Priority);
 952    end Create_Task;
 953
 954    ------------------
 955    -- Finalize_TCB --
 956    ------------------
 957
 958    procedure Finalize_TCB (T : Task_Id) is
 959       Result  : int;
 960       Tmp     : Task_Id          := T;
 961       Is_Self : constant Boolean := (T = Self);
 962
 963       procedure Free is new
 964         Unchecked_Deallocation (Ada_Task_Control_Block, Task_Id);
 965
 966    begin
 967       if not Single_Lock then
 968          Result := semDelete (T.Common.LL.L.Mutex);
 969          pragma Assert (Result = 0);
 970       end if;
 971
 972       T.Common.LL.Thread := 0;
 973
 974       Result := semDelete (T.Common.LL.CV);
 975       pragma Assert (Result = 0);
 976
 977       if T.Known_Tasks_Index /= -1 then
 978          Known_Tasks (T.Known_Tasks_Index) := null;
 979       end if;
 980
 981       Free (Tmp);
 982
 983       if Is_Self then
 984          Result := taskVarDelete (taskIdSelf, ATCB_Key'Access);
 985          pragma Assert (Result /= ERROR);
 986       end if;
 987    end Finalize_TCB;
 988
 989    ---------------
 990    -- Exit_Task --
 991    ---------------
 992
 993    procedure Exit_Task is
 994    begin
 995       Specific.Set (null);
 996    end Exit_Task;
 997
 998    ----------------
 999    -- Abort_Task --
1000    ----------------
1001
1002    procedure Abort_Task (T : Task_Id) is
1003       Result : int;
1004
1005    begin
1006       Result := kill (T.Common.LL.Thread,
1007         Signal (Interrupt_Management.Abort_Task_Signal));
1008       pragma Assert (Result = 0);
1009    end Abort_Task;
1010
1011    ----------------
1012    -- Check_Exit --
1013    ----------------
1014
1015    --  Dummy version
1016
1017    function Check_Exit (Self_ID : ST.Task_Id) return Boolean is
1018       pragma Unreferenced (Self_ID);
1019    begin
1020       return True;
1021    end Check_Exit;
1022
1023    --------------------
1024    -- Check_No_Locks --
1025    --------------------
1026
1027    function Check_No_Locks (Self_ID : ST.Task_Id) return Boolean is
1028       pragma Unreferenced (Self_ID);
1029    begin
1030       return True;
1031    end Check_No_Locks;
1032
1033    ----------------------
1034    -- Environment_Task --
1035    ----------------------
1036
1037    function Environment_Task return Task_Id is
1038    begin
1039       return Environment_Task_Id;
1040    end Environment_Task;
1041
1042    --------------
1043    -- Lock_RTS --
1044    --------------
1045
1046    procedure Lock_RTS is
1047    begin
1048       Write_Lock (Single_RTS_Lock'Access, Global_Lock => True);
1049    end Lock_RTS;
1050
1051    ----------------
1052    -- Unlock_RTS --
1053    ----------------
1054
1055    procedure Unlock_RTS is
1056    begin
1057       Unlock (Single_RTS_Lock'Access, Global_Lock => True);
1058    end Unlock_RTS;
1059
1060    ------------------
1061    -- Suspend_Task --
1062    ------------------
1063
1064    function Suspend_Task
1065      (T           : ST.Task_Id;
1066       Thread_Self : Thread_Id) return Boolean
1067    is
1068    begin
1069       if T.Common.LL.Thread /= 0
1070         and then T.Common.LL.Thread /= Thread_Self
1071       then
1072          return taskSuspend (T.Common.LL.Thread) = 0;
1073       else
1074          return True;
1075       end if;
1076    end Suspend_Task;
1077
1078    -----------------
1079    -- Resume_Task --
1080    -----------------
1081
1082    function Resume_Task
1083      (T           : ST.Task_Id;
1084       Thread_Self : Thread_Id) return Boolean
1085    is
1086    begin
1087       if T.Common.LL.Thread /= 0
1088         and then T.Common.LL.Thread /= Thread_Self
1089       then
1090          return taskResume (T.Common.LL.Thread) = 0;
1091       else
1092          return True;
1093       end if;
1094    end Resume_Task;
1095
1096    ----------------
1097    -- Initialize --
1098    ----------------
1099
1100    procedure Initialize (Environment_Task : Task_Id) is
1101       Result : int;
1102
1103    begin
1104       if Locking_Policy = 'C' then
1105          Mutex_Protocol := Prio_Protect;
1106       elsif Locking_Policy = 'I' then
1107          Mutex_Protocol := Prio_Inherit;
1108       else
1109          Mutex_Protocol := Prio_None;
1110       end if;
1111
1112       if Time_Slice_Val > 0 then
1113          Result := kernelTimeSlice
1114            (To_Clock_Ticks
1115              (Duration (Time_Slice_Val) / Duration (1_000_000.0)));
1116       end if;
1117
1118       Result := sigemptyset (Unblocked_Signal_Mask'Access);
1119       pragma Assert (Result = 0);
1120
1121       for J in Interrupt_Management.Signal_ID loop
1122          if System.Interrupt_Management.Keep_Unmasked (J) then
1123             Result := sigaddset (Unblocked_Signal_Mask'Access, Signal (J));
1124             pragma Assert (Result = 0);
1125          end if;
1126       end loop;
1127
1128       Environment_Task_Id := Environment_Task;
1129
1130       --  Initialize the lock used to synchronize chain of all ATCBs.
1131
1132       Initialize_Lock (Single_RTS_Lock'Access, RTS_Lock_Level);
1133
1134       Enter_Task (Environment_Task);
1135    end Initialize;
1136
1137 end System.Task_Primitives.Operations;