gcc/ada/a-nudira.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --         A D A . N U M E R I C S . D I S C R E T E _ R A N D O M          --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2003 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  24 -- MA 02111-1307, USA.                                                      --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- GNAT was originally developed  by the GNAT team at  New York University. --
  34 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 --  Note: the implementation used in this package was contributed by
  39 --  Robert Eachus. It is based on the work of L. Blum, M. Blum, and
  40 --  M. Shub, SIAM Journal of Computing, Vol 15. No 2, May 1986. The
  41 --  particular choices for P and Q chosen here guarantee a period of
  42 --  562,085,314,430,582 (about 2**49), and the generated sequence has
  43 --  excellent randomness properties. For further details, see the
  44 --  paper "Fast Generation of Trustworthy Random Numbers", by Robert
  45 --  Eachus, which describes both the algorithm and the efficient
  46 --  implementation approach used here.
  47
  48 with Interfaces;
  49
  50 generic
  51    type Result_Subtype is (<>);
  52
  53 package Ada.Numerics.Discrete_Random is
  54
  55    --  The algorithm used here is reliable from a required statistical point
  56    --  of view only up to 48 bits. We try to behave reasonably in the case
  57    --  of larger types, but we can't guarantee the required properties.
  58    --  So generate a warning for these (slightly) dubious cases.
  59
  60    pragma Compile_Time_Warning
  61      (Result_Subtype'Size > 48,
  62       "statistical properties not guaranteed for size '> 48");
  63
  64    --  Basic facilities.
  65
  66    type Generator is limited private;
  67
  68    function Random (Gen : Generator) return Result_Subtype;
  69
  70    procedure Reset (Gen : Generator);
  71    procedure Reset (Gen : Generator; Initiator : Integer);
  72
  73    --  Advanced facilities.
  74
  75    type State is private;
  76
  77    procedure Save  (Gen : Generator; To_State   : out State);
  78    procedure Reset (Gen : Generator; From_State : State);
  79
  80    Max_Image_Width : constant := 80;
  81
  82    function Image (Of_State    : State)  return String;
  83    function Value (Coded_State : String) return State;
  84
  85 private
  86    subtype Int is Interfaces.Integer_32;
  87    subtype Rst is Result_Subtype;
  88
  89    --  We prefer to use 14 digits for Flt, but some targets are more limited
  90
  91    type Flt is digits Positive'Min (14, Long_Long_Float'Digits);
  92
  93    RstF : constant Flt := Flt (Rst'Pos (Rst'First));
  94    RstL : constant Flt := Flt (Rst'Pos (Rst'Last));
  95
  96    Offs : constant Flt := RstF - 0.5;
  97
  98    K1   : constant := 94_833_359;
  99    K1F  : constant := 94_833_359.0;
 100    K2   : constant := 47_416_679;
 101    K2F  : constant := 47_416_679.0;
 102    Scal : constant Flt := (RstL - RstF + 1.0) / (K1F * K2F);
 103
 104    type State is record
 105       X1  : Int := Int (2999 ** 2);
 106       X2  : Int := Int (1439 ** 2);
 107       P   : Int := K1;
 108       Q   : Int := K2;
 109       FP  : Flt := K1F;
 110       Scl : Flt := Scal;
 111    end record;
 112
 113    type Generator is limited record
 114       Gen_State : State;
 115    end record;
 116
 117 end Ada.Numerics.Discrete_Random;