gcc/ada/s-intman-posix.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --           S Y S T E M . I N T E R R U P T _ M A N A G E M E N T          --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is the POSIX threads version of this package
  33
  34 --  Make a careful study of all signals available under the OS, to see which
  35 --  need to be reserved, kept always unmasked, or kept always unmasked. Be on
  36 --  the lookout for special signals that may be used by the thread library.
  37
  38 --  Since this is a multi target file, the signal <-> exception mapping
  39 --  is simple minded. If you need a more precise and target specific
  40 --  signal handling, create a new s-intman.adb that will fit your needs.
  41
  42 --  This file assumes that:
  43
  44 --    SIGFPE, SIGILL, SIGSEGV and SIGBUS exist. They are mapped as follows:
  45 --      SIGPFE  => Constraint_Error
  46 --      SIGILL  => Program_Error
  47 --      SIGSEGV => Storage_Error
  48 --      SIGBUS  => Storage_Error
  49
  50 --    SIGINT exists and will be kept unmasked unless the pragma
  51 --     Unreserve_All_Interrupts is specified anywhere in the application.
  52
  53 --    System.OS_Interface contains the following:
  54 --      SIGADAABORT: the signal that will be used to abort tasks.
  55 --      Unmasked: the OS specific set of signals that should be unmasked in
  56 --                all the threads. SIGADAABORT is unmasked by
  57 --                default
  58 --      Reserved: the OS specific set of signals that are reserved.
  59
  60 with System.Task_Primitives;
  61
  62 package body System.Interrupt_Management is
  63
  64    use Interfaces.C;
  65    use System.OS_Interface;
  66
  67    type Interrupt_List is array (Interrupt_ID range <>) of Interrupt_ID;
  68    Exception_Interrupts : constant Interrupt_List :=
  69      (SIGFPE, SIGILL, SIGSEGV, SIGBUS);
  70
  71    Unreserve_All_Interrupts : Interfaces.C.int;
  72    pragma Import
  73      (C, Unreserve_All_Interrupts, "__gl_unreserve_all_interrupts");
  74
  75    -----------------------
  76    -- Local Subprograms --
  77    -----------------------
  78
  79    function State (Int : Interrupt_ID) return Character;
  80    pragma Import (C, State, "__gnat_get_interrupt_state");
  81    --  Get interrupt state. Defined in init.c The input argument is the
  82    --  interrupt number, and the result is one of the following:
  83
  84    User    : constant Character := 'u';
  85    Runtime : constant Character := 'r';
  86    Default : constant Character := 's';
  87    --    'n'   this interrupt not set by any Interrupt_State pragma
  88    --    'u'   Interrupt_State pragma set state to User
  89    --    'r'   Interrupt_State pragma set state to Runtime
  90    --    's'   Interrupt_State pragma set state to System (use "default"
  91    --           system handler)
  92
  93    procedure Notify_Exception
  94      (signo    : Signal;
  95       siginfo  : System.Address;
  96       ucontext : System.Address);
  97    --  This function identifies the Ada exception to be raised using the
  98    --  information when the system received a synchronous signal. Since this
  99    --  function is machine and OS dependent, different code has to be provided
 100    --  for different target.
 101
 102    ----------------------
 103    -- Notify_Exception --
 104    ----------------------
 105
 106    Signal_Mask : aliased sigset_t;
 107    --  The set of signals handled by Notify_Exception
 108
 109    procedure Notify_Exception
 110      (signo    : Signal;
 111       siginfo  : System.Address;
 112       ucontext : System.Address)
 113    is
 114       pragma Unreferenced (siginfo);
 115
 116       Result : Interfaces.C.int;
 117
 118    begin
 119       --  With the __builtin_longjmp, the signal mask is not restored, so we
 120       --  need to restore it explicitly.
 121
 122       Result := pthread_sigmask (SIG_UNBLOCK, Signal_Mask'Access, null);
 123       pragma Assert (Result = 0);
 124
 125       --  Perform the necessary context adjustments prior to a raise
 126       --  from a signal handler.
 127
 128       Adjust_Context_For_Raise (signo, ucontext);
 129
 130       --  Check that treatment of exception propagation here is consistent with
 131       --  treatment of the abort signal in System.Task_Primitives.Operations.
 132
 133       case signo is
 134          when SIGFPE =>
 135             raise Constraint_Error;
 136          when SIGILL =>
 137             raise Program_Error;
 138          when SIGSEGV =>
 139             raise Storage_Error;
 140          when SIGBUS =>
 141             raise Storage_Error;
 142          when others =>
 143             null;
 144       end case;
 145    end Notify_Exception;
 146
 147    ----------------
 148    -- Initialize --
 149    ----------------
 150
 151    Initialized : Boolean := False;
 152
 153    procedure Initialize is
 154       act     : aliased struct_sigaction;
 155       old_act : aliased struct_sigaction;
 156       Result  : System.OS_Interface.int;
 157
 158       Use_Alternate_Stack : constant Boolean :=
 159                               System.Task_Primitives.Alternate_Stack_Size /= 0;
 160       --  Whether to use an alternate signal stack for stack overflows
 161
 162    begin
 163       if Initialized then
 164          return;
 165       end if;
 166
 167       Initialized := True;
 168
 169       --  Need to call pthread_init very early because it is doing signal
 170       --  initializations.
 171
 172       pthread_init;
 173
 174       Abort_Task_Interrupt := SIGADAABORT;
 175
 176       act.sa_handler := Notify_Exception'Address;
 177
 178       --  Setting SA_SIGINFO asks the kernel to pass more than just the signal
 179       --  number argument to the handler when it is called. The set of extra
 180       --  parameters includes a pointer to the interrupted context, which the
 181       --  ZCX propagation scheme needs.
 182
 183       --  Most man pages for sigaction mention that sa_sigaction should be set
 184       --  instead of sa_handler when SA_SIGINFO is on.  In practice, the two
 185       --  fields are actually union'ed and located at the same offset.
 186
 187       --  On some targets, we set sa_flags to SA_NODEFER so that during the
 188       --  handler execution we do not change the Signal_Mask to be masked for
 189       --  the Signal.
 190
 191       --  This is a temporary fix to the problem that the Signal_Mask is not
 192       --  restored after the exception (longjmp) from the handler. The right
 193       --  fix should be made in sigsetjmp so that we save the Signal_Set and
 194       --  restore it after a longjmp.
 195
 196       --  Since SA_NODEFER is obsolete, instead we reset explicitly the mask
 197       --  in the exception handler.
 198
 199       Result := sigemptyset (Signal_Mask'Access);
 200       pragma Assert (Result = 0);
 201
 202       --  Add signals that map to Ada exceptions to the mask
 203
 204       for J in Exception_Interrupts'Range loop
 205          if State (Exception_Interrupts (J)) /= Default  then
 206             Result :=
 207             sigaddset (Signal_Mask'Access, Signal (Exception_Interrupts (J)));
 208             pragma Assert (Result = 0);
 209          end if;
 210       end loop;
 211
 212       act.sa_mask := Signal_Mask;
 213
 214       pragma Assert (Keep_Unmasked = (Interrupt_ID'Range => False));
 215       pragma Assert (Reserve = (Interrupt_ID'Range => False));
 216
 217       --  Process state of exception signals
 218
 219       for J in Exception_Interrupts'Range loop
 220          if State (Exception_Interrupts (J)) /= User then
 221             Keep_Unmasked (Exception_Interrupts (J)) := True;
 222             Reserve (Exception_Interrupts (J)) := True;
 223
 224             if State (Exception_Interrupts (J)) /= Default then
 225                act.sa_flags := SA_SIGINFO;
 226
 227                if Use_Alternate_Stack
 228                  and then Exception_Interrupts (J) = SIGSEGV
 229                then
 230                   act.sa_flags := act.sa_flags + SA_ONSTACK;
 231                end if;
 232
 233                Result :=
 234                  sigaction
 235                    (Signal (Exception_Interrupts (J)), act'Unchecked_Access,
 236                     old_act'Unchecked_Access);
 237                pragma Assert (Result = 0);
 238             end if;
 239          end if;
 240       end loop;
 241
 242       if State (Abort_Task_Interrupt) /= User then
 243          Keep_Unmasked (Abort_Task_Interrupt) := True;
 244          Reserve (Abort_Task_Interrupt) := True;
 245       end if;
 246
 247       --  Set SIGINT to unmasked state as long as it is not in "User" state.
 248       --  Check for Unreserve_All_Interrupts last.
 249
 250       if State (SIGINT) /= User then
 251          Keep_Unmasked (SIGINT) := True;
 252          Reserve (SIGINT) := True;
 253       end if;
 254
 255       --  Check all signals for state that requires keeping them unmasked and
 256       --  reserved.
 257
 258       for J in Interrupt_ID'Range loop
 259          if State (J) = Default or else State (J) = Runtime then
 260             Keep_Unmasked (J) := True;
 261             Reserve (J) := True;
 262          end if;
 263       end loop;
 264
 265       --  Add the set of signals that must always be unmasked for this target
 266
 267       for J in Unmasked'Range loop
 268          Keep_Unmasked (Interrupt_ID (Unmasked (J))) := True;
 269          Reserve (Interrupt_ID (Unmasked (J))) := True;
 270       end loop;
 271
 272       --  Add target-specific reserved signals
 273
 274       for J in Reserved'Range loop
 275          Reserve (Interrupt_ID (Reserved (J))) := True;
 276       end loop;
 277
 278       --  Process pragma Unreserve_All_Interrupts. This overrides any settings
 279       --  due to pragma Interrupt_State:
 280
 281       if Unreserve_All_Interrupts /= 0 then
 282          Keep_Unmasked (SIGINT) := False;
 283          Reserve (SIGINT) := False;
 284       end if;
 285
 286       --  We do not really have Signal 0. We just use this value to identify
 287       --  non-existent signals (see s-intnam.ads). Therefore, Signal should not
 288       --  be used in all signal related operations hence mark it as reserved.
 289
 290       Reserve (0) := True;
 291    end Initialize;
 292
 293 end System.Interrupt_Management;