gcc/ada/back_end.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                            B A C K _ E N D                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;     use Atree;
  27 with Debug;     use Debug;
  28 with Elists;    use Elists;
  29 with Lib;       use Lib;
  30 with Osint;     use Osint;
  31 with Opt;       use Opt;
  32 with Osint.C;   use Osint.C;
  33 with Namet;     use Namet;
  34 with Nlists;    use Nlists;
  35 with Stand;     use Stand;
  36 with Sinput;    use Sinput;
  37 with Stringt;   use Stringt;
  38 with Switch;    use Switch;
  39 with Switch.C;  use Switch.C;
  40 with System;    use System;
  41 with Types;     use Types;
  42
  43 package body Back_End is
  44
  45    -------------------
  46    -- Call_Back_End --
  47    -------------------
  48
  49    procedure Call_Back_End (Mode : Back_End_Mode_Type) is
  50
  51       --  The Source_File_Record type has a lot of components that are
  52       --  meaningless to the back end, so a new record type is created
  53       --  here to contain the needed information for each file.
  54
  55       type File_Info_Type is record
  56          File_Name        : File_Name_Type;
  57          Num_Source_Lines : Nat;
  58       end record;
  59
  60       File_Info_Array : array (1 .. Last_Source_File) of File_Info_Type;
  61
  62       procedure gigi
  63         (gnat_root                     : Int;
  64          max_gnat_node                 : Int;
  65          number_name                   : Nat;
  66          nodes_ptr                     : Address;
  67
  68          next_node_ptr                 : Address;
  69          prev_node_ptr                 : Address;
  70          elists_ptr                    : Address;
  71          elmts_ptr                     : Address;
  72
  73          strings_ptr                   : Address;
  74          string_chars_ptr              : Address;
  75          list_headers_ptr              : Address;
  76          number_file                   : Nat;
  77
  78          file_info_ptr                 : Address;
  79          gigi_standard_boolean         : Entity_Id;
  80          gigi_standard_integer         : Entity_Id;
  81          gigi_standard_character       : Entity_Id;
  82          gigi_standard_long_long_float : Entity_Id;
  83          gigi_standard_exception_type  : Entity_Id;
  84          gigi_operating_mode           : Back_End_Mode_Type);
  85
  86       pragma Import (C, gigi);
  87
  88    begin
  89       --  Skip call if in -gnatdH mode
  90
  91       if Debug_Flag_HH then
  92          return;
  93       end if;
  94
  95       for J in 1 .. Last_Source_File loop
  96          File_Info_Array (J).File_Name        := Full_Debug_Name (J);
  97          File_Info_Array (J).Num_Source_Lines := Num_Source_Lines (J);
  98       end loop;
  99
 100       gigi
 101         (gnat_root          => Int (Cunit (Main_Unit)),
 102          max_gnat_node      => Int (Last_Node_Id - First_Node_Id + 1),
 103          number_name        => Name_Entries_Count,
 104          nodes_ptr          => Nodes_Address,
 105
 106          next_node_ptr      => Next_Node_Address,
 107          prev_node_ptr      => Prev_Node_Address,
 108          elists_ptr         => Elists_Address,
 109          elmts_ptr          => Elmts_Address,
 110
 111          strings_ptr        => Strings_Address,
 112          string_chars_ptr   => String_Chars_Address,
 113          list_headers_ptr   => Lists_Address,
 114          number_file        => Num_Source_Files,
 115
 116          file_info_ptr                 => File_Info_Array'Address,
 117          gigi_standard_boolean         => Standard_Boolean,
 118          gigi_standard_integer         => Standard_Integer,
 119          gigi_standard_character       => Standard_Character,
 120          gigi_standard_long_long_float => Standard_Long_Long_Float,
 121          gigi_standard_exception_type  => Standard_Exception_Type,
 122          gigi_operating_mode           => Mode);
 123    end Call_Back_End;
 124
 125    -----------------------------
 126    -- Scan_Compiler_Arguments --
 127    -----------------------------
 128
 129    procedure Scan_Compiler_Arguments is
 130       Next_Arg : Pos := 1;
 131
 132       type Arg_Array is array (Nat) of Big_String_Ptr;
 133       type Arg_Array_Ptr is access Arg_Array;
 134
 135       flag_stack_check : Int;
 136       pragma Import (C, flag_stack_check);
 137       --  Import from toplev.c
 138
 139       save_argc : Nat;
 140       pragma Import (C, save_argc);
 141       --  Import from toplev.c
 142
 143       save_argv : Arg_Array_Ptr;
 144       pragma Import (C, save_argv);
 145       --  Import from toplev.c
 146
 147       Output_File_Name_Seen : Boolean := False;
 148       --  Set to True after having scanned file_name for switch "-gnatO file"
 149
 150       --  Local functions
 151
 152       function Len_Arg (Arg : Pos) return Nat;
 153       --  Determine length of argument number Arg on the original command line
 154       --  from gnat1.
 155
 156       procedure Scan_Back_End_Switches (Switch_Chars : String);
 157       --  Procedure to scan out switches stored in Switch_Chars. The first
 158       --  character is known to be a valid switch character, and there are no
 159       --  blanks or other switch terminator characters in the string, so the
 160       --  entire string should consist of valid switch characters, except that
 161       --  an optional terminating NUL character is allowed.
 162       --
 163       --  Back end switches have already been checked and processed by GCC in
 164       --  toplev.c, so no errors can occur and control will always return. The
 165       --  switches must still be scanned to skip "-o" or internal GCC switches
 166       --  with their argument.
 167
 168       -------------
 169       -- Len_Arg --
 170       -------------
 171
 172       function Len_Arg (Arg : Pos) return Nat is
 173       begin
 174          for J in 1 .. Nat'Last loop
 175             if save_argv (Arg).all (Natural (J)) = ASCII.NUL then
 176                return J - 1;
 177             end if;
 178          end loop;
 179
 180          raise Program_Error;
 181       end Len_Arg;
 182
 183       ----------------------------
 184       -- Scan_Back_End_Switches --
 185       ----------------------------
 186
 187       procedure Scan_Back_End_Switches (Switch_Chars : String) is
 188          First : constant Positive := Switch_Chars'First + 1;
 189          Last  : constant Natural  := Switch_Last (Switch_Chars);
 190
 191       begin
 192          --  Skip -o or internal GCC switches together with their argument
 193
 194          if Switch_Chars (First .. Last) = "o"
 195            or else Is_Internal_GCC_Switch (Switch_Chars)
 196          then
 197             Next_Arg := Next_Arg + 1;
 198
 199          --  Do not record -quiet switch
 200
 201          elsif Switch_Chars (First .. Last) = "quiet" then
 202             null;
 203
 204          --  Store any other GCC switches
 205
 206          else
 207             Store_Compilation_Switch (Switch_Chars);
 208
 209             --  Special check, the back end switch -fno-inline also sets the
 210             --  front end flag to entirely inhibit all inlining.
 211
 212             if Switch_Chars (First .. Last) = "fno-inline" then
 213                Opt.Suppress_All_Inlining := True;
 214
 215             --  Another special check, the switch -fpreserve-control-flow
 216             --  which is also a back end switch sets the front end flag
 217             --  that inhibits improper control flow transformations.
 218
 219             elsif Switch_Chars (First .. Last) = "fpreserve-control-flow" then
 220                Opt.Suppress_Control_Flow_Optimizations := True;
 221             end if;
 222          end if;
 223       end Scan_Back_End_Switches;
 224
 225    --  Start of processing for Scan_Compiler_Arguments
 226
 227    begin
 228       --  Acquire stack checking mode directly from GCC
 229
 230       Opt.Stack_Checking_Enabled := (flag_stack_check /= 0);
 231
 232       --  Loop through command line arguments, storing them for later access
 233
 234       while Next_Arg < save_argc loop
 235          Look_At_Arg : declare
 236             Argv_Ptr : constant Big_String_Ptr := save_argv (Next_Arg);
 237             Argv_Len : constant Nat            := Len_Arg (Next_Arg);
 238             Argv     : constant String         :=
 239                          Argv_Ptr (1 .. Natural (Argv_Len));
 240
 241          begin
 242             --  If the previous switch has set the Output_File_Name_Present
 243             --  flag (that is we have seen a -gnatO), then the next argument
 244             --  is the name of the output object file.
 245
 246             if Output_File_Name_Present
 247               and then not Output_File_Name_Seen
 248             then
 249                if Is_Switch (Argv) then
 250                   Fail ("Object file name missing after -gnatO");
 251
 252                else
 253                   Set_Output_Object_File_Name (Argv);
 254                   Output_File_Name_Seen := True;
 255                end if;
 256
 257             --  If the previous switch has set the Search_Directory_Present
 258             --  flag (that is if we have just seen -I), then the next argument
 259             --  is a search directory path.
 260
 261             elsif Search_Directory_Present then
 262                if Is_Switch (Argv) then
 263                   Fail ("search directory missing after -I");
 264                else
 265                   Add_Src_Search_Dir (Argv);
 266                   Search_Directory_Present := False;
 267                end if;
 268
 269             elsif not Is_Switch (Argv) then -- must be a file name
 270                Add_File (Argv);
 271
 272             --  We must recognize -nostdinc to suppress visibility on the
 273             --  standard GNAT RTL sources. This is also a gcc switch.
 274
 275             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdinc" then
 276                Opt.No_Stdinc := True;
 277                Scan_Back_End_Switches (Argv);
 278
 279             --  We must recognize -nostdlib to suppress visibility on the
 280             --  standard GNAT RTL objects.
 281
 282             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdlib" then
 283                Opt.No_Stdlib := True;
 284
 285             elsif Is_Front_End_Switch (Argv) then
 286                Scan_Front_End_Switches (Argv);
 287
 288             --  All non-front-end switches are back-end switches
 289
 290             else
 291                Scan_Back_End_Switches (Argv);
 292             end if;
 293          end Look_At_Arg;
 294
 295          Next_Arg := Next_Arg + 1;
 296       end loop;
 297    end Scan_Compiler_Arguments;
 298
 299 end Back_End;