gcc/ada/prj-pars.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             P R J . P A R S                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Ada.Exceptions; use Ada.Exceptions;
  27 with GNAT.Directory_Operations; use GNAT.Directory_Operations;
  28
  29 with Output;   use Output;
  30 with Prj.Conf; use Prj.Conf;
  31 with Prj.Err;  use Prj.Err;
  32 with Prj.Part;
  33 with Prj.Tree; use Prj.Tree;
  34 with Sinput.P;
  35
  36 package body Prj.Pars is
  37
  38    -----------
  39    -- Parse --
  40    -----------
  41
  42    procedure Parse
  43      (In_Tree           : Project_Tree_Ref;
  44       Project           : out Project_Id;
  45       Project_File_Name : String;
  46       Packages_To_Check : String_List_Access := All_Packages;
  47       When_No_Sources   : Error_Warning := Error;
  48       Report_Error      : Put_Line_Access := null;
  49       Reset_Tree        : Boolean := True)
  50    is
  51       Project_Node      : Project_Node_Id := Empty_Node;
  52       The_Project       : Project_Id      := No_Project;
  53       Success           : Boolean         := True;
  54       Current_Dir       : constant String := Get_Current_Dir;
  55       Project_Node_Tree : Prj.Tree.Project_Node_Tree_Ref;
  56       Automatically_Generated : Boolean;
  57       Config_File_Path        : String_Access;
  58    begin
  59       Project_Node_Tree := new Project_Node_Tree_Data;
  60       Prj.Tree.Initialize (Project_Node_Tree);
  61
  62       --  Parse the main project file into a tree
  63
  64       Sinput.P.Reset_First;
  65       Prj.Part.Parse
  66         (In_Tree                => Project_Node_Tree,
  67          Project                => Project_Node,
  68          Project_File_Name      => Project_File_Name,
  69          Always_Errout_Finalize => False,
  70          Packages_To_Check      => Packages_To_Check,
  71          Current_Directory      => Current_Dir,
  72          Is_Config_File         => False);
  73
  74       --  If there were no error, process the tree
  75
  76       if Project_Node /= Empty_Node then
  77          begin
  78             --  No config file should be read from the disk for gnatmake.
  79             --  However, we will simulate one that only contains the
  80             --  default GNAT naming scheme.
  81
  82             Process_Project_And_Apply_Config
  83               (Main_Project               => The_Project,
  84                User_Project_Node          => Project_Node,
  85                Config_File_Name           => "",
  86                Autoconf_Specified         => False,
  87                Project_Tree               => In_Tree,
  88                Project_Node_Tree          => Project_Node_Tree,
  89                Packages_To_Check          => null,
  90                Allow_Automatic_Generation => False,
  91                Automatically_Generated    => Automatically_Generated,
  92                Config_File_Path           => Config_File_Path,
  93                Report_Error               => Report_Error,
  94                Normalized_Hostname        => "",
  95                Compiler_Driver_Mandatory  => False,
  96                Allow_Duplicate_Basenames  => False,
  97                On_Load_Config             =>
  98                  Add_Default_GNAT_Naming_Scheme'Access,
  99                Reset_Tree                 => Reset_Tree,
 100                When_No_Sources            => When_No_Sources);
 101
 102             Success := The_Project /= No_Project;
 103
 104          exception
 105             when Invalid_Config =>
 106                Success := False;
 107          end;
 108
 109          Prj.Err.Finalize;
 110
 111          if not Success then
 112             The_Project := No_Project;
 113          end if;
 114       end if;
 115
 116       Project := The_Project;
 117
 118       --  ??? Should free the project_node_tree, no longer useful
 119
 120    exception
 121       when X : others =>
 122
 123          --  Internal error
 124
 125          Write_Line (Exception_Information (X));
 126          Write_Str  ("Exception ");
 127          Write_Str  (Exception_Name (X));
 128          Write_Line (" raised, while processing project file");
 129          Project := No_Project;
 130    end Parse;
 131
 132    -------------------
 133    -- Set_Verbosity --
 134    -------------------
 135
 136    procedure Set_Verbosity (To : Verbosity) is
 137    begin
 138       Current_Verbosity := To;
 139    end Set_Verbosity;
 140
 141 end Prj.Pars;