gcc/ada/g-spitbo.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                         G N A T . S P I T B O L                          --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --           Copyright (C) 1997-1999 Ada Core Technologies, Inc.            --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT is maintained by Ada Core Technologies Inc (http://www.gnat.com).   --
  30 --                                                                          --
  31 ------------------------------------------------------------------------------
  32
  33 --  SPITBOL-like interface facilities
  34
  35 --  This package provides a set of interfaces to semantic operations copied
  36 --  from SPITBOL, including a complete implementation of SPITBOL pattern
  37 --  matching. The code is derived from the original SPITBOL MINIMAL sources,
  38 --  created by Robert Dewar. The translation is not exact, but the
  39 --  algorithmic approaches are similar.
  40
  41 with Ada.Finalization;      use Ada.Finalization;
  42 with Ada.Strings.Unbounded; use Ada.Strings.Unbounded;
  43 with Interfaces;            use Interfaces;
  44
  45 package GNAT.Spitbol is
  46 pragma Preelaborate (Spitbol);
  47
  48    --  The Spitbol package relies heavily on the Unbounded_String package,
  49    --  using the synonym VString for variable length string. The following
  50    --  declarations define this type and other useful abbreviations.
  51
  52    subtype VString is Ada.Strings.Unbounded.Unbounded_String;
  53
  54    function V (Source : String) return VString
  55      renames Ada.Strings.Unbounded.To_Unbounded_String;
  56
  57    function S (Source : VString) return String
  58      renames Ada.Strings.Unbounded.To_String;
  59
  60    Nul : VString renames Ada.Strings.Unbounded.Null_Unbounded_String;
  61
  62    -------------------------
  63    -- Facilities Provided --
  64    -------------------------
  65
  66    --  The SPITBOL support in GNAT consists of this package together with
  67    --  several child packages. In this package, we have first a set of
  68    --  useful string functions, copied exactly from the corresponding
  69    --  SPITBOL functions, except that we had to rename REVERSE because
  70    --  reverse is a reserved word (it is now Reverse_String).
  71
  72    --  The second element of the parent package is a generic implementation
  73    --  of a table facility. In SPITBOL, the TABLE function allows general
  74    --  mappings from any datatype to any other datatype, and of course, as
  75    --  always, we can freely mix multiple types in the same table.
  76
  77    --  The Ada version of tables is strongly typed, so the indexing type and
  78    --  the range type are always of a consistent type. In this implementation
  79    --  we only provide VString as an indexing type, since this is by far the
  80    --  most common case. The generic instantiation specifies the range type
  81    --  to be used.
  82
  83    --  Three child packages provide standard instantiations of this table
  84    --  package for three common datatypes:
  85
  86    --    GNAT.Spitbol.Table_Boolean     (file g-sptabo.ads)
  87
  88    --      The range type is Boolean. The default value is False. This
  89    --      means that this table is essentially a representation of a set.
  90
  91    --    GNAT.Spitbol.Table_Integer     (file g-sptain.ads)
  92
  93    --      The range type is Integer. The default value is Integer'First.
  94    --      This provides a general mapping from strings to integers.
  95
  96    --    GNAT.Spitbol.Table_VString     (file g-sptavs.ads)
  97
  98    --      The range type is VString. The default value is the null string.
  99    --      This provides a general mapping from strings to strings.
 100
 101    --  Finally there is another child package:
 102
 103    --    GNAT.Spitbol.Patterns          (file g-spipat.ads)
 104
 105    --       This child package provides a complete implementation of SPITBOL
 106    --       pattern matching. The spec contains a complete tutorial on the
 107    --       use of pattern matching.
 108
 109    ---------------------------------
 110    -- Standard String Subprograms --
 111    ---------------------------------
 112
 113    --  This section contains some operations on unbounded strings that are
 114    --  closely related to those in the package Unbounded.Strings, but they
 115    --  correspond to the SPITBOL semantics for these operations.
 116
 117    function Char (Num : Natural) return Character;
 118    pragma Inline (Char);
 119    --  Equivalent to Character'Val (Num)
 120
 121    function Lpad
 122      (Str  : VString;
 123       Len  : Natural;
 124       Pad  : Character := ' ')
 125       return VString;
 126    function Lpad
 127      (Str  : String;
 128       Len  : Natural;
 129       Pad  : Character := ' ')
 130       return VString;
 131    --  If the length of Str is greater than or equal to Len, then Str is
 132    --  returned unchanged. Otherwise, The value returned is obtained by
 133    --  concatenating Length (Str) - Len instances of the Pad character to
 134    --  the left hand side.
 135
 136    procedure Lpad
 137      (Str  : in out VString;
 138       Len  : Natural;
 139       Pad  : Character := ' ');
 140    --  The procedure form is identical to the function form, except that
 141    --  the result overwrites the input argument Str.
 142
 143    function Reverse_String (Str : VString) return VString;
 144    function Reverse_String (Str : String)  return VString;
 145    --  Returns result of reversing the string Str, i.e. the result returned
 146    --  is a mirror image (end-for-end reversal) of the input string.
 147
 148    procedure Reverse_String (Str : in out VString);
 149    --  The procedure form is identical to the function form, except that the
 150    --  result overwrites the input argument Str.
 151
 152    function Rpad
 153      (Str  : VString;
 154       Len  : Natural;
 155       Pad  : Character := ' ')
 156       return VString;
 157    function Rpad
 158      (Str  : String;
 159       Len  : Natural;
 160       Pad  : Character := ' ')
 161       return VString;
 162    --  If the length of Str is greater than or equal to Len, then Str is
 163    --  returned unchanged. Otherwise, The value returned is obtained by
 164    --  concatenating Length (Str) - Len instances of the Pad character to
 165    --  the right hand side.
 166
 167    procedure Rpad
 168      (Str  : in out VString;
 169       Len  : Natural;
 170       Pad  : Character := ' ');
 171    --  The procedure form is identical to the function form, except that the
 172    --  result overwrites the input argument Str.
 173
 174    function Size (Source : VString) return Natural
 175      renames Ada.Strings.Unbounded.Length;
 176
 177    function Substr
 178      (Str   : VString;
 179       Start : Positive;
 180       Len   : Natural)
 181       return  VString;
 182    function Substr
 183      (Str   : String;
 184       Start : Positive;
 185       Len   : Natural)
 186       return  VString;
 187    --  Returns the substring starting at the given character position (which
 188    --  is always counted from the start of the string, regardless of bounds,
 189    --  e.g. 2 means starting with the second character of the string), and
 190    --  with the length (Len) given. Indexing_Error is raised if the starting
 191    --  position is out of range, and Length_Error is raised if Len is too long.
 192
 193    function Trim (Str : VString) return VString;
 194    function Trim (Str : String)  return VString;
 195    --  Returns the string obtained by removing all spaces from the right
 196    --  hand side of the string Str.
 197
 198    procedure Trim (Str : in out VString);
 199    --  The procedure form is identical to the function form, except that the
 200    --  result overwrites the input argument Str.
 201
 202    -----------------------
 203    -- Utility Functions --
 204    -----------------------
 205
 206    --  In SPITBOL, integer values can be freely treated as strings. The
 207    --  following definitions help provide some of this capability in
 208    --  some common cases.
 209
 210    function "&" (Num : Integer; Str : String)  return String;
 211    function "&" (Str : String;  Num : Integer) return String;
 212    function "&" (Num : Integer; Str : VString) return VString;
 213    function "&" (Str : VString; Num : Integer) return VString;
 214    --  In all these concatenation operations, the integer is converted to
 215    --  its corresponding decimal string form, with no leading blank.
 216
 217    function S (Num : Integer) return String;
 218    function V (Num : Integer) return VString;
 219    --  These operators return the given integer converted to its decimal
 220    --  string form with no leading blank.
 221
 222    function N (Str : VString) return Integer;
 223    --  Converts string to number (same as Integer'Value (S (Str)))
 224
 225    -------------------
 226    -- Table Support --
 227    -------------------
 228
 229    --  So far, we only provide support for tables whose indexing data values
 230    --  are strings (or unbounded strings). The values stored may be of any
 231    --  type, as supplied by the generic formal parameter.
 232
 233    generic
 234
 235       type Value_Type is private;
 236       --  Any non-limited type can be used as the value type in the table
 237
 238       Null_Value : Value_Type;
 239       --  Value used to represent a value that is not present in the table.
 240
 241       with function Img (A : Value_Type) return String;
 242       --  Used to provide image of value in Dump procedure
 243
 244       with function "=" (A, B : Value_Type) return Boolean is <>;
 245       --  This allows a user-defined equality function to override the
 246       --  predefined equality function.
 247
 248    package Table is
 249
 250       ------------------------
 251       -- Table Declarations --
 252       ------------------------
 253
 254       type Table (N : Unsigned_32) is private;
 255       --  This is the table type itself. A table is a mapping from string
 256       --  values to values of Value_Type. The discriminant is an estimate of
 257       --  the number of values in the table. If the estimate is much too
 258       --  high, some space is wasted, if the estimate is too low, access to
 259       --  table elements is slowed down. The type Table has copy semantics,
 260       --  not reference semantics. This means that if a table is copied
 261       --  using simple assignment, then the two copies refer to entirely
 262       --  separate tables.
 263
 264       -----------------------------
 265       -- Table Access Operations --
 266       -----------------------------
 267
 268       function Get (T : Table; Name : VString)   return Value_Type;
 269       function Get (T : Table; Name : Character) return Value_Type;
 270       pragma Inline (Get);
 271       function Get (T : Table; Name : String)    return Value_Type;
 272
 273       --  If an entry with the given name exists in the table, then the
 274       --  corresponding Value_Type value is returned. Otherwise Null_Value
 275       --  is returned.
 276
 277       function Present (T : Table; Name : VString)   return Boolean;
 278       function Present (T : Table; Name : Character) return Boolean;
 279       pragma Inline (Present);
 280       function Present (T : Table; Name : String)    return Boolean;
 281       --  Determines if an entry with the given name is present in the table.
 282       --  A returned value of True means that it is in the table, otherwise
 283       --  False indicates that it is not in the table.
 284
 285       procedure Delete (T : in out Table; Name : VString);
 286       procedure Delete (T : in out Table; Name : Character);
 287       pragma Inline (Delete);
 288       procedure Delete (T : in out Table; Name : String);
 289       --  Deletes the table element with the given name from the table. If
 290       --  no element in the table has this name, then the call has no effect.
 291
 292       procedure Set (T : in out Table; Name  : VString;   Value : Value_Type);
 293       procedure Set (T : in out Table; Name  : Character; Value : Value_Type);
 294       pragma Inline (Set);
 295       procedure Set (T : in out Table; Name  : String;    Value : Value_Type);
 296       --  Sets the value of the element with the given name to the given
 297       --  value. If Value is equal to Null_Value, the effect is to remove
 298       --  the entry from the table. If no element with the given name is
 299       --  currently in the table, then a new element with the given value
 300       --  is created.
 301
 302       ----------------------------
 303       -- Allocation and Copying --
 304       ----------------------------
 305
 306       --  Table is a controlled type, so that all storage associated with
 307       --  tables is properly reclaimed when a Table value is abandoned.
 308       --  Tables have value semantics rather than reference semantics as
 309       --  in Spitbol, i.e. when you assign a copy you end up with two
 310       --  distinct copies of the table, as though COPY had been used in
 311       --  Spitbol. It seems clearly more appropriate in Ada to require
 312       --  the use of explicit pointers for reference semantics.
 313
 314       procedure Clear (T : in out Table);
 315       --  Clears all the elements of the given table, freeing associated
 316       --  storage. On return T is an empty table with no elements.
 317
 318       procedure Copy (From : in Table; To : in out Table);
 319       --  First all the elements of table To are cleared (as described for
 320       --  the Clear procedure above), then all the elements of table From
 321       --  are copied into To. In the case where the tables From and To have
 322       --  the same declared size (i.e. the same discriminant), the call to
 323       --  Copy has the same effect as the assignment of From to To. The
 324       --  difference is that, unlike the assignment statement, which will
 325       --  cause a Constraint_Error if the source and target are of different
 326       --  sizes, Copy works fine with different sized tables.
 327
 328       ----------------
 329       -- Conversion --
 330       ----------------
 331
 332       type Table_Entry is record
 333          Name  : VString;
 334          Value : Value_Type;
 335       end record;
 336
 337       type Table_Array is array (Positive range <>) of Table_Entry;
 338
 339       function Convert_To_Array (T : Table) return Table_Array;
 340       --  Returns a Table_Array value with a low bound of 1, and a length
 341       --  corresponding to the number of elements in the table. The elements
 342       --  of the array give the elements of the table in unsorted order.
 343
 344       ---------------
 345       -- Debugging --
 346       ---------------
 347
 348       procedure Dump (T : Table; Str : String := "Table");
 349       --  Dump contents of given table to the standard output file. The
 350       --  string value Str is used as the name of the table in the dump.
 351
 352       procedure Dump (T : Table_Array; Str : String := "Table_Array");
 353       --  Dump contents of given table array to the current output file. The
 354       --  string value Str is used as the name of the table array in the dump.
 355
 356    private
 357
 358       ------------------
 359       -- Private Part --
 360       ------------------
 361
 362       --  A Table is a pointer to a hash table which contains the indicated
 363       --  number of hash elements (the number is forced to the next odd value
 364       --  if it is even to improve hashing performance). If more than one
 365       --  of the entries in a table hashes to the same slot, the Next field
 366       --  is used to chain entries from the header. The chains are not kept
 367       --  ordered. A chain is terminated by a null pointer in Next. An unused
 368       --  chain is marked by an element whose Name is null and whose value
 369       --  is Null_Value.
 370
 371       type Hash_Element;
 372       type Hash_Element_Ptr is access all Hash_Element;
 373
 374       type Hash_Element is record
 375          Name  : String_Access    := null;
 376          Value : Value_Type       := Null_Value;
 377          Next  : Hash_Element_Ptr := null;
 378       end record;
 379
 380       type Hash_Table is
 381         array (Unsigned_32 range <>) of aliased Hash_Element;
 382
 383       type Table (N : Unsigned_32) is new Controlled with record
 384          Elmts : Hash_Table (1 .. N);
 385       end record;
 386
 387       pragma Finalize_Storage_Only (Table);
 388
 389       procedure Adjust (Object : in out Table);
 390       --  The Adjust procedure does a deep copy of the table structure
 391       --  so that the effect of assignment is, like other assignments
 392       --  in Ada, value-oriented.
 393
 394       procedure Finalize (Object : in out Table);
 395       --  This is the finalization routine that ensures that all storage
 396       --  associated with a table is properly released when a table object
 397       --  is abandoned and finalized.
 398
 399    end Table;
 400
 401 end GNAT.Spitbol;