gcc/ada/s-taprop-linux.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --     S Y S T E M . T A S K _ P R I M I T I V E S . O P E R A T I O N S    --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --         Copyright (C) 1992-2009, Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is a GNU/Linux (GNU/LinuxThreads) version of this package
  33
  34 --  This package contains all the GNULL primitives that interface directly with
  35 --  the underlying OS.
  36
  37 pragma Polling (Off);
  38 --  Turn off polling, we do not want ATC polling to take place during tasking
  39 --  operations. It causes infinite loops and other problems.
  40
  41 with Ada.Unchecked_Conversion;
  42 with Ada.Unchecked_Deallocation;
  43
  44 with Interfaces.C;
  45
  46 with System.Task_Info;
  47 with System.Tasking.Debug;
  48 with System.Interrupt_Management;
  49 with System.OS_Primitives;
  50 with System.Stack_Checking.Operations;
  51
  52 with System.Soft_Links;
  53 --  We use System.Soft_Links instead of System.Tasking.Initialization
  54 --  because the later is a higher level package that we shouldn't depend on.
  55 --  For example when using the restricted run time, it is replaced by
  56 --  System.Tasking.Restricted.Stages.
  57
  58 package body System.Task_Primitives.Operations is
  59
  60    package SSL renames System.Soft_Links;
  61    package SC renames System.Stack_Checking.Operations;
  62
  63    use System.Tasking.Debug;
  64    use System.Tasking;
  65    use Interfaces.C;
  66    use System.OS_Interface;
  67    use System.Parameters;
  68    use System.OS_Primitives;
  69    use System.Task_Info;
  70
  71    ----------------
  72    -- Local Data --
  73    ----------------
  74
  75    --  The followings are logically constants, but need to be initialized
  76    --  at run time.
  77
  78    Single_RTS_Lock : aliased RTS_Lock;
  79    --  This is a lock to allow only one thread of control in the RTS at
  80    --  a time; it is used to execute in mutual exclusion from all other tasks.
  81    --  Used mainly in Single_Lock mode, but also to protect All_Tasks_List
  82
  83    ATCB_Key : aliased pthread_key_t;
  84    --  Key used to find the Ada Task_Id associated with a thread
  85
  86    Environment_Task_Id : Task_Id;
  87    --  A variable to hold Task_Id for the environment task
  88
  89    Unblocked_Signal_Mask : aliased sigset_t;
  90    --  The set of signals that should be unblocked in all tasks
  91
  92    --  The followings are internal configuration constants needed
  93
  94    Next_Serial_Number : Task_Serial_Number := 100;
  95    --  We start at 100 (reserve some special values for using in error checks)
  96
  97    Time_Slice_Val : Integer;
  98    pragma Import (C, Time_Slice_Val, "__gl_time_slice_val");
  99
 100    Dispatching_Policy : Character;
 101    pragma Import (C, Dispatching_Policy, "__gl_task_dispatching_policy");
 102
 103    --  The following are effectively constants, but they need to be initialized
 104    --  by calling a pthread_ function.
 105
 106    Mutex_Attr   : aliased pthread_mutexattr_t;
 107    Cond_Attr    : aliased pthread_condattr_t;
 108
 109    Foreign_Task_Elaborated : aliased Boolean := True;
 110    --  Used to identified fake tasks (i.e., non-Ada Threads)
 111
 112    Use_Alternate_Stack : constant Boolean := Alternate_Stack_Size /= 0;
 113    --  Whether to use an alternate signal stack for stack overflows
 114
 115    Abort_Handler_Installed : Boolean := False;
 116    --  True if a handler for the abort signal is installed
 117
 118    --------------------
 119    -- Local Packages --
 120    --------------------
 121
 122    package Specific is
 123
 124       procedure Initialize (Environment_Task : Task_Id);
 125       pragma Inline (Initialize);
 126       --  Initialize various data needed by this package
 127
 128       function Is_Valid_Task return Boolean;
 129       pragma Inline (Is_Valid_Task);
 130       --  Does executing thread have a TCB?
 131
 132       procedure Set (Self_Id : Task_Id);
 133       pragma Inline (Set);
 134       --  Set the self id for the current task
 135
 136       function Self return Task_Id;
 137       pragma Inline (Self);
 138       --  Return a pointer to the Ada Task Control Block of the calling task
 139
 140    end Specific;
 141
 142    package body Specific is separate;
 143    --  The body of this package is target specific
 144
 145    ---------------------------------
 146    -- Support for foreign threads --
 147    ---------------------------------
 148
 149    function Register_Foreign_Thread (Thread : Thread_Id) return Task_Id;
 150    --  Allocate and Initialize a new ATCB for the current Thread
 151
 152    function Register_Foreign_Thread
 153      (Thread : Thread_Id) return Task_Id is separate;
 154
 155    -----------------------
 156    -- Local Subprograms --
 157    -----------------------
 158
 159    subtype unsigned_long is Interfaces.C.unsigned_long;
 160
 161    procedure Abort_Handler (signo : Signal);
 162
 163    function To_pthread_t is new Ada.Unchecked_Conversion
 164      (unsigned_long, System.OS_Interface.pthread_t);
 165
 166    -------------------
 167    -- Abort_Handler --
 168    -------------------
 169
 170    procedure Abort_Handler (signo : Signal) is
 171       pragma Unreferenced (signo);
 172
 173       Self_Id : constant Task_Id := Self;
 174       Result  : Interfaces.C.int;
 175       Old_Set : aliased sigset_t;
 176
 177    begin
 178       --  It's not safe to raise an exception when using GCC ZCX mechanism.
 179       --  Note that we still need to install a signal handler, since in some
 180       --  cases (e.g. shutdown of the Server_Task in System.Interrupts) we
 181       --  need to send the Abort signal to a task.
 182
 183       if ZCX_By_Default and then GCC_ZCX_Support then
 184          return;
 185       end if;
 186
 187       if Self_Id.Deferral_Level = 0
 188         and then Self_Id.Pending_ATC_Level < Self_Id.ATC_Nesting_Level
 189         and then not Self_Id.Aborting
 190       then
 191          Self_Id.Aborting := True;
 192
 193          --  Make sure signals used for RTS internal purpose are unmasked
 194
 195          Result :=
 196            pthread_sigmask
 197              (SIG_UNBLOCK,
 198               Unblocked_Signal_Mask'Access,
 199               Old_Set'Access);
 200          pragma Assert (Result = 0);
 201
 202          raise Standard'Abort_Signal;
 203       end if;
 204    end Abort_Handler;
 205
 206    --------------
 207    -- Lock_RTS --
 208    --------------
 209
 210    procedure Lock_RTS is
 211    begin
 212       Write_Lock (Single_RTS_Lock'Access, Global_Lock => True);
 213    end Lock_RTS;
 214
 215    ----------------
 216    -- Unlock_RTS --
 217    ----------------
 218
 219    procedure Unlock_RTS is
 220    begin
 221       Unlock (Single_RTS_Lock'Access, Global_Lock => True);
 222    end Unlock_RTS;
 223
 224    -----------------
 225    -- Stack_Guard --
 226    -----------------
 227
 228    --  The underlying thread system extends the memory (up to 2MB) when needed
 229
 230    procedure Stack_Guard (T : ST.Task_Id; On : Boolean) is
 231       pragma Unreferenced (T);
 232       pragma Unreferenced (On);
 233    begin
 234       null;
 235    end Stack_Guard;
 236
 237    --------------------
 238    -- Get_Thread_Id  --
 239    --------------------
 240
 241    function Get_Thread_Id (T : ST.Task_Id) return OSI.Thread_Id is
 242    begin
 243       return T.Common.LL.Thread;
 244    end Get_Thread_Id;
 245
 246    ----------
 247    -- Self --
 248    ----------
 249
 250    function Self return Task_Id renames Specific.Self;
 251
 252    ---------------------
 253    -- Initialize_Lock --
 254    ---------------------
 255
 256    --  Note: mutexes and cond_variables needed per-task basis are initialized
 257    --  in Initialize_TCB and the Storage_Error is handled. Other mutexes (such
 258    --  as RTS_Lock, Memory_Lock...) used in RTS is initialized before any
 259    --  status change of RTS. Therefore raising Storage_Error in the following
 260    --  routines should be able to be handled safely.
 261
 262    procedure Initialize_Lock
 263      (Prio : System.Any_Priority;
 264       L    : not null access Lock)
 265    is
 266       pragma Unreferenced (Prio);
 267
 268       Result : Interfaces.C.int;
 269
 270    begin
 271       Result := pthread_mutex_init (L, Mutex_Attr'Access);
 272
 273       pragma Assert (Result = 0 or else Result = ENOMEM);
 274
 275       if Result = ENOMEM then
 276          raise Storage_Error with "Failed to allocate a lock";
 277       end if;
 278    end Initialize_Lock;
 279
 280    procedure Initialize_Lock
 281      (L     : not null access RTS_Lock;
 282       Level : Lock_Level)
 283    is
 284       pragma Unreferenced (Level);
 285
 286       Result : Interfaces.C.int;
 287
 288    begin
 289       Result := pthread_mutex_init (L, Mutex_Attr'Access);
 290
 291       pragma Assert (Result = 0 or else Result = ENOMEM);
 292
 293       if Result = ENOMEM then
 294          raise Storage_Error;
 295       end if;
 296    end Initialize_Lock;
 297
 298    -------------------
 299    -- Finalize_Lock --
 300    -------------------
 301
 302    procedure Finalize_Lock (L : not null access Lock) is
 303       Result : Interfaces.C.int;
 304    begin
 305       Result := pthread_mutex_destroy (L);
 306       pragma Assert (Result = 0);
 307    end Finalize_Lock;
 308
 309    procedure Finalize_Lock (L : not null access RTS_Lock) is
 310       Result : Interfaces.C.int;
 311    begin
 312       Result := pthread_mutex_destroy (L);
 313       pragma Assert (Result = 0);
 314    end Finalize_Lock;
 315
 316    ----------------
 317    -- Write_Lock --
 318    ----------------
 319
 320    procedure Write_Lock
 321      (L                 : not null access Lock;
 322       Ceiling_Violation : out Boolean)
 323    is
 324       Result : Interfaces.C.int;
 325    begin
 326       Result := pthread_mutex_lock (L);
 327       Ceiling_Violation := Result = EINVAL;
 328
 329       --  Assume the cause of EINVAL is a priority ceiling violation
 330
 331       pragma Assert (Result = 0 or else Result = EINVAL);
 332    end Write_Lock;
 333
 334    procedure Write_Lock
 335      (L           : not null access RTS_Lock;
 336       Global_Lock : Boolean := False)
 337    is
 338       Result : Interfaces.C.int;
 339    begin
 340       if not Single_Lock or else Global_Lock then
 341          Result := pthread_mutex_lock (L);
 342          pragma Assert (Result = 0);
 343       end if;
 344    end Write_Lock;
 345
 346    procedure Write_Lock (T : Task_Id) is
 347       Result : Interfaces.C.int;
 348    begin
 349       if not Single_Lock then
 350          Result := pthread_mutex_lock (T.Common.LL.L'Access);
 351          pragma Assert (Result = 0);
 352       end if;
 353    end Write_Lock;
 354
 355    ---------------
 356    -- Read_Lock --
 357    ---------------
 358
 359    procedure Read_Lock
 360      (L                 : not null access Lock;
 361       Ceiling_Violation : out Boolean)
 362    is
 363    begin
 364       Write_Lock (L, Ceiling_Violation);
 365    end Read_Lock;
 366
 367    ------------
 368    -- Unlock --
 369    ------------
 370
 371    procedure Unlock (L : not null access Lock) is
 372       Result : Interfaces.C.int;
 373    begin
 374       Result := pthread_mutex_unlock (L);
 375       pragma Assert (Result = 0);
 376    end Unlock;
 377
 378    procedure Unlock
 379      (L           : not null access RTS_Lock;
 380       Global_Lock : Boolean := False)
 381    is
 382       Result : Interfaces.C.int;
 383    begin
 384       if not Single_Lock or else Global_Lock then
 385          Result := pthread_mutex_unlock (L);
 386          pragma Assert (Result = 0);
 387       end if;
 388    end Unlock;
 389
 390    procedure Unlock (T : Task_Id) is
 391       Result : Interfaces.C.int;
 392    begin
 393       if not Single_Lock then
 394          Result := pthread_mutex_unlock (T.Common.LL.L'Access);
 395          pragma Assert (Result = 0);
 396       end if;
 397    end Unlock;
 398
 399    -----------------
 400    -- Set_Ceiling --
 401    -----------------
 402
 403    --  Dynamic priority ceilings are not supported by the underlying system
 404
 405    procedure Set_Ceiling
 406      (L    : not null access Lock;
 407       Prio : System.Any_Priority)
 408    is
 409       pragma Unreferenced (L, Prio);
 410    begin
 411       null;
 412    end Set_Ceiling;
 413
 414    -----------
 415    -- Sleep --
 416    -----------
 417
 418    procedure Sleep
 419      (Self_ID  : Task_Id;
 420       Reason   : System.Tasking.Task_States)
 421    is
 422       pragma Unreferenced (Reason);
 423
 424       Result : Interfaces.C.int;
 425
 426    begin
 427       pragma Assert (Self_ID = Self);
 428
 429       if Single_Lock then
 430          Result :=
 431            pthread_cond_wait
 432              (Self_ID.Common.LL.CV'Access, Single_RTS_Lock'Access);
 433       else
 434          Result :=
 435            pthread_cond_wait
 436              (Self_ID.Common.LL.CV'Access, Self_ID.Common.LL.L'Access);
 437       end if;
 438
 439       --  EINTR is not considered a failure
 440
 441       pragma Assert (Result = 0 or else Result = EINTR);
 442    end Sleep;
 443
 444    -----------------
 445    -- Timed_Sleep --
 446    -----------------
 447
 448    --  This is for use within the run-time system, so abort is
 449    --  assumed to be already deferred, and the caller should be
 450    --  holding its own ATCB lock.
 451
 452    procedure Timed_Sleep
 453      (Self_ID  : Task_Id;
 454       Time     : Duration;
 455       Mode     : ST.Delay_Modes;
 456       Reason   : System.Tasking.Task_States;
 457       Timedout : out Boolean;
 458       Yielded  : out Boolean)
 459    is
 460       pragma Unreferenced (Reason);
 461
 462       Base_Time  : constant Duration := Monotonic_Clock;
 463       Check_Time : Duration := Base_Time;
 464       Abs_Time   : Duration;
 465       Request    : aliased timespec;
 466       Result     : Interfaces.C.int;
 467
 468    begin
 469       Timedout := True;
 470       Yielded := False;
 471
 472       if Mode = Relative then
 473          Abs_Time := Duration'Min (Time, Max_Sensible_Delay) + Check_Time;
 474       else
 475          Abs_Time := Duration'Min (Check_Time + Max_Sensible_Delay, Time);
 476       end if;
 477
 478       if Abs_Time > Check_Time then
 479          Request := To_Timespec (Abs_Time);
 480
 481          loop
 482             exit when Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level;
 483
 484             if Single_Lock then
 485                Result :=
 486                  pthread_cond_timedwait
 487                    (Self_ID.Common.LL.CV'Access,
 488                     Single_RTS_Lock'Access,
 489                     Request'Access);
 490
 491             else
 492                Result :=
 493                  pthread_cond_timedwait
 494                    (Self_ID.Common.LL.CV'Access,
 495                     Self_ID.Common.LL.L'Access,
 496                     Request'Access);
 497             end if;
 498
 499             Check_Time := Monotonic_Clock;
 500             exit when Abs_Time <= Check_Time or else Check_Time < Base_Time;
 501
 502             if Result = 0 or else Result = EINTR then
 503
 504                --  Somebody may have called Wakeup for us
 505
 506                Timedout := False;
 507                exit;
 508             end if;
 509
 510             pragma Assert (Result = ETIMEDOUT);
 511          end loop;
 512       end if;
 513    end Timed_Sleep;
 514
 515    -----------------
 516    -- Timed_Delay --
 517    -----------------
 518
 519    --  This is for use in implementing delay statements, so we assume the
 520    --  caller is abort-deferred but is holding no locks.
 521
 522    procedure Timed_Delay
 523      (Self_ID : Task_Id;
 524       Time    : Duration;
 525       Mode    : ST.Delay_Modes)
 526    is
 527       Base_Time  : constant Duration := Monotonic_Clock;
 528       Check_Time : Duration := Base_Time;
 529       Abs_Time   : Duration;
 530       Request    : aliased timespec;
 531
 532       Result : Interfaces.C.int;
 533       pragma Warnings (Off, Result);
 534
 535    begin
 536       if Single_Lock then
 537          Lock_RTS;
 538       end if;
 539
 540       Write_Lock (Self_ID);
 541
 542       if Mode = Relative then
 543          Abs_Time := Time + Check_Time;
 544       else
 545          Abs_Time := Duration'Min (Check_Time + Max_Sensible_Delay, Time);
 546       end if;
 547
 548       if Abs_Time > Check_Time then
 549          Request := To_Timespec (Abs_Time);
 550          Self_ID.Common.State := Delay_Sleep;
 551
 552          loop
 553             exit when Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level;
 554
 555             if Single_Lock then
 556                Result := pthread_cond_timedwait
 557                            (Self_ID.Common.LL.CV'Access,
 558                             Single_RTS_Lock'Access,
 559                             Request'Access);
 560             else
 561                Result := pthread_cond_timedwait
 562                            (Self_ID.Common.LL.CV'Access,
 563                             Self_ID.Common.LL.L'Access,
 564                             Request'Access);
 565             end if;
 566
 567             Check_Time := Monotonic_Clock;
 568             exit when Abs_Time <= Check_Time or else Check_Time < Base_Time;
 569
 570             pragma Assert (Result = 0 or else
 571               Result = ETIMEDOUT or else
 572               Result = EINTR);
 573          end loop;
 574
 575          Self_ID.Common.State := Runnable;
 576       end if;
 577
 578       Unlock (Self_ID);
 579
 580       if Single_Lock then
 581          Unlock_RTS;
 582       end if;
 583
 584       Result := sched_yield;
 585    end Timed_Delay;
 586
 587    ---------------------
 588    -- Monotonic_Clock --
 589    ---------------------
 590
 591    function Monotonic_Clock return Duration is
 592       TV     : aliased struct_timeval;
 593       Result : Interfaces.C.int;
 594    begin
 595       Result := gettimeofday (TV'Access, System.Null_Address);
 596       pragma Assert (Result = 0);
 597       return To_Duration (TV);
 598    end Monotonic_Clock;
 599
 600    -------------------
 601    -- RT_Resolution --
 602    -------------------
 603
 604    function RT_Resolution return Duration is
 605    begin
 606       return 10#1.0#E-6;
 607    end RT_Resolution;
 608
 609    ------------
 610    -- Wakeup --
 611    ------------
 612
 613    procedure Wakeup (T : Task_Id; Reason : System.Tasking.Task_States) is
 614       pragma Unreferenced (Reason);
 615       Result : Interfaces.C.int;
 616    begin
 617       Result := pthread_cond_signal (T.Common.LL.CV'Access);
 618       pragma Assert (Result = 0);
 619    end Wakeup;
 620
 621    -----------
 622    -- Yield --
 623    -----------
 624
 625    procedure Yield (Do_Yield : Boolean := True) is
 626       Result : Interfaces.C.int;
 627       pragma Unreferenced (Result);
 628    begin
 629       if Do_Yield then
 630          Result := sched_yield;
 631       end if;
 632    end Yield;
 633
 634    ------------------
 635    -- Set_Priority --
 636    ------------------
 637
 638    procedure Set_Priority
 639      (T                   : Task_Id;
 640       Prio                : System.Any_Priority;
 641       Loss_Of_Inheritance : Boolean := False)
 642    is
 643       pragma Unreferenced (Loss_Of_Inheritance);
 644
 645       Result : Interfaces.C.int;
 646       Param  : aliased struct_sched_param;
 647
 648       function Get_Policy (Prio : System.Any_Priority) return Character;
 649       pragma Import (C, Get_Policy, "__gnat_get_specific_dispatching");
 650       --  Get priority specific dispatching policy
 651
 652       Priority_Specific_Policy : constant Character := Get_Policy (Prio);
 653       --  Upper case first character of the policy name corresponding to the
 654       --  task as set by a Priority_Specific_Dispatching pragma.
 655
 656    begin
 657       T.Common.Current_Priority := Prio;
 658
 659       --  Priorities are 1 .. 99 on GNU/Linux, so we map 0 .. 98 to 1 .. 99
 660
 661       Param.sched_priority := Interfaces.C.int (Prio) + 1;
 662
 663       if Dispatching_Policy = 'R'
 664         or else Priority_Specific_Policy = 'R'
 665         or else Time_Slice_Val > 0
 666       then
 667          Result :=
 668            pthread_setschedparam
 669              (T.Common.LL.Thread, SCHED_RR, Param'Access);
 670
 671       elsif Dispatching_Policy = 'F'
 672         or else Priority_Specific_Policy = 'F'
 673         or else Time_Slice_Val = 0
 674       then
 675          Result :=
 676            pthread_setschedparam
 677              (T.Common.LL.Thread, SCHED_FIFO, Param'Access);
 678
 679       else
 680          Param.sched_priority := 0;
 681          Result :=
 682            pthread_setschedparam
 683              (T.Common.LL.Thread,
 684               SCHED_OTHER, Param'Access);
 685       end if;
 686
 687       pragma Assert (Result = 0 or else Result = EPERM);
 688    end Set_Priority;
 689
 690    ------------------
 691    -- Get_Priority --
 692    ------------------
 693
 694    function Get_Priority (T : Task_Id) return System.Any_Priority is
 695    begin
 696       return T.Common.Current_Priority;
 697    end Get_Priority;
 698
 699    ----------------
 700    -- Enter_Task --
 701    ----------------
 702
 703    procedure Enter_Task (Self_ID : Task_Id) is
 704    begin
 705       if Self_ID.Common.Task_Info /= null
 706         and then Self_ID.Common.Task_Info.CPU_Affinity = No_CPU
 707       then
 708          raise Invalid_CPU_Number;
 709       end if;
 710
 711       Self_ID.Common.LL.Thread := pthread_self;
 712       Self_ID.Common.LL.LWP := lwp_self;
 713
 714       Specific.Set (Self_ID);
 715
 716       if Use_Alternate_Stack then
 717          declare
 718             Stack  : aliased stack_t;
 719             Result : Interfaces.C.int;
 720          begin
 721             Stack.ss_sp    := Self_ID.Common.Task_Alternate_Stack;
 722             Stack.ss_size  := Alternate_Stack_Size;
 723             Stack.ss_flags := 0;
 724             Result := sigaltstack (Stack'Access, null);
 725             pragma Assert (Result = 0);
 726          end;
 727       end if;
 728    end Enter_Task;
 729
 730    --------------
 731    -- New_ATCB --
 732    --------------
 733
 734    function New_ATCB (Entry_Num : Task_Entry_Index) return Task_Id is
 735    begin
 736       return new Ada_Task_Control_Block (Entry_Num);
 737    end New_ATCB;
 738
 739    -------------------
 740    -- Is_Valid_Task --
 741    -------------------
 742
 743    function Is_Valid_Task return Boolean renames Specific.Is_Valid_Task;
 744
 745    -----------------------------
 746    -- Register_Foreign_Thread --
 747    -----------------------------
 748
 749    function Register_Foreign_Thread return Task_Id is
 750    begin
 751       if Is_Valid_Task then
 752          return Self;
 753       else
 754          return Register_Foreign_Thread (pthread_self);
 755       end if;
 756    end Register_Foreign_Thread;
 757
 758    --------------------
 759    -- Initialize_TCB --
 760    --------------------
 761
 762    procedure Initialize_TCB (Self_ID : Task_Id; Succeeded : out Boolean) is
 763       Result : Interfaces.C.int;
 764
 765    begin
 766       --  Give the task a unique serial number
 767
 768       Self_ID.Serial_Number := Next_Serial_Number;
 769       Next_Serial_Number := Next_Serial_Number + 1;
 770       pragma Assert (Next_Serial_Number /= 0);
 771
 772       Self_ID.Common.LL.Thread := To_pthread_t (-1);
 773
 774       if not Single_Lock then
 775          Result := pthread_mutex_init (Self_ID.Common.LL.L'Access,
 776            Mutex_Attr'Access);
 777          pragma Assert (Result = 0 or else Result = ENOMEM);
 778
 779          if Result /= 0 then
 780             Succeeded := False;
 781             return;
 782          end if;
 783       end if;
 784
 785       Result := pthread_cond_init (Self_ID.Common.LL.CV'Access,
 786         Cond_Attr'Access);
 787       pragma Assert (Result = 0 or else Result = ENOMEM);
 788
 789       if Result = 0 then
 790          Succeeded := True;
 791       else
 792          if not Single_Lock then
 793             Result := pthread_mutex_destroy (Self_ID.Common.LL.L'Access);
 794             pragma Assert (Result = 0);
 795          end if;
 796
 797          Succeeded := False;
 798       end if;
 799    end Initialize_TCB;
 800
 801    -----------------
 802    -- Create_Task --
 803    -----------------
 804
 805    procedure Create_Task
 806      (T          : Task_Id;
 807       Wrapper    : System.Address;
 808       Stack_Size : System.Parameters.Size_Type;
 809       Priority   : System.Any_Priority;
 810       Succeeded  : out Boolean)
 811    is
 812       Attributes          : aliased pthread_attr_t;
 813       Adjusted_Stack_Size : Interfaces.C.size_t;
 814       Result              : Interfaces.C.int;
 815
 816    begin
 817       Adjusted_Stack_Size :=
 818          Interfaces.C.size_t (Stack_Size + Alternate_Stack_Size);
 819
 820       Result := pthread_attr_init (Attributes'Access);
 821       pragma Assert (Result = 0 or else Result = ENOMEM);
 822
 823       if Result /= 0 then
 824          Succeeded := False;
 825          return;
 826       end if;
 827
 828       Result :=
 829         pthread_attr_setstacksize
 830           (Attributes'Access, Adjusted_Stack_Size);
 831       pragma Assert (Result = 0);
 832
 833       Result :=
 834         pthread_attr_setdetachstate
 835           (Attributes'Access, PTHREAD_CREATE_DETACHED);
 836       pragma Assert (Result = 0);
 837
 838       --  Since the initial signal mask of a thread is inherited from the
 839       --  creator, and the Environment task has all its signals masked, we
 840       --  do not need to manipulate caller's signal mask at this point.
 841       --  All tasks in RTS will have All_Tasks_Mask initially.
 842
 843       Result := pthread_create
 844         (T.Common.LL.Thread'Access,
 845          Attributes'Access,
 846          Thread_Body_Access (Wrapper),
 847          To_Address (T));
 848       pragma Assert
 849         (Result = 0 or else Result = EAGAIN or else Result = ENOMEM);
 850
 851       if Result /= 0 then
 852          Succeeded := False;
 853          Result := pthread_attr_destroy (Attributes'Access);
 854          pragma Assert (Result = 0);
 855          return;
 856       end if;
 857
 858       Succeeded := True;
 859
 860       --  Handle Task_Info
 861
 862       if T.Common.Task_Info /= null then
 863          if T.Common.Task_Info.CPU_Affinity /= Task_Info.Any_CPU then
 864             Result :=
 865               pthread_setaffinity_np
 866                 (T.Common.LL.Thread,
 867                  CPU_SETSIZE / 8,
 868                  T.Common.Task_Info.CPU_Affinity'Access);
 869             pragma Assert (Result = 0);
 870          end if;
 871       end if;
 872
 873       Result := pthread_attr_destroy (Attributes'Access);
 874       pragma Assert (Result = 0);
 875
 876       Set_Priority (T, Priority);
 877    end Create_Task;
 878
 879    ------------------
 880    -- Finalize_TCB --
 881    ------------------
 882
 883    procedure Finalize_TCB (T : Task_Id) is
 884       Result  : Interfaces.C.int;
 885       Tmp     : Task_Id := T;
 886       Is_Self : constant Boolean := T = Self;
 887
 888       procedure Free is new
 889         Ada.Unchecked_Deallocation (Ada_Task_Control_Block, Task_Id);
 890
 891    begin
 892       if not Single_Lock then
 893          Result := pthread_mutex_destroy (T.Common.LL.L'Access);
 894          pragma Assert (Result = 0);
 895       end if;
 896
 897       Result := pthread_cond_destroy (T.Common.LL.CV'Access);
 898       pragma Assert (Result = 0);
 899
 900       if T.Known_Tasks_Index /= -1 then
 901          Known_Tasks (T.Known_Tasks_Index) := null;
 902       end if;
 903       SC.Invalidate_Stack_Cache (T.Common.Compiler_Data.Pri_Stack_Info'Access);
 904       Free (Tmp);
 905
 906       if Is_Self then
 907          Specific.Set (null);
 908       end if;
 909    end Finalize_TCB;
 910
 911    ---------------
 912    -- Exit_Task --
 913    ---------------
 914
 915    procedure Exit_Task is
 916    begin
 917       Specific.Set (null);
 918    end Exit_Task;
 919
 920    ----------------
 921    -- Abort_Task --
 922    ----------------
 923
 924    procedure Abort_Task (T : Task_Id) is
 925       Result : Interfaces.C.int;
 926    begin
 927       if Abort_Handler_Installed then
 928          Result :=
 929            pthread_kill
 930              (T.Common.LL.Thread,
 931               Signal (System.Interrupt_Management.Abort_Task_Interrupt));
 932          pragma Assert (Result = 0);
 933       end if;
 934    end Abort_Task;
 935
 936    ----------------
 937    -- Initialize --
 938    ----------------
 939
 940    procedure Initialize (S : in out Suspension_Object) is
 941       Result : Interfaces.C.int;
 942
 943    begin
 944       --  Initialize internal state (always to False (RM D.10(6)))
 945
 946       S.State := False;
 947       S.Waiting := False;
 948
 949       --  Initialize internal mutex
 950
 951       Result := pthread_mutex_init (S.L'Access, Mutex_Attr'Access);
 952
 953       pragma Assert (Result = 0 or else Result = ENOMEM);
 954
 955       if Result = ENOMEM then
 956          raise Storage_Error;
 957       end if;
 958
 959       --  Initialize internal condition variable
 960
 961       Result := pthread_cond_init (S.CV'Access, Cond_Attr'Access);
 962
 963       pragma Assert (Result = 0 or else Result = ENOMEM);
 964
 965       if Result /= 0 then
 966          Result := pthread_mutex_destroy (S.L'Access);
 967          pragma Assert (Result = 0);
 968
 969          if Result = ENOMEM then
 970             raise Storage_Error;
 971          end if;
 972       end if;
 973    end Initialize;
 974
 975    --------------
 976    -- Finalize --
 977    --------------
 978
 979    procedure Finalize (S : in out Suspension_Object) is
 980       Result : Interfaces.C.int;
 981
 982    begin
 983       --  Destroy internal mutex
 984
 985       Result := pthread_mutex_destroy (S.L'Access);
 986       pragma Assert (Result = 0);
 987
 988       --  Destroy internal condition variable
 989
 990       Result := pthread_cond_destroy (S.CV'Access);
 991       pragma Assert (Result = 0);
 992    end Finalize;
 993
 994    -------------------
 995    -- Current_State --
 996    -------------------
 997
 998    function Current_State (S : Suspension_Object) return Boolean is
 999    begin
1000       --  We do not want to use lock on this read operation. State is marked
1001       --  as Atomic so that we ensure that the value retrieved is correct.
1002
1003       return S.State;
1004    end Current_State;
1005
1006    ---------------
1007    -- Set_False --
1008    ---------------
1009
1010    procedure Set_False (S : in out Suspension_Object) is
1011       Result : Interfaces.C.int;
1012
1013    begin
1014       SSL.Abort_Defer.all;
1015
1016       Result := pthread_mutex_lock (S.L'Access);
1017       pragma Assert (Result = 0);
1018
1019       S.State := False;
1020
1021       Result := pthread_mutex_unlock (S.L'Access);
1022       pragma Assert (Result = 0);
1023
1024       SSL.Abort_Undefer.all;
1025    end Set_False;
1026
1027    --------------
1028    -- Set_True --
1029    --------------
1030
1031    procedure Set_True (S : in out Suspension_Object) is
1032       Result : Interfaces.C.int;
1033
1034    begin
1035       SSL.Abort_Defer.all;
1036
1037       Result := pthread_mutex_lock (S.L'Access);
1038       pragma Assert (Result = 0);
1039
1040       --  If there is already a task waiting on this suspension object then
1041       --  we resume it, leaving the state of the suspension object to False,
1042       --  as it is specified in ARM D.10 par. 9. Otherwise, it just leaves
1043       --  the state to True.
1044
1045       if S.Waiting then
1046          S.Waiting := False;
1047          S.State := False;
1048
1049          Result := pthread_cond_signal (S.CV'Access);
1050          pragma Assert (Result = 0);
1051
1052       else
1053          S.State := True;
1054       end if;
1055
1056       Result := pthread_mutex_unlock (S.L'Access);
1057       pragma Assert (Result = 0);
1058
1059       SSL.Abort_Undefer.all;
1060    end Set_True;
1061
1062    ------------------------
1063    -- Suspend_Until_True --
1064    ------------------------
1065
1066    procedure Suspend_Until_True (S : in out Suspension_Object) is
1067       Result : Interfaces.C.int;
1068
1069    begin
1070       SSL.Abort_Defer.all;
1071
1072       Result := pthread_mutex_lock (S.L'Access);
1073       pragma Assert (Result = 0);
1074
1075       if S.Waiting then
1076
1077          --  Program_Error must be raised upon calling Suspend_Until_True
1078          --  if another task is already waiting on that suspension object
1079          --  (RM D.10(10)).
1080
1081          Result := pthread_mutex_unlock (S.L'Access);
1082          pragma Assert (Result = 0);
1083
1084          SSL.Abort_Undefer.all;
1085
1086          raise Program_Error;
1087       else
1088          --  Suspend the task if the state is False. Otherwise, the task
1089          --  continues its execution, and the state of the suspension object
1090          --  is set to False (ARM D.10 par. 9).
1091
1092          if S.State then
1093             S.State := False;
1094          else
1095             S.Waiting := True;
1096
1097             loop
1098                --  Loop in case pthread_cond_wait returns earlier than expected
1099                --  (e.g. in case of EINTR caused by a signal). This should not
1100                --  happen with the current Linux implementation of pthread, but
1101                --  POSIX does not guarantee it, so this may change in the
1102                --  future.
1103
1104                Result := pthread_cond_wait (S.CV'Access, S.L'Access);
1105                pragma Assert (Result = 0 or else Result = EINTR);
1106
1107                exit when not S.Waiting;
1108             end loop;
1109          end if;
1110
1111          Result := pthread_mutex_unlock (S.L'Access);
1112          pragma Assert (Result = 0);
1113
1114          SSL.Abort_Undefer.all;
1115       end if;
1116    end Suspend_Until_True;
1117
1118    ----------------
1119    -- Check_Exit --
1120    ----------------
1121
1122    --  Dummy version
1123
1124    function Check_Exit (Self_ID : ST.Task_Id) return Boolean is
1125       pragma Unreferenced (Self_ID);
1126    begin
1127       return True;
1128    end Check_Exit;
1129
1130    --------------------
1131    -- Check_No_Locks --
1132    --------------------
1133
1134    function Check_No_Locks (Self_ID : ST.Task_Id) return Boolean is
1135       pragma Unreferenced (Self_ID);
1136    begin
1137       return True;
1138    end Check_No_Locks;
1139
1140    ----------------------
1141    -- Environment_Task --
1142    ----------------------
1143
1144    function Environment_Task return Task_Id is
1145    begin
1146       return Environment_Task_Id;
1147    end Environment_Task;
1148
1149    ------------------
1150    -- Suspend_Task --
1151    ------------------
1152
1153    function Suspend_Task
1154      (T           : ST.Task_Id;
1155       Thread_Self : Thread_Id) return Boolean
1156    is
1157    begin
1158       if T.Common.LL.Thread /= Thread_Self then
1159          return pthread_kill (T.Common.LL.Thread, SIGSTOP) = 0;
1160       else
1161          return True;
1162       end if;
1163    end Suspend_Task;
1164
1165    -----------------
1166    -- Resume_Task --
1167    -----------------
1168
1169    function Resume_Task
1170      (T           : ST.Task_Id;
1171       Thread_Self : Thread_Id) return Boolean
1172    is
1173    begin
1174       if T.Common.LL.Thread /= Thread_Self then
1175          return pthread_kill (T.Common.LL.Thread, SIGCONT) = 0;
1176       else
1177          return True;
1178       end if;
1179    end Resume_Task;
1180
1181    --------------------
1182    -- Stop_All_Tasks --
1183    --------------------
1184
1185    procedure Stop_All_Tasks is
1186    begin
1187       null;
1188    end Stop_All_Tasks;
1189
1190    ---------------
1191    -- Stop_Task --
1192    ---------------
1193
1194    function Stop_Task (T : ST.Task_Id) return Boolean is
1195       pragma Unreferenced (T);
1196    begin
1197       return False;
1198    end Stop_Task;
1199
1200    -------------------
1201    -- Continue_Task --
1202    -------------------
1203
1204    function Continue_Task (T : ST.Task_Id) return Boolean is
1205       pragma Unreferenced (T);
1206    begin
1207       return False;
1208    end Continue_Task;
1209
1210    ----------------
1211    -- Initialize --
1212    ----------------
1213
1214    procedure Initialize (Environment_Task : Task_Id) is
1215       act     : aliased struct_sigaction;
1216       old_act : aliased struct_sigaction;
1217       Tmp_Set : aliased sigset_t;
1218       Result  : Interfaces.C.int;
1219       --  Whether to use an alternate signal stack for stack overflows
1220
1221       function State
1222         (Int : System.Interrupt_Management.Interrupt_ID) return Character;
1223       pragma Import (C, State, "__gnat_get_interrupt_state");
1224       --  Get interrupt state.  Defined in a-init.c
1225       --  The input argument is the interrupt number,
1226       --  and the result is one of the following:
1227
1228       Default : constant Character := 's';
1229       --    'n'   this interrupt not set by any Interrupt_State pragma
1230       --    'u'   Interrupt_State pragma set state to User
1231       --    'r'   Interrupt_State pragma set state to Runtime
1232       --    's'   Interrupt_State pragma set state to System (use "default"
1233       --           system handler)
1234
1235    begin
1236       Environment_Task_Id := Environment_Task;
1237
1238       Interrupt_Management.Initialize;
1239
1240       --  Prepare the set of signals that should be unblocked in all tasks
1241
1242       Result := sigemptyset (Unblocked_Signal_Mask'Access);
1243       pragma Assert (Result = 0);
1244
1245       for J in Interrupt_Management.Interrupt_ID loop
1246          if System.Interrupt_Management.Keep_Unmasked (J) then
1247             Result := sigaddset (Unblocked_Signal_Mask'Access, Signal (J));
1248             pragma Assert (Result = 0);
1249          end if;
1250       end loop;
1251
1252       Result := pthread_mutexattr_init (Mutex_Attr'Access);
1253       pragma Assert (Result = 0);
1254
1255       Result := pthread_condattr_init (Cond_Attr'Access);
1256       pragma Assert (Result = 0);
1257
1258       Initialize_Lock (Single_RTS_Lock'Access, RTS_Lock_Level);
1259
1260       --  Initialize the global RTS lock
1261
1262       Specific.Initialize (Environment_Task);
1263
1264       if Use_Alternate_Stack then
1265          Environment_Task.Common.Task_Alternate_Stack :=
1266            Alternate_Stack'Address;
1267       end if;
1268
1269       --  Make environment task known here because it doesn't go through
1270       --  Activate_Tasks, which does it for all other tasks.
1271
1272       Known_Tasks (Known_Tasks'First) := Environment_Task;
1273       Environment_Task.Known_Tasks_Index := Known_Tasks'First;
1274
1275       Enter_Task (Environment_Task);
1276
1277       if State
1278           (System.Interrupt_Management.Abort_Task_Interrupt) /= Default
1279       then
1280          act.sa_flags := 0;
1281          act.sa_handler := Abort_Handler'Address;
1282
1283          Result := sigemptyset (Tmp_Set'Access);
1284          pragma Assert (Result = 0);
1285          act.sa_mask := Tmp_Set;
1286
1287          Result :=
1288            sigaction
1289            (Signal (Interrupt_Management.Abort_Task_Interrupt),
1290             act'Unchecked_Access,
1291             old_act'Unchecked_Access);
1292          pragma Assert (Result = 0);
1293          Abort_Handler_Installed := True;
1294       end if;
1295    end Initialize;
1296
1297 end System.Task_Primitives.Operations;