gcc/ada/s-imgllb.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                       S Y S T E M . I M G _ L L B                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --     Copyright (C) 1992,1993,1994,1995 Free Software Foundation, Inc.     --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 with System.Unsigned_Types; use System.Unsigned_Types;
  36
  37 package body System.Img_LLB is
  38
  39    ---------------------------------------
  40    -- Set_Image_Based_Long_Long_Integer --
  41    ---------------------------------------
  42
  43    procedure Set_Image_Based_Long_Long_Integer
  44      (V : Long_Long_Integer;
  45       B : Natural;
  46       W : Integer;
  47       S : out String;
  48       P : in out Natural)
  49    is
  50       Start : Natural;
  51
  52    begin
  53       --  Positive case can just use the unsigned circuit directly
  54
  55       if V >= 0 then
  56          Set_Image_Based_Long_Long_Unsigned
  57            (Long_Long_Unsigned (V), B, W, S, P);
  58
  59       --  Negative case has to set a minus sign. Note also that we have to be
  60       --  careful not to generate overflow with the largest negative number.
  61
  62       else
  63          P := P + 1;
  64          S (P) := ' ';
  65          Start := P;
  66
  67          declare
  68             pragma Suppress (Overflow_Check);
  69             pragma Suppress (Range_Check);
  70          begin
  71             Set_Image_Based_Long_Long_Unsigned
  72               (Long_Long_Unsigned (-V), B, W - 1, S, P);
  73          end;
  74
  75          --  Set minus sign in last leading blank location. Because of the
  76          --  code above, there must be at least one such location.
  77
  78          while S (Start + 1) = ' ' loop
  79             Start := Start + 1;
  80          end loop;
  81
  82          S (Start) := '-';
  83       end if;
  84
  85    end Set_Image_Based_Long_Long_Integer;
  86
  87    ----------------------------------------
  88    -- Set_Image_Based_Long_Long_Unsigned --
  89    ----------------------------------------
  90
  91    procedure Set_Image_Based_Long_Long_Unsigned
  92      (V : Long_Long_Unsigned;
  93       B : Natural;
  94       W : Integer;
  95       S : out String;
  96       P : in out Natural)
  97    is
  98       Start : constant Natural := P;
  99       F, T  : Natural;
 100       BU    : constant Long_Long_Unsigned := Long_Long_Unsigned (B);
 101       Hex   : constant array
 102                 (Long_Long_Unsigned range 0 .. 15) of Character :=
 103                                                          "0123456789ABCDEF";
 104
 105       procedure Set_Digits (T : Long_Long_Unsigned);
 106       --  Set digits of absolute value of T
 107
 108       procedure Set_Digits (T : Long_Long_Unsigned) is
 109       begin
 110          if T >= BU then
 111             Set_Digits (T / BU);
 112             P := P + 1;
 113             S (P) := Hex (T mod BU);
 114          else
 115             P := P + 1;
 116             S (P) := Hex (T);
 117          end if;
 118       end Set_Digits;
 119
 120    --  Start of processing for Set_Image_Based_Long_Long_Unsigned
 121
 122    begin
 123
 124       if B >= 10 then
 125          P := P + 1;
 126          S (P) := '1';
 127       end if;
 128
 129       P := P + 1;
 130       S (P) := Character'Val (Character'Pos ('0') + B mod 10);
 131
 132       P := P + 1;
 133       S (P) := '#';
 134
 135       Set_Digits (V);
 136
 137       P := P + 1;
 138       S (P) := '#';
 139
 140       --  Add leading spaces if required by width parameter
 141
 142       if P - Start < W then
 143          F := P;
 144          P := Start + W;
 145          T := P;
 146
 147          while F > Start loop
 148             S (T) := S (F);
 149             T := T - 1;
 150             F := F - 1;
 151          end loop;
 152
 153          for J in Start + 1 .. T loop
 154             S (J) := ' ';
 155          end loop;
 156       end if;
 157
 158    end Set_Image_Based_Long_Long_Unsigned;
 159
 160 end System.Img_LLB;