gcc/ada/exp_ch9.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              E X P _ C H 9                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  Expand routines for chapter 9 constructs
  27
  28 with Types; use Types;
  29
  30 package Exp_Ch9 is
  31
  32    type Subprogram_Protection_Mode is
  33      (Dispatching_Mode,
  34       Protected_Mode,
  35       Unprotected_Mode);
  36    --  This type is used to distinguish the different protection modes of a
  37    --  protected subprogram.
  38
  39    procedure Build_Activation_Chain_Entity (N : Node_Id);
  40    --  Given a declaration N of an object that is a task, or contains tasks
  41    --  (other than allocators to tasks) this routine ensures that an activation
  42    --  chain has been declared in the appropriate scope, building the required
  43    --  declaration for the chain variable if not. The name of this variable
  44    --  is always _Chain and it is accessed by name.
  45
  46    function Build_Call_With_Task (N : Node_Id; E : Entity_Id) return Node_Id;
  47    --  N is a node representing the name of a task or an access to a task.
  48    --  The value returned is a call to the function whose name is the entity
  49    --  E (typically a runtime routine entity obtained using RTE) with the
  50    --  Task_Id of the associated task as the parameter. The caller is
  51    --  responsible for analyzing and resolving the resulting tree.
  52
  53    procedure Build_Class_Wide_Master (Typ : Entity_Id);
  54    --  Given an access-to-limited class-wide type or an access-to-limited
  55    --  interface, ensure that the designated type has a _master and generate
  56    --  a renaming of the said master to service the access type.
  57
  58    function Build_Entry_Names (Conc_Typ : Entity_Id) return Node_Id;
  59    --  Create the statements which populate the entry names array of a task or
  60    --  protected type. The statements are wrapped inside a block due to a local
  61    --  declaration.
  62
  63    procedure Build_Master_Entity (Obj_Or_Typ : Entity_Id);
  64    --  Given the name of an object or a type which is either a task, contains
  65    --  tasks or designates tasks, create a _master in the appropriate scope
  66    --  which captures the value of Current_Master. Mark the nearest enclosing
  67    --  body or block as being a task master.
  68
  69    procedure Build_Master_Renaming
  70      (Ptr_Typ : Entity_Id;
  71       Ins_Nod : Node_Id := Empty);
  72    --  Given an access type Ptr_Typ whose designated type is either a task or
  73    --  contains tasks, create a renaming of the form:
  74    --
  75    --     <Ptr_Typ>M : Master_Id renames _Master;
  76    --
  77    --  where _master denotes the task master of the enclosing context. Ins_Nod
  78    --  is used to provide a specific insertion node for the renaming.
  79
  80    function Build_Private_Protected_Declaration (N : Node_Id) return Entity_Id;
  81    --  A subprogram body without a previous spec that appears in a protected
  82    --  body must be expanded separately to create a subprogram declaration
  83    --  for it, in order to resolve internal calls to it from other protected
  84    --  operations. It would seem that no locking version of the operation is
  85    --  needed, but in fact, in Ada 2005 the subprogram may be used in a call-
  86    --  back, and therefore a protected version of the operation must be
  87    --  generated as well.
  88
  89    function Build_Protected_Sub_Specification
  90      (N        : Node_Id;
  91       Prot_Typ : Entity_Id;
  92       Mode     : Subprogram_Protection_Mode) return Node_Id;
  93    --  Build the specification for protected subprogram. This is called when
  94    --  expanding a protected type, and also when expanding the declaration for
  95    --  an Access_To_Protected_Subprogram type. In the latter case, Prot_Typ is
  96    --  empty, and the first parameter of the signature of the protected op is
  97    --  of type System.Address.
  98
  99    procedure Build_Protected_Subprogram_Call
 100      (N        : Node_Id;
 101       Name     : Node_Id;
 102       Rec      : Node_Id;
 103       External : Boolean := True);
 104    --  The node N is a subprogram or entry call to a protected subprogram. This
 105    --  procedure rewrites this call with the appropriate expansion. Name is the
 106    --  subprogram, and Rec is the record corresponding to the protected object.
 107    --  External is False if the call is to another protected subprogram within
 108    --  the same object.
 109
 110    procedure Build_Task_Activation_Call (N : Node_Id);
 111    --  This procedure is called for constructs that can be task activators,
 112    --  i.e. task bodies, subprogram bodies, package bodies and blocks. If the
 113    --  construct is a task activator (as indicated by the non-empty setting of
 114    --  Activation_Chain_Entity, either in the construct, or, in the case of a
 115    --  package body, in its associated package spec), then a call to
 116    --  Activate_Tasks with this entity as the single parameter is inserted at
 117    --  the start of the statements of the activator.
 118
 119    procedure Build_Task_Allocate_Block
 120      (Actions : List_Id;
 121       N       : Node_Id;
 122       Args    : List_Id);
 123    --  This routine is used in the case of allocators where the designated type
 124    --  is a task or contains tasks. In this case, the normal initialize call
 125    --  is replaced by:
 126    --
 127    --    blockname : label;
 128    --    blockname : declare
 129    --       _Chain  : Activation_Chain;
 130    --
 131    --       procedure _Expunge is
 132    --       begin
 133    --         Expunge_Unactivated_Tasks (_Chain);
 134    --       end;
 135    --
 136    --    begin
 137    --       Init (Args);
 138    --       Activate_Tasks (_Chain);
 139    --    at end
 140    --       _Expunge;
 141    --    end;
 142    --
 143    --  to get the task or tasks created and initialized. The expunge call
 144    --  ensures that any tasks that get created but not activated due to an
 145    --  exception are properly expunged (it has no effect in the normal case).
 146    --  The argument N is the allocator, and Args is the list of arguments for
 147    --  the initialization call, constructed by the caller, which uses the
 148    --  Master_Id of the access type as the _Master parameter, and _Chain
 149    --  (defined above) as the _Chain parameter.
 150
 151    procedure Build_Task_Allocate_Block_With_Init_Stmts
 152      (Actions    : List_Id;
 153       N          : Node_Id;
 154       Init_Stmts : List_Id);
 155    --  Ada 2005 (AI-287): Similar to previous routine, but used to expand
 156    --  allocated aggregates with default initialized components. Init_Stmts
 157    --  contains the list of statements required to initialize the allocated
 158    --  aggregate. It replaces the call to Init (Args) done by
 159    --  Build_Task_Allocate_Block.
 160
 161    function Build_Wrapper_Spec
 162      (Subp_Id : Entity_Id;
 163       Obj_Typ : Entity_Id;
 164       Formals : List_Id) return Node_Id;
 165    --  Ada 2005 (AI-345): Build the specification of a primitive operation
 166    --  associated with a protected or task type. This is required to implement
 167    --  dispatching calls through interfaces. Subp_Id is the primitive to be
 168    --  wrapped, Obj_Typ is the type of the newly added formal parameter to
 169    --  handle object notation, Formals are the original entry formals that
 170    --  will be explicitly replicated.
 171
 172    function Concurrent_Ref (N : Node_Id) return Node_Id;
 173    --  Given the name of a concurrent object (task or protected object), or
 174    --  the name of an access to a concurrent object, this function returns an
 175    --  expression referencing the associated Task_Id or Protection object,
 176    --  respectively. Note that a special case is when the name is a reference
 177    --  to a task type name. This can only happen within a task body, and the
 178    --  meaning is to get the Task_Id for the currently executing task.
 179
 180    function Convert_Concurrent
 181      (N   : Node_Id;
 182       Typ : Entity_Id) return Node_Id;
 183    --  N is an expression of type Typ. If the type is not a concurrent type
 184    --  then it is returned unchanged. If it is a task or protected reference,
 185    --  Convert_Concurrent creates an unchecked conversion node from this
 186    --  expression to the corresponding concurrent record type value. We need
 187    --  this in any situation where the concurrent type is used, because the
 188    --  actual concurrent object is an object of the corresponding concurrent
 189    --  type, and manipulations on the concurrent object actually manipulate the
 190    --  corresponding object of the record type.
 191
 192    function Entry_Index_Expression
 193      (Sloc  : Source_Ptr;
 194       Ent   : Entity_Id;
 195       Index : Node_Id;
 196       Ttyp  : Entity_Id)
 197       return  Node_Id;
 198    --  Returns an expression to compute a task entry index given the name of
 199    --  the entry or entry family. For the case of a task entry family, the
 200    --  Index parameter contains the expression for the subscript. Ttyp is the
 201    --  task type.
 202
 203    procedure Establish_Task_Master (N : Node_Id);
 204    --  Given a subprogram body, or a block statement, or a task body, this
 205    --  procedure makes the necessary transformations required of a task master
 206    --  (add Enter_Master call at start, and establish a cleanup routine to make
 207    --  sure Complete_Master is called on exit).
 208
 209    procedure Expand_Access_Protected_Subprogram_Type (N : Node_Id);
 210    --  Build Equivalent_Type for an Access_To_Protected_Subprogram.
 211    --  Equivalent_Type is a record type with two components: a pointer to the
 212    --  protected object, and a pointer to the operation itself.
 213
 214    procedure Expand_Accept_Declarations (N : Node_Id; Ent : Entity_Id);
 215    --  Expand declarations required for accept statement. See bodies of both
 216    --  Expand_Accept_Declarations and Expand_N_Accept_Statement for full
 217    --  details of the nature and use of these declarations, which are inserted
 218    --  immediately before the accept node N. The second argument is the entity
 219    --  for the corresponding entry.
 220
 221    procedure Expand_Entry_Barrier (N : Node_Id; Ent : Entity_Id);
 222    --  Expand the entry barrier into a function. This is called directly
 223    --  from Analyze_Entry_Body so that the discriminals and privals of the
 224    --  barrier can be attached to the function declaration list, and a new
 225    --  set prepared for the entry body procedure, before the entry body
 226    --  statement sequence can be expanded. The resulting function is analyzed
 227    --  now, within the context of the protected object, to resolve calls to
 228    --  other protected functions.
 229
 230    procedure Expand_N_Abort_Statement            (N : Node_Id);
 231    procedure Expand_N_Accept_Statement           (N : Node_Id);
 232    procedure Expand_N_Asynchronous_Select        (N : Node_Id);
 233    procedure Expand_N_Conditional_Entry_Call     (N : Node_Id);
 234    procedure Expand_N_Delay_Relative_Statement   (N : Node_Id);
 235    procedure Expand_N_Delay_Until_Statement      (N : Node_Id);
 236    procedure Expand_N_Entry_Body                 (N : Node_Id);
 237    procedure Expand_N_Entry_Call_Statement       (N : Node_Id);
 238    procedure Expand_N_Entry_Declaration          (N : Node_Id);
 239    procedure Expand_N_Protected_Body             (N : Node_Id);
 240
 241    procedure Expand_N_Protected_Type_Declaration (N : Node_Id);
 242    --  Expands protected type declarations. This results, among other things,
 243    --  in the declaration of a record type for the representation of protected
 244    --  objects and (if there are entries) in an entry service procedure. The
 245    --  Protection value used by the GNARL to control the object will always be
 246    --  the first field of the record, and the entry service procedure spec (if
 247    --  it exists) will always immediately follow the record declaration. This
 248    --  allows these two nodes to be found from the type, without benefit of
 249    --  further attributes, using Corresponding_Record.
 250
 251    procedure Expand_N_Requeue_Statement          (N : Node_Id);
 252    procedure Expand_N_Selective_Accept           (N : Node_Id);
 253    procedure Expand_N_Single_Task_Declaration    (N : Node_Id);
 254    procedure Expand_N_Task_Body                  (N : Node_Id);
 255    procedure Expand_N_Task_Type_Declaration      (N : Node_Id);
 256    procedure Expand_N_Timed_Entry_Call           (N : Node_Id);
 257
 258    procedure Expand_Protected_Body_Declarations
 259      (N       : Node_Id;
 260       Spec_Id : Entity_Id);
 261    --  Expand declarations required for a protected body. See bodies of both
 262    --  Expand_Protected_Body_Declarations and Expand_N_Protected_Body for full
 263    --  details of the nature and use of these declarations. The second argument
 264    --  is the entity for the corresponding protected type declaration.
 265
 266    function External_Subprogram (E : Entity_Id) return Entity_Id;
 267    --  return the external version of a protected operation, which locks
 268    --  the object before invoking the internal protected subprogram body.
 269
 270    function Find_Master_Scope (E : Entity_Id) return Entity_Id;
 271    --  When a type includes tasks, a master entity is created in the scope, to
 272    --  be used by the runtime during activation. In general the master is the
 273    --  immediate scope in which the type is declared, but in Ada 2005, in the
 274    --  presence of synchronized classwide interfaces, the immediate scope of
 275    --  an anonymous access type may be a transient scope, which has no run-time
 276    --  presence. In this case, the scope of the master is the innermost scope
 277    --  that comes from source.
 278
 279    function First_Protected_Operation (D : List_Id) return Node_Id;
 280    --  Given the declarations list for a protected body, find the
 281    --  first protected operation body.
 282
 283    procedure Install_Private_Data_Declarations
 284      (Loc      : Source_Ptr;
 285       Spec_Id  : Entity_Id;
 286       Conc_Typ : Entity_Id;
 287       Body_Nod : Node_Id;
 288       Decls    : List_Id;
 289       Barrier  : Boolean := False;
 290       Family   : Boolean := False);
 291    --  This routines generates several types, objects and object renamings used
 292    --  in the handling of discriminants and private components of protected and
 293    --  task types. It also generates the entry index for entry families. Formal
 294    --  Spec_Id denotes an entry, entry family or a subprogram, Conc_Typ is the
 295    --  concurrent type where Spec_Id resides, Body_Nod is the corresponding
 296    --  body of Spec_Id, Decls are the declarations of the subprogram or entry.
 297    --  Flag Barrier denotes whether the context is an entry barrier function.
 298    --  Flag Family is used in conjunction with Barrier to denote a barrier for
 299    --  an entry family.
 300    --
 301    --  The generated types, entities and renamings are:
 302    --
 303    --  * If flag Barrier is set or Spec_Id denotes a protected entry or an
 304    --    entry family, generate:
 305    --
 306    --      type prot_typVP is access prot_typV;
 307    --      _object : prot_typVP := prot_typV (_O);
 308    --
 309    --    where prot_typV is the corresponding record of a protected type and
 310    --    _O is a formal parameter representing the concurrent object of either
 311    --    the barrier function or the entry (family).
 312    --
 313    --  * If Conc_Typ is a protected type, create a renaming for the Protection
 314    --    field _object:
 315    --
 316    --      conc_typR : protection_typ renames _object._object;
 317    --
 318    --  * If Conc_Typ has discriminants, create renamings of the form:
 319    --
 320    --      discr_nameD : discr_typ renames _object.discr_name;
 321    --        or
 322    --      discr_nameD : discr_typ renames _task.discr_name;
 323    --
 324    --  * If Conc_Typ denotes a protected type and has private components,
 325    --    generate renamings of the form:
 326    --
 327    --      comp_name : comp_typ renames _object.comp_name;
 328    --
 329    --  * Finally, is flag Barrier and Family are set or Spec_Id denotes an
 330    --    entry family, generate the entry index constant:
 331    --
 332    --      subtype Jnn is <Type of Index> range Low .. High;
 333    --      J : constant Jnn :=
 334    --            Jnn'Val (_E - <Index expression> + Jnn'Pos (Jnn'First));
 335    --
 336    --  All the above declarations are inserted in the order shown to the front
 337    --  of Decls.
 338
 339    function Make_Task_Create_Call (Task_Rec : Entity_Id) return Node_Id;
 340    --  Given the entity of the record type created for a task type, build
 341    --  the call to Create_Task
 342
 343    function Make_Initialize_Protection
 344      (Protect_Rec : Entity_Id) return List_Id;
 345    --  Given the entity of the record type created for a protected type, build
 346    --  a list of statements needed for proper initialization of the object.
 347
 348    function Next_Protected_Operation (N : Node_Id) return Node_Id;
 349    --  Given a protected operation node (a subprogram or entry body), find the
 350    --  following node in the declarations list.
 351
 352    procedure Set_Discriminals (Dec : Node_Id);
 353    --  Replace discriminals in a protected type for use by the next protected
 354    --  operation on the type. Each operation needs a new set of discriminals,
 355    --  since it needs a unique renaming of the discriminant fields in the
 356    --  record used to implement the protected type.
 357
 358 end Exp_Ch9;