gcc/ada/s-stalib.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --              S Y S T E M . S T A N D A R D _ L I B R A R Y               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This package is included in all programs. It contains declarations that
  33 --  are required to be part of every Ada program. A special mechanism is
  34 --  required to ensure that these are loaded, since it may be the case in
  35 --  some programs that the only references to these required packages are
  36 --  from C code or from code generated directly by Gigi, and in both cases
  37 --  the binder is not aware of such references.
  38
  39 --  System.Standard_Library also includes data that must be present in every
  40 --  program, in particular data for all the standard exceptions, and also some
  41 --  subprograms that must be present in every program.
  42
  43 --  The binder unconditionally includes s-stalib.ali, which ensures that this
  44 --  package and the packages it references are included in all Ada programs,
  45 --  together with the included data.
  46
  47 pragma Compiler_Unit;
  48
  49 pragma Polling (Off);
  50 --  We must turn polling off for this unit, because otherwise we get
  51 --  elaboration circularities with Ada.Exceptions if polling is on.
  52
  53 with Ada.Unchecked_Conversion;
  54
  55 package System.Standard_Library is
  56    pragma Warnings (Off);
  57    pragma Preelaborate_05;
  58    pragma Warnings (On);
  59
  60    type Big_String_Ptr is access all String (Positive);
  61    for Big_String_Ptr'Storage_Size use 0;
  62    --  A non-fat pointer type for null terminated strings
  63
  64    function To_Ptr is
  65      new Ada.Unchecked_Conversion (System.Address, Big_String_Ptr);
  66
  67    ---------------------------------------------
  68    -- Type For Enumeration Image Index Tables --
  69    ---------------------------------------------
  70
  71    --  Note: these types are declared at the start of this unit, since
  72    --  they must appear before any enumeration types declared in this
  73    --  unit. Note that the spec of system is already elaborated at
  74    --  this point (since we are a child of system), which means that
  75    --  enumeration types in package System cannot use these types.
  76
  77    type Image_Index_Table_8 is
  78      array (Integer range <>) of Short_Short_Integer;
  79    type Image_Index_Table_16 is
  80      array (Integer range <>) of Short_Integer;
  81    type Image_Index_Table_32 is
  82      array (Integer range <>) of Integer;
  83    --  These types are used to generate the index vector used for enumeration
  84    --  type image tables. See spec of Exp_Imgv in the main GNAT sources for a
  85    --  full description of the data structures that are used here.
  86
  87    -------------------------------------
  88    -- Exception Declarations and Data --
  89    -------------------------------------
  90
  91    type Raise_Action is access procedure;
  92    --  A pointer to a procedure used in the Raise_Hook field
  93
  94    type Exception_Data;
  95    type Exception_Data_Ptr is access all Exception_Data;
  96    --  An equivalent of Exception_Id that is public
  97
  98    type Exception_Code is mod 2 ** Integer'Size;
  99    --  A scalar value bound to some exception data. Typically used for
 100    --  imported or exported exceptions on VMS. Having a separate type for this
 101    --  is useful to enforce consistency throughout the various run-time units
 102    --  handling such codes, and having it unsigned is the most appropriate
 103    --  choice for it's currently single use on VMS.
 104
 105    --  ??? The construction in Cstand has no way to access the proper type
 106    --  node for Exception_Code, and currently uses Standard_Unsigned as a
 107    --  fallback. The representations shall match, and the size clause below
 108    --  is aimed at ensuring that.
 109
 110    for Exception_Code'Size use Integer'Size;
 111
 112    --  The following record defines the underlying representation of exceptions
 113
 114    --  WARNING! Any changes to this may need to be reflected in the following
 115    --  locations in the compiler and runtime code:
 116
 117    --    1. The Internal_Exception routine in s-exctab.adb
 118    --    2. The processing in gigi that tests Not_Handled_By_Others
 119    --    3. Expand_N_Exception_Declaration in Exp_Ch11
 120    --    4. The construction of the exception type in Cstand
 121
 122    type Exception_Data is record
 123       Not_Handled_By_Others : Boolean;
 124       --  Normally set False, indicating that the exception is handled in the
 125       --  usual way by others (i.e. an others handler handles the exception).
 126       --  Set True to indicate that this exception is not caught by others
 127       --  handlers, but must be explicitly named in a handler. This latter
 128       --  setting is currently used by the Abort_Signal.
 129
 130       Lang : Character;
 131       --  A character indicating the language raising the exception.
 132       --  Set to "A" for exceptions defined by an Ada program.
 133       --  Set to "V" for imported VMS exceptions.
 134
 135       Name_Length : Natural;
 136       --  Length of fully expanded name of exception
 137
 138       Full_Name : System.Address;
 139       --  Fully expanded name of exception, null terminated
 140       --  You can use To_Ptr to convert this to a string.
 141
 142       HTable_Ptr : Exception_Data_Ptr;
 143       --  Hash table pointer used to link entries together in the hash table
 144       --  built (by Register_Exception in s-exctab.adb) for converting between
 145       --  identities and names.
 146
 147       Import_Code : Exception_Code;
 148       --  Value for imported exceptions. Needed only for the handling of
 149       --  Import/Export_Exception for the VMS case, but present in all
 150       --  implementations (we might well extend this mechanism for other
 151       --  systems in the future).
 152
 153       Raise_Hook : Raise_Action;
 154       --  This field can be used to place a "hook" on an exception. If the
 155       --  value is non-null, then it points to a procedure which is called
 156       --  whenever the exception is raised. This call occurs immediately,
 157       --  before any other actions taken by the raise (and in particular
 158       --  before any unwinding of the stack occurs).
 159    end record;
 160
 161    --  Definitions for standard predefined exceptions defined in Standard,
 162
 163    --  Why are the NULs necessary here, seems like they should not be
 164    --  required, since Gigi is supposed to add a Nul to each name ???
 165
 166    Constraint_Error_Name : constant String := "CONSTRAINT_ERROR" & ASCII.NUL;
 167    Program_Error_Name    : constant String := "PROGRAM_ERROR"    & ASCII.NUL;
 168    Storage_Error_Name    : constant String := "STORAGE_ERROR"    & ASCII.NUL;
 169    Tasking_Error_Name    : constant String := "TASKING_ERROR"    & ASCII.NUL;
 170    Abort_Signal_Name     : constant String := "_ABORT_SIGNAL"    & ASCII.NUL;
 171
 172    Numeric_Error_Name    : constant String := "NUMERIC_ERROR"    & ASCII.NUL;
 173    --  This is used only in the Ada 83 case, but it is not worth having a
 174    --  separate version of s-stalib.ads for use in Ada 83 mode.
 175
 176    Constraint_Error_Def : aliased Exception_Data :=
 177      (Not_Handled_By_Others => False,
 178       Lang                  => 'A',
 179       Name_Length           => Constraint_Error_Name'Length,
 180       Full_Name             => Constraint_Error_Name'Address,
 181       HTable_Ptr            => null,
 182       Import_Code           => 0,
 183       Raise_Hook            => null);
 184
 185    Numeric_Error_Def : aliased Exception_Data :=
 186      (Not_Handled_By_Others => False,
 187       Lang                  => 'A',
 188       Name_Length           => Numeric_Error_Name'Length,
 189       Full_Name             => Numeric_Error_Name'Address,
 190       HTable_Ptr            => null,
 191       Import_Code           => 0,
 192       Raise_Hook            => null);
 193
 194    Program_Error_Def : aliased Exception_Data :=
 195      (Not_Handled_By_Others => False,
 196       Lang                  => 'A',
 197       Name_Length           => Program_Error_Name'Length,
 198       Full_Name             => Program_Error_Name'Address,
 199       HTable_Ptr            => null,
 200       Import_Code           => 0,
 201       Raise_Hook            => null);
 202
 203    Storage_Error_Def : aliased Exception_Data :=
 204      (Not_Handled_By_Others => False,
 205       Lang                  => 'A',
 206       Name_Length           => Storage_Error_Name'Length,
 207       Full_Name             => Storage_Error_Name'Address,
 208       HTable_Ptr            => null,
 209       Import_Code           => 0,
 210       Raise_Hook            => null);
 211
 212    Tasking_Error_Def : aliased Exception_Data :=
 213      (Not_Handled_By_Others => False,
 214       Lang                  => 'A',
 215       Name_Length           => Tasking_Error_Name'Length,
 216       Full_Name             => Tasking_Error_Name'Address,
 217       HTable_Ptr            => null,
 218       Import_Code           => 0,
 219       Raise_Hook            => null);
 220
 221    Abort_Signal_Def : aliased Exception_Data :=
 222      (Not_Handled_By_Others => True,
 223       Lang                  => 'A',
 224       Name_Length           => Abort_Signal_Name'Length,
 225       Full_Name             => Abort_Signal_Name'Address,
 226       HTable_Ptr            => null,
 227       Import_Code           => 0,
 228       Raise_Hook            => null);
 229
 230    pragma Export (C, Constraint_Error_Def, "constraint_error");
 231    pragma Export (C, Numeric_Error_Def,    "numeric_error");
 232    pragma Export (C, Program_Error_Def,    "program_error");
 233    pragma Export (C, Storage_Error_Def,    "storage_error");
 234    pragma Export (C, Tasking_Error_Def,    "tasking_error");
 235    pragma Export (C, Abort_Signal_Def,     "_abort_signal");
 236
 237    Local_Partition_ID : Natural := 0;
 238    --  This variable contains the local Partition_ID that will be used when
 239    --  building exception occurrences. In distributed mode, it will be
 240    --  set by each partition to the correct value during the elaboration.
 241
 242    type Exception_Trace_Kind is
 243      (RM_Convention,
 244       --  No particular trace is requested, only unhandled exceptions
 245       --  in the environment task (following the RM) will be printed.
 246       --  This is the default behavior.
 247
 248       Every_Raise,
 249       --  Denotes every possible raise event, either explicit or due to
 250       --  a specific language rule, within the context of a task or not.
 251
 252       Unhandled_Raise
 253       --  Denotes the raise events corresponding to exceptions for which
 254       --  there is no user defined handler.
 255      );
 256    --  Provide a way to denote different kinds of automatic traces related
 257    --  to exceptions that can be requested.
 258
 259    Exception_Trace : Exception_Trace_Kind := RM_Convention;
 260    pragma Atomic (Exception_Trace);
 261    --  By default, follow the RM convention
 262
 263    -----------------
 264    -- Subprograms --
 265    -----------------
 266
 267    procedure Abort_Undefer_Direct;
 268    pragma Inline (Abort_Undefer_Direct);
 269    --  A little procedure that just calls Abort_Undefer.all, for use in
 270    --  clean up procedures, which only permit a simple subprogram name.
 271
 272    procedure Adafinal;
 273    --  Performs the Ada Runtime finalization the first time it is invoked.
 274    --  All subsequent calls are ignored.
 275
 276 end System.Standard_Library;