gcc/ada/prj.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  P R J                                   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Ada.Characters.Handling; use Ada.Characters.Handling;
  27 with Ada.Unchecked_Deallocation;
  28
  29 with Debug;
  30 with Osint;    use Osint;
  31 with Output;   use Output;
  32 with Prj.Attr;
  33 with Prj.Err;  use Prj.Err;
  34 with Snames;   use Snames;
  35 with Uintp;    use Uintp;
  36
  37 with GNAT.Directory_Operations; use GNAT.Directory_Operations;
  38
  39 with System.Case_Util; use System.Case_Util;
  40 with System.HTable;
  41
  42 package body Prj is
  43
  44    Object_Suffix : constant String := Get_Target_Object_Suffix.all;
  45    --  File suffix for object files
  46
  47    Initial_Buffer_Size : constant := 100;
  48    --  Initial size for extensible buffer used in Add_To_Buffer
  49
  50    The_Empty_String : Name_Id := No_Name;
  51
  52    subtype Known_Casing is Casing_Type range All_Upper_Case .. Mixed_Case;
  53
  54    type Cst_String_Access is access constant String;
  55
  56    All_Lower_Case_Image : aliased constant String := "lowercase";
  57    All_Upper_Case_Image : aliased constant String := "UPPERCASE";
  58    Mixed_Case_Image     : aliased constant String := "MixedCase";
  59
  60    The_Casing_Images : constant array (Known_Casing) of Cst_String_Access :=
  61                          (All_Lower_Case => All_Lower_Case_Image'Access,
  62                           All_Upper_Case => All_Upper_Case_Image'Access,
  63                           Mixed_Case     => Mixed_Case_Image'Access);
  64
  65    Project_Empty : constant Project_Data :=
  66                      (Qualifier                      => Unspecified,
  67                       Externally_Built               => False,
  68                       Config                         => Default_Project_Config,
  69                       Name                           => No_Name,
  70                       Display_Name                   => No_Name,
  71                       Path                           => No_Path_Information,
  72                       Virtual                        => False,
  73                       Location                       => No_Location,
  74                       Mains                          => Nil_String,
  75                       Directory                      => No_Path_Information,
  76                       Library                        => False,
  77                       Library_Dir                    => No_Path_Information,
  78                       Library_Src_Dir                => No_Path_Information,
  79                       Library_ALI_Dir                => No_Path_Information,
  80                       Library_Name                   => No_Name,
  81                       Library_Kind                   => Static,
  82                       Lib_Internal_Name              => No_Name,
  83                       Standalone_Library             => False,
  84                       Lib_Interface_ALIs             => Nil_String,
  85                       Lib_Auto_Init                  => False,
  86                       Libgnarl_Needed                => Unknown,
  87                       Symbol_Data                    => No_Symbols,
  88                       Interfaces_Defined             => False,
  89                       Source_Dirs                    => Nil_String,
  90                       Source_Dir_Ranks               => No_Number_List,
  91                       Object_Directory               => No_Path_Information,
  92                       Library_TS                     => Empty_Time_Stamp,
  93                       Exec_Directory                 => No_Path_Information,
  94                       Extends                        => No_Project,
  95                       Extended_By                    => No_Project,
  96                       Languages                      => No_Language_Index,
  97                       Decl                           => No_Declarations,
  98                       Imported_Projects              => null,
  99                       Include_Path_File              => No_Path,
 100                       All_Imported_Projects          => null,
 101                       Ada_Include_Path               => null,
 102                       Ada_Objects_Path               => null,
 103                       Objects_Path                   => null,
 104                       Objects_Path_File_With_Libs    => No_Path,
 105                       Objects_Path_File_Without_Libs => No_Path,
 106                       Config_File_Name               => No_Path,
 107                       Config_File_Temp               => False,
 108                       Config_Checked                 => False,
 109                       Need_To_Build_Lib              => False,
 110                       Depth                          => 0,
 111                       Unkept_Comments                => False);
 112
 113    procedure Free (Project : in out Project_Id);
 114    --  Free memory allocated for Project
 115
 116    procedure Free_List (Languages : in out Language_Ptr);
 117    procedure Free_List (Source : in out Source_Id);
 118    procedure Free_List (Languages : in out Language_List);
 119    --  Free memory allocated for the list of languages or sources
 120
 121    procedure Free_Units (Table : in out Units_Htable.Instance);
 122    --  Free memory allocated for unit information in the project
 123
 124    procedure Language_Changed (Iter : in out Source_Iterator);
 125    procedure Project_Changed (Iter : in out Source_Iterator);
 126    --  Called when a new project or language was selected for this iterator
 127
 128    function Contains_ALI_Files (Dir : Path_Name_Type) return Boolean;
 129    --  Return True if there is at least one ALI file in the directory Dir
 130
 131    -------------------
 132    -- Add_To_Buffer --
 133    -------------------
 134
 135    procedure Add_To_Buffer
 136      (S    : String;
 137       To   : in out String_Access;
 138       Last : in out Natural)
 139    is
 140    begin
 141       if To = null then
 142          To := new String (1 .. Initial_Buffer_Size);
 143          Last := 0;
 144       end if;
 145
 146       --  If Buffer is too small, double its size
 147
 148       while Last + S'Length > To'Last loop
 149          declare
 150             New_Buffer : constant  String_Access :=
 151                            new String (1 .. 2 * Last);
 152
 153          begin
 154             New_Buffer (1 .. Last) := To (1 .. Last);
 155             Free (To);
 156             To := New_Buffer;
 157          end;
 158       end loop;
 159
 160       To (Last + 1 .. Last + S'Length) := S;
 161       Last := Last + S'Length;
 162    end Add_To_Buffer;
 163
 164    ---------------------------
 165    -- Delete_Temporary_File --
 166    ---------------------------
 167
 168    procedure Delete_Temporary_File
 169      (Tree : Project_Tree_Ref;
 170       Path : Path_Name_Type)
 171    is
 172       Dont_Care : Boolean;
 173       pragma Warnings (Off, Dont_Care);
 174
 175    begin
 176       if not Debug.Debug_Flag_N then
 177          if Current_Verbosity = High then
 178             Write_Line ("Removing temp file: " & Get_Name_String (Path));
 179          end if;
 180
 181          Delete_File (Get_Name_String (Path), Dont_Care);
 182
 183          for Index in
 184            1 .. Temp_Files_Table.Last (Tree.Private_Part.Temp_Files)
 185          loop
 186             if Tree.Private_Part.Temp_Files.Table (Index) = Path then
 187                Tree.Private_Part.Temp_Files.Table (Index) := No_Path;
 188             end if;
 189          end loop;
 190       end if;
 191    end Delete_Temporary_File;
 192
 193    ---------------------------
 194    -- Delete_All_Temp_Files --
 195    ---------------------------
 196
 197    procedure Delete_All_Temp_Files (Tree : Project_Tree_Ref) is
 198       Dont_Care : Boolean;
 199       pragma Warnings (Off, Dont_Care);
 200
 201       Path : Path_Name_Type;
 202
 203    begin
 204       if not Debug.Debug_Flag_N then
 205          for Index in
 206            1 .. Temp_Files_Table.Last (Tree.Private_Part.Temp_Files)
 207          loop
 208             Path := Tree.Private_Part.Temp_Files.Table (Index);
 209
 210             if Path /= No_Path then
 211                if Current_Verbosity = High then
 212                   Write_Line ("Removing temp file: "
 213                               & Get_Name_String (Path));
 214                end if;
 215
 216                Delete_File (Get_Name_String (Path), Dont_Care);
 217             end if;
 218          end loop;
 219
 220          Temp_Files_Table.Free (Tree.Private_Part.Temp_Files);
 221          Temp_Files_Table.Init (Tree.Private_Part.Temp_Files);
 222       end if;
 223
 224       --  If any of the environment variables ADA_PRJ_INCLUDE_FILE or
 225       --  ADA_PRJ_OBJECTS_FILE has been set, then reset their value to
 226       --  the empty string. On VMS, this has the effect of deassigning
 227       --  the logical names.
 228
 229       if Tree.Private_Part.Current_Source_Path_File /= No_Path then
 230          Setenv (Project_Include_Path_File, "");
 231       end if;
 232
 233       if Tree.Private_Part.Current_Object_Path_File /= No_Path then
 234          Setenv (Project_Objects_Path_File, "");
 235       end if;
 236    end Delete_All_Temp_Files;
 237
 238    ---------------------
 239    -- Dependency_Name --
 240    ---------------------
 241
 242    function Dependency_Name
 243      (Source_File_Name : File_Name_Type;
 244       Dependency       : Dependency_File_Kind) return File_Name_Type
 245    is
 246    begin
 247       case Dependency is
 248          when None =>
 249             return No_File;
 250
 251          when Makefile =>
 252             return
 253               File_Name_Type
 254                 (Extend_Name
 255                    (Source_File_Name, Makefile_Dependency_Suffix));
 256
 257          when ALI_File =>
 258             return
 259               File_Name_Type
 260                 (Extend_Name
 261                    (Source_File_Name, ALI_Dependency_Suffix));
 262       end case;
 263    end Dependency_Name;
 264
 265    ----------------
 266    -- Empty_File --
 267    ----------------
 268
 269    function Empty_File return File_Name_Type is
 270    begin
 271       return File_Name_Type (The_Empty_String);
 272    end Empty_File;
 273
 274    -------------------
 275    -- Empty_Project --
 276    -------------------
 277
 278    function Empty_Project return Project_Data is
 279    begin
 280       Prj.Initialize (Tree => No_Project_Tree);
 281       return Project_Empty;
 282    end Empty_Project;
 283
 284    ------------------
 285    -- Empty_String --
 286    ------------------
 287
 288    function Empty_String return Name_Id is
 289    begin
 290       return The_Empty_String;
 291    end Empty_String;
 292
 293    ------------
 294    -- Expect --
 295    ------------
 296
 297    procedure Expect (The_Token : Token_Type; Token_Image : String) is
 298    begin
 299       if Token /= The_Token then
 300          --  ??? Should pass user flags here instead
 301          Error_Msg (Gnatmake_Flags, Token_Image & " expected", Token_Ptr);
 302       end if;
 303    end Expect;
 304
 305    -----------------
 306    -- Extend_Name --
 307    -----------------
 308
 309    function Extend_Name
 310      (File        : File_Name_Type;
 311       With_Suffix : String) return File_Name_Type
 312    is
 313       Last : Positive;
 314
 315    begin
 316       Get_Name_String (File);
 317       Last := Name_Len + 1;
 318
 319       while Name_Len /= 0 and then Name_Buffer (Name_Len) /= '.' loop
 320          Name_Len := Name_Len - 1;
 321       end loop;
 322
 323       if Name_Len <= 1 then
 324          Name_Len := Last;
 325       end if;
 326
 327       for J in With_Suffix'Range loop
 328          Name_Buffer (Name_Len) := With_Suffix (J);
 329          Name_Len := Name_Len + 1;
 330       end loop;
 331
 332       Name_Len := Name_Len - 1;
 333       return Name_Find;
 334
 335    end Extend_Name;
 336
 337    ---------------------
 338    -- Project_Changed --
 339    ---------------------
 340
 341    procedure Project_Changed (Iter : in out Source_Iterator) is
 342    begin
 343       Iter.Language := Iter.Project.Project.Languages;
 344       Language_Changed (Iter);
 345    end Project_Changed;
 346
 347    ----------------------
 348    -- Language_Changed --
 349    ----------------------
 350
 351    procedure Language_Changed (Iter : in out Source_Iterator) is
 352    begin
 353       Iter.Current  := No_Source;
 354
 355       if Iter.Language_Name /= No_Name then
 356          while Iter.Language /= null
 357            and then Iter.Language.Name /= Iter.Language_Name
 358          loop
 359             Iter.Language := Iter.Language.Next;
 360          end loop;
 361       end if;
 362
 363       --  If there is no matching language in this project, move to next
 364
 365       if Iter.Language = No_Language_Index then
 366          if Iter.All_Projects then
 367             Iter.Project := Iter.Project.Next;
 368
 369             if Iter.Project /= null then
 370                Project_Changed (Iter);
 371             end if;
 372
 373          else
 374             Iter.Project := null;
 375          end if;
 376
 377       else
 378          Iter.Current := Iter.Language.First_Source;
 379
 380          if Iter.Current = No_Source then
 381             Iter.Language := Iter.Language.Next;
 382             Language_Changed (Iter);
 383          end if;
 384       end if;
 385    end Language_Changed;
 386
 387    ---------------------
 388    -- For_Each_Source --
 389    ---------------------
 390
 391    function For_Each_Source
 392      (In_Tree  : Project_Tree_Ref;
 393       Project  : Project_Id := No_Project;
 394       Language : Name_Id := No_Name) return Source_Iterator
 395    is
 396       Iter : Source_Iterator;
 397    begin
 398       Iter := Source_Iterator'
 399         (In_Tree       => In_Tree,
 400          Project       => In_Tree.Projects,
 401          All_Projects  => Project = No_Project,
 402          Language_Name => Language,
 403          Language      => No_Language_Index,
 404          Current       => No_Source);
 405
 406       if Project /= null then
 407          while Iter.Project /= null
 408            and then Iter.Project.Project /= Project
 409          loop
 410             Iter.Project := Iter.Project.Next;
 411          end loop;
 412       end if;
 413
 414       Project_Changed (Iter);
 415
 416       return Iter;
 417    end For_Each_Source;
 418
 419    -------------
 420    -- Element --
 421    -------------
 422
 423    function Element (Iter : Source_Iterator) return Source_Id is
 424    begin
 425       return Iter.Current;
 426    end Element;
 427
 428    ----------
 429    -- Next --
 430    ----------
 431
 432    procedure Next (Iter : in out Source_Iterator) is
 433    begin
 434       Iter.Current := Iter.Current.Next_In_Lang;
 435       if Iter.Current = No_Source then
 436          Iter.Language := Iter.Language.Next;
 437          Language_Changed (Iter);
 438       end if;
 439    end Next;
 440
 441    --------------------------------
 442    -- For_Every_Project_Imported --
 443    --------------------------------
 444
 445    procedure For_Every_Project_Imported
 446      (By             : Project_Id;
 447       With_State     : in out State;
 448       Imported_First : Boolean := False)
 449    is
 450       use Project_Boolean_Htable;
 451       Seen : Project_Boolean_Htable.Instance := Project_Boolean_Htable.Nil;
 452
 453       procedure Recursive_Check (Project : Project_Id);
 454       --  Check if a project has already been seen. If not seen, mark it as
 455       --  Seen, Call Action, and check all its imported projects.
 456
 457       ---------------------
 458       -- Recursive_Check --
 459       ---------------------
 460
 461       procedure Recursive_Check (Project : Project_Id) is
 462          List : Project_List;
 463
 464       begin
 465          if not Get (Seen, Project) then
 466             Set (Seen, Project, True);
 467
 468             if not Imported_First then
 469                Action (Project, With_State);
 470             end if;
 471
 472             --  Visited all extended projects
 473
 474             if Project.Extends /= No_Project then
 475                Recursive_Check (Project.Extends);
 476             end if;
 477
 478             --  Visited all imported projects
 479
 480             List := Project.Imported_Projects;
 481             while List /= null loop
 482                Recursive_Check (List.Project);
 483                List := List.Next;
 484             end loop;
 485
 486             if Imported_First then
 487                Action (Project, With_State);
 488             end if;
 489          end if;
 490       end Recursive_Check;
 491
 492    --  Start of processing for For_Every_Project_Imported
 493
 494    begin
 495       Recursive_Check (Project => By);
 496       Reset (Seen);
 497    end For_Every_Project_Imported;
 498
 499    -----------------
 500    -- Find_Source --
 501    -----------------
 502
 503    function Find_Source
 504      (In_Tree          : Project_Tree_Ref;
 505       Project          : Project_Id;
 506       In_Imported_Only : Boolean := False;
 507       In_Extended_Only : Boolean := False;
 508       Base_Name        : File_Name_Type) return Source_Id
 509    is
 510       Result : Source_Id  := No_Source;
 511
 512       procedure Look_For_Sources (Proj : Project_Id; Src : in out Source_Id);
 513       --  Look for Base_Name in the sources of Proj
 514
 515       ----------------------
 516       -- Look_For_Sources --
 517       ----------------------
 518
 519       procedure Look_For_Sources (Proj : Project_Id; Src : in out Source_Id) is
 520          Iterator : Source_Iterator;
 521
 522       begin
 523          Iterator := For_Each_Source (In_Tree => In_Tree, Project => Proj);
 524          while Element (Iterator) /= No_Source loop
 525             if Element (Iterator).File = Base_Name then
 526                Src := Element (Iterator);
 527                return;
 528             end if;
 529
 530             Next (Iterator);
 531          end loop;
 532       end Look_For_Sources;
 533
 534       procedure For_Imported_Projects is new For_Every_Project_Imported
 535         (State => Source_Id, Action => Look_For_Sources);
 536
 537       Proj : Project_Id;
 538
 539    --  Start of processing for Find_Source
 540
 541    begin
 542       if In_Extended_Only then
 543          Proj := Project;
 544          while Proj /= No_Project loop
 545             Look_For_Sources (Proj, Result);
 546             exit when Result /= No_Source;
 547
 548             Proj := Proj.Extends;
 549          end loop;
 550
 551       elsif In_Imported_Only then
 552          Look_For_Sources (Project, Result);
 553
 554          if Result = No_Source then
 555             For_Imported_Projects
 556               (By         => Project,
 557                With_State => Result);
 558          end if;
 559       else
 560          Look_For_Sources (No_Project, Result);
 561       end if;
 562
 563       return Result;
 564    end Find_Source;
 565
 566    ----------
 567    -- Hash --
 568    ----------
 569
 570    function Hash is new System.HTable.Hash (Header_Num => Header_Num);
 571    --  Used in implementation of other functions Hash below
 572
 573    function Hash (Name : File_Name_Type) return Header_Num is
 574    begin
 575       return Hash (Get_Name_String (Name));
 576    end Hash;
 577
 578    function Hash (Name : Name_Id) return Header_Num is
 579    begin
 580       return Hash (Get_Name_String (Name));
 581    end Hash;
 582
 583    function Hash (Name : Path_Name_Type) return Header_Num is
 584    begin
 585       return Hash (Get_Name_String (Name));
 586    end Hash;
 587
 588    function Hash (Project : Project_Id) return Header_Num is
 589    begin
 590       if Project = No_Project then
 591          return Header_Num'First;
 592       else
 593          return Hash (Get_Name_String (Project.Name));
 594       end if;
 595    end Hash;
 596
 597    -----------
 598    -- Image --
 599    -----------
 600
 601    function Image (The_Casing : Casing_Type) return String is
 602    begin
 603       return The_Casing_Images (The_Casing).all;
 604    end Image;
 605
 606    -----------------------------
 607    -- Is_Standard_GNAT_Naming --
 608    -----------------------------
 609
 610    function Is_Standard_GNAT_Naming
 611      (Naming : Lang_Naming_Data) return Boolean
 612    is
 613    begin
 614       return Get_Name_String (Naming.Spec_Suffix) = ".ads"
 615         and then Get_Name_String (Naming.Body_Suffix) = ".adb"
 616         and then Get_Name_String (Naming.Dot_Replacement) = "-";
 617    end Is_Standard_GNAT_Naming;
 618
 619    ----------------
 620    -- Initialize --
 621    ----------------
 622
 623    procedure Initialize (Tree : Project_Tree_Ref) is
 624    begin
 625       if The_Empty_String = No_Name then
 626          Uintp.Initialize;
 627          Name_Len := 0;
 628          The_Empty_String := Name_Find;
 629
 630          Prj.Attr.Initialize;
 631          Set_Name_Table_Byte (Name_Project,  Token_Type'Pos (Tok_Project));
 632          Set_Name_Table_Byte (Name_Extends,  Token_Type'Pos (Tok_Extends));
 633          Set_Name_Table_Byte (Name_External, Token_Type'Pos (Tok_External));
 634       end if;
 635
 636       if Tree /= No_Project_Tree then
 637          Reset (Tree);
 638       end if;
 639    end Initialize;
 640
 641    ------------------
 642    -- Is_Extending --
 643    ------------------
 644
 645    function Is_Extending
 646      (Extending : Project_Id;
 647       Extended  : Project_Id) return Boolean
 648    is
 649       Proj : Project_Id;
 650
 651    begin
 652       Proj := Extending;
 653       while Proj /= No_Project loop
 654          if Proj = Extended then
 655             return True;
 656          end if;
 657
 658          Proj := Proj.Extends;
 659       end loop;
 660
 661       return False;
 662    end Is_Extending;
 663
 664    -----------------
 665    -- Object_Name --
 666    -----------------
 667
 668    function Object_Name
 669      (Source_File_Name   : File_Name_Type;
 670       Object_File_Suffix : Name_Id := No_Name) return File_Name_Type
 671    is
 672    begin
 673       if Object_File_Suffix = No_Name then
 674          return Extend_Name
 675            (Source_File_Name, Object_Suffix);
 676       else
 677          return Extend_Name
 678            (Source_File_Name, Get_Name_String (Object_File_Suffix));
 679       end if;
 680    end Object_Name;
 681
 682    ----------------------
 683    -- Record_Temp_File --
 684    ----------------------
 685
 686    procedure Record_Temp_File
 687      (Tree : Project_Tree_Ref;
 688       Path : Path_Name_Type)
 689    is
 690    begin
 691       Temp_Files_Table.Append (Tree.Private_Part.Temp_Files, Path);
 692    end Record_Temp_File;
 693
 694    ----------
 695    -- Free --
 696    ----------
 697
 698    procedure Free (Project : in out Project_Id) is
 699       procedure Unchecked_Free is new Ada.Unchecked_Deallocation
 700         (Project_Data, Project_Id);
 701
 702    begin
 703       if Project /= null then
 704          Free (Project.Ada_Include_Path);
 705          Free (Project.Objects_Path);
 706          Free (Project.Ada_Objects_Path);
 707          Free_List (Project.Imported_Projects, Free_Project => False);
 708          Free_List (Project.All_Imported_Projects, Free_Project => False);
 709          Free_List (Project.Languages);
 710
 711          Unchecked_Free (Project);
 712       end if;
 713    end Free;
 714
 715    ---------------
 716    -- Free_List --
 717    ---------------
 718
 719    procedure Free_List (Languages : in out Language_List) is
 720       procedure Unchecked_Free is new Ada.Unchecked_Deallocation
 721         (Language_List_Element, Language_List);
 722       Tmp : Language_List;
 723    begin
 724       while Languages /= null loop
 725          Tmp := Languages.Next;
 726          Unchecked_Free (Languages);
 727          Languages := Tmp;
 728       end loop;
 729    end Free_List;
 730
 731    ---------------
 732    -- Free_List --
 733    ---------------
 734
 735    procedure Free_List (Source : in out Source_Id) is
 736       procedure Unchecked_Free is new
 737         Ada.Unchecked_Deallocation (Source_Data, Source_Id);
 738
 739       Tmp : Source_Id;
 740
 741    begin
 742       while Source /= No_Source loop
 743          Tmp := Source.Next_In_Lang;
 744          Free_List (Source.Alternate_Languages);
 745
 746          if Source.Unit /= null
 747            and then Source.Kind in Spec_Or_Body
 748          then
 749             Source.Unit.File_Names (Source.Kind) := null;
 750          end if;
 751
 752          Unchecked_Free (Source);
 753          Source := Tmp;
 754       end loop;
 755    end Free_List;
 756
 757    ---------------
 758    -- Free_List --
 759    ---------------
 760
 761    procedure Free_List
 762      (List         : in out Project_List;
 763       Free_Project : Boolean)
 764    is
 765       procedure Unchecked_Free is new
 766         Ada.Unchecked_Deallocation (Project_List_Element, Project_List);
 767
 768       Tmp : Project_List;
 769
 770    begin
 771       while List /= null loop
 772          Tmp := List.Next;
 773
 774          if Free_Project then
 775             Free (List.Project);
 776          end if;
 777
 778          Unchecked_Free (List);
 779          List := Tmp;
 780       end loop;
 781    end Free_List;
 782
 783    ---------------
 784    -- Free_List --
 785    ---------------
 786
 787    procedure Free_List (Languages : in out Language_Ptr) is
 788       procedure Unchecked_Free is new
 789         Ada.Unchecked_Deallocation (Language_Data, Language_Ptr);
 790
 791       Tmp : Language_Ptr;
 792
 793    begin
 794       while Languages /= null loop
 795          Tmp := Languages.Next;
 796          Free_List (Languages.First_Source);
 797          Unchecked_Free (Languages);
 798          Languages := Tmp;
 799       end loop;
 800    end Free_List;
 801
 802    ----------------
 803    -- Free_Units --
 804    ----------------
 805
 806    procedure Free_Units (Table : in out Units_Htable.Instance) is
 807       procedure Unchecked_Free is new
 808         Ada.Unchecked_Deallocation (Unit_Data, Unit_Index);
 809
 810       Unit : Unit_Index;
 811
 812    begin
 813       Unit := Units_Htable.Get_First (Table);
 814       while Unit /= No_Unit_Index loop
 815          if Unit.File_Names (Spec) /= null then
 816             Unit.File_Names (Spec).Unit := No_Unit_Index;
 817          end if;
 818
 819          if Unit.File_Names (Impl) /= null then
 820             Unit.File_Names (Impl).Unit := No_Unit_Index;
 821          end if;
 822
 823          Unchecked_Free (Unit);
 824          Unit := Units_Htable.Get_Next (Table);
 825       end loop;
 826
 827       Units_Htable.Reset (Table);
 828    end Free_Units;
 829
 830    ----------
 831    -- Free --
 832    ----------
 833
 834    procedure Free (Tree : in out Project_Tree_Ref) is
 835       procedure Unchecked_Free is new
 836         Ada.Unchecked_Deallocation (Project_Tree_Data, Project_Tree_Ref);
 837
 838    begin
 839       if Tree /= null then
 840          Name_List_Table.Free (Tree.Name_Lists);
 841          Number_List_Table.Free (Tree.Number_Lists);
 842          String_Element_Table.Free (Tree.String_Elements);
 843          Variable_Element_Table.Free (Tree.Variable_Elements);
 844          Array_Element_Table.Free (Tree.Array_Elements);
 845          Array_Table.Free (Tree.Arrays);
 846          Package_Table.Free (Tree.Packages);
 847          Source_Paths_Htable.Reset (Tree.Source_Paths_HT);
 848
 849          Free_List (Tree.Projects, Free_Project => True);
 850          Free_Units (Tree.Units_HT);
 851
 852          --  Private part
 853
 854          Temp_Files_Table.Free  (Tree.Private_Part.Temp_Files);
 855
 856          Unchecked_Free (Tree);
 857       end if;
 858    end Free;
 859
 860    -----------
 861    -- Reset --
 862    -----------
 863
 864    procedure Reset (Tree : Project_Tree_Ref) is
 865    begin
 866       --  Visible tables
 867
 868       Name_List_Table.Init          (Tree.Name_Lists);
 869       Number_List_Table.Init        (Tree.Number_Lists);
 870       String_Element_Table.Init     (Tree.String_Elements);
 871       Variable_Element_Table.Init   (Tree.Variable_Elements);
 872       Array_Element_Table.Init      (Tree.Array_Elements);
 873       Array_Table.Init              (Tree.Arrays);
 874       Package_Table.Init            (Tree.Packages);
 875       Source_Paths_Htable.Reset     (Tree.Source_Paths_HT);
 876
 877       Free_List (Tree.Projects, Free_Project => True);
 878       Free_Units (Tree.Units_HT);
 879
 880       --  Private part table
 881
 882       Temp_Files_Table.Init       (Tree.Private_Part.Temp_Files);
 883
 884       Tree.Private_Part.Current_Source_Path_File := No_Path;
 885       Tree.Private_Part.Current_Object_Path_File := No_Path;
 886    end Reset;
 887
 888    -------------------
 889    -- Switches_Name --
 890    -------------------
 891
 892    function Switches_Name
 893      (Source_File_Name : File_Name_Type) return File_Name_Type
 894    is
 895    begin
 896       return Extend_Name (Source_File_Name, Switches_Dependency_Suffix);
 897    end Switches_Name;
 898
 899    -----------
 900    -- Value --
 901    -----------
 902
 903    function Value (Image : String) return Casing_Type is
 904    begin
 905       for Casing in The_Casing_Images'Range loop
 906          if To_Lower (Image) = To_Lower (The_Casing_Images (Casing).all) then
 907             return Casing;
 908          end if;
 909       end loop;
 910
 911       raise Constraint_Error;
 912    end Value;
 913
 914    ---------------------
 915    -- Has_Ada_Sources --
 916    ---------------------
 917
 918    function Has_Ada_Sources (Data : Project_Id) return Boolean is
 919       Lang : Language_Ptr;
 920
 921    begin
 922       Lang := Data.Languages;
 923       while Lang /= No_Language_Index loop
 924          if Lang.Name = Name_Ada then
 925             return Lang.First_Source /= No_Source;
 926          end if;
 927          Lang := Lang.Next;
 928       end loop;
 929
 930       return False;
 931    end Has_Ada_Sources;
 932
 933    ------------------------
 934    -- Contains_ALI_Files --
 935    ------------------------
 936
 937    function Contains_ALI_Files (Dir : Path_Name_Type) return Boolean is
 938       Dir_Name : constant String := Get_Name_String (Dir);
 939       Direct   : Dir_Type;
 940       Name     : String (1 .. 1_000);
 941       Last     : Natural;
 942       Result   : Boolean := False;
 943
 944    begin
 945       Open (Direct, Dir_Name);
 946
 947       --  For each file in the directory, check if it is an ALI file
 948
 949       loop
 950          Read (Direct, Name, Last);
 951          exit when Last = 0;
 952          Canonical_Case_File_Name (Name (1 .. Last));
 953          Result := Last >= 5 and then Name (Last - 3 .. Last) = ".ali";
 954          exit when Result;
 955       end loop;
 956
 957       Close (Direct);
 958       return Result;
 959
 960    exception
 961       --  If there is any problem, close the directory if open and return True.
 962       --  The library directory will be added to the path.
 963
 964       when others =>
 965          if Is_Open (Direct) then
 966             Close (Direct);
 967          end if;
 968
 969          return True;
 970    end Contains_ALI_Files;
 971
 972    --------------------------
 973    -- Get_Object_Directory --
 974    --------------------------
 975
 976    function Get_Object_Directory
 977      (Project             : Project_Id;
 978       Including_Libraries : Boolean;
 979       Only_If_Ada         : Boolean := False) return Path_Name_Type
 980    is
 981    begin
 982       if (Project.Library and then Including_Libraries)
 983         or else
 984           (Project.Object_Directory /= No_Path_Information
 985             and then (not Including_Libraries or else not Project.Library))
 986       then
 987          --  For a library project, add the library ALI directory if there is
 988          --  no object directory or if the library ALI directory contains ALI
 989          --  files; otherwise add the object directory.
 990
 991          if Project.Library then
 992             if Project.Object_Directory = No_Path_Information
 993               or else Contains_ALI_Files (Project.Library_ALI_Dir.Name)
 994             then
 995                return Project.Library_ALI_Dir.Name;
 996             else
 997                return Project.Object_Directory.Name;
 998             end if;
 999
1000             --  For a non-library project, add object directory if it is not a
1001             --  virtual project, and if there are Ada sources in the project or
1002             --  one of the projects it extends. If there are no Ada sources,
1003             --  adding the object directory could disrupt the order of the
1004             --  object dirs in the path.
1005
1006          elsif not Project.Virtual then
1007             declare
1008                Add_Object_Dir : Boolean;
1009                Prj            : Project_Id;
1010
1011             begin
1012                Add_Object_Dir := not Only_If_Ada;
1013                Prj := Project;
1014                while not Add_Object_Dir and then Prj /= No_Project loop
1015                   if Has_Ada_Sources (Prj) then
1016                      Add_Object_Dir := True;
1017                   else
1018                      Prj := Prj.Extends;
1019                   end if;
1020                end loop;
1021
1022                if Add_Object_Dir then
1023                   return Project.Object_Directory.Name;
1024                end if;
1025             end;
1026          end if;
1027       end if;
1028
1029       return No_Path;
1030    end Get_Object_Directory;
1031
1032    -----------------------------------
1033    -- Ultimate_Extending_Project_Of --
1034    -----------------------------------
1035
1036    function Ultimate_Extending_Project_Of
1037      (Proj : Project_Id) return Project_Id
1038    is
1039       Prj : Project_Id;
1040
1041    begin
1042       Prj := Proj;
1043       while Prj /= null and then Prj.Extended_By /= No_Project loop
1044          Prj := Prj.Extended_By;
1045       end loop;
1046
1047       return Prj;
1048    end Ultimate_Extending_Project_Of;
1049
1050    -----------------------------------
1051    -- Compute_All_Imported_Projects --
1052    -----------------------------------
1053
1054    procedure Compute_All_Imported_Projects (Tree : Project_Tree_Ref) is
1055       Project : Project_Id;
1056
1057       procedure Recursive_Add (Prj : Project_Id; Dummy : in out Boolean);
1058       --  Recursively add the projects imported by project Project, but not
1059       --  those that are extended.
1060
1061       -------------------
1062       -- Recursive_Add --
1063       -------------------
1064
1065       procedure Recursive_Add (Prj : Project_Id; Dummy : in out Boolean) is
1066          pragma Unreferenced (Dummy);
1067          List    : Project_List;
1068          Prj2    : Project_Id;
1069
1070       begin
1071          --  A project is not importing itself
1072
1073          Prj2 := Ultimate_Extending_Project_Of (Prj);
1074
1075          if Project /= Prj2 then
1076
1077             --  Check that the project is not already in the list. We know the
1078             --  one passed to Recursive_Add have never been visited before, but
1079             --  the one passed it are the extended projects.
1080
1081             List := Project.All_Imported_Projects;
1082             while List /= null loop
1083                if List.Project = Prj2 then
1084                   return;
1085                end if;
1086
1087                List := List.Next;
1088             end loop;
1089
1090             --  Add it to the list
1091
1092             Project.All_Imported_Projects :=
1093               new Project_List_Element'
1094                 (Project => Prj2,
1095                  Next    => Project.All_Imported_Projects);
1096          end if;
1097       end Recursive_Add;
1098
1099       procedure For_All_Projects is
1100         new For_Every_Project_Imported (Boolean, Recursive_Add);
1101
1102       Dummy : Boolean := False;
1103       List  : Project_List;
1104
1105    begin
1106       List := Tree.Projects;
1107       while List /= null loop
1108          Project := List.Project;
1109          Free_List (Project.All_Imported_Projects, Free_Project => False);
1110          For_All_Projects (Project, Dummy);
1111          List := List.Next;
1112       end loop;
1113    end Compute_All_Imported_Projects;
1114
1115    -------------------
1116    -- Is_Compilable --
1117    -------------------
1118
1119    function Is_Compilable (Source : Source_Id) return Boolean is
1120    begin
1121       return Source.Language.Config.Compiler_Driver /= No_File
1122         and then Length_Of_Name (Source.Language.Config.Compiler_Driver) /= 0
1123         and then not Source.Locally_Removed;
1124    end Is_Compilable;
1125
1126    ------------------------------
1127    -- Object_To_Global_Archive --
1128    ------------------------------
1129
1130    function Object_To_Global_Archive (Source : Source_Id) return Boolean is
1131    begin
1132       return Source.Language.Config.Kind = File_Based
1133         and then Source.Kind = Impl
1134         and then Source.Language.Config.Objects_Linked
1135         and then Is_Compilable (Source)
1136         and then Source.Language.Config.Object_Generated;
1137    end Object_To_Global_Archive;
1138
1139    ----------------------------
1140    -- Get_Language_From_Name --
1141    ----------------------------
1142
1143    function Get_Language_From_Name
1144      (Project : Project_Id;
1145       Name    : String) return Language_Ptr
1146    is
1147       N      : Name_Id;
1148       Result : Language_Ptr;
1149
1150    begin
1151       Name_Len := Name'Length;
1152       Name_Buffer (1 .. Name_Len) := Name;
1153       To_Lower (Name_Buffer (1 .. Name_Len));
1154       N := Name_Find;
1155
1156       Result := Project.Languages;
1157       while Result /= No_Language_Index loop
1158          if Result.Name = N then
1159             return Result;
1160          end if;
1161
1162          Result := Result.Next;
1163       end loop;
1164
1165       return No_Language_Index;
1166    end Get_Language_From_Name;
1167
1168    ----------------
1169    -- Other_Part --
1170    ----------------
1171
1172    function Other_Part (Source : Source_Id) return Source_Id is
1173    begin
1174       if Source.Unit /= No_Unit_Index then
1175          case Source.Kind is
1176             when Impl =>
1177                return Source.Unit.File_Names (Spec);
1178             when Spec =>
1179                return Source.Unit.File_Names (Impl);
1180             when Sep =>
1181                return No_Source;
1182          end case;
1183       else
1184          return No_Source;
1185       end if;
1186    end Other_Part;
1187
1188    ------------------
1189    -- Create_Flags --
1190    ------------------
1191
1192    function Create_Flags
1193      (Report_Error               : Error_Handler;
1194       When_No_Sources            : Error_Warning;
1195       Require_Sources_Other_Lang : Boolean := True;
1196       Allow_Duplicate_Basenames  : Boolean := True;
1197       Compiler_Driver_Mandatory  : Boolean := False;
1198       Error_On_Unknown_Language  : Boolean := True;
1199       Require_Obj_Dirs           : Error_Warning := Error)
1200       return Processing_Flags
1201    is
1202    begin
1203       return Processing_Flags'
1204         (Report_Error               => Report_Error,
1205          When_No_Sources            => When_No_Sources,
1206          Require_Sources_Other_Lang => Require_Sources_Other_Lang,
1207          Allow_Duplicate_Basenames  => Allow_Duplicate_Basenames,
1208          Error_On_Unknown_Language  => Error_On_Unknown_Language,
1209          Compiler_Driver_Mandatory  => Compiler_Driver_Mandatory,
1210          Require_Obj_Dirs           => Require_Obj_Dirs);
1211    end Create_Flags;
1212
1213    ------------
1214    -- Length --
1215    ------------
1216
1217    function Length
1218      (Table : Name_List_Table.Instance;
1219       List  : Name_List_Index) return Natural
1220    is
1221       Count : Natural := 0;
1222       Tmp   : Name_List_Index;
1223
1224    begin
1225       Tmp := List;
1226       while Tmp /= No_Name_List loop
1227          Count := Count + 1;
1228          Tmp := Table.Table (Tmp).Next;
1229       end loop;
1230
1231       return Count;
1232    end Length;
1233
1234 begin
1235    --  Make sure that the standard config and user project file extensions are
1236    --  compatible with canonical case file naming.
1237
1238    Canonical_Case_File_Name (Config_Project_File_Extension);
1239    Canonical_Case_File_Name (Project_File_Extension);
1240 end Prj;