gcc/ada/a-wtinio.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --           A D A . W I D E _ T E X T _ I O . I N T E G E R _ I O          --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Wide_Text_IO.Integer_Aux;
  35 with System.WCh_Con; use System.WCh_Con;
  36 with System.WCh_WtS; use System.WCh_WtS;
  37
  38 package body Ada.Wide_Text_IO.Integer_IO is
  39
  40    Need_LLI : constant Boolean := Num'Base'Size > Integer'Size;
  41    --  Throughout this generic body, we distinguish between the case
  42    --  where type Integer is acceptable, and where a Long_Long_Integer
  43    --  is needed. This constant Boolean is used to test for these cases
  44    --  and since it is a constant, only the code for the relevant case
  45    --  will be included in the instance.
  46
  47    subtype TFT is Ada.Wide_Text_IO.File_Type;
  48    --  File type required for calls to routines in Aux
  49
  50    package Aux renames Ada.Wide_Text_IO.Integer_Aux;
  51
  52    ---------
  53    -- Get --
  54    ---------
  55
  56    procedure Get
  57      (File  : File_Type;
  58       Item  : out Num;
  59       Width : Field := 0)
  60    is
  61    begin
  62       if Need_LLI then
  63          Aux.Get_LLI (TFT (File), Long_Long_Integer (Item), Width);
  64       else
  65          Aux.Get_Int (TFT (File), Integer (Item), Width);
  66       end if;
  67
  68    exception
  69       when Constraint_Error => raise Data_Error;
  70    end Get;
  71
  72    procedure Get
  73      (Item  : out Num;
  74       Width : Field := 0)
  75    is
  76    begin
  77       Get (Current_Input, Item, Width);
  78    end Get;
  79
  80    procedure Get
  81      (From : Wide_String;
  82       Item : out Num;
  83       Last : out Positive)
  84    is
  85       S : constant String := Wide_String_To_String (From, WCEM_Upper);
  86       --  String on which we do the actual conversion. Note that the method
  87       --  used for wide character encoding is irrelevant, since if there is
  88       --  a character outside the Standard.Character range then the call to
  89       --  Aux.Gets will raise Data_Error in any case.
  90
  91    begin
  92       if Need_LLI then
  93          Aux.Gets_LLI (S, Long_Long_Integer (Item), Last);
  94       else
  95          Aux.Gets_Int (S, Integer (Item), Last);
  96       end if;
  97
  98    exception
  99       when Constraint_Error => raise Data_Error;
 100    end Get;
 101
 102    ---------
 103    -- Put --
 104    ---------
 105
 106    procedure Put
 107      (File  : File_Type;
 108       Item  : Num;
 109       Width : Field := Default_Width;
 110       Base  : Number_Base := Default_Base)
 111    is
 112    begin
 113       if Need_LLI then
 114          Aux.Put_LLI (TFT (File), Long_Long_Integer (Item), Width, Base);
 115       else
 116          Aux.Put_Int (TFT (File), Integer (Item), Width, Base);
 117       end if;
 118    end Put;
 119
 120    procedure Put
 121      (Item  : Num;
 122       Width : Field := Default_Width;
 123       Base  : Number_Base := Default_Base)
 124    is
 125    begin
 126       Put (Current_Output, Item, Width, Base);
 127    end Put;
 128
 129    procedure Put
 130      (To   : out Wide_String;
 131       Item : Num;
 132       Base : Number_Base := Default_Base)
 133    is
 134       S : String (To'First .. To'Last);
 135
 136    begin
 137       if Need_LLI then
 138          Aux.Puts_LLI (S, Long_Long_Integer (Item), Base);
 139       else
 140          Aux.Puts_Int (S, Integer (Item), Base);
 141       end if;
 142
 143       for J in S'Range loop
 144          To (J) := Wide_Character'Val (Character'Pos (S (J)));
 145       end loop;
 146    end Put;
 147
 148 end Ada.Wide_Text_IO.Integer_IO;