gcc/ada/itypes.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              I T Y P E S                                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Opt;      use Opt;
  28 with Sem;      use Sem;
  29 with Sinfo;    use Sinfo;
  30 with Stand;    use Stand;
  31 with Targparm; use Targparm;
  32 with Uintp;    use Uintp;
  33
  34 package body Itypes is
  35
  36    ------------------
  37    -- Create_Itype --
  38    ------------------
  39
  40    function Create_Itype
  41      (Ekind        : Entity_Kind;
  42       Related_Nod  : Node_Id;
  43       Related_Id   : Entity_Id := Empty;
  44       Suffix       : Character := ' ';
  45       Suffix_Index : Nat       := 0;
  46       Scope_Id     : Entity_Id := Current_Scope) return Entity_Id
  47    is
  48       Typ : Entity_Id;
  49
  50    begin
  51       --  Should comment setting of Public_Status here ???
  52
  53       if Related_Id = Empty then
  54          Typ := New_Internal_Entity (Ekind, Scope_Id, Sloc (Related_Nod), 'T');
  55          Set_Public_Status (Typ);
  56
  57       else
  58          Typ :=
  59            New_External_Entity
  60              (Ekind, Scope_Id, Sloc (Related_Nod), Related_Id, Suffix,
  61               Suffix_Index, 'T');
  62       end if;
  63
  64       --  Make sure Esize (Typ) was properly initialized, it should be since
  65       --  New_Internal_Entity/New_External_Entity call Init_Size_Align.
  66
  67       pragma Assert (Esize (Typ) = Uint_0);
  68
  69       Set_Etype (Typ, Any_Type);
  70       Set_Is_Itype (Typ);
  71       Set_Associated_Node_For_Itype (Typ, Related_Nod);
  72
  73       if In_Deleted_Code
  74         and then not ASIS_Mode
  75       then
  76          Set_Is_Frozen (Typ);
  77       end if;
  78
  79       if Ekind in Access_Subprogram_Kind then
  80          Set_Can_Use_Internal_Rep (Typ, not Always_Compatible_Rep_On_Target);
  81       end if;
  82
  83       return Typ;
  84    end Create_Itype;
  85
  86    ---------------------------------
  87    -- Create_Null_Excluding_Itype --
  88    ---------------------------------
  89
  90    function Create_Null_Excluding_Itype
  91       (T           : Entity_Id;
  92        Related_Nod : Node_Id;
  93        Scope_Id    : Entity_Id := Current_Scope) return Entity_Id
  94    is
  95       I_Typ        : Entity_Id;
  96
  97    begin
  98       pragma Assert (Is_Access_Type (T));
  99
 100       I_Typ := Create_Itype (Ekind       => E_Access_Subtype,
 101                              Related_Nod => Related_Nod,
 102                              Scope_Id    => Scope_Id);
 103
 104       Set_Directly_Designated_Type (I_Typ, Directly_Designated_Type (T));
 105       Set_Etype                    (I_Typ, Base_Type (T));
 106       Set_Depends_On_Private       (I_Typ, Depends_On_Private (T));
 107       Set_Is_Public                (I_Typ, Is_Public          (T));
 108       Set_From_With_Type           (I_Typ, From_With_Type     (T));
 109       Set_Is_Access_Constant       (I_Typ, Is_Access_Constant (T));
 110       Set_Is_Generic_Type          (I_Typ, Is_Generic_Type    (T));
 111       Set_Is_Volatile              (I_Typ, Is_Volatile        (T));
 112       Set_Treat_As_Volatile        (I_Typ, Treat_As_Volatile  (T));
 113       Set_Is_Atomic                (I_Typ, Is_Atomic          (T));
 114       Set_Is_Ada_2005_Only         (I_Typ, Is_Ada_2005_Only   (T));
 115       Set_Can_Never_Be_Null        (I_Typ);
 116
 117       return I_Typ;
 118    end Create_Null_Excluding_Itype;
 119
 120 end Itypes;