gcc/ada/mlib-tgt-hpux.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             M L I B . T G T                              --
   6 --                             (HP-UX Version)                              --
   7 --                                                                          --
   8 --                                 B o d y                                  --
   9 --                                                                          --
  10 --           Copyright (C) 2003-2005, Ada Core Technologies, Inc.           --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- GNAT was originally developed  by the GNAT team at  New York University. --
  24 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  25 --                                                                          --
  26 ------------------------------------------------------------------------------
  27
  28 --  This package provides a set of target dependent routines to build
  29 --  libraries (static only on HP-UX).
  30
  31 --  This is the HP-UX version of the body.
  32
  33 with MLib.Fil;
  34 with MLib.Utl;
  35 with Namet;  use Namet;
  36 with Opt;
  37 with Output; use Output;
  38 with Prj.Com;
  39 with System;
  40
  41 package body MLib.Tgt is
  42
  43    No_Arguments        : aliased Argument_List         := (1 .. 0 => null);
  44    Empty_Argument_List : constant Argument_List_Access := No_Arguments'Access;
  45
  46    Wl_Init_String : aliased String         := "-Wl,+init";
  47    Wl_Init        : constant String_Access := Wl_Init_String'Access;
  48    Wl_Fini_String : aliased String         := "-Wl,+fini";
  49    Wl_Fini        : constant String_Access := Wl_Fini_String'Access;
  50
  51    Init_Fini_List :  constant Argument_List_Access :=
  52                        new Argument_List'(1 => Wl_Init,
  53                                           2 => null,
  54                                           3 => Wl_Fini,
  55                                           4 => null);
  56    --  Used to put switches for automatic elaboration/finalization
  57    ---------------------
  58    -- Archive_Builder --
  59    ---------------------
  60
  61    function Archive_Builder return String is
  62    begin
  63       return "ar";
  64    end Archive_Builder;
  65
  66    -----------------------------
  67    -- Archive_Builder_Options --
  68    -----------------------------
  69
  70    function Archive_Builder_Options return String_List_Access is
  71    begin
  72       return new String_List'(1 => new String'("cr"));
  73    end Archive_Builder_Options;
  74
  75    -----------------
  76    -- Archive_Ext --
  77    -----------------
  78
  79    function Archive_Ext return String is
  80    begin
  81       return "a";
  82    end Archive_Ext;
  83
  84    ---------------------
  85    -- Archive_Indexer --
  86    ---------------------
  87
  88    function Archive_Indexer return String is
  89    begin
  90       return "ranlib";
  91    end Archive_Indexer;
  92
  93    -----------------------------
  94    -- Archive_Indexer_Options --
  95    -----------------------------
  96
  97    function Archive_Indexer_Options return String_List_Access is
  98    begin
  99       return new String_List (1 .. 0);
 100    end Archive_Indexer_Options;
 101
 102    ---------------------------
 103    -- Build_Dynamic_Library --
 104    ---------------------------
 105
 106    procedure Build_Dynamic_Library
 107      (Ofiles       : Argument_List;
 108       Foreign      : Argument_List;
 109       Afiles       : Argument_List;
 110       Options      : Argument_List;
 111       Options_2    : Argument_List;
 112       Interfaces   : Argument_List;
 113       Lib_Filename : String;
 114       Lib_Dir      : String;
 115       Symbol_Data  : Symbol_Record;
 116       Driver_Name  : Name_Id := No_Name;
 117       Lib_Version  : String  := "";
 118       Auto_Init    : Boolean := False)
 119    is
 120       pragma Unreferenced (Foreign);
 121       pragma Unreferenced (Afiles);
 122       pragma Unreferenced (Interfaces);
 123       pragma Unreferenced (Symbol_Data);
 124
 125       Lib_File : constant String :=
 126                    Lib_Dir & Directory_Separator & "lib" &
 127                    MLib.Fil.Ext_To (Lib_Filename, DLL_Ext);
 128
 129       Version_Arg          : String_Access;
 130       Symbolic_Link_Needed : Boolean := False;
 131
 132       Init_Fini : Argument_List_Access := Empty_Argument_List;
 133
 134       Common_Options : constant Argument_List :=
 135                          Options & new String'(PIC_Option);
 136       --  Common set of options to the gcc command performing the link.
 137       --  On HPUX, this command eventually resorts to collect2, which may
 138       --  generate a C file and compile it on the fly. This compilation shall
 139       --  also generate position independant code for the final link to
 140       --  succeed.
 141    begin
 142       if Opt.Verbose_Mode then
 143          Write_Str ("building relocatable shared library ");
 144          Write_Line (Lib_File);
 145       end if;
 146
 147       --  If specified, add automatic elaboration/finalization
 148
 149       if Auto_Init then
 150          Init_Fini := Init_Fini_List;
 151          Init_Fini (2) := new String'("-Wl," & Lib_Filename & "init");
 152          Init_Fini (4) := new String'("-Wl," & Lib_Filename & "final");
 153       end if;
 154
 155       if Lib_Version = "" then
 156          MLib.Utl.Gcc
 157            (Output_File => Lib_File,
 158             Objects     => Ofiles,
 159             Options     => Common_Options & Init_Fini.all,
 160             Options_2   => Options_2,
 161             Driver_Name => Driver_Name);
 162
 163       else
 164          Version_Arg := new String'("-Wl,+h," & Lib_Version);
 165
 166          if Is_Absolute_Path (Lib_Version) then
 167             MLib.Utl.Gcc
 168               (Output_File => Lib_Version,
 169                Objects     => Ofiles,
 170                Options     => Common_Options & Version_Arg & Init_Fini.all,
 171                Options_2   => Options_2,
 172                Driver_Name => Driver_Name);
 173             Symbolic_Link_Needed := Lib_Version /= Lib_File;
 174
 175          else
 176             MLib.Utl.Gcc
 177               (Output_File => Lib_Dir & Directory_Separator & Lib_Version,
 178                Objects     => Ofiles,
 179                Options     => Common_Options & Version_Arg & Init_Fini.all,
 180                Options_2   => Options_2,
 181                Driver_Name => Driver_Name);
 182             Symbolic_Link_Needed :=
 183               Lib_Dir & Directory_Separator & Lib_Version /= Lib_File;
 184          end if;
 185
 186          if Symbolic_Link_Needed then
 187             declare
 188                Success : Boolean;
 189                Oldpath : String (1 .. Lib_Version'Length + 1);
 190                Newpath : String (1 .. Lib_File'Length + 1);
 191
 192                Result : Integer;
 193                pragma Unreferenced (Result);
 194
 195                function Symlink
 196                  (Oldpath : System.Address;
 197                   Newpath : System.Address) return Integer;
 198                pragma Import (C, Symlink, "__gnat_symlink");
 199
 200             begin
 201                Oldpath (1 .. Lib_Version'Length) := Lib_Version;
 202                Oldpath (Oldpath'Last)            := ASCII.NUL;
 203                Newpath (1 .. Lib_File'Length)    := Lib_File;
 204                Newpath (Newpath'Last)            := ASCII.NUL;
 205
 206                Delete_File (Lib_File, Success);
 207
 208                Result := Symlink (Oldpath'Address, Newpath'Address);
 209             end;
 210          end if;
 211       end if;
 212    end Build_Dynamic_Library;
 213
 214    -------------
 215    -- DLL_Ext --
 216    -------------
 217
 218    function DLL_Ext return String is
 219    begin
 220       return "sl";
 221    end DLL_Ext;
 222
 223    --------------------
 224    -- Dynamic_Option --
 225    --------------------
 226
 227    function Dynamic_Option return String is
 228    begin
 229       return "-shared";
 230    end Dynamic_Option;
 231
 232    -------------------
 233    -- Is_Object_Ext --
 234    -------------------
 235
 236    function Is_Object_Ext (Ext : String) return Boolean is
 237    begin
 238       return Ext = ".o";
 239    end Is_Object_Ext;
 240
 241    --------------
 242    -- Is_C_Ext --
 243    --------------
 244
 245    function Is_C_Ext (Ext : String) return Boolean is
 246    begin
 247       return Ext = ".c";
 248    end Is_C_Ext;
 249
 250    --------------------
 251    -- Is_Archive_Ext --
 252    --------------------
 253
 254    function Is_Archive_Ext (Ext : String) return Boolean is
 255    begin
 256       return Ext = ".a" or else Ext = ".so";
 257    end Is_Archive_Ext;
 258
 259    -------------
 260    -- Libgnat --
 261    -------------
 262
 263    function Libgnat return String is
 264    begin
 265       return "libgnat.a";
 266    end Libgnat;
 267
 268    ------------------------
 269    -- Library_Exists_For --
 270    ------------------------
 271
 272    function Library_Exists_For
 273      (Project : Project_Id; In_Tree : Project_Tree_Ref) return Boolean
 274    is
 275    begin
 276       if not In_Tree.Projects.Table (Project).Library then
 277          Prj.Com.Fail ("INTERNAL ERROR: Library_Exists_For called " &
 278                        "for non library project");
 279          return False;
 280
 281       else
 282          declare
 283             Lib_Dir : constant String :=
 284               Get_Name_String
 285                 (In_Tree.Projects.Table (Project).Library_Dir);
 286             Lib_Name : constant String :=
 287               Get_Name_String
 288                 (In_Tree.Projects.Table (Project).Library_Name);
 289
 290          begin
 291             if In_Tree.Projects.Table (Project).Library_Kind =
 292               Static
 293             then
 294                return Is_Regular_File
 295                  (Lib_Dir & Directory_Separator & "lib" &
 296                   Fil.Ext_To (Lib_Name, Archive_Ext));
 297
 298             else
 299                return Is_Regular_File
 300                  (Lib_Dir & Directory_Separator & "lib" &
 301                   Fil.Ext_To (Lib_Name, DLL_Ext));
 302             end if;
 303          end;
 304       end if;
 305    end Library_Exists_For;
 306
 307    ---------------------------
 308    -- Library_File_Name_For --
 309    ---------------------------
 310
 311    function Library_File_Name_For
 312      (Project : Project_Id;
 313       In_Tree : Project_Tree_Ref) return Name_Id
 314    is
 315    begin
 316       if not In_Tree.Projects.Table (Project).Library then
 317          Prj.Com.Fail ("INTERNAL ERROR: Library_File_Name_For called " &
 318                        "for non library project");
 319          return No_Name;
 320
 321       else
 322          declare
 323             Lib_Name : constant String :=
 324               Get_Name_String
 325                 (In_Tree.Projects.Table (Project).Library_Name);
 326
 327          begin
 328             Name_Len := 3;
 329             Name_Buffer (1 .. Name_Len) := "lib";
 330
 331             if In_Tree.Projects.Table (Project).Library_Kind =
 332               Static
 333             then
 334                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, Archive_Ext));
 335
 336             else
 337                Add_Str_To_Name_Buffer (Fil.Ext_To (Lib_Name, DLL_Ext));
 338             end if;
 339
 340             return Name_Find;
 341          end;
 342       end if;
 343    end Library_File_Name_For;
 344
 345    ----------------
 346    -- Object_Ext --
 347    ----------------
 348
 349    function Object_Ext return String is
 350    begin
 351       return "o";
 352    end Object_Ext;
 353
 354    ----------------
 355    -- PIC_Option --
 356    ----------------
 357
 358    function PIC_Option return String is
 359    begin
 360       return "-fPIC";
 361    end PIC_Option;
 362
 363    -----------------------------------------------
 364    -- Standalone_Library_Auto_Init_Is_Supported --
 365    -----------------------------------------------
 366
 367    function Standalone_Library_Auto_Init_Is_Supported return Boolean is
 368    begin
 369       return True;
 370    end Standalone_Library_Auto_Init_Is_Supported;
 371
 372    ---------------------------
 373    -- Support_For_Libraries --
 374    ---------------------------
 375
 376    function Support_For_Libraries return Library_Support is
 377    begin
 378       return Full;
 379    end Support_For_Libraries;
 380
 381 end MLib.Tgt;