gcc/ada/a-coormu.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --     A D A . C O N T A I N E R S . O R D E R E D _ M U L T I S E T S      --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- This unit was originally developed by Matthew J Heaney.                  --
  34 ------------------------------------------------------------------------------
  35
  36 with Ada.Containers.Red_Black_Trees;
  37 with Ada.Finalization;
  38 with Ada.Streams;
  39
  40 generic
  41    type Element_Type is private;
  42
  43    with function "<" (Left, Right : Element_Type) return Boolean is <>;
  44    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  45
  46 package Ada.Containers.Ordered_Multisets is
  47    pragma Preelaborate;
  48    pragma Remote_Types;
  49
  50    function Equivalent_Elements (Left, Right : Element_Type) return Boolean;
  51
  52    type Set is tagged private;
  53    pragma Preelaborable_Initialization (Set);
  54
  55    type Cursor is private;
  56    pragma Preelaborable_Initialization (Cursor);
  57
  58    Empty_Set : constant Set;
  59
  60    No_Element : constant Cursor;
  61
  62    function "=" (Left, Right : Set) return Boolean;
  63
  64    function Equivalent_Sets (Left, Right : Set) return Boolean;
  65
  66    function To_Set (New_Item : Element_Type) return Set;
  67
  68    function Length (Container : Set) return Count_Type;
  69
  70    function Is_Empty (Container : Set) return Boolean;
  71
  72    procedure Clear (Container : in out Set);
  73
  74    function Element (Position : Cursor) return Element_Type;
  75
  76    procedure Replace_Element
  77      (Container : in out Set;
  78       Position  : Cursor;
  79       New_Item  : Element_Type);
  80
  81    procedure Query_Element
  82      (Position : Cursor;
  83       Process  : not null access procedure (Element : Element_Type));
  84
  85    procedure Move (Target : in out Set; Source : in out Set);
  86
  87    procedure Insert
  88      (Container : in out Set;
  89       New_Item  : Element_Type;
  90       Position  : out Cursor);
  91
  92    procedure Insert
  93      (Container : in out Set;
  94       New_Item  : Element_Type);
  95
  96 --  TODO: include Replace too???
  97 --
  98 --     procedure Replace
  99 --       (Container : in out Set;
 100 --        New_Item  : Element_Type);
 101
 102    procedure Exclude
 103      (Container : in out Set;
 104       Item      : Element_Type);
 105
 106    procedure Delete
 107      (Container : in out Set;
 108       Item      : Element_Type);
 109
 110    procedure Delete
 111      (Container : in out Set;
 112       Position  : in out Cursor);
 113
 114    procedure Delete_First (Container : in out Set);
 115
 116    procedure Delete_Last (Container : in out Set);
 117
 118    procedure Union (Target : in out Set; Source : Set);
 119
 120    function Union (Left, Right : Set) return Set;
 121
 122    function "or" (Left, Right : Set) return Set renames Union;
 123
 124    procedure Intersection (Target : in out Set; Source : Set);
 125
 126    function Intersection (Left, Right : Set) return Set;
 127
 128    function "and" (Left, Right : Set) return Set renames Intersection;
 129
 130    procedure Difference (Target : in out Set; Source : Set);
 131
 132    function Difference (Left, Right : Set) return Set;
 133
 134    function "-" (Left, Right : Set) return Set renames Difference;
 135
 136    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 137
 138    function Symmetric_Difference (Left, Right : Set) return Set;
 139
 140    function "xor" (Left, Right : Set) return Set renames Symmetric_Difference;
 141
 142    function Overlap (Left, Right : Set) return Boolean;
 143
 144    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 145
 146    function First (Container : Set) return Cursor;
 147
 148    function First_Element (Container : Set) return Element_Type;
 149
 150    function Last (Container : Set) return Cursor;
 151
 152    function Last_Element (Container : Set) return Element_Type;
 153
 154    function Next (Position : Cursor) return Cursor;
 155
 156    procedure Next (Position : in out Cursor);
 157
 158    function Previous (Position : Cursor) return Cursor;
 159
 160    procedure Previous (Position : in out Cursor);
 161
 162    function Find (Container : Set; Item : Element_Type) return Cursor;
 163
 164    function Floor (Container : Set; Item : Element_Type) return Cursor;
 165
 166    function Ceiling (Container : Set; Item : Element_Type) return Cursor;
 167
 168    function Contains (Container : Set; Item : Element_Type) return Boolean;
 169
 170    function Has_Element (Position : Cursor) return Boolean;
 171
 172    function "<" (Left, Right : Cursor) return Boolean;
 173
 174    function ">" (Left, Right : Cursor) return Boolean;
 175
 176    function "<" (Left : Cursor; Right : Element_Type) return Boolean;
 177
 178    function ">" (Left : Cursor; Right : Element_Type) return Boolean;
 179
 180    function "<" (Left : Element_Type; Right : Cursor) return Boolean;
 181
 182    function ">" (Left : Element_Type; Right : Cursor) return Boolean;
 183
 184    procedure Iterate
 185      (Container : Set;
 186       Process   : not null access procedure (Position : Cursor));
 187
 188    procedure Reverse_Iterate
 189      (Container : Set;
 190       Process   : not null access procedure (Position : Cursor));
 191
 192    procedure Iterate
 193      (Container : Set;
 194       Item      : Element_Type;
 195       Process   : not null access procedure (Position : Cursor));
 196
 197    procedure Reverse_Iterate
 198      (Container : Set;
 199       Item      : Element_Type;
 200       Process   : not null access procedure (Position : Cursor));
 201
 202    generic
 203       type Key_Type (<>) is private;
 204
 205       with function Key (Element : Element_Type) return Key_Type;
 206
 207       with function "<" (Left, Right : Key_Type) return Boolean is <>;
 208
 209    package Generic_Keys is
 210
 211       function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 212
 213       function Key (Position : Cursor) return Key_Type;
 214
 215       function Element (Container : Set; Key : Key_Type) return Element_Type;
 216
 217       procedure Exclude (Container : in out Set; Key : Key_Type);
 218
 219       procedure Delete (Container : in out Set; Key : Key_Type);
 220
 221       function Find (Container : Set; Key : Key_Type) return Cursor;
 222
 223       function Floor (Container : Set; Key : Key_Type) return Cursor;
 224
 225       function Ceiling (Container : Set; Key : Key_Type) return Cursor;
 226
 227       function Contains (Container : Set; Key : Key_Type) return Boolean;
 228
 229       procedure Update_Element
 230         (Container : in out Set;
 231          Position  : Cursor;
 232          Process   : not null access
 233                        procedure (Element : in out Element_Type));
 234
 235       procedure Iterate
 236         (Container : Set;
 237          Key       : Key_Type;
 238          Process   : not null access procedure (Position : Cursor));
 239
 240       procedure Reverse_Iterate
 241         (Container : Set;
 242          Key       : Key_Type;
 243          Process   : not null access procedure (Position : Cursor));
 244
 245    end Generic_Keys;
 246
 247 private
 248
 249    pragma Inline (Next);
 250    pragma Inline (Previous);
 251
 252    type Node_Type;
 253    type Node_Access is access Node_Type;
 254
 255    type Node_Type is limited record
 256       Parent  : Node_Access;
 257       Left    : Node_Access;
 258       Right   : Node_Access;
 259       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 260       Element : Element_Type;
 261    end record;
 262
 263    package Tree_Types is new Red_Black_Trees.Generic_Tree_Types
 264      (Node_Type,
 265       Node_Access);
 266
 267    type Set is new Ada.Finalization.Controlled with record
 268       Tree : Tree_Types.Tree_Type;
 269    end record;
 270
 271    procedure Adjust (Container : in out Set);
 272
 273    procedure Finalize (Container : in out Set) renames Clear;
 274
 275    use Red_Black_Trees;
 276    use Tree_Types;
 277    use Ada.Finalization;
 278    use Ada.Streams;
 279
 280    type Set_Access is access all Set;
 281    for Set_Access'Storage_Size use 0;
 282
 283    type Cursor is record
 284       Container : Set_Access;
 285       Node      : Node_Access;
 286    end record;
 287
 288    procedure Write
 289      (Stream : not null access Root_Stream_Type'Class;
 290       Item   : Cursor);
 291
 292    for Cursor'Write use Write;
 293
 294    procedure Read
 295      (Stream : not null access Root_Stream_Type'Class;
 296       Item   : out Cursor);
 297
 298    for Cursor'Read use Read;
 299
 300    No_Element : constant Cursor := Cursor'(null, null);
 301
 302    procedure Write
 303      (Stream    : not null access Root_Stream_Type'Class;
 304       Container : Set);
 305
 306    for Set'Write use Write;
 307
 308    procedure Read
 309      (Stream    : not null access Root_Stream_Type'Class;
 310       Container : out Set);
 311
 312    for Set'Read use Read;
 313
 314    Empty_Set : constant Set :=
 315                  (Controlled with Tree => (First  => null,
 316                                            Last   => null,
 317                                            Root   => null,
 318                                            Length => 0,
 319                                            Busy   => 0,
 320                                            Lock   => 0));
 321
 322 end Ada.Containers.Ordered_Multisets;