gcc/ada/fname-uf.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             F N A M E . U F                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision$
  10 --                                                                          --
  11 --          Copyright (C) 1992-2001, Free Software Foundation, Inc.         --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- GNAT was originally developed  by the GNAT team at  New York University. --
  25 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  26 --                                                                          --
  27 ------------------------------------------------------------------------------
  28
  29 with Alloc;
  30 with Debug;    use Debug;
  31 with Fmap;
  32 with Krunch;
  33 with Namet;    use Namet;
  34 with Opt;      use Opt;
  35 with Osint;    use Osint;
  36 with Table;
  37 with Widechar; use Widechar;
  38
  39 with GNAT.HTable;
  40
  41 package body Fname.UF is
  42
  43    --------------------------------------------------------
  44    -- Declarations for Handling Source_File_Name pragmas --
  45    --------------------------------------------------------
  46
  47    type SFN_Entry is record
  48       U : Unit_Name_Type; -- Unit name
  49       F : File_Name_Type; -- Spec/Body file name
  50    end record;
  51    --  Record single Unit_Name type call to Set_File_Name
  52
  53    package SFN_Table is new Table.Table (
  54      Table_Component_Type => SFN_Entry,
  55      Table_Index_Type     => Int,
  56      Table_Low_Bound      => 0,
  57      Table_Initial        => Alloc.SFN_Table_Initial,
  58      Table_Increment      => Alloc.SFN_Table_Increment,
  59      Table_Name           => "SFN_Table");
  60    --  Table recording all Unit_Name calls to Set_File_Name
  61
  62    type SFN_Header_Num is range 0 .. 100;
  63
  64    function SFN_Hash (F : Unit_Name_Type) return SFN_Header_Num;
  65    --  Compute hash index for use by Simple_HTable
  66
  67    No_Entry : constant Int := -1;
  68    --  Signals no entry in following table
  69
  70    package SFN_HTable is new GNAT.HTable.Simple_HTable (
  71      Header_Num => SFN_Header_Num,
  72      Element    => Int,
  73      No_Element => No_Entry,
  74      Key        => Unit_Name_Type,
  75      Hash       => SFN_Hash,
  76      Equal      => "=");
  77    --  Hash table allowing rapid access to SFN_Table, the element value
  78    --  is an index into this table.
  79
  80    type SFN_Pattern_Entry is record
  81       Pat : String_Ptr;   -- File name pattern (with asterisk in it)
  82       Typ : Character;    -- 'S'/'B'/'U' for spec/body/subunit
  83       Dot : String_Ptr;   -- Dot_Separator string
  84       Cas : Casing_Type;  -- Upper/Lower/Mixed
  85    end record;
  86    --  Records single call to Set_File_Name_Patterm
  87
  88    package SFN_Patterns is new Table.Table (
  89      Table_Component_Type => SFN_Pattern_Entry,
  90      Table_Index_Type     => Int,
  91      Table_Low_Bound      => 1,
  92      Table_Initial        => 10,
  93      Table_Increment      => 100,
  94      Table_Name           => "SFN_Patterns");
  95    --  Table recording all calls to Set_File_Name_Pattern. Note that the
  96    --  first two entries are set to represent the standard GNAT rules
  97    --  for file naming.
  98
  99    -----------------------
 100    -- File_Name_Of_Body --
 101    -----------------------
 102
 103    function File_Name_Of_Body (Name : Name_Id) return File_Name_Type is
 104    begin
 105       Get_Name_String (Name);
 106       Name_Buffer (Name_Len + 1 .. Name_Len + 2) := "%b";
 107       Name_Len := Name_Len + 2;
 108       return Get_File_Name (Name_Enter, Subunit => False);
 109    end File_Name_Of_Body;
 110
 111    -----------------------
 112    -- File_Name_Of_Spec --
 113    -----------------------
 114
 115    function File_Name_Of_Spec (Name : Name_Id) return File_Name_Type is
 116    begin
 117       Get_Name_String (Name);
 118       Name_Buffer (Name_Len + 1 .. Name_Len + 2) := "%s";
 119       Name_Len := Name_Len + 2;
 120       return Get_File_Name (Name_Enter, Subunit => False);
 121    end File_Name_Of_Spec;
 122
 123    -------------------
 124    -- Get_File_Name --
 125    -------------------
 126
 127    function Get_File_Name
 128      (Uname   : Unit_Name_Type;
 129       Subunit : Boolean)
 130       return    File_Name_Type
 131    is
 132       Unit_Char : Character;
 133       --  Set to 's' or 'b' for spec or body or to 'u' for a subunit
 134
 135       Unit_Char_Search : Character;
 136       --  Same as Unit_Char, except that in the case of 'u' for a subunit,
 137       --  we set Unit_Char_Search to 'b' if we do not find a subunit match.
 138
 139       N : Int;
 140
 141       Pname : File_Name_Type := No_File;
 142       Fname : File_Name_Type := No_File;
 143
 144    begin
 145       --  Null or error name means that some previous error occurred
 146       --  This is an unrecoverable error, so signal it.
 147
 148       if Uname <= Error_Name then
 149          raise Unrecoverable_Error;
 150       end if;
 151
 152       --  Look into the mapping from unit names to file names
 153
 154       Fname := Fmap.File_Name_Of (Uname);
 155
 156       --  If the unit name is already mapped, return the corresponding
 157       --  file name.
 158
 159       if Fname /= No_File then
 160          return Fname;
 161       end if;
 162
 163       --  If there is a specific SFN pragma, return the corresponding file name
 164
 165       N := SFN_HTable.Get (Uname);
 166
 167       if N /= No_Entry then
 168          return SFN_Table.Table (N).F;
 169       end if;
 170
 171       --  Here for the case where the name was not found in the table
 172
 173       Get_Decoded_Name_String (Uname);
 174
 175       --  A special fudge, normally we don't have operator symbols present,
 176       --  since it is always an error to do so. However, if we do, at this
 177       --  stage it has a leading double quote.
 178
 179       --  What we do in this case is to go back to the undecoded name, which
 180       --  is of the form, for example:
 181
 182       --    Oand%s
 183
 184       --  and build a file name that looks like:
 185
 186       --    _and_.ads
 187
 188       --  which is bit peculiar, but we keep it that way. This means that
 189       --  we avoid bombs due to writing a bad file name, and w get expected
 190       --  error processing downstream, e.g. a compilation following gnatchop.
 191
 192       if Name_Buffer (1) = '"' then
 193          Get_Name_String (Uname);
 194          Name_Len := Name_Len + 1;
 195          Name_Buffer (Name_Len)     := Name_Buffer (Name_Len - 1);
 196          Name_Buffer (Name_Len - 1) := Name_Buffer (Name_Len - 2);
 197          Name_Buffer (Name_Len - 2) := '_';
 198          Name_Buffer (1)            := '_';
 199       end if;
 200
 201       --  Deal with spec or body suffix
 202
 203       Unit_Char := Name_Buffer (Name_Len);
 204       pragma Assert (Unit_Char = 'b' or else Unit_Char = 's');
 205       pragma Assert (Name_Len >= 3 and then Name_Buffer (Name_Len - 1) = '%');
 206       Name_Len := Name_Len - 2;
 207
 208       if Subunit then
 209          Unit_Char := 'u';
 210       end if;
 211
 212       --  Now we need to find the proper translation of the name
 213
 214       declare
 215          Uname : constant String (1 .. Name_Len) :=
 216                    Name_Buffer (1 .. Name_Len);
 217
 218          Pent : Nat;
 219          Plen : Natural;
 220          Fnam : File_Name_Type := No_File;
 221          J    : Natural;
 222          Dot  : String_Ptr;
 223          Dotl : Natural;
 224
 225          function C (N : Natural) return Character;
 226          --  Return N'th character of pattern
 227
 228          function C (N : Natural) return Character is
 229          begin
 230             return SFN_Patterns.Table (Pent).Pat (N);
 231          end C;
 232
 233       --  Start of search through pattern table
 234
 235       begin
 236          --  Search pattern table to find a matching entry. In the general
 237          --  case we do two complete searches. The first time through we
 238          --  stop only if a matching file is found, the second time through
 239          --  we accept the first match regardless. Note that there will
 240          --  always be a match the second time around, because of the
 241          --  default entries at the end of the table.
 242
 243          for No_File_Check in False .. True loop
 244             Unit_Char_Search := Unit_Char;
 245
 246          <<Repeat_Search>>
 247          --  The search is repeated with Unit_Char_Search set to b, if an
 248          --  initial search for the subunit case fails to find any match.
 249
 250             Pent := SFN_Patterns.First;
 251             while Pent <= SFN_Patterns.Last loop
 252                if SFN_Patterns.Table (Pent).Typ = Unit_Char_Search then
 253                   Name_Len := 0;
 254
 255                   --  Found a match, execute the pattern
 256
 257                   Name_Len := Uname'Length;
 258                   Name_Buffer (1 .. Name_Len) := Uname;
 259                   Set_Casing (SFN_Patterns.Table (Pent).Cas);
 260
 261                   --  If dot translation required do it
 262
 263                   Dot  := SFN_Patterns.Table (Pent).Dot;
 264                   Dotl := Dot.all'Length;
 265
 266                   if Dot.all /= "." then
 267                      J := 1;
 268
 269                      while J <= Name_Len loop
 270                         if Name_Buffer (J) = '.' then
 271
 272                            if Dotl = 1 then
 273                               Name_Buffer (J) := Dot (Dot'First);
 274
 275                            else
 276                               Name_Buffer (J + Dotl .. Name_Len + Dotl - 1) :=
 277                                 Name_Buffer (J + 1 .. Name_Len);
 278                               Name_Buffer (J .. J + Dotl - 1) := Dot.all;
 279                               Name_Len := Name_Len + Dotl - 1;
 280                            end if;
 281
 282                            J := J + Dotl;
 283
 284                         --  Skip past wide char sequences to avoid messing
 285                         --  with dot characters that are part of a sequence.
 286
 287                         elsif Name_Buffer (J) = ASCII.ESC
 288                           or else (Upper_Half_Encoding
 289                                     and then
 290                                       Name_Buffer (J) in Upper_Half_Character)
 291                         then
 292                            Skip_Wide (Name_Buffer, J);
 293                         else
 294                            J := J + 1;
 295                         end if;
 296                      end loop;
 297                   end if;
 298
 299                   --  Here move result to right if preinsertion before *
 300
 301                   Plen := SFN_Patterns.Table (Pent).Pat'Length;
 302                   for K in 1 .. Plen loop
 303                      if C (K) = '*' then
 304                         if K /= 1 then
 305                            Name_Buffer (1 + K - 1 .. Name_Len + K - 1) :=
 306                              Name_Buffer (1 .. Name_Len);
 307
 308                            for L in 1 .. K - 1 loop
 309                               Name_Buffer (L) := C (L);
 310                            end loop;
 311
 312                            Name_Len := Name_Len + K - 1;
 313                         end if;
 314
 315                         for L in K + 1 .. Plen loop
 316                            Name_Len := Name_Len + 1;
 317                            Name_Buffer (Name_Len) := C (L);
 318                         end loop;
 319
 320                         exit;
 321                      end if;
 322                   end loop;
 323
 324                   --  Execute possible crunch on constructed name. The krunch
 325                   --  operation excludes any extension that may be present.
 326
 327                   J := Name_Len;
 328                   while J > 1 loop
 329                      exit when Name_Buffer (J) = '.';
 330                      J := J - 1;
 331                   end loop;
 332
 333                   --  Case of extension present
 334
 335                   if J > 1 then
 336                      declare
 337                         Ext : constant String := Name_Buffer (J .. Name_Len);
 338
 339                      begin
 340                         --  Remove extension
 341
 342                         Name_Len := J - 1;
 343
 344                         --  Krunch what's left
 345
 346                         Krunch
 347                           (Name_Buffer,
 348                            Name_Len,
 349                            Integer (Maximum_File_Name_Length),
 350                            Debug_Flag_4);
 351
 352                         --  Replace extension
 353
 354                         Name_Buffer
 355                           (Name_Len + 1 .. Name_Len + Ext'Length) := Ext;
 356                         Name_Len := Name_Len + Ext'Length;
 357                      end;
 358
 359                   --  Case of no extension present, straight krunch on
 360                   --  the entire file name.
 361
 362                   else
 363                      Krunch
 364                        (Name_Buffer,
 365                         Name_Len,
 366                         Integer (Maximum_File_Name_Length),
 367                         Debug_Flag_4);
 368                   end if;
 369
 370                   Fnam := File_Name_Type (Name_Find);
 371
 372                   --  If we are in the first search of the table, then
 373                   --  we check if the file is present, and only accept
 374                   --  the entry if it is indeed present. For the second
 375                   --  search, we accept the entry without this check.
 376
 377                   --  If we only have two entries in the table, then there
 378                   --  is no point in seeing if the file exists, since we
 379                   --  will end up accepting it anyway on the second search,
 380                   --  so just quit and accept it now to save time.
 381
 382                   if No_File_Check or else SFN_Patterns.Last = 2 then
 383                      return Fnam;
 384
 385                   --  Check if file exists and if so, return the entry
 386
 387                   else
 388                      Pname := Find_File (Fnam, Source);
 389
 390                   --  Check if file exists and if so, return the entry
 391
 392                      if Pname /= No_File then
 393
 394                         --  Add to mapping, so that we don't do another
 395                         --  path search in Find_File for this file name
 396
 397                         Fmap.Add (Get_File_Name.Uname, Fnam, Pname);
 398                         return Fnam;
 399
 400                      --  This entry does not match after all, because this is
 401                      --  the first search loop, and the file does not exist.
 402
 403                      else
 404                         Fnam := No_File;
 405                      end if;
 406                   end if;
 407                end if;
 408
 409                Pent := Pent + 1;
 410             end loop;
 411
 412             --  If search failed, and was for a subunit, repeat the search
 413             --  with Unit_Char_Search reset to 'b', since in the normal case
 414             --  we simply treat subunits as bodies.
 415
 416             if Fnam = No_File and then Unit_Char_Search = 'u' then
 417                Unit_Char_Search := 'b';
 418                goto Repeat_Search;
 419             end if;
 420
 421             --  Repeat entire search in No_File_Check mode if necessary
 422
 423          end loop;
 424
 425          --  Something is wrong if search fails completely, since the
 426          --  default entries should catch all possibilities at this stage.
 427
 428          raise Program_Error;
 429       end;
 430    end Get_File_Name;
 431
 432    ----------------
 433    -- Initialize --
 434    ----------------
 435
 436    procedure Initialize is
 437    begin
 438       SFN_Table.Init;
 439       SFN_Patterns.Init;
 440
 441       --  Add default entries to SFN_Patterns.Table to represent the
 442       --  standard default GNAT rules for file name translation.
 443
 444       SFN_Patterns.Append (New_Val =>
 445         (Pat => new String'("*.ads"),
 446          Typ => 's',
 447          Dot => new String'("-"),
 448          Cas => All_Lower_Case));
 449
 450       SFN_Patterns.Append (New_Val =>
 451         (Pat => new String'("*.adb"),
 452          Typ => 'b',
 453          Dot => new String'("-"),
 454          Cas => All_Lower_Case));
 455    end Initialize;
 456
 457    ----------
 458    -- Lock --
 459    ----------
 460
 461    procedure Lock is
 462    begin
 463       SFN_Table.Locked := True;
 464       SFN_Table.Release;
 465    end Lock;
 466
 467    -------------------
 468    -- Set_File_Name --
 469    -------------------
 470
 471    procedure Set_File_Name (U : Unit_Name_Type; F : File_Name_Type) is
 472    begin
 473       SFN_Table.Increment_Last;
 474       SFN_Table.Table (SFN_Table.Last) := (U, F);
 475       SFN_HTable.Set (U, SFN_Table.Last);
 476    end Set_File_Name;
 477
 478    ---------------------------
 479    -- Set_File_Name_Pattern --
 480    ---------------------------
 481
 482    procedure Set_File_Name_Pattern
 483      (Pat : String_Ptr;
 484       Typ : Character;
 485       Dot : String_Ptr;
 486       Cas : Casing_Type)
 487    is
 488       L : constant Nat := SFN_Patterns.Last;
 489    begin
 490       SFN_Patterns.Increment_Last;
 491
 492       --  Move up the last two entries (the default ones) and then
 493       --  put the new entry into the table just before them (we
 494       --  always have the default entries be the last ones).
 495
 496       SFN_Patterns.Table (L + 1) := SFN_Patterns.Table (L);
 497       SFN_Patterns.Table (L)     := SFN_Patterns.Table (L - 1);
 498       SFN_Patterns.Table (L - 1) := (Pat, Typ, Dot, Cas);
 499    end Set_File_Name_Pattern;
 500
 501    --------------
 502    -- SFN_Hash --
 503    --------------
 504
 505    function SFN_Hash (F : Unit_Name_Type) return SFN_Header_Num is
 506    begin
 507       return SFN_Header_Num (Int (F) rem SFN_Header_Num'Range_Length);
 508    end SFN_Hash;
 509
 510 begin
 511
 512    --  We call the initialization routine from the package body, so that
 513    --  Fname.Init only needs to be called explicitly to reinitialize.
 514
 515    Fname.UF.Initialize;
 516 end Fname.UF;