gcc/ada/inline.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               I N L I N E                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Einfo;    use Einfo;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Exp_Ch7;  use Exp_Ch7;
  31 with Exp_Tss;  use Exp_Tss;
  32 with Fname;    use Fname;
  33 with Fname.UF; use Fname.UF;
  34 with Lib;      use Lib;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Sem_Aux;  use Sem_Aux;
  38 with Sem_Ch8;  use Sem_Ch8;
  39 with Sem_Ch10; use Sem_Ch10;
  40 with Sem_Ch12; use Sem_Ch12;
  41 with Sem_Util; use Sem_Util;
  42 with Sinfo;    use Sinfo;
  43 with Snames;   use Snames;
  44 with Stand;    use Stand;
  45 with Uname;    use Uname;
  46
  47 package body Inline is
  48
  49    --------------------
  50    -- Inlined Bodies --
  51    --------------------
  52
  53    --  Inlined functions are actually placed in line by the backend if the
  54    --  corresponding bodies are available (i.e. compiled). Whenever we find
  55    --  a call to an inlined subprogram, we add the name of the enclosing
  56    --  compilation unit to a worklist. After all compilation, and after
  57    --  expansion of generic bodies, we traverse the list of pending bodies
  58    --  and compile them as well.
  59
  60    package Inlined_Bodies is new Table.Table (
  61      Table_Component_Type => Entity_Id,
  62      Table_Index_Type     => Int,
  63      Table_Low_Bound      => 0,
  64      Table_Initial        => Alloc.Inlined_Bodies_Initial,
  65      Table_Increment      => Alloc.Inlined_Bodies_Increment,
  66      Table_Name           => "Inlined_Bodies");
  67
  68    -----------------------
  69    -- Inline Processing --
  70    -----------------------
  71
  72    --  For each call to an inlined subprogram, we make entries in a table
  73    --  that stores caller and callee, and indicates a prerequisite from
  74    --  one to the other. We also record the compilation unit that contains
  75    --  the callee. After analyzing the bodies of all such compilation units,
  76    --  we produce a list of subprograms in  topological order, for use by the
  77    --  back-end. If P2 is a prerequisite of P1, then P1 calls P2, and for
  78    --  proper inlining the back-end must analyze the body of P2 before that of
  79    --  P1. The code below guarantees that the transitive closure of inlined
  80    --  subprograms called from the main compilation unit is made available to
  81    --  the code generator.
  82
  83    Last_Inlined : Entity_Id := Empty;
  84
  85    --  For each entry in the table we keep a list of successors in topological
  86    --  order, i.e. callers of the current subprogram.
  87
  88    type Subp_Index is new Nat;
  89    No_Subp : constant Subp_Index := 0;
  90
  91    --  The subprogram entities are hashed into the Inlined table
  92
  93    Num_Hash_Headers : constant := 512;
  94
  95    Hash_Headers : array (Subp_Index range 0 .. Num_Hash_Headers - 1)
  96                                                           of Subp_Index;
  97
  98    type Succ_Index is new Nat;
  99    No_Succ : constant Succ_Index := 0;
 100
 101    type Succ_Info is record
 102       Subp : Subp_Index;
 103       Next : Succ_Index;
 104    end record;
 105
 106    --  The following table stores list elements for the successor lists.
 107    --  These lists cannot be chained directly through entries in the Inlined
 108    --  table, because a given subprogram can appear in several such lists.
 109
 110    package Successors is new Table.Table (
 111       Table_Component_Type => Succ_Info,
 112       Table_Index_Type     => Succ_Index,
 113       Table_Low_Bound      => 1,
 114       Table_Initial        => Alloc.Successors_Initial,
 115       Table_Increment      => Alloc.Successors_Increment,
 116       Table_Name           => "Successors");
 117
 118    type Subp_Info is record
 119       Name        : Entity_Id  := Empty;
 120       First_Succ  : Succ_Index := No_Succ;
 121       Count       : Integer    := 0;
 122       Listed      : Boolean    := False;
 123       Main_Call   : Boolean    := False;
 124       Next        : Subp_Index := No_Subp;
 125       Next_Nopred : Subp_Index := No_Subp;
 126    end record;
 127
 128    package Inlined is new Table.Table (
 129       Table_Component_Type => Subp_Info,
 130       Table_Index_Type     => Subp_Index,
 131       Table_Low_Bound      => 1,
 132       Table_Initial        => Alloc.Inlined_Initial,
 133       Table_Increment      => Alloc.Inlined_Increment,
 134       Table_Name           => "Inlined");
 135
 136    -----------------------
 137    -- Local Subprograms --
 138    -----------------------
 139
 140    function Get_Code_Unit_Entity (E : Entity_Id) return Entity_Id;
 141    pragma Inline (Get_Code_Unit_Entity);
 142    --  Return the entity node for the unit containing E
 143
 144    function Scope_In_Main_Unit (Scop : Entity_Id) return Boolean;
 145    --  Return True if Scop is in the main unit or its spec
 146
 147    procedure Add_Call (Called : Entity_Id; Caller : Entity_Id := Empty);
 148    --  Make two entries in Inlined table, for an inlined subprogram being
 149    --  called, and for the inlined subprogram that contains the call. If
 150    --  the call is in the main compilation unit, Caller is Empty.
 151
 152    function Add_Subp (E : Entity_Id) return Subp_Index;
 153    --  Make entry in Inlined table for subprogram E, or return table index
 154    --  that already holds E.
 155
 156    function Has_Initialized_Type (E : Entity_Id) return Boolean;
 157    --  If a candidate for inlining contains type declarations for types with
 158    --  non-trivial initialization procedures, they are not worth inlining.
 159
 160    function Is_Nested (E : Entity_Id) return Boolean;
 161    --  If the function is nested inside some other function, it will
 162    --  always be compiled if that function is, so don't add it to the
 163    --  inline list. We cannot compile a nested function outside the
 164    --  scope of the containing function anyway. This is also the case if
 165    --  the function is defined in a task body or within an entry (for
 166    --  example, an initialization procedure).
 167
 168    procedure Add_Inlined_Subprogram (Index : Subp_Index);
 169    --  Add subprogram to Inlined List once all of its predecessors have been
 170    --  placed on the list. Decrement the count of all its successors, and
 171    --  add them to list (recursively) if count drops to zero.
 172
 173    ------------------------------
 174    -- Deferred Cleanup Actions --
 175    ------------------------------
 176
 177    --  The cleanup actions for scopes that contain instantiations is delayed
 178    --  until after expansion of those instantiations, because they may
 179    --  contain finalizable objects or tasks that affect the cleanup code.
 180    --  A scope that contains instantiations only needs to be finalized once,
 181    --  even if it contains more than one instance. We keep a list of scopes
 182    --  that must still be finalized, and call cleanup_actions after all the
 183    --  instantiations have been completed.
 184
 185    To_Clean : Elist_Id;
 186
 187    procedure Add_Scope_To_Clean (Inst : Entity_Id);
 188    --  Build set of scopes on which cleanup actions must be performed
 189
 190    procedure Cleanup_Scopes;
 191    --  Complete cleanup actions on scopes that need it
 192
 193    --------------
 194    -- Add_Call --
 195    --------------
 196
 197    procedure Add_Call (Called : Entity_Id; Caller : Entity_Id := Empty) is
 198       P1 : constant Subp_Index := Add_Subp (Called);
 199       P2 : Subp_Index;
 200       J  : Succ_Index;
 201
 202    begin
 203       if Present (Caller) then
 204          P2 := Add_Subp (Caller);
 205
 206          --  Add P2 to the list of successors of P1, if not already there.
 207          --  Note that P2 may contain more than one call to P1, and only
 208          --  one needs to be recorded.
 209
 210          J := Inlined.Table (P1).First_Succ;
 211          while J /= No_Succ loop
 212             if Successors.Table (J).Subp = P2 then
 213                return;
 214             end if;
 215
 216             J := Successors.Table (J).Next;
 217          end loop;
 218
 219          --  On exit, make a successor entry for P2
 220
 221          Successors.Increment_Last;
 222          Successors.Table (Successors.Last).Subp := P2;
 223          Successors.Table (Successors.Last).Next :=
 224                              Inlined.Table (P1).First_Succ;
 225          Inlined.Table (P1).First_Succ := Successors.Last;
 226
 227          Inlined.Table (P2).Count := Inlined.Table (P2).Count + 1;
 228
 229       else
 230          Inlined.Table (P1).Main_Call := True;
 231       end if;
 232    end Add_Call;
 233
 234    ----------------------
 235    -- Add_Inlined_Body --
 236    ----------------------
 237
 238    procedure Add_Inlined_Body (E : Entity_Id) is
 239
 240       function Must_Inline return Boolean;
 241       --  Inlining is only done if the call statement N is in the main unit,
 242       --  or within the body of another inlined subprogram.
 243
 244       -----------------
 245       -- Must_Inline --
 246       -----------------
 247
 248       function Must_Inline return Boolean is
 249          Scop : Entity_Id;
 250          Comp : Node_Id;
 251
 252       begin
 253          --  Check if call is in main unit
 254
 255          Scop := Current_Scope;
 256
 257          --  Do not try to inline if scope is standard. This could happen, for
 258          --  example, for a call to Add_Global_Declaration, and it causes
 259          --  trouble to try to inline at this level.
 260
 261          if Scop = Standard_Standard then
 262             return False;
 263          end if;
 264
 265          --  Otherwise lookup scope stack to outer scope
 266
 267          while Scope (Scop) /= Standard_Standard
 268            and then not Is_Child_Unit (Scop)
 269          loop
 270             Scop := Scope (Scop);
 271          end loop;
 272
 273          Comp := Parent (Scop);
 274          while Nkind (Comp) /= N_Compilation_Unit loop
 275             Comp := Parent (Comp);
 276          end loop;
 277
 278          if Comp = Cunit (Main_Unit)
 279            or else Comp = Library_Unit (Cunit (Main_Unit))
 280          then
 281             Add_Call (E);
 282             return True;
 283          end if;
 284
 285          --  Call is not in main unit. See if it's in some inlined subprogram
 286
 287          Scop := Current_Scope;
 288          while Scope (Scop) /= Standard_Standard
 289            and then not Is_Child_Unit (Scop)
 290          loop
 291             if Is_Overloadable (Scop)
 292               and then Is_Inlined (Scop)
 293             then
 294                Add_Call (E, Scop);
 295                return True;
 296             end if;
 297
 298             Scop := Scope (Scop);
 299          end loop;
 300
 301          return False;
 302       end Must_Inline;
 303
 304    --  Start of processing for Add_Inlined_Body
 305
 306    begin
 307       --  Find unit containing E, and add to list of inlined bodies if needed.
 308       --  If the body is already present, no need to load any other unit. This
 309       --  is the case for an initialization procedure, which appears in the
 310       --  package declaration that contains the type. It is also the case if
 311       --  the body has already been analyzed. Finally, if the unit enclosing
 312       --  E is an instance, the instance body will be analyzed in any case,
 313       --  and there is no need to add the enclosing unit (whose body might not
 314       --  be available).
 315
 316       --  Library-level functions must be handled specially, because there is
 317       --  no enclosing package to retrieve. In this case, it is the body of
 318       --  the function that will have to be loaded.
 319
 320       if not Is_Abstract_Subprogram (E)
 321         and then not Is_Nested (E)
 322         and then Convention (E) /= Convention_Protected
 323         and then Must_Inline
 324       then
 325          declare
 326             Pack : constant Entity_Id := Get_Code_Unit_Entity (E);
 327
 328          begin
 329             if Pack = E then
 330
 331                --  Library-level inlined function. Add function itself to
 332                --  list of needed units.
 333
 334                Set_Is_Called (E);
 335                Inlined_Bodies.Increment_Last;
 336                Inlined_Bodies.Table (Inlined_Bodies.Last) := E;
 337
 338             elsif Ekind (Pack) = E_Package then
 339                Set_Is_Called (E);
 340
 341                if Is_Generic_Instance (Pack) then
 342                   null;
 343
 344                elsif not Is_Inlined (Pack)
 345                  and then
 346                    (not Has_Completion (E)
 347                      or else Is_Expression_Function (E))
 348                then
 349                   Set_Is_Inlined (Pack);
 350                   Inlined_Bodies.Increment_Last;
 351                   Inlined_Bodies.Table (Inlined_Bodies.Last) := Pack;
 352                end if;
 353             end if;
 354          end;
 355       end if;
 356    end Add_Inlined_Body;
 357
 358    ----------------------------
 359    -- Add_Inlined_Subprogram --
 360    ----------------------------
 361
 362    procedure Add_Inlined_Subprogram (Index : Subp_Index) is
 363       E    : constant Entity_Id := Inlined.Table (Index).Name;
 364       Pack : constant Entity_Id := Get_Code_Unit_Entity (E);
 365       Succ : Succ_Index;
 366       Subp : Subp_Index;
 367
 368       function Back_End_Cannot_Inline (Subp : Entity_Id) return Boolean;
 369       --  There are various conditions under which back-end inlining cannot
 370       --  be done reliably:
 371       --
 372       --    a) If a body has handlers, it must not be inlined, because this
 373       --    may violate program semantics, and because in zero-cost exception
 374       --    mode it will lead to undefined symbols at link time.
 375       --
 376       --    b) If a body contains inlined function instances, it cannot be
 377       --    inlined under ZCX because the numeric suffix generated by gigi
 378       --    will be different in the body and the place of the inlined call.
 379       --
 380       --  This procedure must be carefully coordinated with the back end.
 381
 382       ----------------------------
 383       -- Back_End_Cannot_Inline --
 384       ----------------------------
 385
 386       function Back_End_Cannot_Inline (Subp : Entity_Id) return Boolean is
 387          Decl     : constant Node_Id := Unit_Declaration_Node (Subp);
 388          Body_Ent : Entity_Id;
 389          Ent      : Entity_Id;
 390
 391       begin
 392          if Nkind (Decl) = N_Subprogram_Declaration
 393            and then Present (Corresponding_Body (Decl))
 394          then
 395             Body_Ent := Corresponding_Body (Decl);
 396          else
 397             return False;
 398          end if;
 399
 400          --  If subprogram is marked Inline_Always, inlining is mandatory
 401
 402          if Has_Pragma_Inline_Always (Subp) then
 403             return False;
 404          end if;
 405
 406          if Present
 407           (Exception_Handlers
 408             (Handled_Statement_Sequence
 409               (Unit_Declaration_Node (Corresponding_Body (Decl)))))
 410          then
 411             return True;
 412          end if;
 413
 414          Ent := First_Entity (Body_Ent);
 415          while Present (Ent) loop
 416             if Is_Subprogram (Ent)
 417               and then Is_Generic_Instance (Ent)
 418             then
 419                return True;
 420             end if;
 421
 422             Next_Entity (Ent);
 423          end loop;
 424
 425          return False;
 426       end Back_End_Cannot_Inline;
 427
 428    --  Start of processing for Add_Inlined_Subprogram
 429
 430    begin
 431       --  If the subprogram is to be inlined, and if its unit is known to be
 432       --  inlined or is an instance whose body will be analyzed anyway or the
 433       --  subprogram has been generated by the compiler, and if it is declared
 434       --  at the library level not in the main unit, and if it can be inlined
 435       --  by the back-end, then insert it in the list of inlined subprograms.
 436
 437       if Is_Inlined (E)
 438         and then (Is_Inlined (Pack)
 439                     or else Is_Generic_Instance (Pack)
 440                     or else Is_Internal (E))
 441         and then not Scope_In_Main_Unit (E)
 442         and then not Is_Nested (E)
 443         and then not Has_Initialized_Type (E)
 444       then
 445          if Back_End_Cannot_Inline (E) then
 446             Set_Is_Inlined (E, False);
 447
 448          else
 449             if No (Last_Inlined) then
 450                Set_First_Inlined_Subprogram (Cunit (Main_Unit), E);
 451             else
 452                Set_Next_Inlined_Subprogram (Last_Inlined, E);
 453             end if;
 454
 455             Last_Inlined := E;
 456          end if;
 457       end if;
 458
 459       Inlined.Table (Index).Listed := True;
 460
 461       --  Now add to the list those callers of the current subprogram that
 462       --  are themselves called. They may appear on the graph as callers
 463       --  of the current one, even if they are themselves not called, and
 464       --  there is no point in including them in the list for the backend.
 465       --  Furthermore, they might not even be public, in which case the
 466       --  back-end cannot handle them at all.
 467
 468       Succ := Inlined.Table (Index).First_Succ;
 469       while Succ /= No_Succ loop
 470          Subp := Successors.Table (Succ).Subp;
 471          Inlined.Table (Subp).Count := Inlined.Table (Subp).Count - 1;
 472
 473          if Inlined.Table (Subp).Count = 0
 474            and then Is_Called (Inlined.Table (Subp).Name)
 475          then
 476             Add_Inlined_Subprogram (Subp);
 477          end if;
 478
 479          Succ := Successors.Table (Succ).Next;
 480       end loop;
 481    end Add_Inlined_Subprogram;
 482
 483    ------------------------
 484    -- Add_Scope_To_Clean --
 485    ------------------------
 486
 487    procedure Add_Scope_To_Clean (Inst : Entity_Id) is
 488       Scop : constant Entity_Id := Enclosing_Dynamic_Scope (Inst);
 489       Elmt : Elmt_Id;
 490
 491    begin
 492       --  If the instance appears in a library-level package declaration,
 493       --  all finalization is global, and nothing needs doing here.
 494
 495       if Scop = Standard_Standard then
 496          return;
 497       end if;
 498
 499       --  If the instance is within a generic unit, no finalization code
 500       --  can be generated. Note that at this point all bodies have been
 501       --  analyzed, and the scope stack itself is not present, and the flag
 502       --  Inside_A_Generic is not set.
 503
 504       declare
 505          S : Entity_Id;
 506
 507       begin
 508          S := Scope (Inst);
 509          while Present (S) and then S /= Standard_Standard loop
 510             if Is_Generic_Unit (S) then
 511                return;
 512             end if;
 513
 514             S := Scope (S);
 515          end loop;
 516       end;
 517
 518       Elmt := First_Elmt (To_Clean);
 519       while Present (Elmt) loop
 520          if Node (Elmt) = Scop then
 521             return;
 522          end if;
 523
 524          Elmt := Next_Elmt (Elmt);
 525       end loop;
 526
 527       Append_Elmt (Scop, To_Clean);
 528    end Add_Scope_To_Clean;
 529
 530    --------------
 531    -- Add_Subp --
 532    --------------
 533
 534    function Add_Subp (E : Entity_Id) return Subp_Index is
 535       Index : Subp_Index := Subp_Index (E) mod Num_Hash_Headers;
 536       J     : Subp_Index;
 537
 538       procedure New_Entry;
 539       --  Initialize entry in Inlined table
 540
 541       procedure New_Entry is
 542       begin
 543          Inlined.Increment_Last;
 544          Inlined.Table (Inlined.Last).Name        := E;
 545          Inlined.Table (Inlined.Last).First_Succ  := No_Succ;
 546          Inlined.Table (Inlined.Last).Count       := 0;
 547          Inlined.Table (Inlined.Last).Listed      := False;
 548          Inlined.Table (Inlined.Last).Main_Call   := False;
 549          Inlined.Table (Inlined.Last).Next        := No_Subp;
 550          Inlined.Table (Inlined.Last).Next_Nopred := No_Subp;
 551       end New_Entry;
 552
 553    --  Start of processing for Add_Subp
 554
 555    begin
 556       if Hash_Headers (Index) = No_Subp then
 557          New_Entry;
 558          Hash_Headers (Index) := Inlined.Last;
 559          return Inlined.Last;
 560
 561       else
 562          J := Hash_Headers (Index);
 563          while J /= No_Subp loop
 564             if Inlined.Table (J).Name = E then
 565                return J;
 566             else
 567                Index := J;
 568                J := Inlined.Table (J).Next;
 569             end if;
 570          end loop;
 571
 572          --  On exit, subprogram was not found. Enter in table. Index is
 573          --  the current last entry on the hash chain.
 574
 575          New_Entry;
 576          Inlined.Table (Index).Next := Inlined.Last;
 577          return Inlined.Last;
 578       end if;
 579    end Add_Subp;
 580
 581    ----------------------------
 582    -- Analyze_Inlined_Bodies --
 583    ----------------------------
 584
 585    procedure Analyze_Inlined_Bodies is
 586       Comp_Unit : Node_Id;
 587       J         : Int;
 588       Pack      : Entity_Id;
 589       S         : Succ_Index;
 590
 591       function Is_Ancestor_Of_Main
 592         (U_Name : Entity_Id;
 593          Nam    : Node_Id) return Boolean;
 594       --  Determine whether the unit whose body is loaded is an ancestor of
 595       --  the main unit, and has a with_clause on it. The body is not
 596       --  analyzed yet, so the check is purely lexical: the name of the with
 597       --  clause is a selected component, and names of ancestors must match.
 598
 599       -------------------------
 600       -- Is_Ancestor_Of_Main --
 601       -------------------------
 602
 603       function Is_Ancestor_Of_Main
 604         (U_Name : Entity_Id;
 605          Nam    : Node_Id) return Boolean
 606       is
 607          Pref : Node_Id;
 608
 609       begin
 610          if Nkind (Nam) /= N_Selected_Component then
 611             return False;
 612
 613          else
 614             if Chars (Selector_Name (Nam)) /=
 615                Chars (Cunit_Entity (Main_Unit))
 616             then
 617                return False;
 618             end if;
 619
 620             Pref := Prefix (Nam);
 621             if Nkind (Pref) = N_Identifier then
 622
 623                --  Par is an ancestor of Par.Child.
 624
 625                return Chars (Pref) = Chars (U_Name);
 626
 627             elsif Nkind (Pref) = N_Selected_Component
 628               and then Chars (Selector_Name (Pref)) = Chars (U_Name)
 629             then
 630                --  Par.Child is an ancestor of Par.Child.Grand.
 631
 632                return True;   --  should check that ancestor match
 633
 634             else
 635                --  A is an ancestor of A.B.C if it is an ancestor of A.B
 636
 637                return Is_Ancestor_Of_Main (U_Name, Pref);
 638             end if;
 639          end if;
 640       end Is_Ancestor_Of_Main;
 641
 642    --  Start of processing for  Analyze_Inlined_Bodies
 643
 644    begin
 645       Analyzing_Inlined_Bodies := False;
 646
 647       if Serious_Errors_Detected = 0 then
 648          Push_Scope (Standard_Standard);
 649
 650          J := 0;
 651          while J <= Inlined_Bodies.Last
 652            and then Serious_Errors_Detected = 0
 653          loop
 654             Pack := Inlined_Bodies.Table (J);
 655             while Present (Pack)
 656               and then Scope (Pack) /= Standard_Standard
 657               and then not Is_Child_Unit (Pack)
 658             loop
 659                Pack := Scope (Pack);
 660             end loop;
 661
 662             Comp_Unit := Parent (Pack);
 663             while Present (Comp_Unit)
 664               and then Nkind (Comp_Unit) /= N_Compilation_Unit
 665             loop
 666                Comp_Unit := Parent (Comp_Unit);
 667             end loop;
 668
 669             --  Load the body, unless it the main unit, or is an instance whose
 670             --  body has already been analyzed.
 671
 672             if Present (Comp_Unit)
 673               and then Comp_Unit /= Cunit (Main_Unit)
 674               and then Body_Required (Comp_Unit)
 675               and then (Nkind (Unit (Comp_Unit)) /= N_Package_Declaration
 676                          or else No (Corresponding_Body (Unit (Comp_Unit))))
 677             then
 678                declare
 679                   Bname : constant Unit_Name_Type :=
 680                             Get_Body_Name (Get_Unit_Name (Unit (Comp_Unit)));
 681
 682                   OK : Boolean;
 683
 684                begin
 685                   if not Is_Loaded (Bname) then
 686                      Style_Check := False;
 687                      Load_Needed_Body (Comp_Unit, OK, Do_Analyze => False);
 688
 689                      if not OK then
 690
 691                         --  Warn that a body was not available for inlining
 692                         --  by the back-end.
 693
 694                         Error_Msg_Unit_1 := Bname;
 695                         Error_Msg_N
 696                           ("one or more inlined subprograms accessed in $!?",
 697                            Comp_Unit);
 698                         Error_Msg_File_1 :=
 699                           Get_File_Name (Bname, Subunit => False);
 700                         Error_Msg_N ("\but file{ was not found!?", Comp_Unit);
 701
 702                      else
 703                         --  If the package to be inlined is an ancestor unit of
 704                         --  the main unit, and it has a semantic dependence on
 705                         --  it, the inlining cannot take place to prevent an
 706                         --  elaboration circularity. The desired body is not
 707                         --  analyzed yet, to prevent the completion of Taft
 708                         --  amendment types that would lead to elaboration
 709                         --  circularities in gigi.
 710
 711                         declare
 712                            U_Id      : constant Entity_Id :=
 713                                          Defining_Entity (Unit (Comp_Unit));
 714                            Body_Unit : constant Node_Id :=
 715                                          Library_Unit (Comp_Unit);
 716                            Item      : Node_Id;
 717
 718                         begin
 719                            Item := First (Context_Items (Body_Unit));
 720                            while Present (Item) loop
 721                               if Nkind (Item) = N_With_Clause
 722                                 and then
 723                                   Is_Ancestor_Of_Main (U_Id, Name (Item))
 724                               then
 725                                  Set_Is_Inlined (U_Id, False);
 726                                  exit;
 727                               end if;
 728
 729                               Next (Item);
 730                            end loop;
 731
 732                            --  If no suspicious with_clauses, analyze the body.
 733
 734                            if Is_Inlined (U_Id) then
 735                               Semantics (Body_Unit);
 736                            end if;
 737                         end;
 738                      end if;
 739                   end if;
 740                end;
 741             end if;
 742
 743             J := J + 1;
 744          end loop;
 745
 746          --  The analysis of required bodies may have produced additional
 747          --  generic instantiations. To obtain further inlining, we perform
 748          --  another round of generic body instantiations. Establishing a
 749          --  fully recursive loop between inlining and generic instantiations
 750          --  is unlikely to yield more than this one additional pass.
 751
 752          Instantiate_Bodies;
 753
 754          --  The list of inlined subprograms is an overestimate, because it
 755          --  includes inlined functions called from functions that are compiled
 756          --  as part of an inlined package, but are not themselves called. An
 757          --  accurate computation of just those subprograms that are needed
 758          --  requires that we perform a transitive closure over the call graph,
 759          --  starting from calls in the main program. Here we do one step of
 760          --  the inverse transitive closure, and reset the Is_Called flag on
 761          --  subprograms all of whose callers are not.
 762
 763          for Index in Inlined.First .. Inlined.Last loop
 764             S := Inlined.Table (Index).First_Succ;
 765
 766             if S /= No_Succ
 767               and then not Inlined.Table (Index).Main_Call
 768             then
 769                Set_Is_Called (Inlined.Table (Index).Name, False);
 770
 771                while S /= No_Succ loop
 772                   if Is_Called
 773                     (Inlined.Table (Successors.Table (S).Subp).Name)
 774                    or else Inlined.Table (Successors.Table (S).Subp).Main_Call
 775                   then
 776                      Set_Is_Called (Inlined.Table (Index).Name);
 777                      exit;
 778                   end if;
 779
 780                   S := Successors.Table (S).Next;
 781                end loop;
 782             end if;
 783          end loop;
 784
 785          --  Now that the units are compiled, chain the subprograms within
 786          --  that are called and inlined. Produce list of inlined subprograms
 787          --  sorted in  topological order. Start with all subprograms that
 788          --  have no prerequisites, i.e. inlined subprograms that do not call
 789          --  other inlined subprograms.
 790
 791          for Index in Inlined.First .. Inlined.Last loop
 792
 793             if Is_Called (Inlined.Table (Index).Name)
 794               and then Inlined.Table (Index).Count = 0
 795               and then not Inlined.Table (Index).Listed
 796             then
 797                Add_Inlined_Subprogram (Index);
 798             end if;
 799          end loop;
 800
 801          --  Because Add_Inlined_Subprogram treats recursively nodes that have
 802          --  no prerequisites left, at the end of the loop all subprograms
 803          --  must have been listed. If there are any unlisted subprograms
 804          --  left, there must be some recursive chains that cannot be inlined.
 805
 806          for Index in Inlined.First .. Inlined.Last loop
 807             if Is_Called (Inlined.Table (Index).Name)
 808               and then Inlined.Table (Index).Count /= 0
 809               and then not Is_Predefined_File_Name
 810                 (Unit_File_Name
 811                   (Get_Source_Unit (Inlined.Table (Index).Name)))
 812             then
 813                Error_Msg_N
 814                  ("& cannot be inlined?", Inlined.Table (Index).Name);
 815
 816                --  A warning on the first one might be sufficient ???
 817             end if;
 818          end loop;
 819
 820          Pop_Scope;
 821       end if;
 822    end Analyze_Inlined_Bodies;
 823
 824    -----------------------------
 825    -- Check_Body_For_Inlining --
 826    -----------------------------
 827
 828    procedure Check_Body_For_Inlining (N : Node_Id; P : Entity_Id) is
 829       Bname : Unit_Name_Type;
 830       E     : Entity_Id;
 831       OK    : Boolean;
 832
 833    begin
 834       if Is_Compilation_Unit (P)
 835         and then not Is_Generic_Instance (P)
 836       then
 837          Bname := Get_Body_Name (Get_Unit_Name (Unit (N)));
 838
 839          E := First_Entity (P);
 840          while Present (E) loop
 841             if Has_Pragma_Inline_Always (E)
 842               or else (Front_End_Inlining and then Has_Pragma_Inline (E))
 843             then
 844                if not Is_Loaded (Bname) then
 845                   Load_Needed_Body (N, OK);
 846
 847                   if OK then
 848
 849                      --  Check we are not trying to inline a parent whose body
 850                      --  depends on a child, when we are compiling the body of
 851                      --  the child. Otherwise we have a potential elaboration
 852                      --  circularity with inlined subprograms and with
 853                      --  Taft-Amendment types.
 854
 855                      declare
 856                         Comp        : Node_Id;      --  Body just compiled
 857                         Child_Spec  : Entity_Id;    --  Spec of main unit
 858                         Ent         : Entity_Id;    --  For iteration
 859                         With_Clause : Node_Id;      --  Context of body.
 860
 861                      begin
 862                         if Nkind (Unit (Cunit (Main_Unit))) = N_Package_Body
 863                           and then Present (Body_Entity (P))
 864                         then
 865                            Child_Spec :=
 866                              Defining_Entity
 867                                ((Unit (Library_Unit (Cunit (Main_Unit)))));
 868
 869                            Comp :=
 870                              Parent (Unit_Declaration_Node (Body_Entity (P)));
 871
 872                            --  Check whether the context of the body just
 873                            --  compiled includes a child of itself, and that
 874                            --  child is the spec of the main compilation.
 875
 876                            With_Clause := First (Context_Items (Comp));
 877                            while Present (With_Clause) loop
 878                               if Nkind (With_Clause) = N_With_Clause
 879                                 and then
 880                                   Scope (Entity (Name (With_Clause))) = P
 881                                 and then
 882                                   Entity (Name (With_Clause)) = Child_Spec
 883                               then
 884                                  Error_Msg_Node_2 := Child_Spec;
 885                                  Error_Msg_NE
 886                                    ("body of & depends on child unit&?",
 887                                       With_Clause, P);
 888                                  Error_Msg_N
 889                                    ("\subprograms in body cannot be inlined?",
 890                                       With_Clause);
 891
 892                                  --  Disable further inlining from this unit,
 893                                  --  and keep Taft-amendment types incomplete.
 894
 895                                  Ent := First_Entity (P);
 896                                  while Present (Ent) loop
 897                                     if Is_Type (Ent)
 898                                        and then Has_Completion_In_Body (Ent)
 899                                     then
 900                                        Set_Full_View (Ent, Empty);
 901
 902                                     elsif Is_Subprogram (Ent) then
 903                                        Set_Is_Inlined (Ent, False);
 904                                     end if;
 905
 906                                     Next_Entity (Ent);
 907                                  end loop;
 908
 909                                  return;
 910                               end if;
 911
 912                               Next (With_Clause);
 913                            end loop;
 914                         end if;
 915                      end;
 916
 917                   elsif Ineffective_Inline_Warnings then
 918                      Error_Msg_Unit_1 := Bname;
 919                      Error_Msg_N
 920                        ("unable to inline subprograms defined in $?", P);
 921                      Error_Msg_N ("\body not found?", P);
 922                      return;
 923                   end if;
 924                end if;
 925
 926                return;
 927             end if;
 928
 929             Next_Entity (E);
 930          end loop;
 931       end if;
 932    end Check_Body_For_Inlining;
 933
 934    --------------------
 935    -- Cleanup_Scopes --
 936    --------------------
 937
 938    procedure Cleanup_Scopes is
 939       Elmt : Elmt_Id;
 940       Decl : Node_Id;
 941       Scop : Entity_Id;
 942
 943    begin
 944       Elmt := First_Elmt (To_Clean);
 945       while Present (Elmt) loop
 946          Scop := Node (Elmt);
 947
 948          if Ekind (Scop) = E_Entry then
 949             Scop := Protected_Body_Subprogram (Scop);
 950
 951          elsif Is_Subprogram (Scop)
 952            and then Is_Protected_Type (Scope (Scop))
 953            and then Present (Protected_Body_Subprogram (Scop))
 954          then
 955             --  If a protected operation contains an instance, its
 956             --  cleanup operations have been delayed, and the subprogram
 957             --  has been rewritten in the expansion of the enclosing
 958             --  protected body. It is the corresponding subprogram that
 959             --  may require the cleanup operations, so propagate the
 960             --  information that triggers cleanup activity.
 961
 962             Set_Uses_Sec_Stack
 963               (Protected_Body_Subprogram (Scop),
 964                 Uses_Sec_Stack (Scop));
 965
 966             Scop := Protected_Body_Subprogram (Scop);
 967          end if;
 968
 969          if Ekind (Scop) = E_Block then
 970             Decl := Parent (Block_Node (Scop));
 971
 972          else
 973             Decl := Unit_Declaration_Node (Scop);
 974
 975             if Nkind (Decl) = N_Subprogram_Declaration
 976               or else Nkind (Decl) = N_Task_Type_Declaration
 977               or else Nkind (Decl) = N_Subprogram_Body_Stub
 978             then
 979                Decl := Unit_Declaration_Node (Corresponding_Body (Decl));
 980             end if;
 981          end if;
 982
 983          Push_Scope (Scop);
 984          Expand_Cleanup_Actions (Decl);
 985          End_Scope;
 986
 987          Elmt := Next_Elmt (Elmt);
 988       end loop;
 989    end Cleanup_Scopes;
 990
 991    --------------------------
 992    -- Get_Code_Unit_Entity --
 993    --------------------------
 994
 995    function Get_Code_Unit_Entity (E : Entity_Id) return Entity_Id is
 996    begin
 997       return Cunit_Entity (Get_Code_Unit (E));
 998    end Get_Code_Unit_Entity;
 999
