gcc/ada/a-except-2005.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       A D A . E X C E P T I O N S                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 --  This version of Ada.Exceptions fully supports both Ada 95 and Ada 2005.
  37 --  It is used in all situations except for the build of the compiler and
  38 --  other basic tools. For these latter builds, we use an Ada 95-only version.
  39
  40 --  The reason for this splitting off of a separate version is that bootstrap
  41 --  compilers often will be used that do not support Ada 2005 features, and
  42 --  Ada.Exceptions is part of the compiler sources.
  43
  44 pragma Polling (Off);
  45 --  We must turn polling off for this unit, because otherwise we get
  46 --  elaboration circularities with ourself.
  47
  48 with System;
  49 with System.Parameters;
  50 with System.Standard_Library;
  51 with System.Traceback_Entries;
  52
  53 package Ada.Exceptions is
  54    pragma Warnings (Off);
  55    pragma Preelaborate_05;
  56    pragma Warnings (On);
  57    --  In accordance with Ada 2005 AI-362. The warnings pragmas are so that we
  58    --  can compile this using older compiler versions, which will ignore the
  59    --  pragma, which is fine for the bootstrap.
  60
  61    type Exception_Id is private;
  62    pragma Preelaborable_Initialization (Exception_Id);
  63
  64    Null_Id : constant Exception_Id;
  65
  66    type Exception_Occurrence is limited private;
  67    pragma Preelaborable_Initialization (Exception_Occurrence);
  68
  69    type Exception_Occurrence_Access is access all Exception_Occurrence;
  70
  71    Null_Occurrence : constant Exception_Occurrence;
  72
  73    function Exception_Name (Id : Exception_Id) return String;
  74
  75    function Exception_Name (X : Exception_Occurrence) return String;
  76
  77    function Wide_Exception_Name
  78      (Id : Exception_Id) return Wide_String;
  79    pragma Ada_05 (Wide_Exception_Name);
  80
  81    function Wide_Exception_Name
  82      (X : Exception_Occurrence) return Wide_String;
  83    pragma Ada_05 (Wide_Exception_Name);
  84
  85    function Wide_Wide_Exception_Name
  86      (Id : Exception_Id) return Wide_Wide_String;
  87    pragma Ada_05 (Wide_Wide_Exception_Name);
  88
  89    function Wide_Wide_Exception_Name
  90      (X : Exception_Occurrence) return Wide_Wide_String;
  91    pragma Ada_05 (Wide_Wide_Exception_Name);
  92
  93    procedure Raise_Exception (E : Exception_Id; Message : String := "");
  94    pragma No_Return (Raise_Exception);
  95    --  Note: In accordance with AI-466, CE is raised if E = Null_Id
  96
  97    function Exception_Message (X : Exception_Occurrence) return String;
  98
  99    procedure Reraise_Occurrence (X : Exception_Occurrence);
 100    --  Note: it would be really nice to give a pragma No_Return for this
 101    --  procedure, but it would be wrong, since Reraise_Occurrence does return
 102    --  if the argument is the null exception occurrence. See also procedure
 103    --  Reraise_Occurrence_Always in the private part of this package.
 104
 105    function Exception_Identity (X : Exception_Occurrence) return Exception_Id;
 106
 107    function Exception_Information (X : Exception_Occurrence) return String;
 108    --  The format of the exception information is as follows:
 109    --
 110    --    exception name (as in Exception_Name)
 111    --    message (or a null line if no message)
 112    --    PID=nnnn
 113    --    0xyyyyyyyy 0xyyyyyyyy ...
 114    --
 115    --  The lines are separated by a ASCII.LF character
 116    --
 117    --  The nnnn is the partition Id given as decimal digits
 118    --
 119    --  The 0x... line represents traceback program counter locations,
 120    --  in order with the first one being the exception location.
 121
 122    --  Note on ordering: the compiler uses the Save_Occurrence procedure, but
 123    --  not the function from Rtsfind, so it is important that the procedure
 124    --  come first, since Rtsfind finds the first matching entity.
 125
 126    procedure Save_Occurrence
 127      (Target : out Exception_Occurrence;
 128       Source : Exception_Occurrence);
 129
 130    function Save_Occurrence
 131      (Source : Exception_Occurrence)
 132       return   Exception_Occurrence_Access;
 133
 134    --  Ada 2005 (AI-438): The language revision introduces the following
 135    --  subprograms and attribute definitions. We do not provide them
 136    --  explicitly. instead, the corresponding stream attributes are made
 137    --  available through a pragma Stream_Convert in the private part.
 138
 139    --  procedure Read_Exception_Occurrence
 140    --    (Stream : not null access Ada.Streams.Root_Stream_Type'Class;
 141    --     Item   : out Exception_Occurrence);
 142
 143    --  procedure Write_Exception_Occurrence
 144    --    (Stream : not null access Ada.Streams.Root_Stream_Type'Class;
 145    --     Item   : Exception_Occurrence);
 146
 147    --  for Exception_Occurrence'Read use Read_Exception_Occurrence;
 148    --  for Exception_Occurrence'Write use Write_Exception_Occurrence;
 149
 150 private
 151    package SSL renames System.Standard_Library;
 152    package SP renames System.Parameters;
 153
 154    subtype EOA is Exception_Occurrence_Access;
 155
 156    Exception_Msg_Max_Length : constant := SP.Default_Exception_Msg_Max_Length;
 157
 158    ------------------
 159    -- Exception_Id --
 160    ------------------
 161
 162    subtype Code_Loc is System.Address;
 163    --  Code location used in building exception tables and for call addresses
 164    --  when propagating an exception. Values of this type are created by using
 165    --  Label'Address or extracted from machine states using Get_Code_Loc.
 166
 167    Null_Loc : constant Code_Loc := System.Null_Address;
 168    --  Null code location, used to flag outer level frame
 169
 170    type Exception_Id is new SSL.Exception_Data_Ptr;
 171
 172    function EId_To_String (X : Exception_Id) return String;
 173    function String_To_EId (S : String) return Exception_Id;
 174    pragma Stream_Convert (Exception_Id, String_To_EId, EId_To_String);
 175    --  Functions for implementing Exception_Id stream attributes
 176
 177    Null_Id : constant Exception_Id := null;
 178
 179    -------------------------
 180    -- Private Subprograms --
 181    -------------------------
 182
 183    function Current_Target_Exception return Exception_Occurrence;
 184    pragma Export
 185      (Ada, Current_Target_Exception,
 186       "__gnat_current_target_exception");
 187    --  This routine should return the current raised exception on targets which
 188    --  have built-in exception handling such as the Java Virtual Machine. For
 189    --  other targets this routine is simply ignored. Currently, only JGNAT
 190    --  uses this. See 4jexcept.ads for details. The pragma Export allows this
 191    --  routine to be accessed elsewhere in the run-time, even though it is in
 192    --  the private part of this package (it is not allowed to be in the visible
 193    --  part, since this is set by the reference manual).
 194
 195    function Exception_Name_Simple (X : Exception_Occurrence) return String;
 196    --  Like Exception_Name, but returns the simple non-qualified name of the
 197    --  exception. This is used to implement the Exception_Name function in
 198    --  Current_Exceptions (the DEC compatible unit). It is called from the
 199    --  compiler generated code (using Rtsfind, which does not respect the
 200    --  private barrier, so we can place this function in the private part
 201    --  where the compiler can find it, but the spec is unchanged.)
 202
 203    procedure Raise_Exception_Always (E : Exception_Id; Message : String := "");
 204    pragma No_Return (Raise_Exception_Always);
 205    pragma Export (Ada, Raise_Exception_Always, "__gnat_raise_exception");
 206    --  This differs from Raise_Exception only in that the caller has determined
 207    --  that for sure the parameter E is not null, and that therefore no check
 208    --  for Null_Id is required. The expander converts Raise_Exception calls to
 209    --  Raise_Exception_Always if it can determine this is the case. The Export
 210    --  allows this routine to be accessed from Pure units.
 211
 212    procedure Raise_From_Signal_Handler
 213      (E : Exception_Id;
 214       M : System.Address);
 215    pragma Export
 216      (Ada, Raise_From_Signal_Handler,
 217            "ada__exceptions__raise_from_signal_handler");
 218    pragma No_Return (Raise_From_Signal_Handler);
 219    --  This routine is used to raise an exception from a signal handler. The
 220    --  signal handler has already stored the machine state (i.e. the state that
 221    --  corresponds to the location at which the signal was raised). E is the
 222    --  Exception_Id specifying what exception is being raised, and M is a
 223    --  pointer to a null-terminated string which is the message to be raised.
 224    --  Note that this routine never returns, so it is permissible to simply
 225    --  jump to this routine, rather than call it. This may be appropriate for
 226    --  systems where the right way to get out of signal handler is to alter the
 227    --  PC value in the machine state or in some other way ask the operating
 228    --  system to return here rather than to the original location.
 229
 230    procedure Raise_From_Controlled_Operation
 231      (X : Ada.Exceptions.Exception_Occurrence);
 232    pragma No_Return (Raise_From_Controlled_Operation);
 233    pragma Export
 234      (Ada, Raise_From_Controlled_Operation,
 235            "__gnat_raise_from_controlled_operation");
 236    --  Raise Program_Error, providing information about X (an exception raised
 237    --  during a controlled operation) in the exception message.
 238
 239    procedure Reraise_Occurrence_Always (X : Exception_Occurrence);
 240    pragma No_Return (Reraise_Occurrence_Always);
 241    --  This differs from Raise_Occurrence only in that the caller guarantees
 242    --  that for sure the parameter X is not the null occurrence, and that
 243    --  therefore this procedure cannot return. The expander uses this routine
 244    --  in the translation of a raise statement with no parameter (reraise).
 245
 246    procedure Reraise_Occurrence_No_Defer (X : Exception_Occurrence);
 247    pragma No_Return (Reraise_Occurrence_No_Defer);
 248    --  Exactly like Reraise_Occurrence, except that abort is not deferred
 249    --  before the call and the parameter X is known not to be the null
 250    --  occurrence. This is used in generated code when it is known that abort
 251    --  is already deferred.
 252
 253    -----------------------
 254    -- Polling Interface --
 255    -----------------------
 256
 257    --  The GNAT compiler has an option to generate polling calls to the Poll
 258    --  routine in this package. Specifying the -gnatP option for a compilation
 259    --  causes a call to Ada.Exceptions.Poll to be generated on every subprogram
 260    --  entry and on every iteration of a loop, thus avoiding the possibility of
 261    --  a case of unbounded time between calls.
 262
 263    --  This polling interface may be used for instrumentation or debugging
 264    --  purposes (e.g. implementing watchpoints in software or in the debugger).
 265
 266    --  In the GNAT technology itself, this interface is used to implement
 267    --  immediate asynchronous transfer of control and immediate abort on
 268    --  targets which do not provide for one thread interrupting another.
 269
 270    --  Note: this used to be in a separate unit called System.Poll, but that
 271    --  caused horrible circular elaboration problems between System.Poll and
 272    --  Ada.Exceptions. One way of solving such circularities is unification!
 273
 274    procedure Poll;
 275    --  Check for asynchronous abort. Note that we do not inline the body.
 276    --  This makes the interface more useful for debugging purposes.
 277
 278    --------------------------
 279    -- Exception_Occurrence --
 280    --------------------------
 281
 282    package TBE renames System.Traceback_Entries;
 283
 284    Max_Tracebacks : constant := 50;
 285    --  Maximum number of trace backs stored in exception occurrence
 286
 287    type Tracebacks_Array is array (1 .. Max_Tracebacks) of TBE.Traceback_Entry;
 288    --  Traceback array stored in exception occurrence
 289
 290    type Exception_Occurrence is record
 291       Id : Exception_Id;
 292       --  Exception_Identity for this exception occurrence
 293       --
 294       --  WARNING System.System.Finalization_Implementation.Finalize_List
 295       --  relies on the fact that this field is always first in the exception
 296       --  occurrence
 297
 298       Msg_Length : Natural := 0;
 299       --  Length of message (zero = no message)
 300
 301       Msg : String (1 .. Exception_Msg_Max_Length);
 302       --  Characters of message
 303
 304       Exception_Raised : Boolean := False;
 305       --  Set to true to indicate that this exception occurrence has actually
 306       --  been raised. When an exception occurrence is first created, this is
 307       --  set to False, then when it is processed by Raise_Current_Exception,
 308       --  it is set to True. If Raise_Current_Exception is used to raise an
 309       --  exception for which this flag is already True, then it knows that
 310       --  it is dealing with the reraise case (which is useful to distinguish
 311       --  for exception tracing purposes).
 312
 313       Pid : Natural := 0;
 314       --  Partition_Id for partition raising exception
 315
 316       Num_Tracebacks : Natural range 0 .. Max_Tracebacks := 0;
 317       --  Number of traceback entries stored
 318
 319       Tracebacks : Tracebacks_Array;
 320       --  Stored tracebacks (in Tracebacks (1 .. Num_Tracebacks))
 321    end record;
 322
 323    function "=" (Left, Right : Exception_Occurrence) return Boolean
 324      is abstract;
 325    --  Don't allow comparison on exception occurrences, we should not need
 326    --  this, and it would not work right, because of the Msg and Tracebacks
 327    --  fields which have unused entries not copied by Save_Occurrence.
 328
 329    function EO_To_String (X : Exception_Occurrence) return String;
 330    function String_To_EO (S : String) return Exception_Occurrence;
 331    pragma Stream_Convert (Exception_Occurrence, String_To_EO, EO_To_String);
 332    --  Functions for implementing Exception_Occurrence stream attributes
 333
 334    Null_Occurrence : constant Exception_Occurrence := (
 335      Id               => null,
 336      Msg_Length       => 0,
 337      Msg              => (others => ' '),
 338      Exception_Raised => False,
 339      Pid              => 0,
 340      Num_Tracebacks   => 0,
 341      Tracebacks       => (others => TBE.Null_TB_Entry));
 342
 343 end Ada.Exceptions;