gcc/ada/a-cihama.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      A D A . C O N T A I N E R S .                       --
   6 --               I N D E F I N I T E _ H A S H E D _ M A P S                --
   7 --                                                                          --
   8 --                                 S p e c                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2007, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  25 -- Boston, MA 02110-1301, USA.                                              --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- This unit was originally developed by Matthew J Heaney.                  --
  35 ------------------------------------------------------------------------------
  36
  37 with Ada.Containers.Hash_Tables;
  38 with Ada.Streams;
  39 with Ada.Finalization;
  40
  41 generic
  42    type Key_Type (<>) is private;
  43    type Element_Type (<>) is private;
  44
  45    with function Hash (Key : Key_Type) return Hash_Type;
  46    with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
  47    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  48
  49 package Ada.Containers.Indefinite_Hashed_Maps is
  50    pragma Preelaborate;
  51    pragma Remote_Types;
  52
  53    type Map is tagged private;
  54    pragma Preelaborable_Initialization (Map);
  55
  56    type Cursor is private;
  57    pragma Preelaborable_Initialization (Cursor);
  58
  59    Empty_Map  : constant Map;
  60    No_Element : constant Cursor;
  61
  62    function "=" (Left, Right : Map) return Boolean;
  63
  64    function Capacity (Container : Map) return Count_Type;
  65
  66    procedure Reserve_Capacity
  67      (Container : in out Map;
  68       Capacity  : Count_Type);
  69
  70    function Length (Container : Map) return Count_Type;
  71
  72    function Is_Empty (Container : Map) return Boolean;
  73
  74    procedure Clear (Container : in out Map);
  75
  76    function Key (Position : Cursor) return Key_Type;
  77
  78    function Element (Position : Cursor) return Element_Type;
  79
  80    procedure Replace_Element
  81      (Container : in out Map;
  82       Position  : Cursor;
  83       New_Item  : Element_Type);
  84
  85    procedure Query_Element
  86      (Position : Cursor;
  87       Process  : not null access procedure (Key     : Key_Type;
  88                                             Element : Element_Type));
  89
  90    procedure Update_Element
  91      (Container : in out Map;
  92       Position  : Cursor;
  93       Process   : not null access procedure (Key     : Key_Type;
  94                                             Element : in out Element_Type));
  95
  96    procedure Move (Target : in out Map; Source : in out Map);
  97
  98    procedure Insert
  99      (Container : in out Map;
 100       Key       : Key_Type;
 101       New_Item  : Element_Type;
 102       Position  : out Cursor;
 103       Inserted  : out Boolean);
 104
 105    procedure Insert
 106      (Container : in out Map;
 107       Key       : Key_Type;
 108       New_Item  : Element_Type);
 109
 110    procedure Include
 111      (Container : in out Map;
 112       Key       : Key_Type;
 113       New_Item  : Element_Type);
 114
 115    procedure Replace
 116      (Container : in out Map;
 117       Key       : Key_Type;
 118       New_Item  : Element_Type);
 119
 120    procedure Exclude (Container : in out Map; Key : Key_Type);
 121
 122    procedure Delete (Container : in out Map; Key : Key_Type);
 123
 124    procedure Delete (Container : in out Map; Position : in out Cursor);
 125
 126    function First (Container : Map) return Cursor;
 127
 128    function Next (Position : Cursor) return Cursor;
 129
 130    procedure Next (Position : in out Cursor);
 131
 132    function Find (Container : Map; Key : Key_Type) return Cursor;
 133
 134    function Contains (Container : Map; Key : Key_Type) return Boolean;
 135
 136    function Element (Container : Map; Key : Key_Type) return Element_Type;
 137
 138    function Has_Element (Position : Cursor) return Boolean;
 139
 140    function Equivalent_Keys (Left, Right : Cursor) return Boolean;
 141
 142    function Equivalent_Keys (Left : Cursor; Right : Key_Type) return Boolean;
 143
 144    function Equivalent_Keys (Left : Key_Type; Right : Cursor) return Boolean;
 145
 146    procedure Iterate
 147      (Container : Map;
 148       Process   : not null access procedure (Position : Cursor));
 149
 150 private
 151    pragma Inline ("=");
 152    pragma Inline (Length);
 153    pragma Inline (Is_Empty);
 154    pragma Inline (Clear);
 155    pragma Inline (Key);
 156    pragma Inline (Element);
 157    pragma Inline (Move);
 158    pragma Inline (Contains);
 159    pragma Inline (Capacity);
 160    pragma Inline (Reserve_Capacity);
 161    pragma Inline (Has_Element);
 162    pragma Inline (Equivalent_Keys);
 163    pragma Inline (Next);
 164
 165    type Node_Type;
 166    type Node_Access is access Node_Type;
 167
 168    type Key_Access is access Key_Type;
 169    type Element_Access is access Element_Type;
 170
 171    type Node_Type is limited record
 172       Key     : Key_Access;
 173       Element : Element_Access;
 174       Next    : Node_Access;
 175    end record;
 176
 177    package HT_Types is new Hash_Tables.Generic_Hash_Table_Types
 178      (Node_Type,
 179       Node_Access);
 180
 181    type Map is new Ada.Finalization.Controlled with record
 182       HT : HT_Types.Hash_Table_Type;
 183    end record;
 184
 185    use HT_Types;
 186    use Ada.Finalization;
 187    use Ada.Streams;
 188
 189    procedure Adjust (Container : in out Map);
 190
 191    procedure Finalize (Container : in out Map);
 192
 193    type Map_Access is access constant Map;
 194    for Map_Access'Storage_Size use 0;
 195
 196    type Cursor is
 197       record
 198          Container : Map_Access;
 199          Node      : Node_Access;
 200       end record;
 201
 202    procedure Write
 203      (Stream : not null access Root_Stream_Type'Class;
 204       Item   : Cursor);
 205
 206    for Cursor'Write use Write;
 207
 208    procedure Read
 209      (Stream : not null access Root_Stream_Type'Class;
 210       Item   : out Cursor);
 211
 212    for Cursor'Read use Read;
 213
 214    No_Element : constant Cursor :=
 215      (Container => null,
 216       Node      => null);
 217
 218    procedure Write
 219      (Stream    : not null access Root_Stream_Type'Class;
 220       Container : Map);
 221
 222    for Map'Write use Write;
 223
 224    procedure Read
 225      (Stream    : not null access Root_Stream_Type'Class;
 226       Container : out Map);
 227
 228    for Map'Read use Read;
 229
 230    Empty_Map : constant Map := (Controlled with HT => (null, 0, 0, 0));
 231
 232 end Ada.Containers.Indefinite_Hashed_Maps;