gcc/ada/prj.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  P R J                                   --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  The following package declares the data types for GNAT project.
  27 --  These data types may be used by GNAT Project-aware tools.
  28
  29 --  Children of these package implements various services on these data types.
  30 --  See in particular Prj.Pars and Prj.Env.
  31
  32 with Casing; use Casing;
  33 with Namet;  use Namet;
  34 with Scans;  use Scans;
  35 with Types;  use Types;
  36
  37 with GNAT.Dynamic_HTables; use GNAT.Dynamic_HTables;
  38 with GNAT.Dynamic_Tables;
  39 with GNAT.OS_Lib;          use GNAT.OS_Lib;
  40
  41 package Prj is
  42
  43    All_Other_Names : constant Name_Id := Names_High_Bound;
  44    --  Name used to replace others as an index of an associative array
  45    --  attribute in situations where this is allowed.
  46
  47    Subdirs : String_Ptr := null;
  48    --  The value after the equal sign in switch --subdirs=...
  49    --  Contains the relative subdirectory.
  50
  51    type Library_Support is (None, Static_Only, Full);
  52    --  Support for Library Project File.
  53    --  - None: Library Project Files are not supported at all
  54    --  - Static_Only: Library Project Files are only supported for static
  55    --    libraries.
  56    --  - Full: Library Project Files are supported for static and dynamic
  57    --    (shared) libraries.
  58
  59    type Yes_No_Unknown is (Yes, No, Unknown);
  60    --  Tri-state to decide if -lgnarl is needed when linking
  61
  62    type Project_Qualifier is
  63      (Unspecified,
  64       Standard,
  65       Library,
  66       Configuration,
  67       Dry,
  68       Aggregate,
  69       Aggregate_Library);
  70    --  Qualifiers that can prefix the reserved word "project" in a project
  71    --  file:
  72    --    Standard:             standard project ...
  73    --    Library:              library project is ...
  74    --    Dry:                  abstract project is
  75    --    Aggregate:            aggregate project is
  76    --    Aggregate_Library:    aggregate library project is ...
  77    --    Configuration:        configuration project is ...
  78
  79    All_Packages : constant String_List_Access;
  80    --  Default value of parameter Packages of procedures Parse, in Prj.Pars and
  81    --  Prj.Part, indicating that all packages should be checked.
  82
  83    type Project_Tree_Data;
  84    type Project_Tree_Ref is access all Project_Tree_Data;
  85    --  Reference to a project tree. Several project trees may exist in memory
  86    --  at the same time.
  87
  88    No_Project_Tree : constant Project_Tree_Ref;
  89
  90    procedure Free (Tree : in out Project_Tree_Ref);
  91    --  Free memory associated with the tree
  92
  93    Config_Project_File_Extension : String := ".cgpr";
  94    Project_File_Extension : String := ".gpr";
  95    --  The standard config and user project file name extensions. They are not
  96    --  constants, because Canonical_Case_File_Name is called on these variables
  97    --  in the body of Prj.
  98
  99    function Empty_File   return File_Name_Type;
 100    function Empty_String return Name_Id;
 101    --  Return the id for an empty string ""
 102
 103    type Path_Information is record
 104       Name         : Path_Name_Type := No_Path;
 105       Display_Name : Path_Name_Type := No_Path;
 106    end record;
 107    --  Directory names always end with a directory separator
 108
 109    No_Path_Information : constant Path_Information := (No_Path, No_Path);
 110
 111    type Project_Data;
 112    type Project_Id is access all Project_Data;
 113    No_Project : constant Project_Id := null;
 114    --  Id of a Project File
 115
 116    type String_List_Id is new Nat;
 117    Nil_String : constant String_List_Id := 0;
 118    type String_Element is record
 119       Value         : Name_Id        := No_Name;
 120       Index         : Int            := 0;
 121       Display_Value : Name_Id        := No_Name;
 122       Location      : Source_Ptr     := No_Location;
 123       Flag          : Boolean        := False;
 124       Next          : String_List_Id := Nil_String;
 125    end record;
 126    --  To hold values for string list variables and array elements.
 127    --  Component Flag may be used for various purposes. For source
 128    --  directories, it indicates if the directory contains Ada source(s).
 129
 130    package String_Element_Table is new GNAT.Dynamic_Tables
 131      (Table_Component_Type => String_Element,
 132       Table_Index_Type     => String_List_Id,
 133       Table_Low_Bound      => 1,
 134       Table_Initial        => 200,
 135       Table_Increment      => 100);
 136    --  The table for string elements in string lists
 137
 138    type Variable_Kind is (Undefined, List, Single);
 139    --  Different kinds of variables
 140
 141    subtype Defined_Variable_Kind is Variable_Kind range List .. Single;
 142    --  The defined kinds of variables
 143
 144    Ignored : constant Variable_Kind;
 145    --  Used to indicate that a package declaration must be ignored
 146    --  while processing the project tree (unknown package name).
 147
 148    type Variable_Value (Kind : Variable_Kind := Undefined) is record
 149       Project  : Project_Id := No_Project;
 150       Location : Source_Ptr := No_Location;
 151       Default  : Boolean    := False;
 152       case Kind is
 153          when Undefined =>
 154             null;
 155          when List =>
 156             Values : String_List_Id := Nil_String;
 157          when Single =>
 158             Value : Name_Id := No_Name;
 159             Index : Int     := 0;
 160       end case;
 161    end record;
 162    --  Values for variables and array elements. Default is True if the
 163    --  current value is the default one for the variable
 164
 165    Nil_Variable_Value : constant Variable_Value;
 166    --  Value of a non existing variable or array element
 167
 168    type Variable_Id is new Nat;
 169    No_Variable : constant Variable_Id := 0;
 170    type Variable is record
 171       Next  : Variable_Id := No_Variable;
 172       Name  : Name_Id;
 173       Value : Variable_Value;
 174    end record;
 175    --  To hold the list of variables in a project file and in packages
 176
 177    package Variable_Element_Table is new GNAT.Dynamic_Tables
 178      (Table_Component_Type => Variable,
 179       Table_Index_Type     => Variable_Id,
 180       Table_Low_Bound      => 1,
 181       Table_Initial        => 200,
 182       Table_Increment      => 100);
 183    --  The table of variable in list of variables
 184
 185    type Array_Element_Id is new Nat;
 186    No_Array_Element : constant Array_Element_Id := 0;
 187    type Array_Element is record
 188       Index                : Name_Id;
 189       Src_Index            : Int := 0;
 190       Index_Case_Sensitive : Boolean := True;
 191       Value                : Variable_Value;
 192       Next                 : Array_Element_Id := No_Array_Element;
 193    end record;
 194    --  Each Array_Element represents an array element and is linked (Next)
 195    --  to the next array element, if any, in the array.
 196
 197    package Array_Element_Table is new GNAT.Dynamic_Tables
 198      (Table_Component_Type => Array_Element,
 199       Table_Index_Type     => Array_Element_Id,
 200       Table_Low_Bound      => 1,
 201       Table_Initial        => 200,
 202       Table_Increment      => 100);
 203    --  The table that contains all array elements
 204
 205    type Array_Id is new Nat;
 206    No_Array : constant Array_Id := 0;
 207    type Array_Data is record
 208       Name     : Name_Id          := No_Name;
 209       Location : Source_Ptr       := No_Location;
 210       Value    : Array_Element_Id := No_Array_Element;
 211       Next     : Array_Id         := No_Array;
 212    end record;
 213    --  Each Array_Data value represents an array.
 214    --  Value is the id of the first element.
 215    --  Next is the id of the next array in the project file or package.
 216
 217    package Array_Table is new GNAT.Dynamic_Tables
 218      (Table_Component_Type => Array_Data,
 219       Table_Index_Type     => Array_Id,
 220       Table_Low_Bound      => 1,
 221       Table_Initial        => 200,
 222       Table_Increment      => 100);
 223    --  The table that contains all arrays
 224
 225    type Package_Id is new Nat;
 226    No_Package : constant Package_Id := 0;
 227    type Declarations is record
 228       Variables  : Variable_Id := No_Variable;
 229       Attributes : Variable_Id := No_Variable;
 230       Arrays     : Array_Id    := No_Array;
 231       Packages   : Package_Id  := No_Package;
 232    end record;
 233    --  Contains the declarations (variables, single and array attributes,
 234    --  packages) for a project or a package in a project.
 235
 236    No_Declarations : constant Declarations :=
 237      (Variables  => No_Variable,
 238       Attributes => No_Variable,
 239       Arrays     => No_Array,
 240       Packages   => No_Package);
 241    --  Default value of Declarations: indicates that there is no declarations
 242
 243    type Package_Element is record
 244       Name   : Name_Id      := No_Name;
 245       Decl   : Declarations := No_Declarations;
 246       Parent : Package_Id   := No_Package;
 247       Next   : Package_Id   := No_Package;
 248    end record;
 249    --  A package (includes declarations that may include other packages)
 250
 251    package Package_Table is new GNAT.Dynamic_Tables
 252      (Table_Component_Type => Package_Element,
 253       Table_Index_Type     => Package_Id,
 254       Table_Low_Bound      => 1,
 255       Table_Initial        => 100,
 256       Table_Increment      => 100);
 257    --  The table that contains all packages
 258
 259    type Language_Data;
 260    type Language_Ptr is access all Language_Data;
 261    --  Index of language data
 262
 263    No_Language_Index : constant Language_Ptr := null;
 264    --  Constant indicating that there is no language data
 265
 266    function Get_Language_From_Name
 267      (Project : Project_Id;
 268       Name    : String) return Language_Ptr;
 269    --  Get a language from a project. This might return null if no such
 270    --  language exists in the project
 271
 272    Max_Header_Num : constant := 6150;
 273    type Header_Num is range 0 .. Max_Header_Num;
 274    --  Size for hash table below. The upper bound is an arbitrary value, the
 275    --  value here was chosen after testing to determine a good compromise
 276    --  between speed of access and memory usage.
 277
 278    function Hash (Name : Name_Id)        return Header_Num;
 279    function Hash (Name : File_Name_Type) return Header_Num;
 280    function Hash (Name : Path_Name_Type) return Header_Num;
 281    function Hash (Project : Project_Id) return Header_Num;
 282    --  Used for computing hash values for names put into above hash table
 283
 284    type Language_Kind is (File_Based, Unit_Based);
 285    --  Type for the kind of language. All languages are file based, except Ada
 286    --  which is unit based.
 287
 288    type Dependency_File_Kind is (None, Makefile, ALI_File);
 289    --  Type of dependency to be checked: no dependency file, Makefile fragment
 290    --  or ALI file (for Ada).
 291
 292    Makefile_Dependency_Suffix : constant String := ".d";
 293    ALI_Dependency_Suffix      : constant String := ".ali";
 294
 295    Switches_Dependency_Suffix : constant String := ".cswi";
 296
 297    Binder_Exchange_Suffix     : constant String := ".bexch";
 298    --  Suffix for binder exchange files
 299
 300    Library_Exchange_Suffix     : constant String := ".lexch";
 301    --  Suffix for library exchange files
 302
 303    type Name_List_Index is new Nat;
 304    No_Name_List            : constant Name_List_Index := 0;
 305
 306    type Name_Node is record
 307       Name : Name_Id         := No_Name;
 308       Next : Name_List_Index := No_Name_List;
 309    end record;
 310
 311    package Name_List_Table is new GNAT.Dynamic_Tables
 312      (Table_Component_Type => Name_Node,
 313       Table_Index_Type     => Name_List_Index,
 314       Table_Low_Bound      => 1,
 315       Table_Initial        => 10,
 316       Table_Increment      => 100);
 317    --  The table for lists of names used in package Language_Processing
 318
 319    package Mapping_Files_Htable is new Simple_HTable
 320      (Header_Num => Header_Num,
 321       Element    => Path_Name_Type,
 322       No_Element => No_Path,
 323       Key        => Path_Name_Type,
 324       Hash       => Hash,
 325       Equal      => "=");
 326    --  A hash table to store the mapping files that are not used
 327
 328    type Lang_Naming_Data is record
 329       Dot_Replacement : File_Name_Type := No_File;
 330       --  The string to replace '.' in the source file name (for Ada)
 331
 332       Casing : Casing_Type := All_Lower_Case;
 333       --  The casing of the source file name (for Ada)
 334
 335       Separate_Suffix : File_Name_Type := No_File;
 336       --  String to append to unit name for source file name of an Ada subunit
 337
 338       Spec_Suffix : File_Name_Type := No_File;
 339       --  The string to append to the unit name for the
 340       --  source file name of a spec.
 341
 342       Body_Suffix : File_Name_Type := No_File;
 343       --  The string to append to the unit name for the
 344       --  source file name of a body.
 345    end record;
 346
 347    No_Lang_Naming_Data : constant Lang_Naming_Data :=
 348                            (Dot_Replacement => No_File,
 349                             Casing          => All_Lower_Case,
 350                             Separate_Suffix => No_File,
 351                             Spec_Suffix     => No_File,
 352                             Body_Suffix     => No_File);
 353
 354    function Is_Standard_GNAT_Naming (Naming : Lang_Naming_Data) return Boolean;
 355    --  True if the naming scheme is GNAT's default naming scheme. This
 356    --  is to take into account shortened names like "Ada." (a-), "System." (s-)
 357    --  and so on.
 358
 359    type Source_Data;
 360    type Source_Id is access all Source_Data;
 361
 362    function Is_Compilable (Source : Source_Id) return Boolean;
 363    pragma Inline (Is_Compilable);
 364    --  Return True if we know how to compile Source (i.e. if a compiler is
 365    --  defined). This doesn't indicate whether the source should be compiled.
 366
 367    function Object_To_Global_Archive (Source : Source_Id) return Boolean;
 368    pragma Inline (Object_To_Global_Archive);
 369    --  Return True if the object file should be put in the global archive.
 370    --  This is for Ada, when only the closure of a main needs to be
 371    --  (re)compiled.
 372
 373    function Other_Part (Source : Source_Id) return Source_Id;
 374    pragma Inline (Other_Part);
 375    --  Source ID for the other part, if any: for a spec, indicates its body;
 376    --  for a body, indicates its spec.
 377
 378    No_Source : constant Source_Id := null;
 379
 380    type Path_Syntax_Kind is
 381      (Canonical,
 382       --  Unix style
 383
 384       Host);
 385       --  Host specific syntax, for example on VMS (the default)
 386
 387    type Language_Config is record
 388       Kind : Language_Kind := File_Based;
 389       --  Kind of language. All languages are file based, except Ada which is
 390       --  unit based.
 391
 392       Naming_Data : Lang_Naming_Data;
 393       --  The naming data for the languages (prefixes, etc.)
 394
 395       Include_Compatible_Languages : Name_List_Index := No_Name_List;
 396       --  The list of languages that are "include compatible" with this
 397       --  language. A language B (for example "C") is "include compatible" with
 398       --  a language A (for example "C++") if it is expected that sources of
 399       --  language A may "include" header files from language B.
 400
 401       Compiler_Driver : File_Name_Type := No_File;
 402       --  The name of the executable for the compiler of the language
 403
 404       Compiler_Driver_Path : String_Access := null;
 405       --  The path name of the executable for the compiler of the language
 406
 407       Compiler_Leading_Required_Switches : Name_List_Index := No_Name_List;
 408       --  The list of initial switches that are required as a minimum to invoke
 409       --  the compiler driver.
 410
 411       Compiler_Trailing_Required_Switches : Name_List_Index := No_Name_List;
 412       --  The list of final switches that are required as a minimum to invoke
 413       --  the compiler driver.
 414
 415       Path_Syntax                  : Path_Syntax_Kind := Host;
 416       --  Value may be Canonical (Unix style) or Host (host syntax, for example
 417       --  on VMS for DEC C).
 418
 419       Object_File_Suffix                 : Name_Id := No_Name;
 420       --  Optional alternate object file suffix
 421
 422       Object_File_Switches               : Name_List_Index := No_Name_List;
 423       --  Optional object file switches. When this is defined, the switches
 424       --  are used to specify the object file. The object file name is appended
 425       --  to the last switch in the list. Example: ("-o", "").
 426
 427       Compilation_PIC_Option : Name_List_Index := No_Name_List;
 428       --  The option(s) to compile a source in Position Independent Code for
 429       --  shared libraries. Specified in the configuration. When not specified,
 430       --  there is no need for such switch.
 431
 432       Object_Generated             : Boolean := True;
 433       --  False in no object file is generated
 434
 435       Objects_Linked               : Boolean := True;
 436       --  False if object files are not use to link executables and build
 437       --  libraries.
 438
 439       Runtime_Library_Dir        : Name_Id := No_Name;
 440       --  Path name of the runtime library directory, if any
 441
 442       Runtime_Source_Dir        : Name_Id := No_Name;
 443       --  Path name of the runtime source directory, if any
 444
 445       Mapping_File_Switches  : Name_List_Index := No_Name_List;
 446       --  The option(s) to provide a mapping file to the compiler. Specified in
 447       --  the configuration. When value is No_Name_List, there is no mapping
 448       --  file.
 449
 450       Mapping_Spec_Suffix        : File_Name_Type       := No_File;
 451       --  Placeholder representing the spec suffix in a mapping file
 452
 453       Mapping_Body_Suffix        : File_Name_Type       := No_File;
 454       --  Placeholder representing the body suffix in a mapping file
 455
 456       Config_File_Switches       : Name_List_Index      := No_Name_List;
 457       --  The option(s) to provide a config file to the compiler. Specified in
 458       --  the configuration. When value is No_Name_List, there is no config
 459       --  file.
 460
 461       Dependency_Kind            : Dependency_File_Kind := None;
 462       --  The kind of dependency to be checked: none, Makefile fragment or
 463       --  ALI file (for Ada).
 464
 465       Dependency_Option          : Name_List_Index      := No_Name_List;
 466       --  The option(s) to be used to create the dependency file. When value is
 467       --  No_Name_List, there is not such option(s).
 468
 469       Compute_Dependency         : Name_List_Index      := No_Name_List;
 470       --  Hold the value of attribute Dependency_Driver, if declared for the
 471       --  language.
 472
 473       Include_Option             : Name_List_Index      := No_Name_List;
 474       --  Hold the value of attribute Include_Switches, if declared for the
 475       --  language.
 476
 477       Include_Path : Name_Id := No_Name;
 478       --  Name of environment variable declared by attribute Include_Path for
 479       --  the language.
 480
 481       Include_Path_File : Name_Id := No_Name;
 482       --  Name of environment variable declared by attribute Include_Path_File
 483       --  for the language.
 484
 485       Objects_Path : Name_Id := No_Name;
 486       --  Name of environment variable declared by attribute Objects_Path for
 487       --  the language.
 488
 489       Objects_Path_File : Name_Id := No_Name;
 490       --  Name of environment variable declared by attribute Objects_Path_File
 491       --  for the language.
 492
 493       Config_Body                : Name_Id         := No_Name;
 494       --  The template for a pragma Source_File_Name(_Project) for a specific
 495       --  file name of a body.
 496
 497       Config_Spec           : Name_Id         := No_Name;
 498       --  The template for a pragma Source_File_Name(_Project) for a specific
 499       --  file name of a spec.
 500
 501       Config_Body_Pattern   : Name_Id         := No_Name;
 502       --  The template for a pragma Source_File_Name(_Project) for a naming
 503       --  body pattern.
 504
 505       Config_Spec_Pattern   : Name_Id         := No_Name;
 506       --  The template for a pragma Source_File_Name(_Project) for a naming
 507       --  spec pattern.
 508
 509       Config_File_Unique         : Boolean         := False;
 510       --  Indicate if the config file specified to the compiler needs to be
 511       --  unique. If it is unique, then all config files are concatenated into
 512       --  a temp config file.
 513
 514       Binder_Driver              : File_Name_Type  := No_File;
 515       --  The name of the binder driver for the language, if any
 516
 517       Binder_Driver_Path         : Path_Name_Type  := No_Path;
 518       --  The path name of the binder driver
 519
 520       Binder_Required_Switches   : Name_List_Index      := No_Name_List;
 521       --  Hold the value of attribute Binder'Required_Switches for the language
 522
 523       Binder_Prefix              : Name_Id         := No_Name;
 524       --  Hold the value of attribute Binder'Prefix for the language
 525
 526       Toolchain_Version          : Name_Id         := No_Name;
 527       --  Hold the value of attribute Toolchain_Version for the language
 528
 529       Toolchain_Description      : Name_Id         := No_Name;
 530       --  Hold the value of attribute Toolchain_Description for the language
 531
 532    end record;
 533    --  Record describing the configuration of a language
 534
 535    No_Language_Config : constant Language_Config :=
 536                           (Kind                         => File_Based,
 537                            Naming_Data                  => No_Lang_Naming_Data,
 538                            Include_Compatible_Languages => No_Name_List,
 539                            Compiler_Driver              => No_File,
 540                            Compiler_Driver_Path         => null,
 541                            Compiler_Leading_Required_Switches  => No_Name_List,
 542                            Compiler_Trailing_Required_Switches => No_Name_List,
 543                            Path_Syntax                  => Canonical,
 544                            Object_File_Suffix           => No_Name,
 545                            Object_File_Switches         => No_Name_List,
 546                            Compilation_PIC_Option       => No_Name_List,
 547                            Object_Generated             => True,
 548                            Objects_Linked               => True,
 549                            Runtime_Library_Dir          => No_Name,
 550                            Runtime_Source_Dir           => No_Name,
 551                            Mapping_File_Switches        => No_Name_List,
 552                            Mapping_Spec_Suffix          => No_File,
 553                            Mapping_Body_Suffix          => No_File,
 554                            Config_File_Switches         => No_Name_List,
 555                            Dependency_Kind              => None,
 556                            Dependency_Option            => No_Name_List,
 557                            Compute_Dependency           => No_Name_List,
 558                            Include_Option               => No_Name_List,
 559                            Include_Path                 => No_Name,
 560                            Include_Path_File            => No_Name,
 561                            Objects_Path                 => No_Name,
 562                            Objects_Path_File            => No_Name,
 563                            Config_Body                  => No_Name,
 564                            Config_Spec                  => No_Name,
 565                            Config_Body_Pattern          => No_Name,
 566                            Config_Spec_Pattern          => No_Name,
 567                            Config_File_Unique           => False,
 568                            Binder_Driver                => No_File,
 569                            Binder_Driver_Path           => No_Path,
 570                            Binder_Required_Switches     => No_Name_List,
 571                            Binder_Prefix                => No_Name,
 572                            Toolchain_Version            => No_Name,
 573                            Toolchain_Description        => No_Name);
 574
 575    type Language_Data is record
 576       Name          : Name_Id         := No_Name;
 577       Display_Name  : Name_Id         := No_Name;
 578       Config        : Language_Config := No_Language_Config;
 579       First_Source  : Source_Id       := No_Source;
 580       Mapping_Files : Mapping_Files_Htable.Instance :=
 581                         Mapping_Files_Htable.Nil;
 582       Next          : Language_Ptr  := No_Language_Index;
 583    end record;
 584
 585    No_Language_Data : constant Language_Data :=
 586                         (Name          => No_Name,
 587                          Display_Name  => No_Name,
 588                          Config        => No_Language_Config,
 589                          First_Source  => No_Source,
 590                          Mapping_Files => Mapping_Files_Htable.Nil,
 591                          Next          => No_Language_Index);
 592
 593    type Language_List_Element;
 594    type Language_List is access all Language_List_Element;
 595    type Language_List_Element is record
 596       Language : Language_Ptr := No_Language_Index;
 597       Next     : Language_List;
 598    end record;
 599
 600    type Source_Kind is (Spec, Impl, Sep);
 601    subtype Spec_Or_Body is Source_Kind range Spec .. Impl;
 602
 603    type File_Names_Data is array (Spec_Or_Body) of Source_Id;
 604    type Unit_Data is record
 605       Name       : Name_Id := No_Name;
 606       File_Names : File_Names_Data;
 607    end record;
 608    type Unit_Index is access all Unit_Data;
 609    No_Unit_Index : constant Unit_Index := null;
 610    --  Name and File and Path names of a unit, with a reference to its
 611    --  GNAT Project File(s).
 612
 613    type Source_Data is record
 614       Project                : Project_Id          := No_Project;
 615       --  Project of the source
 616
 617       Language               : Language_Ptr        := No_Language_Index;
 618       --  Index of the language. This is an index into
 619       --  Project_Tree.Languages_Data.
 620
 621       In_Interfaces          : Boolean             := True;
 622       --  False when the source is not included in interfaces, when attribute
 623       --  Interfaces is declared.
 624
 625       Declared_In_Interfaces : Boolean             := False;
 626       --  True when source is declared in attribute Interfaces
 627
 628       Alternate_Languages    : Language_List;
 629       --  List of languages a header file may also be, in addition of language
 630       --  Language_Name.
 631
 632       Kind                   : Source_Kind         := Spec;
 633       --  Kind of the source: spec, body or subunit
 634
 635       Unit                   : Unit_Index          := No_Unit_Index;
 636       --  Name of the unit, if language is unit based. This is only set for
 637       --  those files that are part of the compilation set (for instance a
 638       --  file in an extended project that is overridden will not have this
 639       --  field set).
 640
 641       Index                  : Int                 := 0;
 642       --  Index of the source in a multi unit source file (the same Source_Data
 643       --  is duplicated several times when there are several units in the same
 644       --  file). Index is 0 if there is either no unit or a single one, and
 645       --  starts at 1 when there are multiple units
 646
 647       Locally_Removed        : Boolean             := False;
 648       --  True if the source has been "excluded"
 649
 650       Replaced_By            : Source_Id           := No_Source;
 651
 652       File                   : File_Name_Type      := No_File;
 653       --  Canonical file name of the source
 654
 655       Display_File           : File_Name_Type      := No_File;
 656       --  File name of the source, for display purposes
 657
 658       Path                   : Path_Information    := No_Path_Information;
 659       --  Path name of the source
 660
 661       Source_TS              : Time_Stamp_Type     := Empty_Time_Stamp;
 662       --  Time stamp of the source file
 663
 664       Object_Project         : Project_Id          := No_Project;
 665       --  Project where the object file is. This might be different from
 666       --  Project when using extending project files.
 667
 668       Object                 : File_Name_Type      := No_File;
 669       --  File name of the object file
 670
 671       Current_Object_Path    : Path_Name_Type      := No_Path;
 672       --  Object path of an existing object file
 673
 674       Object_Path            : Path_Name_Type      := No_Path;
 675       --  Object path of the real object file
 676
 677       Object_TS              : Time_Stamp_Type     := Empty_Time_Stamp;
 678       --  Object file time stamp
 679
 680       Dep_Name               : File_Name_Type      := No_File;
 681       --  Dependency file simple name
 682
 683       Current_Dep_Path       : Path_Name_Type      := No_Path;
 684       --  Path name of an existing dependency file
 685
 686       Dep_Path               : Path_Name_Type      := No_Path;
 687       --  Path name of the real dependency file
 688
 689       Dep_TS                 : Time_Stamp_Type     := Empty_Time_Stamp;
 690       --  Dependency file time stamp
 691
 692       Switches               : File_Name_Type      := No_File;
 693       --  File name of the switches file. For all languages, this is a file
 694       --  that ends with the .cswi extension.
 695
 696       Switches_Path          : Path_Name_Type      := No_Path;
 697       --  Path name of the switches file
 698
 699       Switches_TS            : Time_Stamp_Type     := Empty_Time_Stamp;
 700       --  Switches file time stamp
 701
 702       Naming_Exception       : Boolean             := False;
 703       --  True if the source has an exceptional name
 704
 705       Next_In_Lang           : Source_Id           := No_Source;
 706       --  Link to another source of the same language in the same project
 707    end record;
 708
 709    No_Source_Data : constant Source_Data :=
 710                       (Project                => No_Project,
 711                        Language               => No_Language_Index,
 712                        In_Interfaces          => True,
 713                        Declared_In_Interfaces => False,
 714                        Alternate_Languages    => null,
 715                        Kind                   => Spec,
 716                        Unit                   => No_Unit_Index,
 717                        Index                  => 0,
 718                        Locally_Removed        => False,
 719                        Replaced_By            => No_Source,
 720                        File                   => No_File,
 721                        Display_File           => No_File,
 722                        Path                   => No_Path_Information,
 723                        Source_TS              => Empty_Time_Stamp,
 724                        Object_Project         => No_Project,
 725                        Object                 => No_File,
 726                        Current_Object_Path    => No_Path,
 727                        Object_Path            => No_Path,
 728                        Object_TS              => Empty_Time_Stamp,
 729                        Dep_Name               => No_File,
 730                        Current_Dep_Path       => No_Path,
 731                        Dep_Path               => No_Path,
 732                        Dep_TS                 => Empty_Time_Stamp,
 733                        Switches               => No_File,
 734                        Switches_Path          => No_Path,
 735                        Switches_TS            => Empty_Time_Stamp,
 736                        Naming_Exception       => False,
 737                        Next_In_Lang           => No_Source);
 738
 739    package Source_Paths_Htable is new Simple_HTable
 740      (Header_Num => Header_Num,
 741       Element    => Source_Id,
 742       No_Element => No_Source,
 743       Key        => Path_Name_Type,
 744       Hash       => Hash,
 745       Equal      => "=");
 746    --  Mapping of source paths to source ids
 747
 748    package Unit_Sources_Htable is new Simple_HTable
 749      (Header_Num => Header_Num,
 750       Element    => Source_Id,
 751       No_Element => No_Source,
 752       Key        => Name_Id,
 753       Hash       => Hash,
 754       Equal      => "=");
 755
 756    type Verbosity is (Default, Medium, High);
 757    --  Verbosity when parsing GNAT Project Files
 758    --    Default is default (very quiet, if no errors).
 759    --    Medium is more verbose.
 760    --    High is extremely verbose.
 761
 762    Current_Verbosity : Verbosity := Default;
 763    --  The current value of the verbosity the project files are parsed with
 764
 765    type Lib_Kind is (Static, Dynamic, Relocatable);
 766
 767    type Policy is (Autonomous, Compliant, Controlled, Restricted, Direct);
 768    --  Type to specify the symbol policy, when symbol control is supported.
 769    --  See full explanation about this type in package Symbols.
 770    --    Autonomous: Create a symbol file without considering any reference
 771    --    Compliant:  Try to be as compatible as possible with an existing ref
 772    --    Controlled: Fail if symbols are not the same as those in the reference
 773    --    Restricted: Restrict the symbols to those in the symbol file
 774    --    Direct:     The symbol file is used as is
 775
 776    type Symbol_Record is record
 777       Symbol_File   : Path_Name_Type := No_Path;
 778       Reference     : Path_Name_Type := No_Path;
 779       Symbol_Policy : Policy  := Autonomous;
 780    end record;
 781    --  Type to keep the symbol data to be used when building a shared library
 782
 783    No_Symbols : constant Symbol_Record :=
 784      (Symbol_File   => No_Path,
 785       Reference     => No_Path,
 786       Symbol_Policy => Autonomous);
 787    --  The default value of the symbol data
 788
 789    function Image (Casing : Casing_Type) return String;
 790    --  Similar to 'Image (but avoid use of this attribute in compiler)
 791
 792    function Value (Image : String) return Casing_Type;
 793    --  Similar to 'Value (but avoid use of this attribute in compiler)
 794    --  Raises Constraint_Error if not a Casing_Type image.
 795
 796    --  The following record contains data for a naming scheme
 797
 798    function Get_Object_Directory
 799      (Project             : Project_Id;
 800       Including_Libraries : Boolean;
 801       Only_If_Ada         : Boolean := False) return Path_Name_Type;
 802    --  Return the object directory to use for the project. This depends on
 803    --  whether we have a library project or a standard project. This function
 804    --  might return No_Name when no directory applies.
 805    --  If we have a a library project file and Including_Libraries is True then
 806    --  the library dir is returned instead of the object dir.
 807    --  If Only_If_Ada is True, then No_Name will be returned when the project
 808    --  doesn't Ada sources.
 809
 810    procedure Compute_All_Imported_Projects (Project : Project_Id);
 811    --  Compute, the list of the projects imported directly or indirectly by
 812    --  project Project. The result is stored in Project.All_Imported_Projects
 813
 814    function Ultimate_Extending_Project_Of
 815      (Proj : Project_Id) return Project_Id;
 816    --  Returns the ultimate extending project of project Proj. If project Proj
 817    --  is not extended, returns Proj.
 818
 819    type Project_List_Element;
 820    type Project_List is access all Project_List_Element;
 821    type Project_List_Element is record
 822       Project : Project_Id   := No_Project;
 823       Next    : Project_List := null;
 824    end record;
 825    --  A list of projects
 826
 827    procedure Free_List
 828      (List         : in out Project_List;
 829       Free_Project : Boolean);
 830    --  Free the list of projects, if Free_Project, each project is also freed
 831
 832    type Response_File_Format is
 833      (None,
 834       GNU,
 835       Object_List,
 836       Option_List);
 837    --  The format of the different response files
 838
 839    type Project_Configuration is record
 840       Target                        : Name_Id         := No_Name;
 841       --  The target of the configuration, when specified
 842
 843       Run_Path_Option               : Name_List_Index := No_Name_List;
 844       --  The option to use when linking to specify the path where to look for
 845       --  libraries.
 846
 847       Separate_Run_Path_Options     : Boolean := False;
 848       --  True if each directory needs to be specified in a separate run path
 849       --  option.
 850
 851       Executable_Suffix             : Name_Id         := No_Name;
 852       --  The suffix of executables, when specified in the configuration or in
 853       --  package Builder of the main project. When this is not specified, the
 854       --  executable suffix is the default for the platform.
 855
 856       --  Linking
 857
 858       Linker                        : Path_Name_Type  := No_Path;
 859       --  Path name of the linker driver. Specified in the configuration or in
 860       --  the package Builder of the main project.
 861
 862       Map_File_Option               : Name_Id := No_Name;
 863       --  Option to use when invoking the linker to build a map file
 864
 865       Minimum_Linker_Options        : Name_List_Index := No_Name_List;
 866       --  The minimum options for the linker driver. Specified in the
 867       --  configuration.
 868
 869       Linker_Executable_Option      : Name_List_Index := No_Name_List;
 870       --  The option(s) to indicate the name of the executable in the linker
 871       --  command. Specified in the configuration. When not specified, default
 872       --  to -o <executable name>.
 873
 874       Linker_Lib_Dir_Option         : Name_Id         := No_Name;
 875       --  The option to specify where to find a library for linking. Specified
 876       --  in the configuration. When not specified, defaults to "-L".
 877
 878       Linker_Lib_Name_Option        : Name_Id         := No_Name;
 879       --  The option to specify the name of a library for linking. Specified in
 880       --  the configuration. When not specified, defaults to "-l".
 881
 882       Max_Command_Line_Length       : Natural         := 0;
 883       --  When positive and when Resp_File_Format (see below) is not None,
 884       --  if the command line for the invocation of the linker would be greater
 885       --  than this value, a response file is used to invoke the linker.
 886
 887       Resp_File_Format              : Response_File_Format := None;
 888       --  The format of a response file, when linking with a response file is
 889       --  supported.
 890
 891       Resp_File_Options             : Name_List_Index := No_Name_List;
 892       --  The switches, if any, that precede the path name of the response
 893       --  file in the invocation of the linker.
 894
 895       --  Libraries
 896
 897       Library_Builder               : Path_Name_Type  := No_Path;
 898       --  The executable to build library (specified in the configuration)
 899
 900       Lib_Support                   : Library_Support := None;
 901       --  The level of library support. Specified in the configuration. Support
 902       --  is none, static libraries only or both static and shared libraries.
 903
 904       Archive_Builder               : Name_List_Index := No_Name_List;
 905       --  The name of the executable to build archives, with the minimum
 906       --  switches. Specified in the configuration.
 907
 908       Archive_Builder_Append_Option : Name_List_Index := No_Name_List;
 909       --  The options to append object files to an archive
 910
 911       Archive_Indexer               : Name_List_Index := No_Name_List;
 912       --  The name of the executable to index archives, with the minimum
 913       --  switches. Specified in the configuration.
 914
 915       Archive_Suffix                : File_Name_Type  := No_File;
 916       --  The suffix of archives. Specified in the configuration. When not
 917       --  specified, defaults to ".a".
 918
 919       Lib_Partial_Linker            : Name_List_Index := No_Name_List;
 920
 921       --  Shared libraries
 922
 923       Shared_Lib_Driver             : File_Name_Type  := No_File;
 924       --  The driver to link shared libraries. Set with attribute Library_GCC.
 925       --  Default to gcc.
 926
 927       Shared_Lib_Prefix             : File_Name_Type  := No_File;
 928       --  Part of a shared library file name that precedes the name of the
 929       --  library. Specified in the configuration. When not specified, defaults
 930       --  to "lib".
 931
 932       Shared_Lib_Suffix             : File_Name_Type  := No_File;
 933       --  Suffix of shared libraries, after the library name in the shared
 934       --  library name. Specified in the configuration. When not specified,
 935       --  default to ".so".
 936
 937       Shared_Lib_Min_Options        : Name_List_Index := No_Name_List;
 938       --  The minimum options to use when building a shared library
 939
 940       Lib_Version_Options           : Name_List_Index := No_Name_List;
 941       --  The options to use to specify a library version
 942
 943       Symbolic_Link_Supported       : Boolean         := False;
 944       --  True if the platform supports symbolic link files
 945
 946       Lib_Maj_Min_Id_Supported      : Boolean         := False;
 947       --  True if platform supports library major and minor options, such as
 948       --  libname.so -> libname.so.2 -> libname.so.2.4
 949
 950       Auto_Init_Supported           : Boolean         := False;
 951       --  True if automatic initialisation is supported for shared stand-alone
 952       --  libraries.
 953    end record;
 954
 955    Default_Project_Config : constant Project_Configuration :=
 956                               (Target                        => No_Name,
 957                                Run_Path_Option               => No_Name_List,
 958                                Separate_Run_Path_Options     => False,
 959                                Executable_Suffix             => No_Name,
 960                                Linker                        => No_Path,
 961                                Map_File_Option               => No_Name,
 962                                Minimum_Linker_Options        => No_Name_List,
 963                                Linker_Executable_Option      => No_Name_List,
 964                                Linker_Lib_Dir_Option         => No_Name,
 965                                Linker_Lib_Name_Option        => No_Name,
 966                                Library_Builder               => No_Path,
 967                                Max_Command_Line_Length       => 0,
 968                                Resp_File_Format              => None,
 969                                Resp_File_Options             => No_Name_List,
 970                                Lib_Support                   => None,
 971                                Archive_Builder               => No_Name_List,
 972                                Archive_Builder_Append_Option => No_Name_List,
 973                                Archive_Indexer               => No_Name_List,
 974                                Archive_Suffix                => No_File,
 975                                Lib_Partial_Linker            => No_Name_List,
 976                                Shared_Lib_Driver             => No_File,
 977                                Shared_Lib_Prefix             => No_File,
 978                                Shared_Lib_Suffix             => No_File,
 979                                Shared_Lib_Min_Options        => No_Name_List,
 980                                Lib_Version_Options           => No_Name_List,
 981                                Symbolic_Link_Supported       => False,
 982                                Lib_Maj_Min_Id_Supported      => False,
 983                                Auto_Init_Supported           => False);
 984
 985    --  The following record describes a project file representation
 986
 987    --  Note that it is not specified if the path names of directories (source,
 988    --  object, library or exec directories) end with or without a directory
 989    --  separator.
 990
 991    type Project_Data is record
 992
 993       -------------
 994       -- General --
 995       -------------
 996
 997       Name : Name_Id := No_Name;
 998       --  The name of the project
 999
