gcc/ada/ali.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  A L I                                   --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package defines the internal data structures used for representation
  27 --  of Ada Library Information (ALI) acquired from the ALI files generated
  28 --  by the front end.
  29
  30 with Casing;  use Casing;
  31 with Gnatvsn; use Gnatvsn;
  32 with Namet;   use Namet;
  33 with Rident;  use Rident;
  34 with Table;
  35 with Types;   use Types;
  36
  37 with GNAT.HTable; use GNAT.HTable;
  38
  39 package ALI is
  40
  41    --------------
  42    -- Id Types --
  43    --------------
  44
  45    --  The various entries are stored in tables with distinct subscript ranges.
  46    --  The following type definitions show the ranges used for the subscripts
  47    --  (Id values) for the various tables.
  48
  49    type ALI_Id is range 0 .. 999_999;
  50    --  Id values used for ALIs table entries
  51
  52    type Unit_Id is range 1_000_000 .. 1_999_999;
  53    --  Id values used for Unit table entries
  54
  55    type With_Id is range 2_000_000 .. 2_999_999;
  56    --  Id values used for Withs table entries
  57
  58    type Arg_Id is range 3_000_000 .. 3_999_999;
  59    --  Id values used for argument table entries
  60
  61    type Sdep_Id is range 4_000_000 .. 4_999_999;
  62    --  Id values used for Sdep table entries
  63
  64    type Source_Id is range 5_000_000 .. 5_999_999;
  65    --  Id values used for Source table entries
  66
  67    type Interrupt_State_Id is range 6_000_000 .. 6_999_999;
  68    --  Id values used for Interrupt_State table entries
  69
  70    type Priority_Specific_Dispatching_Id is range 7_000_000 .. 7_999_999;
  71    --  Id values used for Priority_Specific_Dispatching table entries
  72
  73    --------------------
  74    -- ALI File Table --
  75    --------------------
  76
  77    --  Each ALI file read generates an entry in the ALIs table
  78
  79    No_ALI_Id : constant ALI_Id := ALI_Id'First;
  80    --  Special value indicating no ALI entry
  81
  82    First_ALI_Entry : constant ALI_Id := No_ALI_Id + 1;
  83    --  Id of first actual entry in table
  84
  85    type Main_Program_Type is (None, Proc, Func);
  86    --  Indicator of whether unit can be used as main program
  87
  88    type ALIs_Record is record
  89
  90       Afile : File_Name_Type;
  91       --  Name of ALI file
  92
  93       Ofile_Full_Name : File_Name_Type;
  94       --  Full name of object file corresponding to the ALI file
  95
  96       Sfile : File_Name_Type;
  97       --  Name of source file that generates this ALI file (which is equal
  98       --  to the name of the source file in the first unit table entry for
  99       --  this ALI file, since the body if present is always first).
 100
 101       Ver : String (1 .. Ver_Len_Max);
 102       --  Value of library version (V line in ALI file). Not set if
 103       --  V lines are ignored as a result of the Ignore_Lines parameter.
 104
 105       Ver_Len : Natural;
 106       --  Length of characters stored in Ver. Not set if V lines are ignored as
 107       --  a result of the Ignore_Lines parameter.
 108
 109       SAL_Interface : Boolean;
 110       --  Set True when this is an interface to a standalone library
 111
 112       First_Unit : Unit_Id;
 113       --  Id of first Unit table entry for this file
 114
 115       Last_Unit : Unit_Id;
 116       --  Id of last Unit table entry for this file
 117
 118       First_Sdep : Sdep_Id;
 119       --  Id of first Sdep table entry for this file
 120
 121       Last_Sdep : Sdep_Id;
 122       --  Id of last Sdep table entry for this file
 123
 124       Main_Program : Main_Program_Type;
 125       --  Indicator of whether first unit can be used as main program. Not set
 126       --  if 'M' appears in Ignore_Lines.
 127
 128       Main_Priority : Int;
 129       --  Indicates priority value if Main_Program field indicates that this
 130       --  can be a main program. A value of -1 (No_Main_Priority) indicates
 131       --  that no parameter was found, or no M line was present. Not set if
 132       --  'M' appears in Ignore_Lines.
 133
 134       Time_Slice_Value : Int;
 135       --  Indicates value of time slice parameter from T=xxx on main program
 136       --  line. A value of -1 indicates that no T=xxx parameter was found, or
 137       --  no M line was present. Not set if 'M' appears in Ignore_Lines.
 138
 139       WC_Encoding : Character;
 140       --  Wide character encoding if main procedure. Otherwise not relevant.
 141       --  Not set if 'M' appears in Ignore_Lines.
 142
 143       Locking_Policy : Character;
 144       --  Indicates locking policy for units in this file. Space means tasking
 145       --  was not used, or that no Locking_Policy pragma was present or that
 146       --  this is a language defined unit. Otherwise set to first character
 147       --  (upper case) of policy name. Not set if 'P' appears in Ignore_Lines.
 148
 149       Queuing_Policy : Character;
 150       --  Indicates queuing policy for units in this file. Space means tasking
 151       --  was not used, or that no Queuing_Policy pragma was present or that
 152       --  this is a language defined unit. Otherwise set to first character
 153       --  (upper case) of policy name. Not set if 'P' appears in Ignore_Lines.
 154
 155       Task_Dispatching_Policy : Character;
 156       --  Indicates task dispatching policy for units in this file. Space means
 157       --  tasking was not used, or that no Task_Dispatching_Policy pragma was
 158       --  present or that this is a language defined unit. Otherwise set to
 159       --  first character (upper case) of policy name. Not set if 'P' appears
 160       --  in Ignore_Lines.
 161
 162       Compile_Errors : Boolean;
 163       --  Set to True if compile errors for unit. Note that No_Object will
 164       --  always be set as well in this case. Not set if 'P' appears in
 165       --  Ignore_Lines.
 166
 167       Float_Format : Character;
 168       --  Set to float format (set to I if no float-format given). Not set if
 169       --  'P' appears in Ignore_Lines.
 170
 171       No_Object : Boolean;
 172       --  Set to True if no object file generated. Not set if 'P' appears in
 173       --  Ignore_Lines.
 174
 175       Normalize_Scalars : Boolean;
 176       --  Set to True if file was compiled with Normalize_Scalars. Not set if
 177       --  'P' appears in Ignore_Lines.
 178
 179       Unit_Exception_Table : Boolean;
 180       --  Set to True if unit exception table pointer generated. Not set if 'P'
 181       --  appears in Ignore_Lines.
 182
 183       Zero_Cost_Exceptions : Boolean;
 184       --  Set to True if file was compiled with zero cost exceptions. Not set
 185       --  if 'P' appears in Ignore_Lines.
 186
 187       Restrictions : Restrictions_Info;
 188       --  Restrictions information reconstructed from R lines
 189
 190       First_Interrupt_State : Interrupt_State_Id;
 191       Last_Interrupt_State  : Interrupt_State_Id'Base;
 192       --  These point to the first and last entries in the interrupt state
 193       --  table for this unit. If no entries, then Last_Interrupt_State =
 194       --  First_Interrupt_State - 1 (that's why the 'Base reference is there,
 195       --  it can be one less than the lower bound of the subtype). Not set if
 196       --  'I' appears in Ignore_Lines
 197
 198       First_Specific_Dispatching : Priority_Specific_Dispatching_Id;
 199       Last_Specific_Dispatching  : Priority_Specific_Dispatching_Id'Base;
 200       --  These point to the first and last entries in the priority specific
 201       --  dispatching table for this unit. If there are no entries, then
 202       --  Last_Specific_Dispatching = First_Specific_Dispatching - 1. That
 203       --  is why the 'Base reference is there, it can be one less than the
 204       --  lower bound of the subtype. Not set if 'S' appears in Ignore_Lines.
 205
 206    end record;
 207
 208    No_Main_Priority : constant Int := -1;
 209    --  Code for no main priority set
 210
 211    package ALIs is new Table.Table (
 212      Table_Component_Type => ALIs_Record,
 213      Table_Index_Type     => ALI_Id,
 214      Table_Low_Bound      => First_ALI_Entry,
 215      Table_Initial        => 500,
 216      Table_Increment      => 200,
 217      Table_Name           => "ALIs");
 218
 219    ----------------
 220    -- Unit Table --
 221    ----------------
 222
 223    --  Each unit within an ALI file generates an entry in the unit table
 224
 225    No_Unit_Id : constant Unit_Id := Unit_Id'First;
 226    --  Special value indicating no unit table entry
 227
 228    First_Unit_Entry : constant Unit_Id := No_Unit_Id + 1;
 229    --  Id of first actual entry in table
 230
 231    type Unit_Type is (Is_Spec, Is_Body, Is_Spec_Only, Is_Body_Only);
 232    --  Indicates type of entry, if both body and spec appear in the ALI file,
 233    --  then the first unit is marked Is_Body, and the second is marked Is_Spec.
 234    --  If only a spec appears, then it is marked as Is_Spec_Only, and if only
 235    --  a body appears, then it is marked Is_Body_Only).
 236
 237    subtype Version_String is String (1 .. 8);
 238    --  Version string, taken from unit record
 239
 240    type Unit_Record is record
 241
 242       My_ALI : ALI_Id;
 243       --  Corresponding ALI entry
 244
 245       Uname : Unit_Name_Type;
 246       --  Name of Unit
 247
 248       Sfile : File_Name_Type;
 249       --  Name of source file
 250
 251       Preelab : Boolean;
 252       --  Indicates presence of PR parameter for a preelaborated package
 253
 254       No_Elab : Boolean;
 255       --  Indicates presence of NE parameter for a unit that has does not
 256       --  have an elaboration routine (since it has no elaboration code).
 257
 258       Pure : Boolean;
 259       --  Indicates presence of PU parameter for a package having pragma Pure
 260
 261       Dynamic_Elab : Boolean;
 262       --  Set to True if the unit was compiled with dynamic elaboration checks
 263       --  (i.e. either -gnatE or pragma Elaboration_Checks (RM) was used to
 264       --  compile the unit).
 265
 266       Elaborate_Body : Boolean;
 267       --  Indicates presence of EB parameter for a package which has a pragma
 268       --  Elaborate_Body, and also for generic package instantiations.
 269
 270       Set_Elab_Entity : Boolean;
 271       --  Indicates presence of EE parameter for a unit which has an
 272       --  elaboration entity which must be set true as part of the
 273       --  elaboration of the entity.
 274
 275       Has_RACW : Boolean;
 276       --  Indicates presence of RA parameter for a package that declares at
 277       --  least one Remote Access to Class_Wide (RACW) object.
 278
 279       Remote_Types : Boolean;
 280       --  Indicates presence of RT parameter for a package which has a
 281       --  pragma Remote_Types.
 282
 283       Shared_Passive : Boolean;
 284       --  Indicates presence of SP parameter for a package which has a pragma
 285       --  Shared_Passive.
 286
 287       RCI : Boolean;
 288       --  Indicates presence of RC parameter for a package which has a pragma
 289       --  Remote_Call_Interface.
 290
 291       Predefined : Boolean;
 292       --  Indicates if unit is language predefined (or a child of such a unit)
 293
 294       Internal : Boolean;
 295       --  Indicates if unit is an internal unit (or a child of such a unit)
 296
 297       First_With : With_Id;
 298       --  Id of first withs table entry for this file
 299
 300       Last_With : With_Id;
 301       --  Id of last withs table entry for this file
 302
 303       First_Arg : Arg_Id;
 304       --  Id of first args table entry for this file
 305
 306       Last_Arg : Arg_Id;
 307       --  Id of last args table entry for this file
 308
 309       Utype : Unit_Type;
 310       --  Type of entry
 311
 312       Is_Generic : Boolean;
 313       --  True for generic unit (i.e. a generic declaration, or a generic
 314       --  body). False for a non-generic unit.
 315
 316       Unit_Kind : Character;
 317       --  Indicates the nature of the unit. 'p' for Packages and 's' for
 318       --  subprograms.
 319
 320       Version : Version_String;
 321       --  Version of unit
 322
 323       Icasing : Casing_Type;
 324       --  Indicates casing of identifiers in source file for this unit. This
 325       --  is used for informational output, and also for constructing the main
 326       --  unit if it is being built in Ada.
 327
 328       Kcasing : Casing_Type;
 329       --  Indicates casing of keywords in source file for this unit. This is
 330       --  used for informational output, and also for constructing the main
 331       --  unit if it is being built in Ada.
 332
 333       Elab_Position : aliased Natural;
 334       --  Initialized to zero. Set non-zero when a unit is chosen and
 335       --  placed in the elaboration order. The value represents the
 336       --  ordinal position in the elaboration order.
 337
 338       Init_Scalars : Boolean;
 339       --  Set True if IS qualifier appears in ALI file, indicating that
 340       --  an Initialize_Scalars pragma applies to the unit.
 341
 342       SAL_Interface : Boolean;
 343       --  Set True when this is an interface to a standalone library
 344
 345       Body_Needed_For_SAL : Boolean;
 346       --  Indicates that the source for the body of the unit (subprogram,
 347       --  package, or generic unit) must be included in a standalone library.
 348
 349       Elaborate_Body_Desirable : Boolean;
 350       --  Indicates that the front end elaboration circuitry decided that it
 351       --  would be a good idea if this package had Elaborate_Body. The binder
 352       --  will attempt, but does not promise, to place the elaboration call
 353       --  for the body right after the call for the spec, or at least as close
 354       --  together as possible.
 355
 356       Optimize_Alignment : Character;
 357       --  Optimize_Alignment setting. Set to L/S/T/O for OL/OS/OT/OO present
 358
 359    end record;
 360
 361    package Units is new Table.Table (
 362      Table_Component_Type => Unit_Record,
 363      Table_Index_Type     => Unit_Id,
 364      Table_Low_Bound      => First_Unit_Entry,
 365      Table_Initial        => 100,
 366      Table_Increment      => 200,
 367      Table_Name           => "Unit");
 368
 369    ---------------------------
 370    -- Interrupt State Table --
 371    ---------------------------
 372
 373    --  An entry is made in this table for each I (interrupt state) line
 374    --  encountered in the input ALI file. The First/Last_Interrupt_Id
 375    --  fields of the ALI file entry show the range of entries defined
 376    --  within a particular ALI file.
 377
 378    type Interrupt_State_Record is record
 379       Interrupt_Id : Nat;
 380       --  Id from interrupt state entry
 381
 382       Interrupt_State : Character;
 383       --  State from interrupt state entry ('u'/'r'/'s')
 384
 385       IS_Pragma_Line : Nat;
 386       --  Line number of Interrupt_State pragma
 387    end record;
 388
 389    package Interrupt_States is new Table.Table (
 390      Table_Component_Type => Interrupt_State_Record,
 391      Table_Index_Type     => Interrupt_State_Id'Base,
 392      Table_Low_Bound      => Interrupt_State_Id'First,
 393      Table_Initial        => 100,
 394      Table_Increment      => 200,
 395      Table_Name           => "Interrupt_States");
 396
 397    -----------------------------------------
 398    -- Priority Specific Dispatching Table --
 399    -----------------------------------------
 400
 401    --  An entry is made in this table for each S (priority specific
 402    --  dispatching) line encountered in the input ALI file. The
 403    --  First/Last_Specific_Dispatching_Id fields of the ALI file
 404    --  entry show the range of entries defined within a particular
 405    --  ALI file.
 406
 407    type Specific_Dispatching_Record is record
 408       Dispatching_Policy : Character;
 409       --  First character (upper case) of the corresponding policy name
 410
 411       First_Priority     : Nat;
 412       --  Lower bound of the priority range to which the specified dispatching
 413       --  policy applies.
 414
 415       Last_Priority      : Nat;
 416       --  Upper bound of the priority range to which the specified dispatching
 417       --  policy applies.
 418
 419       PSD_Pragma_Line : Nat;
 420       --  Line number of Priority_Specific_Dispatching pragma
 421    end record;
 422
 423    package Specific_Dispatching is new Table.Table (
 424      Table_Component_Type => Specific_Dispatching_Record,
 425      Table_Index_Type     => Priority_Specific_Dispatching_Id'Base,
 426      Table_Low_Bound      => Priority_Specific_Dispatching_Id'First,
 427      Table_Initial        => 100,
 428      Table_Increment      => 200,
 429      Table_Name           => "Priority_Specific_Dispatching");
 430
 431    --------------
 432    -- Switches --
 433    --------------
 434
 435    --  These switches record status information about ali files that
 436    --  have been read, for quick reference without searching tables.
 437
 438    --  Note: a switch will be left set at its default value if the line
 439    --  which might otherwise set it is ignored (from Ignore_Lines).
 440
 441    Dynamic_Elaboration_Checks_Specified : Boolean := False;
 442    --  Set to False by Initialize_ALI. Set to True if Scan_ALI reads
 443    --  a unit for which dynamic elaboration checking is enabled.
 444
 445    Float_Format_Specified : Character := ' ';
 446    --  Set to blank by Initialize_ALI. Set to appropriate float format
 447    --  character (V or I, see Opt.Float_Format) if an ali file that
 448    --  is read contains an F line setting the floating point format.
 449
 450    Initialize_Scalars_Used : Boolean := False;
 451    --  Set True if an ali file contains the Initialize_Scalars flag
 452
 453    Locking_Policy_Specified : Character := ' ';
 454    --  Set to blank by Initialize_ALI. Set to the appropriate locking policy
 455    --  character if an ali file contains a P line setting the locking policy.
 456
 457    No_Normalize_Scalars_Specified : Boolean := False;
 458    --  Set to False by Initialize_ALI. Set to True if an ali file indicates
 459    --  that the file was compiled without normalize scalars.
 460
 461    No_Object_Specified : Boolean := False;
 462    --  Set to False by Initialize_ALI. Set to True if an ali file contains
 463    --  the No_Object flag.
 464
 465    Normalize_Scalars_Specified : Boolean := False;
 466    --  Set to False by Initialize_ALI. Set to True if an ali file indicates
 467    --  that the file was compiled in Normalize_Scalars mode.
 468
 469    Queuing_Policy_Specified : Character := ' ';
 470    --  Set to blank by Initialize_ALI. Set to the appropriate queuing policy
 471    --  character if an ali file contains a P line setting the queuing policy.
 472
 473    Cumulative_Restrictions : Restrictions_Info := No_Restrictions;
 474    --  This variable records the cumulative contributions of R lines in all
 475    --  ali files, showing whether a restriction pragma exists anywhere, and
 476    --  accumulating the aggregate knowledge of violations.
 477
 478    Stack_Check_Switch_Set : Boolean := False;
 479    --  Set to True if at least one ALI file contains '-fstack-check' in its
 480    --  argument list.
 481
 482    Static_Elaboration_Model_Used : Boolean := False;
 483    --  Set to False by Initialize_ALI. Set to True if any ALI file for a
 484    --  non-internal unit compiled with the static elaboration model is
 485    --  encountered.
 486
 487    Task_Dispatching_Policy_Specified : Character := ' ';
 488    --  Set to blank by Initialize_ALI. Set to the appropriate task dispatching
 489    --  policy character if an ali file contains a P line setting the
 490    --  task dispatching policy.
 491
 492    Unreserve_All_Interrupts_Specified : Boolean := False;
 493    --  Set to False by Initialize_ALI. Set to True if an ali file is read that
 494    --  has  P line specifying unreserve all interrupts mode.
 495
 496    Zero_Cost_Exceptions_Specified : Boolean := False;
 497    --  Set to False by Initialize_ALI. Set to True if an ali file is read that
 498    --  has a P line specifying the generation of zero cost exceptions.
 499
 500    -----------------
 501    -- Withs Table --
 502    -----------------
 503
 504    --  Each With line (W line) in an ALI file generates a Withs table entry
 505
 506    --  Note: there will be no entries in this table if 'W' lines are ignored
 507
 508    No_With_Id : constant With_Id := With_Id'First;
 509    --  Special value indicating no withs table entry
 510
 511    First_With_Entry : constant With_Id := No_With_Id + 1;
 512    --  Id of first actual entry in table
 513
 514    type With_Record is record
 515
 516       Uname : Unit_Name_Type;
 517       --  Name of Unit
 518
 519       Sfile : File_Name_Type;
 520       --  Name of source file, set to No_File in generic case
 521
 522       Afile : File_Name_Type;
 523       --  Name of ALI file, set to No_File in generic case
 524
 525       Elaborate : Boolean;
 526       --  Indicates presence of E parameter
 527
 528       Elaborate_All : Boolean;
 529       --  Indicates presence of EA parameter
 530
 531       Elab_All_Desirable : Boolean;
 532       --  Indicates presence of AD parameter
 533
 534       Elab_Desirable     : Boolean;
 535       --  Indicates presence of ED parameter
 536
 537       SAL_Interface : Boolean := False;
 538       --  True if the Unit is an Interface of a Stand-Alone Library
 539
 540       Limited_With : Boolean := False;
 541       --  True if unit is named in a limited_with_clause
 542    end record;
 543
 544    package Withs is new Table.Table (
 545      Table_Component_Type => With_Record,
 546      Table_Index_Type     => With_Id,
 547      Table_Low_Bound      => First_With_Entry,
 548      Table_Initial        => 5000,
 549      Table_Increment      => 200,
 550      Table_Name           => "Withs");
 551
 552    ---------------------
 553    -- Arguments Table --
 554    ---------------------
 555
 556    --  Each Arg line (A line) in an ALI file generates an Args table entry
 557
 558    --  Note: there will be no entries in this table if 'A' lines are ignored
 559
 560    No_Arg_Id : constant Arg_Id := Arg_Id'First;
 561    --  Special value indicating no args table entry
 562
 563    First_Arg_Entry : constant Arg_Id := No_Arg_Id + 1;
 564    --  Id of first actual entry in table
 565
 566    package Args is new Table.Table (
 567      Table_Component_Type => String_Ptr,
 568      Table_Index_Type     => Arg_Id,
 569      Table_Low_Bound      => First_Arg_Entry,
 570      Table_Initial        => 1000,
 571      Table_Increment      => 100,
 572      Table_Name           => "Args");
 573
 574    --------------------------
 575    -- Linker_Options Table --
 576    --------------------------
 577
 578    --  If an ALI file has one of more Linker_Options lines, then a single
 579    --  entry is made in this table. If more than one Linker_Options lines
 580    --  appears in a given ALI file, then the arguments are concatenated
 581    --  to form the entry in this table, using a NUL character as the
 582    --  separator, and a final NUL character is appended to the end.
 583
 584    --  Note: there will be no entries in this table if 'L' lines are ignored
 585
 586    type Linker_Option_Record is record
 587       Name : Name_Id;
 588       --  Name entry containing concatenated list of Linker_Options
 589       --  arguments separated by NUL and ended by NUL as described above.
 590
 591       Unit : Unit_Id;
 592       --  Unit_Id for the entry
 593
 594       Internal_File : Boolean;
 595       --  Set True if the linker options are from an internal file. This is
 596       --  used to insert certain standard entries after all the user entries
 597       --  but before the entries from the run-time.
 598
 599       Original_Pos : Positive;
 600       --  Keep track of original position in the linker options table. This
 601       --  is used to implement a stable sort when we sort the linker options
 602       --  table.
 603    end record;
 604
 605    --  Declare the Linker_Options Table
 606
 607    --  The indexes of active entries in this table range from 1 to the
 608    --  value of Linker_Options.Last. The zero'th element is for sort call.
 609
 610    package Linker_Options is new Table.Table (
 611      Table_Component_Type => Linker_Option_Record,
 612      Table_Index_Type     => Integer,
 613      Table_Low_Bound      => 0,
 614      Table_Initial        => 200,
 615      Table_Increment      => 400,
 616      Table_Name           => "Linker_Options");
 617
 618    -------------------------------------------
 619    -- External Version Reference Hash Table --
 620    -------------------------------------------
 621
 622    --  This hash table keeps track of external version reference strings
 623    --  as read from E lines in the ali file. The stored values do not
 624    --  include the terminating quote characters.
 625
 626    --  Note: there will be no entries in this table if 'E' lines are ignored
 627
 628    type Vindex is range 0 .. 98;
 629    --  Type to define range of headers
 630
 631    function SHash (S : String_Ptr) return Vindex;
 632    --  Hash function for this table
 633
 634    function SEq (F1, F2 : String_Ptr) return Boolean;
 635    --  Equality function for this table
 636
 637    package Version_Ref is new Simple_HTable (
 638      Header_Num => Vindex,
 639      Element    => Boolean,
 640      No_Element => False,
 641      Key        => String_Ptr,
 642      Hash       => SHash,
 643      Equal      => SEq);
 644
 645    -------------------------
 646    -- No_Dependency Table --
 647    -------------------------
 648
 649    --  Each R line for a No_Dependency Restriction generates an entry in
 650    --  this No_Dependency table.
 651
 652    type No_Dep_Record is record
 653       ALI_File : ALI_Id;
 654       --  ALI File containing the entry
 655
 656       No_Dep_Unit : Name_Id;
 657       --  Id for names table entry including entire name, including periods
 658    end record;
 659
 660    package No_Deps is new Table.Table (
 661      Table_Component_Type => No_Dep_Record,
 662      Table_Index_Type     => Integer,
 663      Table_Low_Bound      => 0,
 664      Table_Initial        => 200,
 665      Table_Increment      => 400,
 666      Table_Name           => "No_Deps");
 667
 668    ------------------------------------
 669    -- Sdep (Source Dependency) Table --
 670    ------------------------------------
 671
 672    --  Each source dependency (D line) in an ALI file generates an entry in the
 673    --  Sdep table.
 674
 675    --  Note: there will be no entries in this table if 'D' lines are ignored
 676
 677    No_Sdep_Id : constant Sdep_Id := Sdep_Id'First;
 678    --  Special value indicating no Sdep table entry
 679
 680    First_Sdep_Entry : Sdep_Id := No_Sdep_Id + 1;
 681    --  Id of first Sdep entry for current ali file. This is initialized to the
 682    --  first Sdep entry in the table, and then incremented appropriately as
 683    --  successive ALI files are scanned.
 684
 685    type Sdep_Record is record
 686
 687       Sfile : File_Name_Type;
 688       --  Name of source file
 689
 690       Stamp : Time_Stamp_Type;
 691       --  Time stamp value. Note that this will be all zero characters for the
 692       --  dummy entries for missing or non-dependent files.
 693
 694       Checksum : Word;
 695       --  Checksum value. Note that this will be all zero characters for the
 696       --  dummy entries for missing or non-dependent files
 697
 698       Dummy_Entry : Boolean;
 699       --  Set True for dummy entries that correspond to missing files or files
 700       --  where no dependency relationship exists.
 701
 702       Subunit_Name : Name_Id;
 703       --  Name_Id for subunit name if present, else No_Name
 704
 705       Rfile : File_Name_Type;
 706       --  Reference file name. Same as Sfile unless a Source_Reference pragma
 707       --  was used, in which case it reflects the name used in the pragma.
 708
 709       Start_Line : Nat;
 710       --  Starting line number in file. Always 1, unless a Source_Reference
 711       --  pragma was used, in which case it reflects the line number value
 712       --  given in the pragma.
 713
 714    end record;
 715
 716    package Sdep is new Table.Table (
 717      Table_Component_Type => Sdep_Record,
 718      Table_Index_Type     => Sdep_Id,
 719      Table_Low_Bound      => First_Sdep_Entry,
 720      Table_Initial        => 5000,
 721      Table_Increment      => 200,
 722      Table_Name           => "Sdep");
 723
 724    ----------------------------
 725    -- Use of Name Table Info --
 726    ----------------------------
 727
 728    --  All unit names and file names are entered into the Names table. The Info
 729    --  fields of these entries are used as follows:
 730
 731    --    Unit name           Info field has Unit_Id of unit table entry
 732    --    ALI file name       Info field has ALI_Id of ALI table entry
 733    --    Source file name    Info field has Source_Id of source table entry
 734
 735    --------------------------
 736    -- Cross-Reference Data --
 737    --------------------------
 738
 739    --  The following table records cross-reference sections, there is one entry
 740    --  for each X header line in the ALI file for an xref section.
 741
 742    --  Note: there will be no entries in this table if 'X' lines are ignored
 743
 744    type Xref_Section_Record is record
 745       File_Num : Sdep_Id;
 746       --  Dependency number for file (entry in Sdep.Table)
 747
 748       File_Name : File_Name_Type;
 749       --  Name of file
 750
 751       First_Entity : Nat;
 752       --  First entry in Xref_Entity table
 753
 754       Last_Entity : Nat;
 755       --  Last entry in Xref_Entity table
 756    end record;
 757
 758    package Xref_Section is new Table.Table (
 759      Table_Component_Type => Xref_Section_Record,
 760      Table_Index_Type     => Nat,
 761      Table_Low_Bound      => 1,
 762      Table_Initial        => 50,
 763      Table_Increment      => 300,
 764      Table_Name           => "Xref_Section");
 765
 766    --  The following is used to indicate whether a typeref field is present
 767    --  for the entity, and if so what kind of typeref field.
 768
 769    type Tref_Kind is (
 770      Tref_None,    --  No typeref present
 771      Tref_Access,  --  Access type typeref (points to designated type)
 772      Tref_Derived, --  Derived type typeref (points to parent type)
 773      Tref_Type);   --  All other cases
 774
 775    --  The following table records entities for which xrefs are recorded
 776
 777    type Xref_Entity_Record is record
 778       Line : Pos;
 779       --  Line number of definition
 780
 781       Etype : Character;
 782       --  Set to the identification character for the entity. See section
 783       --  "Cross-Reference Entity Identifiers" in lib-xref.ads for details.
 784
 785       Col : Pos;
 786       --  Column number of definition
 787
 788       Lib : Boolean;
 789       --  True if entity is library level entity
 790
 791       Entity : Name_Id;
 792       --  Name of entity
 793
 794       Iref_File_Num : Sdep_Id;
 795       --  This field is set to the dependency reference for the file containing
 796       --  the generic entity that this one instantiates, or to No_Sdep_Id if
 797       --  the current entity is not an instantiation
 798
 799       Iref_Line : Nat;
 800       --  This field is set to the line number in Iref_File_Num of the generic
 801       --  entity that this one instantiates, or to zero if the current entity
 802       --  is not an instantiation.
 803
 804       Rref_Line : Nat;
 805       --  This field is set to the line number of a renaming reference if
 806       --  one is present, or to zero if no renaming reference is present
 807
 808       Rref_Col : Nat;
 809       --  This field is set to the column number of a renaming reference
 810       --  if one is present, or to zero if no renaming reference is present.
 811
 812       Tref : Tref_Kind;
 813       --  Indicates if a typeref is present, and if so what kind. Set to
 814       --  Tref_None if no typeref field is present.
 815
 816       Tref_File_Num : Sdep_Id;
 817       --  This field is set to No_Sdep_Id if no typeref is present, or
 818       --  if the typeref refers to an entity in standard. Otherwise it
 819       --  it is the dependency reference for the file containing the
 820       --  declaration of the typeref entity.
 821
 822       Tref_Line : Nat;
 823       --  This field is set to zero if no typeref is present, or if the
 824       --  typeref refers to an entity in standard. Otherwise it contains
 825       --  the line number of the declaration of the typeref entity.
 826
 827       Tref_Type : Character;
 828       --  This field is set to blank if no typeref is present, or if the
 829       --  typeref refers to an entity in standard. Otherwise it contains
 830       --  the identification character for the typeref entity. See section
 831       --  "Cross-Reference Entity Identifiers" in lib-xref.ads for details.
 832
 833       Tref_Col : Nat;
 834       --  This field is set to zero if no typeref is present, or if the
 835       --  typeref refers to an entity in standard. Otherwise it contains
 836       --  the column number of the declaration of the parent type.
 837
 838       Tref_Standard_Entity : Name_Id;
 839       --  This field is set to No_Name if no typeref is present or if the
 840       --  typeref refers to a declared entity rather than an entity in
 841       --  package Standard. If there is a typeref that references an
 842       --  entity in package Standard, then this field is a Name_Id
 843       --  reference for the entity name.
 844
 845       Oref_File_Num : Sdep_Id;
 846       --  This field is set to No_Sdep_Id if the entity doesn't override any
 847       --  other entity, or to the dependency reference for the overridden
 848       --  entity.
 849
 850       Oref_Line : Nat;
 851       Oref_Col  : Nat;
 852       --  These two fields are set to the line and column of the overridden
 853       --  entity.
 854
 855       First_Xref : Nat;
 856       --  Index into Xref table of first cross-reference
 857
 858       Last_Xref : Nat;
 859       --  Index into Xref table of last cross-reference. The value in
 860       --  Last_Xref can be less than the First_Xref value to indicate
 861       --  that no entries are present in the Xref Table.
 862    end record;
 863
 864    package Xref_Entity is new Table.Table (
 865      Table_Component_Type => Xref_Entity_Record,
 866      Table_Index_Type     => Nat,
 867      Table_Low_Bound      => 1,
 868      Table_Initial        => 500,
 869      Table_Increment      => 300,
 870      Table_Name           => "Xref_Entity");
 871
 872    Array_Index_Reference : constant Character := '*';
 873    Interface_Reference   : constant Character := 'I';
 874    --  Some special types of references. In the ALI file itself, these
 875    --  are output as attributes of the entity, not as references, but
 876    --  there is no provision in Xref_Entity_Record for storing multiple
 877    --  such references.
 878
 879    --  The following table records actual cross-references
 880
 881    type Xref_Record is record
 882       File_Num : Sdep_Id;
 883       --  Set to the file dependency number for the cross-reference. Note
 884       --  that if no file entry is present explicitly, this is just a copy
 885       --  of the reference for the current cross-reference section.
 886
 887       Line : Nat;
 888       --  Line number for the reference. This is zero when referencing a
 889       --  predefined entity, but in this case Name is set.
 890
 891       Rtype : Character;
 892       --  Indicates type of reference, using code used in ALI file:
 893       --    r = reference
 894       --    m = modification
 895       --    b = body entity
 896       --    c = completion of private or incomplete type
 897       --    x = type extension
 898       --    i = implicit reference
 899       --    Array_Index_Reference = reference to the index of an array
 900       --    Interface_Reference   = reference to an interface implemented
 901       --                            by the type
 902       --  See description in lib-xref.ads for further details
 903
 904       Col : Nat;
 905       --  Column number for the reference
 906
 907       Name : Name_Id := No_Name;
 908       --  This is only used when referencing a predefined entity. Currently,
 909       --  this only occurs for array indexes.
 910
 911       --  Note: for instantiation references, Rtype is set to ' ', and Col is
 912       --  set to zero. One or more such entries can follow any other reference.
 913       --  When there is more than one such entry, this is to be read as:
 914       --     e.g. ref1  ref2  ref3
 915       --     ref1 is a reference to an entity that was instantied at ref2.
 916       --     ref2 itself is also the result of an instantiation, that took
 917       --     place at ref3
 918    end record;
 919
 920    package Xref is new Table.Table (
 921      Table_Component_Type => Xref_Record,
 922      Table_Index_Type     => Nat,
 923      Table_Low_Bound      => 1,
 924      Table_Initial        => 2000,
 925      Table_Increment      => 300,
 926      Table_Name           => "Xref");
 927
 928    --------------------------------------
 929    -- Subprograms for Reading ALI File --
 930    --------------------------------------
 931
 932    procedure Initialize_ALI;
 933    --  Initialize the ALI tables. Also resets all switch values to defaults
 934
 935    function Scan_ALI
 936      (F             : File_Name_Type;
 937       T             : Text_Buffer_Ptr;
 938       Ignore_ED     : Boolean;
 939       Err           : Boolean;
 940       Read_Xref     : Boolean := False;
 941       Read_Lines    : String  := "";
 942       Ignore_Lines  : String  := "X";
 943       Ignore_Errors : Boolean := False) return ALI_Id;
 944    --  Given the text, T, of an ALI file, F, scan and store the information
 945    --  from the file, and return the Id of the resulting entry in the ALI
 946    --  table. Switch settings may be modified as described above in the
 947    --  switch description settings.
 948    --
 949    --    Ignore_ED is normally False. If set to True, it indicates that
 950    --    all AD/ED (elaboration desirable) indications in the ALI file are
 951    --    to be ignored. This parameter is obsolete now that the -f switch
 952    --    is removed from gnatbind, and should be removed ???
 953    --
 954    --    Err determines the action taken on an incorrectly formatted file.
 955    --    If Err is False, then an error message is output, and the program
 956    --    is terminated. If Err is True, then no error message is output,
 957    --    and No_ALI_Id is returned.
 958    --
 959    --    Ignore_Lines requests that Scan_ALI ignore any lines that start
 960    --    with any given key character. The default value of X causes all
 961    --    Xref lines to be ignored. The corresponding data in the ALI
 962    --    tables will not be filled in this case. It is not possible
 963    --    to ignore U (unit) lines, they are always read.
 964    --
 965    --    Read_Lines requests that Scan_ALI process only lines that start
 966    --    with one of the given characters. The corresponding data in the
 967    --    ALI file for any characters not given in the list will not be
 968    --    set. The default value of the null string indicates that all
 969    --    lines should be read (unless Ignore_Lines is specified). U
 970    --    (unit) lines are always read regardless of the value of this
 971    --    parameter.
 972    --
 973    --    Note: either Ignore_Lines or Read_Lines should be non-null, but not
 974    --    both. If both are provided then only the Read_Lines value is used,
 975    --    and the Ignore_Lines parameter is ignored.
 976    --
 977    --    Read_XREF is set True to read and acquire the cross-reference
 978    --    information. If Read_XREF is set to True, then the effect is to ignore
 979    --    all lines other than U, W, D and X lines and the Ignore_Lines and
 980    --    Read_Lines parameters are ignored (i.e. the use of True for Read_XREF
 981    --    is equivalent to specifying an argument of "UWDX" for Read_Lines.
 982    --
 983    --    Ignore_Errors is normally False. If it is set True, then Scan_ALI
 984    --    will do its best to scan through a file and extract all information
 985    --    it can, even if there are errors. In this case Err is only set if
 986    --    Scan_ALI was completely unable to process the file (e.g. it did not
 987    --    look like an ALI file at all). Ignore_Errors is intended to improve
 988    --    the downward compatibility of new compilers with old tools.
 989
 990 end ALI;