gcc/ada/i-cstrea.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                 I N T E R F A C E S . C _ S T R E A M S                  --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1995-2003 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package is a thin binding to selected functions in the C
  35 --  library that provide a complete interface for handling C streams.
  36
  37 with System.CRTL;
  38
  39 package Interfaces.C_Streams is
  40    pragma Preelaborate;
  41
  42    subtype chars is System.CRTL.chars;
  43    subtype FILEs is System.CRTL.FILEs;
  44    subtype int is System.CRTL.int;
  45    subtype long is System.CRTL.long;
  46    subtype size_t is System.CRTL.size_t;
  47    subtype voids is System.Address;
  48
  49    NULL_Stream : constant FILEs;
  50    --  Value returned (NULL in C) to indicate an fdopen/fopen/tmpfile error
  51
  52    ----------------------------------
  53    -- Constants Defined in stdio.h --
  54    ----------------------------------
  55
  56    EOF : constant int;
  57    --  Used by a number of routines to indicate error or end of file
  58
  59    IOFBF : constant int;
  60    IOLBF : constant int;
  61    IONBF : constant int;
  62    --  Used to indicate buffering mode for setvbuf call
  63
  64    L_tmpnam : constant int;
  65    --  Maximum length of file name that can be returned by tmpnam
  66
  67    SEEK_CUR : constant int;
  68    SEEK_END : constant int;
  69    SEEK_SET : constant int;
  70    --  Used to indicate origin for fseek call
  71
  72    function stdin  return FILEs;
  73    function stdout return FILEs;
  74    function stderr return FILEs;
  75    --  Streams associated with standard files
  76
  77    --------------------------
  78    -- Standard C functions --
  79    --------------------------
  80
  81    --  The functions selected below are ones that are available in DOS,
  82    --  OS/2, UNIX and Xenix (but not necessarily in ANSI C). These are
  83    --  very thin interfaces which copy exactly the C headers. For more
  84    --  documentation on these functions, see the Microsoft C "Run-Time
  85    --  Library Reference" (Microsoft Press, 1990, ISBN 1-55615-225-6),
  86    --  which includes useful information on system compatibility.
  87
  88    procedure clearerr (stream : FILEs) renames System.CRTL.clearerr;
  89
  90    function fclose (stream : FILEs) return int renames System.CRTL.fclose;
  91
  92    function fdopen (handle : int; mode : chars) return FILEs
  93      renames System.CRTL.fdopen;
  94
  95    function feof (stream : FILEs) return int;
  96
  97    function ferror (stream : FILEs) return int;
  98
  99    function fflush (stream : FILEs) return int renames System.CRTL.fflush;
 100
 101    function fgetc (stream : FILEs) return int renames System.CRTL.fgetc;
 102
 103    function fgets (strng : chars; n : int; stream : FILEs) return chars
 104      renames System.CRTL.fgets;
 105
 106    function fileno (stream : FILEs) return int;
 107
 108    function fopen (filename : chars; Mode : chars) return FILEs
 109      renames System.CRTL.fopen;
 110    --  Note: to maintain target independence, use text_translation_required,
 111    --  a boolean variable defined in a-sysdep.c to deal with the target
 112    --  dependent text translation requirement. If this variable is set,
 113    --  then b/t should be appended to the standard mode argument to set
 114    --  the text translation mode off or on as required.
 115
 116    function fputc (C : int; stream : FILEs) return int
 117      renames System.CRTL.fputc;
 118
 119    function fputs (Strng : chars; Stream : FILEs) return int
 120      renames System.CRTL.fputs;
 121
 122    function fread
 123      (buffer : voids;
 124       size   : size_t;
 125       count  : size_t;
 126       stream : FILEs)
 127       return   size_t;
 128
 129    function fread
 130      (buffer : voids;
 131       index  : size_t;
 132       size   : size_t;
 133       count  : size_t;
 134       stream : FILEs)
 135       return   size_t;
 136    --  Same as normal fread, but has a parameter 'index' that indicates
 137    --  the starting index for the read within 'buffer' (which must be the
 138    --  address of the beginning of a whole array object with an assumed
 139    --  zero base). This is needed for systems that do not support taking
 140    --  the address of an element within an array.
 141
 142    function freopen
 143      (filename : chars;
 144       mode     : chars;
 145       stream   : FILEs)
 146       return     FILEs renames System.CRTL.freopen;
 147
 148    function fseek
 149      (stream : FILEs;
 150       offset : long;
 151       origin : int)
 152       return   int renames System.CRTL.fseek;
 153
 154    function ftell (stream : FILEs) return long
 155      renames System.CRTL.ftell;
 156
 157    function fwrite
 158      (buffer : voids;
 159       size   : size_t;
 160       count  : size_t;
 161       stream : FILEs)
 162       return   size_t;
 163
 164    function isatty (handle : int) return int renames System.CRTL.isatty;
 165
 166    procedure mktemp (template : chars) renames System.CRTL.mktemp;
 167    --  The return value (which is just a pointer to template) is discarded
 168
 169    procedure rewind (stream : FILEs) renames System.CRTL.rewind;
 170
 171    function setvbuf
 172      (stream : FILEs;
 173       buffer : chars;
 174       mode   : int;
 175       size   : size_t)
 176       return   int;
 177
 178    procedure tmpnam (string : chars) renames System.CRTL.tmpnam;
 179    --  The parameter must be a pointer to a string buffer of at least L_tmpnam
 180    --  bytes (the call with a null parameter is not supported). The returned
 181    --  value, which is just a copy of the input argument, is discarded.
 182
 183    function tmpfile return FILEs renames System.CRTL.tmpfile;
 184
 185    function ungetc (c : int; stream : FILEs) return int
 186      renames System.CRTL.ungetc;
 187
 188    function unlink (filename : chars) return int
 189      renames System.CRTL.unlink;
 190
 191    ---------------------
 192    -- Extra functions --
 193    ---------------------
 194
 195    --  These functions supply slightly thicker bindings than those above.
 196    --  They are derived from functions in the C Run-Time Library, but may
 197    --  do a bit more work than just directly calling one of the Library
 198    --  functions.
 199
 200    function file_exists (name : chars) return int;
 201    --  Tests if given name corresponds to an existing file.
 202
 203    function is_regular_file (handle : int) return int;
 204    --  Tests if given handle is for a regular file (result 1) or for
 205    --  a non-regular file (pipe or device, result 0).
 206
 207    ---------------------------------
 208    -- Control of Text/Binary Mode --
 209    ---------------------------------
 210
 211    --  If text_translation_required is true, then the following functions may
 212    --  be used to dynamically switch a file from binary to text mode or vice
 213    --  versa. These functions have no effect if text_translation_required is
 214    --  false (i.e. in normal unix mode). Use fileno to get a stream handle.
 215
 216    procedure set_binary_mode (handle : int);
 217    procedure set_text_mode   (handle : int);
 218
 219    ----------------------------
 220    -- Full Path Name support --
 221    ----------------------------
 222
 223    procedure full_name (nam : chars; buffer : chars);
 224    --  Given a NUL terminated string representing a file name, returns in
 225    --  buffer a NUL terminated string representing the full path name for
 226    --  the file name. On systems where it is relevant the drive is also part
 227    --  of the full path name. It is the responsibility of the caller to
 228    --  pass an actual parameter for buffer that is big enough for any full
 229    --  path name. Use max_path_len given below as the size of buffer.
 230
 231    max_path_len : Integer;
 232    --  Maximum length of an allowable full path name on the system,
 233    --  including a terminating NUL character.
 234
 235 private
 236    --  The following functions are specialized in the body depending on the
 237    --  operating system.
 238
 239    pragma Inline (fread);
 240    pragma Inline (fwrite);
 241    pragma Inline (setvbuf);
 242
 243    pragma Import (C, file_exists, "__gnat_file_exists");
 244    pragma Import (C, is_regular_file, "__gnat_is_regular_file_fd");
 245
 246    pragma Import (C, set_binary_mode, "__gnat_set_binary_mode");
 247    pragma Import (C, set_text_mode, "__gnat_set_text_mode");
 248
 249    pragma Import (C, max_path_len, "__gnat_max_path_len");
 250    pragma Import (C, full_name, "__gnat_full_name");
 251
 252    --  The following may be implemented as macros, and so are supported
 253    --  via an interface function in the a-cstrea.c file.
 254
 255    pragma Import (C, feof,   "__gnat_feof");
 256    pragma Import (C, ferror, "__gnat_ferror");
 257    pragma Import (C, fileno, "__gnat_fileno");
 258
 259    pragma Import (C, EOF, "__gnat_constant_eof");
 260    pragma Import (C, IOFBF, "__gnat_constant_iofbf");
 261    pragma Import (C, IOLBF, "__gnat_constant_iolbf");
 262    pragma Import (C, IONBF, "__gnat_constant_ionbf");
 263    pragma Import (C, SEEK_CUR, "__gnat_constant_seek_cur");
 264    pragma Import (C, SEEK_END, "__gnat_constant_seek_end");
 265    pragma Import (C, SEEK_SET, "__gnat_constant_seek_set");
 266    pragma Import (C, L_tmpnam, "__gnat_constant_l_tmpnam");
 267
 268    pragma Import (C, stderr, "__gnat_constant_stderr");
 269    pragma Import (C, stdin,  "__gnat_constant_stdin");
 270    pragma Import (C, stdout, "__gnat_constant_stdout");
 271
 272    NULL_Stream : constant FILEs := System.Null_Address;
 273
 274 end Interfaces.C_Streams;