gcc/ada/a-ciorma.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      A D A . C O N T A I N E R S .                       --
   6 --             I N D E F I N I T E _ O R D E R E D _ M A P S                --
   7 --                                                                          --
   8 --                                 S p e c                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2005 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  25 -- Boston, MA 02110-1301, USA.                                              --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- This unit was originally developed by Matthew J Heaney.                  --
  35 ------------------------------------------------------------------------------
  36
  37 with Ada.Containers.Red_Black_Trees;
  38 with Ada.Finalization;
  39 with Ada.Streams;
  40
  41 generic
  42    type Key_Type (<>) is private;
  43
  44    type Element_Type (<>) is private;
  45
  46    with function "<" (Left, Right : Key_Type) return Boolean is <>;
  47
  48    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  49
  50 package Ada.Containers.Indefinite_Ordered_Maps is
  51    pragma Preelaborate;
  52
  53    type Map is tagged private;
  54
  55    type Cursor is private;
  56
  57    Empty_Map : constant Map;
  58
  59    No_Element : constant Cursor;
  60
  61    function "=" (Left, Right : Map) return Boolean;
  62
  63    function Length (Container : Map) return Count_Type;
  64
  65    function Is_Empty (Container : Map) return Boolean;
  66
  67    procedure Clear (Container : in out Map);
  68
  69    function Key (Position : Cursor) return Key_Type;
  70
  71    function Element (Position : Cursor) return Element_Type;
  72
  73    procedure Query_Element
  74      (Position : Cursor;
  75       Process  : not null access procedure (Key     : Key_Type;
  76                                             Element : Element_Type));
  77
  78    procedure Update_Element
  79      (Position : Cursor;
  80       Process  : not null access procedure (Key     : Key_Type;
  81                                             Element : in out Element_Type));
  82
  83    procedure Replace_Element (Position : Cursor; By : Element_Type);
  84
  85    procedure Move (Target : in out Map; Source : in out Map);
  86
  87    procedure Insert
  88      (Container : in out Map;
  89       Key       : Key_Type;
  90       New_Item  : Element_Type;
  91       Position  : out Cursor;
  92       Inserted  : out Boolean);
  93
  94    procedure Insert
  95      (Container : in out Map;
  96       Key       : Key_Type;
  97       New_Item  : Element_Type);
  98
  99    procedure Include
 100      (Container : in out Map;
 101       Key       : Key_Type;
 102       New_Item  : Element_Type);
 103
 104    procedure Replace
 105      (Container : in out Map;
 106       Key       : Key_Type;
 107       New_Item  : Element_Type);
 108
 109    procedure Delete
 110      (Container : in out Map;
 111       Key       : Key_Type);
 112
 113    procedure Delete
 114      (Container : in out Map;
 115       Position  : in out Cursor);
 116
 117    procedure Delete_First (Container : in out Map);
 118
 119    procedure Delete_Last (Container : in out Map);
 120
 121    procedure Exclude
 122      (Container : in out Map;
 123       Key       : Key_Type);
 124
 125    function Contains
 126      (Container : Map;
 127       Key       : Key_Type) return Boolean;
 128
 129    function Find
 130      (Container : Map;
 131       Key       : Key_Type) return Cursor;
 132
 133    function Element
 134      (Container : Map;
 135       Key       : Key_Type) return Element_Type;
 136
 137    function Floor
 138      (Container : Map;
 139       Key       : Key_Type) return Cursor;
 140
 141    function Ceiling
 142      (Container : Map;
 143       Key       : Key_Type) return Cursor;
 144
 145    function First (Container : Map) return Cursor;
 146
 147    function First_Key (Container : Map) return Key_Type;
 148
 149    function First_Element (Container : Map) return Element_Type;
 150
 151    function Last (Container : Map) return Cursor;
 152
 153    function Last_Key (Container : Map) return Key_Type;
 154
 155    function Last_Element (Container : Map) return Element_Type;
 156
 157    function Next (Position : Cursor) return Cursor;
 158
 159    procedure Next (Position : in out Cursor);
 160
 161    function Previous (Position : Cursor) return Cursor;
 162
 163    procedure Previous (Position : in out Cursor);
 164
 165    function Has_Element (Position : Cursor) return Boolean;
 166
 167    function "<" (Left, Right : Cursor) return Boolean;
 168
 169    function ">" (Left, Right : Cursor) return Boolean;
 170
 171    function "<" (Left : Cursor; Right : Key_Type) return Boolean;
 172
 173    function ">" (Left : Cursor; Right : Key_Type) return Boolean;
 174
 175    function "<" (Left : Key_Type; Right : Cursor) return Boolean;
 176
 177    function ">" (Left : Key_Type; Right : Cursor) return Boolean;
 178
 179    procedure Iterate
 180      (Container : Map;
 181       Process   : not null access procedure (Position : Cursor));
 182
 183    procedure Reverse_Iterate
 184      (Container : Map;
 185       Process   : not null access procedure (Position : Cursor));
 186
 187 private
 188
 189    type Node_Type;
 190    type Node_Access is access Node_Type;
 191
 192    type Key_Access is access Key_Type;
 193    type Element_Access is access Element_Type;
 194
 195    type Node_Type is limited record
 196       Parent  : Node_Access;
 197       Left    : Node_Access;
 198       Right   : Node_Access;
 199       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 200       Key     : Key_Access;
 201       Element : Element_Access;
 202    end record;
 203
 204    package Tree_Types is new Red_Black_Trees.Generic_Tree_Types
 205      (Node_Type,
 206       Node_Access);
 207
 208    type Map is new Ada.Finalization.Controlled with record
 209       Tree : Tree_Types.Tree_Type;
 210    end record;
 211
 212    procedure Adjust (Container : in out Map);
 213
 214    procedure Finalize (Container : in out Map) renames Clear;
 215
 216    use Red_Black_Trees;
 217    use Tree_Types;
 218    use Ada.Finalization;
 219
 220    type Map_Access is access Map;
 221    for Map_Access'Storage_Size use 0;
 222
 223    type Cursor is record
 224       Container : Map_Access;
 225       Node      : Node_Access;
 226    end record;
 227
 228    No_Element : constant Cursor := Cursor'(null, null);
 229
 230    use Ada.Streams;
 231
 232    procedure Write
 233      (Stream    : access Root_Stream_Type'Class;
 234       Container : Map);
 235
 236    for Map'Write use Write;
 237
 238    procedure Read
 239      (Stream    : access Root_Stream_Type'Class;
 240       Container : out Map);
 241
 242    for Map'Read use Read;
 243
 244    Empty_Map : constant Map :=
 245                  (Controlled with Tree => (First  => null,
 246                                            Last   => null,
 247                                            Root   => null,
 248                                            Length => 0,
 249                                            Busy   => 0,
 250                                            Lock   => 0));
 251
 252 end Ada.Containers.Indefinite_Ordered_Maps;