1000       Display_Name : Name_Id := No_Name;
1001       --  The name of the project with the spelling of its declaration
1002
1003       Qualifier : Project_Qualifier := Unspecified;
1004       --  The eventual qualifier for this project
1005
1006       Externally_Built : Boolean := False;
1007       --  True if the project is externally built. In such case, the Project
1008       --  Manager will not modify anything in this project.
1009
1010       Config : Project_Configuration;
1011
1012       Path : Path_Information := No_Path_Information;
1013       --  The path name of the project file. This include base name of the
1014       --  project file.
1015
1016       Virtual : Boolean := False;
1017       --  True for virtual extending projects
1018
1019       Location : Source_Ptr := No_Location;
1020       --  The location in the project file source of the reserved word project
1021
1022       ---------------
1023       -- Languages --
1024       ---------------
1025
1026       Languages : Language_Ptr := No_Language_Index;
1027       --  First index of the language data in the project.
1028       --  This is an index into the project_tree_data.languages_data.
1029       --  Traversing the list gives access to all the languages supported by
1030       --  the project.
1031
1032       --------------
1033       -- Projects --
1034       --------------
1035
1036       Mains : String_List_Id := Nil_String;
1037       --  List of mains specified by attribute Main
1038
1039       Extends : Project_Id := No_Project;
1040       --  The reference of the project file, if any, that this project file
1041       --  extends.
1042
1043       Extended_By : Project_Id := No_Project;
1044       --  The reference of the project file, if any, that extends this project
1045       --  file.
1046
1047       Decl : Declarations := No_Declarations;
1048       --  The declarations (variables, attributes and packages) of this project
1049       --  file.
1050
1051       Imported_Projects : Project_List;
1052       --  The list of all directly imported projects, if any
1053
1054       All_Imported_Projects : Project_List;
1055       --  The list of all projects imported directly or indirectly, if any
1056
1057       -----------------
1058       -- Directories --
1059       -----------------
1060
1061       Directory : Path_Information := No_Path_Information;
1062       --  Path name of the directory where the project file resides
1063
1064       Object_Directory : Path_Information := No_Path_Information;
1065       --  The path name of the object directory of this project file
1066
1067       Exec_Directory : Path_Information := No_Path_Information;
1068       --  The path name of the exec directory of this project file. Default is
1069       --  equal to Object_Directory.
1070
1071       -------------
1072       -- Library --
1073       -------------
1074
1075       Library : Boolean := False;
1076       --  True if this is a library project
1077
1078       Library_Name : Name_Id := No_Name;
1079       --  If a library project, name of the library
1080
1081       Library_Kind : Lib_Kind := Static;
1082       --  If a library project, kind of library
1083
1084       Library_Dir : Path_Information := No_Path_Information;
1085       --  If a library project, path name of the directory where the library
1086       --  resides.
1087
1088       Library_TS : Time_Stamp_Type := Empty_Time_Stamp;
1089       --  The timestamp of a library file in a library project
1090
1091       Library_Src_Dir : Path_Information := No_Path_Information;
1092       --  If a Stand-Alone Library project, path name of the directory where
1093       --  the sources of the interfaces of the library are copied. By default,
1094       --  if attribute Library_Src_Dir is not specified, sources of the
1095       --  interfaces are not copied anywhere.
1096
1097       Library_ALI_Dir : Path_Information := No_Path_Information;
1098       --  In a library project, path name of the directory where the ALI files
1099       --  are copied. If attribute Library_ALI_Dir is not specified, ALI files
1100       --  are copied in the Library_Dir.
1101
1102       Lib_Internal_Name : Name_Id := No_Name;
1103       --  If a library project, internal name store inside the library
1104
1105       Standalone_Library : Boolean := False;
1106       --  Indicate that this is a Standalone Library Project File
1107
1108       Lib_Interface_ALIs : String_List_Id := Nil_String;
1109       --  For Standalone Library Project Files, indicate the list of Interface
1110       --  ALI files.
1111
1112       Lib_Auto_Init : Boolean := False;
1113       --  For non static Stand-Alone Library Project Files, indicate if
1114       --  the library initialisation should be automatic.
1115
1116       Symbol_Data : Symbol_Record := No_Symbols;
1117       --  Symbol file name, reference symbol file name, symbol policy
1118
1119       Need_To_Build_Lib : Boolean := False;
1120       --  Indicates that the library of a Library Project needs to be built or
1121       --  rebuilt.
1122
1123       -------------
1124       -- Sources --
1125       -------------
1126       --  The sources for all languages including Ada are accessible through
1127       --  the Source_Iterator type
1128
1129       Interfaces_Defined      : Boolean := False;
1130       --  True if attribute Interfaces is declared for the project or any
1131       --  project it extends.
1132
1133       Include_Path : String_Access := null;
1134       --  The search source path for the project. Used as the value for an
1135       --  environment variable, specified by attribute Include_Path
1136       --  (<language>). The names of the environment variables are in component
1137       --  Include_Path of the records Language_Config.
1138
1139       Include_Path_File : Path_Name_Type := No_Path;
1140       --  The path name of the of the source search directory file
1141
1142       Include_Data_Set : Boolean := False;
1143       --  Set True when Imported_Directories_Switches or Include_Path are set
1144
1145       Source_Dirs : String_List_Id := Nil_String;
1146       --  The list of all the source directories
1147
1148       Known_Order_Of_Source_Dirs : Boolean := True;
1149       --  False, if there is any /** in the Source_Dirs, because in this case
1150       --  the ordering of the source subdirs depend on the OS. If True,
1151       --  duplicate file names in the same project file are allowed.
1152
1153       Ada_Include_Path : String_Access := null;
1154       --  The cached value of source search path for this project file. Set by
1155       --  the first call to Prj.Env.Ada_Include_Path for the project. Do not
1156       --  use this field directly outside of the project manager, use
1157       --  Prj.Env.Ada_Include_Path instead.
1158
1159       -------------------
1160       -- Miscellaneous --
1161       -------------------
1162
1163       Ada_Objects_Path : String_Access := null;
1164       --  The cached value of ADA_OBJECTS_PATH for this project file. Do not
1165       --  use this field directly outside of the compiler, use
1166       --  Prj.Env.Ada_Objects_Path instead.
1167
1168       Libgnarl_Needed : Yes_No_Unknown := Unknown;
1169       --  Set to True when libgnarl is needed to link
1170
1171       Objects_Path : String_Access := null;
1172       --  The cached value of the object dir path, used during the binding
1173       --  phase of gprbuild.
1174
1175       Objects_Path_File_With_Libs : Path_Name_Type := No_Path;
1176       --  The cached value of the object path temp file (including library
1177       --  dirs) for this project file.
1178
1179       Objects_Path_File_Without_Libs : Path_Name_Type := No_Path;
1180       --  The cached value of the object path temp file (excluding library
1181       --  dirs) for this project file.
1182
1183       Config_File_Name : Path_Name_Type := No_Path;
1184       --  The path name of the configuration pragmas file, if any
1185
1186       Config_File_Temp : Boolean := False;
1187       --  An indication that the configuration pragmas file is a temporary file
1188       --  that must be deleted at the end.
1189
1190       Config_Checked : Boolean := False;
1191       --  A flag to avoid checking repetitively the configuration pragmas file
1192
1193       Depth : Natural := 0;
1194       --  The maximum depth of a project in the project graph. Depth of main
1195       --  project is 0.
1196
1197       Unkept_Comments : Boolean := False;
1198       --  True if there are comments in the project sources that cannot be kept
1199       --  in the project tree.
1200
1201    end record;
1202
1203    function Empty_Project return Project_Data;
1204    --  Return the representation of an empty project
1205
1206    function Is_Extending
1207      (Extending : Project_Id;
1208       Extended  : Project_Id) return Boolean;
1209    --  Return True if Extending is extending the Extended project
1210
1211    function Has_Ada_Sources (Data : Project_Id) return Boolean;
1212    --  Return True if the project has Ada sources
1213
1214    Project_Error : exception;
1215    --  Raised by some subprograms in Prj.Attr
1216
1217    package Units_Htable is new Simple_HTable
1218      (Header_Num => Header_Num,
1219       Element    => Unit_Index,
1220       No_Element => No_Unit_Index,
1221       Key        => Name_Id,
1222       Hash       => Hash,
1223       Equal      => "=");
1224    --  Mapping of unit names to indexes in the Units table
1225
1226    ---------------------
1227    -- Source_Iterator --
1228    ---------------------
1229
1230    type Source_Iterator is private;
1231
1232    function For_Each_Source
1233      (In_Tree  : Project_Tree_Ref;
1234       Project  : Project_Id := No_Project;
1235       Language : Name_Id := No_Name) return Source_Iterator;
1236    --  Returns an iterator for all the sources of a project tree, or a specific
1237    --  project, or a specific language.
1238
1239    function Element (Iter : Source_Iterator) return Source_Id;
1240    --  Return the current source (or No_Source if there are no more sources)
1241
1242    procedure Next (Iter : in out Source_Iterator);
1243    --  Move on to the next source
1244
1245    function Find_Source
1246      (In_Tree          : Project_Tree_Ref;
1247       Project          : Project_Id;
1248       In_Imported_Only : Boolean := False;
1249       In_Extended_Only : Boolean := False;
1250       Base_Name        : File_Name_Type) return Source_Id;
1251    --  Find the first source file with the given name either in the whole tree
1252    --  (if In_Imported_Only is False) or in the projects imported or extended
1253    --  by Project otherwise. In_Extended_Only implies In_Imported_Only, and
1254    --  will only look in Project and the projects it extends
1255
1256    -----------------------
1257    -- Project_Tree_Data --
1258    -----------------------
1259
1260    type Private_Project_Tree_Data is private;
1261    --  Data for a project tree that is used only by the Project Manager
1262
1263    type Project_Tree_Data is
1264       record
1265          Name_Lists        : Name_List_Table.Instance;
1266          String_Elements   : String_Element_Table.Instance;
1267          Variable_Elements : Variable_Element_Table.Instance;
1268          Array_Elements    : Array_Element_Table.Instance;
1269          Arrays            : Array_Table.Instance;
1270          Packages          : Package_Table.Instance;
1271          Projects          : Project_List;
1272
1273          Units_HT          : Units_Htable.Instance;
1274          --  Unit name to Unit_Index (and from there so Source_Id)
1275
1276          Source_Paths_HT   : Source_Paths_Htable.Instance;
1277          --  Full path to Source_Id
1278
1279          Private_Part      : Private_Project_Tree_Data;
1280       end record;
1281    --  Data for a project tree
1282
1283    procedure Expect (The_Token : Token_Type; Token_Image : String);
1284    --  Check that the current token is The_Token. If it is not, then output
1285    --  an error message.
1286
1287    procedure Initialize (Tree : Project_Tree_Ref);
1288    --  This procedure must be called before using any services from the Prj
1289    --  hierarchy. Namet.Initialize must be called before Prj.Initialize.
1290
1291    procedure Reset (Tree : Project_Tree_Ref);
1292    --  This procedure resets all the tables that are used when processing a
1293    --  project file tree. Initialize must be called before the call to Reset.
1294
1295    package Project_Boolean_Htable is new Simple_HTable
1296      (Header_Num => Header_Num,
1297       Element    => Boolean,
1298       No_Element => False,
1299       Key        => Project_Id,
1300       Hash       => Hash,
1301       Equal      => "=");
1302    --  A table that associates a project to a boolean. This is used to detect
1303    --  whether a project was already processed for instance.
1304
1305    generic
1306       type State is limited private;
1307       with procedure Action
1308         (Project    : Project_Id;
1309          With_State : in out State);
1310    procedure For_Every_Project_Imported
1311      (By             : Project_Id;
1312       With_State     : in out State;
1313       Imported_First : Boolean := False);
1314    --  Call Action for each project imported directly or indirectly by project
1315    --  By, as well as extended projects.
1316    --  The order of processing depends on Imported_First:
1317    --  If False, Action is called according to the order of importation: if A
1318    --  imports B, directly or indirectly, Action will be called for A before
1319    --  it is called for B. If two projects import each other directly or
1320    --  indirectly (using at least one "limited with"), it is not specified
1321    --  for which of these two projects Action will be called first.
1322    --  The order is reversed if Imported_First is True.
1323    --  With_State may be used by Action to choose a behavior or to report some
1324    --  global result.
1325
1326    function Extend_Name
1327      (File        : File_Name_Type;
1328       With_Suffix : String) return File_Name_Type;
1329    --  Replace the extension of File with With_Suffix
1330
1331    function Object_Name
1332      (Source_File_Name   : File_Name_Type;
1333       Object_File_Suffix : Name_Id := No_Name) return File_Name_Type;
1334    --  Returns the object file name corresponding to a source file name
1335
1336    function Dependency_Name
1337      (Source_File_Name : File_Name_Type;
1338       Dependency       : Dependency_File_Kind) return File_Name_Type;
1339    --  Returns the dependency file name corresponding to a source file name
1340
1341    function Switches_Name
1342      (Source_File_Name : File_Name_Type) return File_Name_Type;
1343    --  Returns the switches file name corresponding to a source file name
1344
1345    -----------
1346    -- Flags --
1347    -----------
1348
1349    type Processing_Flags is private;
1350    --  Flags used while parsing and processing a project tree to configure the
1351    --  behavior of the parser, and indicate how to report error messages. This
1352    --  structure does not allocate memory and never needs to be freed
1353
1354    type Error_Warning is (Silent, Warning, Error);
1355    --  Severity of some situations, such as: no Ada sources in a project where
1356    --  Ada is one of the language.
1357    --
1358    --  When the situation occurs, the behaviour depends on the setting:
1359    --
1360    --    - Silent:  no action
1361    --    - Warning: issue a warning, does not cause the tool to fail
1362    --    - Error:   issue an error, causes the tool to fail
1363
1364    type Error_Handler is access procedure
1365      (Project    : Project_Id;
1366       Is_Warning : Boolean);
1367    --  This warngs when an error was found when parsing a project. The error
1368    --  itself is handled through Prj.Err (and Prj.Err.Finalize should be called
1369    --  to actually print the error). This ensures that duplicate error messages
1370    --  are always correctly removed, that errors msgs are sorted, and that all
1371    --  tools will report the same error to the user.
1372
1373    function Create_Flags
1374      (Report_Error               : Error_Handler;
1375       When_No_Sources            : Error_Warning;
1376       Require_Sources_Other_Lang : Boolean := True;
1377       Allow_Duplicate_Basenames  : Boolean := True;
1378       Compiler_Driver_Mandatory  : Boolean := False;
1379       Error_On_Unknown_Language  : Boolean := True) return Processing_Flags;
1380    --  Function used to create Processing_Flags structure
1381    --
1382    --  If Allow_Duplicate_Basenames, then files with the same base names are
1383    --  authorized within a project for source-based languages (never for unit
1384    --  based languages).
1385    --
1386    --  If Compiler_Driver_Mandatory is true, then a Compiler.Driver attribute
1387    --  for each language must be defined, or we will not look for its source
1388    --  files.
1389    --
1390    --  When_No_Sources indicates what should be done when no sources of a
1391    --  language are found in a project where this language is declared.
1392    --  If Require_Sources_Other_Lang is true, then all languages must have at
1393    --  least one source file, or an error is reported via When_No_Sources. If
1394    --  it is false, this is only required for Ada (and only if it is a language
1395    --  of the project). When this parameter is set to False, we do not check
1396    --  that a proper naming scheme is defined for languages other than Ada.
1397    --
1398    --  If Report_Error is null, use the standard error reporting mechanism
1399    --  (Errout). Otherwise, report errors using Report_Error.
1400    --
1401    --  If Error_On_Unknown_Language is true, an error is displayed if some of
1402    --  the source files listed in the project do not match any naming scheme
1403
1404    Gprbuild_Flags : constant Processing_Flags;
1405    Gnatmake_Flags : constant Processing_Flags;
1406    --  Flags used by the various tools. They all display the error messages
1407    --  through Prj.Err.
1408
1409    ----------------
1410    -- Temp Files --
1411    ----------------
1412
1413    procedure Record_Temp_File
1414      (Tree : Project_Tree_Ref;
1415       Path : Path_Name_Type);
1416    --  Record the path of a newly created temporary file, so that it can be
1417    --  deleted later.
1418
1419    procedure Delete_All_Temp_Files (Tree : Project_Tree_Ref);
1420    --  Delete all recorded temporary files.
1421    --  Does nothing if Debug.Debug_Flag_N is set
1422
1423    procedure Delete_Temporary_File
1424      (Tree : Project_Tree_Ref;
1425       Path : Path_Name_Type);
1426    --  Delete a temporary file from the disk. The file is also removed from the
1427    --  list of temporary files to delete at the end of the program, in case
1428    --  another program running on the same machine has recreated it.
1429    --  Does nothing if Debug.Debug_Flag_N is set
1430
1431 private
1432
1433    All_Packages : constant String_List_Access := null;
1434
1435    No_Project_Tree : constant Project_Tree_Ref := null;
1436
1437    Ignored : constant Variable_Kind := Single;
1438
1439    Nil_Variable_Value : constant Variable_Value :=
1440                           (Project  => No_Project,
1441                            Kind     => Undefined,
1442                            Location => No_Location,
1443                            Default  => False);
1444
1445    Virtual_Prefix : constant String := "v$";
1446    --  The prefix for virtual extending projects. Because of the '$', which is
1447    --  normally forbidden for project names, there cannot be any name clash.
1448
1449    type Source_Iterator is record
1450       In_Tree : Project_Tree_Ref;
1451
1452       Project      : Project_List;
1453       All_Projects : Boolean;
1454       --  Current project and whether we should move on to the next
1455
1456       Language : Language_Ptr;
1457       --  Current language processed
1458
1459       Language_Name : Name_Id;
1460       --  Only sources of this language will be returned (or all if No_Name)
1461
1462       Current : Source_Id;
1463    end record;
1464
1465    procedure Add_To_Buffer
1466      (S    : String;
1467       To   : in out String_Access;
1468       Last : in out Natural);
1469    --  Append a String to the Buffer
1470
1471    package Temp_Files_Table is new GNAT.Dynamic_Tables
1472      (Table_Component_Type => Path_Name_Type,
1473       Table_Index_Type     => Integer,
1474       Table_Low_Bound      => 1,
1475       Table_Initial        => 10,
1476       Table_Increment      => 10);
1477    --  Table to store the path name of all the created temporary files, so that
1478    --  they can be deleted at the end, or when the program is interrupted.
1479
1480    type Private_Project_Tree_Data is record
1481       Temp_Files   : Temp_Files_Table.Instance;
1482       --  Temporary files created as part of running tools (pragma files,
1483       --  mapping files,...)
1484
1485       Current_Source_Path_File : Path_Name_Type := No_Path;
1486       --  Current value of project source path file env var. Used to avoid
1487       --  setting the env var to the same value. When different from No_Path,
1488       --  this indicates that logical names (VMS) or environment variables were
1489       --  created and should be deassigned to avoid polluting the environment
1490       --  on VMS.
1491       --  gnatmake only
1492
1493       Current_Object_Path_File : Path_Name_Type := No_Path;
1494       --  Current value of project object path file env var. Used to avoid
1495       --  setting the env var to the same value.
1496       --  gnatmake only
1497
1498    end record;
1499    --  Type to represent the part of a project tree which is private to the
1500    --  Project Manager.
1501
1502    type Processing_Flags is record
1503       Require_Sources_Other_Lang : Boolean;
1504       Report_Error               : Error_Handler;
1505       When_No_Sources            : Error_Warning;
1506       Allow_Duplicate_Basenames  : Boolean;
1507       Compiler_Driver_Mandatory  : Boolean;
1508       Error_On_Unknown_Language  : Boolean;
1509    end record;
1510
1511    Gprbuild_Flags : constant Processing_Flags :=
1512      (Report_Error               => null,
1513       When_No_Sources            => Warning,
1514       Require_Sources_Other_Lang => True,
1515       Allow_Duplicate_Basenames  => False,
1516       Compiler_Driver_Mandatory  => True,
1517       Error_On_Unknown_Language  => True);
1518
1519    Gnatmake_Flags : constant Processing_Flags :=
1520      (Report_Error               => null,
1521       When_No_Sources            => Error,
1522       Require_Sources_Other_Lang => False,
1523       Allow_Duplicate_Basenames  => False,
1524       Compiler_Driver_Mandatory  => False,
1525       Error_On_Unknown_Language  => False);
1526
1527 end Prj;