gcc/ada/s-stchop-vxworks.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --     S Y S T E M . S T A C K _ C H E C K I N G . O P E R A T I O N S      --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1999-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the VxWorks version of this package.
  35 --  This file should be kept synchronized with the general implementation
  36 --  provided by s-stchop.adb.
  37
  38 pragma Restrictions (No_Elaboration_Code);
  39 --  We want to guarantee the absence of elaboration code because the
  40 --  binder does not handle references to this package.
  41
  42 with Ada.Exceptions;
  43
  44 with System.Storage_Elements; use System.Storage_Elements;
  45 with System.Parameters; use System.Parameters;
  46 with System.Soft_Links;
  47 with Interfaces.C;
  48 with System.OS_Interface;
  49
  50 package body System.Stack_Checking.Operations is
  51
  52    --  In order to have stack checking working appropriately on
  53    --  VxWorks we need to extract the stack size information from the
  54    --  VxWorks kernel itself. It means that the library for showing
  55    --  task-related information needs to be linked into the VxWorks
  56    --  system, when using stack checking. The TaskShow library can be
  57    --  linked into the VxWorks system by either:
  58    --    * defining INCLUDE_SHOW_ROUTINES in config.h when using
  59    --      configuration header files, or
  60    --    * selecting INCLUDE_TASK_SHOW when using the Tornado project
  61    --      facility.
  62
  63    function Set_Stack_Info (Stack : access Stack_Access) return Stack_Access;
  64
  65    --  The function Set_Stack_Info is the actual function that updates
  66    --  the cache containing a pointer to the Stack_Info. It may also
  67    --  be used for detecting asynchronous abort in combination with
  68    --  Invalidate_Self_Cache.
  69
  70    --  Set_Stack_Info should do the following things in order:
  71    --     1) Get the Stack_Access value for the current task
  72    --     2) Set Stack.all to the value obtained in 1)
  73    --     3) Optionally Poll to check for asynchronous abort
  74
  75    --  This order is important because if at any time a write to
  76    --  the stack cache is pending, that write should be followed
  77    --  by a Poll to prevent loosing signals.
  78
  79    --  Note: This function must be compiled with Polling turned off
  80
  81    --  Note: on systems like VxWorks and OS/2 with real thread-local storage,
  82    --        Set_Stack_Info should return an access value for such local
  83    --        storage. In those cases the cache will always be up-to-date.
  84
  85    --  The following constants should be imported from some system-specific
  86    --  constants package. The constants must be static for performance reasons.
  87
  88    ----------------------------
  89    -- Invalidate_Stack_Cache --
  90    ----------------------------
  91
  92    procedure Invalidate_Stack_Cache (Any_Stack : Stack_Access) is
  93       pragma Warnings (Off, Any_Stack);
  94    begin
  95       Cache := Null_Stack;
  96    end Invalidate_Stack_Cache;
  97
  98    --------------------
  99    -- Set_Stack_Info --
 100    --------------------
 101
 102    function Set_Stack_Info
 103      (Stack : access Stack_Access) return Stack_Access
 104    is
 105
 106       --  Task descriptor that is handled internally by the VxWorks kernel
 107       type Task_Descriptor is record
 108          T_Id            : Interfaces.C.int; -- task identifier
 109          Td_Name         : System.Address; -- task name
 110          Td_Priority     : Interfaces.C.int; -- task priority
 111          Td_Status       : Interfaces.C.int; -- task status
 112          Td_Options      : Interfaces.C.int; -- task option bits (see below)
 113          Td_Entry        : System.Address; -- original entry point of task
 114          Td_Sp           : System.Address; -- saved stack pointer
 115          Td_PStackBase   : System.Address; -- the bottom of the stack
 116          Td_PStackLimit  : System.Address; -- the effective end of the stack
 117          Td_PStackEnd    : System.Address; -- the actual end of the stack
 118          Td_StackSize    : Interfaces.C.int; -- size of stack in bytes
 119          Td_StackCurrent : Interfaces.C.int; -- current stack usage in bytes
 120          Td_StackHigh    : Interfaces.C.int; -- maximum stack usage in bytes
 121          Td_StackMargin  : Interfaces.C.int; -- current stack margin in bytes
 122          Td_ErrorStatus  : Interfaces.C.int; -- most recent task error status
 123          Td_Delay        : Interfaces.C.int; -- delay/timeout ticks
 124       end record;
 125
 126       --  This VxWorks procedure fills in a specified task descriptor
 127       --  for a specified task.
 128       procedure TaskInfoGet (T_Id : System.OS_Interface.t_id;
 129                              Task_Desc : access Task_Descriptor);
 130       pragma Import (C, TaskInfoGet, "taskInfoGet");
 131
 132       My_Stack  : Stack_Access;
 133       Task_Desc : aliased Task_Descriptor;
 134
 135    begin
 136       --  The order of steps 1 .. 3 is important, see specification.
 137
 138       --  1) Get the Stack_Access value for the current task
 139
 140       My_Stack := Soft_Links.Get_Stack_Info.all;
 141
 142       if My_Stack.Base = Null_Address then
 143
 144          --  First invocation. Ask the VxWorks kernel about stack
 145          --  values.
 146          TaskInfoGet (System.OS_Interface.taskIdSelf, Task_Desc'Access);
 147
 148          My_Stack.Size := System.Storage_Elements.Storage_Offset
 149            (Task_Desc.Td_StackSize);
 150          My_Stack.Base := Task_Desc.Td_PStackBase;
 151          My_Stack.Limit := Task_Desc.Td_PStackLimit;
 152
 153       end if;
 154
 155       --  2) Set Stack.all to the value obtained in 1)
 156
 157       Stack.all := My_Stack;
 158
 159       --  3) Optionally Poll to check for asynchronous abort
 160
 161       if Soft_Links.Check_Abort_Status.all /= 0 then
 162          raise Standard'Abort_Signal;
 163       end if;
 164
 165       return My_Stack; -- Never trust the cached value, but return local copy!
 166    end Set_Stack_Info;
 167
 168    --------------------
 169    -- Set_Stack_Size --
 170    --------------------
 171
 172    --  Specify the stack size for the current frame.
 173
 174    procedure Set_Stack_Size
 175      (Stack_Size : System.Storage_Elements.Storage_Offset)
 176    is
 177       My_Stack      : Stack_Access;
 178       Frame_Address : constant System.Address := My_Stack'Address;
 179
 180    begin
 181       My_Stack := Stack_Check (Frame_Address);
 182
 183       if Stack_Grows_Down then
 184          My_Stack.Limit := My_Stack.Base - Stack_Size;
 185       else
 186          My_Stack.Limit := My_Stack.Base + Stack_Size;
 187       end if;
 188    end Set_Stack_Size;
 189
 190    -----------------
 191    -- Stack_Check --
 192    -----------------
 193
 194    function Stack_Check
 195      (Stack_Address : System.Address) return Stack_Access
 196    is
 197       type Frame_Marker is null record;
 198       Marker        : Frame_Marker;
 199       Cached_Stack  : constant Stack_Access := Cache;
 200       Frame_Address : constant System.Address := Marker'Address;
 201
 202    begin
 203       --  This function first does a "cheap" check which is correct
 204       --  if it succeeds. In case of failure, the full check is done.
 205       --  Ideally the cheap check should be done in an optimized manner,
 206       --  or be inlined.
 207
 208       if (Stack_Grows_Down and then
 209             (Frame_Address <= Cached_Stack.Base
 210                and
 211              Stack_Address > Cached_Stack.Limit))
 212         or else
 213          (not Stack_Grows_Down and then
 214             (Frame_Address >= Cached_Stack.Base
 215                and
 216              Stack_Address < Cached_Stack.Limit))
 217       then
 218          --  Cached_Stack is valid as it passed the stack check
 219          return Cached_Stack;
 220       end if;
 221
 222       Full_Check :
 223       declare
 224          My_Stack : constant Stack_Access := Set_Stack_Info (Cache'Access);
 225          --  At this point Stack.all might already be invalid, so
 226          --  it is essential to use our local copy of Stack!
 227
 228       begin
 229          if (Stack_Grows_Down and then
 230                   Stack_Address < My_Stack.Limit)
 231            or else
 232             (not Stack_Grows_Down and then
 233                   Stack_Address > My_Stack.Limit)
 234          then
 235             Ada.Exceptions.Raise_Exception
 236               (E       => Storage_Error'Identity,
 237                Message => "stack overflow detected");
 238          end if;
 239
 240          return My_Stack;
 241       end Full_Check;
 242    end Stack_Check;
 243
 244    ------------------------
 245    -- Update_Stack_Cache --
 246    ------------------------
 247
 248    procedure Update_Stack_Cache (Stack : Stack_Access) is
 249    begin
 250       if not Multi_Processor then
 251          Cache := Stack;
 252       end if;
 253    end Update_Stack_Cache;
 254
 255 end System.Stack_Checking.Operations;