1000    --------------------------
1001    -- Has_Initialized_Type --
1002    --------------------------
1003
1004    function Has_Initialized_Type (E : Entity_Id) return Boolean is
1005       E_Body : constant Node_Id := Get_Subprogram_Body (E);
1006       Decl   : Node_Id;
1007
1008    begin
1009       if No (E_Body) then        --  imported subprogram
1010          return False;
1011
1012       else
1013          Decl := First (Declarations (E_Body));
1014          while Present (Decl) loop
1015
1016             if Nkind (Decl) = N_Full_Type_Declaration
1017               and then Present (Init_Proc (Defining_Identifier (Decl)))
1018             then
1019                return True;
1020             end if;
1021
1022             Next (Decl);
1023          end loop;
1024       end if;
1025
1026       return False;
1027    end Has_Initialized_Type;
1028
1029    ----------------
1030    -- Initialize --
1031    ----------------
1032
1033    procedure Initialize is
1034    begin
1035       Analyzing_Inlined_Bodies := False;
1036       Pending_Descriptor.Init;
1037       Pending_Instantiations.Init;
1038       Inlined_Bodies.Init;
1039       Successors.Init;
1040       Inlined.Init;
1041
1042       for J in Hash_Headers'Range loop
1043          Hash_Headers (J) := No_Subp;
1044       end loop;
1045    end Initialize;
1046
1047    ------------------------
1048    -- Instantiate_Bodies --
1049    ------------------------
1050
1051    --  Generic bodies contain all the non-local references, so an
1052    --  instantiation does not need any more context than Standard
1053    --  itself, even if the instantiation appears in an inner scope.
1054    --  Generic associations have verified that the contract model is
1055    --  satisfied, so that any error that may occur in the analysis of
1056    --  the body is an internal error.
1057
1058    procedure Instantiate_Bodies is
1059       J    : Int;
1060       Info : Pending_Body_Info;
1061
1062    begin
1063       if Serious_Errors_Detected = 0 then
1064
1065          Expander_Active := (Operating_Mode = Opt.Generate_Code);
1066          Push_Scope (Standard_Standard);
1067          To_Clean := New_Elmt_List;
1068
1069          if Is_Generic_Unit (Cunit_Entity (Main_Unit)) then
1070             Start_Generic;
1071          end if;
1072
1073          --  A body instantiation may generate additional instantiations, so
1074          --  the following loop must scan to the end of a possibly expanding
1075          --  set (that's why we can't simply use a FOR loop here).
1076
1077          J := 0;
1078          while J <= Pending_Instantiations.Last
1079            and then Serious_Errors_Detected = 0
1080          loop
1081             Info := Pending_Instantiations.Table (J);
1082
1083             --  If the instantiation node is absent, it has been removed
1084             --  as part of unreachable code.
1085
1086             if No (Info.Inst_Node) then
1087                null;
1088
1089             elsif Nkind (Info.Act_Decl) = N_Package_Declaration then
1090                Instantiate_Package_Body (Info);
1091                Add_Scope_To_Clean (Defining_Entity (Info.Act_Decl));
1092
1093             else
1094                Instantiate_Subprogram_Body (Info);
1095             end if;
1096
1097             J := J + 1;
1098          end loop;
1099
1100          --  Reset the table of instantiations. Additional instantiations
1101          --  may be added through inlining, when additional bodies are
1102          --  analyzed.
1103
1104          Pending_Instantiations.Init;
1105
1106          --  We can now complete the cleanup actions of scopes that contain
1107          --  pending instantiations (skipped for generic units, since we
1108          --  never need any cleanups in generic units).
1109          --  pending instantiations.
1110
1111          if Expander_Active
1112            and then not Is_Generic_Unit (Main_Unit_Entity)
1113          then
1114             Cleanup_Scopes;
1115          elsif Is_Generic_Unit (Cunit_Entity (Main_Unit)) then
1116             End_Generic;
1117          end if;
1118
1119          Pop_Scope;
1120       end if;
1121    end Instantiate_Bodies;
1122
1123    ---------------
1124    -- Is_Nested --
1125    ---------------
1126
1127    function Is_Nested (E : Entity_Id) return Boolean is
1128       Scop : Entity_Id;
1129
1130    begin
1131       Scop := Scope (E);
1132       while Scop /= Standard_Standard loop
1133          if Ekind (Scop) in Subprogram_Kind then
1134             return True;
1135
1136          elsif Ekind (Scop) = E_Task_Type
1137            or else Ekind (Scop) = E_Entry
1138            or else Ekind (Scop) = E_Entry_Family then
1139             return True;
1140          end if;
1141
1142          Scop := Scope (Scop);
1143       end loop;
1144
1145       return False;
1146    end Is_Nested;
1147
1148    ----------
1149    -- Lock --
1150    ----------
1151
1152    procedure Lock is
1153    begin
1154       Pending_Instantiations.Locked := True;
1155       Inlined_Bodies.Locked := True;
1156       Successors.Locked := True;
1157       Inlined.Locked := True;
1158       Pending_Instantiations.Release;
1159       Inlined_Bodies.Release;
1160       Successors.Release;
1161       Inlined.Release;
1162    end Lock;
1163
1164    --------------------------
1165    -- Remove_Dead_Instance --
1166    --------------------------
1167
1168    procedure Remove_Dead_Instance (N : Node_Id) is
1169       J : Int;
1170
1171    begin
1172       J := 0;
1173       while J <= Pending_Instantiations.Last loop
1174          if Pending_Instantiations.Table (J).Inst_Node = N then
1175             Pending_Instantiations.Table (J).Inst_Node := Empty;
1176             return;
1177          end if;
1178
1179          J := J + 1;
1180       end loop;
1181    end Remove_Dead_Instance;
1182
1183    ------------------------
1184    -- Scope_In_Main_Unit --
1185    ------------------------
1186
1187    function Scope_In_Main_Unit (Scop : Entity_Id) return Boolean is
1188       Comp : constant Node_Id := Cunit (Get_Code_Unit (Scop));
1189
1190    begin
1191       --  Check whether the scope of the subprogram to inline is within the
1192       --  main unit or within its spec. In either case there are no additional
1193       --  bodies to process. If the subprogram appears in a parent of the
1194       --  current unit, the check on whether inlining is possible is done in
1195       --  Analyze_Inlined_Bodies.
1196
1197       return
1198         Comp = Cunit (Main_Unit)
1199           or else Comp = Library_Unit (Cunit (Main_Unit));
1200    end Scope_In_Main_Unit;
1201
1202 end Inline;