gcc/ada/s-regpat.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                          G N A T . R E G P A T                           --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --               Copyright (C) 1986 by University of Toronto.               --
  10 --                      Copyright (C) 1999-2007, AdaCore                    --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  21 -- Boston, MA 02110-1301, USA.                                              --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is an altered Ada 95 version of the original V8 style regular
  36 --  expression library written in C by Henry Spencer. Apart from the
  37 --  translation to Ada, the interface has been considerably changed to
  38 --  use the Ada String type instead of C-style nul-terminated strings.
  39
  40 --  Beware that some of this code is subtly aware of the way operator
  41 --  precedence is structured in regular expressions. Serious changes in
  42 --  regular-expression syntax might require a total rethink.
  43
  44 with System.IO;               use System.IO;
  45 with Ada.Characters.Handling; use Ada.Characters.Handling;
  46 with Ada.Unchecked_Conversion;
  47
  48 package body System.Regpat is
  49
  50    MAGIC : constant Character := Character'Val (10#0234#);
  51    --  The first byte of the regexp internal "program" is actually
  52    --  this magic number; the start node begins in the second byte.
  53    --
  54    --  This is used to make sure that a regular expression was correctly
  55    --  compiled.
  56
  57    ----------------------------
  58    -- Implementation details --
  59    ----------------------------
  60
  61    --  This is essentially a linear encoding of a nondeterministic
  62    --  finite-state machine, also known as syntax charts or
  63    --  "railroad normal form" in parsing technology.
  64
  65    --  Each node is an opcode plus a "next" pointer, possibly plus an
  66    --  operand. "Next" pointers of all nodes except BRANCH implement
  67    --  concatenation; a "next" pointer with a BRANCH on both ends of it
  68    --  is connecting two alternatives.
  69
  70    --  The operand of some types of node is a literal string; for others,
  71    --  it is a node leading into a sub-FSM. In particular, the operand of
  72    --  a BRANCH node is the first node of the branch.
  73    --  (NB this is *not* a tree structure:  the tail of the branch connects
  74    --  to the thing following the set of BRANCHes).
  75
  76    --  You can see the exact byte-compiled version by using the Dump
  77    --  subprogram. However, here are a few examples:
  78
  79    --  (a|b):  1 : MAGIC
  80    --          2 : BRANCH  (next at  10)
  81    --          5 :    EXACT  (next at  18)   operand=a
  82    --         10 : BRANCH  (next at  18)
  83    --         13 :    EXACT  (next at  18)   operand=b
  84    --         18 : EOP  (next at 0)
  85    --
  86    --  (ab)*:  1 : MAGIC
  87    --          2 : CURLYX  (next at  26)  { 0, 32767}
  88    --          9 :    OPEN 1  (next at  13)
  89    --         13 :       EXACT  (next at  19)   operand=ab
  90    --         19 :    CLOSE 1  (next at  23)
  91    --         23 :    WHILEM  (next at 0)
  92    --         26 : NOTHING  (next at  29)
  93    --         29 : EOP  (next at 0)
  94
  95    --  The opcodes are:
  96
  97    type Opcode is
  98
  99       --  Name          Operand?  Meaning
 100
 101      (EOP,        -- no        End of program
 102       MINMOD,     -- no        Next operator is not greedy
 103
 104       --  Classes of characters
 105
 106       ANY,        -- no        Match any one character except newline
 107       SANY,       -- no        Match any character, including new line
 108       ANYOF,      -- class     Match any character in this class
 109       EXACT,      -- str       Match this string exactly
 110       EXACTF,     -- str       Match this string (case-folding is one)
 111       NOTHING,    -- no        Match empty string
 112       SPACE,      -- no        Match any whitespace character
 113       NSPACE,     -- no        Match any non-whitespace character
 114       DIGIT,      -- no        Match any numeric character
 115       NDIGIT,     -- no        Match any non-numeric character
 116       ALNUM,      -- no        Match any alphanumeric character
 117       NALNUM,     -- no        Match any non-alphanumeric character
 118
 119       --  Branches
 120
 121       BRANCH,     -- node      Match this alternative, or the next
 122
 123       --  Simple loops (when the following node is one character in length)
 124
 125       STAR,       -- node      Match this simple thing 0 or more times
 126       PLUS,       -- node      Match this simple thing 1 or more times
 127       CURLY,      -- 2num node Match this simple thing between n and m times.
 128
 129       --  Complex loops
 130
 131       CURLYX,     -- 2num node Match this complex thing {n,m} times
 132       --                       The nums are coded on two characters each
 133
 134       WHILEM,     -- no        Do curly processing and see if rest matches
 135
 136       --  Matches after or before a word
 137
 138       BOL,        -- no        Match "" at beginning of line
 139       MBOL,       -- no        Same, assuming mutiline (match after \n)
 140       SBOL,       -- no        Same, assuming single line (don't match at \n)
 141       EOL,        -- no        Match "" at end of line
 142       MEOL,       -- no        Same, assuming mutiline (match before \n)
 143       SEOL,       -- no        Same, assuming single line (don't match at \n)
 144
 145       BOUND,      -- no        Match "" at any word boundary
 146       NBOUND,     -- no        Match "" at any word non-boundary
 147
 148       --  Parenthesis groups handling
 149
 150       REFF,       -- num       Match some already matched string, folded
 151       OPEN,       -- num       Mark this point in input as start of #n
 152       CLOSE);     -- num       Analogous to OPEN
 153
 154    for Opcode'Size use 8;
 155
 156    --  Opcode notes:
 157
 158    --  BRANCH
 159    --    The set of branches constituting a single choice are hooked
 160    --    together with their "next" pointers, since precedence prevents
 161    --    anything being concatenated to any individual branch. The
 162    --    "next" pointer of the last BRANCH in a choice points to the
 163    --    thing following the whole choice. This is also where the
 164    --    final "next" pointer of each individual branch points; each
 165    --    branch starts with the operand node of a BRANCH node.
 166
 167    --  STAR,PLUS
 168    --    '?', and complex '*' and '+', are implemented with CURLYX.
 169    --    branches. Simple cases (one character per match) are implemented with
 170    --    STAR and PLUS for speed and to minimize recursive plunges.
 171
 172    --  OPEN,CLOSE
 173    --    ...are numbered at compile time.
 174
 175    --  EXACT, EXACTF
 176    --    There are in fact two arguments, the first one is the length (minus
 177    --    one of the string argument), coded on one character, the second
 178    --    argument is the string itself, coded on length + 1 characters.
 179
 180    --  A node is one char of opcode followed by two chars of "next" pointer.
 181    --  "Next" pointers are stored as two 8-bit pieces, high order first. The
 182    --  value is a positive offset from the opcode of the node containing it.
 183    --  An operand, if any, simply follows the node. (Note that much of the
 184    --  code generation knows about this implicit relationship.)
 185
 186    --  Using two bytes for the "next" pointer is vast overkill for most
 187    --  things, but allows patterns to get big without disasters.
 188
 189    -----------------------
 190    -- Character classes --
 191    -----------------------
 192    --  This is the implementation for character classes ([...]) in the
 193    --  syntax for regular expressions. Each character (0..256) has an
 194    --  entry into the table. This makes for a very fast matching
 195    --  algorithm.
 196
 197    type Class_Byte is mod 256;
 198    type Character_Class is array (Class_Byte range 0 .. 31) of Class_Byte;
 199
 200    type Bit_Conversion_Array is array (Class_Byte range 0 .. 7) of Class_Byte;
 201    Bit_Conversion : constant Bit_Conversion_Array :=
 202                       (1, 2, 4, 8, 16, 32, 64, 128);
 203
 204    type Std_Class is (ANYOF_NONE,
 205                       ANYOF_ALNUM,   --  Alphanumeric class [a-zA-Z0-9]
 206                       ANYOF_NALNUM,
 207                       ANYOF_SPACE,   --  Space class [ \t\n\r\f]
 208                       ANYOF_NSPACE,
 209                       ANYOF_DIGIT,   --  Digit class [0-9]
 210                       ANYOF_NDIGIT,
 211                       ANYOF_ALNUMC,  --  Alphanumeric class [a-zA-Z0-9]
 212                       ANYOF_NALNUMC,
 213                       ANYOF_ALPHA,   --  Alpha class [a-zA-Z]
 214                       ANYOF_NALPHA,
 215                       ANYOF_ASCII,   --  Ascii class (7 bits) 0..127
 216                       ANYOF_NASCII,
 217                       ANYOF_CNTRL,   --  Control class
 218                       ANYOF_NCNTRL,
 219                       ANYOF_GRAPH,   --  Graphic class
 220                       ANYOF_NGRAPH,
 221                       ANYOF_LOWER,   --  Lower case class [a-z]
 222                       ANYOF_NLOWER,
 223                       ANYOF_PRINT,   --  printable class
 224                       ANYOF_NPRINT,
 225                       ANYOF_PUNCT,   --
 226                       ANYOF_NPUNCT,
 227                       ANYOF_UPPER,   --  Upper case class [A-Z]
 228                       ANYOF_NUPPER,
 229                       ANYOF_XDIGIT,  --  Hexadecimal digit
 230                       ANYOF_NXDIGIT
 231                       );
 232
 233    procedure Set_In_Class
 234      (Bitmap : in out Character_Class;
 235       C      : Character);
 236    --  Set the entry to True for C in the class Bitmap
 237
 238    function Get_From_Class
 239      (Bitmap : Character_Class;
 240       C      : Character) return Boolean;
 241    --  Return True if the entry is set for C in the class Bitmap
 242
 243    procedure Reset_Class (Bitmap : out Character_Class);
 244    --  Clear all the entries in the class Bitmap
 245
 246    pragma Inline (Set_In_Class);
 247    pragma Inline (Get_From_Class);
 248    pragma Inline (Reset_Class);
 249
 250    -----------------------
 251    -- Local Subprograms --
 252    -----------------------
 253
 254    function "=" (Left : Character; Right : Opcode) return Boolean;
 255
 256    function Is_Alnum (C : Character) return Boolean;
 257    --  Return True if C is an alphanum character or an underscore ('_')
 258
 259    function Is_White_Space (C : Character) return Boolean;
 260    --  Return True if C is a whitespace character
 261
 262    function Is_Printable (C : Character) return Boolean;
 263    --  Return True if C is a printable character
 264
 265    function Operand (P : Pointer) return Pointer;
 266    --  Return a pointer to the first operand of the node at P
 267
 268    function String_Length
 269      (Program : Program_Data;
 270       P       : Pointer) return Program_Size;
 271    --  Return the length of the string argument of the node at P
 272
 273    function String_Operand (P : Pointer) return Pointer;
 274    --  Return a pointer to the string argument of the node at P
 275
 276    procedure Bitmap_Operand
 277      (Program : Program_Data;
 278       P       : Pointer;
 279       Op      : out Character_Class);
 280    --  Return a pointer to the string argument of the node at P
 281
 282    function Get_Next_Offset
 283      (Program : Program_Data;
 284       IP      : Pointer) return Pointer;
 285    --  Get the offset field of a node. Used by Get_Next
 286
 287    function Get_Next
 288      (Program : Program_Data;
 289       IP      : Pointer) return Pointer;
 290    --  Dig the next instruction pointer out of a node
 291
 292    procedure Optimize (Self : in out Pattern_Matcher);
 293    --  Optimize a Pattern_Matcher by noting certain special cases
 294
 295    function Read_Natural
 296      (Program : Program_Data;
 297       IP      : Pointer) return Natural;
 298    --  Return the 2-byte natural coded at position IP
 299
 300    --  All of the subprograms above are tiny and should be inlined
 301
 302    pragma Inline ("=");
 303    pragma Inline (Is_Alnum);
 304    pragma Inline (Is_White_Space);
 305    pragma Inline (Get_Next);
 306    pragma Inline (Get_Next_Offset);
 307    pragma Inline (Operand);
 308    pragma Inline (Read_Natural);
 309    pragma Inline (String_Length);
 310    pragma Inline (String_Operand);
 311
 312    type Expression_Flags is record
 313       Has_Width,            -- Known never to match null string
 314       Simple,               -- Simple enough to be STAR/PLUS operand
 315       SP_Start  : Boolean;  -- Starts with * or +
 316    end record;
 317
 318    Worst_Expression : constant Expression_Flags := (others => False);
 319    --  Worst case
 320
 321    ---------
 322    -- "=" --
 323    ---------
 324
 325    function "=" (Left : Character; Right : Opcode) return Boolean is
 326    begin
 327       return Character'Pos (Left) = Opcode'Pos (Right);
 328    end "=";
 329
 330    --------------------
 331    -- Bitmap_Operand --
 332    --------------------
 333
 334    procedure Bitmap_Operand
 335      (Program : Program_Data;
 336       P       : Pointer;
 337       Op      : out Character_Class)
 338    is
 339       function Convert is new Ada.Unchecked_Conversion
 340         (Program_Data, Character_Class);
 341
 342    begin
 343       Op (0 .. 31) := Convert (Program (P + 3 .. P + 34));
 344    end Bitmap_Operand;
 345
 346    -------------
 347    -- Compile --
 348    -------------
 349
 350    procedure Compile
 351      (Matcher         : out Pattern_Matcher;
 352       Expression      : String;
 353       Final_Code_Size : out Program_Size;
 354       Flags           : Regexp_Flags := No_Flags)
 355    is
 356       --  We can't allocate space until we know how big the compiled form
 357       --  will be, but we can't compile it (and thus know how big it is)
 358       --  until we've got a place to put the code. So we cheat: we compile
 359       --  it twice, once with code generation turned off and size counting
 360       --  turned on, and once "for real".
 361
 362       --  This also means that we don't allocate space until we are sure
 363       --  that the thing really will compile successfully, and we never
 364       --  have to move the code and thus invalidate pointers into it.
 365
 366       --  Beware that the optimization-preparation code in here knows
 367       --  about some of the structure of the compiled regexp.
 368
 369       PM        : Pattern_Matcher renames Matcher;
 370       Program   : Program_Data renames PM.Program;
 371
 372       Emit_Code : constant Boolean := PM.Size > 0;
 373       Emit_Ptr  : Pointer := Program_First;
 374
 375       Parse_Pos : Natural := Expression'First; -- Input-scan pointer
 376       Parse_End : constant Natural := Expression'Last;
 377
 378       ----------------------------
 379       -- Subprograms for Create --
 380       ----------------------------
 381
 382       procedure Emit (B : Character);
 383       --  Output the Character B to the Program. If code-generation is
 384       --  disabled, simply increments the program counter.
 385
 386       function  Emit_Node (Op : Opcode) return Pointer;
 387       --  If code-generation is enabled, Emit_Node outputs the
 388       --  opcode Op and reserves space for a pointer to the next node.
 389       --  Return value is the location of new opcode, ie old Emit_Ptr.
 390
 391       procedure Emit_Natural (IP : Pointer; N : Natural);
 392       --  Split N on two characters at position IP
 393
 394       procedure Emit_Class (Bitmap : Character_Class);
 395       --  Emits a character class
 396
 397       procedure Case_Emit (C : Character);
 398       --  Emit C, after converting is to lower-case if the regular
 399       --  expression is case insensitive.
 400
 401       procedure Parse
 402         (Parenthesized : Boolean;
 403          Flags         : out Expression_Flags;
 404          IP            : out Pointer);
 405       --  Parse regular expression, i.e. main body or parenthesized thing
 406       --  Caller must absorb opening parenthesis.
 407
 408       procedure Parse_Branch
 409         (Flags         : out Expression_Flags;
 410          First         : Boolean;
 411          IP            : out Pointer);
 412       --  Implements the concatenation operator and handles '|'
 413       --  First should be true if this is the first item of the alternative.
 414
 415       procedure Parse_Piece
 416         (Expr_Flags : out Expression_Flags;
 417          IP         : out Pointer);
 418       --  Parse something followed by possible [*+?]
 419
 420       procedure Parse_Atom
 421         (Expr_Flags : out Expression_Flags;
 422          IP         : out Pointer);
 423       --  Parse_Atom is the lowest level parse procedure.
 424       --  Optimization:  gobbles an entire sequence of ordinary characters
 425       --  so that it can turn them into a single node, which is smaller to
 426       --  store and faster to run. Backslashed characters are exceptions,
 427       --  each becoming a separate node; the code is simpler that way and
 428       --  it's not worth fixing.
 429
 430       procedure Insert_Operator
 431         (Op       : Opcode;
 432          Operand  : Pointer;
 433          Greedy   : Boolean := True);
 434       --  Insert_Operator inserts an operator in front of an
 435       --  already-emitted operand and relocates the operand.
 436       --  This applies to PLUS and STAR.
 437       --  If Minmod is True, then the operator is non-greedy.
 438
 439       procedure Insert_Curly_Operator
 440         (Op      : Opcode;
 441          Min     : Natural;
 442          Max     : Natural;
 443          Operand : Pointer;
 444          Greedy  : Boolean := True);
 445       --  Insert an operator for CURLY ({Min}, {Min,} or {Min,Max}).
 446       --  If Minmod is True, then the operator is non-greedy.
 447
 448       procedure Link_Tail (P, Val : Pointer);
 449       --  Link_Tail sets the next-pointer at the end of a node chain
 450
 451       procedure Link_Operand_Tail (P, Val : Pointer);
 452       --  Link_Tail on operand of first argument; nop if operandless
 453
 454       function  Next_Instruction (P : Pointer) return Pointer;
 455       --  Dig the "next" pointer out of a node
 456
 457       procedure Fail (M : String);
 458       pragma No_Return (Fail);
 459       --  Fail with a diagnostic message, if possible
 460
 461       function Is_Curly_Operator (IP : Natural) return Boolean;
 462       --  Return True if IP is looking at a '{' that is the beginning
 463       --  of a curly operator, ie it matches {\d+,?\d*}
 464
 465       function Is_Mult (IP : Natural) return Boolean;
 466       --  Return True if C is a regexp multiplier: '+', '*' or '?'
 467
 468       procedure Get_Curly_Arguments
 469         (IP     : Natural;
 470          Min    : out Natural;
 471          Max    : out Natural;
 472          Greedy : out Boolean);
 473       --  Parse the argument list for a curly operator.
 474       --  It is assumed that IP is indeed pointing at a valid operator.
 475       --  So what is IP and how come IP is not referenced in the body ???
 476
 477       procedure Parse_Character_Class (IP : out Pointer);
 478       --  Parse a character class.
 479       --  The calling subprogram should consume the opening '[' before.
 480
 481       procedure Parse_Literal
 482         (Expr_Flags : out Expression_Flags;
 483          IP         : out Pointer);
 484       --  Parse_Literal encodes a string of characters to be matched exactly
 485
 486       function Parse_Posix_Character_Class return Std_Class;
 487       --  Parse a posic character class, like [:alpha:] or [:^alpha:].
 488       --  The called is suppoed to absorbe the opening [.
 489
 490       pragma Inline (Is_Mult);
 491       pragma Inline (Emit_Natural);
 492       pragma Inline (Parse_Character_Class); --  since used only once
 493
 494       ---------------
 495       -- Case_Emit --
 496       ---------------
 497
 498       procedure Case_Emit (C : Character) is
 499       begin
 500          if (Flags and Case_Insensitive) /= 0 then
 501             Emit (To_Lower (C));
 502
 503          else
 504             --  Dump current character
 505
 506             Emit (C);
 507          end if;
 508       end Case_Emit;
 509
 510       ----------
 511       -- Emit --
 512       ----------
 513
 514       procedure Emit (B : Character) is
 515       begin
 516          if Emit_Code then
 517             Program (Emit_Ptr) := B;
 518          end if;
 519
 520          Emit_Ptr := Emit_Ptr + 1;
 521       end Emit;
 522
 523       ----------------
 524       -- Emit_Class --
 525       ----------------
 526
 527       procedure Emit_Class (Bitmap : Character_Class) is
 528          subtype Program31 is Program_Data (0 .. 31);
 529
 530          function Convert is new Ada.Unchecked_Conversion
 531            (Character_Class, Program31);
 532
 533       begin
 534          if Emit_Code then
 535             Program (Emit_Ptr .. Emit_Ptr + 31) := Convert (Bitmap);
 536          end if;
 537
 538          Emit_Ptr := Emit_Ptr + 32;
 539       end Emit_Class;
 540
 541       ------------------
 542       -- Emit_Natural --
 543       ------------------
 544
 545       procedure Emit_Natural (IP : Pointer; N : Natural) is
 546       begin
 547          if Emit_Code then
 548             Program (IP + 1) := Character'Val (N / 256);
 549             Program (IP) := Character'Val (N mod 256);
 550          end if;
 551       end Emit_Natural;
 552
 553       ---------------
 554       -- Emit_Node --
 555       ---------------
 556
 557       function Emit_Node (Op : Opcode) return Pointer is
 558          Result : constant Pointer := Emit_Ptr;
 559
 560       begin
 561          if Emit_Code then
 562             Program (Emit_Ptr) := Character'Val (Opcode'Pos (Op));
 563             Program (Emit_Ptr + 1) := ASCII.NUL;
 564             Program (Emit_Ptr + 2) := ASCII.NUL;
 565          end if;
 566
 567          Emit_Ptr := Emit_Ptr + 3;
 568          return Result;
 569       end Emit_Node;
 570
 571       ----------
 572       -- Fail --
 573       ----------
 574
 575       procedure Fail (M : String) is
 576       begin
 577          raise Expression_Error with M;
 578       end Fail;
 579
 580       -------------------------
 581       -- Get_Curly_Arguments --
 582       -------------------------
 583
 584       procedure Get_Curly_Arguments
 585         (IP     : Natural;
 586          Min    : out Natural;
 587          Max    : out Natural;
 588          Greedy : out Boolean)
 589       is
 590          pragma Unreferenced (IP);
 591
 592          Save_Pos : Natural := Parse_Pos + 1;
 593
 594       begin
 595          Min := 0;
 596          Max := Max_Curly_Repeat;
 597
 598          while Expression (Parse_Pos) /= '}'
 599            and then Expression (Parse_Pos) /= ','
 600          loop
 601             Parse_Pos := Parse_Pos + 1;
 602          end loop;
 603
 604          Min := Natural'Value (Expression (Save_Pos .. Parse_Pos - 1));
 605
 606          if Expression (Parse_Pos) = ',' then
 607             Save_Pos := Parse_Pos + 1;
 608             while Expression (Parse_Pos) /= '}' loop
 609                Parse_Pos := Parse_Pos + 1;
 610             end loop;
 611
 612             if Save_Pos /= Parse_Pos then
 613                Max := Natural'Value (Expression (Save_Pos .. Parse_Pos - 1));
 614             end if;
 615
 616          else
 617             Max := Min;
 618          end if;
 619
 620          if Parse_Pos < Expression'Last
 621            and then Expression (Parse_Pos + 1) = '?'
 622          then
 623             Greedy := False;
 624             Parse_Pos := Parse_Pos + 1;
 625
 626          else
 627             Greedy := True;
 628          end if;
 629       end Get_Curly_Arguments;
 630
 631       ---------------------------
 632       -- Insert_Curly_Operator --
 633       ---------------------------
 634
 635       procedure Insert_Curly_Operator
 636         (Op      : Opcode;
 637          Min     : Natural;
 638          Max     : Natural;
 639          Operand : Pointer;
 640          Greedy  : Boolean := True)
 641       is
 642          Dest   : constant Pointer := Emit_Ptr;
 643          Old    : Pointer;
 644          Size   : Pointer := 7;
 645
 646       begin
 647          --  If the operand is not greedy, insert an extra operand before it
 648
 649          if not Greedy then
 650             Size := Size + 3;
 651          end if;
 652
 653          --  Move the operand in the byte-compilation, so that we can insert
 654          --  the operator before it.
 655
 656          if Emit_Code then
 657             Program (Operand + Size .. Emit_Ptr + Size) :=
 658               Program (Operand .. Emit_Ptr);
 659          end if;
 660
 661          --  Insert the operator at the position previously occupied by the
 662          --  operand.
 663
 664          Emit_Ptr := Operand;
 665
 666          if not Greedy then
 667             Old := Emit_Node (MINMOD);
 668             Link_Tail (Old, Old + 3);
 669          end if;
 670
 671          Old := Emit_Node (Op);
 672          Emit_Natural (Old + 3, Min);
 673          Emit_Natural (Old + 5, Max);
 674
 675          Emit_Ptr := Dest + Size;
 676       end Insert_Curly_Operator;
 677
 678       ---------------------
 679       -- Insert_Operator --
 680       ---------------------
 681
 682       procedure Insert_Operator
 683         (Op      : Opcode;
 684          Operand : Pointer;
 685          Greedy  : Boolean := True)
 686       is
 687          Dest : constant Pointer := Emit_Ptr;
 688          Old  : Pointer;
 689          Size : Pointer := 3;
 690
 691          Discard : Pointer;
 692          pragma Warnings (Off, Discard);
 693
 694       begin
 695          --  If not greedy, we have to emit another opcode first
 696
 697          if not Greedy then
 698             Size := Size + 3;
 699          end if;
 700
 701          --  Move the operand in the byte-compilation, so that we can insert
 702          --  the operator before it.
 703
 704          if Emit_Code then
 705             Program (Operand + Size .. Emit_Ptr + Size) :=
 706               Program (Operand .. Emit_Ptr);
 707          end if;
 708
 709          --  Insert the operator at the position previously occupied by the
 710          --  operand.
 711
 712          Emit_Ptr := Operand;
 713
 714          if not Greedy then
 715             Old := Emit_Node (MINMOD);
 716             Link_Tail (Old, Old + 3);
 717          end if;
 718
 719          Discard := Emit_Node (Op);
 720          Emit_Ptr := Dest + Size;
 721       end Insert_Operator;
 722
 723       -----------------------
 724       -- Is_Curly_Operator --
 725       -----------------------
 726
 727       function Is_Curly_Operator (IP : Natural) return Boolean is
 728          Scan : Natural := IP;
 729
 730       begin
 731          if Expression (Scan) /= '{'
 732            or else Scan + 2 > Expression'Last
 733            or else not Is_Digit (Expression (Scan + 1))
 734          then
 735             return False;
 736          end if;
 737
 738          Scan := Scan + 1;
 739
 740          --  The first digit
 741
 742          loop
 743             Scan := Scan + 1;
 744
 745             if Scan > Expression'Last then
 746                return False;
 747             end if;
 748
 749             exit when not Is_Digit (Expression (Scan));
 750          end loop;
 751
 752          if Expression (Scan) = ',' then
 753             loop
 754                Scan := Scan + 1;
 755
 756                if Scan > Expression'Last then
 757                   return False;
 758                end if;
 759
 760                exit when not Is_Digit (Expression (Scan));
 761             end loop;
 762          end if;
 763
 764          return Expression (Scan) = '}';
 765       end Is_Curly_Operator;
 766
 767       -------------
 768       -- Is_Mult --
 769       -------------
 770
 771       function Is_Mult (IP : Natural) return Boolean is
 772          C : constant Character := Expression (IP);
 773
 774       begin
 775          return     C = '*'
 776            or else  C = '+'
 777            or else  C = '?'
 778            or else (C = '{' and then Is_Curly_Operator (IP));
 779       end Is_Mult;
 780
 781       -----------------------
 782       -- Link_Operand_Tail --
 783       -----------------------
 784
 785       procedure Link_Operand_Tail (P, Val : Pointer) is
 786       begin
 787          if Emit_Code and then Program (P) = BRANCH then
 788             Link_Tail (Operand (P), Val);
 789          end if;
 790       end Link_Operand_Tail;
 791
 792       ---------------
 793       -- Link_Tail --
 794       ---------------
 795
 796       procedure Link_Tail (P, Val : Pointer) is
 797          Scan   : Pointer;
 798          Temp   : Pointer;
 799          Offset : Pointer;
 800
 801       begin
 802          if not Emit_Code then
 803             return;
 804          end if;
 805
 806          --  Find last node
 807
 808          Scan := P;
 809          loop
 810             Temp := Next_Instruction (Scan);
 811             exit when Temp = 0;
 812             Scan := Temp;
 813          end loop;
 814
 815          Offset := Val - Scan;
 816
 817          Emit_Natural (Scan + 1, Natural (Offset));
 818       end Link_Tail;
 819
 820       ----------------------
 821       -- Next_Instruction --
 822       ----------------------
 823
 824       function Next_Instruction (P : Pointer) return Pointer is
 825          Offset : Pointer;
 826
 827       begin
 828          if not Emit_Code then
 829             return 0;
 830          end if;
 831
 832          Offset := Get_Next_Offset (Program, P);
 833
 834          if Offset = 0 then
 835             return 0;
 836          end if;
 837
 838          return P + Offset;
 839       end Next_Instruction;
 840
 841       -----------
 842       -- Parse --
 843       -----------
 844
 845       --  Combining parenthesis handling with the base level
 846       --  of regular expression is a trifle forced, but the
 847       --  need to tie the tails of the branches to what follows
 848       --  makes it hard to avoid.
 849
 850       procedure Parse
 851         (Parenthesized  : Boolean;
 852          Flags          : out Expression_Flags;
 853          IP             : out Pointer)
 854       is
 855          E              : String renames Expression;
 856          Br             : Pointer;
 857          Ender          : Pointer;
 858          Par_No         : Natural;
 859          New_Flags      : Expression_Flags;
 860          Have_Branch    : Boolean := False;
 861
 862       begin
 863          Flags := (Has_Width => True, others => False);  -- Tentatively
 864
 865          --  Make an OPEN node, if parenthesized
 866
 867          if Parenthesized then
 868             if Matcher.Paren_Count > Max_Paren_Count then
 869                Fail ("too many ()");
 870             end if;
 871
 872             Par_No := Matcher.Paren_Count + 1;
 873             Matcher.Paren_Count := Matcher.Paren_Count + 1;
 874             IP := Emit_Node (OPEN);
 875             Emit (Character'Val (Par_No));
 876
 877          else
 878             IP := 0;
 879             Par_No := 0;
 880          end if;
 881
 882          --  Pick up the branches, linking them together
 883
 884          Parse_Branch (New_Flags, True, Br);
 885
 886          if Br = 0 then
 887             IP := 0;
 888             return;
 889          end if;
 890
 891          if Parse_Pos <= Parse_End
 892            and then E (Parse_Pos) = '|'
 893          then
 894             Insert_Operator (BRANCH, Br);
 895             Have_Branch := True;
 896          end if;
 897
 898          if IP /= 0 then
 899             Link_Tail (IP, Br);   -- OPEN -> first
 900          else
 901             IP := Br;
 902          end if;
 903
 904          if not New_Flags.Has_Width then
 905             Flags.Has_Width := False;
 906          end if;
 907
 908          Flags.SP_Start := Flags.SP_Start or New_Flags.SP_Start;
 909
 910          while Parse_Pos <= Parse_End
 911            and then (E (Parse_Pos) = '|')
 912          loop
 913             Parse_Pos := Parse_Pos + 1;
 914             Parse_Branch (New_Flags, False, Br);
 915
 916             if Br = 0 then
 917                IP := 0;
 918                return;
 919             end if;
 920
 921             Link_Tail (IP, Br);   -- BRANCH -> BRANCH
 922
 923             if not New_Flags.Has_Width then
 924                Flags.Has_Width := False;
 925             end if;
 926
 927             Flags.SP_Start := Flags.SP_Start or New_Flags.SP_Start;
 928          end loop;
 929
 930          --  Make a closing node, and hook it on the end
 931
 932          if Parenthesized then
 933             Ender := Emit_Node (CLOSE);
 934             Emit (Character'Val (Par_No));
 935          else
 936             Ender := Emit_Node (EOP);
 937          end if;
 938
 939          Link_Tail (IP, Ender);
 940
 941          if Have_Branch then
 942
 943             --  Hook the tails of the branches to the closing node
 944
 945             Br := IP;
 946             loop
 947                exit when Br = 0;
 948                Link_Operand_Tail (Br, Ender);
 949                Br := Next_Instruction (Br);
 950             end loop;
 951          end if;
 952
 953          --  Check for proper termination
 954
 955          if Parenthesized then
 956             if Parse_Pos > Parse_End or else E (Parse_Pos) /= ')' then
 957                Fail ("unmatched ()");
 958             end if;
 959
 960             Parse_Pos := Parse_Pos + 1;
 961
 962          elsif Parse_Pos <= Parse_End then
 963             if E (Parse_Pos) = ')'  then
 964                Fail ("unmatched ()");
 965             else
 966                Fail ("junk on end");         -- "Can't happen"
 967             end if;
 968          end if;
 969       end Parse;
 970
 971       ----------------
 972       -- Parse_Atom --
 973       ----------------
 974
 975       procedure Parse_Atom
 976         (Expr_Flags : out Expression_Flags;
 977          IP         : out Pointer)
 978       is
 979          C : Character;
 980
 981       begin
 982          --  Tentatively set worst expression case
 983
 984          Expr_Flags := Worst_Expression;
 985
 986          C := Expression (Parse_Pos);
 987          Parse_Pos := Parse_Pos + 1;
 988
 989          case (C) is
 990             when '^' =>
 991                if (Flags and Multiple_Lines) /= 0  then
 992                   IP := Emit_Node (MBOL);
 993                elsif (Flags and Single_Line) /= 0 then
 994                   IP := Emit_Node (SBOL);
 995                else
 996                   IP := Emit_Node (BOL);
 997                end if;
 998
 999             when '$' =>
1000                if (Flags and Multiple_Lines) /= 0  then
1001                   IP := Emit_Node (MEOL);
1002                elsif (Flags and Single_Line) /= 0 then
1003                   IP := Emit_Node (SEOL);
1004                else
1005                   IP := Emit_Node (EOL);
1006                end if;
1007
1008             when '.' =>
1009                if (Flags and Single_Line) /= 0 then
1010                   IP := Emit_Node (SANY);
1011                else
1012                   IP := Emit_Node (ANY);
1013                end if;
1014
1015                Expr_Flags.Has_Width := True;
1016                Expr_Flags.Simple := True;
1017
1018             when '[' =>
1019                Parse_Character_Class (IP);
1020                Expr_Flags.Has_Width := True;
1021                Expr_Flags.Simple := True;
1022
1023             when '(' =>
1024                declare
1025                   New_Flags : Expression_Flags;
1026
1027                begin
1028                   Parse (True, New_Flags, IP);
1029
1030                   if IP = 0 then
1031                      return;
1032                   end if;
1033
1034                   Expr_Flags.Has_Width :=
1035                     Expr_Flags.Has_Width or New_Flags.Has_Width;
1036                   Expr_Flags.SP_Start :=
1037                     Expr_Flags.SP_Start or New_Flags.SP_Start;
1038                end;
1039
1040             when '|' | ASCII.LF | ')' =>
1041                Fail ("internal urp");  --  Supposed to be caught earlier
1042
1043             when '?' | '+' | '*' =>
1044                Fail (C & " follows nothing");
1045
1046             when '{' =>
1047                if Is_Curly_Operator (Parse_Pos - 1) then
1048                   Fail (C & " follows nothing");
1049                else
1050                   Parse_Literal (Expr_Flags, IP);
1051                end if;
1052
1053             when '\' =>
1054                if Parse_Pos > Parse_End then
1055                   Fail ("trailing \");
1056                end if;
1057
1058                Parse_Pos := Parse_Pos + 1;
1059
1060                case Expression (Parse_Pos - 1) is
1061                   when 'b'        =>
1062                      IP := Emit_Node (BOUND);
1063
1064                   when 'B'        =>
1065                      IP := Emit_Node (NBOUND);
1066
1067                   when 's'        =>
1068                      IP := Emit_Node (SPACE);
1069                      Expr_Flags.Simple := True;
1070                      Expr_Flags.Has_Width := True;
1071
1072                   when 'S'        =>
1073                      IP := Emit_Node (NSPACE);
1074                      Expr_Flags.Simple := True;
1075                      Expr_Flags.Has_Width := True;
1076
1077                   when 'd'        =>
1078                      IP := Emit_Node (DIGIT);
1079                      Expr_Flags.Simple := True;
1080                      Expr_Flags.Has_Width := True;
1081
1082                   when 'D'        =>
1083                      IP := Emit_Node (NDIGIT);
1084                      Expr_Flags.Simple := True;
1085                      Expr_Flags.Has_Width := True;
1086
1087                   when 'w'        =>
1088                      IP := Emit_Node (ALNUM);
1089                      Expr_Flags.Simple := True;
1090                      Expr_Flags.Has_Width := True;
1091
1092                   when 'W'        =>
1093                      IP := Emit_Node (NALNUM);
1094                      Expr_Flags.Simple := True;
1095                      Expr_Flags.Has_Width := True;
1096
1097                   when 'A'        =>
1098                      IP := Emit_Node (SBOL);
1099
1100                   when 'G'        =>
1101                      IP := Emit_Node (SEOL);
1102
1103                   when '0' .. '9' =>
1104                      IP := Emit_Node (REFF);
1105
1106                      declare
1107                         Save : constant Natural := Parse_Pos - 1;
1108
1109                      begin
1110                         while Parse_Pos <= Expression'Last
1111                           and then Is_Digit (Expression (Parse_Pos))
1112                         loop
1113                            Parse_Pos := Parse_Pos + 1;
1114                         end loop;
1115
1116                         Emit (Character'Val (Natural'Value
1117                                (Expression (Save .. Parse_Pos - 1))));
1118                      end;
1119
1120                   when others =>
1121                      Parse_Pos := Parse_Pos - 1;
1122                      Parse_Literal (Expr_Flags, IP);
1123                end case;
1124
1125             when others =>
1126                Parse_Literal (Expr_Flags, IP);
1127          end case;
1128       end Parse_Atom;
1129
1130       ------------------
1131       -- Parse_Branch --
1132       ------------------
1133
1134       procedure Parse_Branch
1135         (Flags : out Expression_Flags;
1136          First : Boolean;
1137          IP    : out Pointer)
1138       is
1139          E         : String renames Expression;
1140          Chain     : Pointer;
1141          Last      : Pointer;
1142          New_Flags : Expression_Flags;
1143
1144          Discard : Pointer;
1145          pragma Warnings (Off, Discard);
1146
1147       begin
1148          Flags := Worst_Expression;    -- Tentatively
1149
1150          if First then
1151             IP := Emit_Ptr;
1152          else
1153             IP := Emit_Node (BRANCH);
1154          end if;
1155
1156          Chain := 0;
1157
1158          while Parse_Pos <= Parse_End
1159            and then E (Parse_Pos) /= ')'
1160            and then E (Parse_Pos) /= ASCII.LF
1161            and then E (Parse_Pos) /= '|'
1162          loop
1163             Parse_Piece (New_Flags, Last);
1164
1165             if Last = 0 then
1166                IP := 0;
1167                return;
1168             end if;
1169
1170             Flags.Has_Width := Flags.Has_Width or New_Flags.Has_Width;
1171
1172             if Chain = 0 then            -- First piece
1173                Flags.SP_Start := Flags.SP_Start or New_Flags.SP_Start;
1174             else
1175                Link_Tail (Chain, Last);
1176             end if;
1177
1178             Chain := Last;
1179          end loop;
1180
1181          --  Case where loop ran zero CURLY
1182
1183          if Chain = 0 then
1184             Discard := Emit_Node (NOTHING);
1185          end if;
1186       end Parse_Branch;
1187
1188       ---------------------------
1189       -- Parse_Character_Class --
1190       ---------------------------
1191
1192       procedure Parse_Character_Class (IP : out Pointer) is
1193          Bitmap      : Character_Class;
1194          Invert      : Boolean := False;
1195          In_Range    : Boolean := False;
1196          Named_Class : Std_Class := ANYOF_NONE;
1197          Value       : Character;
1198          Last_Value  : Character := ASCII.Nul;
1199
1200       begin
1201          Reset_Class (Bitmap);
1202
1203          --  Do we have an invert character class ?
1204
1205          if Parse_Pos <= Parse_End
1206            and then Expression (Parse_Pos) = '^'
1207          then
1208             Invert := True;
1209             Parse_Pos := Parse_Pos + 1;
1210          end if;
1211
1212          --  First character can be ] or - without closing the class
1213
1214          if Parse_Pos <= Parse_End
1215            and then (Expression (Parse_Pos) = ']'
1216                       or else Expression (Parse_Pos) = '-')
1217          then
1218             Set_In_Class (Bitmap, Expression (Parse_Pos));
1219             Parse_Pos := Parse_Pos + 1;
1220          end if;
1221
1222          --  While we don't have the end of the class
1223
1224          while Parse_Pos <= Parse_End
1225            and then Expression (Parse_Pos) /= ']'
1226          loop
1227             Named_Class := ANYOF_NONE;
1228             Value := Expression (Parse_Pos);
1229             Parse_Pos := Parse_Pos + 1;
1230
1231             --  Do we have a Posix character class
1232             if Value = '[' then
1233                Named_Class := Parse_Posix_Character_Class;
1234
1235             elsif Value = '\' then
1236                if Parse_Pos = Parse_End then
1237                   Fail ("Trailing \");
1238                end if;
1239                Value := Expression (Parse_Pos);
1240                Parse_Pos := Parse_Pos + 1;
1241
1242                case Value is
1243                   when 'w' => Named_Class := ANYOF_ALNUM;
1244                   when 'W' => Named_Class := ANYOF_NALNUM;
1245                   when 's' => Named_Class := ANYOF_SPACE;
1246                   when 'S' => Named_Class := ANYOF_NSPACE;
1247                   when 'd' => Named_Class := ANYOF_DIGIT;
1248                   when 'D' => Named_Class := ANYOF_NDIGIT;
1249                   when 'n' => Value := ASCII.LF;
1250                   when 'r' => Value := ASCII.CR;
1251                   when 't' => Value := ASCII.HT;
1252                   when 'f' => Value := ASCII.FF;
1253                   when 'e' => Value := ASCII.ESC;
1254                   when 'a' => Value := ASCII.BEL;
1255
1256                   --  when 'x'  => ??? hexadecimal value
1257                   --  when 'c'  => ??? control character
1258                   --  when '0'..'9' => ??? octal character
1259
1260                   when others => null;
1261                end case;
1262             end if;
1263
1264             --  Do we have a character class?
1265
1266             if Named_Class /= ANYOF_NONE then
1267
1268                --  A range like 'a-\d' or 'a-[:digit:] is not a range
1269
1270                if In_Range then
1271                   Set_In_Class (Bitmap, Last_Value);
1272                   Set_In_Class (Bitmap, '-');
1273                   In_Range := False;
1274                end if;
1275
1276                --  Expand the range
1277
1278                case Named_Class is
1279                   when ANYOF_NONE => null;
1280
1281                   when ANYOF_ALNUM | ANYOF_ALNUMC =>
1282                      for Value in Class_Byte'Range loop
1283                         if Is_Alnum (Character'Val (Value)) then
1284                            Set_In_Class (Bitmap, Character'Val (Value));
1285                         end if;
1286                      end loop;
1287
1288                   when ANYOF_NALNUM | ANYOF_NALNUMC =>
1289                      for Value in Class_Byte'Range loop
1290                         if not Is_Alnum (Character'Val (Value)) then
1291                            Set_In_Class (Bitmap, Character'Val (Value));
1292                         end if;
1293                      end loop;
1294
1295                   when ANYOF_SPACE =>
1296                      for Value in Class_Byte'Range loop
1297                         if Is_White_Space (Character'Val (Value)) then
1298                            Set_In_Class (Bitmap, Character'Val (Value));
1299                         end if;
1300                      end loop;
1301
1302                   when ANYOF_NSPACE =>
1303                      for Value in Class_Byte'Range loop
1304                         if not Is_White_Space (Character'Val (Value)) then
1305                            Set_In_Class (Bitmap, Character'Val (Value));
1306                         end if;
1307                      end loop;
1308
1309                   when ANYOF_DIGIT =>
1310                      for Value in Class_Byte'Range loop
1311                         if Is_Digit (Character'Val (Value)) then
1312                            Set_In_Class (Bitmap, Character'Val (Value));
1313                         end if;
1314                      end loop;
1315
1316                   when ANYOF_NDIGIT =>
1317                      for Value in Class_Byte'Range loop
1318                         if not Is_Digit (Character'Val (Value)) then
1319                            Set_In_Class (Bitmap, Character'Val (Value));
1320                         end if;
1321                      end loop;
1322
1323                   when ANYOF_ALPHA =>
1324                      for Value in Class_Byte'Range loop
1325                         if Is_Letter (Character'Val (Value)) then
1326                            Set_In_Class (Bitmap, Character'Val (Value));
1327                         end if;
1328                      end loop;
1329
1330                   when ANYOF_NALPHA =>
1331                      for Value in Class_Byte'Range loop
1332                         if not Is_Letter (Character'Val (Value)) then
1333                            Set_In_Class (Bitmap, Character'Val (Value));
1334                         end if;
1335                      end loop;
1336
1337                   when ANYOF_ASCII =>
1338                      for Value in 0 .. 127 loop
1339                         Set_In_Class (Bitmap, Character'Val (Value));
1340                      end loop;
1341
1342                   when ANYOF_NASCII =>
1343                      for Value in 128 .. 255 loop
1344                         Set_In_Class (Bitmap, Character'Val (Value));
1345                      end loop;
1346
1347                   when ANYOF_CNTRL =>
1348                      for Value in Class_Byte'Range loop
1349                         if Is_Control (Character'Val (Value)) then
1350                            Set_In_Class (Bitmap, Character'Val (Value));
1351                         end if;
1352                      end loop;
1353
1354                   when ANYOF_NCNTRL =>
1355                      for Value in Class_Byte'Range loop
1356                         if not Is_Control (Character'Val (Value)) then
1357                            Set_In_Class (Bitmap, Character'Val (Value));
1358                         end if;
1359                      end loop;
1360
1361                   when ANYOF_GRAPH =>
1362                      for Value in Class_Byte'Range loop
1363                         if Is_Graphic (Character'Val (Value)) then
1364                            Set_In_Class (Bitmap, Character'Val (Value));
1365                         end if;
1366                      end loop;
1367
1368                   when ANYOF_NGRAPH =>
1369                      for Value in Class_Byte'Range loop
1370                         if not Is_Graphic (Character'Val (Value)) then
1371                            Set_In_Class (Bitmap, Character'Val (Value));
1372                         end if;
1373                      end loop;
1374
1375                   when ANYOF_LOWER =>
1376                      for Value in Class_Byte'Range loop
1377                         if Is_Lower (Character'Val (Value)) then
1378                            Set_In_Class (Bitmap, Character'Val (Value));
1379                         end if;
1380                      end loop;
1381
1382                   when ANYOF_NLOWER =>
1383                      for Value in Class_Byte'Range loop
1384                         if not Is_Lower (Character'Val (Value)) then
1385                            Set_In_Class (Bitmap, Character'Val (Value));
1386                         end if;
1387                      end loop;
1388
1389                   when ANYOF_PRINT =>
1390                      for Value in Class_Byte'Range loop
1391                         if Is_Printable (Character'Val (Value)) then
1392                            Set_In_Class (Bitmap, Character'Val (Value));
1393                         end if;
1394                      end loop;
1395
1396                   when ANYOF_NPRINT =>
1397                      for Value in Class_Byte'Range loop
1398                         if not Is_Printable (Character'Val (Value)) then
1399                            Set_In_Class (Bitmap, Character'Val (Value));
1400                         end if;
1401                      end loop;
1402
1403                   when ANYOF_PUNCT =>
1404                      for Value in Class_Byte'Range loop
1405                         if Is_Printable (Character'Val (Value))
1406                           and then not Is_White_Space (Character'Val (Value))
1407                           and then not Is_Alnum (Character'Val (Value))
1408                         then
1409                            Set_In_Class (Bitmap, Character'Val (Value));
1410                         end if;
1411                      end loop;
1412
1413                   when ANYOF_NPUNCT =>
1414                      for Value in Class_Byte'Range loop
1415                         if not Is_Printable (Character'Val (Value))
1416                           or else Is_White_Space (Character'Val (Value))
1417                           or else Is_Alnum (Character'Val (Value))
1418                         then
1419                            Set_In_Class (Bitmap, Character'Val (Value));
1420                         end if;
1421                      end loop;
1422
1423                   when ANYOF_UPPER =>
1424                      for Value in Class_Byte'Range loop
1425                         if Is_Upper (Character'Val (Value)) then
1426                            Set_In_Class (Bitmap, Character'Val (Value));
1427                         end if;
1428                      end loop;
1429
1430                   when ANYOF_NUPPER =>
1431                      for Value in Class_Byte'Range loop
1432                         if not Is_Upper (Character'Val (Value)) then
1433                            Set_In_Class (Bitmap, Character'Val (Value));
1434                         end if;
1435                      end loop;
1436
1437                   when ANYOF_XDIGIT =>
1438                      for Value in Class_Byte'Range loop
1439                         if Is_Hexadecimal_Digit (Character'Val (Value)) then
1440                            Set_In_Class (Bitmap, Character'Val (Value));
1441                         end if;
1442                      end loop;
1443
1444                   when ANYOF_NXDIGIT =>
1445                      for Value in Class_Byte'Range loop
1446                         if not Is_Hexadecimal_Digit
1447                           (Character'Val (Value))
1448                         then
1449                            Set_In_Class (Bitmap, Character'Val (Value));
1450                         end if;
1451                      end loop;
1452
1453                end case;
1454
1455             --  Not a character range
1456
1457             elsif not In_Range then
1458                Last_Value := Value;
1459
1460                if Expression (Parse_Pos) = '-'
1461                  and then Parse_Pos < Parse_End
1462                  and then Expression (Parse_Pos + 1) /= ']'
1463                then
1464                   Parse_Pos := Parse_Pos + 1;
1465
1466                   --  Do we have a range like '\d-a' and '[:space:]-a'
1467                   --  which is not a real range
1468
1469                   if Named_Class /= ANYOF_NONE then
1470                      Set_In_Class (Bitmap, '-');
1471                   else
1472                      In_Range := True;
1473                   end if;
1474
1475                else
1476                   Set_In_Class (Bitmap, Value);
1477
1478                end if;
1479
1480             --  Else in a character range
1481
1482             else
1483                if Last_Value > Value then
1484                   Fail ("Invalid Range [" & Last_Value'Img
1485                         & "-" & Value'Img & "]");
1486                end if;
1487
1488                while Last_Value <= Value loop
1489                   Set_In_Class (Bitmap, Last_Value);
1490                   Last_Value := Character'Succ (Last_Value);
1491                end loop;
1492
1493                In_Range := False;
1494
1495             end if;
1496
1497          end loop;
1498
1499          --  Optimize case-insensitive ranges (put the upper case or lower
1500          --  case character into the bitmap)
1501
1502          if (Flags and Case_Insensitive) /= 0 then
1503             for C in Character'Range loop
1504                if Get_From_Class (Bitmap, C) then
1505                   Set_In_Class (Bitmap, To_Lower (C));
1506                   Set_In_Class (Bitmap, To_Upper (C));
1507                end if;
1508             end loop;
1509          end if;
1510
1511          --  Optimize inverted classes
1512
1513          if Invert then
1514             for J in Bitmap'Range loop
1515                Bitmap (J) := not Bitmap (J);
1516             end loop;
1517          end if;
1518
1519          Parse_Pos := Parse_Pos + 1;
1520
1521          --  Emit the class
1522
1523          IP := Emit_Node (ANYOF);
1524          Emit_Class (Bitmap);
1525       end Parse_Character_Class;
1526
1527       -------------------
1528       -- Parse_Literal --
1529       -------------------
1530
1531       --  This is a bit tricky due to quoted chars and due to
1532       --  the multiplier characters '*', '+', and '?' that
1533       --  take the SINGLE char previous as their operand.
1534
1535       --  On entry, the character at Parse_Pos - 1 is going to go
1536       --  into the string, no matter what it is. It could be
1537       --  following a \ if Parse_Atom was entered from the '\' case.
1538
1539       --  Basic idea is to pick up a good char in C and examine
1540       --  the next char. If Is_Mult (C) then twiddle, if it's a \
1541       --  then frozzle and if it's another magic char then push C and
1542       --  terminate the string. If none of the above, push C on the
1543       --  string and go around again.
1544
1545       --  Start_Pos is used to remember where "the current character"
1546       --  starts in the string, if due to an Is_Mult we need to back
1547       --  up and put the current char in a separate 1-character string.
1548       --  When Start_Pos is 0, C is the only char in the string;
1549       --  this is used in Is_Mult handling, and in setting the SIMPLE
1550       --  flag at the end.
1551
1552       procedure Parse_Literal
1553         (Expr_Flags : out Expression_Flags;
1554          IP         : out Pointer)
1555       is
1556          Start_Pos  : Natural := 0;
1557          C          : Character;
1558          Length_Ptr : Pointer;
1559
1560          Has_Special_Operator : Boolean := False;
1561
1562       begin
1563          Parse_Pos := Parse_Pos - 1;      --  Look at current character
1564
1565          if (Flags and Case_Insensitive) /= 0 then
1566             IP := Emit_Node (EXACTF);
1567          else
1568             IP := Emit_Node (EXACT);
1569          end if;
1570
1571          Length_Ptr := Emit_Ptr;
1572          Emit_Ptr := String_Operand (IP);
1573
1574          Parse_Loop :
1575          loop
1576             C := Expression (Parse_Pos); --  Get current character
1577
1578             case C is
1579                when '.' | '[' | '(' | ')' | '|' | ASCII.LF | '$' | '^' =>
1580
1581                   if Start_Pos = 0 then
1582                      Start_Pos := Parse_Pos;
1583                      Emit (C);         --  First character is always emitted
1584                   else
1585                      exit Parse_Loop;  --  Else we are done
1586                   end if;
1587
1588                when '?' | '+' | '*' | '{' =>
1589
1590                   if Start_Pos = 0 then
1591                      Start_Pos := Parse_Pos;
1592                      Emit (C);         --  First character is always emitted
1593
1594                   --  Are we looking at an operator, or is this
1595                   --  simply a normal character ?
1596
1597                   elsif not Is_Mult (Parse_Pos) then
1598                      Start_Pos := Parse_Pos;
1599                      Case_Emit (C);
1600
1601                   else
1602                      --  We've got something like "abc?d".  Mark this as a
1603                      --  special case. What we want to emit is a first
1604                      --  constant string for "ab", then one for "c" that will
1605                      --  ultimately be transformed with a CURLY operator, A
1606                      --  special case has to be handled for "a?", since there
1607                      --  is no initial string to emit.
1608
1609                      Has_Special_Operator := True;
1610                      exit Parse_Loop;
1611                   end if;
1612
1613                when '\' =>
1614                   Start_Pos := Parse_Pos;
1615
1616                   if Parse_Pos = Parse_End then
1617                      Fail ("Trailing \");
1618
1619                   else
1620                      case Expression (Parse_Pos + 1) is
1621                         when 'b' | 'B' | 's' | 'S' | 'd' | 'D'
1622                           | 'w' | 'W' | '0' .. '9' | 'G' | 'A'
1623                           => exit Parse_Loop;
1624                         when 'n'         => Emit (ASCII.LF);
1625                         when 't'         => Emit (ASCII.HT);
1626                         when 'r'         => Emit (ASCII.CR);
1627                         when 'f'         => Emit (ASCII.FF);
1628                         when 'e'         => Emit (ASCII.ESC);
1629                         when 'a'         => Emit (ASCII.BEL);
1630                         when others      => Emit (Expression (Parse_Pos + 1));
1631                      end case;
1632
1633                      Parse_Pos := Parse_Pos + 1;
1634                   end if;
1635
1636                when others =>
1637                   Start_Pos := Parse_Pos;
1638                   Case_Emit (C);
1639             end case;
1640
1641             exit Parse_Loop when Emit_Ptr - Length_Ptr = 254;
1642
1643             Parse_Pos := Parse_Pos + 1;
1644
1645             exit Parse_Loop when Parse_Pos > Parse_End;
1646          end loop Parse_Loop;
1647
1648          --  Is the string followed by a '*+?{' operator ? If yes, and if there
1649          --  is an initial string to emit, do it now.
1650
1651          if Has_Special_Operator
1652            and then Emit_Ptr >= Length_Ptr + 3
1653          then
1654             Emit_Ptr := Emit_Ptr - 1;
1655             Parse_Pos := Start_Pos;
1656          end if;
1657
1658          if Emit_Code then
1659             Program (Length_Ptr) := Character'Val (Emit_Ptr - Length_Ptr - 2);
1660          end if;
1661
1662          Expr_Flags.Has_Width := True;
1663
1664          --  Slight optimization when there is a single character
1665
1666          if Emit_Ptr = Length_Ptr + 2 then
1667             Expr_Flags.Simple := True;
1668          end if;
1669       end Parse_Literal;
1670
1671       -----------------
1672       -- Parse_Piece --
1673       -----------------
1674
1675       --  Note that the branching code sequences used for '?' and the
1676       --  general cases of '*' and + are somewhat optimized: they use
1677       --  the same NOTHING node as both the endmarker for their branch
1678       --  list and the body of the last branch. It might seem that
1679       --  this node could be dispensed with entirely, but the endmarker
1680       --  role is not redundant.
1681
1682       procedure Parse_Piece
1683         (Expr_Flags : out Expression_Flags;
1684          IP         : out Pointer)
1685       is
1686          Op        : Character;
1687          New_Flags : Expression_Flags;
1688          Greedy    : Boolean := True;
1689
1690       begin
1691          Parse_Atom (New_Flags, IP);
1692
1693          if IP = 0 then
1694             return;
1695          end if;
1696
1697          if Parse_Pos > Parse_End
1698            or else not Is_Mult (Parse_Pos)
1699          then
1700             Expr_Flags := New_Flags;
1701             return;
1702          end if;
1703
1704          Op := Expression (Parse_Pos);
1705
1706          if Op /= '+' then
1707             Expr_Flags := (SP_Start => True, others => False);
1708          else
1709             Expr_Flags := (Has_Width => True, others => False);
1710          end if;
1711
1712          --  Detect non greedy operators in the easy cases
1713
1714          if Op /= '{'
1715            and then Parse_Pos + 1 <= Parse_End
1716            and then Expression (Parse_Pos + 1) = '?'
1717          then
1718             Greedy := False;
1719             Parse_Pos := Parse_Pos + 1;
1720          end if;
1721
1722          --  Generate the byte code
1723
1724          case Op is
1725             when '*' =>
1726
1727                if New_Flags.Simple then
1728                   Insert_Operator (STAR, IP, Greedy);
1729                else
1730                   Link_Tail (IP, Emit_Node (WHILEM));
1731                   Insert_Curly_Operator
1732                     (CURLYX, 0, Max_Curly_Repeat, IP, Greedy);
1733                   Link_Tail (IP, Emit_Node (NOTHING));
1734                end if;
1735
1736             when '+' =>
1737
1738                if New_Flags.Simple then
1739                   Insert_Operator (PLUS, IP, Greedy);
1740                else
1741                   Link_Tail (IP, Emit_Node (WHILEM));
1742                   Insert_Curly_Operator
1743                     (CURLYX, 1, Max_Curly_Repeat, IP, Greedy);
1744                   Link_Tail (IP, Emit_Node (NOTHING));
1745                end if;
1746
1747             when '?' =>
1748                if New_Flags.Simple then
1749                   Insert_Curly_Operator (CURLY, 0, 1, IP, Greedy);
1750                else
1751                   Link_Tail (IP, Emit_Node (WHILEM));
1752                   Insert_Curly_Operator (CURLYX, 0, 1, IP, Greedy);
1753                   Link_Tail (IP, Emit_Node (NOTHING));
1754                end if;
1755
1756             when '{' =>
1757                declare
1758                   Min, Max : Natural;
1759
1760                begin
1761                   Get_Curly_Arguments (Parse_Pos, Min, Max, Greedy);
1762
1763                   if New_Flags.Simple then
1764                      Insert_Curly_Operator (CURLY, Min, Max, IP, Greedy);
1765                   else
1766                      Link_Tail (IP, Emit_Node (WHILEM));
1767                      Insert_Curly_Operator (CURLYX, Min, Max, IP, Greedy);
1768                      Link_Tail (IP, Emit_Node (NOTHING));
1769                   end if;
1770                end;
1771
1772             when others =>
1773                null;
1774          end case;
1775
1776          Parse_Pos := Parse_Pos + 1;
1777
1778          if Parse_Pos <= Parse_End
1779            and then Is_Mult (Parse_Pos)
1780          then
1781             Fail ("nested *+{");
1782          end if;
1783       end Parse_Piece;
1784
1785       ---------------------------------
1786       -- Parse_Posix_Character_Class --
1787       ---------------------------------
1788
1789       function Parse_Posix_Character_Class return Std_Class is
1790          Invert : Boolean := False;
1791          Class  : Std_Class := ANYOF_NONE;
1792          E      : String renames Expression;
1793
1794          --  Class names. Note that code assumes that the length of all
1795          --  classes starting with the same letter have the same length.
1796
1797          Alnum   : constant String := "alnum:]";
1798          Alpha   : constant String := "alpha:]";
1799          Ascii_C : constant String := "ascii:]";
1800          Cntrl   : constant String := "cntrl:]";
1801          Digit   : constant String := "digit:]";
1802          Graph   : constant String := "graph:]";
1803          Lower   : constant String := "lower:]";
1804          Print   : constant String := "print:]";
1805          Punct   : constant String := "punct:]";
1806          Space   : constant String := "space:]";
1807          Upper   : constant String := "upper:]";
1808          Word    : constant String := "word:]";
1809          Xdigit  : constant String := "xdigit:]";
1810
1811       begin
1812          --  Case of character class specified
1813
1814          if Parse_Pos <= Parse_End
1815            and then Expression (Parse_Pos) = ':'
1816          then
1817             Parse_Pos := Parse_Pos + 1;
1818
1819             --  Do we have something like:  [[:^alpha:]]
1820
1821             if Parse_Pos <= Parse_End
1822               and then Expression (Parse_Pos) = '^'
1823             then
1824                Invert := True;
1825                Parse_Pos := Parse_Pos + 1;
1826             end if;
1827
1828             --  Check for class names based on first letter
1829
1830             case Expression (Parse_Pos) is
1831                when 'a' =>
1832
1833                   --  All 'a' classes have the same length (Alnum'Length)
1834
1835                   if Parse_Pos + Alnum'Length - 1 <= Parse_End then
1836                      if
1837                        E (Parse_Pos .. Parse_Pos + Alnum'Length - 1) = Alnum
1838                      then
1839                         if Invert then
1840                            Class := ANYOF_NALNUMC;
1841                         else
1842                            Class := ANYOF_ALNUMC;
1843                         end if;
1844
1845                         Parse_Pos := Parse_Pos + Alnum'Length;
1846
1847                      elsif
1848                        E (Parse_Pos .. Parse_Pos + Alpha'Length - 1) = Alpha
1849                      then
1850                         if Invert then
1851                            Class := ANYOF_NALPHA;
1852                         else
1853                            Class := ANYOF_ALPHA;
1854                         end if;
1855
1856                         Parse_Pos := Parse_Pos + Alpha'Length;
1857
1858                      elsif E (Parse_Pos .. Parse_Pos + Ascii_C'Length - 1) =
1859                                                                       Ascii_C
1860                      then
1861                         if Invert then
1862                            Class := ANYOF_NASCII;
1863                         else
1864                            Class := ANYOF_ASCII;
1865                         end if;
1866
1867                         Parse_Pos := Parse_Pos + Ascii_C'Length;
1868
1869                      else
1870                         Fail ("Invalid character class: " & E);
1871                      end if;
1872
1873                   else
1874                      Fail ("Invalid character class: " & E);
1875                   end if;
1876
1877                when 'c' =>
1878                   if Parse_Pos + Cntrl'Length - 1 <= Parse_End
1879                     and then
1880                       E (Parse_Pos .. Parse_Pos + Cntrl'Length - 1) = Cntrl
1881                   then
1882                      if Invert then
1883                         Class := ANYOF_NCNTRL;
1884                      else
1885                         Class := ANYOF_CNTRL;
1886                      end if;
1887
1888                      Parse_Pos := Parse_Pos + Cntrl'Length;
1889
1890                   else
1891                      Fail ("Invalid character class: " & E);
1892                   end if;
1893
1894                when 'd' =>
1895                   if Parse_Pos + Digit'Length - 1 <= Parse_End
1896                     and then
1897                       E (Parse_Pos .. Parse_Pos + Digit'Length - 1) = Digit
1898                   then
1899                      if Invert then
1900                         Class := ANYOF_NDIGIT;
1901                      else
1902                         Class := ANYOF_DIGIT;
1903                      end if;
1904
1905                      Parse_Pos := Parse_Pos + Digit'Length;
1906                   end if;
1907
1908                when 'g' =>
1909                   if Parse_Pos + Graph'Length - 1 <= Parse_End
1910                     and then
1911                       E (Parse_Pos .. Parse_Pos + Graph'Length - 1) = Graph
1912                   then
1913                      if Invert then
1914                         Class := ANYOF_NGRAPH;
1915                      else
1916                         Class := ANYOF_GRAPH;
1917                      end if;
1918
1919                      Parse_Pos := Parse_Pos + Graph'Length;
1920
1921                   else
1922                      Fail ("Invalid character class: " & E);
1923                   end if;
1924
1925                when 'l' =>
1926                   if Parse_Pos + Lower'Length - 1 <= Parse_End
1927                     and then
1928                       E (Parse_Pos .. Parse_Pos + Lower'Length - 1) = Lower
1929                   then
1930                      if Invert then
1931                         Class := ANYOF_NLOWER;
1932                      else
1933                         Class := ANYOF_LOWER;
1934                      end if;
1935
1936                      Parse_Pos := Parse_Pos + Lower'Length;
1937
1938                   else
1939                      Fail ("Invalid character class: " & E);
1940                   end if;
1941
1942                when 'p' =>
1943
1944                   --  All 'p' classes have the same length
1945
1946                   if Parse_Pos + Print'Length - 1 <= Parse_End then
1947                      if
1948                        E (Parse_Pos .. Parse_Pos + Print'Length - 1) = Print
1949                      then
1950                         if Invert then
1951                            Class := ANYOF_NPRINT;
1952                         else
1953                            Class := ANYOF_PRINT;
1954                         end if;
1955
1956                         Parse_Pos := Parse_Pos + Print'Length;
1957
1958                      elsif
1959                        E (Parse_Pos .. Parse_Pos + Punct'Length - 1) = Punct
1960                      then
1961                         if Invert then
1962                            Class := ANYOF_NPUNCT;
1963                         else
1964                            Class := ANYOF_PUNCT;
1965                         end if;
1966
1967                         Parse_Pos := Parse_Pos + Punct'Length;
1968
1969                      else
1970                         Fail ("Invalid character class: " & E);
1971                      end if;
1972
1973                   else
1974                      Fail ("Invalid character class: " & E);
1975                   end if;
1976
1977                when 's' =>
1978                   if Parse_Pos + Space'Length - 1 <= Parse_End
1979                     and then
1980                       E (Parse_Pos .. Parse_Pos + Space'Length - 1) = Space
1981                   then
1982                      if Invert then
1983                         Class := ANYOF_NSPACE;
1984                      else
1985                         Class := ANYOF_SPACE;
1986                      end if;
1987
1988                      Parse_Pos := Parse_Pos + Space'Length;
1989
1990                   else
1991                      Fail ("Invalid character class: " & E);
1992                   end if;
1993
1994                when 'u' =>
1995                   if Parse_Pos + Upper'Length - 1 <= Parse_End
1996                     and then
1997                       E (Parse_Pos .. Parse_Pos + Upper'Length - 1) = Upper
1998                   then
1999                      if Invert then
2000                         Class := ANYOF_NUPPER;
2001                      else
2002                         Class := ANYOF_UPPER;
2003                      end if;
2004
2005                      Parse_Pos := Parse_Pos + Upper'Length;
2006
2007                   else
2008                      Fail ("Invalid character class: " & E);
2009                   end if;
2010
2011                when 'w' =>
2012                   if Parse_Pos + Word'Length - 1 <= Parse_End
2013                     and then
2014                       E (Parse_Pos .. Parse_Pos + Word'Length - 1) = Word
2015                   then
2016                      if Invert then
2017                         Class := ANYOF_NALNUM;
2018                      else
2019                         Class := ANYOF_ALNUM;
2020                      end if;
2021
2022                      Parse_Pos := Parse_Pos + Word'Length;
2023
2024                   else
2025                      Fail ("Invalid character class: " & E);
2026                   end if;
2027
2028                when 'x' =>
2029                   if Parse_Pos + Xdigit'Length - 1 <= Parse_End
2030                     and then
2031                       E (Parse_Pos .. Parse_Pos + Xdigit'Length - 1) = Xdigit
2032                   then
2033                      if Invert then
2034                         Class := ANYOF_NXDIGIT;
2035                      else
2036                         Class := ANYOF_XDIGIT;
2037                      end if;
2038
2039                      Parse_Pos := Parse_Pos + Xdigit'Length;
2040
2041                   else
2042                      Fail ("Invalid character class: " & E);
2043                   end if;
2044
2045                when others =>
2046                   Fail ("Invalid character class: " & E);
2047             end case;
2048
2049          --  Character class not specified
2050
2051          else
2052             return ANYOF_NONE;
2053          end if;
2054
2055          return Class;
2056       end Parse_Posix_Character_Class;
2057
2058       Expr_Flags : Expression_Flags;
2059       Result     : Pointer;
2060
2061    --  Start of processing for Compile
2062
2063    begin
2064       Emit (MAGIC);
2065       Parse (False, Expr_Flags, Result);
2066
2067       if Result = 0 then
2068          Fail ("Couldn't compile expression");
2069       end if;
2070
2071       Final_Code_Size := Emit_Ptr - 1;
2072
2073       --  Do we want to actually compile the expression, or simply get the
2074       --  code size ???
2075
2076       if Emit_Code then
2077          Optimize (PM);
2078       end if;
2079
2080       PM.Flags := Flags;
2081    end Compile;
2082
2083    function Compile
2084      (Expression : String;
2085       Flags      : Regexp_Flags := No_Flags) return Pattern_Matcher
2086    is
2087       Size  : Program_Size;
2088       Dummy : Pattern_Matcher (0);
2089
2090    begin
2091       Compile (Dummy, Expression, Size, Flags);
2092
2093       declare
2094          Result : Pattern_Matcher (Size);
2095       begin
2096          Compile (Result, Expression, Size, Flags);
2097          return Result;
2098       end;
2099    end Compile;
2100
2101    procedure Compile
2102      (Matcher    : out Pattern_Matcher;
2103       Expression : String;
2104       Flags      : Regexp_Flags := No_Flags)
2105    is
2106       Size : Program_Size;
2107    begin
2108       Compile (Matcher, Expression, Size, Flags);
2109    end Compile;
2110
2111    ----------
2112    -- Dump --
2113    ----------
2114
2115    procedure Dump (Self : Pattern_Matcher) is
2116       Op      : Opcode;
2117       Program : Program_Data renames Self.Program;
2118
2119       procedure Dump_Until
2120         (Start  : Pointer;
2121          Till   : Pointer;
2122          Indent : Natural := 0);
2123       --  Dump the program until the node Till (not included) is met.
2124       --  Every line is indented with Index spaces at the beginning
2125       --  Dumps till the end if Till is 0.
2126
2127       ----------------
2128       -- Dump_Until --
2129       ----------------
2130
2131       procedure Dump_Until
2132         (Start  : Pointer;
2133          Till   : Pointer;
2134          Indent : Natural := 0)
2135       is
2136          Next         : Pointer;
2137          Index        : Pointer;
2138          Local_Indent : Natural := Indent;
2139          Length       : Pointer;
2140
2141       begin
2142          Index := Start;
2143          while Index < Till loop
2144             Op := Opcode'Val (Character'Pos ((Self.Program (Index))));
2145
2146             if Op = CLOSE then
2147                Local_Indent := Local_Indent - 3;
2148             end if;
2149
2150             declare
2151                Point : constant String := Pointer'Image (Index);
2152
2153             begin
2154                for J in 1 .. 6 - Point'Length loop
2155                   Put (' ');
2156                end loop;
2157
2158                Put (Point
2159                     & " : "
2160                     & (1 .. Local_Indent => ' ')
2161                     & Opcode'Image (Op));
2162             end;
2163
2164             --  Print the parenthesis number
2165
2166             if Op = OPEN or else Op = CLOSE or else Op = REFF then
2167                Put (Natural'Image (Character'Pos (Program (Index + 3))));
2168             end if;
2169
2170             Next := Index + Get_Next_Offset (Program, Index);
2171
2172             if Next = Index then
2173                Put ("  (next at 0)");
2174             else
2175                Put ("  (next at " & Pointer'Image (Next) & ")");
2176             end if;
2177
2178             case Op is
2179
2180                --  Character class operand
2181
2182                when ANYOF =>  null;
2183                   declare
2184                      Bitmap  : Character_Class;
2185                      Last    : Character := ASCII.Nul;
2186                      Current : Natural := 0;
2187
2188                      Current_Char : Character;
2189
2190                   begin
2191                      Bitmap_Operand (Program, Index, Bitmap);
2192                      Put ("   operand=");
2193
2194                      while Current <= 255 loop
2195                         Current_Char := Character'Val (Current);
2196
2197                         --  First item in a range
2198
2199                         if Get_From_Class (Bitmap, Current_Char) then
2200                            Last := Current_Char;
2201
2202                            --  Search for the last item in the range
2203
2204                            loop
2205                               Current := Current + 1;
2206                               exit when Current > 255;
2207                               Current_Char := Character'Val (Current);
2208                               exit when
2209                                 not Get_From_Class (Bitmap, Current_Char);
2210
2211                            end loop;
2212
2213                            if Last <= ' ' then
2214                               Put (Last'Img);
2215                            else
2216                               Put (Last);
2217                            end if;
2218
2219                            if Character'Succ (Last) /= Current_Char then
2220                               Put ("-" & Character'Pred (Current_Char));
2221                            end if;
2222
2223                         else
2224                            Current := Current + 1;
2225                         end if;
2226                      end loop;
2227
2228                      New_Line;
2229                      Index := Index + 3 + Bitmap'Length;
2230                   end;
2231
2232                --  string operand
2233
2234                when EXACT | EXACTF =>
2235                   Length := String_Length (Program, Index);
2236                   Put ("   operand (length:" & Program_Size'Image (Length + 1)
2237                        & ") ="
2238                        & String (Program (String_Operand (Index)
2239                                           .. String_Operand (Index)
2240                                           + Length)));
2241                   Index := String_Operand (Index) + Length + 1;
2242                   New_Line;
2243
2244                --  Node operand
2245
2246                when BRANCH =>
2247                   New_Line;
2248                   Dump_Until (Index + 3, Next, Local_Indent + 3);
2249                   Index := Next;
2250
2251                when STAR | PLUS =>
2252                   New_Line;
2253
2254                   --  Only one instruction
2255
2256                   Dump_Until (Index + 3, Index + 4, Local_Indent + 3);
2257                   Index := Next;
2258
2259                when CURLY | CURLYX =>
2260                   Put ("  {"
2261                        & Natural'Image (Read_Natural (Program, Index + 3))
2262                        & ","
2263                        & Natural'Image (Read_Natural (Program, Index + 5))
2264                        & "}");
2265                   New_Line;
2266                   Dump_Until (Index + 7, Next, Local_Indent + 3);
2267                   Index := Next;
2268
2269                when OPEN =>
2270                   New_Line;
2271                   Index := Index + 4;
2272                   Local_Indent := Local_Indent + 3;
2273
2274                when CLOSE | REFF =>
2275                   New_Line;
2276                   Index := Index + 4;
2277
2278                when EOP =>
2279                   Index := Index + 3;
2280                   New_Line;
2281                   exit;
2282
2283                --  No operand
2284
2285                when others =>
2286                   Index := Index + 3;
2287                   New_Line;
2288             end case;
2289          end loop;
2290       end Dump_Until;
2291
2292    --  Start of processing for Dump
2293
2294    begin
2295       pragma Assert (Self.Program (Program_First) = MAGIC,
2296                      "Corrupted Pattern_Matcher");
2297
2298       Put_Line ("Must start with (Self.First) = "
2299                 & Character'Image (Self.First));
2300
2301       if (Self.Flags and Case_Insensitive) /= 0 then
2302          Put_Line ("  Case_Insensitive mode");
2303       end if;
2304
2305       if (Self.Flags and Single_Line) /= 0 then
2306          Put_Line ("  Single_Line mode");
2307       end if;
2308
2309       if (Self.Flags and Multiple_Lines) /= 0 then
2310          Put_Line ("  Multiple_Lines mode");
2311       end if;
2312
2313       Put_Line ("     1 : MAGIC");
2314       Dump_Until (Program_First + 1, Self.Program'Last + 1);
2315    end Dump;
2316
2317    --------------------
2318    -- Get_From_Class --
2319    --------------------
2320
2321    function Get_From_Class
2322      (Bitmap : Character_Class;
2323       C      : Character) return Boolean
2324    is
2325       Value : constant Class_Byte := Character'Pos (C);
2326    begin
2327       return
2328         (Bitmap (Value / 8) and Bit_Conversion (Value mod 8)) /= 0;
2329    end Get_From_Class;
2330
2331    --------------
2332    -- Get_Next --
2333    --------------
2334
2335    function Get_Next (Program : Program_Data; IP : Pointer) return Pointer is
2336       Offset : constant Pointer := Get_Next_Offset (Program, IP);
2337    begin
2338       if Offset = 0 then
2339          return 0;
2340       else
2341          return IP + Offset;
2342       end if;
2343    end Get_Next;
2344
2345    ---------------------
2346    -- Get_Next_Offset --
2347    ---------------------
2348
2349    function Get_Next_Offset
2350      (Program : Program_Data;
2351       IP      : Pointer) return Pointer
2352    is
2353    begin
2354       return Pointer (Read_Natural (Program, IP + 1));
2355    end Get_Next_Offset;
2356
2357    --------------
2358    -- Is_Alnum --
2359    --------------
2360
2361    function Is_Alnum (C : Character) return Boolean is
2362    begin
2363       return Is_Alphanumeric (C) or else C = '_';
2364    end Is_Alnum;
2365
2366    ------------------
2367    -- Is_Printable --
2368    ------------------
2369
2370    function Is_Printable (C : Character) return Boolean is
2371    begin
2372       --  Printable if space or graphic character or other whitespace
2373       --  Other white space includes (HT/LF/VT/FF/CR = codes 9-13)
2374
2375       return C in Character'Val (32) .. Character'Val (126)
2376         or else C in ASCII.HT .. ASCII.CR;
2377    end Is_Printable;
2378
2379    --------------------
2380    -- Is_White_Space --
2381    --------------------
2382
2383    function Is_White_Space (C : Character) return Boolean is
2384    begin
2385       --  Note: HT = 9, LF = 10, VT = 11, FF = 12, CR = 13
2386
2387       return C = ' ' or else C in ASCII.HT .. ASCII.CR;
2388    end Is_White_Space;
2389
2390    -----------
2391    -- Match --
2392    -----------
2393
2394    procedure Match
2395      (Self       : Pattern_Matcher;
2396       Data       : String;
2397       Matches    : out Match_Array;
2398       Data_First : Integer := -1;
2399       Data_Last  : Positive := Positive'Last)
2400    is
2401       Program : Program_Data renames Self.Program; -- Shorter notation
2402
2403       First_In_Data : constant Integer := Integer'Max (Data_First, Data'First);
2404       Last_In_Data  : constant Integer := Integer'Min (Data_Last, Data'Last);
2405
2406       --  Global work variables
2407
2408       Input_Pos : Natural;           -- String-input pointer
2409       BOL_Pos   : Natural;           -- Beginning of input, for ^ check
2410       Matched   : Boolean := False;  -- Until proven True
2411
2412       Matches_Full : Match_Array (0 .. Natural'Max (Self.Paren_Count,
2413                                                     Matches'Last));
2414       --  Stores the value of all the parenthesis pairs.
2415       --  We do not use directly Matches, so that we can also use back
2416       --  references (REFF) even if Matches is too small.
2417
2418       type Natural_Array is array (Match_Count range <>) of Natural;
2419       Matches_Tmp : Natural_Array (Matches_Full'Range);
2420       --  Save the opening position of parenthesis
2421
2422       Last_Paren  : Natural := 0;
2423       --  Last parenthesis seen
2424
2425       Greedy : Boolean := True;
2426       --  True if the next operator should be greedy
2427
2428       type Current_Curly_Record;
2429       type Current_Curly_Access is access all Current_Curly_Record;
2430       type Current_Curly_Record is record
2431          Paren_Floor : Natural;  --  How far back to strip parenthesis data
2432          Cur         : Integer;  --  How many instances of scan we've matched
2433          Min         : Natural;  --  Minimal number of scans to match
2434          Max         : Natural;  --  Maximal number of scans to match
2435          Greedy      : Boolean;  --  Whether to work our way up or down
2436          Scan        : Pointer;  --  The thing to match
2437          Next        : Pointer;  --  What has to match after it
2438          Lastloc     : Natural;  --  Where we started matching this scan
2439          Old_Cc      : Current_Curly_Access; --  Before we started this one
2440       end record;
2441       --  Data used to handle the curly operator and the plus and star
2442       --  operators for complex expressions.
2443
2444       Current_Curly : Current_Curly_Access := null;
2445       --  The curly currently being processed
2446
2447       -----------------------
2448       -- Local Subprograms --
2449       -----------------------
2450
2451       function Index (Start : Positive; C : Character) return Natural;
2452       --  Find character C in Data starting at Start and return position
2453
2454       function Repeat
2455         (IP  : Pointer;
2456          Max : Natural := Natural'Last) return Natural;
2457       --  Repeatedly match something simple, report how many
2458       --  It only matches on things of length 1.
2459       --  Starting from Input_Pos, it matches at most Max CURLY.
2460
2461       function Try (Pos : Positive) return Boolean;
2462       --  Try to match at specific point
2463
2464       function Match (IP : Pointer) return Boolean;
2465       --  This is the main matching routine. Conceptually the strategy
2466       --  is simple:  check to see whether the current node matches,
2467       --  call self recursively to see whether the rest matches,
2468       --  and then act accordingly.
2469       --
2470       --  In practice Match makes some effort to avoid recursion, in
2471       --  particular by going through "ordinary" nodes (that don't
2472       --  need to know whether the rest of the match failed) by
2473       --  using a loop instead of recursion.
2474       --  Why is the above comment part of the spec rather than body ???
2475
2476       function Match_Whilem (IP : Pointer) return Boolean;
2477       --  Return True if a WHILEM matches
2478       --  How come IP is unreferenced in the body ???
2479
2480       function Recurse_Match (IP : Pointer; From : Natural) return Boolean;
2481       pragma Inline (Recurse_Match);
2482       --  Calls Match recursively. It saves and restores the parenthesis
2483       --  status and location in the input stream correctly, so that
2484       --  backtracking is possible
2485
2486       function Match_Simple_Operator
2487         (Op     : Opcode;
2488          Scan   : Pointer;
2489          Next   : Pointer;
2490          Greedy : Boolean) return Boolean;
2491       --  Return True it the simple operator (possibly non-greedy) matches
2492
2493       pragma Inline (Index);
2494       pragma Inline (Repeat);
2495
2496       --  These are two complex functions, but used only once
2497
2498       pragma Inline (Match_Whilem);
2499       pragma Inline (Match_Simple_Operator);
2500
2501       -----------
2502       -- Index --
2503       -----------
2504
2505       function Index (Start : Positive; C : Character) return Natural is
2506       begin
2507          for J in Start .. Last_In_Data loop
2508             if Data (J) = C then
2509                return J;
2510             end if;
2511          end loop;
2512
2513          return 0;
2514       end Index;
2515
2516       -------------------
2517       -- Recurse_Match --
2518       -------------------
2519
2520       function Recurse_Match (IP : Pointer; From : Natural) return Boolean is
2521          L : constant Natural := Last_Paren;
2522
2523          Tmp_F : constant Match_Array :=
2524                    Matches_Full (From + 1 .. Matches_Full'Last);
2525
2526          Start : constant Natural_Array :=
2527                    Matches_Tmp (From + 1 .. Matches_Tmp'Last);
2528          Input : constant Natural := Input_Pos;
2529
2530       begin
2531          if Match (IP) then
2532             return True;
2533          end if;
2534
2535          Last_Paren := L;
2536          Matches_Full (Tmp_F'Range) := Tmp_F;
2537          Matches_Tmp (Start'Range) := Start;
2538          Input_Pos := Input;
2539          return False;
2540       end Recurse_Match;
2541
2542       -----------
2543       -- Match --
2544       -----------
2545
2546       function Match (IP : Pointer) return Boolean is
2547          Scan   : Pointer := IP;
2548          Next   : Pointer;
2549          Op     : Opcode;
2550
2551       begin
2552          State_Machine :
2553          loop
2554             pragma Assert (Scan /= 0);
2555
2556             --  Determine current opcode and count its usage in debug mode
2557
2558             Op := Opcode'Val (Character'Pos (Program (Scan)));
2559
2560             --  Calculate offset of next instruction.
2561             --  Second character is most significant in Program_Data.
2562
2563             Next := Get_Next (Program, Scan);
2564
2565             case Op is
2566                when EOP =>
2567                   return True;  --  Success !
2568
2569                when BRANCH =>
2570                   if Program (Next) /= BRANCH then
2571                      Next := Operand (Scan); -- No choice, avoid recursion
2572
2573                   else
2574                      loop
2575                         if Recurse_Match (Operand (Scan), 0) then
2576                            return True;
2577                         end if;
2578
2579                         Scan := Get_Next (Program, Scan);
2580                         exit when Scan = 0 or else Program (Scan) /= BRANCH;
2581                      end loop;
2582
2583                      exit State_Machine;
2584                   end if;
2585
2586                when NOTHING =>
2587                   null;
2588
2589                when BOL =>
2590                   exit State_Machine when Input_Pos /= BOL_Pos
2591                     and then ((Self.Flags and Multiple_Lines) = 0
2592                               or else Data (Input_Pos - 1) /= ASCII.LF);
2593
2594                when MBOL =>
2595                   exit State_Machine when Input_Pos /= BOL_Pos
2596                     and then Data (Input_Pos - 1) /= ASCII.LF;
2597
2598                when SBOL =>
2599                   exit State_Machine when Input_Pos /= BOL_Pos;
2600
2601                when EOL =>
2602                   exit State_Machine when Input_Pos <= Data'Last
2603                     and then ((Self.Flags and Multiple_Lines) = 0
2604                               or else Data (Input_Pos) /= ASCII.LF);
2605
2606                when MEOL =>
2607                   exit State_Machine when Input_Pos <= Data'Last
2608                     and then Data (Input_Pos) /= ASCII.LF;
2609
2610                when SEOL =>
2611                   exit State_Machine when Input_Pos <= Data'Last;
2612
2613                when BOUND | NBOUND =>
2614
2615                   --  Was last char in word ?
2616
2617                   declare
2618                      N  : Boolean := False;
2619                      Ln : Boolean := False;
2620
2621                   begin
2622                      if Input_Pos /= First_In_Data then
2623                         N := Is_Alnum (Data (Input_Pos - 1));
2624                      end if;
2625
2626                      if Input_Pos > Last_In_Data then
2627                         Ln := False;
2628                      else
2629                         Ln := Is_Alnum (Data (Input_Pos));
2630                      end if;
2631
2632                      if Op = BOUND then
2633                         if N = Ln then
2634                            exit State_Machine;
2635                         end if;
2636                      else
2637                         if N /= Ln then
2638                            exit State_Machine;
2639                         end if;
2640                      end if;
2641                   end;
2642
2643                when SPACE =>
2644                   exit State_Machine when Input_Pos > Last_In_Data
2645                     or else not Is_White_Space (Data (Input_Pos));
2646                   Input_Pos := Input_Pos + 1;
2647
2648                when NSPACE =>
2649                   exit State_Machine when Input_Pos > Last_In_Data
2650                     or else Is_White_Space (Data (Input_Pos));
2651                   Input_Pos := Input_Pos + 1;
2652
2653                when DIGIT =>
2654                   exit State_Machine when Input_Pos > Last_In_Data
2655                     or else not Is_Digit (Data (Input_Pos));
2656                   Input_Pos := Input_Pos + 1;
2657
2658                when NDIGIT =>
2659                   exit State_Machine when Input_Pos > Last_In_Data
2660                     or else Is_Digit (Data (Input_Pos));
2661                   Input_Pos := Input_Pos + 1;
2662
2663                when ALNUM =>
2664                   exit State_Machine when Input_Pos > Last_In_Data
2665                     or else not Is_Alnum (Data (Input_Pos));
2666                   Input_Pos := Input_Pos + 1;
2667
2668                when NALNUM =>
2669                   exit State_Machine when Input_Pos > Last_In_Data
2670                     or else Is_Alnum (Data (Input_Pos));
2671                   Input_Pos := Input_Pos + 1;
2672
2673                when ANY =>
2674                   exit State_Machine when Input_Pos > Last_In_Data
2675                     or else Data (Input_Pos) = ASCII.LF;
2676                   Input_Pos := Input_Pos + 1;
2677
2678                when SANY =>
2679                   exit State_Machine when Input_Pos > Last_In_Data;
2680                   Input_Pos := Input_Pos + 1;
2681
2682                when EXACT =>
2683                   declare
2684                      Opnd    : Pointer  := String_Operand (Scan);
2685                      Current : Positive := Input_Pos;
2686
2687                      Last    : constant Pointer :=
2688                                  Opnd + String_Length (Program, Scan);
2689
2690                   begin
2691                      while Opnd <= Last loop
2692                         exit State_Machine when Current > Last_In_Data
2693                           or else Program (Opnd) /= Data (Current);
2694                         Current := Current + 1;
2695                         Opnd := Opnd + 1;
2696                      end loop;
2697
2698                      Input_Pos := Current;
2699                   end;
2700
2701                when EXACTF =>
2702                   declare
2703                      Opnd    : Pointer  := String_Operand (Scan);
2704                      Current : Positive := Input_Pos;
2705
2706                      Last : constant Pointer :=
2707                               Opnd + String_Length (Program, Scan);
2708
2709                   begin
2710                      while Opnd <= Last loop
2711                         exit State_Machine when Current > Last_In_Data
2712                           or else Program (Opnd) /= To_Lower (Data (Current));
2713                         Current := Current + 1;
2714                         Opnd := Opnd + 1;
2715                      end loop;
2716
2717                      Input_Pos := Current;
2718                   end;
2719
2720                when ANYOF =>
2721                   declare
2722                      Bitmap : Character_Class;
2723                   begin
2724                      Bitmap_Operand (Program, Scan, Bitmap);
2725                      exit State_Machine when Input_Pos > Last_In_Data
2726                        or else not Get_From_Class (Bitmap, Data (Input_Pos));
2727                      Input_Pos := Input_Pos + 1;
2728                   end;
2729
2730                when OPEN =>
2731                   declare
2732                      No : constant Natural :=
2733                             Character'Pos (Program (Operand (Scan)));
2734                   begin
2735                      Matches_Tmp (No) := Input_Pos;
2736                   end;
2737
2738                when CLOSE =>
2739                   declare
2740                      No : constant Natural :=
2741                             Character'Pos (Program (Operand (Scan)));
2742
2743                   begin
2744                      Matches_Full (No) := (Matches_Tmp (No), Input_Pos - 1);
2745
2746                      if Last_Paren < No then
2747                         Last_Paren := No;
2748                      end if;
2749                   end;
2750
2751                when REFF =>
2752                   declare
2753                      No : constant Natural :=
2754                             Character'Pos (Program (Operand (Scan)));
2755
2756                      Data_Pos : Natural;
2757
2758                   begin
2759                      --  If we haven't seen that parenthesis yet
2760
2761                      if Last_Paren < No then
2762                         return False;
2763                      end if;
2764
2765                      Data_Pos := Matches_Full (No).First;
2766
2767                      while Data_Pos <= Matches_Full (No).Last loop
2768                         if Input_Pos > Last_In_Data
2769                           or else Data (Input_Pos) /= Data (Data_Pos)
2770                         then
2771                            return False;
2772                         end if;
2773
2774                         Input_Pos := Input_Pos + 1;
2775                         Data_Pos := Data_Pos + 1;
2776                      end loop;
2777                   end;
2778
2779                when MINMOD =>
2780                   Greedy := False;
2781
2782                when STAR | PLUS | CURLY =>
2783                   declare
2784                      Greed : constant Boolean := Greedy;
2785                   begin
2786                      Greedy := True;
2787                      return Match_Simple_Operator (Op, Scan, Next, Greed);
2788                   end;
2789
2790                when CURLYX =>
2791
2792                   --  Looking at something like:
2793
2794                   --    1: CURLYX {n,m}  (->4)
2795                   --    2:   code for complex thing  (->3)
2796                   --    3:   WHILEM (->0)
2797                   --    4: NOTHING
2798
2799                   declare
2800                      Min : constant Natural :=
2801                              Read_Natural (Program, Scan + 3);
2802                      Max : constant Natural :=
2803                              Read_Natural (Program, Scan + 5);
2804                      Cc  : aliased Current_Curly_Record;
2805
2806                      Has_Match : Boolean;
2807
2808                   begin
2809                      Cc := (Paren_Floor => Last_Paren,
2810                             Cur         => -1,
2811                             Min         => Min,
2812                             Max         => Max,
2813                             Greedy      => Greedy,
2814                             Scan        => Scan + 7,
2815                             Next        => Next,
2816                             Lastloc     => 0,
2817                             Old_Cc      => Current_Curly);
2818                      Current_Curly := Cc'Unchecked_Access;
2819
2820                      Has_Match := Match (Next - 3);
2821
2822                      --  Start on the WHILEM
2823
2824                      Current_Curly := Cc.Old_Cc;
2825                      return Has_Match;
2826                   end;
2827
2828                when WHILEM =>
2829                   return Match_Whilem (IP);
2830             end case;
2831
2832             Scan := Next;
2833          end loop State_Machine;
2834
2835          --  If we get here, there is no match.
2836          --  For successful matches when EOP is the terminating point.
2837
2838          return False;
2839       end Match;
2840
2841       ---------------------------
2842       -- Match_Simple_Operator --
2843       ---------------------------
2844
2845       function Match_Simple_Operator
2846         (Op     : Opcode;
2847          Scan   : Pointer;
2848          Next   : Pointer;
2849          Greedy : Boolean) return Boolean
2850       is
2851          Next_Char       : Character := ASCII.Nul;
2852          Next_Char_Known : Boolean := False;
2853          No              : Integer;  --  Can be negative
2854          Min             : Natural;
2855          Max             : Natural := Natural'Last;
2856          Operand_Code    : Pointer;
2857          Old             : Natural;
2858          Last_Pos        : Natural;
2859          Save            : constant Natural := Input_Pos;
2860
2861       begin
2862          --  Lookahead to avoid useless match attempts
2863          --  when we know what character comes next.
2864
2865          if Program (Next) = EXACT then
2866             Next_Char := Program (String_Operand (Next));
2867             Next_Char_Known := True;
2868          end if;
2869
2870          --  Find the minimal and maximal values for the operator
2871
2872          case Op is
2873             when STAR =>
2874                Min := 0;
2875                Operand_Code := Operand (Scan);
2876
2877             when PLUS =>
2878                Min := 1;
2879                Operand_Code := Operand (Scan);
2880
2881             when others =>
2882                Min := Read_Natural (Program, Scan + 3);
2883                Max := Read_Natural (Program, Scan + 5);
2884                Operand_Code := Scan + 7;
2885          end case;
2886
2887          --  Non greedy operators
2888
2889          if not Greedy then
2890
2891             --  Test the minimal repetitions
2892
2893             if Min /= 0
2894               and then Repeat (Operand_Code, Min) < Min
2895             then
2896                return False;
2897             end if;
2898
2899             Old := Input_Pos;
2900
2901             --  Find the place where 'next' could work
2902
2903             if Next_Char_Known then
2904                --  Last position to check
2905
2906                if Max = Natural'Last then
2907                   Last_Pos := Last_In_Data;
2908                else
2909                   Last_Pos := Input_Pos + Max;
2910
2911                   if Last_Pos > Last_In_Data then
2912                      Last_Pos := Last_In_Data;
2913                   end if;
2914                end if;
2915
2916                --  Look for the first possible opportunity
2917
2918                loop
2919                   --  Find the next possible position
2920
2921                   while Input_Pos <= Last_Pos
2922                     and then Data (Input_Pos) /= Next_Char
2923                   loop
2924                      Input_Pos := Input_Pos + 1;
2925                   end loop;
2926
2927                   if Input_Pos > Last_Pos then
2928                      return False;
2929                   end if;
2930
2931                   --  Check that we still match if we stop
2932                   --  at the position we just found.
2933
2934                   declare
2935                      Num : constant Natural := Input_Pos - Old;
2936
2937                   begin
2938                      Input_Pos := Old;
2939
2940                      if Repeat (Operand_Code, Num) < Num then
2941                         return False;
2942                      end if;
2943                   end;
2944
2945                   --  Input_Pos now points to the new position
2946
2947                   if Match (Get_Next (Program, Scan)) then
2948                      return True;
2949                   end if;
2950
2951                   Old := Input_Pos;
2952                   Input_Pos := Input_Pos + 1;
2953                end loop;
2954
2955             --  We know what the next character is
2956
2957             else
2958                while Max >= Min loop
2959
2960                   --  If the next character matches
2961
2962                   if Match (Next) then
2963                      return True;
2964                   end if;
2965
2966                   Input_Pos := Save + Min;
2967
2968                   --  Could not or did not match -- move forward
2969
2970                   if Repeat (Operand_Code, 1) /= 0 then
2971                      Min := Min + 1;
2972                   else
2973                      return False;
2974                   end if;
2975                end loop;
2976             end if;
2977
2978             return False;
2979
2980          --  Greedy operators
2981
2982          else
2983             No := Repeat (Operand_Code, Max);
2984
2985             --  ??? Perl has some special code here in case the
2986             --  next instruction is of type EOL, since $ and \Z
2987             --  can match before *and* after newline at the end.
2988
2989             --  ??? Perl has some special code here in case (paren)
2990             --  is True.
2991
2992             --  Else, if we don't have any parenthesis
2993
2994             while No >= Min loop
2995                if not Next_Char_Known
2996                  or else (Input_Pos <= Last_In_Data
2997                            and then Data (Input_Pos) = Next_Char)
2998                then
2999                   if Match (Next) then
3000                      return True;
3001                   end if;
3002                end if;
3003
3004                --  Could not or did not work, we back up
3005
3006                No := No - 1;
3007                Input_Pos := Save + No;
3008             end loop;
3009
3010             return False;
3011          end if;
3012       end Match_Simple_Operator;
3013
3014       ------------------
3015       -- Match_Whilem --
3016       ------------------
3017
3018       --  This is really hard to understand, because after we match what we
3019       --  are trying to match, we must make sure the rest of the REx is going
3020       --  to match for sure, and to do that we have to go back UP the parse
3021       --  tree by recursing ever deeper.  And if it fails, we have to reset
3022       --  our parent's current state that we can try again after backing off.
3023
3024       function Match_Whilem (IP : Pointer) return Boolean is
3025          pragma Unreferenced (IP);
3026
3027          Cc : constant Current_Curly_Access := Current_Curly;
3028          N  : constant Natural              := Cc.Cur + 1;
3029          Ln : Natural                       := 0;
3030
3031          Lastloc : constant Natural := Cc.Lastloc;
3032          --  Detection of 0-len
3033
3034       begin
3035          --  If degenerate scan matches "", assume scan done
3036
3037          if Input_Pos = Cc.Lastloc
3038            and then N >= Cc.Min
3039          then
3040             --  Temporarily restore the old context, and check that we
3041             --  match was comes after CURLYX.
3042
3043             Current_Curly := Cc.Old_Cc;
3044
3045             if Current_Curly /= null then
3046                Ln := Current_Curly.Cur;
3047             end if;
3048
3049             if Match (Cc.Next) then
3050                return True;
3051             end if;
3052
3053             if Current_Curly /= null then
3054                Current_Curly.Cur := Ln;
3055             end if;
3056
3057             Current_Curly := Cc;
3058             return False;
3059          end if;
3060
3061          --  First, just match a string of min scans
3062
3063          if N < Cc.Min then
3064             Cc.Cur := N;
3065             Cc.Lastloc := Input_Pos;
3066
3067             if Match (Cc.Scan) then
3068                return True;
3069             end if;
3070
3071             Cc.Cur := N - 1;
3072             Cc.Lastloc := Lastloc;
3073             return False;
3074          end if;
3075
3076          --  Prefer next over scan for minimal matching
3077
3078          if not Cc.Greedy then
3079             Current_Curly := Cc.Old_Cc;
3080
3081             if Current_Curly /= null then
3082                Ln := Current_Curly.Cur;
3083             end if;
3084
3085             if Recurse_Match (Cc.Next, Cc.Paren_Floor) then
3086                return True;
3087             end if;
3088
3089             if Current_Curly /= null then
3090                Current_Curly.Cur := Ln;
3091             end if;
3092
3093             Current_Curly := Cc;
3094
3095             --  Maximum greed exceeded ?
3096
3097             if N >= Cc.Max then
3098                return False;
3099             end if;
3100
3101             --  Try scanning more and see if it helps
3102             Cc.Cur := N;
3103             Cc.Lastloc := Input_Pos;
3104
3105             if Recurse_Match (Cc.Scan, Cc.Paren_Floor) then
3106                return True;
3107             end if;
3108
3109             Cc.Cur := N - 1;
3110             Cc.Lastloc := Lastloc;
3111             return False;
3112          end if;
3113
3114          --  Prefer scan over next for maximal matching
3115
3116          if N < Cc.Max then   --  more greed allowed ?
3117             Cc.Cur := N;
3118             Cc.Lastloc := Input_Pos;
3119
3120             if Recurse_Match (Cc.Scan, Cc.Paren_Floor) then
3121                return True;
3122             end if;
3123          end if;
3124
3125          --  Failed deeper matches of scan, so see if this one works
3126
3127          Current_Curly := Cc.Old_Cc;
3128
3129          if Current_Curly /= null then
3130             Ln := Current_Curly.Cur;
3131          end if;
3132
3133          if Match (Cc.Next) then
3134             return True;
3135          end if;
3136
3137          if Current_Curly /= null then
3138             Current_Curly.Cur := Ln;
3139          end if;
3140
3141          Current_Curly := Cc;
3142          Cc.Cur := N - 1;
3143          Cc.Lastloc := Lastloc;
3144          return False;
3145       end Match_Whilem;
3146
3147       ------------
3148       -- Repeat --
3149       ------------
3150
3151       function Repeat
3152         (IP  : Pointer;
3153          Max : Natural := Natural'Last) return Natural
3154       is
3155          Scan  : Natural := Input_Pos;
3156          Last  : Natural;
3157          Op    : constant Opcode := Opcode'Val (Character'Pos (Program (IP)));
3158          Count : Natural;
3159          C     : Character;
3160          Is_First : Boolean := True;
3161          Bitmap   : Character_Class;
3162
3163       begin
3164          if Max = Natural'Last or else Scan + Max - 1 > Last_In_Data then
3165             Last := Last_In_Data;
3166          else
3167             Last := Scan + Max - 1;
3168          end if;
3169
3170          case Op is
3171             when ANY =>
3172                while Scan <= Last
3173                  and then Data (Scan) /= ASCII.LF
3174                loop
3175                   Scan := Scan + 1;
3176                end loop;
3177
3178             when SANY =>
3179                Scan := Last + 1;
3180
3181             when EXACT =>
3182
3183                --  The string has only one character if Repeat was called
3184
3185                C := Program (String_Operand (IP));
3186                while Scan <= Last
3187                  and then C = Data (Scan)
3188                loop
3189                   Scan := Scan + 1;
3190                end loop;
3191
3192             when EXACTF =>
3193
3194                --  The string has only one character if Repeat was called
3195
3196                C := Program (String_Operand (IP));
3197                while Scan <= Last
3198                  and then To_Lower (C) = Data (Scan)
3199                loop
3200                   Scan := Scan + 1;
3201                end loop;
3202
3203             when ANYOF =>
3204                if Is_First then
3205                   Bitmap_Operand (Program, IP, Bitmap);
3206                   Is_First := False;
3207                end if;
3208
3209                while Scan <= Last
3210                  and then Get_From_Class (Bitmap, Data (Scan))
3211                loop
3212                   Scan := Scan + 1;
3213                end loop;
3214
3215             when ALNUM =>
3216                while Scan <= Last
3217                  and then Is_Alnum (Data (Scan))
3218                loop
3219                   Scan := Scan + 1;
3220                end loop;
3221
3222             when NALNUM =>
3223                while Scan <= Last
3224                  and then not Is_Alnum (Data (Scan))
3225                loop
3226                   Scan := Scan + 1;
3227                end loop;
3228
3229             when SPACE =>
3230                while Scan <= Last
3231                  and then Is_White_Space (Data (Scan))
3232                loop
3233                   Scan := Scan + 1;
3234                end loop;
3235
3236             when NSPACE =>
3237                while Scan <= Last
3238                  and then not Is_White_Space (Data (Scan))
3239                loop
3240                   Scan := Scan + 1;
3241                end loop;
3242
3243             when DIGIT  =>
3244                while Scan <= Last
3245                  and then Is_Digit (Data (Scan))
3246                loop
3247                   Scan := Scan + 1;
3248                end loop;
3249
3250             when NDIGIT  =>
3251                while Scan <= Last
3252                  and then not Is_Digit (Data (Scan))
3253                loop
3254                   Scan := Scan + 1;
3255                end loop;
3256
3257             when others =>
3258                raise Program_Error;
3259          end case;
3260
3261          Count := Scan - Input_Pos;
3262          Input_Pos := Scan;
3263          return Count;
3264       end Repeat;
3265
3266       ---------
3267       -- Try --
3268       ---------
3269
3270       function Try (Pos : Positive) return Boolean is
3271       begin
3272          Input_Pos  := Pos;
3273          Last_Paren := 0;
3274          Matches_Full := (others => No_Match);
3275
3276          if Match (Program_First + 1) then
3277             Matches_Full (0) := (Pos, Input_Pos - 1);
3278             return True;
3279          end if;
3280
3281          return False;
3282       end Try;
3283
3284    --  Start of processing for Match
3285
3286    begin
3287       --  Do we have the regexp Never_Match?
3288
3289       if Self.Size = 0 then
3290          Matches := (others => No_Match);
3291          return;
3292       end if;
3293
3294       --  Check validity of program
3295
3296       pragma Assert
3297         (Program (Program_First) = MAGIC,
3298          "Corrupted Pattern_Matcher");
3299
3300       --  If there is a "must appear" string, look for it
3301
3302       if Self.Must_Have_Length > 0 then
3303          declare
3304             First      : constant Character := Program (Self.Must_Have);
3305             Must_First : constant Pointer := Self.Must_Have;
3306             Must_Last  : constant Pointer :=
3307                            Must_First + Pointer (Self.Must_Have_Length - 1);
3308             Next_Try   : Natural := Index (First_In_Data, First);
3309
3310          begin
3311             while Next_Try /= 0
3312               and then Data (Next_Try .. Next_Try + Self.Must_Have_Length - 1)
3313                           = String (Program (Must_First .. Must_Last))
3314             loop
3315                Next_Try := Index (Next_Try + 1, First);
3316             end loop;
3317
3318             if Next_Try = 0 then
3319                Matches := (others => No_Match);
3320                return;                  -- Not present
3321             end if;
3322          end;
3323       end if;
3324
3325       --  Mark beginning of line for ^
3326
3327       BOL_Pos := Data'First;
3328
3329       --  Simplest case first: an anchored match need be tried only once
3330
3331       if Self.Anchored and then (Self.Flags and Multiple_Lines) = 0 then
3332          Matched := Try (First_In_Data);
3333
3334       elsif Self.Anchored then
3335          declare
3336             Next_Try : Natural := First_In_Data;
3337          begin
3338             --  Test the first position in the buffer
3339             Matched := Try (Next_Try);
3340
3341             --  Else only test after newlines
3342
3343             if not Matched then
3344                while Next_Try <= Last_In_Data loop
3345                   while Next_Try <= Last_In_Data
3346                     and then Data (Next_Try) /= ASCII.LF
3347                   loop
3348                      Next_Try := Next_Try + 1;
3349                   end loop;
3350
3351                   Next_Try := Next_Try + 1;
3352
3353                   if Next_Try <= Last_In_Data then
3354                      Matched := Try (Next_Try);
3355                      exit when Matched;
3356                   end if;
3357                end loop;
3358             end if;
3359          end;
3360
3361       elsif Self.First /= ASCII.NUL then
3362          --  We know what char it must start with
3363
3364          declare
3365             Next_Try : Natural := Index (First_In_Data, Self.First);
3366
3367          begin
3368             while Next_Try /= 0 loop
3369                Matched := Try (Next_Try);
3370                exit when Matched;
3371                Next_Try := Index (Next_Try + 1, Self.First);
3372             end loop;
3373          end;
3374
3375       else
3376          --  Messy cases: try all locations (including for the empty string)
3377
3378          Matched := Try (First_In_Data);
3379
3380          if not Matched then
3381             for S in First_In_Data + 1 .. Last_In_Data loop
3382                Matched := Try (S);
3383                exit when Matched;
3384             end loop;
3385          end if;
3386       end if;
3387
3388       --  Matched has its value
3389
3390       for J in Last_Paren + 1 .. Matches'Last loop
3391          Matches_Full (J) := No_Match;
3392       end loop;
3393
3394       Matches := Matches_Full (Matches'Range);
3395    end Match;
3396
3397    -----------
3398    -- Match --
3399    -----------
3400
3401    function Match
3402      (Self       : Pattern_Matcher;
3403       Data       : String;
3404       Data_First : Integer := -1;
3405       Data_Last  : Positive := Positive'Last) return Natural
3406    is
3407       Matches : Match_Array (0 .. 0);
3408
3409    begin
3410       Match (Self, Data, Matches, Data_First, Data_Last);
3411       if Matches (0) = No_Match then
3412          return Data'First - 1;
3413       else
3414          return Matches (0).First;
3415       end if;
3416    end Match;
3417
3418    function Match
3419      (Self       : Pattern_Matcher;
3420       Data       : String;
3421       Data_First : Integer  := -1;
3422       Data_Last  : Positive := Positive'Last) return Boolean
3423    is
3424       Matches : Match_Array (0 .. 0);
3425
3426    begin
3427       Match (Self, Data, Matches, Data_First, Data_Last);
3428       return Matches (0).First >= Data'First;
3429    end Match;
3430
3431    procedure Match
3432      (Expression : String;
3433       Data       : String;
3434       Matches    : out Match_Array;
3435       Size       : Program_Size := Auto_Size;
3436       Data_First : Integer      := -1;
3437       Data_Last  : Positive     := Positive'Last)
3438    is
3439       PM            : Pattern_Matcher (Size);
3440       Finalize_Size : Program_Size;
3441
3442    begin
3443       if Size = 0 then
3444          Match (Compile (Expression), Data, Matches, Data_First, Data_Last);
3445       else
3446          Compile (PM, Expression, Finalize_Size);
3447          Match (PM, Data, Matches, Data_First, Data_Last);
3448       end if;
3449    end Match;
3450
3451    -----------
3452    -- Match --
3453    -----------
3454
3455    function Match
3456      (Expression : String;
3457       Data       : String;
3458       Size       : Program_Size := Auto_Size;
3459       Data_First : Integer      := -1;
3460       Data_Last  : Positive     := Positive'Last) return Natural
3461    is
3462       PM         : Pattern_Matcher (Size);
3463       Final_Size : Program_Size; -- unused
3464
3465    begin
3466       if Size = 0 then
3467          return Match (Compile (Expression), Data, Data_First, Data_Last);
3468       else
3469          Compile (PM, Expression, Final_Size);
3470          return Match (PM, Data, Data_First, Data_Last);
3471       end if;
3472    end Match;
3473
3474    -----------
3475    -- Match --
3476    -----------
3477
3478    function  Match
3479      (Expression : String;
3480       Data       : String;
3481       Size       : Program_Size := Auto_Size;
3482       Data_First : Integer      := -1;
3483       Data_Last  : Positive     := Positive'Last) return Boolean
3484    is
3485       Matches    : Match_Array (0 .. 0);
3486       PM         : Pattern_Matcher (Size);
3487       Final_Size : Program_Size; -- unused
3488
3489    begin
3490       if Size = 0 then
3491          Match (Compile (Expression), Data, Matches, Data_First, Data_Last);
3492       else
3493          Compile (PM, Expression, Final_Size);
3494          Match (PM, Data, Matches, Data_First, Data_Last);
3495       end if;
3496
3497       return Matches (0).First >= Data'First;
3498    end Match;
3499
3500    -------------
3501    -- Operand --
3502    -------------
3503
3504    function Operand (P : Pointer) return Pointer is
3505    begin
3506       return P + 3;
3507    end Operand;
3508
3509    --------------
3510    -- Optimize --
3511    --------------
3512
3513    procedure Optimize (Self : in out Pattern_Matcher) is
3514       Scan    : Pointer;
3515       Program : Program_Data renames Self.Program;
3516
3517    begin
3518       --  Start with safe defaults (no optimization):
3519       --    *  No known first character of match
3520       --    *  Does not necessarily start at beginning of line
3521       --    *  No string known that has to appear in data
3522
3523       Self.First := ASCII.NUL;
3524       Self.Anchored := False;
3525       Self.Must_Have := Program'Last + 1;
3526       Self.Must_Have_Length := 0;
3527
3528       Scan := Program_First + 1;  --  First instruction (can be anything)
3529
3530       if Program (Scan) = EXACT then
3531          Self.First := Program (String_Operand (Scan));
3532
3533       elsif Program (Scan) = BOL
3534         or else Program (Scan) = SBOL
3535         or else Program (Scan) = MBOL
3536       then
3537          Self.Anchored := True;
3538       end if;
3539    end Optimize;
3540
3541    -----------------
3542    -- Paren_Count --
3543    -----------------
3544
3545    function Paren_Count (Regexp : Pattern_Matcher) return Match_Count is
3546    begin
3547       return Regexp.Paren_Count;
3548    end Paren_Count;
3549
3550    -----------
3551    -- Quote --
3552    -----------
3553
3554    function Quote (Str : String) return String is
3555       S    : String (1 .. Str'Length * 2);
3556       Last : Natural := 0;
3557
3558    begin
3559       for J in Str'Range loop
3560          case Str (J) is
3561             when '^' | '$' | '|' | '*' | '+' | '?' | '{' |
3562                  '}' | '[' | ']' | '(' | ')' | '\' | '.' =>
3563
3564                S (Last + 1) := '\';
3565                S (Last + 2) := Str (J);
3566                Last := Last + 2;
3567
3568             when others =>
3569                S (Last + 1) := Str (J);
3570                Last := Last + 1;
3571          end case;
3572       end loop;
3573
3574       return S (1 .. Last);
3575    end Quote;
3576
3577    ------------------
3578    -- Read_Natural --
3579    ------------------
3580
3581    function Read_Natural
3582      (Program : Program_Data;
3583       IP      : Pointer) return Natural
3584    is
3585    begin
3586       return Character'Pos (Program (IP)) +
3587                256 * Character'Pos (Program (IP + 1));
3588    end Read_Natural;
3589
3590    -----------------
3591    -- Reset_Class --
3592    -----------------
3593
3594    procedure Reset_Class (Bitmap : out Character_Class) is
3595    begin
3596       Bitmap := (others => 0);
3597    end Reset_Class;
3598
3599    ------------------
3600    -- Set_In_Class --
3601    ------------------
3602
3603    procedure Set_In_Class
3604      (Bitmap : in out Character_Class;
3605       C      : Character)
3606    is
3607       Value : constant Class_Byte := Character'Pos (C);
3608    begin
3609       Bitmap (Value / 8) := Bitmap (Value / 8)
3610         or Bit_Conversion (Value mod 8);
3611    end Set_In_Class;
3612
3613    -------------------
3614    -- String_Length --
3615    -------------------
3616
3617    function String_Length
3618      (Program : Program_Data;
3619       P       : Pointer) return Program_Size
3620    is
3621    begin
3622       pragma Assert (Program (P) = EXACT or else Program (P) = EXACTF);
3623       return Character'Pos (Program (P + 3));
3624    end String_Length;
3625
3626    --------------------
3627    -- String_Operand --
3628    --------------------
3629
3630    function String_Operand (P : Pointer) return Pointer is
3631    begin
3632       return P + 4;
3633    end String_Operand;
3634
3635 end System.Regpat;