gcc/ada/a-calend.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         A D A . C A L E N D A R                          --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with Ada.Unchecked_Conversion;
  33
  34 with System.OS_Primitives;
  35
  36 package body Ada.Calendar is
  37
  38    --------------------------
  39    -- Implementation Notes --
  40    --------------------------
  41
  42    --  In complex algorithms, some variables of type Ada.Calendar.Time carry
  43    --  suffix _S or _N to denote units of seconds or nanoseconds.
  44    --
  45    --  Because time is measured in different units and from different origins
  46    --  on various targets, a system independent model is incorporated into
  47    --  Ada.Calendar. The idea behind the design is to encapsulate all target
  48    --  dependent machinery in a single package, thus providing a uniform
  49    --  interface to all existing and any potential children.
  50
  51    --     package Ada.Calendar
  52    --        procedure Split (5 parameters) -------+
  53    --                                              | Call from local routine
  54    --     private                                  |
  55    --        package Formatting_Operations         |
  56    --           procedure Split (11 parameters) <--+
  57    --        end Formatting_Operations             |
  58    --     end Ada.Calendar                         |
  59    --                                              |
  60    --     package Ada.Calendar.Formatting          | Call from child routine
  61    --        procedure Split (9 or 10 parameters) -+
  62    --     end Ada.Calendar.Formatting
  63
  64    --  The behaviour of the interfacing routines is controlled via various
  65    --  flags. All new Ada 2005 types from children of Ada.Calendar are
  66    --  emulated by a similar type. For instance, type Day_Number is replaced
  67    --  by Integer in various routines. One ramification of this model is that
  68    --  the caller site must perform validity checks on returned results.
  69    --  The end result of this model is the lack of target specific files per
  70    --  child of Ada.Calendar (a-calfor, a-calfor-vms, a-calfor-vxwors, etc).
  71
  72    -----------------------
  73    -- Local Subprograms --
  74    -----------------------
  75
  76    procedure Check_Within_Time_Bounds (T : Time_Rep);
  77    --  Ensure that a time representation value falls withing the bounds of Ada
  78    --  time. Leap seconds support is taken into account.
  79
  80    procedure Cumulative_Leap_Seconds
  81      (Start_Date    : Time_Rep;
  82       End_Date      : Time_Rep;
  83       Elapsed_Leaps : out Natural;
  84       Next_Leap     : out Time_Rep);
  85    --  Elapsed_Leaps is the sum of the leap seconds that have occurred on or
  86    --  after Start_Date and before (strictly before) End_Date. Next_Leap_Sec
  87    --  represents the next leap second occurrence on or after End_Date. If
  88    --  there are no leaps seconds after End_Date, End_Of_Time is returned.
  89    --  End_Of_Time can be used as End_Date to count all the leap seconds that
  90    --  have occurred on or after Start_Date.
  91    --
  92    --  Note: Any sub seconds of Start_Date and End_Date are discarded before
  93    --  the calculations are done. For instance: if 113 seconds is a leap
  94    --  second (it isn't) and 113.5 is input as an End_Date, the leap second
  95    --  at 113 will not be counted in Leaps_Between, but it will be returned
  96    --  as Next_Leap_Sec. Thus, if the caller wants to know if the End_Date is
  97    --  a leap second, the comparison should be:
  98    --
  99    --     End_Date >= Next_Leap_Sec;
 100    --
 101    --  After_Last_Leap is designed so that this comparison works without
 102    --  having to first check if Next_Leap_Sec is a valid leap second.
 103
 104    function Duration_To_Time_Rep is
 105      new Ada.Unchecked_Conversion (Duration, Time_Rep);
 106    --  Convert a duration value into a time representation value
 107
 108    function Time_Rep_To_Duration is
 109      new Ada.Unchecked_Conversion (Time_Rep, Duration);
 110    --  Convert a time representation value into a duration value
 111
 112    -----------------
 113    -- Local Types --
 114    -----------------
 115
 116    --  An integer time duration. The type is used whenever a positive elapsed
 117    --  duration is needed, for instance when splitting a time value. Here is
 118    --  how Time_Rep and Time_Dur are related:
 119
 120    --            'First  Ada_Low                  Ada_High  'Last
 121    --  Time_Rep: +-------+------------------------+---------+
 122    --  Time_Dur:         +------------------------+---------+
 123    --                    0                                  'Last
 124
 125    type Time_Dur is range 0 .. 2 ** 63 - 1;
 126
 127    --------------------------
 128    -- Leap seconds control --
 129    --------------------------
 130
 131    Flag : Integer;
 132    pragma Import (C, Flag, "__gl_leap_seconds_support");
 133    --  This imported value is used to determine whether the compilation had
 134    --  binder flag "-y" present which enables leap seconds. A value of zero
 135    --  signifies no leap seconds support while a value of one enables the
 136    --  support.
 137
 138    Leap_Support : constant Boolean := Flag = 1;
 139    --  The above flag controls the usage of leap seconds in all Ada.Calendar
 140    --  routines.
 141
 142    Leap_Seconds_Count : constant Natural := 24;
 143
 144    ---------------------
 145    -- Local Constants --
 146    ---------------------
 147
 148    Ada_Min_Year          : constant Year_Number := Year_Number'First;
 149    Secs_In_Four_Years    : constant := (3 * 365 + 366) * Secs_In_Day;
 150    Secs_In_Non_Leap_Year : constant := 365 * Secs_In_Day;
 151    Nanos_In_Four_Years   : constant := Secs_In_Four_Years * Nano;
 152
 153    --  Lower and upper bound of Ada time. The zero (0) value of type Time is
 154    --  positioned at year 2150. Note that the lower and upper bound account
 155    --  for the non-leap centennial years.
 156
 157    Ada_Low  : constant Time_Rep := -(61 * 366 + 188 * 365) * Nanos_In_Day;
 158    Ada_High : constant Time_Rep :=  (60 * 366 + 190 * 365) * Nanos_In_Day;
 159
 160    --  Even though the upper bound of time is 2399-12-31 23:59:59.999999999
 161    --  UTC, it must be increased to include all leap seconds.
 162
 163    Ada_High_And_Leaps : constant Time_Rep :=
 164                           Ada_High + Time_Rep (Leap_Seconds_Count) * Nano;
 165
 166    --  Two constants used in the calculations of elapsed leap seconds.
 167    --  End_Of_Time is later than Ada_High in time zone -28. Start_Of_Time
 168    --  is earlier than Ada_Low in time zone +28.
 169
 170    End_Of_Time   : constant Time_Rep :=
 171                      Ada_High + Time_Rep (3) * Nanos_In_Day;
 172    Start_Of_Time : constant Time_Rep :=
 173                      Ada_Low - Time_Rep (3) * Nanos_In_Day;
 174
 175    --  The Unix lower time bound expressed as nanoseconds since the
 176    --  start of Ada time in UTC.
 177
 178    Unix_Min : constant Time_Rep :=
 179                 Ada_Low + Time_Rep (17 * 366 + 52 * 365) * Nanos_In_Day;
 180
 181    Epoch_Offset : constant Time_Rep := (136 * 365 + 44 * 366) * Nanos_In_Day;
 182    --  The difference between 2150-1-1 UTC and 1970-1-1 UTC expressed in
 183    --  nanoseconds. Note that year 2100 is non-leap.
 184
 185    Cumulative_Days_Before_Month :
 186      constant array (Month_Number) of Natural :=
 187        (0, 31, 59, 90, 120, 151, 181, 212, 243, 273, 304, 334);
 188
 189    --  The following table contains the hard time values of all existing leap
 190    --  seconds. The values are produced by the utility program xleaps.adb.
 191
 192    Leap_Second_Times : constant array (1 .. Leap_Seconds_Count) of Time_Rep :=
 193      (-5601484800000000000,
 194       -5585587199000000000,
 195       -5554051198000000000,
 196       -5522515197000000000,
 197       -5490979196000000000,
 198       -5459356795000000000,
 199       -5427820794000000000,
 200       -5396284793000000000,
 201       -5364748792000000000,
 202       -5317487991000000000,
 203       -5285951990000000000,
 204       -5254415989000000000,
 205       -5191257588000000000,
 206       -5112287987000000000,
 207       -5049129586000000000,
 208       -5017593585000000000,
 209       -4970332784000000000,
 210       -4938796783000000000,
 211       -4907260782000000000,
 212       -4859827181000000000,
 213       -4812566380000000000,
 214       -4765132779000000000,
 215       -4544207978000000000,
 216       -4449513577000000000);
 217
 218    ---------
 219    -- "+" --
 220    ---------
 221
 222    function "+" (Left : Time; Right : Duration) return Time is
 223       pragma Unsuppress (Overflow_Check);
 224       Left_N : constant Time_Rep := Time_Rep (Left);
 225    begin
 226       return Time (Left_N + Duration_To_Time_Rep (Right));
 227    exception
 228       when Constraint_Error =>
 229          raise Time_Error;
 230    end "+";
 231
 232    function "+" (Left : Duration; Right : Time) return Time is
 233    begin
 234       return Right + Left;
 235    end "+";
 236
 237    ---------
 238    -- "-" --
 239    ---------
 240
 241    function "-" (Left : Time; Right : Duration) return Time is
 242       pragma Unsuppress (Overflow_Check);
 243       Left_N : constant Time_Rep := Time_Rep (Left);
 244    begin
 245       return Time (Left_N - Duration_To_Time_Rep (Right));
 246    exception
 247       when Constraint_Error =>
 248          raise Time_Error;
 249    end "-";
 250
 251    function "-" (Left : Time; Right : Time) return Duration is
 252       pragma Unsuppress (Overflow_Check);
 253
 254       --  The bounds of type Duration expressed as time representations
 255
 256       Dur_Low  : constant Time_Rep := Duration_To_Time_Rep (Duration'First);
 257       Dur_High : constant Time_Rep := Duration_To_Time_Rep (Duration'Last);
 258
 259       Res_N : Time_Rep;
 260
 261    begin
 262       Res_N := Time_Rep (Left) - Time_Rep (Right);
 263
 264       --  Due to the extended range of Ada time, "-" is capable of producing
 265       --  results which may exceed the range of Duration. In order to prevent
 266       --  the generation of bogus values by the Unchecked_Conversion, we apply
 267       --  the following check.
 268
 269       if Res_N < Dur_Low
 270         or else Res_N > Dur_High
 271       then
 272          raise Time_Error;
 273       end if;
 274
 275       return Time_Rep_To_Duration (Res_N);
 276    exception
 277       when Constraint_Error =>
 278          raise Time_Error;
 279    end "-";
 280
 281    ---------
 282    -- "<" --
 283    ---------
 284
 285    function "<" (Left, Right : Time) return Boolean is
 286    begin
 287       return Time_Rep (Left) < Time_Rep (Right);
 288    end "<";
 289
 290    ----------
 291    -- "<=" --
 292    ----------
 293
 294    function "<=" (Left, Right : Time) return Boolean is
 295    begin
 296       return Time_Rep (Left) <= Time_Rep (Right);
 297    end "<=";
 298
 299    ---------
 300    -- ">" --
 301    ---------
 302
 303    function ">" (Left, Right : Time) return Boolean is
 304    begin
 305       return Time_Rep (Left) > Time_Rep (Right);
 306    end ">";
 307
 308    ----------
 309    -- ">=" --
 310    ----------
 311
 312    function ">=" (Left, Right : Time) return Boolean is
 313    begin
 314       return Time_Rep (Left) >= Time_Rep (Right);
 315    end ">=";
 316
 317    ------------------------------
 318    -- Check_Within_Time_Bounds --
 319    ------------------------------
 320
 321    procedure Check_Within_Time_Bounds (T : Time_Rep) is
 322    begin
 323       if Leap_Support then
 324          if T < Ada_Low or else T > Ada_High_And_Leaps then
 325             raise Time_Error;
 326          end if;
 327       else
 328          if T < Ada_Low or else T > Ada_High then
 329             raise Time_Error;
 330          end if;
 331       end if;
 332    end Check_Within_Time_Bounds;
 333
 334    -----------
 335    -- Clock --
 336    -----------
 337
 338    function Clock return Time is
 339       Elapsed_Leaps : Natural;
 340       Next_Leap_N   : Time_Rep;
 341
 342       --  The system clock returns the time in UTC since the Unix Epoch of
 343       --  1970-01-01 00:00:00.0. We perform an origin shift to the Ada Epoch
 344       --  by adding the number of nanoseconds between the two origins.
 345
 346       Res_N : Time_Rep :=
 347                 Duration_To_Time_Rep (System.OS_Primitives.Clock) +
 348                   Unix_Min;
 349
 350    begin
 351       --  If the target supports leap seconds, determine the number of leap
 352       --  seconds elapsed until this moment.
 353
 354       if Leap_Support then
 355          Cumulative_Leap_Seconds
 356            (Start_Of_Time, Res_N, Elapsed_Leaps, Next_Leap_N);
 357
 358          --  The system clock may fall exactly on a leap second
 359
 360          if Res_N >= Next_Leap_N then
 361             Elapsed_Leaps := Elapsed_Leaps + 1;
 362          end if;
 363
 364       --  The target does not support leap seconds
 365
 366       else
 367          Elapsed_Leaps := 0;
 368       end if;
 369
 370       Res_N := Res_N + Time_Rep (Elapsed_Leaps) * Nano;
 371
 372       return Time (Res_N);
 373    end Clock;
 374
 375    -----------------------------
 376    -- Cumulative_Leap_Seconds --
 377    -----------------------------
 378
 379    procedure Cumulative_Leap_Seconds
 380      (Start_Date    : Time_Rep;
 381       End_Date      : Time_Rep;
 382       Elapsed_Leaps : out Natural;
 383       Next_Leap     : out Time_Rep)
 384    is
 385       End_Index   : Positive;
 386       End_T       : Time_Rep := End_Date;
 387       Start_Index : Positive;
 388       Start_T     : Time_Rep := Start_Date;
 389
 390    begin
 391       --  Both input dates must be normalized to UTC
 392
 393       pragma Assert (Leap_Support and then End_Date >= Start_Date);
 394
 395       Next_Leap := End_Of_Time;
 396
 397       --  Make sure that the end date does not exceed the upper bound
 398       --  of Ada time.
 399
 400       if End_Date > Ada_High then
 401          End_T := Ada_High;
 402       end if;
 403
 404       --  Remove the sub seconds from both dates
 405
 406       Start_T := Start_T - (Start_T mod Nano);
 407       End_T   := End_T   - (End_T   mod Nano);
 408
 409       --  Some trivial cases:
 410       --                     Leap 1 . . . Leap N
 411       --  ---+========+------+############+-------+========+-----
 412       --     Start_T  End_T                       Start_T  End_T
 413
 414       if End_T < Leap_Second_Times (1) then
 415          Elapsed_Leaps := 0;
 416          Next_Leap     := Leap_Second_Times (1);
 417          return;
 418
 419       elsif Start_T > Leap_Second_Times (Leap_Seconds_Count) then
 420          Elapsed_Leaps := 0;
 421          Next_Leap     := End_Of_Time;
 422          return;
 423       end if;
 424
 425       --  Perform the calculations only if the start date is within the leap
 426       --  second occurrences table.
 427
 428       if Start_T <= Leap_Second_Times (Leap_Seconds_Count) then
 429
 430          --    1    2                  N - 1   N
 431          --  +----+----+--  . . .  --+-------+---+
 432          --  | T1 | T2 |             | N - 1 | N |
 433          --  +----+----+--  . . .  --+-------+---+
 434          --         ^                   ^
 435          --         | Start_Index       | End_Index
 436          --         +-------------------+
 437          --             Leaps_Between
 438
 439          --  The idea behind the algorithm is to iterate and find two
 440          --  closest dates which are after Start_T and End_T. Their
 441          --  corresponding index difference denotes the number of leap
 442          --  seconds elapsed.
 443
 444          Start_Index := 1;
 445          loop
 446             exit when Leap_Second_Times (Start_Index) >= Start_T;
 447             Start_Index := Start_Index + 1;
 448          end loop;
 449
 450          End_Index := Start_Index;
 451          loop
 452             exit when End_Index > Leap_Seconds_Count
 453               or else Leap_Second_Times (End_Index) >= End_T;
 454             End_Index := End_Index + 1;
 455          end loop;
 456
 457          if End_Index <= Leap_Seconds_Count then
 458             Next_Leap := Leap_Second_Times (End_Index);
 459          end if;
 460
 461          Elapsed_Leaps := End_Index - Start_Index;
 462
 463       else
 464          Elapsed_Leaps := 0;
 465       end if;
 466    end Cumulative_Leap_Seconds;
 467
 468    ---------
 469    -- Day --
 470    ---------
 471
 472    function Day (Date : Time) return Day_Number is
 473       D : Day_Number;
 474       Y : Year_Number;
 475       M : Month_Number;
 476       S : Day_Duration;
 477       pragma Unreferenced (Y, M, S);
 478    begin
 479       Split (Date, Y, M, D, S);
 480       return D;
 481    end Day;
 482
 483    -------------
 484    -- Is_Leap --
 485    -------------
 486
 487    function Is_Leap (Year : Year_Number) return Boolean is
 488    begin
 489       --  Leap centennial years
 490
 491       if Year mod 400 = 0 then
 492          return True;
 493
 494       --  Non-leap centennial years
 495
 496       elsif Year mod 100 = 0 then
 497          return False;
 498
 499       --  Regular years
 500
 501       else
 502          return Year mod 4 = 0;
 503       end if;
 504    end Is_Leap;
 505
 506    -----------
 507    -- Month --
 508    -----------
 509
 510    function Month (Date : Time) return Month_Number is
 511       Y : Year_Number;
 512       M : Month_Number;
 513       D : Day_Number;
 514       S : Day_Duration;
 515       pragma Unreferenced (Y, D, S);
 516    begin
 517       Split (Date, Y, M, D, S);
 518       return M;
 519    end Month;
 520
 521    -------------
 522    -- Seconds --
 523    -------------
 524
 525    function Seconds (Date : Time) return Day_Duration is
 526       Y : Year_Number;
 527       M : Month_Number;
 528       D : Day_Number;
 529       S : Day_Duration;
 530       pragma Unreferenced (Y, M, D);
 531    begin
 532       Split (Date, Y, M, D, S);
 533       return S;
 534    end Seconds;
 535
 536    -----------
 537    -- Split --
 538    -----------
 539
 540    procedure Split
 541      (Date    : Time;
 542       Year    : out Year_Number;
 543       Month   : out Month_Number;
 544       Day     : out Day_Number;
 545       Seconds : out Day_Duration)
 546    is
 547       H  : Integer;
 548       M  : Integer;
 549       Se : Integer;
 550       Ss : Duration;
 551       Le : Boolean;
 552
 553       pragma Unreferenced (H, M, Se, Ss, Le);
 554
 555    begin
 556       --  Even though the input time zone is UTC (0), the flag Is_Ada_05 will
 557       --  ensure that Split picks up the local time zone.
 558
 559       Formatting_Operations.Split
 560         (Date      => Date,
 561          Year      => Year,
 562          Month     => Month,
 563          Day       => Day,
 564          Day_Secs  => Seconds,
 565          Hour      => H,
 566          Minute    => M,
 567          Second    => Se,
 568          Sub_Sec   => Ss,
 569          Leap_Sec  => Le,
 570          Is_Ada_05 => False,
 571          Time_Zone => 0);
 572
 573       --  Validity checks
 574
 575       if not Year'Valid
 576         or else not Month'Valid
 577         or else not Day'Valid
 578         or else not Seconds'Valid
 579       then
 580          raise Time_Error;
 581       end if;
 582    end Split;
 583
 584    -------------
 585    -- Time_Of --
 586    -------------
 587
 588    function Time_Of
 589      (Year    : Year_Number;
 590       Month   : Month_Number;
 591       Day     : Day_Number;
 592       Seconds : Day_Duration := 0.0) return Time
 593    is
 594       --  The values in the following constants are irrelevant, they are just
 595       --  placeholders; the choice of constructing a Day_Duration value is
 596       --  controlled by the Use_Day_Secs flag.
 597
 598       H  : constant Integer := 1;
 599       M  : constant Integer := 1;
 600       Se : constant Integer := 1;
 601       Ss : constant Duration := 0.1;
 602
 603    begin
 604       --  Validity checks
 605
 606       if not Year'Valid
 607         or else not Month'Valid
 608         or else not Day'Valid
 609         or else not Seconds'Valid
 610       then
 611          raise Time_Error;
 612       end if;
 613
 614       --  Even though the input time zone is UTC (0), the flag Is_Ada_05 will
 615       --  ensure that Split picks up the local time zone.
 616
 617       return
 618         Formatting_Operations.Time_Of
 619           (Year         => Year,
 620            Month        => Month,
 621            Day          => Day,
 622            Day_Secs     => Seconds,
 623            Hour         => H,
 624            Minute       => M,
 625            Second       => Se,
 626            Sub_Sec      => Ss,
 627            Leap_Sec     => False,
 628            Use_Day_Secs => True,
 629            Is_Ada_05    => False,
 630            Time_Zone    => 0);
 631    end Time_Of;
 632
 633    ----------
 634    -- Year --
 635    ----------
 636
 637    function Year (Date : Time) return Year_Number is
 638       Y : Year_Number;
 639       M : Month_Number;
 640       D : Day_Number;
 641       S : Day_Duration;
 642       pragma Unreferenced (M, D, S);
 643    begin
 644       Split (Date, Y, M, D, S);
 645       return Y;
 646    end Year;
 647
 648    --  The following packages assume that Time is a signed 64 bit integer
 649    --  type, the units are nanoseconds and the origin is the start of Ada
 650    --  time (1901-01-01 00:00:00.0 UTC).
 651
 652    ---------------------------
 653    -- Arithmetic_Operations --
 654    ---------------------------
 655
 656    package body Arithmetic_Operations is
 657
 658       ---------
 659       -- Add --
 660       ---------
 661
 662       function Add (Date : Time; Days : Long_Integer) return Time is
 663          pragma Unsuppress (Overflow_Check);
 664          Date_N : constant Time_Rep := Time_Rep (Date);
 665       begin
 666          return Time (Date_N + Time_Rep (Days) * Nanos_In_Day);
 667       exception
 668          when Constraint_Error =>
 669             raise Time_Error;
 670       end Add;
 671
 672       ----------------
 673       -- Difference --
 674       ----------------
 675
 676       procedure Difference
 677         (Left         : Time;
 678          Right        : Time;
 679          Days         : out Long_Integer;
 680          Seconds      : out Duration;
 681          Leap_Seconds : out Integer)
 682       is
 683          Res_Dur       : Time_Dur;
 684          Earlier       : Time_Rep;
 685          Elapsed_Leaps : Natural;
 686          Later         : Time_Rep;
 687          Negate        : Boolean := False;
 688          Next_Leap_N   : Time_Rep;
 689          Sub_Secs      : Duration;
 690          Sub_Secs_Diff : Time_Rep;
 691
 692       begin
 693          --  Both input time values are assumed to be in UTC
 694
 695          if Left >= Right then
 696             Later   := Time_Rep (Left);
 697             Earlier := Time_Rep (Right);
 698          else
 699             Later   := Time_Rep (Right);
 700             Earlier := Time_Rep (Left);
 701             Negate  := True;
 702          end if;
 703
 704          --  If the target supports leap seconds, process them
 705
 706          if Leap_Support then
 707             Cumulative_Leap_Seconds
 708               (Earlier, Later, Elapsed_Leaps, Next_Leap_N);
 709
 710             if Later >= Next_Leap_N then
 711                Elapsed_Leaps := Elapsed_Leaps + 1;
 712             end if;
 713
 714          --  The target does not support leap seconds
 715
 716          else
 717             Elapsed_Leaps := 0;
 718          end if;
 719
 720          --  Sub seconds processing. We add the resulting difference to one
 721          --  of the input dates in order to account for any potential rounding
 722          --  of the difference in the next step.
 723
 724          Sub_Secs_Diff := Later mod Nano - Earlier mod Nano;
 725          Earlier       := Earlier + Sub_Secs_Diff;
 726          Sub_Secs      := Duration (Sub_Secs_Diff) / Nano_F;
 727
 728          --  Difference processing. This operation should be able to calculate
 729          --  the difference between opposite values which are close to the end
 730          --  and start of Ada time. To accommodate the large range, we convert
 731          --  to seconds. This action may potentially round the two values and
 732          --  either add or drop a second. We compensate for this issue in the
 733          --  previous step.
 734
 735          Res_Dur :=
 736            Time_Dur (Later / Nano - Earlier / Nano) - Time_Dur (Elapsed_Leaps);
 737
 738          Days         := Long_Integer (Res_Dur / Secs_In_Day);
 739          Seconds      := Duration (Res_Dur mod Secs_In_Day) + Sub_Secs;
 740          Leap_Seconds := Integer (Elapsed_Leaps);
 741
 742          if Negate then
 743             Days    := -Days;
 744             Seconds := -Seconds;
 745
 746             if Leap_Seconds /= 0 then
 747                Leap_Seconds := -Leap_Seconds;
 748             end if;
 749          end if;
 750       end Difference;
 751
 752       --------------
 753       -- Subtract --
 754       --------------
 755
 756       function Subtract (Date : Time; Days : Long_Integer) return Time is
 757          pragma Unsuppress (Overflow_Check);
 758          Date_N : constant Time_Rep := Time_Rep (Date);
 759       begin
 760          return Time (Date_N - Time_Rep (Days) * Nanos_In_Day);
 761       exception
 762          when Constraint_Error =>
 763             raise Time_Error;
 764       end Subtract;
 765
 766    end Arithmetic_Operations;
 767
 768    ---------------------------
 769    -- Conversion_Operations --
 770    ---------------------------
 771
 772    package body Conversion_Operations is
 773
 774       -----------------
 775       -- To_Ada_Time --
 776       -----------------
 777
 778       function To_Ada_Time (Unix_Time : Long_Integer) return Time is
 779          pragma Unsuppress (Overflow_Check);
 780          Unix_Rep : constant Time_Rep := Time_Rep (Unix_Time) * Nano;
 781       begin
 782          return Time (Unix_Rep - Epoch_Offset);
 783       exception
 784          when Constraint_Error =>
 785             raise Time_Error;
 786       end To_Ada_Time;
 787
 788       -----------------
 789       -- To_Ada_Time --
 790       -----------------
 791
 792       function To_Ada_Time
 793         (tm_year  : Integer;
 794          tm_mon   : Integer;
 795          tm_day   : Integer;
 796          tm_hour  : Integer;
 797          tm_min   : Integer;
 798          tm_sec   : Integer;
 799          tm_isdst : Integer) return Time
 800       is
 801          pragma Unsuppress (Overflow_Check);
 802          Year   : Year_Number;
 803          Month  : Month_Number;
 804          Day    : Day_Number;
 805          Second : Integer;
 806          Leap   : Boolean;
 807          Result : Time_Rep;
 808
 809       begin
 810          --  Input processing
 811
 812          Year  := Year_Number (1900 + tm_year);
 813          Month := Month_Number (1 + tm_mon);
 814          Day   := Day_Number (tm_day);
 815
 816          --  Step 1: Validity checks of input values
 817
 818          if not Year'Valid
 819            or else not Month'Valid
 820            or else not Day'Valid
 821            or else tm_hour not in 0 .. 24
 822            or else tm_min not in 0 .. 59
 823            or else tm_sec not in 0 .. 60
 824            or else tm_isdst not in -1 .. 1
 825          then
 826             raise Time_Error;
 827          end if;
 828
 829          --  Step 2: Potential leap second
 830
 831          if tm_sec = 60 then
 832             Leap   := True;
 833             Second := 59;
 834          else
 835             Leap   := False;
 836             Second := tm_sec;
 837          end if;
 838
 839          --  Step 3: Calculate the time value
 840
 841          Result :=
 842            Time_Rep
 843              (Formatting_Operations.Time_Of
 844                (Year         => Year,
 845                 Month        => Month,
 846                 Day          => Day,
 847                 Day_Secs     => 0.0,      --  Time is given in h:m:s
 848                 Hour         => tm_hour,
 849                 Minute       => tm_min,
 850                 Second       => Second,
 851                 Sub_Sec      => 0.0,      --  No precise sub second given
 852                 Leap_Sec     => Leap,
 853                 Use_Day_Secs => False,    --  Time is given in h:m:s
 854                 Is_Ada_05    => True,     --  Force usage of explicit time zone
 855                 Time_Zone    => 0));      --  Place the value in UTC
 856
 857          --  Step 4: Daylight Savings Time
 858
 859          if tm_isdst = 1 then
 860             Result := Result + Time_Rep (3_600) * Nano;
 861          end if;
 862
 863          return Time (Result);
 864
 865       exception
 866          when Constraint_Error =>
 867             raise Time_Error;
 868       end To_Ada_Time;
 869
 870       -----------------
 871       -- To_Duration --
 872       -----------------
 873
 874       function To_Duration
 875         (tv_sec  : Long_Integer;
 876          tv_nsec : Long_Integer) return Duration
 877       is
 878          pragma Unsuppress (Overflow_Check);
 879       begin
 880          return Duration (tv_sec) + Duration (tv_nsec) / Nano_F;
 881       end To_Duration;
 882
 883       ------------------------
 884       -- To_Struct_Timespec --
 885       ------------------------
 886
 887       procedure To_Struct_Timespec
 888         (D       : Duration;
 889          tv_sec  : out Long_Integer;
 890          tv_nsec : out Long_Integer)
 891       is
 892          pragma Unsuppress (Overflow_Check);
 893          Secs      : Duration;
 894          Nano_Secs : Duration;
 895
 896       begin
 897          --  Seconds extraction, avoid potential rounding errors
 898
 899          Secs   := D - 0.5;
 900          tv_sec := Long_Integer (Secs);
 901
 902          --  Nanoseconds extraction
 903
 904          Nano_Secs := D - Duration (tv_sec);
 905          tv_nsec := Long_Integer (Nano_Secs * Nano);
 906       end To_Struct_Timespec;
 907
 908       ------------------
 909       -- To_Struct_Tm --
 910       ------------------
 911
 912       procedure To_Struct_Tm
 913         (T       : Time;
 914          tm_year : out Integer;
 915          tm_mon  : out Integer;
 916          tm_day  : out Integer;
 917          tm_hour : out Integer;
 918          tm_min  : out Integer;
 919          tm_sec  : out Integer)
 920       is
 921          pragma Unsuppress (Overflow_Check);
 922          Year      : Year_Number;
 923          Month     : Month_Number;
 924          Second    : Integer;
 925          Day_Secs  : Day_Duration;
 926          Sub_Sec   : Duration;
 927          Leap_Sec  : Boolean;
 928
 929       begin
 930          --  Step 1: Split the input time
 931
 932          Formatting_Operations.Split
 933            (T, Year, Month, tm_day, Day_Secs,
 934             tm_hour, tm_min, Second, Sub_Sec, Leap_Sec, True, 0);
 935
 936          --  Step 2: Correct the year and month
 937
 938          tm_year := Year - 1900;
 939          tm_mon  := Month - 1;
 940
 941          --  Step 3: Handle leap second occurrences
 942
 943          tm_sec := (if Leap_Sec then 60 else Second);
 944       end To_Struct_Tm;
 945
 946       ------------------
 947       -- To_Unix_Time --
 948       ------------------
 949
 950       function To_Unix_Time (Ada_Time : Time) return Long_Integer is
 951          pragma Unsuppress (Overflow_Check);
 952          Ada_Rep : constant Time_Rep := Time_Rep (Ada_Time);
 953       begin
 954          return Long_Integer ((Ada_Rep + Epoch_Offset) / Nano);
 955       exception
 956          when Constraint_Error =>
 957             raise Time_Error;
 958       end To_Unix_Time;
 959    end Conversion_Operations;
 960
 961    ----------------------
 962    -- Delay_Operations --
 963    ----------------------
 964
 965    package body Delay_Operations is
 966
 967       -----------------
 968       -- To_Duration --
 969       -----------------
 970
 971       function To_Duration (Date : Time) return Duration is
 972          pragma Unsuppress (Overflow_Check);
 973
 974          Safe_Ada_High : constant Time_Rep := Ada_High - Epoch_Offset;
 975          --  This value represents a "safe" end of time. In order to perform a
 976          --  proper conversion to Unix duration, we will have to shift origins
 977          --  at one point. For very distant dates, this means an overflow check
 978          --  failure. To prevent this, the function returns the "safe" end of
 979          --  time (roughly 2219) which is still distant enough.
 980
 981          Elapsed_Leaps : Natural;
 982          Next_Leap_N   : Time_Rep;
 983          Res_N         : Time_Rep;
 984
 985       begin
 986          Res_N := Time_Rep (Date);
 987
 988          --  Step 1: If the target supports leap seconds, remove any leap
 989          --  seconds elapsed up to the input date.
 990
 991          if Leap_Support then
 992             Cumulative_Leap_Seconds
 993               (Start_Of_Time, Res_N, Elapsed_Leaps, Next_Leap_N);
 994
 995             --  The input time value may fall on a leap second occurrence
 996
 997             if Res_N >= Next_Leap_N then
 998                Elapsed_Leaps := Elapsed_Leaps + 1;
 999             end if;
1000
1001          --  The target does not support leap seconds
1002
1003          else
1004             Elapsed_Leaps := 0;
1005          end if;
1006
1007          Res_N := Res_N - Time_Rep (Elapsed_Leaps) * Nano;
1008
1009          --  Step 2: Perform a shift in origins to obtain a Unix equivalent of
1010          --  the input. Guard against very large delay values such as the end
1011          --  of time since the computation will overflow.
1012
1013          Res_N := (if Res_N > Safe_Ada_High then Safe_Ada_High
1014                                             else Res_N + Epoch_Offset);
1015
1016          return Time_Rep_To_Duration (Res_N);
1017       end To_Duration;
1018
1019    end Delay_Operations;
1020
1021    ---------------------------
1022    -- Formatting_Operations --
1023    ---------------------------
1024
1025    package body Formatting_Operations is
1026
1027       -----------------
1028       -- Day_Of_Week --
1029       -----------------
1030
1031       function Day_Of_Week (Date : Time) return Integer is
1032          Date_N    : constant Time_Rep := Time_Rep (Date);
1033          Time_Zone : constant Long_Integer :=
1034                        Time_Zones_Operations.UTC_Time_Offset (Date);
1035
1036          Ada_Low_N : Time_Rep;
1037          Day_Count : Long_Integer;
1038          Day_Dur   : Time_Dur;
1039          High_N    : Time_Rep;
1040          Low_N     : Time_Rep;
1041
1042       begin
1043          --  As declared, the Ada Epoch is set in UTC. For this calculation to
1044          --  work properly, both the Epoch and the input date must be in the
1045          --  same time zone. The following places the Epoch in the input date's
1046          --  time zone.
1047
1048          Ada_Low_N := Ada_Low - Time_Rep (Time_Zone) * Nano;
1049
1050          if Date_N > Ada_Low_N then
1051             High_N := Date_N;
1052             Low_N  := Ada_Low_N;
1053          else
1054             High_N := Ada_Low_N;
1055             Low_N  := Date_N;
1056          end if;
1057
1058          --  Determine the elapsed seconds since the start of Ada time
1059
1060          Day_Dur := Time_Dur (High_N / Nano - Low_N / Nano);
1061
1062          --  Count the number of days since the start of Ada time. 1901-01-01
1063          --  GMT was a Tuesday.
1064
1065          Day_Count := Long_Integer (Day_Dur / Secs_In_Day) + 1;
1066
1067          return Integer (Day_Count mod 7);
1068       end Day_Of_Week;
1069
1070       -----------
1071       -- Split --
1072       -----------
1073
1074       procedure Split
1075         (Date      : Time;
1076          Year      : out Year_Number;
1077          Month     : out Month_Number;
1078          Day       : out Day_Number;
1079          Day_Secs  : out Day_Duration;
1080          Hour      : out Integer;
1081          Minute    : out Integer;
1082          Second    : out Integer;
1083          Sub_Sec   : out Duration;
1084          Leap_Sec  : out Boolean;
1085          Is_Ada_05 : Boolean;
1086          Time_Zone : Long_Integer)
1087       is
1088          --  The following constants represent the number of nanoseconds
1089          --  elapsed since the start of Ada time to and including the non
1090          --  leap centennial years.
1091
1092          Year_2101 : constant Time_Rep := Ada_Low +
1093                        Time_Rep (49 * 366 + 151 * 365) * Nanos_In_Day;
1094          Year_2201 : constant Time_Rep := Ada_Low +
1095                        Time_Rep (73 * 366 + 227 * 365) * Nanos_In_Day;
1096          Year_2301 : constant Time_Rep := Ada_Low +
1097                        Time_Rep (97 * 366 + 303 * 365) * Nanos_In_Day;
1098
1099          Date_Dur       : Time_Dur;
1100          Date_N         : Time_Rep;
1101          Day_Seconds    : Natural;
1102          Elapsed_Leaps  : Natural;
1103          Four_Year_Segs : Natural;
1104          Hour_Seconds   : Natural;
1105          Is_Leap_Year   : Boolean;
1106          Next_Leap_N    : Time_Rep;
1107          Rem_Years      : Natural;
1108          Sub_Sec_N      : Time_Rep;
1109          Year_Day       : Natural;
1110
1111       begin
1112          Date_N := Time_Rep (Date);
1113
1114          --  Step 1: Leap seconds processing in UTC
1115
1116          if Leap_Support then
1117             Cumulative_Leap_Seconds
1118               (Start_Of_Time, Date_N, Elapsed_Leaps, Next_Leap_N);
1119
1120             Leap_Sec := Date_N >= Next_Leap_N;
1121
1122             if Leap_Sec then
1123                Elapsed_Leaps := Elapsed_Leaps + 1;
1124             end if;
1125
1126          --  The target does not support leap seconds
1127
1128          else
1129             Elapsed_Leaps := 0;
1130             Leap_Sec      := False;
1131          end if;
1132
1133          Date_N := Date_N - Time_Rep (Elapsed_Leaps) * Nano;
1134
1135          --  Step 2: Time zone processing. This action converts the input date
1136          --  from GMT to the requested time zone.
1137
1138          if Is_Ada_05 then
1139             if Time_Zone /= 0 then
1140                Date_N := Date_N + Time_Rep (Time_Zone) * 60 * Nano;
1141             end if;
1142
1143          --  Ada 83 and 95
1144
1145          else
1146             declare
1147                Off : constant Long_Integer :=
1148                        Time_Zones_Operations.UTC_Time_Offset (Time (Date_N));
1149             begin
1150                Date_N := Date_N + Time_Rep (Off) * Nano;
1151             end;
1152          end if;
1153
1154          --  Step 3: Non-leap centennial year adjustment in local time zone
1155
1156          --  In order for all divisions to work properly and to avoid more
1157          --  complicated arithmetic, we add fake February 29s to dates which
1158          --  occur after a non-leap centennial year.
1159
1160          if Date_N >= Year_2301 then
1161             Date_N := Date_N + Time_Rep (3) * Nanos_In_Day;
1162
1163          elsif Date_N >= Year_2201 then
1164             Date_N := Date_N + Time_Rep (2) * Nanos_In_Day;
1165
1166          elsif Date_N >= Year_2101 then
1167             Date_N := Date_N + Time_Rep (1) * Nanos_In_Day;
1168          end if;
1169
1170          --  Step 4: Sub second processing in local time zone
1171
1172          Sub_Sec_N := Date_N mod Nano;
1173          Sub_Sec   := Duration (Sub_Sec_N) / Nano_F;
1174          Date_N    := Date_N - Sub_Sec_N;
1175
1176          --  Convert Date_N into a time duration value, changing the units
1177          --  to seconds.
1178
1179          Date_Dur := Time_Dur (Date_N / Nano - Ada_Low / Nano);
1180
1181          --  Step 5: Year processing in local time zone. Determine the number
1182          --  of four year segments since the start of Ada time and the input
1183          --  date.
1184
1185          Four_Year_Segs := Natural (Date_Dur / Secs_In_Four_Years);
1186
1187          if Four_Year_Segs > 0 then
1188             Date_Dur := Date_Dur - Time_Dur (Four_Year_Segs) *
1189                                    Secs_In_Four_Years;
1190          end if;
1191
1192          --  Calculate the remaining non-leap years
1193
1194          Rem_Years := Natural (Date_Dur / Secs_In_Non_Leap_Year);
1195
1196          if Rem_Years > 3 then
1197             Rem_Years := 3;
1198          end if;
1199
1200          Date_Dur := Date_Dur - Time_Dur (Rem_Years) * Secs_In_Non_Leap_Year;
1201
1202          Year := Ada_Min_Year + Natural (4 * Four_Year_Segs + Rem_Years);
1203          Is_Leap_Year := Is_Leap (Year);
1204
1205          --  Step 6: Month and day processing in local time zone
1206
1207          Year_Day := Natural (Date_Dur / Secs_In_Day) + 1;
1208
1209          Month := 1;
1210
1211          --  Processing for months after January
1212
1213          if Year_Day > 31 then
1214             Month    := 2;
1215             Year_Day := Year_Day - 31;
1216
1217             --  Processing for a new month or a leap February
1218
1219             if Year_Day > 28
1220               and then (not Is_Leap_Year or else Year_Day > 29)
1221             then
1222                Month    := 3;
1223                Year_Day := Year_Day - 28;
1224
1225                if Is_Leap_Year then
1226                   Year_Day := Year_Day - 1;
1227                end if;
1228
1229                --  Remaining months
1230
1231                while Year_Day > Days_In_Month (Month) loop
1232                   Year_Day := Year_Day - Days_In_Month (Month);
1233                   Month    := Month + 1;
1234                end loop;
1235             end if;
1236          end if;
1237
1238          --  Step 7: Hour, minute, second and sub second processing in local
1239          --  time zone.
1240
1241          Day          := Day_Number (Year_Day);
1242          Day_Seconds  := Integer (Date_Dur mod Secs_In_Day);
1243          Day_Secs     := Duration (Day_Seconds) + Sub_Sec;
1244          Hour         := Day_Seconds / 3_600;
1245          Hour_Seconds := Day_Seconds mod 3_600;
1246          Minute       := Hour_Seconds / 60;
1247          Second       := Hour_Seconds mod 60;
1248       end Split;
1249
1250       -------------
1251       -- Time_Of --
1252       -------------
1253
1254       function Time_Of
1255         (Year         : Year_Number;
1256          Month        : Month_Number;
1257          Day          : Day_Number;
1258          Day_Secs     : Day_Duration;
1259          Hour         : Integer;
1260          Minute       : Integer;
1261          Second       : Integer;
1262          Sub_Sec      : Duration;
1263          Leap_Sec     : Boolean := False;
1264          Use_Day_Secs : Boolean := False;
1265          Is_Ada_05    : Boolean := False;
1266          Time_Zone    : Long_Integer := 0) return Time
1267       is
1268          Count         : Integer;
1269          Elapsed_Leaps : Natural;
1270          Next_Leap_N   : Time_Rep;
1271          Res_N         : Time_Rep;
1272          Rounded_Res_N : Time_Rep;
1273
1274       begin
1275          --  Step 1: Check whether the day, month and year form a valid date
1276
1277          if Day > Days_In_Month (Month)
1278            and then (Day /= 29 or else Month /= 2 or else not Is_Leap (Year))
1279          then
1280             raise Time_Error;
1281          end if;
1282
1283          --  Start accumulating nanoseconds from the low bound of Ada time
1284
1285          Res_N := Ada_Low;
1286
1287          --  Step 2: Year processing and centennial year adjustment. Determine
1288          --  the number of four year segments since the start of Ada time and
1289          --  the input date.
1290
1291          Count := (Year - Year_Number'First) / 4;
1292          for Four_Year_Segments in 1 .. Count loop
1293             Res_N := Res_N + Nanos_In_Four_Years;
1294          end loop;
1295
1296          --  Note that non-leap centennial years are automatically considered
1297          --  leap in the operation above. An adjustment of several days is
1298          --  required to compensate for this.
1299
1300          if Year > 2300 then
1301             Res_N := Res_N - Time_Rep (3) * Nanos_In_Day;
1302
1303          elsif Year > 2200 then
1304             Res_N := Res_N - Time_Rep (2) * Nanos_In_Day;
1305
1306          elsif Year > 2100 then
1307             Res_N := Res_N - Time_Rep (1) * Nanos_In_Day;
1308          end if;
1309
1310          --  Add the remaining non-leap years
1311
1312          Count := (Year - Year_Number'First) mod 4;
1313          Res_N := Res_N + Time_Rep (Count) * Secs_In_Non_Leap_Year * Nano;
1314
1315          --  Step 3: Day of month processing. Determine the number of days
1316          --  since the start of the current year. Do not add the current
1317          --  day since it has not elapsed yet.
1318
1319          Count := Cumulative_Days_Before_Month (Month) + Day - 1;
1320
1321          --  The input year is leap and we have passed February
1322
1323          if Is_Leap (Year)
1324            and then Month > 2
1325          then
1326             Count := Count + 1;
1327          end if;
1328
1329          Res_N := Res_N + Time_Rep (Count) * Nanos_In_Day;
1330
1331          --  Step 4: Hour, minute, second and sub second processing
1332
1333          if Use_Day_Secs then
1334             Res_N := Res_N + Duration_To_Time_Rep (Day_Secs);
1335
1336          else
1337             Res_N :=
1338               Res_N + Time_Rep (Hour * 3_600 + Minute * 60 + Second) * Nano;
1339
1340             if Sub_Sec = 1.0 then
1341                Res_N := Res_N + Time_Rep (1) * Nano;
1342             else
1343                Res_N := Res_N + Duration_To_Time_Rep (Sub_Sec);
1344             end if;
1345          end if;
1346
1347          --  At this point, the generated time value should be withing the
1348          --  bounds of Ada time.
1349
1350          Check_Within_Time_Bounds (Res_N);
1351
1352          --  Step 4: Time zone processing. At this point we have built an
1353          --  arbitrary time value which is not related to any time zone.
1354          --  For simplicity, the time value is normalized to GMT, producing
1355          --  a uniform representation which can be treated by arithmetic
1356          --  operations for instance without any additional corrections.
1357
1358          if Is_Ada_05 then
1359             if Time_Zone /= 0 then
1360                Res_N := Res_N - Time_Rep (Time_Zone) * 60 * Nano;
1361             end if;
1362
1363          --  Ada 83 and 95
1364
1365          else
1366             declare
1367                Current_Off   : constant Long_Integer :=
1368                                  Time_Zones_Operations.UTC_Time_Offset
1369                                    (Time (Res_N));
1370                Current_Res_N : constant Time_Rep :=
1371                                  Res_N - Time_Rep (Current_Off) * Nano;
1372                Off           : constant Long_Integer :=
1373                                  Time_Zones_Operations.UTC_Time_Offset
1374                                    (Time (Current_Res_N));
1375             begin
1376                Res_N := Res_N - Time_Rep (Off) * Nano;
1377             end;
1378          end if;
1379
1380          --  Step 5: Leap seconds processing in GMT
1381
1382          if Leap_Support then
1383             Cumulative_Leap_Seconds
1384               (Start_Of_Time, Res_N, Elapsed_Leaps, Next_Leap_N);
1385
1386             Res_N := Res_N + Time_Rep (Elapsed_Leaps) * Nano;
1387
1388             --  An Ada 2005 caller requesting an explicit leap second or an
1389             --  Ada 95 caller accounting for an invisible leap second.
1390
1391             if Leap_Sec
1392               or else Res_N >= Next_Leap_N
1393             then
1394                Res_N := Res_N + Time_Rep (1) * Nano;
1395             end if;
1396
1397             --  Leap second validity check
1398
1399             Rounded_Res_N := Res_N - (Res_N mod Nano);
1400
1401             if Is_Ada_05
1402               and then Leap_Sec
1403               and then Rounded_Res_N /= Next_Leap_N
1404             then
1405                raise Time_Error;
1406             end if;
1407          end if;
1408
1409          return Time (Res_N);
1410       end Time_Of;
1411
1412    end Formatting_Operations;
1413
1414    ---------------------------
1415    -- Time_Zones_Operations --
1416    ---------------------------
1417
1418    package body Time_Zones_Operations is
1419
1420       --  The Unix time bounds in nanoseconds: 1970/1/1 .. 2037/1/1
1421
1422       Unix_Min : constant Time_Rep := Ada_Low +
1423                    Time_Rep (17 * 366 +  52 * 365) * Nanos_In_Day;
1424
1425       Unix_Max : constant Time_Rep := Ada_Low +
1426                    Time_Rep (34 * 366 + 102 * 365) * Nanos_In_Day +
1427                    Time_Rep (Leap_Seconds_Count) * Nano;
1428
1429       --  The following constants denote February 28 during non-leap
1430       --  centennial years, the units are nanoseconds.
1431
1432       T_2100_2_28 : constant Time_Rep := Ada_Low +
1433                       (Time_Rep (49 * 366 + 150 * 365 + 59) * Secs_In_Day +
1434                        Time_Rep (Leap_Seconds_Count)) * Nano;
1435
1436       T_2200_2_28 : constant Time_Rep := Ada_Low +
1437                       (Time_Rep (73 * 366 + 226 * 365 + 59) * Secs_In_Day +
1438                        Time_Rep (Leap_Seconds_Count)) * Nano;
1439
1440       T_2300_2_28 : constant Time_Rep := Ada_Low +
1441                       (Time_Rep (97 * 366 + 302 * 365 + 59) * Secs_In_Day +
1442                        Time_Rep (Leap_Seconds_Count)) * Nano;
1443
1444       --  56 years (14 leap years + 42 non leap years) in nanoseconds:
1445
1446       Nanos_In_56_Years : constant := (14 * 366 + 42 * 365) * Nanos_In_Day;
1447
1448       subtype long is Long_Integer;
1449       type long_Pointer is access all long;
1450
1451       type time_t is
1452         range -(2 ** (Standard'Address_Size - Integer'(1))) ..
1453               +(2 ** (Standard'Address_Size - Integer'(1)) - 1);
1454       type time_t_Pointer is access all time_t;
1455
1456       procedure localtime_tzoff
1457        (timer : time_t_Pointer;
1458         off   : long_Pointer);
1459       pragma Import (C, localtime_tzoff, "__gnat_localtime_tzoff");
1460       --  This is a lightweight wrapper around the system library function
1461       --  localtime_r. Parameter 'off' captures the UTC offset which is either
1462       --  retrieved from the tm struct or calculated from the 'timezone' extern
1463       --  and the tm_isdst flag in the tm struct.
1464
1465       ---------------------
1466       -- UTC_Time_Offset --
1467       ---------------------
1468
1469       function UTC_Time_Offset (Date : Time) return Long_Integer is
1470          Adj_Cent : Integer;
1471          Date_N   : Time_Rep;
1472          Offset   : aliased long;
1473          Secs_T   : aliased time_t;
1474
1475       begin
1476          Date_N := Time_Rep (Date);
1477
1478          --  Dates which are 56 years apart fall on the same day, day light
1479          --  saving and so on. Non-leap centennial years violate this rule by
1480          --  one day and as a consequence, special adjustment is needed.
1481
1482          Adj_Cent :=
1483            (if    Date_N <= T_2100_2_28 then 0
1484             elsif Date_N <= T_2200_2_28 then 1
1485             elsif Date_N <= T_2300_2_28 then 2
1486             else                             3);
1487
1488          if Adj_Cent > 0 then
1489             Date_N := Date_N - Time_Rep (Adj_Cent) * Nanos_In_Day;
1490          end if;
1491
1492          --  Shift the date within bounds of Unix time
1493
1494          while Date_N < Unix_Min loop
1495             Date_N := Date_N + Nanos_In_56_Years;
1496          end loop;
1497
1498          while Date_N >= Unix_Max loop
1499             Date_N := Date_N - Nanos_In_56_Years;
1500          end loop;
1501
1502          --  Perform a shift in origins from Ada to Unix
1503
1504          Date_N := Date_N - Unix_Min;
1505
1506          --  Convert the date into seconds
1507
1508          Secs_T := time_t (Date_N / Nano);
1509
1510          localtime_tzoff
1511            (Secs_T'Unchecked_Access,
1512             Offset'Unchecked_Access);
1513
1514          return Offset;
1515       end UTC_Time_Offset;
1516
1517    end Time_Zones_Operations;
1518
1519 --  Start of elaboration code for Ada.Calendar
1520
1521 begin
1522    System.OS_Primitives.Initialize;
1523 end Ada.Calendar;