gcc/ada/exp_ch13.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ C H 1 3                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Exp_Ch3;  use Exp_Ch3;
  30 with Exp_Ch6;  use Exp_Ch6;
  31 with Exp_Imgv; use Exp_Imgv;
  32 with Exp_Tss;  use Exp_Tss;
  33 with Exp_Util; use Exp_Util;
  34 with Namet;    use Namet;
  35 with Nlists;   use Nlists;
  36 with Nmake;    use Nmake;
  37 with Rtsfind;  use Rtsfind;
  38 with Sem;      use Sem;
  39 with Sem_Ch7;  use Sem_Ch7;
  40 with Sem_Ch8;  use Sem_Ch8;
  41 with Sem_Eval; use Sem_Eval;
  42 with Sem_Util; use Sem_Util;
  43 with Sinfo;    use Sinfo;
  44 with Snames;   use Snames;
  45 with Stand;    use Stand;
  46 with Tbuild;   use Tbuild;
  47 with Uintp;    use Uintp;
  48
  49 package body Exp_Ch13 is
  50
  51    ------------------------------------------
  52    -- Expand_N_Attribute_Definition_Clause --
  53    ------------------------------------------
  54
  55    --  Expansion action depends on attribute involved
  56
  57    procedure Expand_N_Attribute_Definition_Clause (N : Node_Id) is
  58       Loc : constant Source_Ptr := Sloc (N);
  59       Exp : constant Node_Id    := Expression (N);
  60       Ent : Entity_Id;
  61       V   : Node_Id;
  62
  63    begin
  64       Ent := Entity (Name (N));
  65
  66       if Is_Type (Ent) then
  67          Ent := Underlying_Type (Ent);
  68       end if;
  69
  70       case Get_Attribute_Id (Chars (N)) is
  71
  72          -------------
  73          -- Address --
  74          -------------
  75
  76          when Attribute_Address =>
  77
  78             --  If there is an initialization which did not come from the
  79             --  source program, then it is an artifact of our expansion, and we
  80             --  suppress it. The case we are most concerned about here is the
  81             --  initialization of a packed array to all false, which seems
  82             --  inappropriate for variable to which an address clause is
  83             --  applied. The expression may itself have been rewritten if the
  84             --  type is packed array, so we need to examine whether the
  85             --  original node is in the source. An exception though is the case
  86             --  of an access variable which is default initialized to null, and
  87             --  such initialization is retained.
  88
  89             --  Furthermore, if the initialization is the equivalent aggregate
  90             --  of the type initialization procedure, it replaces an implicit
  91             --  call to the init proc, and must be respected. Note that for
  92             --  packed types we do not build equivalent aggregates.
  93
  94             declare
  95                Decl : constant Node_Id := Declaration_Node (Ent);
  96                Typ  : constant Entity_Id := Etype (Ent);
  97             begin
  98                if Nkind (Decl) = N_Object_Declaration
  99                   and then Present (Expression (Decl))
 100                   and then Nkind (Expression (Decl)) /= N_Null
 101                   and then
 102                    not Comes_From_Source (Original_Node (Expression (Decl)))
 103                then
 104                   if Present (Base_Init_Proc (Typ))
 105                     and then
 106                       Present (Static_Initialization (Base_Init_Proc (Typ)))
 107                   then
 108                      null;
 109                   else
 110                      Set_Expression (Decl, Empty);
 111                   end if;
 112                end if;
 113             end;
 114
 115          ---------------
 116          -- Alignment --
 117          ---------------
 118
 119          when Attribute_Alignment =>
 120
 121             --  As required by Gigi, we guarantee that the operand is an
 122             --  integer literal (this simplifies things in Gigi).
 123
 124             if Nkind (Exp) /= N_Integer_Literal then
 125                Rewrite
 126                  (Exp, Make_Integer_Literal (Loc, Expr_Value (Exp)));
 127             end if;
 128
 129          ------------------
 130          -- Storage_Size --
 131          ------------------
 132
 133          when Attribute_Storage_Size =>
 134
 135             --  If the type is a task type, then assign the value of the
 136             --  storage size to the Size variable associated with the task.
 137             --    task_typeZ := expression
 138
 139             if Ekind (Ent) = E_Task_Type then
 140                Insert_Action (N,
 141                  Make_Assignment_Statement (Loc,
 142                    Name => New_Reference_To (Storage_Size_Variable (Ent), Loc),
 143                    Expression =>
 144                      Convert_To (RTE (RE_Size_Type), Expression (N))));
 145
 146             --  For Storage_Size for an access type, create a variable to hold
 147             --  the value of the specified size with name typeV and expand an
 148             --  assignment statement to initialze this value.
 149
 150             elsif Is_Access_Type (Ent) then
 151                V := Make_Defining_Identifier (Loc,
 152                       New_External_Name (Chars (Ent), 'V'));
 153
 154                Insert_Action (N,
 155                  Make_Object_Declaration (Loc,
 156                    Defining_Identifier => V,
 157                    Object_Definition  =>
 158                      New_Reference_To (RTE (RE_Storage_Offset), Loc),
 159                    Expression =>
 160                      Convert_To (RTE (RE_Storage_Offset), Expression (N))));
 161
 162                Set_Storage_Size_Variable (Ent, Entity_Id (V));
 163             end if;
 164
 165          --  Other attributes require no expansion
 166
 167          when others =>
 168             null;
 169
 170       end case;
 171    end Expand_N_Attribute_Definition_Clause;
 172
 173    ----------------------------
 174    -- Expand_N_Freeze_Entity --
 175    ----------------------------
 176
 177    procedure Expand_N_Freeze_Entity (N : Node_Id) is
 178       E              : constant Entity_Id := Entity (N);
 179       E_Scope        : Entity_Id;
 180       S              : Entity_Id;
 181       In_Other_Scope : Boolean;
 182       In_Outer_Scope : Boolean;
 183       Decl           : Node_Id;
 184       Delete         : Boolean := False;
 185
 186    begin
 187       --  Processing for objects with address clauses
 188
 189       if Is_Object (E) and then Present (Address_Clause (E)) then
 190          Apply_Address_Clause_Check (E, N);
 191          return;
 192
 193       --  Only other items requiring any front end action are types and
 194       --  subprograms.
 195
 196       elsif not Is_Type (E) and then not Is_Subprogram (E) then
 197          return;
 198       end if;
 199
 200       --  Here E is a type or a subprogram
 201
 202       E_Scope := Scope (E);
 203
 204       --  This is an error protection against previous errors
 205
 206       if No (E_Scope) then
 207          return;
 208       end if;
 209
 210       --  If we are freezing entities defined in protected types, they belong
 211       --  in the enclosing scope, given that the original type has been
 212       --  expanded away. The same is true for entities in task types, in
 213       --  particular the parameter records of entries (Entities in bodies are
 214       --  all frozen within the body). If we are in the task body, this is a
 215       --  proper scope.
 216
 217       if Ekind (E_Scope) = E_Protected_Type
 218         or else (Ekind (E_Scope) = E_Task_Type
 219                    and then not Has_Completion (E_Scope))
 220       then
 221          E_Scope := Scope (E_Scope);
 222       end if;
 223
 224       S := Current_Scope;
 225       while S /= Standard_Standard and then S /= E_Scope loop
 226          S := Scope (S);
 227       end loop;
 228
 229       In_Other_Scope := not (S = E_Scope);
 230       In_Outer_Scope := (not In_Other_Scope) and then (S /= Current_Scope);
 231
 232       --  If the entity being frozen is defined in a scope that is not
 233       --  currently on the scope stack, we must establish the proper
 234       --  visibility before freezing the entity and related subprograms.
 235
 236       if In_Other_Scope then
 237          Push_Scope (E_Scope);
 238          Install_Visible_Declarations (E_Scope);
 239
 240          if Ekind (E_Scope) = E_Package         or else
 241             Ekind (E_Scope) = E_Generic_Package or else
 242             Is_Protected_Type (E_Scope)         or else
 243             Is_Task_Type (E_Scope)
 244          then
 245             Install_Private_Declarations (E_Scope);
 246          end if;
 247
 248       --  If the entity is in an outer scope, then that scope needs to
 249       --  temporarily become the current scope so that operations created
 250       --  during type freezing will be declared in the right scope and
 251       --  can properly override any corresponding inherited operations.
 252
 253       elsif In_Outer_Scope then
 254          Push_Scope (E_Scope);
 255       end if;
 256
 257       --  If type, freeze the type
 258
 259       if Is_Type (E) then
 260          Delete := Freeze_Type (N);
 261
 262          --  And for enumeration type, build the enumeration tables
 263
 264          if Is_Enumeration_Type (E) then
 265             Build_Enumeration_Image_Tables (E, N);
 266          end if;
 267
 268       --  If subprogram, freeze the subprogram
 269
 270       elsif Is_Subprogram (E) then
 271          Freeze_Subprogram (N);
 272
 273          --  Ada 2005 (AI-251): Remove the freezing node associated with the
 274          --  entities internally used by the frontend to register primitives
 275          --  covering abstract interfaces. The call to Freeze_Subprogram has
 276          --  already expanded the code that fills the corresponding entry in
 277          --  its secondary dispatch table and therefore the code generator
 278          --  has nothing else to do with this freezing node.
 279
 280          Delete := Present (Abstract_Interface_Alias (E));
 281       end if;
 282
 283       --  Analyze actions generated by freezing. The init_proc contains source
 284       --  expressions that may raise Constraint_Error, and the assignment
 285       --  procedure for complex types needs checks on individual component
 286       --  assignments, but all other freezing actions should be compiled with
 287       --  all checks off.
 288
 289       if Present (Actions (N)) then
 290          Decl := First (Actions (N));
 291          while Present (Decl) loop
 292             if Nkind (Decl) = N_Subprogram_Body
 293               and then (Is_Init_Proc (Defining_Entity (Decl))
 294                           or else
 295                             Chars (Defining_Entity (Decl)) = Name_uAssign)
 296             then
 297                Analyze (Decl);
 298
 299             --  A subprogram body created for a renaming_as_body completes
 300             --  a previous declaration, which may be in a different scope.
 301             --  Establish the proper scope before analysis.
 302
 303             elsif Nkind (Decl) = N_Subprogram_Body
 304               and then Present (Corresponding_Spec (Decl))
 305               and then Scope (Corresponding_Spec (Decl)) /= Current_Scope
 306             then
 307                Push_Scope (Scope (Corresponding_Spec (Decl)));
 308                Analyze (Decl, Suppress => All_Checks);
 309                Pop_Scope;
 310
 311             else
 312                Analyze (Decl, Suppress => All_Checks);
 313             end if;
 314
 315             Next (Decl);
 316          end loop;
 317       end if;
 318
 319       --  If we are to delete this N_Freeze_Entity, do so by rewriting so that
 320       --  a loop on all nodes being inserted will work propertly.
 321
 322       if Delete then
 323          Rewrite (N, Make_Null_Statement (Sloc (N)));
 324       end if;
 325
 326       if In_Other_Scope then
 327          if Ekind (Current_Scope) = E_Package then
 328             End_Package_Scope (E_Scope);
 329          else
 330             End_Scope;
 331          end if;
 332
 333       elsif In_Outer_Scope then
 334          Pop_Scope;
 335       end if;
 336    end Expand_N_Freeze_Entity;
 337
 338    -------------------------------------------
 339    -- Expand_N_Record_Representation_Clause --
 340    -------------------------------------------
 341
 342    --  The only expansion required is for the case of a mod clause present,
 343    --  which is removed, and translated into an alignment representation
 344    --  clause inserted immediately after the record rep clause with any
 345    --  initial pragmas inserted at the start of the component clause list.
 346
 347    procedure Expand_N_Record_Representation_Clause (N : Node_Id) is
 348       Loc     : constant Source_Ptr := Sloc (N);
 349       Rectype : constant Entity_Id  := Entity (Identifier (N));
 350       Mod_Val : Uint;
 351       Citems  : List_Id;
 352       Repitem : Node_Id;
 353       AtM_Nod : Node_Id;
 354
 355    begin
 356       if Present (Mod_Clause (N)) then
 357          Mod_Val := Expr_Value (Expression (Mod_Clause (N)));
 358          Citems  := Pragmas_Before (Mod_Clause (N));
 359
 360          if Present (Citems) then
 361             Append_List_To (Citems, Component_Clauses (N));
 362             Set_Component_Clauses (N, Citems);
 363          end if;
 364
 365          AtM_Nod :=
 366            Make_Attribute_Definition_Clause (Loc,
 367              Name       => New_Reference_To (Base_Type (Rectype), Loc),
 368              Chars      => Name_Alignment,
 369              Expression => Make_Integer_Literal (Loc, Mod_Val));
 370
 371          Set_From_At_Mod (AtM_Nod);
 372          Insert_After (N, AtM_Nod);
 373          Set_Mod_Clause (N, Empty);
 374       end if;
 375
 376       --  If the record representation clause has no components, then
 377       --  completely remove it.  Note that we also have to remove
 378       --  ourself from the Rep Item list.
 379
 380       if Is_Empty_List (Component_Clauses (N)) then
 381          if First_Rep_Item (Rectype) = N then
 382             Set_First_Rep_Item (Rectype, Next_Rep_Item (N));
 383          else
 384             Repitem := First_Rep_Item (Rectype);
 385             while Present (Next_Rep_Item (Repitem)) loop
 386                if Next_Rep_Item (Repitem) = N then
 387                   Set_Next_Rep_Item (Repitem, Next_Rep_Item (N));
 388                   exit;
 389                end if;
 390
 391                Next_Rep_Item (Repitem);
 392             end loop;
 393          end if;
 394
 395          Rewrite (N,
 396            Make_Null_Statement (Loc));
 397       end if;
 398    end Expand_N_Record_Representation_Clause;
 399
 400 end Exp_Ch13;