gcc/ada/a-swuwti.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                  ADA.STRINGS.WIDE_UNBOUNDED.WIDE_TEXT_IO                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1997-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Wide_Text_IO; use Ada.Wide_Text_IO;
  35
  36 package body Ada.Strings.Wide_Unbounded.Wide_Text_IO is
  37
  38    --------------
  39    -- Get_Line --
  40    --------------
  41
  42    function Get_Line return Unbounded_Wide_String is
  43       Buffer : Wide_String (1 .. 1000);
  44       Last   : Natural;
  45       Str1   : Wide_String_Access;
  46       Str2   : Wide_String_Access;
  47       Result : Unbounded_Wide_String;
  48
  49    begin
  50       Get_Line (Buffer, Last);
  51       Str1 := new Wide_String'(Buffer (1 .. Last));
  52       while Last = Buffer'Last loop
  53          Get_Line (Buffer, Last);
  54          Str2 := new Wide_String'(Str1.all & Buffer (1 .. Last));
  55          Free (Str1);
  56          Str1 := Str2;
  57       end loop;
  58
  59       Result.Reference := Str1;
  60       Result.Last      := Str1'Length;
  61       return Result;
  62    end Get_Line;
  63
  64    function Get_Line
  65      (File : Ada.Wide_Text_IO.File_Type) return Unbounded_Wide_String
  66    is
  67       Buffer : Wide_String (1 .. 1000);
  68       Last   : Natural;
  69       Str1   : Wide_String_Access;
  70       Str2   : Wide_String_Access;
  71       Result : Unbounded_Wide_String;
  72
  73    begin
  74       Get_Line (File, Buffer, Last);
  75       Str1 := new Wide_String'(Buffer (1 .. Last));
  76       while Last = Buffer'Last loop
  77          Get_Line (File, Buffer, Last);
  78          Str2 := new Wide_String'(Str1.all & Buffer (1 .. Last));
  79          Free (Str1);
  80          Str1 := Str2;
  81       end loop;
  82
  83       Result.Reference := Str1;
  84       Result.Last      := Str1'Length;
  85       return Result;
  86    end Get_Line;
  87
  88    procedure Get_Line (Item : out Unbounded_Wide_String) is
  89    begin
  90       Get_Line (Current_Input, Item);
  91    end Get_Line;
  92
  93    procedure Get_Line
  94      (File : Ada.Wide_Text_IO.File_Type;
  95       Item : out Unbounded_Wide_String)
  96    is
  97    begin
  98       --  We are going to read into the string that is already there and
  99       --  allocated. Hopefully it is big enough now, if not, we will extend
 100       --  it in the usual manner using Realloc_For_Chunk.
 101
 102       --  Make sure we start with at least 80 characters
 103
 104       if Item.Reference'Last < 80 then
 105          Realloc_For_Chunk (Item, 80);
 106       end if;
 107
 108       --  Loop to read data, filling current string as far as possible.
 109       --  Item.Last holds the number of characters read so far.
 110
 111       Item.Last := 0;
 112       loop
 113          Get_Line
 114            (File,
 115             Item.Reference (Item.Last + 1 .. Item.Reference'Last),
 116             Item.Last);
 117
 118          --  If we hit the end of the line before the end of the buffer, then
 119          --  we are all done, and the result length is properly set.
 120
 121          if Item.Last < Item.Reference'Last then
 122             return;
 123          end if;
 124
 125          --  If not enough room, double it and keep reading
 126
 127          Realloc_For_Chunk (Item, Item.Last);
 128       end loop;
 129    end Get_Line;
 130
 131    ---------
 132    -- Put --
 133    ---------
 134
 135    procedure Put (U : Unbounded_Wide_String) is
 136    begin
 137       Put (U.Reference (1 .. U.Last));
 138    end Put;
 139
 140    procedure Put (File : File_Type; U : Unbounded_Wide_String) is
 141    begin
 142       Put (File, U.Reference (1 .. U.Last));
 143    end Put;
 144
 145    --------------
 146    -- Put_Line --
 147    --------------
 148
 149    procedure Put_Line (U : Unbounded_Wide_String) is
 150    begin
 151       Put_Line (U.Reference (1 .. U.Last));
 152    end Put_Line;
 153
 154    procedure Put_Line (File : File_Type; U : Unbounded_Wide_String) is
 155    begin
 156       Put_Line (File, U.Reference (1 .. U.Last));
 157    end Put_Line;
 158
 159 end Ada.Strings.Wide_Unbounded.Wide_Text_IO;