gcc/ada/exp_util.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ U T I L                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.8 $
  10 --                                                                          --
  11 --          Copyright (C) 1992-2001, Free Software Foundation, Inc.         --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- GNAT was originally developed  by the GNAT team at  New York University. --
  25 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  26 --                                                                          --
  27 ------------------------------------------------------------------------------
  28
  29 with Atree;    use Atree;
  30 with Checks;   use Checks;
  31 with Einfo;    use Einfo;
  32 with Elists;   use Elists;
  33 with Errout;   use Errout;
  34 with Exp_Ch7;  use Exp_Ch7;
  35 with Exp_Ch11; use Exp_Ch11;
  36 with Hostparm; use Hostparm;
  37 with Inline;   use Inline;
  38 with Itypes;   use Itypes;
  39 with Lib;      use Lib;
  40 with Namet;    use Namet;
  41 with Nlists;   use Nlists;
  42 with Nmake;    use Nmake;
  43 with Opt;      use Opt;
  44 with Restrict; use Restrict;
  45 with Sem;      use Sem;
  46 with Sem_Ch8;  use Sem_Ch8;
  47 with Sem_Eval; use Sem_Eval;
  48 with Sem_Res;  use Sem_Res;
  49 with Sem_Util; use Sem_Util;
  50 with Sinfo;    use Sinfo;
  51 with Stand;    use Stand;
  52 with Stringt;  use Stringt;
  53 with Tbuild;   use Tbuild;
  54 with Ttypes;   use Ttypes;
  55 with Uintp;    use Uintp;
  56 with Validsw;  use Validsw;
  57
  58 package body Exp_Util is
  59
  60    -----------------------
  61    -- Local Subprograms --
  62    -----------------------
  63
  64    function Build_Task_Array_Image
  65      (Loc    : Source_Ptr;
  66       Id_Ref : Node_Id;
  67       A_Type : Entity_Id;
  68       Dyn    : Boolean := False)
  69       return   Node_Id;
  70    --  Build function to generate the image string for a task that is an
  71    --  array component, concatenating the images of each index. To avoid
  72    --  storage leaks, the string is built with successive slice assignments.
  73    --  The flag Dyn indicates whether this is called for the initialization
  74    --  procedure of an array of tasks, or for the name of a dynamically
  75    --  created task that is assigned to an indexed component.
  76
  77    function Build_Task_Image_Function
  78      (Loc   : Source_Ptr;
  79       Decls : List_Id;
  80       Stats : List_Id;
  81       Res   : Entity_Id)
  82       return  Node_Id;
  83    --  Common processing for Task_Array_Image and Task_Record_Image.
  84    --  Build function body that computes image.
  85
  86    procedure Build_Task_Image_Prefix
  87       (Loc    : Source_Ptr;
  88        Len    : out Entity_Id;
  89        Res    : out Entity_Id;
  90        Pos    : out Entity_Id;
  91        Prefix : Entity_Id;
  92        Sum    : Node_Id;
  93        Decls  : in out List_Id;
  94        Stats  : in out List_Id);
  95    --  Common processing for Task_Array_Image and Task_Record_Image.
  96    --  Create local variables and assign prefix of name to result string.
  97
  98    function Build_Task_Record_Image
  99      (Loc    : Source_Ptr;
 100       Id_Ref : Node_Id;
 101       A_Type : Entity_Id;
 102       Dyn    : Boolean := False)
 103       return Node_Id;
 104    --  Build function to generate the image string for a task that is a
 105    --  record component. Concatenate name of variable with that of selector.
 106    --  The flag Dyn indicates whether this is called for the initialization
 107    --  procedure of record with task components, or for a dynamically
 108    --  created task that is assigned to a selected component.
 109
 110    function Make_CW_Equivalent_Type
 111      (T    : Entity_Id;
 112       E    : Node_Id)
 113       return Entity_Id;
 114    --  T is a class-wide type entity, E is the initial expression node that
 115    --  constrains T in case such as: " X: T := E" or "new T'(E)"
 116    --  This function returns the entity of the Equivalent type and inserts
 117    --  on the fly the necessary declaration such as:
 118    --    type anon is record
 119    --       _parent : Root_Type (T); constrained with E discriminants (if any)
 120    --       Extension : String (1 .. expr to match size of E);
 121    --    end record;
 122    --
 123    --  This record is compatible with any object of the class of T thanks
 124    --  to the first field and has the same size as E thanks to the second.
 125
 126    function Make_Literal_Range
 127      (Loc         : Source_Ptr;
 128       Literal_Typ : Entity_Id)
 129       return        Node_Id;
 130    --  Produce a Range node whose bounds are:
 131    --    Low_Bound (Literal_Type) ..
 132    --        Low_Bound (Literal_Type) + Length (Literal_Typ) - 1
 133    --  this is used for expanding declarations like X : String := "sdfgdfg";
 134
 135    function New_Class_Wide_Subtype
 136      (CW_Typ : Entity_Id;
 137       N      : Node_Id)
 138       return   Entity_Id;
 139    --  Create an implicit subtype of CW_Typ attached to node N.
 140
 141    ----------------------
 142    -- Adjust_Condition --
 143    ----------------------
 144
 145    procedure Adjust_Condition (N : Node_Id) is
 146    begin
 147       if No (N) then
 148          return;
 149       end if;
 150
 151       declare
 152          Loc : constant Source_Ptr := Sloc (N);
 153          T   : constant Entity_Id  := Etype (N);
 154          Ti  : Entity_Id;
 155
 156       begin
 157          --  For now, we simply ignore a call where the argument has no
 158          --  type (probably case of unanalyzed condition), or has a type
 159          --  that is not Boolean. This is because this is a pretty marginal
 160          --  piece of functionality, and violations of these rules are
 161          --  likely to be truly marginal (how much code uses Fortran Logical
 162          --  as the barrier to a protected entry?) and we do not want to
 163          --  blow up existing programs. We can change this to an assertion
 164          --  after 3.12a is released ???
 165
 166          if No (T) or else not Is_Boolean_Type (T) then
 167             return;
 168          end if;
 169
 170          --  Apply validity checking if needed
 171
 172          if Validity_Checks_On and Validity_Check_Tests then
 173             Ensure_Valid (N);
 174          end if;
 175
 176          --  Immediate return if standard boolean, the most common case,
 177          --  where nothing needs to be done.
 178
 179          if Base_Type (T) = Standard_Boolean then
 180             return;
 181          end if;
 182
 183          --  Case of zero/non-zero semantics or non-standard enumeration
 184          --  representation. In each case, we rewrite the node as:
 185
 186          --      ityp!(N) /= False'Enum_Rep
 187
 188          --  where ityp is an integer type with large enough size to hold
 189          --  any value of type T.
 190
 191          if Nonzero_Is_True (T) or else Has_Non_Standard_Rep (T) then
 192             if Esize (T) <= Esize (Standard_Integer) then
 193                Ti := Standard_Integer;
 194             else
 195                Ti := Standard_Long_Long_Integer;
 196             end if;
 197
 198             Rewrite (N,
 199               Make_Op_Ne (Loc,
 200                 Left_Opnd  => Unchecked_Convert_To (Ti, N),
 201                 Right_Opnd =>
 202                   Make_Attribute_Reference (Loc,
 203                     Attribute_Name => Name_Enum_Rep,
 204                     Prefix         =>
 205                       New_Occurrence_Of (First_Literal (T), Loc))));
 206             Analyze_And_Resolve (N, Standard_Boolean);
 207
 208          else
 209             Rewrite (N, Convert_To (Standard_Boolean, N));
 210             Analyze_And_Resolve (N, Standard_Boolean);
 211          end if;
 212       end;
 213    end Adjust_Condition;
 214
 215    ------------------------
 216    -- Adjust_Result_Type --
 217    ------------------------
 218
 219    procedure Adjust_Result_Type (N : Node_Id; T : Entity_Id) is
 220    begin
 221       --  Ignore call if current type is not Standard.Boolean
 222
 223       if Etype (N) /= Standard_Boolean then
 224          return;
 225       end if;
 226
 227       --  If result is already of correct type, nothing to do. Note that
 228       --  this will get the most common case where everything has a type
 229       --  of Standard.Boolean.
 230
 231       if Base_Type (T) = Standard_Boolean then
 232          return;
 233
 234       else
 235          declare
 236             KP : constant Node_Kind := Nkind (Parent (N));
 237
 238          begin
 239             --  If result is to be used as a Condition in the syntax, no need
 240             --  to convert it back, since if it was changed to Standard.Boolean
 241             --  using Adjust_Condition, that is just fine for this usage.
 242
 243             if KP in N_Raise_xxx_Error or else KP in N_Has_Condition then
 244                return;
 245
 246             --  If result is an operand of another logical operation, no need
 247             --  to reset its type, since Standard.Boolean is just fine, and
 248             --  such operations always do Adjust_Condition on their operands.
 249
 250             elsif KP in N_Op_Boolean
 251               or else KP = N_And_Then
 252               or else KP = N_Or_Else
 253               or else KP = N_Op_Not
 254             then
 255                return;
 256
 257             --  Otherwise we perform a conversion from the current type,
 258             --  which must be Standard.Boolean, to the desired type.
 259
 260             else
 261                Set_Analyzed (N);
 262                Rewrite (N, Convert_To (T, N));
 263                Analyze_And_Resolve (N, T);
 264             end if;
 265          end;
 266       end if;
 267    end Adjust_Result_Type;
 268
 269    --------------------------
 270    -- Append_Freeze_Action --
 271    --------------------------
 272
 273    procedure Append_Freeze_Action (T : Entity_Id; N : Node_Id) is
 274       Fnode : Node_Id := Freeze_Node (T);
 275
 276    begin
 277       Ensure_Freeze_Node (T);
 278       Fnode := Freeze_Node (T);
 279
 280       if not Present (Actions (Fnode)) then
 281          Set_Actions (Fnode, New_List);
 282       end if;
 283
 284       Append (N, Actions (Fnode));
 285    end Append_Freeze_Action;
 286
 287    ---------------------------
 288    -- Append_Freeze_Actions --
 289    ---------------------------
 290
 291    procedure Append_Freeze_Actions (T : Entity_Id; L : List_Id) is
 292       Fnode : constant Node_Id := Freeze_Node (T);
 293
 294    begin
 295       if No (L) then
 296          return;
 297
 298       else
 299          if No (Actions (Fnode)) then
 300             Set_Actions (Fnode, L);
 301
 302          else
 303             Append_List (L, Actions (Fnode));
 304          end if;
 305
 306       end if;
 307    end Append_Freeze_Actions;
 308
 309    ------------------------
 310    -- Build_Runtime_Call --
 311    ------------------------
 312
 313    function Build_Runtime_Call (Loc : Source_Ptr; RE : RE_Id) return Node_Id is
 314    begin
 315       return
 316         Make_Procedure_Call_Statement (Loc,
 317           Name => New_Reference_To (RTE (RE), Loc));
 318    end Build_Runtime_Call;
 319
 320    -----------------------------
 321    --  Build_Task_Array_Image --
 322    -----------------------------
 323
 324    --  This function generates the body for a function that constructs the
 325    --  image string for a task that is an array component. The function is
 326    --  local to the init_proc for the array type, and is called for each one
 327    --  of the components. The constructed image has the form of an indexed
 328    --  component, whose prefix is the outer variable of the array type.
 329    --  The n-dimensional array type has known indices Index, Index2...
 330    --  Id_Ref is an indexed component form created by the enclosing init_proc.
 331    --  Its successive indices are Val1, Val2,.. which are the loop variables
 332    --  in the loops that call the individual task init_proc on each component.
 333
 334    --  The generated function has the following structure:
 335
 336    --  function F return Task_Image_Type is
 337    --     Pref : string := Task_Id.all;
 338    --     T1 : String := Index1'Image (Val1);
 339    --     ...
 340    --     Tn : String := indexn'image (Valn);
 341    --     Len : Integer := T1'Length + ... + Tn'Length + n + 1;
 342    --     --  Len includes commas and the end parentheses.
 343    --     Res : String (1..Len);
 344    --     Pos : Integer := Pref'Length;
 345    --
 346    --  begin
 347    --     Res (1 .. Pos) := Pref;
 348    --     Pos := Pos + 1;
 349    --     Res (Pos)    := '(';
 350    --     Pos := Pos + 1;
 351    --     Res (Pos .. Pos + T1'Length - 1) := T1;
 352    --     Pos := Pos + T1'Length;
 353    --     Res (Pos) := '.';
 354    --     Pos := Pos + 1;
 355    --     ...
 356    --     Res (Pos .. Pos + Tn'Length - 1) := Tn;
 357    --     Res (Len) := ')';
 358    --
 359    --     return new String (Res);
 360    --  end F;
 361    --
 362    --  Needless to say, multidimensional arrays of tasks are rare enough
 363    --  that the bulkiness of this code is not really a concern.
 364
 365    function Build_Task_Array_Image
 366      (Loc    : Source_Ptr;
 367       Id_Ref : Node_Id;
 368       A_Type : Entity_Id;
 369       Dyn    : Boolean := False)
 370       return   Node_Id
 371    is
 372       Dims : constant Nat := Number_Dimensions (A_Type);
 373       --  Number of dimensions for array of tasks.
 374
 375       Temps : array (1 .. Dims) of Entity_Id;
 376       --  Array of temporaries to hold string for each index.
 377
 378       Indx : Node_Id;
 379       --  Index expression
 380
 381       Len : Entity_Id;
 382       --  Total length of generated name
 383
 384       Pos : Entity_Id;
 385       --  Running index for substring assignments
 386
 387       Pref : Entity_Id;
 388       --  Name of enclosing variable, prefix of resulting name
 389
 390       P_Nam : Node_Id;
 391       --  string expression for Pref.
 392
 393       Res : Entity_Id;
 394       --  String to hold result
 395
 396       Val : Node_Id;
 397       --  Value of successive indices
 398
 399       Sum : Node_Id;
 400       --  Expression to compute total size of string
 401
 402       T : Entity_Id;
 403       --  Entity for name at one index position
 404
 405       Decls : List_Id := New_List;
 406       Stats : List_Id := New_List;
 407
 408    begin
 409       Pref := Make_Defining_Identifier (Loc, New_Internal_Name ('P'));
 410
 411       --  For a dynamic task, the name comes from the target variable.
 412       --  For a static one it is a formal of the enclosing init_proc.
 413
 414       if Dyn then
 415          Get_Name_String (Chars (Entity (Prefix (Id_Ref))));
 416          P_Nam :=
 417            Make_String_Literal (Loc, Strval => String_From_Name_Buffer);
 418       else
 419          P_Nam :=
 420            Make_Explicit_Dereference (Loc,
 421              Prefix => Make_Identifier (Loc, Name_uTask_Id));
 422       end if;
 423
 424       Append_To (Decls,
 425         Make_Object_Declaration (Loc,
 426           Defining_Identifier => Pref,
 427           Object_Definition => New_Occurrence_Of (Standard_String, Loc),
 428           Expression => P_Nam));
 429
 430       Indx := First_Index (A_Type);
 431       Val  := First (Expressions (Id_Ref));
 432
 433       for J in 1 .. Dims loop
 434          T := Make_Defining_Identifier (Loc, New_Internal_Name ('T'));
 435          Temps (J) := T;
 436
 437          Append_To (Decls,
 438             Make_Object_Declaration (Loc,
 439                Defining_Identifier => T,
 440                Object_Definition => New_Occurrence_Of (Standard_String, Loc),
 441                Expression =>
 442                  Make_Attribute_Reference (Loc,
 443                    Attribute_Name => Name_Image,
 444                    Prefix =>
 445                      New_Occurrence_Of (Etype (Indx), Loc),
 446                    Expressions => New_List (
 447                      New_Copy_Tree (Val)))));
 448
 449          Next_Index (Indx);
 450          Next (Val);
 451       end loop;
 452
 453       Sum := Make_Integer_Literal (Loc, Dims + 1);
 454
 455       Sum :=
 456         Make_Op_Add (Loc,
 457           Left_Opnd => Sum,
 458           Right_Opnd =>
 459            Make_Attribute_Reference (Loc,
 460              Attribute_Name => Name_Length,
 461              Prefix =>
 462                New_Occurrence_Of (Pref, Loc),
 463              Expressions => New_List (Make_Integer_Literal (Loc, 1))));
 464
 465       for J in 1 .. Dims loop
 466          Sum :=
 467             Make_Op_Add (Loc,
 468              Left_Opnd => Sum,
 469              Right_Opnd =>
 470               Make_Attribute_Reference (Loc,
 471                 Attribute_Name => Name_Length,
 472                 Prefix =>
 473                   New_Occurrence_Of (Temps (J), Loc),
 474                 Expressions => New_List (Make_Integer_Literal (Loc, 1))));
 475       end loop;
 476
 477       Build_Task_Image_Prefix (Loc, Len, Res, Pos, Pref, Sum, Decls, Stats);
 478
 479       Set_Character_Literal_Name (Char_Code (Character'Pos ('(')));
 480
 481       Append_To (Stats,
 482          Make_Assignment_Statement (Loc,
 483            Name => Make_Indexed_Component (Loc,
 484               Prefix => New_Occurrence_Of (Res, Loc),
 485               Expressions => New_List (New_Occurrence_Of (Pos, Loc))),
 486            Expression =>
 487              Make_Character_Literal (Loc,
 488                Chars => Name_Find,
 489                Char_Literal_Value =>
 490                  Char_Code (Character'Pos ('(')))));
 491
 492       Append_To (Stats,
 493          Make_Assignment_Statement (Loc,
 494             Name => New_Occurrence_Of (Pos, Loc),
 495             Expression =>
 496               Make_Op_Add (Loc,
 497                 Left_Opnd => New_Occurrence_Of (Pos, Loc),
 498                 Right_Opnd => Make_Integer_Literal (Loc, 1))));
 499
 500       for J in 1 .. Dims loop
 501
 502          Append_To (Stats,
 503             Make_Assignment_Statement (Loc,
 504               Name => Make_Slice (Loc,
 505                  Prefix => New_Occurrence_Of (Res, Loc),
 506                  Discrete_Range  =>
 507                    Make_Range (Loc,
 508                       Low_Bound => New_Occurrence_Of  (Pos, Loc),
 509                       High_Bound => Make_Op_Subtract (Loc,
 510                         Left_Opnd =>
 511                           Make_Op_Add (Loc,
 512                             Left_Opnd => New_Occurrence_Of (Pos, Loc),
 513                             Right_Opnd =>
 514                               Make_Attribute_Reference (Loc,
 515                                 Attribute_Name => Name_Length,
 516                                 Prefix =>
 517                                   New_Occurrence_Of (Temps (J), Loc),
 518                                 Expressions =>
 519                                   New_List (Make_Integer_Literal (Loc, 1)))),
 520                          Right_Opnd => Make_Integer_Literal (Loc, 1)))),
 521
 522               Expression => New_Occurrence_Of (Temps (J), Loc)));
 523
 524          if J < Dims then
 525             Append_To (Stats,
 526                Make_Assignment_Statement (Loc,
 527                   Name => New_Occurrence_Of (Pos, Loc),
 528                   Expression =>
 529                     Make_Op_Add (Loc,
 530                       Left_Opnd => New_Occurrence_Of (Pos, Loc),
 531                       Right_Opnd =>
 532                         Make_Attribute_Reference (Loc,
 533                           Attribute_Name => Name_Length,
 534                             Prefix => New_Occurrence_Of (Temps (J), Loc),
 535                             Expressions =>
 536                               New_List (Make_Integer_Literal (Loc, 1))))));
 537
 538             Set_Character_Literal_Name (Char_Code (Character'Pos (',')));
 539
 540             Append_To (Stats,
 541                Make_Assignment_Statement (Loc,
 542                  Name => Make_Indexed_Component (Loc,
 543                     Prefix => New_Occurrence_Of (Res, Loc),
 544                     Expressions => New_List (New_Occurrence_Of (Pos, Loc))),
 545                  Expression =>
 546                    Make_Character_Literal (Loc,
 547                      Chars => Name_Find,
 548                      Char_Literal_Value =>
 549                        Char_Code (Character'Pos (',')))));
 550
 551             Append_To (Stats,
 552               Make_Assignment_Statement (Loc,
 553                 Name => New_Occurrence_Of (Pos, Loc),
 554                   Expression =>
 555                     Make_Op_Add (Loc,
 556                       Left_Opnd => New_Occurrence_Of (Pos, Loc),
 557                       Right_Opnd => Make_Integer_Literal (Loc, 1))));
 558          end if;
 559       end loop;
 560
 561       Set_Character_Literal_Name (Char_Code (Character'Pos (')')));
 562
 563       Append_To (Stats,
 564          Make_Assignment_Statement (Loc,
 565            Name => Make_Indexed_Component (Loc,
 566               Prefix => New_Occurrence_Of (Res, Loc),
 567               Expressions => New_List (New_Occurrence_Of (Len, Loc))),
 568            Expression =>
 569              Make_Character_Literal (Loc,
 570                Chars => Name_Find,
 571                Char_Literal_Value =>
 572                  Char_Code (Character'Pos (')')))));
 573       return Build_Task_Image_Function (Loc, Decls, Stats, Res);
 574    end Build_Task_Array_Image;
 575
 576    ----------------------------
 577    -- Build_Task_Image_Decls --
 578    ----------------------------
 579
 580    function Build_Task_Image_Decls
 581      (Loc    : Source_Ptr;
 582       Id_Ref : Node_Id;
 583       A_Type : Entity_Id)
 584       return   List_Id
 585    is
 586       T_Id   : Entity_Id := Empty;
 587       Decl   : Node_Id;
 588       Decls  : List_Id   := New_List;
 589       Expr   : Node_Id   := Empty;
 590       Fun    : Node_Id   := Empty;
 591       Is_Dyn : constant Boolean :=
 592         Nkind (Parent (Id_Ref)) = N_Assignment_Statement
 593          and then Nkind (Expression (Parent (Id_Ref))) = N_Allocator;
 594
 595    begin
 596       --  If Discard_Names is in effect, generate a dummy declaration only.
 597
 598       if Global_Discard_Names then
 599          T_Id :=
 600            Make_Defining_Identifier (Loc, New_Internal_Name ('I'));
 601
 602          return
 603            New_List (
 604              Make_Object_Declaration (Loc,
 605                Defining_Identifier => T_Id,
 606                Object_Definition =>
 607                  New_Occurrence_Of (RTE (RE_Task_Image_Type), Loc)));
 608
 609       else
 610          if Nkind (Id_Ref) = N_Identifier
 611            or else Nkind (Id_Ref) = N_Defining_Identifier
 612          then
 613             --  For a simple variable, the image of the task is the name
 614             --  of the variable.
 615
 616             T_Id :=
 617               Make_Defining_Identifier (Loc,
 618                 New_External_Name (Chars (Id_Ref), 'I'));
 619
 620             Get_Name_String (Chars (Id_Ref));
 621
 622             Expr :=
 623              Make_Allocator (Loc,
 624                Expression =>
 625                  Make_Qualified_Expression (Loc,
 626                    Subtype_Mark =>
 627                      New_Occurrence_Of (Standard_String, Loc),
 628                    Expression =>
 629                      Make_String_Literal
 630                        (Loc, Strval => String_From_Name_Buffer)));
 631
 632          elsif Nkind (Id_Ref) = N_Selected_Component then
 633             T_Id :=
 634               Make_Defining_Identifier (Loc,
 635                 New_External_Name (Chars (Selector_Name (Id_Ref)), 'I'));
 636             Fun := Build_Task_Record_Image (Loc, Id_Ref, A_Type, Is_Dyn);
 637
 638          elsif Nkind (Id_Ref) = N_Indexed_Component then
 639             T_Id :=
 640               Make_Defining_Identifier (Loc,
 641                 New_External_Name (Chars (A_Type), 'I'));
 642
 643             Fun := Build_Task_Array_Image (Loc, Id_Ref, A_Type, Is_Dyn);
 644          end if;
 645       end if;
 646
 647       if Present (Fun) then
 648          Append (Fun, Decls);
 649
 650          Expr :=
 651             Make_Function_Call (Loc,
 652             Name => New_Occurrence_Of (Defining_Entity (Fun), Loc));
 653       end if;
 654
 655       Decl := Make_Object_Declaration (Loc,
 656         Defining_Identifier => T_Id,
 657         Object_Definition =>
 658           New_Occurrence_Of (RTE (RE_Task_Image_Type), Loc),
 659         Expression => Expr);
 660
 661       Append (Decl, Decls);
 662       return Decls;
 663    end Build_Task_Image_Decls;
 664
 665    -------------------------------
 666    -- Build_Task_Image_Function --
 667    -------------------------------
 668
 669    function Build_Task_Image_Function
 670      (Loc   : Source_Ptr;
 671       Decls : List_Id;
 672       Stats : List_Id;
 673       Res   : Entity_Id)
 674       return  Node_Id
 675    is
 676       Spec : Node_Id;
 677
 678    begin
 679       Append_To (Stats,
 680         Make_Return_Statement (Loc,
 681           Expression =>
 682                Make_Allocator (Loc,
 683               Expression =>
 684                 Make_Qualified_Expression (Loc,
 685                   Subtype_Mark =>
 686                     New_Occurrence_Of (Standard_String, Loc),
 687                   Expression => New_Occurrence_Of (Res, Loc)))));
 688
 689       Spec := Make_Function_Specification  (Loc,
 690       Defining_Unit_Name =>
 691         Make_Defining_Identifier (Loc, New_Internal_Name ('F')),
 692       Subtype_Mark => New_Occurrence_Of (RTE (RE_Task_Image_Type), Loc));
 693
 694       return Make_Subprogram_Body (Loc,
 695          Specification => Spec,
 696          Declarations => Decls,
 697          Handled_Statement_Sequence =>
 698            Make_Handled_Sequence_Of_Statements (Loc,
 699              Statements => Stats));
 700    end Build_Task_Image_Function;
 701
 702    -----------------------------
 703    -- Build_Task_Image_Prefix --
 704    -----------------------------
 705
 706    procedure Build_Task_Image_Prefix
 707       (Loc    : Source_Ptr;
 708        Len    : out Entity_Id;
 709        Res    : out Entity_Id;
 710        Pos    : out Entity_Id;
 711        Prefix : Entity_Id;
 712        Sum    : Node_Id;
 713        Decls  : in out List_Id;
 714        Stats  : in out List_Id)
 715    is
 716    begin
 717       Len := Make_Defining_Identifier (Loc, New_Internal_Name ('L'));
 718
 719       Append_To (Decls,
 720         Make_Object_Declaration (Loc,
 721           Defining_Identifier => Len,
 722           Object_Definition => New_Occurrence_Of (Standard_Integer, Loc),
 723           Expression        => Sum));
 724
 725       Res := Make_Defining_Identifier (Loc, New_Internal_Name ('R'));
 726
 727       Append_To (Decls,
 728          Make_Object_Declaration (Loc,
 729             Defining_Identifier => Res,
 730             Object_Definition =>
 731                Make_Subtype_Indication (Loc,
 732                   Subtype_Mark => New_Occurrence_Of (Standard_String, Loc),
 733                Constraint =>
 734                  Make_Index_Or_Discriminant_Constraint (Loc,
 735                    Constraints =>
 736                      New_List (
 737                        Make_Range (Loc,
 738                          Low_Bound => Make_Integer_Literal (Loc, 1),
 739                          High_Bound => New_Occurrence_Of (Len, Loc)))))));
 740
 741       Pos := Make_Defining_Identifier (Loc, New_Internal_Name ('P'));
 742
 743       Append_To (Decls,
 744          Make_Object_Declaration (Loc,
 745             Defining_Identifier => Pos,
 746             Object_Definition => New_Occurrence_Of (Standard_Integer, Loc)));
 747
 748       --  Pos := Prefix'Length;
 749
 750       Append_To (Stats,
 751          Make_Assignment_Statement (Loc,
 752             Name => New_Occurrence_Of (Pos, Loc),
 753             Expression =>
 754               Make_Attribute_Reference (Loc,
 755                 Attribute_Name => Name_Length,
 756                 Prefix => New_Occurrence_Of (Prefix, Loc),
 757                 Expressions =>
 758                     New_List (Make_Integer_Literal (Loc, 1)))));
 759
 760       --  Res (1 .. Pos) := Prefix;
 761
 762       Append_To (Stats,
 763          Make_Assignment_Statement (Loc,
 764            Name => Make_Slice (Loc,
 765               Prefix => New_Occurrence_Of (Res, Loc),
 766               Discrete_Range  =>
 767                 Make_Range (Loc,
 768                    Low_Bound => Make_Integer_Literal (Loc, 1),
 769                    High_Bound => New_Occurrence_Of (Pos, Loc))),
 770
 771            Expression => New_Occurrence_Of (Prefix, Loc)));
 772
 773       Append_To (Stats,
 774          Make_Assignment_Statement (Loc,
 775             Name => New_Occurrence_Of (Pos, Loc),
 776             Expression =>
 777               Make_Op_Add (Loc,
 778                 Left_Opnd => New_Occurrence_Of (Pos, Loc),
 779                 Right_Opnd => Make_Integer_Literal (Loc, 1))));
 780    end Build_Task_Image_Prefix;
 781
 782    -----------------------------
 783    -- Build_Task_Record_Image --
 784    -----------------------------
 785
 786    function Build_Task_Record_Image
 787      (Loc    : Source_Ptr;
 788       Id_Ref : Node_Id;
 789       A_Type : Entity_Id;
 790       Dyn    : Boolean := False)
 791       return   Node_Id
 792    is
 793       Len : Entity_Id;
 794       --  Total length of generated name
 795
 796       Pos : Entity_Id;
 797       --  Index into result
 798
 799       Res : Entity_Id;
 800       --  String to hold result
 801
 802       Pref : Entity_Id;
 803       --  Name of enclosing variable, prefix of resulting name
 804
 805       P_Nam : Node_Id;
 806       --  string expression for Pref.
 807
 808       Sum : Node_Id;
 809       --  Expression to compute total size of string.
 810
 811       Sel : Entity_Id;
 812       --  Entity for selector name
 813
 814       Decls : List_Id := New_List;
 815       Stats : List_Id := New_List;
 816
 817    begin
 818       Pref := Make_Defining_Identifier (Loc, New_Internal_Name ('P'));
 819
 820       --  For a dynamic task, the name comes from the target variable.
 821       --  For a static one it is a formal of the enclosing init_proc.
 822
 823       if Dyn then
 824          Get_Name_String (Chars (Entity (Prefix (Id_Ref))));
 825          P_Nam :=
 826            Make_String_Literal (Loc, Strval => String_From_Name_Buffer);
 827       else
 828          P_Nam :=
 829            Make_Explicit_Dereference (Loc,
 830              Prefix => Make_Identifier (Loc, Name_uTask_Id));
 831       end if;
 832
 833       Append_To (Decls,
 834         Make_Object_Declaration (Loc,
 835           Defining_Identifier => Pref,
 836           Object_Definition => New_Occurrence_Of (Standard_String, Loc),
 837           Expression => P_Nam));
 838
 839       Sel := Make_Defining_Identifier (Loc, New_Internal_Name ('S'));
 840
 841       Get_Name_String (Chars (Selector_Name (Id_Ref)));
 842
 843       Append_To (Decls,
 844          Make_Object_Declaration (Loc,
 845            Defining_Identifier => Sel,
 846            Object_Definition => New_Occurrence_Of (Standard_String, Loc),
 847            Expression =>
 848               Make_String_Literal (Loc, Strval => String_From_Name_Buffer)));
 849
 850       Sum := Make_Integer_Literal (Loc, Nat (Name_Len + 1));
 851
 852       Sum :=
 853         Make_Op_Add (Loc,
 854           Left_Opnd => Sum,
 855           Right_Opnd =>
 856            Make_Attribute_Reference (Loc,
 857              Attribute_Name => Name_Length,
 858              Prefix =>
 859                New_Occurrence_Of (Pref, Loc),
 860              Expressions => New_List (Make_Integer_Literal (Loc, 1))));
 861
 862       Build_Task_Image_Prefix (Loc, Len, Res, Pos, Pref, Sum, Decls, Stats);
 863
 864       Set_Character_Literal_Name (Char_Code (Character'Pos ('.')));
 865
 866       --  Res (Pos) := '.';
 867
 868       Append_To (Stats,
 869          Make_Assignment_Statement (Loc,
 870            Name => Make_Indexed_Component (Loc,
 871               Prefix => New_Occurrence_Of (Res, Loc),
 872               Expressions => New_List (New_Occurrence_Of (Pos, Loc))),
 873            Expression =>
 874              Make_Character_Literal (Loc,
 875                Chars => Name_Find,
 876                Char_Literal_Value =>
 877                  Char_Code (Character'Pos ('.')))));
 878
 879       Append_To (Stats,
 880         Make_Assignment_Statement (Loc,
 881           Name => New_Occurrence_Of (Pos, Loc),
 882           Expression =>
 883             Make_Op_Add (Loc,
 884               Left_Opnd => New_Occurrence_Of (Pos, Loc),
 885               Right_Opnd => Make_Integer_Literal (Loc, 1))));
 886
 887       --  Res (Pos .. Len) := Selector;
 888
 889       Append_To (Stats,
 890         Make_Assignment_Statement (Loc,
 891           Name => Make_Slice (Loc,
 892              Prefix => New_Occurrence_Of (Res, Loc),
 893              Discrete_Range  =>
 894                Make_Range (Loc,
 895                  Low_Bound  => New_Occurrence_Of (Pos, Loc),
 896                  High_Bound => New_Occurrence_Of (Len, Loc))),
 897           Expression => New_Occurrence_Of (Sel, Loc)));
 898
 899       return Build_Task_Image_Function (Loc, Decls, Stats, Res);
 900    end Build_Task_Record_Image;
 901
 902    -------------------------------
 903    -- Convert_To_Actual_Subtype --
 904    -------------------------------
 905
 906    procedure Convert_To_Actual_Subtype (Exp : Entity_Id) is
 907       Act_ST : Entity_Id;
 908
 909    begin
 910       Act_ST := Get_Actual_Subtype (Exp);
 911
 912       if Act_ST = Etype (Exp) then
 913          return;
 914
 915       else
 916          Rewrite (Exp,
 917            Convert_To (Act_ST, Relocate_Node (Exp)));
 918          Analyze_And_Resolve (Exp, Act_ST);
 919       end if;
 920    end Convert_To_Actual_Subtype;
 921
 922    -----------------------------------
 923    -- Current_Sem_Unit_Declarations --
 924    -----------------------------------
 925
 926    function Current_Sem_Unit_Declarations return List_Id is
 927       U     : Node_Id := Unit (Cunit (Current_Sem_Unit));
 928       Decls : List_Id;
 929
 930    begin
 931       --  If the current unit is a package body, locate the visible
 932       --  declarations of the package spec.
 933
 934       if Nkind (U) = N_Package_Body then
 935          U := Unit (Library_Unit (Cunit (Current_Sem_Unit)));
 936       end if;
 937
 938       if Nkind (U) = N_Package_Declaration then
 939          U := Specification (U);
 940          Decls := Visible_Declarations (U);
 941
 942          if No (Decls) then
 943             Decls := New_List;
 944             Set_Visible_Declarations (U, Decls);
 945          end if;
 946
 947       else
 948          Decls := Declarations (U);
 949
 950          if No (Decls) then
 951             Decls := New_List;
 952             Set_Declarations (U, Decls);
 953          end if;
 954       end if;
 955
 956       return Decls;
 957    end Current_Sem_Unit_Declarations;
 958
 959    -----------------------
 960    -- Duplicate_Subexpr --
 961    -----------------------
 962
 963    function Duplicate_Subexpr
 964      (Exp      : Node_Id;
 965       Name_Req : Boolean := False)
 966       return     Node_Id
 967    is
 968    begin
 969       Remove_Side_Effects (Exp, Name_Req);
 970       return New_Copy_Tree (Exp);
 971    end Duplicate_Subexpr;
 972
 973    --------------------
 974    -- Ensure_Defined --
 975    --------------------
 976
 977    procedure Ensure_Defined (Typ : Entity_Id; N : Node_Id) is
 978       IR : Node_Id;
 979       P  : Node_Id;
 980
 981    begin
 982       if Is_Itype (Typ) then
 983          IR := Make_Itype_Reference (Sloc (N));
 984          Set_Itype (IR, Typ);
 985
 986          if not In_Open_Scopes (Scope (Typ))
 987            and then Is_Subprogram (Current_Scope)
 988            and then Scope (Current_Scope) /= Standard_Standard
 989          then
 990             --  Insert node in front of subprogram, to avoid scope anomalies
 991             --  in gigi.
 992
 993             P := Parent (N);
 994
 995             while Present (P)
 996               and then Nkind (P) /= N_Subprogram_Body
 997             loop
 998                P := Parent (P);
 999             end loop;
1000
1001             if Present (P) then
1002                Insert_Action (P, IR);
1003             else
1004                Insert_Action (N, IR);
1005             end if;
1006
1007          else
1008             Insert_Action (N, IR);
1009          end if;
1010       end if;
1011    end Ensure_Defined;
1012
1013    ---------------------
1014    -- Evolve_And_Then --
1015    ---------------------
1016
1017    procedure Evolve_And_Then (Cond : in out Node_Id; Cond1 : Node_Id) is
1018    begin
1019       if No (Cond) then
1020          Cond := Cond1;
1021       else
1022          Cond :=
1023            Make_And_Then (Sloc (Cond1),
1024              Left_Opnd  => Cond,
1025              Right_Opnd => Cond1);
1026       end if;
1027    end Evolve_And_Then;
1028
1029    --------------------
1030    -- Evolve_Or_Else --
1031    --------------------
1032
1033    procedure Evolve_Or_Else (Cond : in out Node_Id; Cond1 : Node_Id) is
1034    begin
1035       if No (Cond) then
1036          Cond := Cond1;
1037       else
1038          Cond :=
1039            Make_Or_Else (Sloc (Cond1),
1040              Left_Opnd  => Cond,
1041              Right_Opnd => Cond1);
1042       end if;
1043    end Evolve_Or_Else;
1044
1045    ------------------------------
1046    -- Expand_Subtype_From_Expr --
1047    ------------------------------
1048
1049    --  This function is applicable for both static and dynamic allocation of
1050    --  objects which are constrained by an initial expression. Basically it
1051    --  transforms an unconstrained subtype indication into a constrained one.
1052    --  The expression may also be transformed in certain cases in order to
1053    --  avoid multiple evaulation. In the static allocation case, the general
1054    --  scheme is :
1055
1056    --     Val : T := Expr;
1057
1058    --        is transformed into
1059
1060    --     Val : Constrained_Subtype_of_T := Maybe_Modified_Expr;
1061    --
1062    --  Here are the main cases :
1063    --
1064    --  <if Expr is a Slice>
1065    --    Val : T ([Index_Subtype (Expr)]) := Expr;
1066    --
1067    --  <elsif Expr is a String Literal>
1068    --    Val : T (T'First .. T'First + Length (string literal) - 1) := Expr;
1069    --
1070    --  <elsif Expr is Constrained>
1071    --    subtype T is Type_Of_Expr
1072    --    Val : T := Expr;
1073    --
1074    --  <elsif Expr is an entity_name>
1075    --    Val : T (constraints taken from Expr) := Expr;
1076    --
1077    --  <else>
1078    --    type Axxx is access all T;
1079    --    Rval : Axxx := Expr'ref;
1080    --    Val  : T (constraints taken from Rval) := Rval.all;
1081
1082    --    ??? note: when the Expression is allocated in the secondary stack
1083    --              we could use it directly instead of copying it by declaring
1084    --              Val : T (...) renames Rval.all
1085
1086    procedure Expand_Subtype_From_Expr
1087      (N             : Node_Id;
1088       Unc_Type      : Entity_Id;
1089       Subtype_Indic : Node_Id;
1090       Exp           : Node_Id)
1091    is
1092       Loc     : constant Source_Ptr := Sloc (N);
1093       Exp_Typ : constant Entity_Id  := Etype (Exp);
1094       T       : Entity_Id;
1095
1096    begin
1097       --  In general we cannot build the subtype if expansion is disabled,
1098       --  because internal entities may not have been defined. However, to
1099       --  avoid some cascaded errors, we try to continue when the expression
1100       --  is an array (or string), because it is safe to compute the bounds.
1101       --  It is in fact required to do so even in a generic context, because
1102       --  there may be constants that depend on bounds of string literal.
1103
1104       if not Expander_Active
1105         and then (No (Etype (Exp))
1106                    or else Base_Type (Etype (Exp)) /= Standard_String)
1107       then
1108          return;
1109       end if;
1110
1111       if Nkind (Exp) = N_Slice then
1112          declare
1113             Slice_Type : constant Entity_Id := Etype (First_Index (Exp_Typ));
1114
1115          begin
1116             Rewrite (Subtype_Indic,
1117               Make_Subtype_Indication (Loc,
1118                 Subtype_Mark => New_Reference_To (Unc_Type, Loc),
1119                 Constraint =>
1120                   Make_Index_Or_Discriminant_Constraint (Loc,
1121                     Constraints => New_List
1122                       (New_Reference_To (Slice_Type, Loc)))));
1123
1124             --  This subtype indication may be used later for contraint checks
1125             --  we better make sure that if a variable was used as a bound of
1126             --  of the original slice, its value is frozen.
1127
1128             Force_Evaluation (Low_Bound (Scalar_Range (Slice_Type)));
1129             Force_Evaluation (High_Bound (Scalar_Range (Slice_Type)));
1130          end;
1131
1132       elsif Ekind (Exp_Typ) = E_String_Literal_Subtype then
1133          Rewrite (Subtype_Indic,
1134            Make_Subtype_Indication (Loc,
1135              Subtype_Mark => New_Reference_To (Unc_Type, Loc),
1136              Constraint =>
1137                Make_Index_Or_Discriminant_Constraint (Loc,
1138                  Constraints => New_List (
1139                    Make_Literal_Range (Loc,
1140                      Literal_Typ => Exp_Typ)))));
1141
1142       elsif Is_Constrained (Exp_Typ)
1143         and then not Is_Class_Wide_Type (Unc_Type)
1144       then
1145          if Is_Itype (Exp_Typ) then
1146
1147             --  No need to generate a new one.
1148
1149             T := Exp_Typ;
1150
1151          else
1152             T :=
1153               Make_Defining_Identifier (Loc,
1154                 Chars => New_Internal_Name ('T'));
1155
1156             Insert_Action (N,
1157               Make_Subtype_Declaration (Loc,
1158                 Defining_Identifier => T,
1159                 Subtype_Indication  => New_Reference_To (Exp_Typ, Loc)));
1160
1161             --  This type is marked as an itype even though it has an
1162             --  explicit declaration because otherwise it can be marked
1163             --  with Is_Generic_Actual_Type and generate spurious errors.
1164             --  (see sem_ch8.Analyze_Package_Renaming and sem_type.covers)
1165
1166             Set_Is_Itype (T);
1167             Set_Associated_Node_For_Itype (T, Exp);
1168          end if;
1169
1170          Rewrite (Subtype_Indic, New_Reference_To (T, Loc));
1171
1172       --  nothing needs to be done for private types with unknown discriminants
1173       --  if the underlying type is not an unconstrained composite type.
1174
1175       elsif Is_Private_Type (Unc_Type)
1176         and then Has_Unknown_Discriminants (Unc_Type)
1177         and then (not Is_Composite_Type (Underlying_Type (Unc_Type))
1178                     or else Is_Constrained (Underlying_Type (Unc_Type)))
1179       then
1180          null;
1181
1182       else
1183          Remove_Side_Effects (Exp);
1184          Rewrite (Subtype_Indic,
1185            Make_Subtype_From_Expr (Exp, Unc_Type));
1186       end if;
1187    end Expand_Subtype_From_Expr;
1188
1189    ------------------
1190    -- Find_Prim_Op --
1191    ------------------
1192
1193    function Find_Prim_Op (T : Entity_Id; Name : Name_Id) return Entity_Id is
1194       Prim : Elmt_Id;
1195       Typ  : Entity_Id := T;
1196
1197    begin
1198       if Is_Class_Wide_Type (Typ) then
1199          Typ := Root_Type (Typ);
1200       end if;
1201
1202       Typ := Underlying_Type (Typ);
1203
1204       Prim := First_Elmt (Primitive_Operations (Typ));
1205       while Chars (Node (Prim)) /= Name loop
1206          Next_Elmt (Prim);
1207          pragma Assert (Present (Prim));
1208       end loop;
1209
1210       return Node (Prim);
1211    end Find_Prim_Op;
1212
1213    ----------------------
1214    -- Force_Evaluation --
1215    ----------------------
1216
1217    procedure Force_Evaluation (Exp : Node_Id; Name_Req : Boolean := False) is
1218    begin
1219       Remove_Side_Effects (Exp, Name_Req, Variable_Ref => True);
1220    end Force_Evaluation;
1221
1222    ------------------------
1223    -- Generate_Poll_Call --
1224    ------------------------
1225
1226    procedure Generate_Poll_Call (N : Node_Id) is
1227    begin
1228       --  No poll call if polling not active
1229
1230       if not Polling_Required then
1231          return;
1232
1233       --  Otherwise generate require poll call
1234
1235       else
1236          Insert_Before_And_Analyze (N,
1237            Make_Procedure_Call_Statement (Sloc (N),
1238              Name => New_Occurrence_Of (RTE (RE_Poll), Sloc (N))));
1239       end if;
1240    end Generate_Poll_Call;
1241
1242    --------------------
1243    -- Homonym_Number --
1244    --------------------
1245
1246    function Homonym_Number (Subp : Entity_Id) return Nat is
1247       Count : Nat;
1248       Hom   : Entity_Id;
1249
1250    begin
1251       Count := 1;
1252       Hom := Homonym (Subp);
1253       while Present (Hom) loop
1254          if Scope (Hom) = Scope (Subp) then
1255             Count := Count + 1;
1256          end if;
1257
1258          Hom := Homonym (Hom);
1259       end loop;
1260
1261       return Count;
1262    end Homonym_Number;
1263
1264    ------------------------------
1265    -- In_Unconditional_Context --
1266    ------------------------------
1267
1268    function In_Unconditional_Context (Node : Node_Id) return Boolean is
1269       P : Node_Id;
1270
1271    begin
1272       P := Node;
1273       while Present (P) loop
1274          case Nkind (P) is
1275             when N_Subprogram_Body =>
1276                return True;
1277
1278             when N_If_Statement =>
1279                return False;
1280
1281             when N_Loop_Statement =>
1282                return False;
1283
1284             when N_Case_Statement =>
1285                return False;
1286
1287             when others =>
1288                P := Parent (P);
1289          end case;
1290       end loop;
1291
1292       return False;
1293    end In_Unconditional_Context;
1294
1295    -------------------
1296    -- Insert_Action --
1297    -------------------
1298
1299    procedure Insert_Action (Assoc_Node : Node_Id; Ins_Action : Node_Id) is
1300    begin
1301       if Present (Ins_Action) then
1302          Insert_Actions (Assoc_Node, New_List (Ins_Action));
1303       end if;
1304    end Insert_Action;
1305
1306    --  Version with check(s) suppressed
1307
1308    procedure Insert_Action
1309      (Assoc_Node : Node_Id; Ins_Action : Node_Id; Suppress : Check_Id)
1310    is
1311    begin
1312       Insert_Actions (Assoc_Node, New_List (Ins_Action), Suppress);
1313    end Insert_Action;
1314
1315    --------------------
1316    -- Insert_Actions --
1317    --------------------
1318
1319    procedure Insert_Actions (Assoc_Node : Node_Id; Ins_Actions : List_Id) is
1320       N : Node_Id;
1321       P : Node_Id;
1322
1323       Wrapped_Node : Node_Id := Empty;
1324
1325    begin
1326       if No (Ins_Actions) or else Is_Empty_List (Ins_Actions) then
1327          return;
1328       end if;
1329
1330       --  Ignore insert of actions from inside default expression in the
1331       --  special preliminary analyze mode. Any insertions at this point
1332       --  have no relevance, since we are only doing the analyze to freeze
1333       --  the types of any static expressions. See section "Handling of
1334       --  Default Expressions" in the spec of package Sem for further details.
1335
1336       if In_Default_Expression then
1337          return;
1338       end if;
1339
1340       --  If the action derives from stuff inside a record, then the actions
1341       --  are attached to the current scope, to be inserted and analyzed on
1342       --  exit from the scope. The reason for this is that we may also
1343       --  be generating freeze actions at the same time, and they must
1344       --  eventually be elaborated in the correct order.
1345
1346       if Is_Record_Type (Current_Scope)
1347         and then not Is_Frozen (Current_Scope)
1348       then
1349          if No (Scope_Stack.Table
1350            (Scope_Stack.Last).Pending_Freeze_Actions)
1351          then
1352             Scope_Stack.Table (Scope_Stack.Last).Pending_Freeze_Actions :=
1353               Ins_Actions;
1354          else
1355             Append_List
1356               (Ins_Actions,
1357                Scope_Stack.Table (Scope_Stack.Last).Pending_Freeze_Actions);
1358          end if;
1359
1360          return;
1361       end if;
1362
1363       --  We now intend to climb up the tree to find the right point to
1364       --  insert the actions. We start at Assoc_Node, unless this node is
1365       --  a subexpression in which case we start with its parent. We do this
1366       --  for two reasons. First it speeds things up. Second, if Assoc_Node
1367       --  is itself one of the special nodes like N_And_Then, then we assume
1368       --  that an initial request to insert actions for such a node does not
1369       --  expect the actions to get deposited in the node for later handling
1370       --  when the node is expanded, since clearly the node is being dealt
1371       --  with by the caller. Note that in the subexpression case, N is
1372       --  always the child we came from.
1373
1374       --  N_Raise_xxx_Error is an annoying special case, it is a statement
1375       --  if it has type Standard_Void_Type, and a subexpression otherwise.
1376       --  otherwise. Procedure attribute references are also statements.
1377
1378       if Nkind (Assoc_Node) in N_Subexpr
1379         and then (Nkind (Assoc_Node) in N_Raise_xxx_Error
1380                    or else Etype (Assoc_Node) /= Standard_Void_Type)
1381         and then (Nkind (Assoc_Node) /= N_Attribute_Reference
1382                    or else
1383                      not Is_Procedure_Attribute_Name
1384                            (Attribute_Name (Assoc_Node)))
1385       then
1386          P := Assoc_Node;             -- ????? does not agree with above!
1387          N := Parent (Assoc_Node);
1388
1389       --  Non-subexpression case. Note that N is initially Empty in this
1390       --  case (N is only guaranteed Non-Empty in the subexpr case).
1391
1392       else
1393          P := Assoc_Node;
1394          N := Empty;
1395       end if;
1396
1397       --  Capture root of the transient scope
1398
1399       if Scope_Is_Transient then
1400          Wrapped_Node  := Node_To_Be_Wrapped;
1401       end if;
1402
1403       loop
1404          pragma Assert (Present (P));
1405
1406          case Nkind (P) is
1407
1408             --  Case of right operand of AND THEN or OR ELSE. Put the actions
1409             --  in the Actions field of the right operand. They will be moved
1410             --  out further when the AND THEN or OR ELSE operator is expanded.
1411             --  Nothing special needs to be done for the left operand since
1412             --  in that case the actions are executed unconditionally.
1413
1414             when N_And_Then | N_Or_Else =>
1415                if N = Right_Opnd (P) then
1416                   if Present (Actions (P)) then
1417                      Insert_List_After_And_Analyze
1418                       (Last (Actions (P)), Ins_Actions);
1419                   else
1420                      Set_Actions (P, Ins_Actions);
1421                      Analyze_List (Actions (P));
1422                   end if;
1423
1424                   return;
1425                end if;
1426
1427             --  Then or Else operand of conditional expression. Add actions to
1428             --  Then_Actions or Else_Actions field as appropriate. The actions
1429             --  will be moved further out when the conditional is expanded.
1430
1431             when N_Conditional_Expression =>
1432                declare
1433                   ThenX : constant Node_Id := Next (First (Expressions (P)));
1434                   ElseX : constant Node_Id := Next (ThenX);
1435
1436                begin
1437                   --  Actions belong to the then expression, temporarily
1438                   --  place them as Then_Actions of the conditional expr.
1439                   --  They will be moved to the proper place later when
1440                   --  the conditional expression is expanded.
1441
1442                   if N = ThenX then
1443                      if Present (Then_Actions (P)) then
1444                         Insert_List_After_And_Analyze
1445                           (Last (Then_Actions (P)), Ins_Actions);
1446                      else
1447                         Set_Then_Actions (P, Ins_Actions);
1448                         Analyze_List (Then_Actions (P));
1449                      end if;
1450
1451                      return;
1452
1453                   --  Actions belong to the else expression, temporarily
1454                   --  place them as Else_Actions of the conditional expr.
1455                   --  They will be moved to the proper place later when
1456                   --  the conditional expression is expanded.
1457
1458                   elsif N = ElseX then
1459                      if Present (Else_Actions (P)) then
1460                         Insert_List_After_And_Analyze
1461                           (Last (Else_Actions (P)), Ins_Actions);
1462                      else
1463                         Set_Else_Actions (P, Ins_Actions);
1464                         Analyze_List (Else_Actions (P));
1465                      end if;
1466
1467                      return;
1468
1469                   --  Actions belong to the condition. In this case they are
1470                   --  unconditionally executed, and so we can continue the
1471                   --  search for the proper insert point.
1472
1473                   else
1474                      null;
1475                   end if;
1476                end;
1477
1478             --  Case of appearing in the condition of a while expression or
1479             --  elsif. We insert the actions into the Condition_Actions field.
1480             --  They will be moved further out when the while loop or elsif
1481             --  is analyzed.
1482
1483             when N_Iteration_Scheme |
1484                  N_Elsif_Part
1485             =>
1486                if N = Condition (P) then
1487                   if Present (Condition_Actions (P)) then
1488                      Insert_List_After_And_Analyze
1489                        (Last (Condition_Actions (P)), Ins_Actions);
1490                   else
1491                      Set_Condition_Actions (P, Ins_Actions);
1492
1493                      --  Set the parent of the insert actions explicitly.
1494                      --  This is not a syntactic field, but we need the
1495                      --  parent field set, in particular so that freeze
1496                      --  can understand that it is dealing with condition
1497                      --  actions, and properly insert the freezing actions.
1498
1499                      Set_Parent (Ins_Actions, P);
1500                      Analyze_List (Condition_Actions (P));
1501                   end if;
1502
1503                   return;
1504                end if;
1505
1506             --  Statements, declarations, pragmas, representation clauses.
1507
1508             when
1509                --  Statements
1510
1511                N_Procedure_Call_Statement               |
1512                N_Statement_Other_Than_Procedure_Call    |
1513
1514                --  Pragmas
1515
1516                N_Pragma                                 |
1517
1518                --  Representation_Clause
1519
1520                N_At_Clause                              |
1521                N_Attribute_Definition_Clause            |
1522                N_Enumeration_Representation_Clause      |
1523                N_Record_Representation_Clause           |
1524
1525                --  Declarations
1526
1527                N_Abstract_Subprogram_Declaration        |
1528                N_Entry_Body                             |
1529                N_Exception_Declaration                  |
1530                N_Exception_Renaming_Declaration         |
1531                N_Formal_Object_Declaration              |
1532                N_Formal_Subprogram_Declaration          |
1533                N_Formal_Type_Declaration                |
1534                N_Full_Type_Declaration                  |
1535                N_Function_Instantiation                 |
1536                N_Generic_Function_Renaming_Declaration  |
1537                N_Generic_Package_Declaration            |
1538                N_Generic_Package_Renaming_Declaration   |
1539                N_Generic_Procedure_Renaming_Declaration |
1540                N_Generic_Subprogram_Declaration         |
1541                N_Implicit_Label_Declaration             |
1542                N_Incomplete_Type_Declaration            |
1543                N_Number_Declaration                     |
1544                N_Object_Declaration                     |
1545                N_Object_Renaming_Declaration            |
1546                N_Package_Body                           |
1547                N_Package_Body_Stub                      |
1548                N_Package_Declaration                    |
1549                N_Package_Instantiation                  |
1550                N_Package_Renaming_Declaration           |
1551                N_Private_Extension_Declaration          |
1552                N_Private_Type_Declaration               |
1553                N_Procedure_Instantiation                |
1554                N_Protected_Body_Stub                    |
1555                N_Protected_Type_Declaration             |
1556                N_Single_Task_Declaration                |
1557                N_Subprogram_Body                        |
1558                N_Subprogram_Body_Stub                   |
1559                N_Subprogram_Declaration                 |
1560                N_Subprogram_Renaming_Declaration        |
1561                N_Subtype_Declaration                    |
1562                N_Task_Body                              |
1563                N_Task_Body_Stub                         |
1564                N_Task_Type_Declaration                  |
1565
1566                --  Freeze entity behaves like a declaration or statement
1567
1568                N_Freeze_Entity
1569             =>
1570                --  Do not insert here if the item is not a list member (this
1571                --  happens for example with a triggering statement, and the
1572                --  proper approach is to insert before the entire select).
1573
1574                if not Is_List_Member (P) then
1575                   null;
1576
1577                --  Do not insert if parent of P is an N_Component_Association
1578                --  node (i.e. we are in the context of an N_Aggregate node.
1579                --  In this case we want to insert before the entire aggregate.
1580
1581                elsif Nkind (Parent (P)) = N_Component_Association then
1582                   null;
1583
1584                --  Do not insert if the parent of P is either an N_Variant
1585                --  node or an N_Record_Definition node, meaning in either
1586                --  case that P is a member of a component list, and that
1587                --  therefore the actions should be inserted outside the
1588                --  complete record declaration.
1589
1590                elsif Nkind (Parent (P)) = N_Variant
1591                  or else Nkind (Parent (P)) = N_Record_Definition
1592                then
1593                   null;
1594
1595                --  Do not insert freeze nodes within the loop generated for
1596                --  an aggregate, because they may be elaborated too late for
1597                --  subsequent use in the back end: within a package spec the
1598                --  loop is part of the elaboration procedure and is only
1599                --  elaborated during the second pass.
1600                --  If the loop comes from source, or the entity is local to
1601                --  the loop itself it must remain within.
1602
1603                elsif Nkind (Parent (P)) = N_Loop_Statement
1604                  and then not Comes_From_Source (Parent (P))
1605                  and then Nkind (First (Ins_Actions)) = N_Freeze_Entity
1606                  and then
1607                    Scope (Entity (First (Ins_Actions))) /= Current_Scope
1608                then
1609                   null;
1610
1611                --  Otherwise we can go ahead and do the insertion
1612
1613                elsif  P = Wrapped_Node then
1614                   Store_Before_Actions_In_Scope (Ins_Actions);
1615                   return;
1616
1617                else
1618                   Insert_List_Before_And_Analyze (P, Ins_Actions);
1619                   return;
1620                end if;
1621
1622             --  A special case, N_Raise_xxx_Error can act either as a
1623             --  statement or a subexpression. We tell the difference
1624             --  by looking at the Etype. It is set to Standard_Void_Type
1625             --  in the statement case.
1626
1627             when
1628                N_Raise_xxx_Error =>
1629                   if Etype (P) = Standard_Void_Type then
1630                      if  P = Wrapped_Node then
1631                         Store_Before_Actions_In_Scope (Ins_Actions);
1632                      else
1633                         Insert_List_Before_And_Analyze (P, Ins_Actions);
1634                      end if;
1635
1636                      return;
1637
1638                   --  In the subexpression case, keep climbing
1639
1640                   else
1641                      null;
1642                   end if;
1643
1644             --  If a component association appears within a loop created for
1645             --  an array aggregate, attach the actions to the association so
1646             --  they can be subsequently inserted within the loop. For other
1647             --  component associations insert outside of the aggregate.
1648
1649             --  The list of loop_actions can in turn generate additional ones,
1650             --  that are inserted before the associated node. If the associated
1651             --  node is outside the aggregate, the new actions are collected
1652             --  at the end of the loop actions, to respect the order in which
1653             --  they are to be elaborated.
1654
1655             when
1656                N_Component_Association =>
1657                   if Nkind (Parent (P)) = N_Aggregate
1658                     and then Present (Aggregate_Bounds (Parent (P)))
1659                     and then Nkind (First (Choices (P))) = N_Others_Choice
1660                     and then Nkind (First (Ins_Actions)) /= N_Freeze_Entity
1661                   then
1662                      if No (Loop_Actions (P)) then
1663                         Set_Loop_Actions (P, Ins_Actions);
1664                         Analyze_List (Ins_Actions);
1665
1666                      else
1667                         declare
1668                            Decl : Node_Id := Assoc_Node;
1669
1670                         begin
1671                            --  Check whether these actions were generated
1672                            --  by a declaration that is part of the loop_
1673                            --  actions for the component_association.
1674
1675                            while Present (Decl) loop
1676                               exit when Parent (Decl) = P
1677                                 and then Is_List_Member (Decl)
1678                                 and then
1679                                   List_Containing (Decl) = Loop_Actions (P);
1680                               Decl := Parent (Decl);
1681                            end loop;
1682
1683                            if Present (Decl) then
1684                               Insert_List_Before_And_Analyze
1685                                 (Decl, Ins_Actions);
1686                            else
1687                               Insert_List_After_And_Analyze
1688                                 (Last (Loop_Actions (P)), Ins_Actions);
1689                            end if;
1690                         end;
1691                      end if;
1692
1693                      return;
1694
1695                   else
1696                      null;
1697                   end if;
1698
1699             --  Another special case, an attribute denoting a procedure call
1700
1701             when
1702                N_Attribute_Reference =>
1703                   if Is_Procedure_Attribute_Name (Attribute_Name (P)) then
1704                      if P = Wrapped_Node then
1705                         Store_Before_Actions_In_Scope (Ins_Actions);
1706                      else
1707                         Insert_List_Before_And_Analyze (P, Ins_Actions);
1708                      end if;
1709
1710                      return;
1711
1712                   --  In the subexpression case, keep climbing
1713
1714                   else
1715                      null;
1716                   end if;
1717
1718             --  For all other node types, keep climbing tree
1719
1720             when
1721                N_Abortable_Part                         |
1722                N_Accept_Alternative                     |
1723                N_Access_Definition                      |
1724                N_Access_Function_Definition             |
1725                N_Access_Procedure_Definition            |
1726                N_Access_To_Object_Definition            |
1727                N_Aggregate                              |
1728                N_Allocator                              |
1729                N_Case_Statement_Alternative             |
1730                N_Character_Literal                      |
1731                N_Compilation_Unit                       |
1732                N_Compilation_Unit_Aux                   |
1733                N_Component_Clause                       |
1734                N_Component_Declaration                  |
1735                N_Component_List                         |
1736                N_Constrained_Array_Definition           |
1737                N_Decimal_Fixed_Point_Definition         |
1738                N_Defining_Character_Literal             |
1739                N_Defining_Identifier                    |
1740                N_Defining_Operator_Symbol               |
1741                N_Defining_Program_Unit_Name             |
1742                N_Delay_Alternative                      |
1743                N_Delta_Constraint                       |
1744                N_Derived_Type_Definition                |
1745                N_Designator                             |
1746                N_Digits_Constraint                      |
1747                N_Discriminant_Association               |
1748                N_Discriminant_Specification             |
1749                N_Empty                                  |
1750                N_Entry_Body_Formal_Part                 |
1751                N_Entry_Call_Alternative                 |
1752                N_Entry_Declaration                      |
1753                N_Entry_Index_Specification              |
1754                N_Enumeration_Type_Definition            |
1755                N_Error                                  |
1756                N_Exception_Handler                      |
1757                N_Expanded_Name                          |
1758                N_Explicit_Dereference                   |
1759                N_Extension_Aggregate                    |
1760                N_Floating_Point_Definition              |
1761                N_Formal_Decimal_Fixed_Point_Definition  |
1762                N_Formal_Derived_Type_Definition         |
1763                N_Formal_Discrete_Type_Definition        |
1764                N_Formal_Floating_Point_Definition       |
1765                N_Formal_Modular_Type_Definition         |
1766                N_Formal_Ordinary_Fixed_Point_Definition |
1767                N_Formal_Package_Declaration             |
1768                N_Formal_Private_Type_Definition         |
1769                N_Formal_Signed_Integer_Type_Definition  |
1770                N_Function_Call                          |
1771                N_Function_Specification                 |
1772                N_Generic_Association                    |
1773                N_Handled_Sequence_Of_Statements         |
1774                N_Identifier                             |
1775                N_In                                     |
1776                N_Index_Or_Discriminant_Constraint       |
1777                N_Indexed_Component                      |
1778                N_Integer_Literal                        |
1779                N_Itype_Reference                        |
1780                N_Label                                  |
1781                N_Loop_Parameter_Specification           |
1782                N_Mod_Clause                             |
1783                N_Modular_Type_Definition                |
1784                N_Not_In                                 |
1785                N_Null                                   |
1786                N_Op_Abs                                 |
1787                N_Op_Add                                 |
1788                N_Op_And                                 |
1789                N_Op_Concat                              |
1790                N_Op_Divide                              |
1791                N_Op_Eq                                  |
1792                N_Op_Expon                               |
1793                N_Op_Ge                                  |
1794                N_Op_Gt                                  |
1795                N_Op_Le                                  |
1796                N_Op_Lt                                  |
1797                N_Op_Minus                               |
1798                N_Op_Mod                                 |
1799                N_Op_Multiply                            |
1800                N_Op_Ne                                  |
1801                N_Op_Not                                 |
1802                N_Op_Or                                  |
1803                N_Op_Plus                                |
1804                N_Op_Rem                                 |
1805                N_Op_Rotate_Left                         |
1806                N_Op_Rotate_Right                        |
1807                N_Op_Shift_Left                          |
1808                N_Op_Shift_Right                         |
1809                N_Op_Shift_Right_Arithmetic              |
1810                N_Op_Subtract                            |
1811                N_Op_Xor                                 |
1812                N_Operator_Symbol                        |
1813                N_Ordinary_Fixed_Point_Definition        |
1814                N_Others_Choice                          |
1815                N_Package_Specification                  |
1816                N_Parameter_Association                  |
1817                N_Parameter_Specification                |
1818                N_Pragma_Argument_Association            |
1819                N_Procedure_Specification                |
1820                N_Protected_Body                         |
1821                N_Protected_Definition                   |
1822                N_Qualified_Expression                   |
1823                N_Range                                  |
1824                N_Range_Constraint                       |
1825                N_Real_Literal                           |
1826                N_Real_Range_Specification               |
1827                N_Record_Definition                      |
1828                N_Reference                              |
1829                N_Selected_Component                     |
1830                N_Signed_Integer_Type_Definition         |
1831                N_Single_Protected_Declaration           |
1832                N_Slice                                  |
1833                N_String_Literal                         |
1834                N_Subprogram_Info                        |
1835                N_Subtype_Indication                     |
1836                N_Subunit                                |
1837                N_Task_Definition                        |
1838                N_Terminate_Alternative                  |
1839                N_Triggering_Alternative                 |
1840                N_Type_Conversion                        |
1841                N_Unchecked_Expression                   |
1842                N_Unchecked_Type_Conversion              |
1843                N_Unconstrained_Array_Definition         |
1844                N_Unused_At_End                          |
1845                N_Unused_At_Start                        |
1846                N_Use_Package_Clause                     |
1847                N_Use_Type_Clause                        |
1848                N_Variant                                |
1849                N_Variant_Part                           |
1850                N_Validate_Unchecked_Conversion          |
1851                N_With_Clause                            |
1852                N_With_Type_Clause
1853             =>
1854                null;
1855
1856          end case;
1857
1858          --  Make sure that inserted actions stay in the transient scope
1859
1860          if P = Wrapped_Node then
1861             Store_Before_Actions_In_Scope (Ins_Actions);
1862             return;
1863          end if;
1864
1865          --  If we fall through above tests, keep climbing tree
1866
1867          N := P;
1868
1869          if Nkind (Parent (N)) = N_Subunit then
1870
1871             --  This is the proper body corresponding to a stub. Insertion
1872             --  must be done at the point of the stub, which is in the decla-
1873             --  tive part of the parent unit.
1874
1875             P := Corresponding_Stub (Parent (N));
1876
1877          else
1878             P := Parent (N);
1879          end if;
1880       end loop;
1881
1882    end Insert_Actions;
1883
1884    --  Version with check(s) suppressed
1885
1886    procedure Insert_Actions
1887      (Assoc_Node : Node_Id; Ins_Actions : List_Id; Suppress : Check_Id)
1888    is
1889    begin
1890       if Suppress = All_Checks then
1891          declare
1892             Svg : constant Suppress_Record := Scope_Suppress;
1893
1894          begin
1895             Scope_Suppress := (others => True);
1896             Insert_Actions (Assoc_Node, Ins_Actions);
1897             Scope_Suppress := Svg;
1898          end;
1899
1900       else
1901          declare
1902             Svg : constant Boolean := Get_Scope_Suppress (Suppress);
1903
1904          begin
1905             Set_Scope_Suppress (Suppress, True);
1906             Insert_Actions (Assoc_Node, Ins_Actions);
1907             Set_Scope_Suppress (Suppress, Svg);
1908          end;
1909       end if;
1910    end Insert_Actions;
1911
1912    --------------------------
1913    -- Insert_Actions_After --
1914    --------------------------
1915
1916    procedure Insert_Actions_After
1917      (Assoc_Node  : Node_Id;
1918       Ins_Actions : List_Id)
1919    is
1920    begin
1921       if Scope_Is_Transient
1922         and then Assoc_Node = Node_To_Be_Wrapped
1923       then
1924          Store_After_Actions_In_Scope (Ins_Actions);
1925       else
1926          Insert_List_After_And_Analyze (Assoc_Node, Ins_Actions);
1927       end if;
1928    end Insert_Actions_After;
1929
1930    ---------------------------------
1931    -- Insert_Library_Level_Action --
1932    ---------------------------------
1933
1934    procedure Insert_Library_Level_Action (N : Node_Id) is
1935       Aux : constant Node_Id := Aux_Decls_Node (Cunit (Main_Unit));
1936
1937    begin
1938       New_Scope (Cunit_Entity (Main_Unit));
1939
1940       if No (Actions (Aux)) then
1941          Set_Actions (Aux, New_List (N));
1942       else
1943          Append (N, Actions (Aux));
1944       end if;
1945
1946       Analyze (N);
1947       Pop_Scope;
1948    end Insert_Library_Level_Action;
1949
1950    ----------------------------------
1951    -- Insert_Library_Level_Actions --
1952    ----------------------------------
1953
1954    procedure Insert_Library_Level_Actions (L : List_Id) is
1955       Aux : constant Node_Id := Aux_Decls_Node (Cunit (Main_Unit));
1956
1957    begin
1958       if Is_Non_Empty_List (L) then
1959          New_Scope (Cunit_Entity (Main_Unit));
1960
1961          if No (Actions (Aux)) then
1962             Set_Actions (Aux, L);
1963             Analyze_List (L);
1964          else
1965             Insert_List_After_And_Analyze (Last (Actions (Aux)), L);
1966          end if;
1967
1968          Pop_Scope;
1969       end if;
1970    end Insert_Library_Level_Actions;
1971
1972    ----------------------
1973    -- Inside_Init_Proc --
1974    ----------------------
1975
1976    function Inside_Init_Proc return Boolean is
1977       S : Entity_Id;
1978
1979    begin
1980       S := Current_Scope;
1981       while S /= Standard_Standard loop
1982          if Chars (S) = Name_uInit_Proc then
1983             return True;
1984          else
1985             S := Scope (S);
1986          end if;
1987       end loop;
1988
1989       return False;
1990    end Inside_Init_Proc;
1991
1992    --------------------------------
1993    -- Is_Ref_To_Bit_Packed_Array --
1994    --------------------------------
1995
1996    function Is_Ref_To_Bit_Packed_Array (P : Node_Id) return Boolean is
1997       Result : Boolean;
1998       Expr   : Node_Id;
1999
2000    begin
2001       if Nkind (P) = N_Indexed_Component
2002            or else
2003          Nkind (P) = N_Selected_Component
2004       then
2005          if Is_Bit_Packed_Array (Etype (Prefix (P))) then
2006             Result := True;
2007          else
2008             Result := Is_Ref_To_Bit_Packed_Array (Prefix (P));
2009          end if;
2010
2011          if Result and then Nkind (P) = N_Indexed_Component then
2012             Expr := First (Expressions (P));
2013
2014             while Present (Expr) loop
2015                Force_Evaluation (Expr);
2016                Next (Expr);
2017             end loop;
2018          end if;
2019
2020          return Result;
2021
2022       else
2023          return False;
2024       end if;
2025    end Is_Ref_To_Bit_Packed_Array;
2026
2027    --------------------------------
2028    -- Is_Ref_To_Bit_Packed_Slce --
2029    --------------------------------
2030
2031    function Is_Ref_To_Bit_Packed_Slice (P : Node_Id) return Boolean is
2032    begin
2033       if Nkind (P) = N_Slice
2034         and then Is_Bit_Packed_Array (Etype (Prefix (P)))
2035       then
2036          return True;
2037
2038       elsif Nkind (P) = N_Indexed_Component
2039            or else
2040          Nkind (P) = N_Selected_Component
2041       then
2042          return Is_Ref_To_Bit_Packed_Slice (Prefix (P));
2043
2044       else
2045          return False;
2046       end if;
2047    end Is_Ref_To_Bit_Packed_Slice;
2048
2049    -----------------------
2050    -- Is_Renamed_Object --
2051    -----------------------
2052
2053    function Is_Renamed_Object (N : Node_Id) return Boolean is
2054       Pnod : constant Node_Id   := Parent (N);
2055       Kind : constant Node_Kind := Nkind (Pnod);
2056
2057    begin
2058       if Kind = N_Object_Renaming_Declaration then
2059          return True;
2060
2061       elsif Kind = N_Indexed_Component
2062         or else Kind = N_Selected_Component
2063       then
2064          return Is_Renamed_Object (Pnod);
2065
2066       else
2067          return False;
2068       end if;
2069    end Is_Renamed_Object;
2070
2071    ----------------------------
2072    -- Is_Untagged_Derivation --
2073    ----------------------------
2074
2075    function Is_Untagged_Derivation (T : Entity_Id) return Boolean is
2076    begin
2077       return (not Is_Tagged_Type (T) and then Is_Derived_Type (T))
2078                or else
2079              (Is_Private_Type (T) and then Present (Full_View (T))
2080                and then not Is_Tagged_Type (Full_View (T))
2081                and then Is_Derived_Type (Full_View (T))
2082                and then Etype (Full_View (T)) /= T);
2083
2084    end Is_Untagged_Derivation;
2085
2086    --------------------
2087    -- Kill_Dead_Code --
2088    --------------------
2089
2090    procedure Kill_Dead_Code (N : Node_Id) is
2091    begin
2092       if Present (N) then
2093          Remove_Handler_Entries (N);
2094          Remove_Warning_Messages (N);
2095
2096          --  Recurse into block statements to process declarations/statements
2097
2098          if Nkind (N) = N_Block_Statement then
2099             Kill_Dead_Code (Declarations (N));
2100             Kill_Dead_Code (Statements (Handled_Statement_Sequence (N)));
2101
2102          --  Recurse into composite statement to kill individual statements,
2103          --  in particular instantiations.
2104
2105          elsif Nkind (N) = N_If_Statement then
2106             Kill_Dead_Code (Then_Statements (N));
2107             Kill_Dead_Code (Elsif_Parts (N));
2108             Kill_Dead_Code (Else_Statements (N));
2109
2110          elsif Nkind (N) = N_Loop_Statement then
2111             Kill_Dead_Code (Statements (N));
2112
2113          elsif Nkind (N) = N_Case_Statement then
2114             declare
2115                Alt : Node_Id := First (Alternatives (N));
2116
2117             begin
2118                while Present (Alt) loop
2119                   Kill_Dead_Code (Statements (Alt));
2120                   Next (Alt);
2121                end loop;
2122             end;
2123
2124          --  Deal with dead instances caused by deleting instantiations
2125
2126          elsif Nkind (N) in N_Generic_Instantiation then
2127             Remove_Dead_Instance (N);
2128          end if;
2129
2130          Delete_Tree (N);
2131       end if;
2132    end Kill_Dead_Code;
2133
2134    --  Case where argument is a list of nodes to be killed
2135
2136    procedure Kill_Dead_Code (L : List_Id) is
2137       N : Node_Id;
2138
2139    begin
2140       if Is_Non_Empty_List (L) then
2141          loop
2142             N := Remove_Head (L);
2143             exit when No (N);
2144             Kill_Dead_Code (N);
2145          end loop;
2146       end if;
2147    end Kill_Dead_Code;
2148
2149    ------------------------
2150    -- Known_Non_Negative --
2151    ------------------------
2152
2153    function Known_Non_Negative (Opnd : Node_Id) return Boolean is
2154    begin
2155       if Is_OK_Static_Expression (Opnd)
2156         and then Expr_Value (Opnd) >= 0
2157       then
2158          return True;
2159
2160       else
2161          declare
2162             Lo : constant Node_Id := Type_Low_Bound (Etype (Opnd));
2163
2164          begin
2165             return
2166               Is_OK_Static_Expression (Lo) and then Expr_Value (Lo) >= 0;
2167          end;
2168       end if;
2169    end Known_Non_Negative;
2170
2171    -----------------------------
2172    -- Make_CW_Equivalent_Type --
2173    -----------------------------
2174
2175    --  Create a record type used as an equivalent of any member
2176    --  of the class which takes its size from exp.
2177
2178    --  Generate the following code:
2179
2180    --   type Equiv_T is record
2181    --     _parent :  T (List of discriminant constaints taken from Exp);
2182    --     Ext__50 : Storage_Array (1 .. (Exp'size - Typ'size) / Storage_Unit);
2183    --   end Equiv_T;
2184
2185    function Make_CW_Equivalent_Type
2186      (T    : Entity_Id;
2187       E    : Node_Id)
2188       return Entity_Id
2189    is
2190       Loc         : constant Source_Ptr := Sloc (E);
2191       Root_Typ    : constant Entity_Id  := Root_Type (T);
2192       Equiv_Type  : Entity_Id;
2193       Range_Type  : Entity_Id;
2194       Str_Type    : Entity_Id;
2195       List_Def    : List_Id := Empty_List;
2196       Constr_Root : Entity_Id;
2197       Sizexpr     : Node_Id;
2198
2199    begin
2200       if not Has_Discriminants (Root_Typ) then
2201          Constr_Root := Root_Typ;
2202       else
2203          Constr_Root :=
2204            Make_Defining_Identifier (Loc, New_Internal_Name ('R'));
2205
2206          --  subtype cstr__n is T (List of discr constraints taken from Exp)
2207
2208          Append_To (List_Def,
2209            Make_Subtype_Declaration (Loc,
2210              Defining_Identifier => Constr_Root,
2211                Subtype_Indication =>
2212                  Make_Subtype_From_Expr (E, Root_Typ)));
2213       end if;
2214
2215       --  subtype rg__xx is Storage_Offset range
2216       --                           (Expr'size - typ'size) / Storage_Unit
2217
2218       Range_Type := Make_Defining_Identifier (Loc, New_Internal_Name ('G'));
2219
2220       Sizexpr :=
2221         Make_Op_Subtract (Loc,
2222           Left_Opnd =>
2223             Make_Attribute_Reference (Loc,
2224               Prefix         => OK_Convert_To (T, Duplicate_Subexpr (E)),
2225               Attribute_Name => Name_Size),
2226           Right_Opnd =>
2227             Make_Attribute_Reference (Loc,
2228               Prefix => New_Reference_To (Constr_Root, Loc),
2229               Attribute_Name => Name_Size));
2230
2231       Set_Paren_Count (Sizexpr, 1);
2232
2233       Append_To (List_Def,
2234         Make_Subtype_Declaration (Loc,
2235           Defining_Identifier => Range_Type,
2236           Subtype_Indication =>
2237             Make_Subtype_Indication (Loc,
2238               Subtype_Mark => New_Reference_To (RTE (RE_Storage_Offset), Loc),
2239               Constraint => Make_Range_Constraint (Loc,
2240                 Range_Expression =>
2241                   Make_Range (Loc,
2242                     Low_Bound => Make_Integer_Literal (Loc, 1),
2243                     High_Bound =>
2244                       Make_Op_Divide (Loc,
2245                         Left_Opnd => Sizexpr,
2246                         Right_Opnd => Make_Integer_Literal (Loc,
2247                             Intval => System_Storage_Unit)))))));
2248
2249       --  subtype str__nn is Storage_Array (rg__x);
2250
2251       Str_Type := Make_Defining_Identifier (Loc, New_Internal_Name ('S'));
2252       Append_To (List_Def,
2253         Make_Subtype_Declaration (Loc,
2254           Defining_Identifier => Str_Type,
2255           Subtype_Indication =>
2256             Make_Subtype_Indication (Loc,
2257               Subtype_Mark => New_Reference_To (RTE (RE_Storage_Array), Loc),
2258               Constraint =>
2259                 Make_Index_Or_Discriminant_Constraint (Loc,
2260                   Constraints =>
2261                     New_List (New_Reference_To (Range_Type, Loc))))));
2262
2263       --  type Equiv_T is record
2264       --    _parent : Tnn;
2265       --    E : Str_Type;
2266       --  end Equiv_T;
2267
2268       Equiv_Type := Make_Defining_Identifier (Loc, New_Internal_Name ('T'));
2269
2270       --  Avoid the generation of an init procedure
2271
2272       Set_Is_Frozen (Equiv_Type);
2273
2274       Set_Ekind (Equiv_Type, E_Record_Type);
2275       Set_Parent_Subtype (Equiv_Type, Constr_Root);
2276
2277       Append_To (List_Def,
2278         Make_Full_Type_Declaration (Loc,
2279           Defining_Identifier => Equiv_Type,
2280
2281           Type_Definition =>
2282             Make_Record_Definition (Loc,
2283               Component_List => Make_Component_List (Loc,
2284                 Component_Items => New_List (
2285                   Make_Component_Declaration (Loc,
2286                     Defining_Identifier =>
2287                       Make_Defining_Identifier (Loc, Name_uParent),
2288                     Subtype_Indication => New_Reference_To (Constr_Root, Loc)),
2289
2290                   Make_Component_Declaration (Loc,
2291                     Defining_Identifier =>
2292                       Make_Defining_Identifier (Loc,
2293                         Chars => New_Internal_Name ('C')),
2294                     Subtype_Indication => New_Reference_To (Str_Type, Loc))),
2295                 Variant_Part => Empty))));
2296
2297       Insert_Actions (E, List_Def);
2298       return Equiv_Type;
2299    end Make_CW_Equivalent_Type;
2300
2301    ------------------------
2302    -- Make_Literal_Range --
2303    ------------------------
2304
2305    function Make_Literal_Range
2306      (Loc         : Source_Ptr;
2307       Literal_Typ : Entity_Id)
2308       return        Node_Id
2309    is
2310       Lo : Node_Id :=
2311              New_Copy_Tree (String_Literal_Low_Bound (Literal_Typ));
2312
2313    begin
2314       Set_Analyzed (Lo, False);
2315
2316          return
2317            Make_Range (Loc,
2318              Low_Bound => Lo,
2319
2320              High_Bound =>
2321                Make_Op_Subtract (Loc,
2322                   Left_Opnd =>
2323                     Make_Op_Add (Loc,
2324                       Left_Opnd  => New_Copy_Tree (Lo),
2325                       Right_Opnd =>
2326                         Make_Integer_Literal (Loc,
2327                           String_Literal_Length (Literal_Typ))),
2328                   Right_Opnd => Make_Integer_Literal (Loc, 1)));
2329    end Make_Literal_Range;
2330
2331    ----------------------------
2332    -- Make_Subtype_From_Expr --
2333    ----------------------------
2334
2335    --  1. If Expr is an uncontrained array expression, creates
2336    --    Unc_Type(Expr'first(1)..Expr'Last(1),..., Expr'first(n)..Expr'last(n))
2337
2338    --  2. If Expr is a unconstrained discriminated type expression, creates
2339    --    Unc_Type(Expr.Discr1, ... , Expr.Discr_n)
2340
2341    --  3. If Expr is class-wide, creates an implicit class wide subtype
2342
2343    function Make_Subtype_From_Expr
2344      (E       : Node_Id;
2345       Unc_Typ : Entity_Id)
2346       return    Node_Id
2347    is
2348       Loc         : constant Source_Ptr := Sloc (E);
2349       List_Constr : List_Id := New_List;
2350       D           : Entity_Id;
2351
2352       Full_Subtyp  : Entity_Id;
2353       Priv_Subtyp  : Entity_Id;
2354       Utyp         : Entity_Id;
2355       Full_Exp     : Node_Id;
2356
2357    begin
2358       if Is_Private_Type (Unc_Typ)
2359         and then Has_Unknown_Discriminants (Unc_Typ)
2360       then
2361          --  Prepare the subtype completion
2362
2363          Utyp        := Underlying_Type (Unc_Typ);
2364          Full_Subtyp := Make_Defining_Identifier (Loc,
2365                           New_Internal_Name ('C'));
2366          Full_Exp    := Unchecked_Convert_To (Utyp, Duplicate_Subexpr (E));
2367          Set_Parent (Full_Exp, Parent (E));
2368
2369          Priv_Subtyp :=
2370            Make_Defining_Identifier (Loc, New_Internal_Name ('P'));
2371
2372          Insert_Action (E,
2373            Make_Subtype_Declaration (Loc,
2374              Defining_Identifier => Full_Subtyp,
2375              Subtype_Indication  => Make_Subtype_From_Expr (Full_Exp, Utyp)));
2376
2377          --  Define the dummy private subtype
2378
2379          Set_Ekind          (Priv_Subtyp, Subtype_Kind (Ekind (Unc_Typ)));
2380          Set_Etype          (Priv_Subtyp, Unc_Typ);
2381          Set_Scope          (Priv_Subtyp, Full_Subtyp);
2382          Set_Is_Constrained (Priv_Subtyp);
2383          Set_Is_Tagged_Type (Priv_Subtyp, Is_Tagged_Type (Unc_Typ));
2384          Set_Is_Itype       (Priv_Subtyp);
2385          Set_Associated_Node_For_Itype (Priv_Subtyp, E);
2386
2387          if Is_Tagged_Type  (Priv_Subtyp) then
2388             Set_Class_Wide_Type
2389               (Base_Type (Priv_Subtyp), Class_Wide_Type (Unc_Typ));
2390             Set_Primitive_Operations (Priv_Subtyp,
2391               Primitive_Operations (Unc_Typ));
2392          end if;
2393
2394          Set_Full_View (Priv_Subtyp, Full_Subtyp);
2395
2396          return New_Reference_To (Priv_Subtyp, Loc);
2397
2398       elsif Is_Array_Type (Unc_Typ) then
2399          for J in 1 .. Number_Dimensions (Unc_Typ) loop
2400             Append_To (List_Constr,
2401               Make_Range (Loc,
2402                 Low_Bound =>
2403                   Make_Attribute_Reference (Loc,
2404                     Prefix => Duplicate_Subexpr (E),
2405                     Attribute_Name => Name_First,
2406                     Expressions => New_List (
2407                       Make_Integer_Literal (Loc, J))),
2408                 High_Bound =>
2409                   Make_Attribute_Reference (Loc,
2410                     Prefix         => Duplicate_Subexpr (E),
2411                     Attribute_Name => Name_Last,
2412                     Expressions    => New_List (
2413                       Make_Integer_Literal (Loc, J)))));
2414          end loop;
2415
2416       elsif Is_Class_Wide_Type (Unc_Typ) then
2417          declare
2418             CW_Subtype : Entity_Id;
2419             EQ_Typ     : Entity_Id := Empty;
2420
2421          begin
2422             --  A class-wide equivalent type is not needed when Java_VM
2423             --  because the JVM back end handles the class-wide object
2424             --  initialization itself (and doesn't need or want the
2425             --  additional intermediate type to handle the assignment).
2426
2427             if Expander_Active and then not Java_VM then
2428                EQ_Typ := Make_CW_Equivalent_Type (Unc_Typ, E);
2429             end if;
2430
2431             CW_Subtype := New_Class_Wide_Subtype (Unc_Typ, E);
2432             Set_Equivalent_Type (CW_Subtype, EQ_Typ);
2433             Set_Cloned_Subtype (CW_Subtype, Base_Type (Unc_Typ));
2434
2435             return New_Occurrence_Of (CW_Subtype, Loc);
2436          end;
2437
2438       else
2439          D := First_Discriminant (Unc_Typ);
2440          while (Present (D)) loop
2441
2442             Append_To (List_Constr,
2443               Make_Selected_Component (Loc,
2444                 Prefix        => Duplicate_Subexpr (E),
2445                 Selector_Name => New_Reference_To (D, Loc)));
2446
2447             Next_Discriminant (D);
2448          end loop;
2449       end if;
2450
2451       return
2452         Make_Subtype_Indication (Loc,
2453           Subtype_Mark => New_Reference_To (Unc_Typ, Loc),
2454           Constraint   =>
2455             Make_Index_Or_Discriminant_Constraint (Loc,
2456               Constraints => List_Constr));
2457    end Make_Subtype_From_Expr;
2458
2459    -----------------------------
2460    -- May_Generate_Large_Temp --
2461    -----------------------------
2462
2463    --  At the current time, the only types that we return False for (i.e.
2464    --  where we decide we know they cannot generate large temps) are ones
2465    --  where we know the size is 128 bits or less at compile time, and we
2466    --  are still not doing a thorough job on arrays and records ???
2467
2468    function May_Generate_Large_Temp (Typ : Entity_Id) return Boolean is
2469    begin
2470       if not Stack_Checking_Enabled then
2471          return False;
2472
2473       elsif not Size_Known_At_Compile_Time (Typ) then
2474          return False;
2475
2476       elsif Esize (Typ) /= 0 and then Esize (Typ) <= 256 then
2477          return False;
2478
2479       elsif Is_Array_Type (Typ)
2480         and then Present (Packed_Array_Type (Typ))
2481       then
2482          return May_Generate_Large_Temp (Packed_Array_Type (Typ));
2483
2484       --  We could do more here to find other small types ???
2485
2486       else
2487          return True;
2488       end if;
2489    end May_Generate_Large_Temp;
2490
2491    ----------------------------
2492    -- New_Class_Wide_Subtype --
2493    ----------------------------
2494
2495    function New_Class_Wide_Subtype
2496      (CW_Typ : Entity_Id;
2497       N      : Node_Id)
2498       return   Entity_Id
2499    is
2500       Res      : Entity_Id := Create_Itype (E_Void, N);
2501       Res_Name : constant Name_Id := Chars (Res);
2502       Res_Scope : Entity_Id := Scope (Res);
2503
2504    begin
2505       Copy_Node (CW_Typ, Res);
2506       Set_Sloc (Res, Sloc (N));
2507       Set_Is_Itype (Res);
2508       Set_Associated_Node_For_Itype (Res, N);
2509       Set_Is_Public (Res, False);   --  By default, may be changed below.
2510       Set_Public_Status (Res);
2511       Set_Chars (Res, Res_Name);
2512       Set_Scope (Res, Res_Scope);
2513       Set_Ekind (Res, E_Class_Wide_Subtype);
2514       Set_Next_Entity (Res, Empty);
2515       Set_Etype (Res, Base_Type (CW_Typ));
2516       Set_Freeze_Node (Res, Empty);
2517       return (Res);
2518    end New_Class_Wide_Subtype;
2519
2520    -------------------------
2521    -- Remove_Side_Effects --
2522    -------------------------
2523
2524    procedure Remove_Side_Effects
2525      (Exp          : Node_Id;
2526       Name_Req     : Boolean := False;
2527       Variable_Ref : Boolean := False)
2528    is
2529       Loc          : constant Source_Ptr := Sloc (Exp);
2530       Exp_Type     : constant Entity_Id  := Etype (Exp);
2531       Svg_Suppress : constant Suppress_Record := Scope_Suppress;
2532       Def_Id       : Entity_Id;
2533       Ref_Type     : Entity_Id;
2534       Res          : Node_Id;
2535       Ptr_Typ_Decl : Node_Id;
2536       New_Exp      : Node_Id;
2537       E            : Node_Id;
2538
2539       function Side_Effect_Free (N : Node_Id) return Boolean;
2540       --  Determines if the tree N represents an expession that is known
2541       --  not to have side effects, and for which no processing is required.
2542
2543       function Side_Effect_Free (L : List_Id) return Boolean;
2544       --  Determines if all elements of the list L are side effect free
2545
2546       function Mutable_Dereference (N : Node_Id) return Boolean;
2547       --  If a selected component involves an implicit dereference and
2548       --  the type of the prefix is not an_access_to_constant, the node
2549       --  must be evaluated because it may be affected by a subsequent
2550       --  assignment.
2551
2552       -------------------------
2553       -- Mutable_Dereference --
2554       -------------------------
2555
2556       function Mutable_Dereference (N : Node_Id) return Boolean is
2557       begin
2558          return Nkind (N) = N_Selected_Component
2559            and then Is_Access_Type (Etype (Prefix (N)))
2560            and then not Is_Access_Constant (Etype (Prefix (N)))
2561            and then Variable_Ref;
2562       end Mutable_Dereference;
2563
2564       ----------------------
2565       -- Side_Effect_Free --
2566       ----------------------
2567
2568       function Side_Effect_Free (N : Node_Id) return Boolean is
2569          K : constant Node_Kind := Nkind (N);
2570
2571       begin
2572          --  Note on checks that could raise Constraint_Error. Strictly, if
2573          --  we take advantage of 11.6, these checks do not count as side
2574          --  effects. However, we would just as soon consider that they are
2575          --  side effects, since the backend CSE does not work very well on
2576          --  expressions which can raise Constraint_Error. On the other
2577          --  hand, if we do not consider them to be side effect free, then
2578          --  we get some awkward expansions in -gnato mode, resulting in
2579          --  code insertions at a point where we do not have a clear model
2580          --  for performing the insertions. See 4908-002/comment for details.
2581
2582          --  An attribute reference is side effect free if its expressions
2583          --  are side effect free and its prefix is (could be a dereference
2584          --  or an indexed retrieval for example).
2585
2586          if K = N_Attribute_Reference then
2587             return Side_Effect_Free (Expressions (N))
2588               and then (Is_Entity_Name (Prefix (N))
2589                          or else Side_Effect_Free (Prefix (N)));
2590
2591          --  An entity is side effect free unless it is a function call, or
2592          --  a reference to a volatile variable and Name_Req is False. If
2593          --  Name_Req is True then we can't help returning a name which
2594          --  effectively allows multiple references in any case.
2595
2596          elsif Is_Entity_Name (N)
2597            and then Ekind (Entity (N)) /= E_Function
2598            and then (not Is_Volatile (Entity (N)) or else Name_Req)
2599          then
2600             --  If the entity is a constant, it is definitely side effect
2601             --  free. Note that the test of Is_Variable (N) below might
2602             --  be expected to catch this case, but it does not, because
2603             --  this test goes to the original tree, and we may have
2604             --  already rewritten a variable node with a constant as
2605             --  a result of an earlier Force_Evaluation call.
2606
2607             if Ekind (Entity (N)) = E_Constant then
2608                return True;
2609
2610             --  If the Variable_Ref flag is set, any variable reference is
2611             --  is considered a side-effect
2612
2613             elsif Variable_Ref then
2614                return not Is_Variable (N);
2615
2616             else
2617                return True;
2618             end if;
2619
2620          --  A value known at compile time is always side effect free
2621
2622          elsif Compile_Time_Known_Value (N) then
2623             return True;
2624
2625          --  Literals are always side-effect free
2626
2627          elsif (K = N_Integer_Literal
2628                  or else K = N_Real_Literal
2629                  or else K = N_Character_Literal
2630                  or else K = N_String_Literal
2631                  or else K = N_Null)
2632            and then not Raises_Constraint_Error (N)
2633          then
2634             return True;
2635
2636          --  A type conversion or qualification is side effect free if the
2637          --  expression to be converted is side effect free.
2638
2639          elsif K = N_Type_Conversion or else K = N_Qualified_Expression then
2640             return Side_Effect_Free (Expression (N));
2641
2642          --  An unchecked type conversion is never side effect free since we
2643          --  need to check whether it is safe.
2644          --  effect free if its argument is side effect free.
2645
2646          elsif K = N_Unchecked_Type_Conversion then
2647             if Safe_Unchecked_Type_Conversion (N) then
2648                return Side_Effect_Free (Expression (N));
2649             else
2650                return False;
2651             end if;
2652
2653          --  A unary operator is side effect free if the operand
2654          --  is side effect free.
2655
2656          elsif K in N_Unary_Op then
2657             return Side_Effect_Free (Right_Opnd (N));
2658
2659          --  A binary operator is side effect free if and both operands
2660          --  are side effect free.
2661
2662          elsif K in N_Binary_Op then
2663             return Side_Effect_Free (Left_Opnd  (N))
2664               and then Side_Effect_Free (Right_Opnd (N));
2665
2666          --  An explicit dereference or selected component is side effect
2667          --  free if its prefix is side effect free.
2668
2669          elsif K = N_Explicit_Dereference
2670            or else K = N_Selected_Component
2671          then
2672             return Side_Effect_Free (Prefix (N))
2673               and then not Mutable_Dereference (Prefix (N));
2674
2675          --  An indexed component can be copied if the prefix is copyable
2676          --  and all the indexing expressions are copyable and there is
2677          --  no access check and no range checks.
2678
2679          elsif K = N_Indexed_Component then
2680             return Side_Effect_Free (Prefix (N))
2681               and then Side_Effect_Free (Expressions (N));
2682
2683          elsif K = N_Unchecked_Expression then
2684             return Side_Effect_Free (Expression (N));
2685
2686          --  A call to _rep_to_pos is side effect free, since we generate
2687          --  this pure function call ourselves. Moreover it is critically
2688          --  important to make this exception, since otherwise we can
2689          --  have discriminants in array components which don't look
2690          --  side effect free in the case of an array whose index type
2691          --  is an enumeration type with an enumeration rep clause.
2692
2693          elsif K = N_Function_Call
2694            and then Nkind (Name (N)) = N_Identifier
2695            and then Chars (Name (N)) = Name_uRep_To_Pos
2696          then
2697             return True;
2698
2699          --  We consider that anything else has side effects. This is a bit
2700          --  crude, but we are pretty close for most common cases, and we
2701          --  are certainly correct (i.e. we never return True when the
2702          --  answer should be False).
2703
2704          else
2705             return False;
2706          end if;
2707       end Side_Effect_Free;
2708
2709       function Side_Effect_Free (L : List_Id) return Boolean is
2710          N : Node_Id;
2711
2712       begin
2713          if L = No_List or else L = Error_List then
2714             return True;
2715
2716          else
2717             N := First (L);
2718
2719             while Present (N) loop
2720                if not Side_Effect_Free (N) then
2721                   return False;
2722                else
2723                   Next (N);
2724                end if;
2725             end loop;
2726
2727             return True;
2728          end if;
2729       end Side_Effect_Free;
2730
2731    --  Start of processing for Remove_Side_Effects
2732
2733    begin
2734       --  If we are side effect free already or expansion is disabled,
2735       --  there is nothing to do.
2736
2737       if Side_Effect_Free (Exp) or else not Expander_Active then
2738          return;
2739       end if;
2740
2741       --  All the must not have any checks
2742
2743       Scope_Suppress := (others => True);
2744
2745       --  If the expression has the form v.all then we can just capture
2746       --  the pointer, and then do an explicit dereference on the result.
2747
2748       if Nkind (Exp) = N_Explicit_Dereference then
2749          Def_Id :=
2750            Make_Defining_Identifier (Loc, New_Internal_Name ('R'));
2751          Res :=
2752            Make_Explicit_Dereference (Loc, New_Reference_To (Def_Id, Loc));
2753
2754          Insert_Action (Exp,
2755            Make_Object_Declaration (Loc,
2756              Defining_Identifier => Def_Id,
2757              Object_Definition   =>
2758                New_Reference_To (Etype (Prefix (Exp)), Loc),
2759              Constant_Present    => True,
2760              Expression          => Relocate_Node (Prefix (Exp))));
2761
2762       --  If this is a type conversion, leave the type conversion and remove
2763       --  the side effects in the expression. This is important in several
2764       --  circumstances: for change of representations, and also when this
2765       --  is a view conversion to a smaller object, where gigi can end up
2766       --  its own temporary of the wrong size.
2767
2768       --  ??? this transformation is inhibited for elementary types that are
2769       --  not involved in a change of representation because it causes
2770       --  regressions that are not fully understood yet.
2771
2772       elsif Nkind (Exp) = N_Type_Conversion
2773         and then (not Is_Elementary_Type (Underlying_Type (Exp_Type))
2774                    or else Nkind (Parent (Exp)) = N_Assignment_Statement)
2775       then
2776          Remove_Side_Effects (Expression (Exp), Variable_Ref);
2777          Scope_Suppress := Svg_Suppress;
2778          return;
2779
2780       --  For expressions that denote objects, we can use a renaming scheme.
2781       --  We skip using this if we have a volatile variable and we do not
2782       --  have Nam_Req set true (see comments above for Side_Effect_Free).
2783       --  We also skip this scheme for class-wide expressions in order to
2784       --  avoid recursive expension (see Expand_N_Object_Renaming_Declaration)
2785       --  If the object is a function call, we need to create a temporary and
2786       --  not a renaming.
2787
2788       elsif Is_Object_Reference (Exp)
2789         and then Nkind (Exp) /= N_Function_Call
2790         and then not Variable_Ref
2791         and then (Name_Req
2792                    or else not Is_Entity_Name (Exp)
2793                    or else not Is_Volatile (Entity (Exp)))
2794         and then not Is_Class_Wide_Type (Exp_Type)
2795       then
2796          Def_Id := Make_Defining_Identifier (Loc, New_Internal_Name ('R'));
2797
2798          if Nkind (Exp) = N_Selected_Component
2799            and then Nkind (Prefix (Exp)) = N_Function_Call
2800            and then Is_Array_Type (Etype (Exp))
2801          then
2802             --  Avoid generating a variable-sized temporary, by generating
2803             --  the renaming declaration just for the function call. The
2804             --  transformation could be refined to apply only when the array
2805             --  component is constrained by a discriminant???
2806
2807             Res :=
2808               Make_Selected_Component (Loc,
2809                 Prefix => New_Occurrence_Of (Def_Id, Loc),
2810                 Selector_Name => Selector_Name (Exp));
2811
2812             Insert_Action (Exp,
2813               Make_Object_Renaming_Declaration (Loc,
2814                 Defining_Identifier => Def_Id,
2815                 Subtype_Mark        =>
2816                   New_Reference_To (Base_Type (Etype (Prefix (Exp))), Loc),
2817                 Name                => Relocate_Node (Prefix (Exp))));
2818          else
2819             Res := New_Reference_To (Def_Id, Loc);
2820
2821             Insert_Action (Exp,
2822               Make_Object_Renaming_Declaration (Loc,
2823                 Defining_Identifier => Def_Id,
2824                 Subtype_Mark        => New_Reference_To (Exp_Type, Loc),
2825                 Name                => Relocate_Node (Exp)));
2826          end if;
2827
2828       --  If it is a scalar type, just make a copy.
2829
2830       elsif Is_Elementary_Type (Exp_Type) then
2831          Def_Id := Make_Defining_Identifier (Loc, New_Internal_Name ('R'));
2832          Set_Etype (Def_Id, Exp_Type);
2833          Res := New_Reference_To (Def_Id, Loc);
2834
2835          E :=
2836            Make_Object_Declaration (Loc,
2837              Defining_Identifier => Def_Id,
2838              Object_Definition   => New_Reference_To (Exp_Type, Loc),
2839              Constant_Present    => True,
2840              Expression          => Relocate_Node (Exp));
2841
2842          Set_Assignment_OK (E);
2843          Insert_Action (Exp, E);
2844
2845       --  If this is an unchecked conversion that Gigi can't handle, make
2846       --  a copy or a use a renaming to capture the value.
2847
2848       elsif (Nkind (Exp) = N_Unchecked_Type_Conversion
2849         and then not Safe_Unchecked_Type_Conversion (Exp))
2850       then
2851          if Controlled_Type (Etype (Exp)) then
2852             --  Use a renaming to capture the expression, rather than create
2853             --  a controlled temporary.
2854
2855             Def_Id := Make_Defining_Identifier (Loc, New_Internal_Name ('R'));
2856             Res := New_Reference_To (Def_Id, Loc);
2857
2858             Insert_Action (Exp,
2859               Make_Object_Renaming_Declaration (Loc,
2860                 Defining_Identifier => Def_Id,
2861                 Subtype_Mark        => New_Reference_To (Exp_Type, Loc),
2862                 Name                => Relocate_Node (Exp)));
2863
2864          else
2865             Def_Id := Make_Defining_Identifier (Loc, New_Internal_Name ('R'));
2866             Set_Etype (Def_Id, Exp_Type);
2867             Res := New_Reference_To (Def_Id, Loc);
2868
2869             E :=
2870               Make_Object_Declaration (Loc,
2871                 Defining_Identifier => Def_Id,
2872                 Object_Definition   => New_Reference_To (Exp_Type, Loc),
2873                 Constant_Present    => True,
2874                 Expression          => Relocate_Node (Exp));
2875
2876             Set_Assignment_OK (E);
2877             Insert_Action (Exp, E);
2878          end if;
2879
2880       --  Otherwise we generate a reference to the value
2881
2882       else
2883          Ref_Type := Make_Defining_Identifier (Loc, New_Internal_Name ('A'));
2884
2885          Ptr_Typ_Decl :=
2886            Make_Full_Type_Declaration (Loc,
2887              Defining_Identifier => Ref_Type,
2888              Type_Definition =>
2889                Make_Access_To_Object_Definition (Loc,
2890                  All_Present => True,
2891                  Subtype_Indication =>
2892                    New_Reference_To (Exp_Type, Loc)));
2893
2894          E := Exp;
2895          Insert_Action (Exp, Ptr_Typ_Decl);
2896
2897          Def_Id := Make_Defining_Identifier (Loc, New_Internal_Name ('R'));
2898          Set_Etype (Def_Id, Exp_Type);
2899
2900          Res :=
2901            Make_Explicit_Dereference (Loc,
2902              Prefix => New_Reference_To (Def_Id, Loc));
2903
2904          if Nkind (E) = N_Explicit_Dereference then
2905             New_Exp := Relocate_Node (Prefix (E));
2906          else
2907             E := Relocate_Node (E);
2908             New_Exp := Make_Reference (Loc, E);
2909          end if;
2910
2911          if Nkind (E) = N_Aggregate and then Expansion_Delayed (E) then
2912             Set_Expansion_Delayed (E, False);
2913             Set_Analyzed (E, False);
2914          end if;
2915
2916          Insert_Action (Exp,
2917            Make_Object_Declaration (Loc,
2918              Defining_Identifier => Def_Id,
2919              Object_Definition   => New_Reference_To (Ref_Type, Loc),
2920              Expression          => New_Exp));
2921       end if;
2922
2923       --  Preserve the Assignment_OK flag in all copies, since at least
2924       --  one copy may be used in a context where this flag must be set
2925       --  (otherwise why would the flag be set in the first place).
2926
2927       Set_Assignment_OK (Res, Assignment_OK (Exp));
2928
2929       --  Finally rewrite the original expression and we are done
2930
2931       Rewrite (Exp, Res);
2932       Analyze_And_Resolve (Exp, Exp_Type);
2933       Scope_Suppress := Svg_Suppress;
2934    end Remove_Side_Effects;
2935
2936    ------------------------------------
2937    -- Safe_Unchecked_Type_Conversion --
2938    ------------------------------------
2939
2940    --  Note: this function knows quite a bit about the exact requirements
2941    --  of Gigi with respect to unchecked type conversions, and its code
2942    --  must be coordinated with any changes in Gigi in this area.
2943
2944    --  The above requirements should be documented in Sinfo ???
2945
2946    function Safe_Unchecked_Type_Conversion (Exp : Node_Id) return Boolean is
2947       Otyp   : Entity_Id;
2948       Ityp   : Entity_Id;
2949       Oalign : Uint;
2950       Ialign : Uint;
2951       Pexp   : constant Node_Id := Parent (Exp);
2952
2953    begin
2954       --  If the expression is the RHS of an assignment or object declaration
2955       --   we are always OK because there will always be a target.
2956
2957       --  Object renaming declarations, (generated for view conversions of
2958       --  actuals in inlined calls), like object declarations, provide an
2959       --  explicit type, and are safe as well.
2960
2961       if (Nkind (Pexp) = N_Assignment_Statement
2962            and then Expression (Pexp) = Exp)
2963         or else Nkind (Pexp) = N_Object_Declaration
2964         or else Nkind (Pexp) = N_Object_Renaming_Declaration
2965       then
2966          return True;
2967
2968       --  If the expression is the prefix of an N_Selected_Component
2969       --  we should also be OK because GCC knows to look inside the
2970       --  conversion except if the type is discriminated. We assume
2971       --  that we are OK anyway if the type is not set yet or if it is
2972       --  controlled since we can't afford to introduce a temporary in
2973       --  this case.
2974
2975       elsif Nkind (Pexp) = N_Selected_Component
2976          and then Prefix (Pexp) = Exp
2977       then
2978          if No (Etype (Pexp)) then
2979             return True;
2980          else
2981             return
2982               not Has_Discriminants (Etype (Pexp))
2983                 or else Is_Constrained (Etype (Pexp));
2984          end if;
2985       end if;
2986
2987       --  Set the output type, this comes from Etype if it is set, otherwise
2988       --  we take it from the subtype mark, which we assume was already
2989       --  fully analyzed.
2990
2991       if Present (Etype (Exp)) then
2992          Otyp := Etype (Exp);
2993       else
2994          Otyp := Entity (Subtype_Mark (Exp));
2995       end if;
2996
2997       --  The input type always comes from the expression, and we assume
2998       --  this is indeed always analyzed, so we can simply get the Etype.
2999
3000       Ityp := Etype (Expression (Exp));
3001
3002       --  Initialize alignments to unknown so far
3003
3004       Oalign := No_Uint;
3005       Ialign := No_Uint;
3006
3007       --  Replace a concurrent type by its corresponding record type
3008       --  and each type by its underlying type and do the tests on those.
3009       --  The original type may be a private type whose completion is a
3010       --  concurrent type, so find the underlying type first.
3011
3012       if Present (Underlying_Type (Otyp)) then
3013          Otyp := Underlying_Type (Otyp);
3014       end if;
3015
3016       if Present (Underlying_Type (Ityp)) then
3017          Ityp := Underlying_Type (Ityp);
3018       end if;
3019
3020       if Is_Concurrent_Type (Otyp) then
3021          Otyp := Corresponding_Record_Type (Otyp);
3022       end if;
3023
3024       if Is_Concurrent_Type (Ityp) then
3025          Ityp := Corresponding_Record_Type (Ityp);
3026       end if;
3027
3028       --  If the base types are the same, we know there is no problem since
3029       --  this conversion will be a noop.
3030
3031       if Implementation_Base_Type (Otyp) = Implementation_Base_Type (Ityp) then
3032          return True;
3033
3034       --  If the size of output type is known at compile time, there is
3035       --  never a problem.  Note that unconstrained records are considered
3036       --  to be of known size, but we can't consider them that way here,
3037       --  because we are talking about the actual size of the object.
3038
3039       --  We also make sure that in addition to the size being known, we do
3040       --  not have a case which might generate an embarrassingly large temp
3041       --  in stack checking mode.
3042
3043       elsif Size_Known_At_Compile_Time (Otyp)
3044         and then not May_Generate_Large_Temp (Otyp)
3045         and then not (Is_Record_Type (Otyp) and then not Is_Constrained (Otyp))
3046       then
3047          return True;
3048
3049       --  If either type is tagged, then we know the alignment is OK so
3050       --  Gigi will be able to use pointer punning.
3051
3052       elsif Is_Tagged_Type (Otyp) or else Is_Tagged_Type (Ityp) then
3053          return True;
3054
3055       --  If either type is a limited record type, we cannot do a copy, so
3056       --  say safe since there's nothing else we can do.
3057
3058       elsif Is_Limited_Record (Otyp) or else Is_Limited_Record (Ityp) then
3059          return True;
3060
3061       --  Conversions to and from packed array types are always ignored and
3062       --  hence are safe.
3063
3064       elsif Is_Packed_Array_Type (Otyp)
3065         or else Is_Packed_Array_Type (Ityp)
3066       then
3067          return True;
3068       end if;
3069
3070       --  The only other cases known to be safe is if the input type's
3071       --  alignment is known to be at least the maximum alignment for the
3072       --  target or if both alignments are known and the output type's
3073       --  alignment is no stricter than the input's.  We can use the alignment
3074       --  of the component type of an array if a type is an unpacked
3075       --  array type.
3076
3077       if Present (Alignment_Clause (Otyp)) then
3078          Oalign := Expr_Value (Expression (Alignment_Clause (Otyp)));
3079
3080       elsif Is_Array_Type (Otyp)
3081         and then Present (Alignment_Clause (Component_Type (Otyp)))
3082       then
3083          Oalign := Expr_Value (Expression (Alignment_Clause
3084                                            (Component_Type (Otyp))));
3085       end if;
3086
3087       if Present (Alignment_Clause (Ityp)) then
3088          Ialign := Expr_Value (Expression (Alignment_Clause (Ityp)));
3089
3090       elsif Is_Array_Type (Ityp)
3091         and then Present (Alignment_Clause (Component_Type (Ityp)))
3092       then
3093          Ialign := Expr_Value (Expression (Alignment_Clause
3094                                            (Component_Type (Ityp))));
3095       end if;
3096
3097       if Ialign /= No_Uint and then Ialign > Maximum_Alignment then
3098          return True;
3099
3100       elsif Ialign /= No_Uint and then Oalign /= No_Uint
3101         and then Ialign <= Oalign
3102       then
3103          return True;
3104
3105       --   Otherwise, Gigi cannot handle this and we must make a temporary.
3106
3107       else
3108          return False;
3109       end if;
3110
3111    end Safe_Unchecked_Type_Conversion;
3112
3113    --------------------------
3114    -- Set_Elaboration_Flag --
3115    --------------------------
3116
3117    procedure Set_Elaboration_Flag (N : Node_Id; Spec_Id : Entity_Id) is
3118       Loc : constant Source_Ptr := Sloc (N);
3119       Asn : Node_Id;
3120
3121    begin
3122       if Present (Elaboration_Entity (Spec_Id)) then
3123
3124          --  Nothing to do if at the compilation unit level, because in this
3125          --  case the flag is set by the binder generated elaboration routine.
3126
3127          if Nkind (Parent (N)) = N_Compilation_Unit then
3128             null;
3129
3130          --  Here we do need to generate an assignment statement
3131
3132          else
3133             Check_Restriction (No_Elaboration_Code, N);
3134             Asn :=
3135               Make_Assignment_Statement (Loc,
3136                 Name => New_Occurrence_Of (Elaboration_Entity (Spec_Id), Loc),
3137                 Expression => New_Occurrence_Of (Standard_True, Loc));
3138
3139             if Nkind (Parent (N)) = N_Subunit then
3140                Insert_After (Corresponding_Stub (Parent (N)), Asn);
3141             else
3142                Insert_After (N, Asn);
3143             end if;
3144
3145             Analyze (Asn);
3146          end if;
3147       end if;
3148    end Set_Elaboration_Flag;
3149
3150    ----------------------------
3151    -- Wrap_Cleanup_Procedure --
3152    ----------------------------
3153
3154    procedure Wrap_Cleanup_Procedure (N : Node_Id) is
3155       Loc   : constant Source_Ptr := Sloc (N);
3156       Stseq : constant Node_Id    := Handled_Statement_Sequence (N);
3157       Stmts : constant List_Id    := Statements (Stseq);
3158
3159    begin
3160       if Abort_Allowed then
3161          Prepend_To (Stmts, Build_Runtime_Call (Loc, RE_Abort_Defer));
3162          Append_To  (Stmts, Build_Runtime_Call (Loc, RE_Abort_Undefer));
3163       end if;
3164    end Wrap_Cleanup_Procedure;
3165
3166 end Exp_Util;