gcc/ada/a-dirval-mingw.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --             A D A . D I R E C T O R I E S . V A L I D I T Y              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                            (Windows Version)                             --
   9 --                                                                          --
  10 --          Copyright (C) 2004 Free Software Foundation, Inc.               --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is the Windows version of this package
  36
  37 with Ada.Characters.Latin_1; use Ada.Characters.Latin_1;
  38
  39 package body Ada.Directories.Validity is
  40
  41    Invalid_Character : constant array (Character) of Boolean :=
  42                          (NUL .. US             => True,
  43                           '/' | ':' | '*' | '?' => True,
  44                           '"' | '<' | '>' | '|' => True,
  45                           DEL .. NBSP           => True,
  46                           others                => False);
  47
  48    ------------------------
  49    -- Is_Valid_Path_Name --
  50    ------------------------
  51
  52    function Is_Valid_Path_Name (Name : String) return Boolean is
  53       Start : Positive := Name'First;
  54       Last  : Natural;
  55
  56    begin
  57       --  A path name cannot be empty, cannot contain more than 256 characters,
  58       --  cannot contain invalid characters and each directory/file name need
  59       --  to be valid.
  60
  61       if Name'Length = 0 or else Name'Length > 256 then
  62          return False;
  63
  64       else
  65          --  A drive letter may be specified at the beginning
  66
  67          if Name'Length >= 2
  68            and then  Name (Start + 1) = ':'
  69            and then
  70             (Name (Start) in 'A' .. 'Z' or else
  71              Name (Start) in 'a' .. 'z')
  72          then
  73             Start := Start + 2;
  74          end if;
  75
  76          loop
  77             --  Look for the start of the next directory or file name
  78
  79             while Start <= Name'Last and then Name (Start) = '\' loop
  80                Start := Start + 1;
  81             end loop;
  82
  83             --  If all directories/file names are OK, return True
  84
  85             exit when Start > Name'Last;
  86
  87             Last := Start;
  88
  89             --  Look for the end of the directory/file name
  90
  91             while Last < Name'Last loop
  92                exit when Name (Last + 1) = '\';
  93                Last := Last + 1;
  94             end loop;
  95
  96             --  Check if the directory/file name is valid
  97
  98             if not Is_Valid_Simple_Name (Name (Start .. Last)) then
  99                   return False;
 100             end if;
 101
 102             --  Move to the next name
 103
 104             Start := Last + 1;
 105          end loop;
 106       end if;
 107
 108       --  If Name follows the rules, it is valid
 109
 110       return True;
 111    end Is_Valid_Path_Name;
 112
 113    --------------------------
 114    -- Is_Valid_Simple_Name --
 115    --------------------------
 116
 117    function Is_Valid_Simple_Name (Name : String) return Boolean is
 118       Only_Spaces : Boolean;
 119
 120    begin
 121       --  A file name cannot be empty, cannot contain more than 256 characters,
 122       --  and cannot contain invalid characters, including '\'
 123
 124       if Name'Length = 0 or else Name'Length > 256 then
 125          return False;
 126
 127       --  Name length is OK
 128
 129       else
 130          Only_Spaces := True;
 131          for J in Name'Range loop
 132             if Invalid_Character (Name (J)) or else Name (J) = '\' then
 133                return False;
 134             elsif Name (J) /= ' ' then
 135                Only_Spaces := False;
 136             end if;
 137          end loop;
 138
 139          --  If no invalid chars, and not all spaces, file name is valid.
 140
 141          return not Only_Spaces;
 142       end if;
 143    end Is_Valid_Simple_Name;
 144
 145 end Ada.Directories.Validity;
 146