gcc/ada/frontend.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             F R O N T E N D                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with System.Strings; use System.Strings;
  28
  29 with Atree;    use Atree;
  30 with Checks;
  31 with CStand;
  32 with Debug;    use Debug;
  33 with Elists;
  34 with Exp_Dbug;
  35 with Fmap;
  36 with Fname.UF;
  37 with Inline;   use Inline;
  38 with Lib;      use Lib;
  39 with Lib.Load; use Lib.Load;
  40 with Live;     use Live;
  41 with Namet;    use Namet;
  42 with Nlists;   use Nlists;
  43 with Opt;      use Opt;
  44 with Osint;
  45 with Par;
  46 with Prepcomp;
  47 with Rtsfind;
  48 with Sprint;
  49 with Scn;      use Scn;
  50 with Sem;      use Sem;
  51 with Sem_Ch8;  use Sem_Ch8;
  52 with Sem_Elab; use Sem_Elab;
  53 with Sem_Prag; use Sem_Prag;
  54 with Sem_Warn; use Sem_Warn;
  55 with Sinfo;    use Sinfo;
  56 with Sinput;   use Sinput;
  57 with Sinput.L; use Sinput.L;
  58 with Targparm; use Targparm;
  59 with Tbuild;   use Tbuild;
  60 with Types;    use Types;
  61
  62 procedure Frontend is
  63       Config_Pragmas : List_Id;
  64       --  Gather configuration pragmas
  65
  66 begin
  67    --  Carry out package initializations. These are initializations which
  68    --  might logically be performed at elaboration time, were it not for
  69    --  the fact that we may be doing things more than once in the big loop
  70    --  over files. Like elaboration, the order in which these calls are
  71    --  made is in some cases important. For example, Lib cannot be
  72    --  initialized until Namet, since it uses names table entries.
  73
  74    Rtsfind.Initialize;
  75    Atree.Initialize;
  76    Nlists.Initialize;
  77    Elists.Initialize;
  78    Lib.Load.Initialize;
  79    Sem_Ch8.Initialize;
  80    Fname.UF.Initialize;
  81    Checks.Initialize;
  82
  83    --  Create package Standard
  84
  85    CStand.Create_Standard;
  86
  87    --  Check possible symbol definitions specified by -gnateD switches
  88
  89    Prepcomp.Process_Command_Line_Symbol_Definitions;
  90
  91    --  If -gnatep= was specified, parse the preprocessing data file
  92
  93    if Preprocessing_Data_File /= null then
  94       Name_Len := Preprocessing_Data_File'Length;
  95       Name_Buffer (1 .. Name_Len) := Preprocessing_Data_File.all;
  96       Prepcomp.Parse_Preprocessing_Data_File (Name_Find);
  97
  98    --  Otherwise, check if there were preprocessing symbols on the command
  99    --  line and set preprocessing if there are.
 100
 101    else
 102       Prepcomp.Check_Symbols;
 103    end if;
 104
 105    --  Now that the preprocessing situation is established, we are able to
 106    --  load the main source (this is no longer done by Lib.Load.Initalize).
 107
 108    Lib.Load.Load_Main_Source;
 109
 110    --  Return immediately if the main source could not be parsed
 111
 112    if Sinput.Main_Source_File = No_Source_File then
 113       return;
 114    end if;
 115
 116    --  Read and process configuration pragma files if present
 117
 118    declare
 119       Save_Style_Check : constant Boolean := Opt.Style_Check;
 120       --  Save style check mode so it can be restored later
 121
 122       Source_Config_File : Source_File_Index;
 123       --  Source reference for -gnatec configuration file
 124
 125       Prag : Node_Id;
 126
 127    begin
 128       --  We always analyze config files with style checks off, since
 129       --  we don't want a miscellaneous gnat.adc that is around to
 130       --  discombobulate intended -gnatg or -gnaty compilations. We
 131       --  also disconnect checking for maximum line length.
 132
 133       Opt.Style_Check := False;
 134       Style_Check := False;
 135
 136       --  Capture current suppress options, which may get modified
 137
 138       Scope_Suppress := Opt.Suppress_Options;
 139
 140       --  First deal with gnat.adc file
 141
 142       if Opt.Config_File then
 143          Name_Buffer (1 .. 8) := "gnat.adc";
 144          Name_Len := 8;
 145          Source_gnat_adc := Load_Config_File (Name_Enter);
 146
 147          if Source_gnat_adc /= No_Source_File then
 148             Initialize_Scanner (No_Unit, Source_gnat_adc);
 149             Config_Pragmas := Par (Configuration_Pragmas => True);
 150
 151          else
 152             Config_Pragmas := Empty_List;
 153          end if;
 154
 155       else
 156          Config_Pragmas := Empty_List;
 157       end if;
 158
 159       --  Now deal with specified config pragmas files if there are any
 160
 161       if Opt.Config_File_Names /= null then
 162          for Index in Opt.Config_File_Names'Range loop
 163             Name_Len := Config_File_Names (Index)'Length;
 164             Name_Buffer (1 .. Name_Len) := Config_File_Names (Index).all;
 165             Source_Config_File := Load_Config_File (Name_Enter);
 166
 167             if Source_Config_File = No_Source_File then
 168                Osint.Fail
 169                  ("cannot find configuration pragmas file ",
 170                   Config_File_Names (Index).all);
 171             end if;
 172
 173             Initialize_Scanner (No_Unit, Source_Config_File);
 174             Append_List_To
 175               (Config_Pragmas, Par (Configuration_Pragmas => True));
 176          end loop;
 177       end if;
 178
 179       --  Now analyze all pragmas except those whose analysis must be
 180       --  deferred till after the main unit is analyzed.
 181
 182       if Config_Pragmas /= Error_List
 183         and then Operating_Mode /= Check_Syntax
 184       then
 185          Prag := First (Config_Pragmas);
 186          while Present (Prag) loop
 187             if not Delay_Config_Pragma_Analyze (Prag) then
 188                Analyze_Pragma (Prag);
 189             end if;
 190
 191             Next (Prag);
 192          end loop;
 193       end if;
 194
 195       --  Restore style check, but if config file turned on checks, leave on!
 196
 197       Opt.Style_Check := Save_Style_Check or Style_Check;
 198
 199       --  Capture any modifications to suppress options from config pragmas
 200
 201       Opt.Suppress_Options := Scope_Suppress;
 202    end;
 203
 204    --  If there was a -gnatem switch, initialize the mappings of unit names to
 205    --  file names and of file names to path names from the mapping file.
 206
 207    if Mapping_File_Name /= null then
 208       Fmap.Initialize (Mapping_File_Name.all);
 209    end if;
 210
 211    --  We have now processed the command line switches, and the gnat.adc
 212    --  file, so this is the point at which we want to capture the values
 213    --  of the configuration switches (see Opt for further details).
 214
 215    Opt.Register_Opt_Config_Switches;
 216
 217    --  Check for file which contains No_Body pragma
 218
 219    if Source_File_Is_No_Body (Source_Index (Main_Unit)) then
 220       Change_Main_Unit_To_Spec;
 221    end if;
 222
 223    --  Initialize the scanner. Note that we do this after the call to
 224    --  Create_Standard, which uses the scanner in its processing of
 225    --  floating-point bounds.
 226
 227    Initialize_Scanner (Main_Unit, Source_Index (Main_Unit));
 228
 229    --  Here we call the parser to parse the compilation unit (or units in
 230    --  the check syntax mode, but in that case we won't go on to the
 231    --  semantics in any case).
 232
 233    Discard_List (Par (Configuration_Pragmas => False));
 234
 235    --  The main unit is now loaded, and subunits of it can be loaded,
 236    --  without reporting spurious loading circularities.
 237
 238    Set_Loading (Main_Unit, False);
 239
 240    --  Now that the main unit is installed, we can complete the analysis
 241    --  of the pragmas in gnat.adc and the configuration file, that require
 242    --  a context for their semantic processing.
 243
 244    if Config_Pragmas /= Error_List
 245      and then Operating_Mode /= Check_Syntax
 246    then
 247       --  Pragmas that require some semantic activity, such as
 248       --  Interrupt_State, cannot be processed until the main unit
 249       --  is installed, because they require a compilation unit on
 250       --  which to attach with_clauses, etc. So analyze them now.
 251
 252       declare
 253          Prag : Node_Id;
 254
 255       begin
 256          Prag := First (Config_Pragmas);
 257          while Present (Prag) loop
 258             if Delay_Config_Pragma_Analyze (Prag) then
 259                Analyze_Pragma (Prag);
 260             end if;
 261
 262             Next (Prag);
 263          end loop;
 264       end;
 265    end if;
 266
 267    --  Now on to the semantics. Skip if in syntax only mode
 268
 269    if Operating_Mode /= Check_Syntax then
 270
 271       --  Install the configuration pragmas in the tree
 272
 273       Set_Config_Pragmas (Aux_Decls_Node (Cunit (Main_Unit)), Config_Pragmas);
 274
 275       --  Following steps are skipped if we had a fatal error during parsing
 276
 277       if not Fatal_Error (Main_Unit) then
 278
 279          --  Reset Operating_Mode to Check_Semantics for subunits. We cannot
 280          --  actually generate code for subunits, so we suppress expansion.
 281          --  This also corrects certain problems that occur if we try to
 282          --  incorporate subunits at a lower level.
 283
 284          if Operating_Mode = Generate_Code
 285             and then Nkind (Unit (Cunit (Main_Unit))) = N_Subunit
 286          then
 287             Operating_Mode := Check_Semantics;
 288          end if;
 289
 290          --  Analyze (and possibly expand) main unit
 291
 292          Scope_Suppress := Suppress_Options;
 293          Semantics (Cunit (Main_Unit));
 294
 295          --  Cleanup processing after completing main analysis
 296
 297          if Operating_Mode = Generate_Code
 298             or else (Operating_Mode = Check_Semantics
 299                       and then ASIS_Mode)
 300          then
 301             Instantiate_Bodies;
 302          end if;
 303
 304          if Operating_Mode = Generate_Code then
 305             if Inline_Processing_Required then
 306                Analyze_Inlined_Bodies;
 307             end if;
 308
 309             --  Remove entities from program that do not have any
 310             --  execution time references.
 311
 312             if Debug_Flag_UU then
 313                Collect_Garbage_Entities;
 314             end if;
 315
 316             Check_Elab_Calls;
 317          end if;
 318
 319          --  List library units if requested
 320
 321          if List_Units then
 322             Lib.List;
 323          end if;
 324
 325          --  Output waiting warning messages
 326
 327          Sem_Warn.Output_Non_Modifed_In_Out_Warnings;
 328          Sem_Warn.Output_Unreferenced_Messages;
 329          Sem_Warn.Check_Unused_Withs;
 330       end if;
 331    end if;
 332
 333    --  Qualify all entity names in inner packages, package bodies, etc.,
 334    --  except when compiling for the VM back-ends, which depend on
 335    --  having unqualified names in certain cases and handles the
 336    --  generation of qualified names when needed.
 337
 338    if VM_Target = No_VM then
 339       Exp_Dbug.Qualify_All_Entity_Names;
 340    end if;
 341
 342    --  Dump the source now. Note that we do this as soon as the analysis
 343    --  of the tree is complete, because it is not just a dump in the case
 344    --  of -gnatD, where it rewrites all source locations in the tree.
 345
 346    Sprint.Source_Dump;
 347
 348    --  If a mapping file has been specified by a -gnatem switch, update
 349    --  it if there has been some sourcs that were not in the mappings.
 350
 351    if Mapping_File_Name /= null then
 352       Fmap.Update_Mapping_File (Mapping_File_Name.all);
 353    end if;
 354
 355    return;
 356 end Frontend;