gcc/ada/s-htable.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                        S Y S T E M . H T A B L E                         --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 1995-2010, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  Hash table searching routines
  35
  36 --  This package contains two separate packages. The Simple_HTable package
  37 --  provides a very simple abstraction that associates one element to one
  38 --  key value and takes care of all allocations automatically using the heap.
  39 --  The Static_HTable package provides a more complex interface that allows
  40 --  complete control over allocation.
  41
  42 pragma Compiler_Unit;
  43
  44 package System.HTable is
  45    pragma Preelaborate;
  46
  47    -------------------
  48    -- Simple_HTable --
  49    -------------------
  50
  51    --  A simple hash table abstraction, easy to instantiate, easy to use.
  52    --  The table associates one element to one key with the procedure Set.
  53    --  Get retrieves the Element stored for a given Key. The efficiency of
  54    --  retrieval is function of the size of the Table parameterized by
  55    --  Header_Num and the hashing function Hash.
  56
  57    generic
  58       type Header_Num is range <>;
  59       --  An integer type indicating the number and range of hash headers
  60
  61       type Element is private;
  62       --  The type of element to be stored
  63
  64       No_Element : Element;
  65       --  The object that is returned by Get when no element has been set for
  66       --  a given key
  67
  68       type Key is private;
  69       with function Hash  (F : Key)      return Header_Num;
  70       with function Equal (F1, F2 : Key) return Boolean;
  71
  72    package Simple_HTable is
  73
  74       procedure Set (K : Key; E : Element);
  75       --  Associates an element with a given key. Overrides any previously
  76       --  associated element.
  77
  78       procedure Reset;
  79       --  Removes and frees all elements in the table
  80
  81       function Get (K : Key) return Element;
  82       --  Returns the Element associated with a key or No_Element if the
  83       --  given key has no associated element.
  84
  85       procedure Remove (K : Key);
  86       --  Removes the latest inserted element pointer associated with the
  87       --  given key if any, does nothing if none.
  88
  89       function Get_First return Element;
  90       --  Returns No_Element if the HTable is empty, otherwise returns one
  91       --  non specified element. There is no guarantee that two calls to this
  92       --  function will return the same element.
  93
  94       function Get_Next return Element;
  95       --  Returns a non-specified element that has not been returned by the
  96       --  same function since the last call to Get_First or No_Element if
  97       --  there is no such element. If there is no call to Set in between
  98       --  Get_Next calls, all the elements of the HTable will be traversed.
  99
 100       procedure Get_First (K : in out Key; E : out Element);
 101       --  This version of the iterator returns a key/element pair. A non-
 102       --  specified entry is returned, and there is no guarantee that two
 103       --  calls to this procedure will return the same element. If the table
 104       --  is empty, E is set to No_Element, and K is unchanged, otherwise
 105       --  K and E are set to the first returned entry.
 106
 107       procedure Get_Next (K : in out Key; E : out Element);
 108       --  This version of the iterator returns a key/element pair. It returns
 109       --  a non-specified element that has not been returned since the last
 110       --  call to Get_First. If there is no remaining element, then E is set
 111       --  to No_Element, and the value in K is unchanged, otherwise K and E
 112       --  are set to the next entry. If there is no call to Set in between
 113       --  Get_Next calls, all the elements of the HTable will be traversed.
 114
 115    end Simple_HTable;
 116
 117    -------------------
 118    -- Static_HTable --
 119    -------------------
 120
 121    --  A low-level Hash-Table abstraction, not as easy to instantiate as
 122    --  Simple_HTable but designed to allow complete control over the
 123    --  allocation of necessary data structures. Particularly useful when
 124    --  dynamic allocation is not desired. The model is that each Element
 125    --  contains its own Key that can be retrieved by Get_Key. Furthermore,
 126    --  Element provides a link that can be used by the HTable for linking
 127    --  elements with same hash codes:
 128
 129    --       Element
 130
 131    --         +-------------------+
 132    --         |       Key         |
 133    --         +-------------------+
 134    --         :    other data     :
 135    --         +-------------------+
 136    --         |     Next Elmt     |
 137    --         +-------------------+
 138
 139    generic
 140       type Header_Num is range <>;
 141       --  An integer type indicating the number and range of hash headers
 142
 143       type Element (<>) is limited private;
 144       --  The type of element to be stored. This is historically part of the
 145       --  interface, even though it is not used at all in the operations of
 146       --  the package.
 147
 148       pragma Warnings (Off, Element);
 149       --  We have to kill warnings here, because Element is and always
 150       --  has been unreferenced, but we cannot remove it at this stage,
 151       --  since this unit is in wide use, and it certainly seems harmless.
 152
 153       type Elmt_Ptr is private;
 154       --  The type used to reference an element (will usually be an access
 155       --  type, but could be some other form of type such as an integer type).
 156
 157       Null_Ptr : Elmt_Ptr;
 158       --  The null value of the Elmt_Ptr type
 159
 160       with procedure Set_Next (E : Elmt_Ptr; Next : Elmt_Ptr);
 161       with function  Next     (E : Elmt_Ptr) return Elmt_Ptr;
 162       --  The type must provide an internal link for the sake of the
 163       --  staticness of the HTable.
 164
 165       type Key is limited private;
 166       with function Get_Key (E : Elmt_Ptr) return Key;
 167       with function Hash    (F : Key)      return Header_Num;
 168       with function Equal   (F1, F2 : Key) return Boolean;
 169
 170    package Static_HTable is
 171
 172       procedure Reset;
 173       --  Resets the hash table by setting all its elements to Null_Ptr. The
 174       --  effect is to clear the hash table so that it can be reused. For the
 175       --  most common case where Elmt_Ptr is an access type, and Null_Ptr is
 176       --  null, this is only needed if the same table is reused in a new
 177       --  context. If Elmt_Ptr is other than an access type, or Null_Ptr is
 178       --  other than null, then Reset must be called before the first use
 179       --  of the hash table.
 180
 181       procedure Set (E : Elmt_Ptr);
 182       --  Insert the element pointer in the HTable
 183
 184       function Get (K : Key) return Elmt_Ptr;
 185       --  Returns the latest inserted element pointer with the given Key
 186       --  or null if none.
 187
 188       procedure Remove (K : Key);
 189       --  Removes the latest inserted element pointer associated with the
 190       --  given key if any, does nothing if none.
 191
 192       function Get_First return Elmt_Ptr;
 193       --  Returns Null_Ptr if the HTable is empty, otherwise returns one
 194       --  non specified element. There is no guarantee that two calls to this
 195       --  function will return the same element.
 196
 197       function Get_Next return Elmt_Ptr;
 198       --  Returns a non-specified element that has not been returned by the
 199       --  same function since the last call to Get_First or Null_Ptr if
 200       --  there is no such element or Get_First has never been called. If
 201       --  there is no call to 'Set' in between Get_Next calls, all the
 202       --  elements of the HTable will be traversed.
 203
 204    end Static_HTable;
 205
 206    ----------
 207    -- Hash --
 208    ----------
 209
 210    --  A generic hashing function working on String keys
 211
 212    generic
 213       type Header_Num is range <>;
 214    function Hash (Key : String) return Header_Num;
 215
 216 end System.HTable;