gcc/ada/mlib-tgt-specific-vms-ia64.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                    M L I B . T G T . S P E C I F I C                     --
   6 --                         (Integrity VMS Version)                          --
   7 --                                                                          --
   8 --                                 B o d y                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2008, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  20 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  This is the Integrity VMS version of the body
  28
  29 with Ada.Characters.Handling; use Ada.Characters.Handling;
  30
  31 with MLib.Fil;
  32 with MLib.Utl;
  33
  34 with MLib.Tgt.VMS_Common;
  35 pragma Warnings (Off, MLib.Tgt.VMS_Common);
  36 --  MLib.Tgt.VMS_Common is with'ed only for elaboration purposes
  37
  38 with Opt;      use Opt;
  39 with Output;   use Output;
  40
  41 with GNAT.Directory_Operations; use GNAT.Directory_Operations;
  42
  43 with System;           use System;
  44 with System.Case_Util; use System.Case_Util;
  45 with System.CRTL;      use System.CRTL;
  46
  47 package body MLib.Tgt.Specific is
  48
  49    --  Non default subprogram, see comment in mlib-tgt.ads
  50
  51    procedure Build_Dynamic_Library
  52      (Ofiles       : Argument_List;
  53       Options      : Argument_List;
  54       Interfaces   : Argument_List;
  55       Lib_Filename : String;
  56       Lib_Dir      : String;
  57       Symbol_Data  : Symbol_Record;
  58       Driver_Name  : Name_Id := No_Name;
  59       Lib_Version  : String  := "";
  60       Auto_Init    : Boolean := False);
  61
  62    --  Local variables
  63
  64    Empty_Argument_List : aliased Argument_List := (1 .. 0 => null);
  65    Additional_Objects  : Argument_List_Access := Empty_Argument_List'Access;
  66    --  Used to add the generated auto-init object files for auto-initializing
  67    --  stand-alone libraries.
  68
  69    Macro_Name : constant String := "mcr gnu:[bin]gcc -c -x assembler";
  70    --  The name of the command to invoke the macro-assembler
  71
  72    VMS_Options : Argument_List := (1 .. 1 => null);
  73
  74    Gnatsym_Name : constant String := "gnatsym";
  75
  76    Gnatsym_Path : String_Access;
  77
  78    Arguments     : Argument_List_Access := null;
  79    Last_Argument : Natural := 0;
  80
  81    Success : Boolean := False;
  82
  83    Shared_Libgcc : aliased String := "-shared-libgcc";
  84
  85    Shared_Libgcc_Switch : constant Argument_List :=
  86                             (1 => Shared_Libgcc'Access);
  87
  88    ---------------------------
  89    -- Build_Dynamic_Library --
  90    ---------------------------
  91
  92    procedure Build_Dynamic_Library
  93      (Ofiles       : Argument_List;
  94       Options      : Argument_List;
  95       Interfaces   : Argument_List;
  96       Lib_Filename : String;
  97       Lib_Dir      : String;
  98       Symbol_Data  : Symbol_Record;
  99       Driver_Name  : Name_Id := No_Name;
 100       Lib_Version  : String  := "";
 101       Auto_Init    : Boolean := False)
 102    is
 103
 104       Lib_File : constant String :=
 105                    Lib_Dir & Directory_Separator & "lib" &
 106                    Fil.Ext_To (Lib_Filename, DLL_Ext);
 107
 108       Opts      : Argument_List := Options;
 109       Last_Opt  : Natural       := Opts'Last;
 110       Opts2     : Argument_List (Options'Range);
 111       Last_Opt2 : Natural       := Opts2'First - 1;
 112
 113       Inter : constant Argument_List := Interfaces;
 114
 115       function Is_Interface (Obj_File : String) return Boolean;
 116       --  For a Stand-Alone Library, returns True if Obj_File is the object
 117       --  file name of an interface of the SAL. For other libraries, always
 118       --  return True.
 119
 120       function Option_File_Name return String;
 121       --  Returns Symbol_File, if not empty. Otherwise, returns "symvec.opt"
 122
 123       function Version_String return String;
 124       --  Returns Lib_Version if not empty and if Symbol_Data.Symbol_Policy is
 125       --  not Autonomous, otherwise returns "". When Symbol_Data.Symbol_Policy
 126       --  is Autonomous, fails gnatmake if Lib_Version is not the image of a
 127       --  positive number.
 128
 129       ------------------
 130       -- Is_Interface --
 131       ------------------
 132
 133       function Is_Interface (Obj_File : String) return Boolean is
 134          ALI : constant String :=
 135                  Fil.Ext_To
 136                   (Filename => To_Lower (Base_Name (Obj_File)),
 137                    New_Ext  => "ali");
 138
 139       begin
 140          if Inter'Length = 0 then
 141             return True;
 142
 143          elsif ALI'Length > 2 and then
 144                ALI (ALI'First .. ALI'First + 2) = "b__"
 145          then
 146             return True;
 147
 148          else
 149             for J in Inter'Range loop
 150                if Inter (J).all = ALI then
 151                   return True;
 152                end if;
 153             end loop;
 154
 155             return False;
 156          end if;
 157       end Is_Interface;
 158
 159       ----------------------
 160       -- Option_File_Name --
 161       ----------------------
 162
 163       function Option_File_Name return String is
 164       begin
 165          if Symbol_Data.Symbol_File = No_Path then
 166             return "symvec.opt";
 167          else
 168             Get_Name_String (Symbol_Data.Symbol_File);
 169             To_Lower (Name_Buffer (1 .. Name_Len));
 170             return Name_Buffer (1 .. Name_Len);
 171          end if;
 172       end Option_File_Name;
 173
 174       --------------------
 175       -- Version_String --
 176       --------------------
 177
 178       function Version_String return String is
 179          Version : Integer := 0;
 180       begin
 181          if Lib_Version = ""
 182            or else Symbol_Data.Symbol_Policy /= Autonomous
 183          then
 184             return "";
 185
 186          else
 187             begin
 188                Version := Integer'Value (Lib_Version);
 189
 190                if Version <= 0 then
 191                   raise Constraint_Error;
 192                end if;
 193
 194                return Lib_Version;
 195
 196             exception
 197                when Constraint_Error =>
 198                   Fail ("illegal version """
 199                         & Lib_Version
 200                         & """ (on VMS version must be a positive number)");
 201                   return "";
 202             end;
 203          end if;
 204       end Version_String;
 205
 206       ---------------------
 207       -- Local Variables --
 208       ---------------------
 209
 210       Opt_File_Name  : constant String := Option_File_Name;
 211       Version        : constant String := Version_String;
 212       For_Linker_Opt : String_Access;
 213
 214    --  Start of processing for Build_Dynamic_Library
 215
 216    begin
 217       --  Option file must end with ".opt"
 218
 219       if Opt_File_Name'Length > 4
 220         and then
 221           Opt_File_Name (Opt_File_Name'Last - 3 .. Opt_File_Name'Last) = ".opt"
 222       then
 223          For_Linker_Opt := new String'("--for-linker=" & Opt_File_Name);
 224       else
 225          Fail ("Options File """ & Opt_File_Name & """ must end with .opt");
 226       end if;
 227
 228       VMS_Options (VMS_Options'First) := For_Linker_Opt;
 229
 230       for J in Inter'Range loop
 231          To_Lower (Inter (J).all);
 232       end loop;
 233
 234       --  "gnatsym" is necessary for building the option file
 235
 236       if Gnatsym_Path = null then
 237          Gnatsym_Path := Locate_Exec_On_Path (Gnatsym_Name);
 238
 239          if Gnatsym_Path = null then
 240             Fail (Gnatsym_Name & " not found in path");
 241          end if;
 242       end if;
 243
 244       --  For auto-initialization of a stand-alone library, we create
 245       --  a macro-assembly file and we invoke the macro-assembler.
 246
 247       if Auto_Init then
 248          declare
 249             Macro_File_Name : constant String := Lib_Filename & "__init.asm";
 250             Macro_File      : File_Descriptor;
 251             Init_Proc       : String := Lib_Filename & "INIT";
 252             Popen_Result    : System.Address;
 253             Pclose_Result   : Integer;
 254             Len             : Natural;
 255             OK              : Boolean := True;
 256
 257             command : constant String :=
 258                         Macro_Name & " " & Macro_File_Name & ASCII.NUL;
 259             --  The command to invoke the assembler on the generated auto-init
 260             --  assembly file.
 261             --  Why odd lower case name ???
 262
 263             mode : constant String := "r" & ASCII.NUL;
 264             --  The mode for the invocation of Popen
 265             --  Why odd lower case name ???
 266
 267          begin
 268             To_Upper (Init_Proc);
 269
 270             if Verbose_Mode then
 271                Write_Str ("Creating auto-init assembly file """);
 272                Write_Str (Macro_File_Name);
 273                Write_Line ("""");
 274             end if;
 275
 276             --  Create and write the auto-init assembly file
 277
 278             declare
 279                use ASCII;
 280
 281                --  Output a dummy transfer address for debugging
 282                --  followed by the LIB$INITIALIZE section.
 283
 284                Lines : constant String :=
 285                  HT & ".pred.safe_across_calls p1-p5,p16-p63" & LF &
 286                  HT & ".text" & LF &
 287                  HT & ".align 16" & LF &
 288                  HT & ".global __main#" & LF &
 289                  HT & ".proc __main#" & LF &
 290                       "__main:" & LF &
 291                  HT & ".prologue" & LF &
 292                  HT & ".body" & LF &
 293                  HT & ".mib" & LF &
 294                  HT & "nop 0" & LF &
 295                  HT & "nop 0" & LF &
 296                  HT & "br.ret.sptk.many b0" & LF &
 297                  HT & ".endp __main#" & LF & LF &
 298                  HT & ".type " & Init_Proc & "#, @function" & LF &
 299                  HT & ".global " & Init_Proc & "#" & LF &
 300                  HT & ".global LIB$INITIALIZE#" & LF &
 301                  HT & ".section LIB$INITIALIZE#,""a"",@progbits" & LF &
 302                  HT & "data4 @fptr(" & Init_Proc & "#)" & LF;
 303
 304             begin
 305                Macro_File := Create_File (Macro_File_Name, Text);
 306                OK := Macro_File /= Invalid_FD;
 307
 308                if OK then
 309                   Len := Write
 310                     (Macro_File, Lines (Lines'First)'Address,
 311                      Lines'Length);
 312                   OK := Len = Lines'Length;
 313                end if;
 314
 315                if OK then
 316                   Close (Macro_File, OK);
 317                end if;
 318
 319                if not OK then
 320                   Fail ("creation of auto-init assembly file """
 321                         & Macro_File_Name
 322                         & """ failed");
 323                end if;
 324             end;
 325
 326             --  Invoke the macro-assembler
 327
 328             if Verbose_Mode then
 329                Write_Str ("Assembling auto-init assembly file """);
 330                Write_Str (Macro_File_Name);
 331                Write_Line ("""");
 332             end if;
 333
 334             Popen_Result := popen (command (command'First)'Address,
 335                                    mode (mode'First)'Address);
 336
 337             if Popen_Result = Null_Address then
 338                Fail ("assembly of auto-init assembly file """
 339                      & Macro_File_Name
 340                      & """ failed");
 341             end if;
 342
 343             --  Wait for the end of execution of the macro-assembler
 344
 345             Pclose_Result := pclose (Popen_Result);
 346
 347             if Pclose_Result < 0 then
 348                Fail ("assembly of auto init assembly file """
 349                      & Macro_File_Name
 350                      & """ failed");
 351             end if;
 352
 353             --  Add the generated object file to the list of objects to be
 354             --  included in the library.
 355
 356             Additional_Objects :=
 357               new Argument_List'
 358                 (1 => new String'(Lib_Filename & "__init.obj"));
 359          end;
 360       end if;
 361
 362       --  Allocate the argument list and put the symbol file name, the
 363       --  reference (if any) and the policy (if not autonomous).
 364
 365       Arguments := new Argument_List (1 .. Ofiles'Length + 8);
 366
 367       Last_Argument := 0;
 368
 369       --  Verbosity
 370
 371       if Verbose_Mode then
 372          Last_Argument := Last_Argument + 1;
 373          Arguments (Last_Argument) := new String'("-v");
 374       end if;
 375
 376       --  Version number (major ID)
 377
 378       if Lib_Version /= "" then
 379          Last_Argument := Last_Argument + 1;
 380          Arguments (Last_Argument) := new String'("-V");
 381          Last_Argument := Last_Argument + 1;
 382          Arguments (Last_Argument) := new String'(Version);
 383       end if;
 384
 385       --  Symbol file
 386
 387       Last_Argument := Last_Argument + 1;
 388       Arguments (Last_Argument) := new String'("-s");
 389       Last_Argument := Last_Argument + 1;
 390       Arguments (Last_Argument) := new String'(Opt_File_Name);
 391
 392       --  Reference Symbol File
 393
 394       if Symbol_Data.Reference /= No_Path then
 395          Last_Argument := Last_Argument + 1;
 396          Arguments (Last_Argument) := new String'("-r");
 397          Last_Argument := Last_Argument + 1;
 398          Arguments (Last_Argument) :=
 399            new String'(Get_Name_String (Symbol_Data.Reference));
 400       end if;
 401
 402       --  Policy
 403
 404       case Symbol_Data.Symbol_Policy is
 405          when Autonomous =>
 406             null;
 407
 408          when Compliant =>
 409             Last_Argument := Last_Argument + 1;
 410             Arguments (Last_Argument) := new String'("-c");
 411
 412          when Controlled =>
 413             Last_Argument := Last_Argument + 1;
 414             Arguments (Last_Argument) := new String'("-C");
 415
 416          when Restricted =>
 417             Last_Argument := Last_Argument + 1;
 418             Arguments (Last_Argument) := new String'("-R");
 419
 420          when Direct =>
 421             Last_Argument := Last_Argument + 1;
 422             Arguments (Last_Argument) := new String'("-D");
 423       end case;
 424
 425       --  Add each relevant object file
 426
 427       for Index in Ofiles'Range loop
 428          if Is_Interface (Ofiles (Index).all) then
 429             Last_Argument := Last_Argument + 1;
 430             Arguments (Last_Argument) := new String'(Ofiles (Index).all);
 431          end if;
 432       end loop;
 433
 434       --  Spawn gnatsym
 435
 436       Spawn (Program_Name => Gnatsym_Path.all,
 437              Args         => Arguments (1 .. Last_Argument),
 438              Success      => Success);
 439
 440       if not Success then
 441          Fail ("unable to create symbol file for library """
 442                & Lib_Filename
 443                & """");
 444       end if;
 445
 446       Free (Arguments);
 447
 448       --  Move all the -l switches from Opts to Opts2
 449
 450       declare
 451          Index : Natural := Opts'First;
 452          Opt   : String_Access;
 453
 454       begin
 455          while Index <= Last_Opt loop
 456             Opt := Opts (Index);
 457
 458             if Opt'Length > 2 and then
 459               Opt (Opt'First .. Opt'First + 1) = "-l"
 460             then
 461                if Index < Last_Opt then
 462                   Opts (Index .. Last_Opt - 1) :=
 463                     Opts (Index + 1 .. Last_Opt);
 464                end if;
 465
 466                Last_Opt := Last_Opt - 1;
 467
 468                Last_Opt2 := Last_Opt2 + 1;
 469                Opts2 (Last_Opt2) := Opt;
 470
 471             else
 472                Index := Index + 1;
 473             end if;
 474          end loop;
 475       end;
 476
 477       --  Invoke gcc to build the library
 478
 479       Utl.Gcc
 480         (Output_File => Lib_File,
 481          Objects     => Ofiles & Additional_Objects.all,
 482          Options     => VMS_Options,
 483          Options_2   => Shared_Libgcc_Switch &
 484                         Opts (Opts'First .. Last_Opt) &
 485                         Opts2 (Opts2'First .. Last_Opt2),
 486          Driver_Name => Driver_Name);
 487
 488       --  The auto-init object file need to be deleted, so that it will not
 489       --  be included in the library as a regular object file, otherwise
 490       --  it will be included twice when the library will be built next
 491       --  time, which may lead to errors.
 492
 493       if Auto_Init then
 494          declare
 495             Auto_Init_Object_File_Name : constant String :=
 496                                            Lib_Filename & "__init.obj";
 497
 498             Disregard : Boolean;
 499             pragma Warnings (Off, Disregard);
 500
 501          begin
 502             if Verbose_Mode then
 503                Write_Str ("deleting auto-init object file """);
 504                Write_Str (Auto_Init_Object_File_Name);
 505                Write_Line ("""");
 506             end if;
 507
 508             Delete_File (Auto_Init_Object_File_Name, Success => Disregard);
 509          end;
 510       end if;
 511    end Build_Dynamic_Library;
 512
 513 --  Package initialization
 514
 515 begin
 516    Build_Dynamic_Library_Ptr    := Build_Dynamic_Library'Access;
 517 end MLib.Tgt.Specific;