gcc/ada/s-intman-solaris.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --           S Y S T E M . I N T E R R U P T _ M A N A G E M E N T          --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is a Solaris version of this package
  33
  34 --  Make a careful study of all signals available under the OS, to see which
  35 --  need to be reserved, kept always unmasked, or kept always unmasked.
  36
  37 --  Be on the lookout for special signals that may be used by the thread
  38 --  library.
  39
  40 package body System.Interrupt_Management is
  41
  42    use Interfaces.C;
  43    use System.OS_Interface;
  44
  45    type Interrupt_List is array (Interrupt_ID range <>) of Interrupt_ID;
  46
  47    Exception_Interrupts : constant Interrupt_List :=
  48      (SIGFPE, SIGILL, SIGSEGV, SIGBUS);
  49
  50    Unreserve_All_Interrupts : Interfaces.C.int;
  51    pragma Import
  52      (C, Unreserve_All_Interrupts, "__gl_unreserve_all_interrupts");
  53
  54    function State (Int : Interrupt_ID) return Character;
  55    pragma Import (C, State, "__gnat_get_interrupt_state");
  56    --  Get interrupt state.  Defined in init.c
  57    --  The input argument is the interrupt number,
  58    --  and the result is one of the following:
  59
  60    User    : constant Character := 'u';
  61    Runtime : constant Character := 'r';
  62    Default : constant Character := 's';
  63    --    'n'   this interrupt not set by any Interrupt_State pragma
  64    --    'u'   Interrupt_State pragma set state to User
  65    --    'r'   Interrupt_State pragma set state to Runtime
  66    --    's'   Interrupt_State pragma set state to System (use "default"
  67    --           system handler)
  68
  69    ----------------------
  70    -- Notify_Exception --
  71    ----------------------
  72
  73    --  This function identifies the Ada exception to be raised using the
  74    --  information when the system received a synchronous signal. Since this
  75    --  function is machine and OS dependent, different code has to be provided
  76    --  for different target.
  77
  78    procedure Notify_Exception
  79      (signo   : Signal;
  80       info    : access siginfo_t;
  81       context : access ucontext_t);
  82
  83    ----------------------
  84    -- Notify_Exception --
  85    ----------------------
  86
  87    procedure Notify_Exception
  88      (signo   : Signal;
  89       info    : access siginfo_t;
  90       context : access ucontext_t)
  91    is
  92    begin
  93       --  Perform the necessary context adjustments prior to a raise
  94       --  from a signal handler.
  95
  96       Adjust_Context_For_Raise (signo, context.all'Address);
  97
  98       --  Check that treatment of exception propagation here
  99       --  is consistent with treatment of the abort signal in
 100       --  System.Task_Primitives.Operations.
 101
 102       case signo is
 103          when SIGFPE =>
 104             case info.si_code is
 105                when  FPE_INTDIV |
 106                      FPE_INTOVF |
 107                      FPE_FLTDIV |
 108                      FPE_FLTOVF |
 109                      FPE_FLTUND |
 110                      FPE_FLTRES |
 111                      FPE_FLTINV |
 112                      FPE_FLTSUB =>
 113
 114                   raise Constraint_Error;
 115
 116                when others =>
 117                   pragma Assert (False);
 118                   null;
 119             end case;
 120
 121          when SIGILL | SIGSEGV | SIGBUS  =>
 122             raise Storage_Error;
 123
 124          when others =>
 125             pragma Assert (False);
 126             null;
 127       end case;
 128    end Notify_Exception;
 129
 130    ----------------
 131    -- Initialize --
 132    ----------------
 133
 134    Initialized : Boolean := False;
 135
 136    procedure Initialize is
 137       act     : aliased struct_sigaction;
 138       old_act : aliased struct_sigaction;
 139       mask    : aliased sigset_t;
 140       Result  : Interfaces.C.int;
 141
 142    begin
 143       if Initialized then
 144          return;
 145       end if;
 146
 147       Initialized := True;
 148
 149       --  Need to call pthread_init very early because it is doing signal
 150       --  initializations.
 151
 152       pthread_init;
 153
 154       --  Change this if you want to use another signal for task abort.
 155       --  SIGTERM might be a good one.
 156
 157       Abort_Task_Interrupt := SIGABRT;
 158
 159       act.sa_handler := Notify_Exception'Address;
 160
 161       --  Set sa_flags to SA_NODEFER so that during the handler execution
 162       --  we do not change the Signal_Mask to be masked for the Signal.
 163       --  This is a temporary fix to the problem that the Signal_Mask is
 164       --  not restored after the exception (longjmp) from the handler.
 165       --  The right fix should be made in sigsetjmp so that we save
 166       --  the Signal_Set and restore it after a longjmp.
 167
 168       --  In that case, this field should be changed back to 0. ??? (Dong-Ik)
 169
 170       act.sa_flags := 16;
 171
 172       Result := sigemptyset (mask'Access);
 173       pragma Assert (Result = 0);
 174
 175       --  ??? For the same reason explained above, we can't mask these signals
 176       --  because otherwise we won't be able to catch more than one signal.
 177
 178       act.sa_mask := mask;
 179
 180       pragma Assert (Keep_Unmasked = (Interrupt_ID'Range => False));
 181       pragma Assert (Reserve = (Interrupt_ID'Range => False));
 182
 183       for J in Exception_Interrupts'Range loop
 184          if State (Exception_Interrupts (J)) /= User then
 185             Keep_Unmasked (Exception_Interrupts (J)) := True;
 186             Reserve (Exception_Interrupts (J)) := True;
 187
 188             if State (Exception_Interrupts (J)) /= Default then
 189                Result :=
 190                  sigaction
 191                  (Signal (Exception_Interrupts (J)), act'Unchecked_Access,
 192                   old_act'Unchecked_Access);
 193                pragma Assert (Result = 0);
 194             end if;
 195          end if;
 196       end loop;
 197
 198       if State (Abort_Task_Interrupt) /= User then
 199          Keep_Unmasked (Abort_Task_Interrupt) := True;
 200          Reserve (Abort_Task_Interrupt) := True;
 201       end if;
 202
 203       --  Set SIGINT to unmasked state as long as it's
 204       --  not in "User" state.  Check for Unreserve_All_Interrupts last
 205
 206       if State (SIGINT) /= User then
 207          Keep_Unmasked (SIGINT) := True;
 208          Reserve (SIGINT) := True;
 209       end if;
 210
 211       --  Check all signals for state that requires keeping them
 212       --  unmasked and reserved
 213
 214       for J in Interrupt_ID'Range loop
 215          if State (J) = Default or else State (J) = Runtime then
 216             Keep_Unmasked (J) := True;
 217             Reserve (J) := True;
 218          end if;
 219       end loop;
 220
 221       --  Add the set of signals that must always be unmasked for this target
 222
 223       for J in Unmasked'Range loop
 224          Keep_Unmasked (Interrupt_ID (Unmasked (J))) := True;
 225          Reserve (Interrupt_ID (Unmasked (J))) := True;
 226       end loop;
 227
 228       --  Add target-specific reserved signals
 229
 230       for J in Reserved'Range loop
 231          Reserve (Interrupt_ID (Reserved (J))) := True;
 232       end loop;
 233
 234       --  Process pragma Unreserve_All_Interrupts. This overrides any
 235       --  settings due to pragma Interrupt_State:
 236
 237       if Unreserve_All_Interrupts /= 0 then
 238          Keep_Unmasked (SIGINT) := False;
 239          Reserve (SIGINT) := False;
 240       end if;
 241
 242       --  We do not have Signal 0 in reality. We just use this value to
 243       --  identify not existing signals (see s-intnam.ads). Therefore, Signal 0
 244       --  should not be used in all signal related operations hence mark it as
 245       --  reserved.
 246
 247       Reserve (0) := True;
 248    end Initialize;
 249
 250 end System.Interrupt_Management;