gcc/ada/s-finimp.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --    S Y S T E M . F I N A L I Z A T I O N _ I M P L E M E N T A T I O N   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Exceptions;
  35 with Ada.Tags;
  36
  37 with System.Storage_Elements;
  38 with System.Soft_Links;
  39
  40 with Unchecked_Conversion;
  41 with System.Restrictions;
  42
  43 package body System.Finalization_Implementation is
  44
  45    use Ada.Exceptions;
  46    use System.Finalization_Root;
  47
  48    package SSL renames System.Soft_Links;
  49
  50    package SSE renames System.Storage_Elements;
  51    use type SSE.Storage_Offset;
  52
  53    -----------------------
  54    -- Local Subprograms --
  55    -----------------------
  56
  57    type RC_Ptr is access all Record_Controller;
  58
  59    function To_RC_Ptr is
  60      new Unchecked_Conversion (Address, RC_Ptr);
  61
  62    procedure Raise_Exception_No_Defer
  63      (E       : in Exception_Id;
  64       Message : in String := "");
  65    pragma Import (Ada, Raise_Exception_No_Defer,
  66      "ada__exceptions__raise_exception_no_defer");
  67    pragma No_Return (Raise_Exception_No_Defer);
  68    --  Raise an exception without deferring abort. Note that we have to
  69    --  use this rather kludgy Ada Import interface, since this subprogram
  70    --  is not available in the visible spec of Ada.Exceptions.
  71
  72    procedure Raise_From_Finalize
  73      (L          : Finalizable_Ptr;
  74       From_Abort : Boolean;
  75       E_Occ      : Exception_Occurrence);
  76    --  Deal with an exception raised during finalization of a list. L is a
  77    --  pointer to the list of element not yet finalized. From_Abort is true
  78    --  if the finalization actions come from an abort rather than a normal
  79    --  exit. E_Occ represents the exception being raised.
  80
  81    function RC_Offset (T : Ada.Tags.Tag) return SSE.Storage_Offset;
  82    pragma Import (Ada, RC_Offset, "ada__tags__get_rc_offset");
  83
  84    function Parent_Size (Obj : Address; T : Ada.Tags.Tag)
  85      return SSE.Storage_Count;
  86    pragma Import (Ada, Parent_Size, "ada__tags__parent_size");
  87
  88    function Parent_Tag (T : Ada.Tags.Tag) return Ada.Tags.Tag;
  89    pragma Import (Ada, Parent_Tag, "ada__tags__parent_tag");
  90
  91    function Get_Deep_Controller (Obj : System.Address) return RC_Ptr;
  92    --  Given the address (obj) of a tagged object, return a
  93    --  pointer to the record controller of this object.
  94
  95    ------------
  96    -- Adjust --
  97    ------------
  98
  99    procedure Adjust (Object : in out Record_Controller) is
 100
 101       First_Comp : Finalizable_Ptr;
 102       My_Offset : constant SSE.Storage_Offset :=
 103                     Object.My_Address - Object'Address;
 104
 105       procedure Ptr_Adjust (Ptr : in out Finalizable_Ptr);
 106       --  Subtract the offset to the pointer
 107
 108       procedure Reverse_Adjust (P : Finalizable_Ptr);
 109       --  Ajust the components in the reverse order in which they are stored
 110       --  on the finalization list. (Adjust and Finalization are not done in
 111       --  the same order)
 112
 113       ----------------
 114       -- Ptr_Adjust --
 115       ----------------
 116
 117       procedure Ptr_Adjust (Ptr : in out Finalizable_Ptr) is
 118       begin
 119          if Ptr /= null then
 120             Ptr := To_Finalizable_Ptr (To_Addr (Ptr) - My_Offset);
 121          end if;
 122       end Ptr_Adjust;
 123
 124       --------------------
 125       -- Reverse_Adjust --
 126       --------------------
 127
 128       procedure Reverse_Adjust (P : Finalizable_Ptr) is
 129       begin
 130          if P /= null then
 131             Ptr_Adjust (P.Next);
 132             Reverse_Adjust (P.Next);
 133             Adjust (P.all);
 134             Object.F := P;   --  Successfully adjusted, so place in list.
 135          end if;
 136       end Reverse_Adjust;
 137
 138    --  Start of processing for Adjust
 139
 140    begin
 141       --  Adjust the components and their finalization pointers next. We must
 142       --  protect against an exception in some call to Adjust, so we keep
 143       --  pointing to the list of successfully adjusted components, which can
 144       --  be finalized if an exception is raised.
 145
 146       First_Comp := Object.F;
 147       Object.F := null;               --  nothing adjusted yet.
 148       Ptr_Adjust (First_Comp);        --  set addresss of first component.
 149       Reverse_Adjust (First_Comp);
 150
 151       --  Then Adjust the controller itself
 152
 153       Object.My_Address := Object'Address;
 154
 155    exception
 156       when others =>
 157          --  Finalize those components that were successfully adjusted, and
 158          --  propagate exception. The object itself is not yet attached to
 159          --  global finalization list, so we cannot rely on the outer call to
 160          --  Clean to take care of these components.
 161
 162          Finalize (Object);
 163          raise;
 164    end Adjust;
 165
 166    --------------------------
 167    -- Attach_To_Final_List --
 168    --------------------------
 169
 170    procedure Attach_To_Final_List
 171      (L       : in out Finalizable_Ptr;
 172       Obj     : in out Finalizable;
 173       Nb_Link : Short_Short_Integer)
 174    is
 175    begin
 176       --  Simple case: attachement to a one way list
 177
 178       if Nb_Link = 1 then
 179          Obj.Next := L;
 180          L        := Obj'Unchecked_Access;
 181
 182       --  Dynamically allocated objects: they are attached to a doubly linked
 183       --  list, so that an element can be finalized at any moment by means of
 184       --  an unchecked deallocation. Attachement is protected against
 185       --  multi-threaded access.
 186
 187       elsif Nb_Link = 2 then
 188
 189          Locked_Processing : begin
 190             SSL.Lock_Task.all;
 191             Obj.Next    := L.Next;
 192             Obj.Prev    := L.Next.Prev;
 193             L.Next.Prev := Obj'Unchecked_Access;
 194             L.Next      := Obj'Unchecked_Access;
 195             SSL.Unlock_Task.all;
 196
 197          exception
 198             when others =>
 199                SSL.Unlock_Task.all;
 200                raise;
 201          end Locked_Processing;
 202
 203       --  Attachement of arrays to the final list (used only for objects
 204       --  returned by function). Obj, in this case is the last element,
 205       --  but all other elements are already threaded after it. We just
 206       --  attach the rest of the final list at the end of the array list.
 207
 208       elsif Nb_Link = 3 then
 209          declare
 210             P : Finalizable_Ptr := Obj'Unchecked_Access;
 211
 212          begin
 213             while P.Next /= null loop
 214                P := P.Next;
 215             end loop;
 216
 217             P.Next := L;
 218             L := Obj'Unchecked_Access;
 219          end;
 220       end if;
 221    end Attach_To_Final_List;
 222
 223    ---------------------
 224    -- Deep_Tag_Adjust --
 225    ---------------------
 226
 227    procedure Deep_Tag_Adjust
 228      (L : in out SFR.Finalizable_Ptr;
 229       A : System.Address;
 230       B : Short_Short_Integer)
 231    is
 232       V          : constant SFR.Finalizable_Ptr := To_Finalizable_Ptr (A);
 233       Controller : constant RC_Ptr := Get_Deep_Controller (A);
 234
 235    begin
 236       if Controller /= null then
 237          Adjust (Controller.all);
 238          Attach_To_Final_List (L, Controller.all, B);
 239       end if;
 240
 241       --  Is controlled
 242
 243       if V.all in Finalizable then
 244          Adjust (V.all);
 245          Attach_To_Final_List (L, Finalizable (V.all), 1);
 246       end if;
 247    end Deep_Tag_Adjust;
 248
 249    ---------------------
 250    -- Deep_Tag_Attach --
 251    ----------------------
 252
 253    procedure Deep_Tag_Attach
 254      (L : in out SFR.Finalizable_Ptr;
 255       A : System.Address;
 256       B : Short_Short_Integer)
 257    is
 258       V          : constant SFR.Finalizable_Ptr := To_Finalizable_Ptr (A);
 259       Controller : constant RC_Ptr := Get_Deep_Controller (A);
 260
 261    begin
 262       if Controller /= null then
 263          Attach_To_Final_List (L, Controller.all, B);
 264       end if;
 265
 266       --  Is controlled
 267
 268       if V.all in Finalizable then
 269          Attach_To_Final_List (L, V.all, B);
 270       end if;
 271    end Deep_Tag_Attach;
 272
 273    -----------------------
 274    -- Deep_Tag_Finalize --
 275    -----------------------
 276
 277    procedure Deep_Tag_Finalize
 278      (L : in out SFR.Finalizable_Ptr;
 279       A : System.Address;
 280       B : Boolean)
 281    is
 282       pragma Warnings (Off, L);
 283
 284       V          : constant SFR.Finalizable_Ptr := To_Finalizable_Ptr (A);
 285       Controller : constant RC_Ptr := Get_Deep_Controller (A);
 286
 287    begin
 288       if Controller /= null then
 289          if B then
 290             Finalize_One (Controller.all);
 291          else
 292             Finalize (Controller.all);
 293          end if;
 294       end if;
 295
 296       --  Is controlled
 297
 298       if V.all in Finalizable then
 299          if B then
 300             Finalize_One (V.all);
 301          else
 302             Finalize (V.all);
 303          end if;
 304       end if;
 305    end Deep_Tag_Finalize;
 306
 307    -------------------------
 308    -- Deep_Tag_Initialize --
 309    -------------------------
 310
 311    procedure Deep_Tag_Initialize
 312      (L : in out SFR.Finalizable_Ptr;
 313       A :        System.Address;
 314       B :        Short_Short_Integer)
 315    is
 316       V          : constant SFR.Finalizable_Ptr := To_Finalizable_Ptr (A);
 317       Controller : constant RC_Ptr := Get_Deep_Controller (A);
 318
 319    begin
 320       --  This procedure should not be called if the object has no
 321       --  controlled components
 322
 323       if Controller = null then
 324          raise Program_Error;
 325
 326       --  Has controlled components
 327
 328       else
 329          Initialize (Controller.all);
 330          Attach_To_Final_List (L, Controller.all, B);
 331       end if;
 332
 333       --  Is controlled
 334
 335       if V.all in Finalizable then
 336          Initialize (V.all);
 337          Attach_To_Final_List (Controller.F, Finalizable (Controller.all), 1);
 338       end if;
 339    end Deep_Tag_Initialize;
 340
 341    -----------------------------
 342    -- Detach_From_Final_List --
 343    -----------------------------
 344
 345    --  We know that the detach object is neither at the beginning nor at the
 346    --  end of the list, thank's to the dummy First and Last Elements but the
 347    --  object may not be attached at all if it is Finalize_Storage_Only
 348
 349    procedure Detach_From_Final_List (Obj : in out Finalizable) is
 350    begin
 351
 352       --  When objects are not properly attached to a doubly linked list do
 353       --  not try to detach them. The only case where it can happen is when
 354       --  dealing with Finalize_Storage_Only objects which are not always
 355       --  attached to the finalization list.
 356
 357       if Obj.Next /= null and then Obj.Prev /= null then
 358          SSL.Lock_Task.all;
 359          Obj.Next.Prev := Obj.Prev;
 360          Obj.Prev.Next := Obj.Next;
 361          SSL.Unlock_Task.all;
 362       end if;
 363
 364    exception
 365       when others =>
 366          SSL.Unlock_Task.all;
 367          raise;
 368    end Detach_From_Final_List;
 369
 370    --------------
 371    -- Finalize --
 372    --------------
 373
 374    procedure Finalize   (Object : in out Limited_Record_Controller) is
 375    begin
 376       Finalize_List (Object.F);
 377    end Finalize;
 378
 379    --------------------------
 380    -- Finalize_Global_List --
 381    --------------------------
 382
 383    procedure Finalize_Global_List is
 384    begin
 385       --  There are three case here:
 386       --  a. the application uses tasks, in which case Finalize_Global_Tasks
 387       --     will defer abortion
 388       --  b. the application doesn't use tasks but uses other tasking
 389       --     constructs, such as ATCs and protected objects. In this case,
 390       --     the binder will call Finalize_Global_List instead of
 391       --     Finalize_Global_Tasks, letting abort undeferred, and leading
 392       --     to assertion failures in the GNULL
 393       --  c. the application doesn't use any tasking construct in which case
 394       --     deferring abort isn't necessary.
 395       --
 396       --  Until another solution is found to deal with case b, we need to
 397       --  call abort_defer here to pass the checks, but we do not need to
 398       --  undefer abortion, since Finalize_Global_List is the last procedure
 399       --  called before exiting the partition.
 400
 401       SSL.Abort_Defer.all;
 402       Finalize_List (Global_Final_List);
 403    end Finalize_Global_List;
 404
 405    -------------------
 406    -- Finalize_List --
 407    -------------------
 408
 409    procedure Finalize_List (L : Finalizable_Ptr) is
 410       P : Finalizable_Ptr := L;
 411       Q : Finalizable_Ptr;
 412
 413       type Fake_Exception_Occurence is record
 414          Id : Exception_Id;
 415       end record;
 416       type Ptr is access all Fake_Exception_Occurence;
 417
 418       function To_Ptr is new
 419         Unchecked_Conversion (Exception_Occurrence_Access, Ptr);
 420
 421       X :  Exception_Id := Null_Id;
 422
 423    begin
 424       --  If abort is allowed, we get the current exception before starting
 425       --  to finalize in order to check if we are in the abort case if an
 426       --  exception is raised. When abort is not allowed, avoid accessing the
 427       --  current exception since this can be a pretty costly operation in
 428       --  programs using controlled types heavily.
 429
 430       if System.Restrictions.Abort_Allowed then
 431          X := To_Ptr (System.Soft_Links.Get_Current_Excep.all).Id;
 432       end if;
 433
 434       while P /= null loop
 435          Q := P.Next;
 436          Finalize (P.all);
 437          P := Q;
 438       end loop;
 439
 440    exception
 441       when E_Occ : others =>
 442          Raise_From_Finalize (
 443            Q,
 444            X = Standard'Abort_Signal'Identity,
 445            E_Occ);
 446    end Finalize_List;
 447
 448    ------------------
 449    -- Finalize_One --
 450    ------------------
 451
 452    procedure Finalize_One (Obj : in out  Finalizable) is
 453    begin
 454       Detach_From_Final_List (Obj);
 455       Finalize (Obj);
 456    exception
 457       when E_Occ : others => Raise_From_Finalize (null, False, E_Occ);
 458    end Finalize_One;
 459
 460    -------------------------
 461    -- Get_Deep_Controller --
 462    -------------------------
 463
 464    function Get_Deep_Controller (Obj : System.Address) return RC_Ptr is
 465       The_Tag : Ada.Tags.Tag := To_Finalizable_Ptr (Obj)'Tag;
 466       Offset  : SSE.Storage_Offset := RC_Offset (The_Tag);
 467
 468    begin
 469       --  Fetch the controller from the Parent or above if necessary
 470       --  when there are no controller at this level
 471
 472       while Offset = -2 loop
 473          The_Tag := Parent_Tag (The_Tag);
 474          Offset  := RC_Offset (The_Tag);
 475       end loop;
 476
 477       --  No Controlled component case
 478
 479       if Offset = 0 then
 480          return null;
 481
 482       --  The _controller Offset is known statically
 483
 484       elsif Offset > 0 then
 485          return To_RC_Ptr (Obj + Offset);
 486
 487       --  At this stage, we know that the controller is part of the
 488       --  ancestor corresponding to the tag "The_Tag" and that its parent
 489       --  is variable sized. We assume that the _controller is the first
 490       --  compoment right after the parent.
 491
 492       --  ??? note that it may not be true if there are new discriminants
 493
 494       else --  Offset = -1
 495
 496          declare
 497             --  define a faked record controller to avoid generating
 498             --  unnecessary expanded code for controlled types
 499
 500             type Faked_Record_Controller is record
 501                Tag, Prec, Next : Address;
 502             end record;
 503
 504             --  Reconstruction of a type with characteristics
 505             --  comparable to the original type
 506
 507             D : constant := SSE.Storage_Offset (Storage_Unit - 1);
 508
 509             type Parent_Type is new SSE.Storage_Array
 510                    (1 .. (Parent_Size (Obj, The_Tag) + D) /
 511                             SSE.Storage_Offset (Storage_Unit));
 512             for Parent_Type'Alignment use Address'Alignment;
 513
 514             type Faked_Type_Of_Obj is record
 515                Parent : Parent_Type;
 516                Controller : Faked_Record_Controller;
 517             end record;
 518
 519             type Obj_Ptr is access all Faked_Type_Of_Obj;
 520             function To_Obj_Ptr is
 521               new Unchecked_Conversion (Address, Obj_Ptr);
 522
 523          begin
 524             return To_RC_Ptr (To_Obj_Ptr (Obj).Controller'Address);
 525          end;
 526       end if;
 527    end Get_Deep_Controller;
 528
 529    ----------------
 530    -- Initialize --
 531    ----------------
 532
 533    procedure Initialize (Object : in out Limited_Record_Controller) is
 534       pragma Warnings (Off, Object);
 535    begin
 536       null;
 537    end Initialize;
 538
 539    procedure Initialize (Object : in out Record_Controller) is
 540    begin
 541       Object.My_Address := Object'Address;
 542    end Initialize;
 543
 544    -------------------------
 545    -- Raise_From_Finalize --
 546    -------------------------
 547
 548    procedure Raise_From_Finalize
 549      (L          : Finalizable_Ptr;
 550       From_Abort : Boolean;
 551       E_Occ      : Exception_Occurrence)
 552    is
 553       Msg : constant String := Exception_Message (E_Occ);
 554       P   : Finalizable_Ptr := L;
 555       Q   : Finalizable_Ptr;
 556
 557    begin
 558       --  We already got an exception. We now finalize the remainder of
 559       --  the list, ignoring all further exceptions.
 560
 561       while P /= null loop
 562          Q := P.Next;
 563
 564          begin
 565             Finalize (P.all);
 566          exception
 567             when others => null;
 568          end;
 569
 570          P := Q;
 571       end loop;
 572
 573       --  If finalization from an Abort, then nothing to do
 574
 575       if From_Abort then
 576          null;
 577
 578       --  If no message, then add our own message saying what happened
 579
 580       elsif Msg = "" then
 581          Raise_Exception_No_Defer
 582            (E       => Program_Error'Identity,
 583             Message => "exception " &
 584                        Exception_Name (E_Occ) &
 585                        " raised during finalization");
 586
 587       --  If there was a message, pass it on
 588
 589       else
 590          Raise_Exception_No_Defer (Program_Error'Identity, Msg);
 591       end if;
 592    end Raise_From_Finalize;
 593
 594 --  Initialization of package, set Adafinal soft link
 595
 596 begin
 597    SSL.Adafinal := Finalize_Global_List'Access;
 598
 599 end System.Finalization_Implementation;