gcc/ada/mlib-tgt-linux.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             M L I B . T G T                              --
   6 --                           (GNU/Linux Version)                            --
   7 --                                                                          --
   8 --                                 B o d y                                  --
   9 --                                                                          --
  10 --              Copyright (C) 2001-2004, Free Software Foundation, Inc.     --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- GNAT was originally developed  by the GNAT team at  New York University. --
  24 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  25 --                                                                          --
  26 ------------------------------------------------------------------------------
  27
  28 --  This package provides a set of target dependent routines to build
  29 --  static, dynamic and shared libraries.
  30
  31 --  This is the GNU/Linux version of the body.
  32
  33 with MLib.Fil;
  34 with MLib.Utl;
  35 with Namet;  use Namet;
  36 with Opt;
  37 with Output; use Output;
  38 with Prj.Com;
  39 with System;
  40
  41 package body MLib.Tgt is
  42
  43    use GNAT;
  44    use MLib;
  45
  46    No_Arguments        : aliased Argument_List         := (1 .. 0 => null);
  47    Empty_Argument_List : constant Argument_List_Access := No_Arguments'Access;
  48
  49    Wl_Init_String : aliased String         := "-Wl,-init";
  50    Wl_Init        : constant String_Access := Wl_Init_String'Access;
  51    Wl_Fini_String : aliased String         := "-Wl,-fini";
  52    Wl_Fini        : constant String_Access := Wl_Fini_String'Access;
  53
  54    Init_Fini_List :  constant Argument_List_Access :=
  55                        new Argument_List'(1 => Wl_Init,
  56                                           2 => null,
  57                                           3 => Wl_Fini,
  58                                           4 => null);
  59    --  Used to put switches for automatic elaboration/finalization
  60
  61    ---------------------
  62    -- Archive_Builder --
  63    ---------------------
  64
  65    function Archive_Builder return String is
  66    begin
  67       return "ar";
  68    end Archive_Builder;
  69
  70    -----------------------------
  71    -- Archive_Builder_Options --
  72    -----------------------------
  73
  74    function Archive_Builder_Options return String_List_Access is
  75    begin
  76       return new String_List'(1 => new String'("cr"));
  77    end Archive_Builder_Options;
  78
  79    -----------------
  80    -- Archive_Ext --
  81    -----------------
  82
  83    function Archive_Ext return  String is
  84    begin
  85       return "a";
  86    end Archive_Ext;
  87
  88    ---------------------
  89    -- Archive_Indexer --
  90    ---------------------
  91
  92    function Archive_Indexer return String is
  93    begin
  94       return "ranlib";
  95    end Archive_Indexer;
  96
  97    ---------------------------
  98    -- Build_Dynamic_Library --
  99    ---------------------------
 100
 101    procedure Build_Dynamic_Library
 102      (Ofiles       : Argument_List;
 103       Foreign      : Argument_List;
 104       Afiles       : Argument_List;
 105       Options      : Argument_List;
 106       Interfaces   : Argument_List;
 107       Lib_Filename : String;
 108       Lib_Dir      : String;
 109       Symbol_Data  : Symbol_Record;
 110       Driver_Name  : Name_Id := No_Name;
 111       Lib_Version  : String  := "";
 112       Auto_Init    : Boolean := False)
 113    is
 114       pragma Unreferenced (Foreign);
 115       pragma Unreferenced (Afiles);
 116       pragma Unreferenced (Interfaces);
 117       pragma Unreferenced (Symbol_Data);
 118
 119       Lib_File : constant String :=
 120                    Lib_Dir & Directory_Separator & "lib" &
 121                    Fil.Ext_To (Lib_Filename, DLL_Ext);
 122
 123       Version_Arg          : String_Access;
 124       Symbolic_Link_Needed : Boolean := False;
 125
 126       Init_Fini : Argument_List_Access := Empty_Argument_List;
 127
 128    begin
 129       if Opt.Verbose_Mode then
 130          Write_Str ("building relocatable shared library ");
 131          Write_Line (Lib_File);
 132       end if;
 133
 134       --  If specified, add automatic elaboration/finalization
 135
 136       if Auto_Init then
 137          Init_Fini := Init_Fini_List;
 138          Init_Fini (2) := new String'("-Wl," & Lib_Filename & "init");
 139          Init_Fini (4) := new String'("-Wl," & Lib_Filename & "final");
 140       end if;
 141
 142       if Lib_Version = "" then
 143          Utl.Gcc
 144            (Output_File => Lib_File,
 145             Objects     => Ofiles,
 146             Options     => Options & Init_Fini.all,
 147             Driver_Name => Driver_Name);
 148
 149       else
 150          Version_Arg := new String'("-Wl,-soname," & Lib_Version);
 151
 152          if Is_Absolute_Path (Lib_Version) then
 153             Utl.Gcc
 154               (Output_File => Lib_Version,
 155                Objects     => Ofiles,
 156                Options     => Options & Version_Arg & Init_Fini.all,
 157                Driver_Name => Driver_Name);
 158             Symbolic_Link_Needed := Lib_Version /= Lib_File;
 159
 160          else
 161             Utl.Gcc
 162               (Output_File => Lib_Dir & Directory_Separator & Lib_Version,
 163                Objects     => Ofiles,
 164                Options     => Options & Version_Arg & Init_Fini.all,
 165                Driver_Name => Driver_Name);
 166             Symbolic_Link_Needed :=
 167               Lib_Dir & Directory_Separator & Lib_Version /= Lib_File;
 168          end if;
 169
 170          if Symbolic_Link_Needed then
 171             declare
 172                Success : Boolean;
 173                Oldpath : String (1 .. Lib_Version'Length + 1);
 174                Newpath : String (1 .. Lib_File'Length + 1);
 175
 176                Result : Integer;
 177                pragma Unreferenced (Result);
 178
 179                function Symlink
 180                  (Oldpath : System.Address;
 181                   Newpath : System.Address) return Integer;
 182                pragma Import (C, Symlink, "__gnat_symlink");
 183
 184             begin
 185                Oldpath (1 .. Lib_Version'Length) := Lib_Version;
 186                Oldpath (Oldpath'Last)            := ASCII.NUL;
 187                Newpath (1 .. Lib_File'Length)    := Lib_File;
 188                Newpath (Newpath'Last)            := ASCII.NUL;
 189
 190                Delete_File (Lib_File, Success);
 191
 192                Result := Symlink (Oldpath'Address, Newpath'Address);
 193             end;
 194          end if;
 195       end if;
 196    end Build_Dynamic_Library;
 197
 198    -------------
 199    -- DLL_Ext --
 200    -------------
 201
 202    function DLL_Ext return String is
 203    begin
 204       return "so";
 205    end DLL_Ext;
 206
 207    --------------------
 208    -- Dynamic_Option --
 209    --------------------
 210
 211    function Dynamic_Option return String is
 212    begin
 213       return "-shared";
 214    end Dynamic_Option;
 215
 216    -------------------
 217    -- Is_Object_Ext --
 218    -------------------
 219
 220    function Is_Object_Ext (Ext : String) return Boolean is
 221    begin
 222       return Ext = ".o";
 223    end Is_Object_Ext;
 224
 225    --------------
 226    -- Is_C_Ext --
 227    --------------
 228
 229    function Is_C_Ext (Ext : String) return Boolean is
 230    begin
 231       return Ext = ".c";
 232    end Is_C_Ext;
 233
 234    --------------------
 235    -- Is_Archive_Ext --
 236    --------------------
 237
 238    function Is_Archive_Ext (Ext : String) return Boolean is
 239    begin
 240       return Ext = ".a" or else Ext = ".so";
 241    end Is_Archive_Ext;
 242
 243    -------------
 244    -- Libgnat --
 245    -------------
 246
 247    function Libgnat return String is
 248    begin
 249       return "libgnat.a";
 250    end Libgnat;
 251
 252    ------------------------
 253    -- Library_Exists_For --
 254    ------------------------
 255
 256    function Library_Exists_For (Project : Project_Id) return Boolean is
 257    begin
 258       if not Projects.Table (Project).Library then
 259          Prj.Com.Fail ("INTERNAL ERROR: Library_Exists_For called " &
 260                        "for non library project");
 261          return False;
 262
 263       else
 264          declare
 265             Lib_Dir : constant String :=
 266               Get_Name_String (Projects.Table (Project).Library_Dir);
 267             Lib_Name : constant String :=
 268               Get_Name_String (Projects.Table (Project).Library_Name);
 269
 270          begin
 271             if Projects.Table (Project).Library_Kind = Static then
 272                return Is_Regular_File
 273                  (Lib_Dir & Directory_Separator & "lib" &
 274                   Fil.Ext_To (Lib_Name, Archive_Ext));
 275
 276             else
 277                return Is_Regular_File
 278                  (Lib_Dir & Directory_Separator & "lib" &
 279                   Fil.Ext_To (Lib_Name, DLL_Ext));
 280             end if;
 281          end;
 282       end if;
 283    end Library_Exists_For;
 284
 285    ---------------------------
 286    -- Library_File_Name_For --
 287    ---------------------------
 288
 289    function Library_File_Name_For (Project : Project_Id) return Name_Id is
 290    begin
 291       if not Projects.Table (Project).Library then
 292          Prj.Com.Fail ("INTERNAL ERROR: Library_File_Name_For called " &
 293                        "for non library project");
 294          return No_Name;
 295
 296       else
 297          declare
 298             Lib_Name : constant String :=
 299               Get_Name_String (Projects.Table (Project).Library_Name);
 300
 301          begin
 302             Name_Len := 3;
 303             Name_Buffer (1 .. Name_Len) := "lib";
 304
 305             if Projects.Table (Project).Library_Kind = Static then
 306                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, Archive_Ext));
 307
 308             else
 309                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, DLL_Ext));
 310             end if;
 311
 312             return Name_Find;
 313          end;
 314       end if;
 315    end Library_File_Name_For;
 316
 317    ----------------
 318    -- Object_Ext --
 319    ----------------
 320
 321    function Object_Ext return String is
 322    begin
 323       return "o";
 324    end Object_Ext;
 325
 326    ----------------
 327    -- PIC_Option --
 328    ----------------
 329
 330    function PIC_Option return String is
 331    begin
 332       return "-fPIC";
 333    end PIC_Option;
 334
 335    -----------------------------------------------
 336    -- Standalone_Library_Auto_Init_Is_Supported --
 337    -----------------------------------------------
 338
 339    function Standalone_Library_Auto_Init_Is_Supported return Boolean is
 340    begin
 341       return True;
 342    end Standalone_Library_Auto_Init_Is_Supported;
 343
 344    ---------------------------
 345    -- Support_For_Libraries --
 346    ---------------------------
 347
 348    function Support_For_Libraries return Library_Support is
 349    begin
 350       return Full;
 351    end Support_For_Libraries;
 352
 353 end MLib.Tgt;