gcc/ada/a-calari.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --              A D A . C A L E N D A R . A R I T H M E T I C               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --            Copyright (C) 2006, Free Software Foundation, Inc.            --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Unchecked_Conversion;
  35
  36 package body Ada.Calendar.Arithmetic is
  37
  38    use Leap_Sec_Ops;
  39
  40    Day_Duration : constant Duration := 86_400.0;
  41
  42    ---------
  43    -- "+" --
  44    ---------
  45
  46    function "+" (Left : Time; Right : Day_Count) return Time is
  47    begin
  48       return Left + Integer (Right) * Day_Duration;
  49    end "+";
  50
  51    function "+" (Left : Day_Count; Right : Time) return Time is
  52    begin
  53       return Integer (Left) * Day_Duration + Right;
  54    end "+";
  55
  56    ---------
  57    -- "-" --
  58    ---------
  59
  60    function "-" (Left : Time; Right : Day_Count) return Time is
  61    begin
  62       return Left - Integer (Right) * Day_Duration;
  63    end "-";
  64
  65    function "-" (Left, Right : Time) return Day_Count is
  66       Days         : Day_Count;
  67       Seconds      : Duration;
  68       Leap_Seconds : Leap_Seconds_Count;
  69
  70    begin
  71       Difference (Left, Right, Days, Seconds, Leap_Seconds);
  72       return Days;
  73    end "-";
  74
  75    ----------------
  76    -- Difference --
  77    ----------------
  78
  79    procedure Difference
  80      (Left, Right  : Time;
  81       Days         : out Day_Count;
  82       Seconds      : out Duration;
  83       Leap_Seconds : out Leap_Seconds_Count)
  84    is
  85       Diff        : Duration;
  86       Earlier     : Time;
  87       Later       : Time;
  88       Leaps_Dur   : Duration;
  89       Negate      : Boolean;
  90       Next_Leap   : Time;
  91       Secs_Diff   : Long_Integer;
  92       Sub_Seconds : Duration;
  93
  94    begin
  95       if Left >= Right then
  96          Later   := Left;
  97          Earlier := Right;
  98          Negate  := False;
  99       else
 100          Later   := Right;
 101          Earlier := Left;
 102          Negate  := True;
 103       end if;
 104
 105       Diff := Later - Earlier;
 106
 107       Cumulative_Leap_Secs (Earlier, Later, Leaps_Dur, Next_Leap);
 108
 109       if Later >= Next_Leap then
 110          Leaps_Dur := Leaps_Dur + 1.0;
 111       end if;
 112
 113       Diff := Diff - Leaps_Dur;
 114
 115       declare
 116          type D_Int is range 0 .. 2 ** (Duration'Size - 1) - 1;
 117          for D_Int'Size use Duration'Size;
 118
 119          Small_Div : constant D_Int := D_Int (1.0 / Duration'Small);
 120          D_As_Int  : D_Int;
 121
 122          function To_D_As_Int is new Unchecked_Conversion (Duration, D_Int);
 123          function To_Duration is new Unchecked_Conversion (D_Int, Duration);
 124
 125       begin
 126          D_As_Int    := To_D_As_Int (Diff);
 127          Secs_Diff   := Long_Integer (D_As_Int / Small_Div);
 128          Sub_Seconds := To_Duration (D_As_Int rem Small_Div);
 129       end;
 130
 131       Days    := Day_Count (Secs_Diff / 86_400);
 132       Seconds := Duration (Secs_Diff mod 86_400) + Sub_Seconds;
 133       Leap_Seconds := Leap_Seconds_Count (Leaps_Dur);
 134
 135       if Negate then
 136          Days         := -Days;
 137          Seconds      := -Seconds;
 138          Leap_Seconds := -Leap_Seconds;
 139       end if;
 140    end Difference;
 141
 142 end Ada.Calendar.Arithmetic;