gcc/ada/a-textio.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                          A D A . T E X T _ I O                           --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- GNAT was originally developed  by the GNAT team at  New York University. --
  34 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 --  Note: the generic subpackages of Text_IO (Integer_IO, Float_IO, Fixed_IO,
  39 --  Modular_IO, Decimal_IO and Enumeration_IO) appear as private children in
  40 --  GNAT. These children are with'ed automatically if they are referenced, so
  41 --  this rearrangement is invisible to user programs, but has the advantage
  42 --  that only the needed parts of Text_IO are processed and loaded.
  43
  44 with Ada.IO_Exceptions;
  45 with Ada.Streams;
  46 with System;
  47 with System.File_Control_Block;
  48 with System.WCh_Con;
  49
  50 package Ada.Text_IO is
  51    pragma Elaborate_Body;
  52
  53    type File_Type is limited private;
  54    type File_Mode is (In_File, Out_File, Append_File);
  55
  56    --  The following representation clause allows the use of unchecked
  57    --  conversion for rapid translation between the File_Mode type
  58    --  used in this package and System.File_IO.
  59
  60    for File_Mode use
  61      (In_File     => 0,  -- System.FIle_IO.File_Mode'Pos (In_File)
  62       Out_File    => 2,  -- System.File_IO.File_Mode'Pos (Out_File)
  63       Append_File => 3); -- System.File_IO.File_Mode'Pos (Append_File)
  64
  65    type Count is range 0 .. Natural'Last;
  66    --  The value of Count'Last must be large enough so that the assumption
  67    --  enough so that the assumption that the Line, Column and Page
  68    --  counts can never exceed this value is a valid assumption.
  69
  70    subtype Positive_Count is Count range 1 .. Count'Last;
  71
  72    Unbounded : constant Count := 0;
  73    --  Line and page length
  74
  75    subtype Field is Integer range 0 .. 255;
  76    --  Note: if for any reason, there is a need to increase this value,
  77    --  then it will be necessary to change the corresponding value in
  78    --  System.Img_Real in file s-imgrea.adb.
  79
  80    subtype Number_Base is Integer range 2 .. 16;
  81
  82    type Type_Set is (Lower_Case, Upper_Case);
  83
  84    ---------------------
  85    -- File Management --
  86    ---------------------
  87
  88    procedure Create
  89      (File : in out File_Type;
  90       Mode : File_Mode := Out_File;
  91       Name : String := "";
  92       Form : String := "");
  93
  94    procedure Open
  95      (File : in out File_Type;
  96       Mode : File_Mode;
  97       Name : String;
  98       Form : String := "");
  99
 100    procedure Close  (File : in out File_Type);
 101    procedure Delete (File : in out File_Type);
 102    procedure Reset  (File : in out File_Type; Mode : File_Mode);
 103    procedure Reset  (File : in out File_Type);
 104
 105    function Mode (File : File_Type) return File_Mode;
 106    function Name (File : File_Type) return String;
 107    function Form (File : File_Type) return String;
 108
 109    function Is_Open (File : File_Type) return Boolean;
 110
 111    ------------------------------------------------------
 112    -- Control of default input, output and error files --
 113    ------------------------------------------------------
 114
 115    procedure Set_Input  (File : File_Type);
 116    procedure Set_Output (File : File_Type);
 117    procedure Set_Error  (File : File_Type);
 118
 119    function Standard_Input  return File_Type;
 120    function Standard_Output return File_Type;
 121    function Standard_Error  return File_Type;
 122
 123    function Current_Input  return File_Type;
 124    function Current_Output return File_Type;
 125    function Current_Error  return File_Type;
 126
 127    type File_Access is access constant File_Type;
 128
 129    function Standard_Input  return File_Access;
 130    function Standard_Output return File_Access;
 131    function Standard_Error  return File_Access;
 132
 133    function Current_Input  return File_Access;
 134    function Current_Output return File_Access;
 135    function Current_Error  return File_Access;
 136
 137    --------------------
 138    -- Buffer control --
 139    --------------------
 140
 141    --  Note: The parameter file is IN OUT in the RM, but this is clearly
 142    --  an oversight, and was intended to be IN, see AI95-00057.
 143
 144    procedure Flush (File : File_Type);
 145    procedure Flush;
 146
 147    --------------------------------------------
 148    -- Specification of line and page lengths --
 149    --------------------------------------------
 150
 151    procedure Set_Line_Length (File : File_Type; To : Count);
 152    procedure Set_Line_Length (To : Count);
 153
 154    procedure Set_Page_Length (File : File_Type; To : Count);
 155    procedure Set_Page_Length (To : Count);
 156
 157    function Line_Length (File : File_Type) return Count;
 158    function Line_Length return Count;
 159
 160    function Page_Length (File : File_Type) return Count;
 161    function Page_Length return Count;
 162
 163    ------------------------------------
 164    -- Column, Line, and Page Control --
 165    ------------------------------------
 166
 167    procedure New_Line (File : File_Type; Spacing : Positive_Count := 1);
 168    procedure New_Line (Spacing : Positive_Count := 1);
 169
 170    procedure Skip_Line (File : File_Type; Spacing : Positive_Count := 1);
 171    procedure Skip_Line (Spacing : Positive_Count := 1);
 172
 173    function End_Of_Line (File : File_Type) return Boolean;
 174    function End_Of_Line return Boolean;
 175
 176    procedure New_Page (File : File_Type);
 177    procedure New_Page;
 178
 179    procedure Skip_Page (File : File_Type);
 180    procedure Skip_Page;
 181
 182    function End_Of_Page (File : File_Type) return Boolean;
 183    function End_Of_Page return Boolean;
 184
 185    function End_Of_File (File : File_Type) return Boolean;
 186    function End_Of_File return Boolean;
 187
 188    procedure Set_Col (File : File_Type;  To : Positive_Count);
 189    procedure Set_Col (To : Positive_Count);
 190
 191    procedure Set_Line (File : File_Type; To : Positive_Count);
 192    procedure Set_Line (To : Positive_Count);
 193
 194    function Col (File : File_Type) return Positive_Count;
 195    function Col return Positive_Count;
 196
 197    function Line (File : File_Type) return Positive_Count;
 198    function Line return Positive_Count;
 199
 200    function Page (File : File_Type) return Positive_Count;
 201    function Page return Positive_Count;
 202
 203    ----------------------------
 204    -- Character Input-Output --
 205    ----------------------------
 206
 207    procedure Get (File : File_Type; Item : out Character);
 208    procedure Get (Item : out Character);
 209    procedure Put (File : File_Type; Item : Character);
 210    procedure Put (Item : Character);
 211
 212    procedure Look_Ahead
 213      (File        : File_Type;
 214       Item        : out Character;
 215       End_Of_Line : out Boolean);
 216
 217    procedure Look_Ahead
 218      (Item        : out Character;
 219       End_Of_Line : out Boolean);
 220
 221    procedure Get_Immediate
 222      (File : File_Type;
 223       Item : out Character);
 224
 225    procedure Get_Immediate
 226      (Item : out Character);
 227
 228    procedure Get_Immediate
 229      (File      : File_Type;
 230       Item      : out Character;
 231       Available : out Boolean);
 232
 233    procedure Get_Immediate
 234      (Item      : out Character;
 235       Available : out Boolean);
 236
 237    -------------------------
 238    -- String Input-Output --
 239    -------------------------
 240
 241    procedure Get (File : File_Type; Item : out String);
 242    procedure Get (Item : out String);
 243    procedure Put (File : File_Type; Item : String);
 244    procedure Put (Item : String);
 245
 246    procedure Get_Line
 247      (File : File_Type;
 248       Item : out String;
 249       Last : out Natural);
 250
 251    procedure Get_Line
 252      (Item : out String;
 253       Last : out Natural);
 254
 255    function Get_Line (File : File_Type) return String;
 256    pragma Ada_05 (Get_Line);
 257
 258    function Get_Line return String;
 259    pragma Ada_05 (Get_Line);
 260
 261    procedure Put_Line
 262      (File : File_Type;
 263       Item : String);
 264
 265    procedure Put_Line
 266      (Item : String);
 267
 268    ---------------------------------------
 269    -- Generic packages for Input-Output --
 270    ---------------------------------------
 271
 272    --  The generic packages:
 273
 274    --    Ada.Text_IO.Integer_IO
 275    --    Ada.Text_IO.Modular_IO
 276    --    Ada.Text_IO.Float_IO
 277    --    Ada.Text_IO.Fixed_IO
 278    --    Ada.Text_IO.Decimal_IO
 279    --    Ada.Text_IO.Enumeration_IO
 280
 281    --  are implemented as separate child packages in GNAT, so the
 282    --  spec and body of these packages are to be found in separate
 283    --  child units. This implementation detail is hidden from the
 284    --  Ada programmer by special circuitry in the compiler that
 285    --  treats these child packages as though they were nested in
 286    --  Text_IO. The advantage of this special processing is that
 287    --  the subsidiary routines needed if these generics are used
 288    --  are not loaded when they are not used.
 289
 290    ----------------
 291    -- Exceptions --
 292    ----------------
 293
 294    Status_Error : exception renames IO_Exceptions.Status_Error;
 295    Mode_Error   : exception renames IO_Exceptions.Mode_Error;
 296    Name_Error   : exception renames IO_Exceptions.Name_Error;
 297    Use_Error    : exception renames IO_Exceptions.Use_Error;
 298    Device_Error : exception renames IO_Exceptions.Device_Error;
 299    End_Error    : exception renames IO_Exceptions.End_Error;
 300    Data_Error   : exception renames IO_Exceptions.Data_Error;
 301    Layout_Error : exception renames IO_Exceptions.Layout_Error;
 302
 303 private
 304    -----------------------------------
 305    -- Handling of Format Characters --
 306    -----------------------------------
 307
 308    --  Line marks are represented by the single character ASCII.LF (16#0A#).
 309    --  In DOS and similar systems, underlying file translation takes care
 310    --  of translating this to and from the standard CR/LF sequences used in
 311    --  these operating systems to mark the end of a line. On output there is
 312    --  always a line mark at the end of the last line, but on input, this
 313    --  line mark can be omitted, and is implied by the end of file.
 314
 315    --  Page marks are represented by the single character ASCII.FF (16#0C#),
 316    --  The page mark at the end of the file may be omitted, and is normally
 317    --  omitted on output unless an explicit New_Page call is made before
 318    --  closing the file. No page mark is added when a file is appended to,
 319    --  so, in accordance with the permission in (RM A.10.2(4)), there may
 320    --  or may not be a page mark separating preexisting text in the file
 321    --  from the new text to be written.
 322
 323    --  A file mark is marked by the physical end of file. In DOS translation
 324    --  mode on input, an EOF character (SUB = 16#1A#) gets translated to the
 325    --  physical end of file, so in effect this character is recognized as
 326    --  marking the end of file in DOS and similar systems.
 327
 328    LM : constant := Character'Pos (ASCII.LF);
 329    --  Used as line mark
 330
 331    PM : constant := Character'Pos (ASCII.FF);
 332    --  Used as page mark, except at end of file where it is implied
 333
 334    --------------------------------
 335    -- Text_IO File Control Block --
 336    --------------------------------
 337
 338    Default_WCEM : System.WCh_Con.WC_Encoding_Method :=
 339                     System.WCh_Con.WCEM_UTF8;
 340    --  This gets modified during initialization (see body) using
 341    --  the default value established in the call to Set_Globals.
 342
 343    package FCB renames System.File_Control_Block;
 344
 345    type Text_AFCB;
 346    type File_Type is access all Text_AFCB;
 347
 348    type Text_AFCB is new FCB.AFCB with record
 349       Page        : Count := 1;
 350       Line        : Count := 1;
 351       Col         : Count := 1;
 352       Line_Length : Count := 0;
 353       Page_Length : Count := 0;
 354
 355       Self : aliased File_Type;
 356       --  Set to point to the containing Text_AFCB block. This is used to
 357       --  implement the Current_{Error,Input,Output} functions which return
 358       --  a File_Access, the file access value returned is a pointer to
 359       --  the Self field of the corresponding file.
 360
 361       Before_LM : Boolean := False;
 362       --  This flag is used to deal with the anomalies introduced by the
 363       --  peculiar definition of End_Of_File and End_Of_Page in Ada. These
 364       --  functions require looking ahead more than one character. Since
 365       --  there is no convenient way of backing up more than one character,
 366       --  what we do is to leave ourselves positioned past the LM, but set
 367       --  this flag, so that we know that from an Ada point of view we are
 368       --  in front of the LM, not after it. A bit of a kludge, but it works!
 369
 370       Before_LM_PM : Boolean := False;
 371       --  This flag similarly handles the case of being physically positioned
 372       --  after a LM-PM sequence when logically we are before the LM-PM. This
 373       --  flag can only be set if Before_LM is also set.
 374
 375       WC_Method : System.WCh_Con.WC_Encoding_Method := Default_WCEM;
 376       --  Encoding method to be used for this file. Text_IO does not deal with
 377       --  wide characters, but it does deal with upper half characters in the
 378       --  range 16#80#-16#FF# which may need encoding, e.g. in UTF-8 mode.
 379
 380       Before_Upper_Half_Character : Boolean := False;
 381       --  This flag is set to indicate that an encoded upper half character has
 382       --  been read by Text_IO.Look_Ahead. If it is set to True, then it means
 383       --  that the stream is logically positioned before the character but is
 384       --  physically positioned after it. The character involved must be in
 385       --  the range 16#80#-16#FF#, i.e. if the flag is set, then we know the
 386       --  next character has a code greater than 16#7F#, and the value of this
 387       --  character is saved in Saved_Upper_Half_Character.
 388
 389       Saved_Upper_Half_Character : Character;
 390       --  This field is valid only if Before_Upper_Half_Character is set. It
 391       --  contains an upper-half character read by Look_Ahead. If Look_Ahead
 392       --  reads a character in the range 16#00# to 16#7F#, then it can use
 393       --  ungetc to put it back, but ungetc cannot be called more than once,
 394       --  so for characters above this range, we don't try to back up the
 395       --  file. Instead we save the character in this field and set the flag
 396       --  Before_Upper_Half_Character to True to indicate that we are logically
 397       --  positioned before this character even though the stream is physically
 398       --  positioned after it.
 399
 400    end record;
 401
 402    function AFCB_Allocate (Control_Block : Text_AFCB) return FCB.AFCB_Ptr;
 403
 404    procedure AFCB_Close (File : not null access Text_AFCB);
 405    procedure AFCB_Free  (File : not null access Text_AFCB);
 406
 407    procedure Read
 408      (File : in out Text_AFCB;
 409       Item : out Ada.Streams.Stream_Element_Array;
 410       Last : out Ada.Streams.Stream_Element_Offset);
 411    --  Read operation used when Text_IO file is treated directly as Stream
 412
 413    procedure Write
 414      (File : in out Text_AFCB;
 415       Item : Ada.Streams.Stream_Element_Array);
 416    --  Write operation used when Text_IO file is treated directly as Stream
 417
 418    ------------------------
 419    -- The Standard Files --
 420    ------------------------
 421
 422    Null_Str : aliased constant String := "";
 423    --  Used as name and form of standard files
 424
 425    Standard_In_AFCB  : aliased Text_AFCB;
 426    Standard_Out_AFCB : aliased Text_AFCB;
 427    Standard_Err_AFCB : aliased Text_AFCB;
 428
 429    Standard_In  : aliased File_Type := Standard_In_AFCB'Access;
 430    Standard_Out : aliased File_Type := Standard_Out_AFCB'Access;
 431    Standard_Err : aliased File_Type := Standard_Err_AFCB'Access;
 432    --  Standard files
 433
 434    Current_In   : aliased File_Type := Standard_In;
 435    Current_Out  : aliased File_Type := Standard_Out;
 436    Current_Err  : aliased File_Type := Standard_Err;
 437    --  Current files
 438
 439    -----------------------
 440    -- Local Subprograms --
 441    -----------------------
 442
 443    --  These subprograms are in the private part of the spec so that they can
 444    --  be shared by the routines in the body of Ada.Text_IO.Wide_Text_IO.
 445
 446    --  Note: we use Integer in these declarations instead of the more accurate
 447    --  Interfaces.C_Streams.int, because we do not want to drag in the spec of
 448    --  this interfaces package with the spec of Ada.Text_IO, and we know that
 449    --  in fact these types are identical
 450
 451    function EOF_Char return Integer;
 452    --  Returns the system-specific character indicating the end of a text file.
 453    --  This is exported for use by child packages such as Enumeration_Aux to
 454    --  eliminate their needing to depend directly on Interfaces.C_Streams.
 455
 456    function Getc (File : File_Type) return Integer;
 457    --  Gets next character from file, which has already been checked for
 458    --  being in read status, and returns the character read if no error
 459    --  occurs. The result is EOF if the end of file was read.
 460
 461    function Nextc (File : File_Type) return Integer;
 462    --  Returns next character from file without skipping past it (i.e. it
 463    --  is a combination of Getc followed by an Ungetc).
 464
 465    procedure Putc (ch : Integer; File : File_Type);
 466    --  Outputs the given character to the file, which has already been
 467    --  checked for being in output status. Device_Error is raised if the
 468    --  character cannot be written.
 469
 470    procedure Terminate_Line (File : File_Type);
 471    --  If the file is in Write_File or Append_File mode, and the current
 472    --  line is not terminated, then a line terminator is written using
 473    --  New_Line. Note that there is no Terminate_Page routine, because
 474    --  the page mark at the end of the file is implied if necessary.
 475
 476    procedure Ungetc (ch : Integer; File : File_Type);
 477    --  Pushes back character into stream, using ungetc. The caller has
 478    --  checked that the file is in read status. Device_Error is raised
 479    --  if the character cannot be pushed back. An attempt to push back
 480    --  and end of file character (EOF) is ignored.
 481
 482 end Ada.Text_IO;