gcc/ada/5wgloloc.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                  S Y S T E M . G L O B A L _ L O C K S                   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.5 $
  10 --                                                                          --
  11 --           Copyright (C) 1999-2001 Ada Core Technologies, Inc.            --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNAT is maintained by Ada Core Technologies Inc (http://www.gnat.com).   --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This implementation is specific to NT.
  36
  37 with GNAT.Task_Lock;
  38
  39 with Interfaces.C.Strings;
  40 with System.OS_Interface;
  41
  42 package body System.Global_Locks is
  43
  44    package TSL renames GNAT.Task_Lock;
  45    package OSI renames System.OS_Interface;
  46    package ICS renames Interfaces.C.Strings;
  47
  48    subtype Lock_File_Entry is OSI.HANDLE;
  49
  50    Last_Lock  : Lock_Type := Null_Lock;
  51    Lock_Table : array (Lock_Type range 1 .. 15) of Lock_File_Entry;
  52
  53    -----------------
  54    -- Create_Lock --
  55    -----------------
  56
  57    procedure Create_Lock
  58      (Lock : out Lock_Type;
  59       Name : in String)
  60    is
  61       L : Lock_Type;
  62
  63    begin
  64       TSL.Lock;
  65       Last_Lock := Last_Lock + 1;
  66       L := Last_Lock;
  67       TSL.Unlock;
  68
  69       if L > Lock_Table'Last then
  70          raise Lock_Error;
  71       end if;
  72
  73       Lock_Table (L) :=
  74         OSI.CreateMutex (null, OSI.BOOL (False), ICS.New_String (Name));
  75       Lock := L;
  76    end Create_Lock;
  77
  78    ------------------
  79    -- Acquire_Lock --
  80    ------------------
  81
  82    procedure Acquire_Lock
  83      (Lock : in out Lock_Type)
  84    is
  85       use type OSI.DWORD;
  86
  87       Res : OSI.DWORD;
  88    begin
  89       Res := OSI.WaitForSingleObject (Lock_Table (Lock), OSI.Wait_Infinite);
  90
  91       if Res = OSI.WAIT_FAILED then
  92          raise Lock_Error;
  93       end if;
  94    end Acquire_Lock;
  95
  96    ------------------
  97    -- Release_Lock --
  98    ------------------
  99
 100    procedure Release_Lock
 101      (Lock : in out Lock_Type)
 102    is
 103       use type OSI.BOOL;
 104
 105       Res : OSI.BOOL;
 106    begin
 107       Res := OSI.ReleaseMutex (Lock_Table (Lock));
 108
 109       if Res = OSI.False then
 110          raise Lock_Error;
 111       end if;
 112    end Release_Lock;
 113
 114 end System.Global_Locks;