gcc/ada/a-ztinio.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --      A D A . W I D E _ W I D E _ T E X T _ I O . I N T E G E R _ I O     --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with Ada.Wide_Wide_Text_IO.Integer_Aux;
  33 with System.WCh_Con; use System.WCh_Con;
  34 with System.WCh_WtS; use System.WCh_WtS;
  35
  36 package body Ada.Wide_Wide_Text_IO.Integer_IO is
  37
  38    Need_LLI : constant Boolean := Num'Base'Size > Integer'Size;
  39    --  Throughout this generic body, we distinguish between the case
  40    --  where type Integer is acceptable, and where a Long_Long_Integer
  41    --  is needed. This constant Boolean is used to test for these cases
  42    --  and since it is a constant, only the code for the relevant case
  43    --  will be included in the instance.
  44
  45    subtype TFT is Ada.Wide_Wide_Text_IO.File_Type;
  46    --  File type required for calls to routines in Aux
  47
  48    package Aux renames Ada.Wide_Wide_Text_IO.Integer_Aux;
  49
  50    ---------
  51    -- Get --
  52    ---------
  53
  54    procedure Get
  55      (File  : File_Type;
  56       Item  : out Num;
  57       Width : Field := 0)
  58    is
  59    begin
  60       if Need_LLI then
  61          Aux.Get_LLI (TFT (File), Long_Long_Integer (Item), Width);
  62       else
  63          Aux.Get_Int (TFT (File), Integer (Item), Width);
  64       end if;
  65
  66    exception
  67       when Constraint_Error => raise Data_Error;
  68    end Get;
  69
  70    procedure Get
  71      (Item  : out Num;
  72       Width : Field := 0)
  73    is
  74    begin
  75       Get (Current_Input, Item, Width);
  76    end Get;
  77
  78    procedure Get
  79      (From : Wide_Wide_String;
  80       Item : out Num;
  81       Last : out Positive)
  82    is
  83       S : constant String := Wide_Wide_String_To_String (From, WCEM_Upper);
  84       --  String on which we do the actual conversion. Note that the method
  85       --  used for wide character encoding is irrelevant, since if there is
  86       --  a character outside the Standard.Character range then the call to
  87       --  Aux.Gets will raise Data_Error in any case.
  88
  89    begin
  90       if Need_LLI then
  91          Aux.Gets_LLI (S, Long_Long_Integer (Item), Last);
  92       else
  93          Aux.Gets_Int (S, Integer (Item), Last);
  94       end if;
  95
  96    exception
  97       when Constraint_Error => raise Data_Error;
  98    end Get;
  99
 100    ---------
 101    -- Put --
 102    ---------
 103
 104    procedure Put
 105      (File  : File_Type;
 106       Item  : Num;
 107       Width : Field := Default_Width;
 108       Base  : Number_Base := Default_Base)
 109    is
 110    begin
 111       if Need_LLI then
 112          Aux.Put_LLI (TFT (File), Long_Long_Integer (Item), Width, Base);
 113       else
 114          Aux.Put_Int (TFT (File), Integer (Item), Width, Base);
 115       end if;
 116    end Put;
 117
 118    procedure Put
 119      (Item  : Num;
 120       Width : Field := Default_Width;
 121       Base  : Number_Base := Default_Base)
 122    is
 123    begin
 124       Put (Current_Output, Item, Width, Base);
 125    end Put;
 126
 127    procedure Put
 128      (To   : out Wide_Wide_String;
 129       Item : Num;
 130       Base : Number_Base := Default_Base)
 131    is
 132       S : String (To'First .. To'Last);
 133
 134    begin
 135       if Need_LLI then
 136          Aux.Puts_LLI (S, Long_Long_Integer (Item), Base);
 137       else
 138          Aux.Puts_Int (S, Integer (Item), Base);
 139       end if;
 140
 141       for J in S'Range loop
 142          To (J) := Wide_Wide_Character'Val (Character'Pos (S (J)));
 143       end loop;
 144    end Put;
 145
 146 end Ada.Wide_Wide_Text_IO.Integer_IO;