gcc/ada/a-coorse.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --           A D A . C O N T A I N E R S . O R D E R E D _ S E T S          --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- This unit was originally developed by Matthew J Heaney.                  --
  34 ------------------------------------------------------------------------------
  35
  36 with Ada.Containers.Red_Black_Trees;
  37 with Ada.Finalization;
  38 with Ada.Streams;
  39
  40 generic
  41    type Element_Type is private;
  42
  43    with function "<" (Left, Right : Element_Type) return Boolean is <>;
  44    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  45
  46 package Ada.Containers.Ordered_Sets is
  47    pragma Preelaborate;
  48
  49    function Equivalent_Elements (Left, Right : Element_Type) return Boolean;
  50
  51    type Set is tagged private;
  52    pragma Preelaborable_Initialization (Set);
  53
  54    type Cursor is private;
  55    pragma Preelaborable_Initialization (Cursor);
  56
  57    Empty_Set : constant Set;
  58
  59    No_Element : constant Cursor;
  60
  61    function "=" (Left, Right : Set) return Boolean;
  62
  63    function Equivalent_Sets (Left, Right : Set) return Boolean;
  64
  65    function To_Set (New_Item : Element_Type) return Set;
  66
  67    function Length (Container : Set) return Count_Type;
  68
  69    function Is_Empty (Container : Set) return Boolean;
  70
  71    procedure Clear (Container : in out Set);
  72
  73    function Element (Position : Cursor) return Element_Type;
  74
  75    procedure Replace_Element
  76      (Container : in out Set;
  77       Position  : Cursor;
  78       New_Item  : Element_Type);
  79
  80    procedure Query_Element
  81      (Position : Cursor;
  82       Process  : not null access procedure (Element : Element_Type));
  83
  84    procedure Move (Target : in out Set; Source : in out Set);
  85
  86    procedure Insert
  87      (Container : in out Set;
  88       New_Item  : Element_Type;
  89       Position  : out Cursor;
  90       Inserted  : out Boolean);
  91
  92    procedure Insert
  93      (Container : in out Set;
  94       New_Item  : Element_Type);
  95
  96    procedure Include
  97      (Container : in out Set;
  98       New_Item  : Element_Type);
  99
 100    procedure Replace
 101      (Container : in out Set;
 102       New_Item  : Element_Type);
 103
 104    procedure Exclude
 105      (Container : in out Set;
 106       Item      : Element_Type);
 107
 108    procedure Delete
 109      (Container : in out Set;
 110       Item      : Element_Type);
 111
 112    procedure Delete
 113      (Container : in out Set;
 114       Position  : in out Cursor);
 115
 116    procedure Delete_First (Container : in out Set);
 117
 118    procedure Delete_Last (Container : in out Set);
 119
 120    procedure Union (Target : in out Set; Source : Set);
 121
 122    function Union (Left, Right : Set) return Set;
 123
 124    function "or" (Left, Right : Set) return Set renames Union;
 125
 126    procedure Intersection (Target : in out Set; Source : Set);
 127
 128    function Intersection (Left, Right : Set) return Set;
 129
 130    function "and" (Left, Right : Set) return Set renames Intersection;
 131
 132    procedure Difference (Target : in out Set; Source : Set);
 133
 134    function Difference (Left, Right : Set) return Set;
 135
 136    function "-" (Left, Right : Set) return Set renames Difference;
 137
 138    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 139
 140    function Symmetric_Difference (Left, Right : Set) return Set;
 141
 142    function "xor" (Left, Right : Set) return Set renames Symmetric_Difference;
 143
 144    function Overlap (Left, Right : Set) return Boolean;
 145
 146    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 147
 148    function First (Container : Set) return Cursor;
 149
 150    function First_Element (Container : Set) return Element_Type;
 151
 152    function Last (Container : Set) return Cursor;
 153
 154    function Last_Element (Container : Set) return Element_Type;
 155
 156    function Next (Position : Cursor) return Cursor;
 157
 158    procedure Next (Position : in out Cursor);
 159
 160    function Previous (Position : Cursor) return Cursor;
 161
 162    procedure Previous (Position : in out Cursor);
 163
 164    function Find (Container : Set; Item : Element_Type) return Cursor;
 165
 166    function Floor (Container : Set; Item : Element_Type) return Cursor;
 167
 168    function Ceiling (Container : Set; Item : Element_Type) return Cursor;
 169
 170    function Contains (Container : Set; Item : Element_Type) return Boolean;
 171
 172    function Has_Element (Position : Cursor) return Boolean;
 173
 174    function "<" (Left, Right : Cursor) return Boolean;
 175
 176    function ">" (Left, Right : Cursor) return Boolean;
 177
 178    function "<" (Left : Cursor; Right : Element_Type) return Boolean;
 179
 180    function ">" (Left : Cursor; Right : Element_Type) return Boolean;
 181
 182    function "<" (Left : Element_Type; Right : Cursor) return Boolean;
 183
 184    function ">" (Left : Element_Type; Right : Cursor) return Boolean;
 185
 186    procedure Iterate
 187      (Container : Set;
 188       Process   : not null access procedure (Position : Cursor));
 189
 190    procedure Reverse_Iterate
 191      (Container : Set;
 192       Process   : not null access procedure (Position : Cursor));
 193
 194    generic
 195       type Key_Type (<>) is private;
 196
 197       with function Key (Element : Element_Type) return Key_Type;
 198
 199       with function "<" (Left, Right : Key_Type) return Boolean is <>;
 200
 201    package Generic_Keys is
 202
 203       function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 204
 205       function Key (Position : Cursor) return Key_Type;
 206
 207       function Element (Container : Set; Key : Key_Type) return Element_Type;
 208
 209       procedure Replace
 210         (Container : in out Set;
 211          Key       : Key_Type;
 212          New_Item  : Element_Type);
 213
 214       procedure Exclude (Container : in out Set; Key : Key_Type);
 215
 216       procedure Delete (Container : in out Set; Key : Key_Type);
 217
 218       function Find (Container : Set; Key : Key_Type) return Cursor;
 219
 220       function Floor (Container : Set; Key : Key_Type) return Cursor;
 221
 222       function Ceiling (Container : Set; Key : Key_Type) return Cursor;
 223
 224       function Contains (Container : Set; Key : Key_Type) return Boolean;
 225
 226       procedure Update_Element_Preserving_Key
 227         (Container : in out Set;
 228          Position  : Cursor;
 229          Process   : not null access
 230                        procedure (Element : in out Element_Type));
 231
 232    end Generic_Keys;
 233
 234 private
 235
 236    type Node_Type;
 237    type Node_Access is access Node_Type;
 238
 239    type Node_Type is limited record
 240       Parent  : Node_Access;
 241       Left    : Node_Access;
 242       Right   : Node_Access;
 243       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 244       Element : Element_Type;
 245    end record;
 246
 247    package Tree_Types is new Red_Black_Trees.Generic_Tree_Types
 248      (Node_Type,
 249       Node_Access);
 250
 251    type Set is new Ada.Finalization.Controlled with record
 252       Tree : Tree_Types.Tree_Type;
 253    end record;
 254
 255    procedure Adjust (Container : in out Set);
 256
 257    procedure Finalize (Container : in out Set) renames Clear;
 258
 259    use Red_Black_Trees;
 260    use Tree_Types;
 261    use Ada.Finalization;
 262    use Ada.Streams;
 263
 264    type Set_Access is access all Set;
 265    for Set_Access'Storage_Size use 0;
 266
 267    type Cursor is record
 268       Container : Set_Access;
 269       Node      : Node_Access;
 270    end record;
 271
 272    procedure Write
 273      (Stream : not null access Root_Stream_Type'Class;
 274       Item   : Cursor);
 275
 276    for Cursor'Write use Write;
 277
 278    procedure Read
 279      (Stream : not null access Root_Stream_Type'Class;
 280       Item   : out Cursor);
 281
 282    for Cursor'Read use Read;
 283
 284    No_Element : constant Cursor := Cursor'(null, null);
 285
 286    procedure Write
 287      (Stream    : not null access Root_Stream_Type'Class;
 288       Container : Set);
 289
 290    for Set'Write use Write;
 291
 292    procedure Read
 293      (Stream    : not null access Root_Stream_Type'Class;
 294       Container : out Set);
 295
 296    for Set'Read use Read;
 297
 298    Empty_Set : constant Set :=
 299                  (Controlled with Tree => (First  => null,
 300                                            Last   => null,
 301                                            Root   => null,
 302                                            Length => 0,
 303                                            Busy   => 0,
 304                                            Lock   => 0));
 305
 306 end Ada.Containers.Ordered_Sets;