gcc/ada/exp_tss.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              E X P _ T S S                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  Type Support Subprogram (TSS) handling
  28
  29 with Namet; use Namet;
  30 with Types; use Types;
  31
  32 package Exp_Tss is
  33
  34    --  A type support subprogram (TSS) is an internally generated function or
  35    --  procedure that is associated with a particular type. Examples are the
  36    --  implicit initialization procedure, and subprograms for the Input and
  37    --  Output attributes.
  38
  39    --  A given TSS is either generated once at the point of the declaration of
  40    --  the type, or it is generated as needed in clients, but only one copy is
  41    --  required in any one generated object file. The choice between these two
  42    --  possibilities is made on a TSS-by-TSS basis depending on the estimation
  43    --  of how likely the TSS is to be used. Initialization procedures fall in
  44    --  the first category, for example, since it is likely that any declared
  45    --  type will be used in a context requiring initialization, but the stream
  46    --  attributes use the second approach, since it is more likely that they
  47    --  will not be used at all, or will only be used in one client in any case.
  48
  49    -------------------------
  50    -- Current Limitations --
  51    -------------------------
  52
  53    --  In the current version of this package, only the case of generating a
  54    --  TSS at the point of declaration of the type is accomodated. A clear
  55    --  improvement would be to follow through with the full implementation
  56    --  as described above, and also accomodate the requirement of generating
  57    --  only one copy in a given object file.
  58
  59    --  For now, we deal with the local case by generating duplicate versions
  60    --  of the TSS routine, which is clearly rather inefficient in space usage.
  61    --  This is done by using Make_TSS_Name_Local to generate unique names
  62    --  for the different instances of TSS routines in a given scope.
  63
  64    ----------------
  65    -- TSS Naming --
  66    ----------------
  67
  68    --  A TSS is identified by its Chars name. The name has the form typXY or
  69    --  typ_<serial>XY, where typ is the type name, and XY are two characters
  70    --  that identify the particular TSS routine. A unique serial number is
  71    --  included for the case where several local instances of the same TSS
  72    --  must be generated (see discussion under Make_TSS_Name_Local).
  73
  74    --  The following codes are used to denote TSSs:
  75
  76    --  Note: When making additions to this list, update the list in snames.adb
  77
  78    type TSS_Name_Type is new String (1 .. 2);
  79    subtype TNT is TSS_Name_Type;
  80
  81    TSS_Deep_Adjust        : constant TNT := "DA";  -- Deep Adjust
  82    TSS_Deep_Finalize      : constant TNT := "DF";  -- Deep Finalize
  83    TSS_Deep_Initialize    : constant TNT := "DI";  -- Deep Initialize
  84    TSS_Composite_Equality : constant TNT := "EQ";  -- Composite Equality
  85    TSS_From_Any           : constant TNT := "FA";  -- PolyORB/DSA From_Any
  86    TSS_Init_Proc          : constant TNT := "IP";  -- Initialization Procedure
  87    TSS_RAS_Access         : constant TNT := "RA";  -- RAS type access
  88    TSS_RAS_Dereference    : constant TNT := "RD";  -- RAS type deference
  89    TSS_Rep_To_Pos         : constant TNT := "RP";  -- Rep to Pos conversion
  90    TSS_Slice_Assign       : constant TNT := "SA";  -- Slice assignment
  91    TSS_Stream_Input       : constant TNT := "SI";  -- Stream Input attribute
  92    TSS_Stream_Output      : constant TNT := "SO";  -- Stream Output attribute
  93    TSS_Stream_Read        : constant TNT := "SR";  -- Stream Read attribute
  94    TSS_Stream_Write       : constant TNT := "SW";  -- Stream Write attribute
  95    TSS_To_Any             : constant TNT := "TA";  -- PolyORB/DSA To_Any
  96    TSS_TypeCode           : constant TNT := "TC";  -- PolyORB/DSA TypeCode
  97
  98    --  The array below contains all valid TSS names
  99
 100    TSS_Names : constant array (Natural range <>) of TSS_Name_Type :=
 101      (TSS_Deep_Adjust,
 102       TSS_Deep_Finalize,
 103       TSS_Deep_Initialize,
 104       TSS_Composite_Equality,
 105       TSS_From_Any,
 106       TSS_Init_Proc,
 107       TSS_RAS_Access,
 108       TSS_RAS_Dereference,
 109       TSS_Rep_To_Pos,
 110       TSS_Slice_Assign,
 111       TSS_Stream_Input,
 112       TSS_Stream_Output,
 113       TSS_Stream_Read,
 114       TSS_Stream_Write,
 115       TSS_To_Any,
 116       TSS_TypeCode);
 117
 118    TSS_Null : constant TNT := "  ";
 119    --  Dummy entry used to indicated that this is not really a TSS
 120
 121    function Get_TSS_Name (E : Entity_Id) return TSS_Name_Type;
 122    --  Given an entity, if it is a TSS, then return the corresponding TSS
 123    --  name type, otherwise return TSS_Null.
 124
 125    function Make_TSS_Name
 126      (Typ : Entity_Id;
 127       Nam : TSS_Name_Type) return Name_Id;
 128    --  Construct the name as described above for the given TSS routine
 129    --  identified by Nam for the type identified by Typ.
 130
 131    function Make_TSS_Name_Local
 132      (Typ : Entity_Id;
 133       Nam : TSS_Name_Type) return Name_Id;
 134    --  Similar to the above call, but a string of the form _nnn is inserted
 135    --  before the TSS code suffix, where nnn is a unique serial number. This
 136    --  is used when multiple instances of the same TSS routine may be
 137    --  generated in the same scope (see also discussion above of current
 138    --  limitations).
 139
 140    function Make_Init_Proc_Name (Typ : Entity_Id) return Name_Id;
 141    --  Version for init procs, same as Make_TSS_Name (Typ, TSS_Init_Proc)
 142
 143    function Is_TSS (E : Entity_Id; Nam : TSS_Name_Type) return Boolean;
 144    --  Determines if given entity (E) is the name of a TSS identified by Nam
 145
 146    function Is_TSS (N : Name_Id; Nam : TSS_Name_Type) return Boolean;
 147    --  Same test applied directly to a Name_Id value
 148
 149    function Is_Init_Proc (E : Entity_Id) return Boolean;
 150    --  Version for init procs, same as Is_TSS (E, TSS_Init_Proc);
 151
 152    -----------------------------------------
 153    -- TSS Data structures and Subprograms --
 154    -----------------------------------------
 155
 156    --  The TSS's for a given type are stored in an element list associated with
 157    --  the type, and referenced from the TSS_Elist field of the N_Freeze_Entity
 158    --  node associated with the type (all types that need TSS's always need to
 159    --  be explicitly frozen, so the N_Freeze_Entity node always exists).
 160
 161    function TSS (Typ : Entity_Id; Nam : TSS_Name_Type) return Entity_Id;
 162    --  Finds the TSS with the given name associated with the given type
 163    --  If no such TSS exists, then Empty is returned;
 164
 165    function TSS (Typ : Entity_Id; Nam : Name_Id) return Entity_Id;
 166    --  Finds the TSS with the given name associated with the given type. If
 167    --  no such TSS exists, then Empty is returned.
 168
 169    function Same_TSS (E1, E2 : Entity_Id) return Boolean;
 170    --  Returns True if E1 and E2 are the same kind of TSS, even if the names
 171    --  are different (i.e. if the names of E1 and E2 end with two upper case
 172    --  letters that are the same).
 173
 174    procedure Set_TSS (Typ : Entity_Id; TSS : Entity_Id);
 175    --  This procedure is used to install a newly created TSS. The second
 176    --  argument is the entity for such a new TSS. This entity is placed in the
 177    --  TSS list for the type given as the first argument, replacing an old
 178    --  entry of the same name if one was present. The tree for the body of this
 179    --  TSS, which is not analyzed yet, is placed in the actions field of the
 180    --  freeze node for the type. All such bodies are inserted into the main
 181    --  tree and analyzed at the point at which the freeze node itself is
 182    --  expanded.
 183
 184    procedure Copy_TSS (TSS : Entity_Id; Typ : Entity_Id);
 185    --  Given an existing TSS for another type (which is already installed,
 186    --  analyzed and expanded), install it as the corresponding TSS for Typ.
 187    --  Note that this just copies a reference, not the tree. This can also be
 188    --  used to initially install a TSS in the case where the subprogram for the
 189    --  TSS has already been created and its declaration processed.
 190
 191    function Init_Proc (Typ : Entity_Id) return Entity_Id;
 192    pragma Inline (Init_Proc);
 193    --  Obtains the _init TSS entry for the given type. This function call is
 194    --  equivalent to TSS (Typ, Name_uInit). The _init TSS is the procedure
 195    --  used to initialize otherwise uninitialized instances of a type. If
 196    --  there is no _init TSS, then the type requires no initialization. Note
 197    --  that subtypes and implicit types never have an _init TSS since subtype
 198    --  objects are always initialized using the initialization procedure for
 199    --  the corresponding base type (see Base_Init_Proc function). A special
 200    --  case arises for concurrent types. Such types do not themselves have an
 201    --  init proc TSS, but initialization is required. The init proc used is
 202    --  the one for the corresponding record type (see Base_Init_Proc).
 203
 204    function Base_Init_Proc (Typ : Entity_Id) return Entity_Id;
 205    --  Obtains the _Init TSS entry from the base type of the entity, and also
 206    --  deals with going indirect through the Corresponding_Record_Type field
 207    --  for concurrent objects (which are initialized with the initialization
 208    --  routine for the corresponding record type). Returns Empty if there is
 209    --  no _Init TSS entry for the base type.
 210
 211    procedure Set_Init_Proc (Typ : Entity_Id; Init : Entity_Id);
 212    pragma Inline (Set_Init_Proc);
 213    --  The second argument is the _init TSS to be established for the type
 214    --  given as the first argument. Equivalent to Set_TSS (Typ, Init).
 215
 216    function Has_Non_Null_Base_Init_Proc (Typ : Entity_Id) return Boolean;
 217    --  Returns true if the given type has a defined Base_Init_Proc and
 218    --  this init proc is not a null init proc (null init procs occur as
 219    --  a result of the processing for Initialize_Scalars. This function
 220    --  is used to test for the presence of an init proc in cases where
 221    --  a null init proc is considered equivalent to no init proc.
 222
 223    function Find_Inherited_TSS
 224      (Typ : Entity_Id;
 225       Nam : TSS_Name_Type) return Entity_Id;
 226    --  Returns the TSS of name Nam of Typ, or of its closest ancestor defining
 227    --  such a TSS. Empty is returned is neither Typ nor any of its ancestors
 228    --  have such a TSS.
 229
 230 end Exp_Tss;