gcc/ada/g-debuti.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                 G N A T . D E B U G _ U T I L I T I E S                  --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.3 $                              --
  10 --                                                                          --
  11 --           Copyright (C) 1997-1998 Ada Core Technologies, Inc.            --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNAT is maintained by Ada Core Technologies Inc (http://www.gnat.com).   --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 with System;                  use System;
  36 with System.Storage_Elements; use System.Storage_Elements;
  37
  38 package body GNAT.Debug_Utilities is
  39
  40    --------------------------
  41    -- Image (address case) --
  42    --------------------------
  43
  44    function Image (A : Address) return String is
  45       S : String (1 .. Address_Image_Length);
  46       P : Natural := S'Last - 1;
  47       N : Integer_Address := To_Integer (A);
  48       U : Natural := 0;
  49
  50       H : array (Integer range 0 .. 15) of Character := "0123456789ABCDEF";
  51
  52    begin
  53       S (S'Last) := '#';
  54
  55       while P > 3 loop
  56          if U = 4 then
  57             S (P) := '_';
  58             P := P - 1;
  59             U := 1;
  60
  61          else
  62             U := U + 1;
  63          end if;
  64
  65          S (P) := H (Integer (N mod 16));
  66          P := P - 1;
  67          N := N / 16;
  68       end loop;
  69
  70       S (1 .. 3) := "16#";
  71       return S;
  72    end Image;
  73
  74    -------------------------
  75    -- Image (string case) --
  76    -------------------------
  77
  78    function Image (S : String) return String is
  79       W : String (1 .. 2 * S'Length + 2);
  80       P : Positive := 1;
  81
  82    begin
  83       W (1) := '"';
  84
  85       for J in S'Range loop
  86          if S (J) = '"' then
  87             P := P + 1;
  88             W (P) := '"';
  89          end if;
  90
  91          P := P + 1;
  92          W (P) := S (J);
  93       end loop;
  94
  95       P := P + 1;
  96       W (P) := '"';
  97       return W (1 .. P);
  98    end Image;
  99
 100    -----------
 101    -- Value --
 102    -----------
 103
 104    function Value (S : String) return System.Address is
 105       N : constant Integer_Address := Integer_Address'Value (S);
 106
 107    begin
 108       return To_Address (N);
 109    end Value;
 110
 111 end GNAT.Debug_Utilities;