gcc/ada/g-crc32.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                           G N A T . C R C 3 2                            --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 2004-2005, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package provides routines for computing a commonly used checksum
  35 --  called CRC-32. This is a checksum based on treating the binary data
  36 --  as a polynomial over a binary field, and the exact specifications of
  37 --  the CRC-32 algorithm are as follows:
  38
  39 --     Name   : "CRC-32"
  40 --     Width  : 32
  41 --     Poly   : 04C11DB7
  42 --     Init   : FFFFFFFF
  43 --     RefIn  : True
  44 --     RefOut : True
  45 --     XorOut : FFFFFFFF
  46 --     Check  : CBF43926
  47
  48 --  Note that this is the algorithm used by PKZip, Ethernet and FDDI
  49
  50 --  For more information about this algorithm see:
  51
  52 --    ftp://ftp.rocksoft.com/papers/crc_v3.txt
  53
  54 --  "A Painless Guide to CRC Error Detection Algorithms", Ross N. Williams
  55
  56 --  "Computation of Cyclic Redundancy Checks via Table Look-Up", Communications
  57 --  of the ACM, Vol. 31 No. 8, pp.1008-1013 Aug. 1988. Sarwate, D.V.
  58
  59 with Ada.Streams;
  60 with Interfaces;
  61 with System.CRC32;
  62
  63 package GNAT.CRC32 is
  64
  65    subtype CRC32 is System.CRC32.CRC32;
  66    --  Used to represent CRC32 values, which are 32 bit bit-strings
  67
  68    procedure Initialize (C : out CRC32)
  69      renames System.CRC32.Initialize;
  70    --  Initialize CRC value by assigning the standard Init value (16#FFFF_FFFF)
  71
  72    procedure Update
  73      (C     : in out CRC32;
  74       Value : Character)
  75      renames System.CRC32.Update;
  76    --  Evolve CRC by including the contribution from Character'Pos (Value)
  77
  78    procedure Update
  79      (C     : in out CRC32;
  80       Value : String);
  81    --  For each character in the Value string call above routine
  82
  83    procedure Wide_Update
  84      (C     : in out CRC32;
  85       Value : Wide_Character);
  86    --  Evolve CRC by including the contribution from Wide_Character'Pos (Value)
  87    --  with the bytes being included in the natural memory order.
  88
  89    procedure Wide_Update
  90      (C     : in out CRC32;
  91       Value : Wide_String);
  92    --  For each character in the Value string call above routine
  93
  94    procedure Update
  95      (C     : in out CRC32;
  96       Value : Ada.Streams.Stream_Element);
  97    --  Evolve CRC by including the contribution from Value
  98
  99    procedure Update
 100      (C     : in out CRC32;
 101       Value : Ada.Streams.Stream_Element_Array);
 102    --  For each element in the Value array call above routine
 103
 104    function Get_Value (C : CRC32) return Interfaces.Unsigned_32
 105      renames System.CRC32.Get_Value;
 106    --  Get_Value computes the CRC32 value by performing an XOR with the
 107    --  standard XorOut value (16#FFFF_FFFF). Note that this does not
 108    --  change the value of C, so it may be used to retrieve intermediate
 109    --  values of the CRC32 value during a sequence of Update calls.
 110
 111    pragma Inline (Update);
 112    pragma Inline (Wide_Update);
 113 end GNAT.CRC32;